etc/cshrc

   1 #----------------------------------*-sh-*--------------------------------------
   2 # =========                 |
   3 # \\      /  F ield         | OpenFOAM: The Open Source CFD Toolbox
   4 #  \\    /   O peration     |
   5 #   \\  /    A nd           | Copyright (C) 1991-2008 OpenCFD Ltd.
   6 #    \\/     M anipulation  |
   7 #------------------------------------------------------------------------------
   8 # License
   9 #     This file is part of OpenFOAM.
  10 #
  11 #     OpenFOAM is free software; you can redistribute it and/or modify it
  12 #     under the terms of the GNU General Public License as published by the
  13 #     Free Software Foundation; either version 2 of the License, or (at your
  14 #     option) any later version.
  15 #
  16 #     OpenFOAM is distributed in the hope that it will be useful, but WITHOUT
  17 #     ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  18 #     FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  19 #     for more details.
  20 #
  21 #     You should have received a copy of the GNU General Public License
  22 #     along with OpenFOAM; if not, write to the Free Software Foundation,
  23 #     Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
  24 #
  25 # Script
  26 #     etc/cshrc
  27 #
  28 # Description
  29 #     Startup file for OpenFOAM
  30 #     Sourced from ~/.login or ~/.cshrc
  31 #
  32 #------------------------------------------------------------------------------
  33
  34 setenv WM_PROJECT OpenFOAM
  35 setenv WM_PROJECT_VERSION 1.5.x
  36
  37 #!!User:
  38 #    either setenv FOAM_INST_DIR before sourcing this file or set
  39 #    foamInstall below to where OpenFOAM is installed
  40 #
  41 # Location of FOAM installation
  42 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  43 set foamInstall = $HOME/$WM_PROJECT
  44 # set foamInstall = ~$WM_PROJECT
  45 # set foamInstall = /usr/local/$WM_PROJECT
  46 # set foamInstall = /opt/$WM_PROJECT
  47
  48 if ( ! $?FOAM_INST_DIR ) setenv FOAM_INST_DIR $foamInstall
  49
  50
  51 # Location of site/user files
  52 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~
  53 setenv WM_PROJECT_INST_DIR $FOAM_INST_DIR
  54 setenv WM_PROJECT_DIR $WM_PROJECT_INST_DIR/$WM_PROJECT-$WM_PROJECT_VERSION
  55 setenv WM_PROJECT_USER_DIR $HOME/$WM_PROJECT/$LOGNAME-$WM_PROJECT_VERSION
  56
  57
  58 # Location of third-party software
  59 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  60 setenv WM_THIRD_PARTY_DIR $WM_PROJECT_INST_DIR/ThirdParty
  61
  62
  63 # Compiler: set to Gcc, Gcc42 or Icc (for Intel's icc)
  64 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  65 if ( ! $?WM_COMPILER ) setenv WM_COMPILER Gcc
  66
  67 setenv WM_COMPILER_ARCH
  68 setenv WM_COMPILER_LIB_ARCH
  69
  70
  71 # Compilation options (architecture, precision, optimised, debug or profiling)
  72 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  73 # WM_ARCH_OPTION = 32 | 64
  74 if ( ! $?WM_ARCH_OPTION ) setenv WM_ARCH_OPTION 64
  75
  76 # WM_PRECISION_OPTION = DP | SP
  77 if ( ! $?WM_PRECISION_OPTION ) setenv WM_PRECISION_OPTION DP
  78
  79 # WM_COMPILE_OPTION = Opt | Debug | Prof
  80 if ( ! $?WM_COMPILE_OPTION ) setenv WM_COMPILE_OPTION Opt
  81
  82 # WM_JAVAC_OPTION = Opt | Debug
  83 if ( ! $?WM_JAVAC_OPTION ) setenv WM_JAVAC_OPTION Opt
  84
  85 # WM_MPLIB = | OPENMPI | LAM | MPICH | MPICH-GM | HPMPI | GAMMA | MPI | QSMPI
  86 if ( ! $?WM_MPLIB ) setenv WM_MPLIB OPENMPI
  87
  88
  89 # Run options (floating-point signal handling and memory initialisation)
  90 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  91 setenv FOAM_SIGFPE
  92 # setenv FOAM_SETNAN
  93
  94
  95 # Detect system type and set environment variables
  96 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  97 setenv WM_ARCH `uname -s`
  98
  99 switch ($WM_ARCH)
 100 case Linux:
 101     setenv WM_ARCH linux
 102
 103     switch (`uname -m`)
 104     case i686:
 105         breaksw
 106     case x86_64:
 107         switch ($WM_ARCH_OPTION)
 108         case 32:
 109             setenv WM_ARCH linux
 110             setenv WM_COMPILER_ARCH '-64'
 111             setenv WM_CC 'gcc'
 112             setenv WM_CXX 'g++'
 113             setenv WM_CFLAGS '-m32 -fPIC'
 114             setenv WM_CXXFLAGS '-m32 -fPIC'
 115             setenv WM_LDFLAGS '-m32'
 116             breaksw
 117         case 64:
 118             setenv WM_ARCH linux64
 119             setenv WM_COMPILER_LIB_ARCH 64
 120             setenv WM_CC 'gcc'
 121             setenv WM_CXX 'g++'
 122             setenv WM_CFLAGS '-m64 -fPIC'
 123             setenv WM_CXXFLAGS '-m64 -fPIC'
 124             setenv WM_LDFLAGS '-m64'
 125             breaksw
 126         default:
 127             echo Unknown WM_ARCH_OPTION $WM_ARCH_OPTION, should be 32 or 64
 128             breaksw
 129         endsw
 130         breaksw
 131     case ia64:
 132         setenv WM_ARCH linuxIA64
 133         setenv WM_COMPILER I64
 134         breaksw
 135     case mips64:
 136         setenv WM_ARCH SiCortex64
 137         setenv WM_COMPILER_LIB_ARCH 64
 138         setenv WM_CC 'gcc'
 139         setenv WM_CXX 'g++'
 140         setenv WM_CFLAGS '-mabi=64 -fPIC'
 141         setenv WM_CXXFLAGS '-mabi=64 -fPIC'
 142         setenv WM_LDFLAGS '-mabi=64 -G0'
 143         setenv WM_MPLIB MPI
 144         breaksw
 145     default:
 146         echo Unknown processor type `uname -m` for Linux
 147         breaksw
 148     endsw
 149     breaksw
 150
 151 case SunOS:
 152     setenv WM_ARCH SunOS64
 153     setenv WM_COMPILER_LIB_ARCH 64
 154     setenv WM_CC 'gcc'
 155     setenv WM_CXX 'g++'
 156     setenv WM_CFLAGS '-mabi=64 -fPIC'
 157     setenv WM_CXXFLAGS '-mabi=64 -fPIC'
 158     setenv WM_LDFLAGS '-mabi=64 -G0'
 159     setenv WM_MPLIB FJMPI
 160     breaksw
 161
 162 default:
 163     echo
 164     echo "Your '$WM_ARCH' operating system is not supported by this release"
 165     echo "of OpenFOAM. For further assistance, please contact www.openfoam.org"
 166     echo
 167     breaksw
 168
 169 endsw
 170
 171
 172 # Clean standard environment variables (path, PATH, MANPATH, LD_LIBRARY_PATH)
 173 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 174 set cleanProg=$WM_PROJECT_DIR/bin/foamCleanPath
 175
 176 if (! $?LD_LIBRARY_PATH ) then
 177     setenv LD_LIBRARY_PATH ''
 178 endif
 179 if (! $?MANPATH) then
 180     setenv MANPATH ''
 181 endif
 182
 183 # Remove anything under top-level foam directory
 184 set wildCards="$WM_PROJECT_INST_DIR $HOME/$WM_PROJECT/$LOGNAME"
 185
 186 #- Clean path/PATH
 187 set colonPath=`echo "$path" | sed -e 's/ /:/g'`
 188 set PATH=`$cleanProg "$colonPath" "$wildCards"`
 189 if ( $status == 0 ) then
 190     set path=`echo "$PATH" | sed -e 's/:/ /g'`
 191 endif
 192
 193 #- Clean LD_LIBRARY_PATH
 194 setenv LD_LIBRARY_PATH `$cleanProg "$LD_LIBRARY_PATH" "$wildCards"`
 195
 196 #- Clean MANPATH
 197 setenv MANPATH `$cleanProg "$MANPATH" "$wildCards"`
 198
 199
 200 # Source project setup files
 201 # ~~~~~~~~~~~~~~~~~~~~~~~~~~
 202 alias _foamSource 'if ($?FOAM_VERBOSE && $?prompt) echo "Executing: \!*"; source \!*'
 203
 204 _foamSource $WM_PROJECT_DIR/etc/settings.csh
 205 _foamSource $WM_PROJECT_DIR/etc/aliases.csh
 206
 207 # Source user setup files for optional packages
 208 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 209 # _foamSource $WM_PROJECT_DIR/etc/apps/paraview/cshrc
 210 _foamSource $WM_PROJECT_DIR/etc/apps/paraview3/cshrc
 211 # _foamSource $WM_PROJECT_DIR/etc/apps/ensightFoam/cshrc
 212
 213
 214 # Again clean environment (path, PATH, MANPATH, LD_LIBRARY_PATH)
 215 # ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 216 #- Clean path/PATH. Only remove duplicates
 217 set colonPath=`echo "$path" | sed -e 's/ /:/g'`
 218 set PATH=`$cleanProg "$colonPath"`
 219 if ( $status == 0 ) then
 220     set path=`echo "$PATH" | sed -e 's/:/ /g'`
 221 endif
 222
 223 #- Clean LD_LIBRARY_PATH
 224 setenv LD_LIBRARY_PATH `$cleanProg "$LD_LIBRARY_PATH"`
 225
 226 #- Clean MANPATH
 227 setenv MANPATH `$cleanProg "$MANPATH"`
 228
 229 #- Clean LD_PRELOAD
 230 if ( $?LD_PRELOAD ) then
 231     setenv LD_PRELOAD `$cleanProg "$LD_PRELOAD"`
 232 endif
 233
 234 # cleanup environment:
 235 # ~~~~~~~~~~~~~~~~~~~~
 236 unset cleanProg
 237 unset wildCards
 238 unset colonPath
 239 unalias _foamSource
 240 # -----------------------------------------------------------------------------