regina/build.com

   1 $
   2 $! build procedure for regina on vms
   3 $! - sample environment and invoke mmk/mms
   4 $ SET NOON
   5 $ _V = F$VERIFY(1)
   6 $!
   7 $ IF P1 .EQS. "CLEAN"
   8 $ THEN
   9 $   DELETE/NOLOG *.OBJ;*,*.EXE;*
  10 $   EXIT $STATUS
  11 $ ENDIF
  12 $!
  13 $ DEBUG=0
  14 $ IF P1 .EQS. "DEBUG"
  15 $ THEN
  16 $   DEBUG=1
  17 $   DEBUGGING=1
  18 $ ENDIF
  19 $!
  20 $ MACRO1 = "UNDEF"
  21 $ MACRO2 = "UNDEF"
  22 $ MACRO3 = "UNDEF"
  23 $!
  24 $ IF F$GETSYI("VERSION") .GTS. "V5.2"
  25 $ THEN
  26 $!
  27 $   IF F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE") .EQS. "ALPHA"
  28 $   THEN
  29 $     MACRO1 = "ALPHA"
  30 $   ELSE
  31 $     MACRO1 = "VAX"
  32 $   ENDIF
  33 $!
  34 $   IF F$GETSYI("VERSION") .LTS. "V6.2"
  35 $   THEN
  36 $     MACRO2 = "DOESNT_HAVE_UNAME"
  37 $   ELSE
  38 $     IF F$GETSYI("VERSION") .LES. "V7.0"
  39 $     THEN
  40 $       MACRO2 = "DOESNT_HAVE_UNAME"
  41 $     ENDIF
  42 $   ENDIF
  43 $!
  44 $ ELSE
  45 $   MACRO1 = "VAX"      ! accounts for early versions of vms
  46 $ ENDIF
  47 $!
  48 $ ! double quote character
  49 $ DQ = """
  50 $ _MAKE="MMK /DESCRIP=DESCRIP.MMS /OUTPUT=''MACRO1'_BUILD.LOG"
  51 $ IF MACRO3 .NES. "UNDEF"
  52 $ THEN
  53 $   _MACRO = DQ + MACRO1 + DQ + "," + DQ + MACRO2 + DQ + "," + DQ + MACRO3 + DQ
  54 $ ELSE
  55 $   IF MACRO2 .NES. "UNDEF"
  56 $   THEN
  57 $     _MACRO = DQ + MACRO1 + DQ + "," + DQ + MACRO2 + DQ
  58 $   ELSE
  59 $     _MACRO = DQ + MACRO1 + DQ
  60 $   ENDIF
  61 $ ENDIF
  62 $
  63 $ IF DEBUG THEN _MACRO = _MACRO + "," + DQ + "DEBUG" + DQ
  64 $
  65 $ '_MAKE' /MACRO=('_MACRO')
  66 $
  67 $! IF F$SEARCH("REXX.EXE") .NES. "" THEN COPY REXX.EXE REXX.EXE_'MACRO1'
  68 $! IF F$SEARCH("REGINA.EXE") .NES. "" THEN COPY REGINA.EXE REGINA.EXE_'MACRO1'
  69 $! IF F$SEARCH("EXERCISER.EXE") .NES. "" THEN COPY EXERCISER.EXE EXERCISER.EXE_'MACRO1'
  70 $!
  71 $ _V = F$VERIFY(_V)     ! reset
  72 $ EXIT $STATUS