toolchain/gcc/gcc/ada/g-table.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUNTIME COMPONENTS                          --
   4 --                                                                          --
   5 --                            G N A T . T A B L E                           --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --            Copyright (C) 1998-2003 Ada Core Technologies, Inc.           --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  Resizable one dimensional array support
  35
  36 --  This package provides an implementation of dynamically resizable one
  37 --  dimensional arrays. The idea is to mimic the normal Ada semantics for
  38 --  arrays as closely as possible with the one additional capability of
  39 --  dynamically modifying the value of the Last attribute.
  40
  41 --  This package provides a facility similar to that of GNAT.Dynamic_Tables,
  42 --  except that this package declares a single instance of the table type,
  43 --  while an instantiation of GNAT.Dynamic_Tables creates a type that can be
  44 --  used to define dynamic instances of the table.
  45
  46 --  Note that this interface should remain synchronized with those in
  47 --  GNAT.Dynamic_Tables and the GNAT compiler source unit Table to keep
  48 --  as much coherency as possible between these three related units.
  49
  50 generic
  51    type Table_Component_Type is private;
  52    type Table_Index_Type     is range <>;
  53
  54    Table_Low_Bound : Table_Index_Type;
  55    Table_Initial   : Positive;
  56    Table_Increment : Natural;
  57
  58 package GNAT.Table is
  59 pragma Elaborate_Body (Table);
  60
  61    --  Table_Component_Type and Table_Index_Type specify the type of the
  62    --  array, Table_Low_Bound is the lower bound. Index_type must be an
  63    --  integer type. The effect is roughly to declare:
  64
  65    --    Table : array (Table_Index_Type range Table_Low_Bound .. <>)
  66    --                       of Table_Component_Type;
  67
  68    --    Note: since the upper bound can be one less than the lower
  69    --    bound for an empty array, the table index type must be able
  70    --    to cover this range, e.g. if the lower bound is 1, then the
  71    --    Table_Index_Type should be Natural rather than Positive.
  72
  73    --  Table_Component_Type may be any Ada type, except that controlled
  74    --  types are not supported. Note however that default initialization
  75    --  will NOT occur for array components.
  76
  77    --  The Table_Initial values controls the allocation of the table when
  78    --  it is first allocated, either by default, or by an explicit Init call.
  79
  80    --  The Table_Increment value controls the amount of increase, if the
  81    --  table has to be increased in size. The value given is a percentage
  82    --  value (e.g. 100 = increase table size by 100%, i.e. double it).
  83
  84    --  The Last and Set_Last subprograms provide control over the current
  85    --  logical allocation. They are quite efficient, so they can be used
  86    --  freely (expensive reallocation occurs only at major granularity
  87    --  chunks controlled by the allocation parameters).
  88
  89    --  Note: we do not make the table components aliased, since this would
  90    --  restrict the use of table for discriminated types. If it is necessary
  91    --  to take the access of a table element, use Unrestricted_Access.
  92
  93    --  WARNING: On HPPA, the virtual addressing approach used in this unit
  94    --  is incompatible with the indexing instructions on the HPPA. So when
  95    --  using this unit, compile your application with -mdisable-indexing.
  96
  97    --  WARNING: If the table is reallocated, then the address of all its
  98    --  components will change. So do not capture the address of an element
  99    --  and then use the address later after the table may be reallocated.
 100    --  One tricky case of this is passing an element of the table to a
 101    --  subprogram by reference where the table gets reallocated during
 102    --  the execution of the subprogram. The best rule to follow is never
 103    --  to pass a table element as a parameter except for the case of IN
 104    --  mode parameters with scalar values.
 105
 106    type Table_Type is
 107      array (Table_Index_Type range <>) of Table_Component_Type;
 108
 109    subtype Big_Table_Type is
 110      Table_Type (Table_Low_Bound .. Table_Index_Type'Last);
 111    --  We work with pointers to a bogus array type that is constrained
 112    --  with the maximum possible range bound. This means that the pointer
 113    --  is a thin pointer, which is more efficient. Since subscript checks
 114    --  in any case must be on the logical, rather than physical bounds,
 115    --  safety is not compromised by this approach.
 116
 117    type Table_Ptr is access all Big_Table_Type;
 118    --  The table is actually represented as a pointer to allow reallocation
 119
 120    Table : aliased Table_Ptr := null;
 121    --  The table itself. The lower bound is the value of Low_Bound.
 122    --  Logically the upper bound is the current value of Last (although
 123    --  the actual size of the allocated table may be larger than this).
 124    --  The program may only access and modify Table entries in the range
 125    --  First .. Last.
 126
 127    Locked : Boolean := False;
 128    --  Table expansion is permitted only if this switch is set to False. A
 129    --  client may set Locked to True, in which case any attempt to expand
 130    --  the table will cause an assertion failure. Note that while a table
 131    --  is locked, its address in memory remains fixed and unchanging.
 132
 133    procedure Init;
 134    --  This procedure allocates a new table of size Initial (freeing any
 135    --  previously allocated larger table). It is not necessary to call
 136    --  Init when a table is first instantiated (since the instantiation does
 137    --  the same initialization steps). However, it is harmless to do so, and
 138    --  Init is convenient in reestablishing a table for new use.
 139
 140    function Last return Table_Index_Type;
 141    pragma Inline (Last);
 142    --  Returns the current value of the last used entry in the table, which
 143    --  can then be used as a subscript for Table. Note that the only way to
 144    --  modify Last is to call the Set_Last procedure. Last must always be
 145    --  used to determine the logically last entry.
 146
 147    procedure Release;
 148    --  Storage is allocated in chunks according to the values given in the
 149    --  Initial and Increment parameters. A call to Release releases all
 150    --  storage that is allocated, but is not logically part of the current
 151    --  array value. Current array values are not affected by this call.
 152
 153    procedure Free;
 154    --  Free all allocated memory for the table. A call to init is required
 155    --  before any use of this table after calling Free.
 156
 157    First : constant Table_Index_Type := Table_Low_Bound;
 158    --  Export First as synonym for Low_Bound (parallel with use of Last)
 159
 160    procedure Set_Last (New_Val : Table_Index_Type);
 161    pragma Inline (Set_Last);
 162    --  This procedure sets Last to the indicated value. If necessary the
 163    --  table is reallocated to accommodate the new value (i.e. on return
 164    --  the allocated table has an upper bound of at least Last). If Set_Last
 165    --  reduces the size of the table, then logically entries are removed
 166    --  from the table. If Set_Last increases the size of the table, then
 167    --  new entries are logically added to the table.
 168
 169    procedure Increment_Last;
 170    pragma Inline (Increment_Last);
 171    --  Adds 1 to Last (same as Set_Last (Last + 1)
 172
 173    procedure Decrement_Last;
 174    pragma Inline (Decrement_Last);
 175    --  Subtracts 1 from Last (same as Set_Last (Last - 1)
 176
 177    procedure Append (New_Val : Table_Component_Type);
 178    pragma Inline (Append);
 179    --  Equivalent to:
 180    --    x.Increment_Last;
 181    --    x.Table (x.Last) := New_Val;
 182    --  i.e. the table size is increased by one, and the given new item
 183    --  stored in the newly created table element.
 184
 185    procedure Set_Item
 186      (Index : Table_Index_Type;
 187       Item  : Table_Component_Type);
 188    pragma Inline (Set_Item);
 189    --  Put Item in the table at position Index. The table is expanded if the
 190    --  current table length is less than Index and in that case Last is set to
 191    --  Index. Item will replace any value already present in the table at this
 192    --  position.
 193
 194    function Allocate (Num : Integer := 1) return Table_Index_Type;
 195    pragma Inline (Allocate);
 196    --  Adds Num to Last, and returns the old value of Last + 1. Note that
 197    --  this function has the possible side effect of reallocating the table.
 198    --  This means that a reference X.Table (X.Allocate) is incorrect, since
 199    --  the call to X.Allocate may modify the results of calling X.Table.
 200
 201 end GNAT.Table;