configure.ac

   1 AC_PREREQ([2.63])
   2 AC_INIT([Yelp],[3.16.0],[http://bugzilla.gnome.org/enter_bug.cgi?product=yelp],[yelp])
   3
   4 AC_CONFIG_SRCDIR([src/yelp.c])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AM_INIT_AUTOMAKE([1.11 dist-bzip2 no-dist-gzip tar-ustar])
   9 AM_MAINTAINER_MODE([enable])
  10
  11 AM_SILENT_RULES([yes])
  12
  13 AX_IS_RELEASE([git-directory])
  14 AX_CHECK_ENABLE_DEBUG([info], [YELP_DEBUG], [$ax_is_release])
  15
  16 AX_COMPILER_FLAGS([], [], [$ax_is_release])
  17 # Check for programs
  18 AC_PROG_CC
  19 AC_PROG_CC_C_O
  20 AC_PROG_LN_S
  21
  22 AC_PATH_PROGS(SED, gsed sed)
  23
  24 AM_PATH_GLIB_2_0
  25 GLIB_GSETTINGS
  26
  27 # Library dependecies
  28 PKG_CHECK_MODULES(YELP,
  29 [
  30         gio-2.0 >= 2.38.0
  31         gio-unix-2.0
  32         gtk+-unix-print-3.0
  33         gtk+-3.0 >= 3.13.3
  34         libxml-2.0 >= 2.6.5
  35         libxslt >= 1.1.4
  36         libexslt >= 0.8.1
  37         sqlite3
  38         webkitgtk-3.0 >= 1.3.10
  39         yelp-xsl >= 3.12.0
  40 ])
  41 AC_SUBST([YELP_CFLAGS])
  42 AC_SUBST([YELP_LIBS])
  43
  44
  45 # Initialize libtool
  46 LT_PREREQ([2.2.6])
  47 LT_INIT
  48
  49 # i18n stuff
  50 AX_REQUIRE_DEFINED([IT_PROG_INTLTOOL])
  51 IT_PROG_INTLTOOL([0.41.0])
  52
  53 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
  54 AC_SUBST(ALL_LINGUAS)
  55
  56 GETTEXT_PACKAGE=yelp
  57 AC_SUBST(GETTEXT_PACKAGE)
  58 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",
  59                    [The gettext translation domain])
  60
  61 AC_ARG_VAR([ITSTOOL], [Path to the `itstool` command])
  62 AC_CHECK_PROG([ITSTOOL], [itstool], [itstool])
  63 if test x"$ITSTOOL" = x; then
  64   AC_MSG_ERROR([itstool is required to build the translation XML files])
  65 fi
  66 ITSTOOL_VERSION=`itstool --version | cut -d' ' -f2 | awk -F. '{print $ 1 * 10000 + $ 2 * 100 + $ 3; }'`
  67 if test "$ITSTOOL_VERSION" -lt 10200; then
  68   AC_MSG_ERROR([itstool >= 1.2.0 is required to build the translation XML files])
  69 fi
  70
  71 LIBLZMA_REQUIRED=4.9
  72 AC_ARG_ENABLE(lzma,
  73         AS_HELP_STRING([--enable-lzma],[Enable lzma decoder support [[default=yes]]]),
  74         [enable_lzma=$enableval],
  75         [enable_lzma="auto"])
  76 if test x"$enable_lzma" = "xauto"; then
  77         PKG_CHECK_MODULES(YELP_LZMA,
  78                           liblzma >= $LIBLZMA_REQUIRED,
  79                           enable_lzma=yes,
  80                           enable_lzma=no)
  81 elif test x"$enable_lzma" = "xyes"; then
  82         PKG_CHECK_MODULES(YELP_LZMA, liblzma >= $LIBLZMA_REQUIRED)
  83 fi
  84 if test x"$enable_lzma" = "xyes"; then
  85         YELP_CFLAGS="$YELP_LZMA_CFLAGS $YELP_CFLAGS";
  86         YELP_LIBS="$YELP_LZMA_LIBS $YELP_LIBS";
  87         AC_DEFINE(ENABLE_LZMA, 1, [Enable lzma decoder support])
  88 fi
  89 AM_CONDITIONAL([ENABLE_LZMA],[test x"$enable_lzma" != "xno"])
  90
  91 AC_ARG_ENABLE(bz2,
  92         AS_HELP_STRING([--enable-bz2],[Enable bz2 decoder support [[default=yes]]]),
  93         [enable_bz2=$enableval],
  94         [enable_bz2="auto"])
  95 if test x"$enable_bz2" = "xauto"; then
  96         AC_CHECK_LIB(bz2,
  97                      BZ2_bzread,
  98                      enable_bz2=yes,
  99                      enable_bz2=no)
 100 elif test x"$enable_bz2" = "xyes"; then
 101         AC_CHECK_LIB(bz2, BZ2_bzread)
 102 fi
 103 if test x"$enable_bz2" = "xyes"; then
 104         YELP_LIBS="-lbz2 $YELP_LIBS";
 105         AC_DEFINE(ENABLE_BZ2, 1, [Enable bz2 decoder support])
 106 fi
 107 AM_CONDITIONAL([ENABLE_BZ2],[test x"$enable_bz2" != "xno"])
 108
 109 AC_SUBST([YELP_CFLAGS])
 110 AC_SUBST([YELP_LIBS])
 111
 112 DATADIR=`(
 113         case $prefix in
 114                 NONE) prefix=$ac_default_prefix ;;
 115                 *) ;;
 116         esac
 117         eval echo $(eval echo $datadir)/yelp
 118 )`
 119 AC_SUBST([DATADIR])
 120
 121
 122 XSL_PATH="`$PKG_CONFIG --variable=xsltdir yelp-xsl`"
 123
 124 XSL_DB2XHTML="`$PKG_CONFIG --variable=db2xhtml yelp-xsl`"
 125 AC_SUBST(XSL_DB2XHTML)
 126
 127 XSL_MAL2XHTML="`$PKG_CONFIG --variable=mal2xhtml yelp-xsl`"
 128 AC_SUBST(XSL_MAL2XHTML)
 129
 130 XSL_COLOR="`$PKG_CONFIG --variable=xsltdir yelp-xsl`/common/color.xsl"
 131 AC_SUBST(XSL_COLOR)
 132 XSL_ICONS="`$PKG_CONFIG --variable=xsltdir yelp-xsl`/common/icons.xsl"
 133 AC_SUBST(XSL_ICONS)
 134 XSL_HTML="`$PKG_CONFIG --variable=xsltdir yelp-xsl`/common/html.xsl"
 135 AC_SUBST(XSL_HTML)
 136 XSL_JSDIR="`$PKG_CONFIG --variable=jsdir yelp-xsl`"
 137 AC_SUBST(XSL_JSDIR)
 138
 139 XSL_GETTEXT="`$PKG_CONFIG --variable=gettext yelp-xsl`"
 140 AC_SUBST(XSL_GETTEXT)
 141
 142 YELP_ICON_PATH="`$PKG_CONFIG --variable=icondir yelp-xsl`"
 143 AC_SUBST(YELP_ICON_PATH)
 144
 145 GLIB_GENMARSHAL="`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`"
 146 AC_SUBST(GLIB_GENMARSHAL)
 147
 148
 149 AX_REQUIRE_DEFINED([GTK_DOC_CHECK])
 150 GTK_DOC_CHECK([1.13],[--flavour no-tmpl])
 151
 152 AC_CONFIG_FILES([
 153 Makefile
 154 docs/Makefile
 155 docs/libyelp/Makefile
 156 docs/libyelp/version.xml
 157 libyelp/Makefile
 158 src/Makefile
 159 data/Makefile
 160 data/domains/Makefile
 161 data/dtd/Makefile
 162 data/dtd/catalog
 163 data/icons/Makefile
 164 data/icons/hicolor/Makefile
 165 data/icons/hicolor/16x16/Makefile
 166 data/icons/hicolor/16x16/status/Makefile
 167 data/icons/hicolor/scalable/Makefile
 168 data/icons/hicolor/scalable/status/Makefile
 169 data/mathjax/Makefile
 170 data/mathjax/config/Makefile
 171 data/mathjax/extensions/HTML-CSS/Makefile
 172 data/mathjax/extensions/Makefile
 173 data/mathjax/fonts/HTML-CSS/TeX/woff/Makefile
 174 data/mathjax/jax/Makefile
 175 data/mathjax/jax/element/Makefile
 176 data/mathjax/jax/element/mml/Makefile
 177 data/mathjax/jax/element/mml/optable/Makefile
 178 data/mathjax/jax/input/Makefile
 179 data/mathjax/jax/input/MathML/Makefile
 180 data/mathjax/jax/input/MathML/entities/Makefile
 181 data/mathjax/jax/output/HTML-CSS/Makefile
 182 data/mathjax/jax/output/HTML-CSS/autoload/Makefile
 183 data/mathjax/jax/output/HTML-CSS/fonts/Makefile
 184 data/mathjax/jax/output/HTML-CSS/fonts/TeX/AMS/Regular/Makefile
 185 data/mathjax/jax/output/HTML-CSS/fonts/TeX/Caligraphic/Bold/Makefile
 186 data/mathjax/jax/output/HTML-CSS/fonts/TeX/Caligraphic/Regular/Makefile
 187 data/mathjax/jax/output/HTML-CSS/fonts/TeX/Fraktur/Bold/Makefile
 188 data/mathjax/jax/output/HTML-CSS/fonts/TeX/Fraktur/Regular/Makefile
 189 data/mathjax/jax/output/HTML-CSS/fonts/TeX/Greek/Bold/Makefile
 190 data/mathjax/jax/output/HTML-CSS/fonts/TeX/Greek/BoldItalic/Makefile
 191 data/mathjax/jax/output/HTML-CSS/fonts/TeX/Greek/Italic/Makefile
 192 data/mathjax/jax/output/HTML-CSS/fonts/TeX/Greek/Regular/Makefile
 193 data/mathjax/jax/output/HTML-CSS/fonts/TeX/Main/Bold/Makefile
 194 data/mathjax/jax/output/HTML-CSS/fonts/TeX/Main/Italic/Makefile
 195 data/mathjax/jax/output/HTML-CSS/fonts/TeX/Main/Regular/Makefile
 196 data/mathjax/jax/output/HTML-CSS/fonts/TeX/Makefile
 197 data/mathjax/jax/output/HTML-CSS/fonts/TeX/Math/BoldItalic/Makefile
 198 data/mathjax/jax/output/HTML-CSS/fonts/TeX/Math/Italic/Makefile
 199 data/mathjax/jax/output/HTML-CSS/fonts/TeX/SansSerif/Bold/Makefile
 200 data/mathjax/jax/output/HTML-CSS/fonts/TeX/SansSerif/Italic/Makefile
 201 data/mathjax/jax/output/HTML-CSS/fonts/TeX/SansSerif/Regular/Makefile
 202 data/mathjax/jax/output/HTML-CSS/fonts/TeX/Script/Regular/Makefile
 203 data/mathjax/jax/output/HTML-CSS/fonts/TeX/Size1/Regular/Makefile
 204 data/mathjax/jax/output/HTML-CSS/fonts/TeX/Size2/Regular/Makefile
 205 data/mathjax/jax/output/HTML-CSS/fonts/TeX/Size3/Regular/Makefile
 206 data/mathjax/jax/output/HTML-CSS/fonts/TeX/Size4/Regular/Makefile
 207 data/mathjax/jax/output/HTML-CSS/fonts/TeX/Typewriter/Regular/Makefile
 208 data/mathjax/jax/output/Makefile
 209 data/mathjax/jax/output/NativeMML/Makefile
 210 data/mathjax/unpacked/Makefile
 211 data/xslt/Makefile
 212 data/xslt/db2html.xsl
 213 data/xslt/info2html.xsl
 214 data/xslt/mal2html.xsl
 215 data/xslt/man2html.xsl
 216 data/xslt/yelp-common.xsl
 217 po/Makefile.in
 218 tests/Makefile
 219 yelp.desktop.in
 220 ])
 221
 222 AC_OUTPUT
 223
 224 dnl ==========================================================================
 225 echo "
 226 yelp-$VERSION:
 227
 228         prefix:                   ${prefix}
 229         source code location:     ${srcdir}
 230         compiler:                 ${CC}
 231
 232         Documentation:            ${enable_gtk_doc}
 233         Debug enabled:            ${enable_debug}
 234         Enable BZ2:               ${enable_bz2}
 235         Enable LZMA:              ${enable_lzma}
 236
 237 "