configure.ac

   1 AC_PREREQ([2.63])
   2 AC_INIT([Yelp],[3.21.3],[http://bugzilla.gnome.org/enter_bug.cgi?product=yelp],[yelp])
   3
   4 AC_CONFIG_AUX_DIR([build-aux])
   5 AC_CONFIG_SRCDIR([src/yelp.c])
   6 AC_CONFIG_HEADERS([config.h])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AM_INIT_AUTOMAKE([1.11.2 dist-xz no-dist-gzip subdir-objects tar-ustar])
  10 AM_MAINTAINER_MODE([enable])
  11
  12 AM_SILENT_RULES([yes])
  13
  14 AX_IS_RELEASE([git-directory])
  15 AX_CHECK_ENABLE_DEBUG([info], [YELP_DEBUG], [$ax_is_release])
  16
  17 AX_COMPILER_FLAGS([], [], [$ax_is_release])
  18 # Check for programs
  19 AC_PROG_CC
  20 AC_PROG_CC_C_O
  21 AC_PROG_LN_S
  22 GLIB_GSETTINGS
  23
  24 # Library dependecies
  25 LT_LIB_M
  26 PKG_CHECK_MODULES(YELP,
  27 [
  28         gio-2.0 >= 2.38.0
  29         gio-unix-2.0
  30         gtk+-unix-print-3.0
  31         gtk+-3.0 >= 3.13.3
  32         libxml-2.0 >= 2.6.5
  33         libxslt >= 1.1.4
  34         libexslt >= 0.8.1
  35         sqlite3
  36         webkit2gtk-4.0 >= 2.7.1
  37         yelp-xsl >= 3.12.0
  38 ])
  39 AC_SUBST([YELP_CFLAGS])
  40 AC_SUBST([YELP_LIBS])
  41
  42
  43 # Initialize libtool
  44 LT_PREREQ([2.2.6])
  45 LT_INIT
  46
  47 PKG_CHECK_MODULES([YELP_EXTENSION], [webkit2gtk-web-extension-4.0 >= 2.7.2])
  48 AC_SUBST(YELP_EXTENSION_CFLAGS)
  49 AC_SUBST(YELP_EXTENSION_LIBS)
  50
  51 # i18n stuff
  52 AX_REQUIRE_DEFINED([IT_PROG_INTLTOOL])
  53 IT_PROG_INTLTOOL([0.41.0])
  54
  55 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
  56 AC_SUBST(ALL_LINGUAS)
  57
  58 GETTEXT_PACKAGE=yelp
  59 AC_SUBST(GETTEXT_PACKAGE)
  60 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",
  61                    [The gettext translation domain])
  62
  63 AC_ARG_VAR([ITSTOOL], [Path to the `itstool` command])
  64 AC_CHECK_PROG([ITSTOOL], [itstool], [itstool])
  65 if test x"$ITSTOOL" = x; then
  66   AC_MSG_ERROR([itstool is required to build the translation XML files])
  67 fi
  68 ITSTOOL_VERSION=`itstool --version | cut -d' ' -f2 | awk -F. '{print $ 1 * 10000 + $ 2 * 100 + $ 3; }'`
  69 if test "$ITSTOOL_VERSION" -lt 10200; then
  70   AC_MSG_ERROR([itstool >= 1.2.0 is required to build the translation XML files])
  71 fi
  72
  73 LIBLZMA_REQUIRED=4.9
  74 AC_ARG_ENABLE(lzma,
  75         AS_HELP_STRING([--enable-lzma],[Enable lzma decoder support [[default=yes]]]),
  76         [enable_lzma=$enableval],
  77         [enable_lzma="auto"])
  78 if test x"$enable_lzma" = "xauto"; then
  79         PKG_CHECK_MODULES(YELP_LZMA,
  80                           liblzma >= $LIBLZMA_REQUIRED,
  81                           enable_lzma=yes,
  82                           enable_lzma=no)
  83 elif test x"$enable_lzma" = "xyes"; then
  84         PKG_CHECK_MODULES(YELP_LZMA, liblzma >= $LIBLZMA_REQUIRED)
  85 fi
  86 if test x"$enable_lzma" = "xyes"; then
  87         YELP_CFLAGS="$YELP_LZMA_CFLAGS $YELP_CFLAGS";
  88         YELP_LIBS="$YELP_LZMA_LIBS $YELP_LIBS";
  89         AC_DEFINE(ENABLE_LZMA, 1, [Enable lzma decoder support])
  90 fi
  91 AM_CONDITIONAL([ENABLE_LZMA],[test x"$enable_lzma" != "xno"])
  92
  93 AC_ARG_ENABLE(bz2,
  94         AS_HELP_STRING([--enable-bz2],[Enable bz2 decoder support [[default=yes]]]),
  95         [enable_bz2=$enableval],
  96         [enable_bz2="auto"])
  97 if test x"$enable_bz2" = "xauto"; then
  98         AC_CHECK_LIB(bz2,
  99                      BZ2_bzread,
 100                      enable_bz2=yes,
 101                      enable_bz2=no)
 102 elif test x"$enable_bz2" = "xyes"; then
 103         AC_CHECK_LIB(bz2, BZ2_bzread)
 104 fi
 105 if test x"$enable_bz2" = "xyes"; then
 106         YELP_LIBS="-lbz2 $YELP_LIBS";
 107         AC_DEFINE(ENABLE_BZ2, 1, [Enable bz2 decoder support])
 108 fi
 109 AM_CONDITIONAL([ENABLE_BZ2],[test x"$enable_bz2" != "xno"])
 110
 111 AC_SUBST([YELP_CFLAGS])
 112 AC_SUBST([YELP_LIBS])
 113
 114 DATADIR=`(
 115         case $prefix in
 116                 NONE) prefix=$ac_default_prefix ;;
 117                 *) ;;
 118         esac
 119         eval echo $(eval echo $datadir)/yelp
 120 )`
 121 AC_SUBST([DATADIR])
 122
 123
 124 XSL_PATH="`$PKG_CONFIG --variable=xsltdir yelp-xsl`"
 125
 126 XSL_DB2XHTML="`$PKG_CONFIG --variable=db2xhtml yelp-xsl`"
 127 AC_SUBST(XSL_DB2XHTML)
 128
 129 XSL_MAL2XHTML="`$PKG_CONFIG --variable=mal2xhtml yelp-xsl`"
 130 AC_SUBST(XSL_MAL2XHTML)
 131
 132 XSL_COLOR="`$PKG_CONFIG --variable=xsltdir yelp-xsl`/common/color.xsl"
 133 AC_SUBST(XSL_COLOR)
 134 XSL_ICONS="`$PKG_CONFIG --variable=xsltdir yelp-xsl`/common/icons.xsl"
 135 AC_SUBST(XSL_ICONS)
 136 XSL_HTML="`$PKG_CONFIG --variable=xsltdir yelp-xsl`/common/html.xsl"
 137 AC_SUBST(XSL_HTML)
 138 XSL_JSDIR="`$PKG_CONFIG --variable=jsdir yelp-xsl`"
 139 AC_SUBST(XSL_JSDIR)
 140
 141 XSL_GETTEXT="`$PKG_CONFIG --variable=gettext yelp-xsl`"
 142 AC_SUBST(XSL_GETTEXT)
 143
 144 YELP_ICON_PATH="`$PKG_CONFIG --variable=icondir yelp-xsl`"
 145 AC_SUBST(YELP_ICON_PATH)
 146
 147 GLIB_GENMARSHAL="`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`"
 148 AC_SUBST(GLIB_GENMARSHAL)
 149
 150
 151 AX_REQUIRE_DEFINED([GTK_DOC_CHECK])
 152 GTK_DOC_CHECK([1.13],[--flavour no-tmpl])
 153
 154 AC_CONFIG_FILES([
 155 Makefile
 156 docs/libyelp/Makefile
 157 docs/libyelp/version.xml
 158 data/dtd/catalog
 159 data/xslt/db2html.xsl
 160 data/xslt/info2html.xsl
 161 data/xslt/mal2html.xsl
 162 data/xslt/man2html.xsl
 163 data/xslt/yelp-common.xsl
 164 po/Makefile.in
 165 yelp.desktop.in
 166 ])
 167
 168 AC_OUTPUT
 169
 170 dnl ==========================================================================
 171 echo "
 172 yelp-$VERSION:
 173
 174         prefix:                   ${prefix}
 175         source code location:     ${srcdir}
 176         compiler:                 ${CC}
 177
 178         Documentation:            ${enable_gtk_doc}
 179         Debug enabled:            ${enable_debug}
 180         Enable BZ2:               ${enable_bz2}
 181         Enable LZMA:              ${enable_lzma}
 182
 183 "