configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 ###############################################################################
   5 #
   6 # Author: Lasse Collin
   7 #
   8 # This file has been put into the public domain.
   9 # You can do whatever you want with this file.
  10 #
  11 ###############################################################################
  12
  13 # NOTE: Don't add useless checks. autoscan detects this and that, but don't
  14 # let it confuse you. For example, we don't care about checking for behavior
  15 # of malloc(), stat(), or lstat(), since we don't use those functions in
  16 # a way that would cause the problems the autoconf macros check.
  17
  18 AC_PREREQ([2.64])
  19
  20 AC_INIT([XZ Utils], m4_esyscmd([/bin/sh build-aux/version.sh]),
  21         [lasse.collin@tukaani.org], [xz], [http://tukaani.org/xz/])
  22 AC_CONFIG_SRCDIR([src/liblzma/common/common.h])
  23 AC_CONFIG_AUX_DIR([build-aux])
  24 AC_CONFIG_MACRO_DIR([m4])
  25 AC_CONFIG_HEADER([config.h])
  26
  27 echo
  28 echo "$PACKAGE_STRING"
  29
  30 echo
  31 echo "System type:"
  32 # This is needed to know if assembler optimizations can be used.
  33 AC_CANONICAL_HOST
  34
  35 # We do some special things on Windows (32-bit or 64-bit) builds.
  36 case $host_os in
  37         mingw* | cygwin*) is_w32=yes ;;
  38         *)                is_w32=no ;;
  39 esac
  40 AM_CONDITIONAL([COND_W32], [test "$is_w32" = yes])
  41
  42 # We need to use $EXEEXT with $(LN_S) when creating symlinks to
  43 # executables. Cygwin is an exception to this, since it is recommended
  44 # that symlinks don't have the .exe suffix. To make this work, we
  45 # define LN_EXEEXT.
  46 case $host_os in
  47         cygwin)  LN_EXEEXT= ;;
  48         *)       LN_EXEEXT='$(EXEEXT)' ;;
  49 esac
  50 AC_SUBST([LN_EXEEXT])
  51
  52 echo
  53 echo "Configure options:"
  54 AM_CFLAGS=
  55
  56
  57 #############
  58 # Debugging #
  59 #############
  60
  61 AC_MSG_CHECKING([if debugging code should be compiled])
  62 AC_ARG_ENABLE([debug], AC_HELP_STRING([--enable-debug], [Enable debugging code.]),
  63         [], enable_debug=no)
  64 if test "x$enable_debug" = xyes; then
  65         AC_MSG_RESULT([yes])
  66 else
  67         AC_DEFINE([NDEBUG], [1], [Define to 1 to disable debugging code.])
  68         AC_MSG_RESULT([no])
  69 fi
  70
  71
  72 ###########
  73 # Filters #
  74 ###########
  75
  76 m4_define([SUPPORTED_FILTERS], [lzma1,lzma2,delta,x86,powerpc,ia64,arm,armthumb,sparc])dnl
  77 m4_define([SIMPLE_FILTERS], [x86,powerpc,ia64,arm,armthumb,sparc])
  78 m4_define([LZ_FILTERS], [lzma1,lzma2])
  79
  80 m4_foreach([NAME], [SUPPORTED_FILTERS],
  81 [enable_filter_[]NAME=no
  82 enable_encoder_[]NAME=no
  83 enable_decoder_[]NAME=no
  84 ])dnl
  85
  86 AC_MSG_CHECKING([which encoders to build])
  87 AC_ARG_ENABLE([encoders], AC_HELP_STRING([--enable-encoders=LIST],
  88                 [Comma-separated list of encoders to build. Default=all.
  89                 Available encoders:]
  90                         m4_translit(m4_defn([SUPPORTED_FILTERS]), [,], [ ])),
  91         [], [enable_encoders=SUPPORTED_FILTERS])
  92 enable_encoders=`echo "$enable_encoders" | sed 's/,/ /g'`
  93 if test "x$enable_encoders" = xno || test "x$enable_encoders" = x; then
  94         AC_MSG_RESULT([(none)])
  95 else
  96         for arg in $enable_encoders
  97         do
  98                 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
  99                         NAME)
 100                                 enable_filter_[]NAME=yes
 101                                 enable_encoder_[]NAME=yes
 102                                 AC_DEFINE(HAVE_ENCODER_[]m4_toupper(NAME), [1],
 103                                 [Define to 1 if] NAME [encoder is enabled.])
 104                                 ;;])
 105                         *)
 106                                 AC_MSG_RESULT([])
 107                                 AC_MSG_ERROR([unknown filter: $arg])
 108                                 ;;
 109                 esac
 110         done
 111         AC_MSG_RESULT([$enable_encoders])
 112 fi
 113
 114 AC_MSG_CHECKING([which decoders to build])
 115 AC_ARG_ENABLE([decoders], AC_HELP_STRING([--enable-decoders=LIST],
 116                 [Comma-separated list of decoders to build. Default=all.
 117                 Available decoders are the same as available encoders.]),
 118         [], [enable_decoders=SUPPORTED_FILTERS])
 119 enable_decoders=`echo "$enable_decoders" | sed 's/,/ /g'`
 120 if test "x$enable_decoders" = xno || test "x$enable_decoders" = x; then
 121         AC_MSG_RESULT([(none)])
 122 else
 123         for arg in $enable_decoders
 124         do
 125                 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
 126                         NAME)
 127                                 enable_filter_[]NAME=yes
 128                                 enable_decoder_[]NAME=yes
 129                                 AC_DEFINE(HAVE_DECODER_[]m4_toupper(NAME), [1],
 130                                 [Define to 1 if] NAME [decoder is enabled.])
 131                                 ;;])
 132                         *)
 133                                 AC_MSG_RESULT([])
 134                                 AC_MSG_ERROR([unknown filter: $arg])
 135                                 ;;
 136                 esac
 137         done
 138
 139         # LZMA2 requires that LZMA1 is enabled.
 140         test "x$enable_encoder_lzma2" = xyes && enable_encoder_lzma1=yes
 141         test "x$enable_decoder_lzma2" = xyes && enable_decoder_lzma1=yes
 142
 143         AC_MSG_RESULT([$enable_decoders])
 144 fi
 145
 146 if test "x$enable_encoder_lzma2$enable_encoder_lzma1" = xyesno \
 147                 || test "x$enable_decoder_lzma2$enable_decoder_lzma1" = xyesno; then
 148         AC_MSG_ERROR([LZMA2 requires that LZMA1 is also enabled.])
 149 fi
 150
 151 AM_CONDITIONAL(COND_MAIN_ENCODER, test "x$enable_encoders" != xno && test "x$enable_encoders" != x)
 152 AM_CONDITIONAL(COND_MAIN_DECODER, test "x$enable_decoders" != xno && test "x$enable_decoders" != x)
 153
 154 m4_foreach([NAME], [SUPPORTED_FILTERS],
 155 [AM_CONDITIONAL(COND_FILTER_[]m4_toupper(NAME), test "x$enable_filter_[]NAME" = xyes)
 156 AM_CONDITIONAL(COND_ENCODER_[]m4_toupper(NAME), test "x$enable_encoder_[]NAME" = xyes)
 157 AM_CONDITIONAL(COND_DECODER_[]m4_toupper(NAME), test "x$enable_decoder_[]NAME" = xyes)
 158 ])dnl
 159
 160 # The so called "simple filters" share common code.
 161 enable_filter_simple=no
 162 enable_encoder_simple=no
 163 enable_decoder_simple=no
 164 m4_foreach([NAME], [SIMPLE_FILTERS],
 165 [test "x$enable_filter_[]NAME" = xyes && enable_filter_simple=yes
 166 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_simple=yes
 167 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_simple=yes
 168 ])dnl
 169 AM_CONDITIONAL(COND_FILTER_SIMPLE, test "x$enable_filter_simple" = xyes)
 170 AM_CONDITIONAL(COND_ENCODER_SIMPLE, test "x$enable_encoder_simple" = xyes)
 171 AM_CONDITIONAL(COND_DECODER_SIMPLE, test "x$enable_decoder_simple" = xyes)
 172
 173 # LZ-based filters share common code.
 174 enable_filter_lz=no
 175 enable_encoder_lz=no
 176 enable_decoder_lz=no
 177 m4_foreach([NAME], [LZ_FILTERS],
 178 [test "x$enable_filter_[]NAME" = xyes && enable_filter_lz=yes
 179 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_lz=yes
 180 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_lz=yes
 181 ])dnl
 182 AM_CONDITIONAL(COND_FILTER_LZ, test "x$enable_filter_lz" = xyes)
 183 AM_CONDITIONAL(COND_ENCODER_LZ, test "x$enable_encoder_lz" = xyes)
 184 AM_CONDITIONAL(COND_DECODER_LZ, test "x$enable_decoder_lz" = xyes)
 185
 186
 187 #################
 188 # Match finders #
 189 #################
 190
 191 m4_define([SUPPORTED_MATCH_FINDERS], [hc3,hc4,bt2,bt3,bt4])
 192
 193 m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS],
 194 [enable_match_finder_[]NAME=no
 195 ])
 196
 197 AC_MSG_CHECKING([which match finders to build])
 198 AC_ARG_ENABLE([match-finders], AC_HELP_STRING([--enable-match-finders=LIST],
 199                 [Comma-separated list of match finders to build. Default=all.
 200                 At least one match finder is required for encoding with
 201                 the LZMA1 and LZMA2 filters. Available match finders:]
 202                 m4_translit(m4_defn([SUPPORTED_MATCH_FINDERS]), [,], [ ])), [],
 203         [enable_match_finders=SUPPORTED_MATCH_FINDERS])
 204 enable_match_finders=`echo "$enable_match_finders" | sed 's/,/ /g'`
 205 if test "x$enable_encoder_lz" = xyes ; then
 206         for arg in $enable_match_finders
 207                 do
 208                 case $arg in m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS], [
 209                         NAME)
 210                                 enable_match_finder_[]NAME=yes
 211                                 AC_DEFINE(HAVE_MF_[]m4_toupper(NAME), [1],
 212                                 [Define to 1 to enable] NAME [match finder.])
 213                                 ;;])
 214                         *)
 215                                 AC_MSG_RESULT([])
 216                                 AC_MSG_ERROR([unknown match finder: $arg])
 217                                 ;;
 218                 esac
 219         done
 220         AC_MSG_RESULT([$enable_match_finders])
 221 else
 222         AC_MSG_RESULT([(none because not building any LZ-based encoder)])
 223 fi
 224
 225
 226 ####################
 227 # Integrity checks #
 228 ####################
 229
 230 m4_define([SUPPORTED_CHECKS], [crc32,crc64,sha256])
 231
 232 m4_foreach([NAME], [SUPPORTED_CHECKS],
 233 [enable_check_[]NAME=no
 234 ])dnl
 235
 236 AC_MSG_CHECKING([which integrity checks to build])
 237 AC_ARG_ENABLE([checks], AC_HELP_STRING([--enable-checks=LIST],
 238                 [Comma-separated list of integrity checks to build.
 239                 Default=all. Available integrity checks:]
 240                 m4_translit(m4_defn([SUPPORTED_CHECKS]), [,], [ ])),
 241         [], [enable_checks=SUPPORTED_CHECKS])
 242 enable_checks=`echo "$enable_checks" | sed 's/,/ /g'`
 243 if test "x$enable_checks" = xno || test "x$enable_checks" = x; then
 244         AC_MSG_RESULT([(none)])
 245 else
 246         for arg in $enable_checks
 247         do
 248                 case $arg in m4_foreach([NAME], [SUPPORTED_CHECKS], [
 249                         NAME)
 250                                 enable_check_[]NAME=yes
 251                                 AC_DEFINE(HAVE_CHECK_[]m4_toupper(NAME), [1],
 252                                 [Define to 1 if] NAME
 253                                 [integrity check is enabled.])
 254                                 ;;])
 255                         *)
 256                                 AC_MSG_RESULT([])
 257                                 AC_MSG_ERROR([unknown integrity check: $arg])
 258                                 ;;
 259                 esac
 260         done
 261         AC_MSG_RESULT([$enable_checks])
 262 fi
 263 if test "x$enable_check_crc32" = xno ; then
 264         AC_MSG_ERROR([For now, the CRC32 check must always be enabled.])
 265 fi
 266
 267 m4_foreach([NAME], [SUPPORTED_CHECKS],
 268 [AM_CONDITIONAL(COND_CHECK_[]m4_toupper(NAME), test "x$enable_check_[]NAME" = xyes)
 269 ])dnl
 270
 271
 272 ###########################
 273 # Assembler optimizations #
 274 ###########################
 275
 276 AC_MSG_CHECKING([if assembler optimizations should be used])
 277 AC_ARG_ENABLE([assembler], AC_HELP_STRING([--disable-assembler],
 278                 [Do not use assembler optimizations even if such exist
 279                 for the architecture.]),
 280         [], [enable_assembler=yes])
 281 if test "x$enable_assembler" = xyes; then
 282         enable_assembler=no
 283         case $host_os in
 284                 # Darwin should work too but only if not creating universal
 285                 # binaries. Solaris x86 could work too but I cannot test.
 286                 linux* | *bsd* | mingw* | cygwin* | *djgpp*)
 287                         case $host_cpu in
 288                                 i?86)   enable_assembler=x86 ;;
 289                                 x86_64) enable_assembler=x86_64 ;;
 290                         esac
 291                         ;;
 292         esac
 293 fi
 294 case $enable_assembler in
 295         x86 | x86_64 | no)
 296                 AC_MSG_RESULT([$enable_assembler])
 297                 ;;
 298         *)
 299                 AC_MSG_RESULT([])
 300                 AC_MSG_ERROR([--enable-assembler accepts only \`yes', \`no', \`x86', or \`x86_64'.])
 301                 ;;
 302 esac
 303 AM_CONDITIONAL(COND_ASM_X86, test "x$enable_assembler" = xx86)
 304 AM_CONDITIONAL(COND_ASM_X86_64, test "x$enable_assembler" = xx86_64)
 305
 306
 307 #####################
 308 # Size optimization #
 309 #####################
 310
 311 AC_MSG_CHECKING([if small size is preferred over speed])
 312 AC_ARG_ENABLE([small], AC_HELP_STRING([--enable-small],
 313                 [Make liblzma smaller and a little slower.
 314                 This is disabled by default to optimize for speed.]),
 315         [], [enable_small=no])
 316 if test "x$enable_small" = xyes; then
 317         AC_DEFINE([HAVE_SMALL], [1], [Define to 1 if optimizing for size.])
 318 elif test "x$enable_small" != xno; then
 319         AC_MSG_RESULT([])
 320         AC_MSG_ERROR([--enable-small accepts only \`yes' or \`no'])
 321 fi
 322 AC_MSG_RESULT([$enable_small])
 323 AM_CONDITIONAL(COND_SMALL, test "x$enable_small" = xyes)
 324
 325
 326 #############
 327 # Threading #
 328 #############
 329
 330 AC_MSG_CHECKING([if threading support is wanted])
 331 AC_ARG_ENABLE([threads], AC_HELP_STRING([--disable-threads],
 332                 [Disable threading support.
 333                 This makes some things thread-unsafe.]),
 334         [], [enable_threads=yes])
 335 if test "x$enable_threads" != xyes && test "x$enable_threads" != xno; then
 336         AC_MSG_RESULT([])
 337         AC_MSG_ERROR([--enable-threads accepts only \`yes' or \`no'])
 338 fi
 339 AC_MSG_RESULT([$enable_threads])
 340 # We use the actual result a little later.
 341
 342
 343 #########################
 344 # Assumed amount of RAM #
 345 #########################
 346
 347 # We use 128 MiB as default, because it will allow decompressing files
 348 # created with "xz -9". It would be slightly safer to guess a lower value,
 349 # but most systems, on which we don't have any way to determine the amount
 350 # of RAM, will probably have at least 128 MiB of RAM.
 351 AC_MSG_CHECKING([how much RAM to assume if the real amount is unknown])
 352 AC_ARG_ENABLE([assume-ram], AC_HELP_STRING([--enable-assume-ram=SIZE],
 353                 [If and only if the real amount of RAM cannot be determined,
 354                 assume SIZE MiB. The default is 128 MiB. This affects the
 355                 default memory usage limit.]),
 356         [], [enable_assume_ram=128])
 357 assume_ram_check=`echo "$enable_assume_ram" | tr -d 0123456789`
 358 if test -z "$enable_assume_ram" || test -n "$assume_ram_check"; then
 359         AC_MSG_RESULT([])
 360         AC_MSG_ERROR([--enable-assume-ram accepts only an integer argument])
 361 fi
 362 AC_MSG_RESULT([$enable_assume_ram MiB])
 363 AC_DEFINE_UNQUOTED([ASSUME_RAM], [$enable_assume_ram],
 364                 [How many MiB of RAM to assume if the real amount cannot
 365                 be determined.])
 366
 367
 368 #########################
 369 # Components to install #
 370 #########################
 371
 372 AC_ARG_ENABLE([xz], [AC_HELP_STRING([--disable-xz],
 373                 [do not build the xz tool])],
 374         [], [enable_xz=yes])
 375 AM_CONDITIONAL([COND_XZ], [test x$enable_xz != xno])
 376
 377 AC_ARG_ENABLE([xzdec], [AC_HELP_STRING([--disable-xzdec],
 378                 [do not build xzdec])],
 379         [], [enable_xzdec=yes])
 380 AM_CONDITIONAL([COND_XZDEC], [test x$enable_xzdec != xno])
 381
 382 AC_ARG_ENABLE([lzmadec], [AC_HELP_STRING([--disable-lzmadec],
 383                 [do not build lzmadec
 384                 (it exists primarily for LZMA Utils compatibility)])],
 385         [], [enable_lzmadec=yes])
 386 AM_CONDITIONAL([COND_LZMADEC], [test x$enable_lzmadec != xno])
 387
 388 AC_ARG_ENABLE([lzmainfo], [AC_HELP_STRING([--disable-lzmainfo],
 389                 [do not build lzmainfo
 390                 (it exists primarily for LZMA Utils compatibility)])],
 391         [], [enable_lzmainfo=yes])
 392 AM_CONDITIONAL([COND_LZMAINFO], [test x$enable_lzmainfo != xno])
 393
 394 AC_ARG_ENABLE([lzma-links], [AC_HELP_STRING([--disable-lzma-links],
 395                 [do not create symlinks for LZMA Utils compatibility])],
 396         [], [enable_lzma_links=yes])
 397 AM_CONDITIONAL([COND_LZMALINKS], [test x$enable_lzma_links != xno])
 398
 399 AC_ARG_ENABLE([scripts], [AC_HELP_STRING([--disable-scripts],
 400                 [do not install the scripts xzdiff, xzgrep, xzless, xzmore,
 401                 and their symlinks])],
 402         [], [enable_scripts=yes])
 403 AM_CONDITIONAL([COND_SCRIPTS], [test x$enable_scripts != xno])
 404
 405 AC_ARG_ENABLE([doc], [AC_HELP_STRING([--disable-doc],
 406                 [do not install documentation files to docdir
 407                 (man pages will still be installed)])],
 408         [], [enable_doc=yes])
 409 AM_CONDITIONAL([COND_DOC], [test x$enable_doc != xno])
 410
 411
 412 ###############################################################################
 413 # Checks for programs.
 414 ###############################################################################
 415
 416 echo
 417 gl_POSIX_SHELL
 418 if test -z "$POSIX_SHELL" ; then
 419         AC_MSG_ERROR([No POSIX conforming shell (sh) was found.])
 420 fi
 421
 422 echo
 423 echo "Initializing Automake:"
 424
 425 AM_INIT_AUTOMAKE([1.12 foreign tar-v7 filename-length-max=99 serial-tests])
 426 AC_PROG_LN_S
 427
 428 AC_PROG_CC_C99
 429 if test x$ac_cv_prog_cc_c99 = xno ; then
 430         AC_MSG_ERROR([No C99 compiler was found.])
 431 fi
 432
 433 AM_PROG_CC_C_O
 434 AM_PROG_AS
 435 AC_USE_SYSTEM_EXTENSIONS
 436
 437 if test "x$enable_threads" = xyes; then
 438         echo
 439         echo "Threading support:"
 440         AX_PTHREAD
 441         LIBS="$LIBS $PTHREAD_LIBS"
 442         AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"
 443
 444         dnl NOTE: PTHREAD_CC is ignored. It would be useful on AIX, but
 445         dnl it's tricky to get it right together with AC_PROG_CC_C99.
 446         dnl Thus, this is handled by telling the user in INSTALL to set
 447         dnl the correct CC manually.
 448 fi
 449
 450 echo
 451 echo "Initializing Libtool:"
 452 LT_PREREQ([2.2])
 453 LT_INIT([win32-dll])
 454 LT_LANG([Windows Resource])
 455
 456 # This is a bit wrong since it is possible to request that only some libs
 457 # are built as shared. Using that feature isn't so common though, and this
 458 # breaks only on Windows (at least for now) if the user enables only some
 459 # libs as shared.
 460 AM_CONDITIONAL([COND_SHARED], [test "x$enable_shared" != xno])
 461
 462
 463 ###############################################################################
 464 # Checks for libraries.
 465 ###############################################################################
 466
 467 echo
 468 echo "Initializing gettext:"
 469 AM_GNU_GETTEXT_VERSION([0.18])
 470 AM_GNU_GETTEXT([external])
 471
 472 ###############################################################################
 473 # Checks for header files.
 474 ###############################################################################
 475
 476 echo
 477 echo "System headers and functions:"
 478
 479 # There is currently no workarounds in this package if some of
 480 # these headers are missing.
 481 AC_CHECK_HEADERS([fcntl.h limits.h sys/time.h],
 482         [],
 483         [AC_MSG_ERROR([Required header file(s) are missing.])])
 484
 485
 486 ###############################################################################
 487 # Checks for typedefs, structures, and compiler characteristics.
 488 ###############################################################################
 489
 490 dnl We don't need these as long as we need a C99 compiler anyway.
 491 dnl AC_C_INLINE
 492 dnl AC_C_RESTRICT
 493
 494 AC_HEADER_STDBOOL
 495
 496 AC_TYPE_UINT8_T
 497 AC_TYPE_UINT16_T
 498 AC_TYPE_INT32_T
 499 AC_TYPE_UINT32_T
 500 AC_TYPE_INT64_T
 501 AC_TYPE_UINT64_T
 502 AC_TYPE_UINTPTR_T
 503
 504 AC_CHECK_SIZEOF([size_t])
 505
 506 # The command line tool can copy high resolution timestamps if such
 507 # information is available in struct stat. Otherwise one second accuracy
 508 # is used.
 509 AC_CHECK_MEMBERS([
 510         struct stat.st_atim.tv_nsec,
 511         struct stat.st_atimespec.tv_nsec,
 512         struct stat.st_atimensec,
 513         struct stat.st_uatime,
 514         struct stat.st_atim.st__tim.tv_nsec])
 515
 516 AC_SYS_LARGEFILE
 517 AC_C_BIGENDIAN
 518
 519
 520 ###############################################################################
 521 # Checks for library functions.
 522 ###############################################################################
 523
 524 # Gnulib replacements as needed
 525 gl_GETOPT
 526
 527 # Find the best function to set timestamps.
 528 AC_CHECK_FUNCS([futimens futimes futimesat utimes utime], [break])
 529
 530 TUKLIB_PROGNAME
 531 TUKLIB_INTEGER
 532 TUKLIB_PHYSMEM
 533 TUKLIB_CPUCORES
 534 TUKLIB_MBSTR
 535
 536
 537 ###############################################################################
 538 # If using GCC, set some additional AM_CFLAGS:
 539 ###############################################################################
 540
 541 if test "$GCC" = yes ; then
 542         echo
 543         echo "GCC extensions:"
 544 fi
 545
 546 # Always do the visibility check but don't set AM_CFLAGS on Windows.
 547 # This way things get set properly even on Windows.
 548 gl_VISIBILITY
 549 if test -n "$CFLAG_VISIBILITY" && test "$is_w32" = no; then
 550         AM_CFLAGS="$AM_CFLAGS $CFLAG_VISIBILITY"
 551 fi
 552
 553 if test "$GCC" = yes ; then
 554         # Enable as much warnings as possible. These commented warnings won't
 555         # work for this package though:
 556         #   * -Wunreachable-code breaks several assert(0) cases, which are
 557         #     backed up with "return LZMA_PROG_ERROR".
 558         #   * -Wcast-qual would break various things where we need a non-const
 559         #     pointer although we don't modify anything through it.
 560         #   * -Wcast-align breaks optimized CRC32 and CRC64 implementation
 561         #     on some architectures (not on x86), where this warning is bogus,
 562         #     because we take care of correct alignment.
 563         #   * -Winline, -Wdisabled-optimization, -Wunsafe-loop-optimizations
 564         #     don't seem so useful here; at least the last one gives some
 565         #     warnings which are not bugs.
 566         for NEW_FLAG in \
 567                         -Wall \
 568                         -Wextra \
 569                         -Wvla \
 570                         -Wformat=2 \
 571                         -Winit-self \
 572                         -Wmissing-include-dirs \
 573                         -Wstrict-aliasing \
 574                         -Wfloat-equal \
 575                         -Wundef \
 576                         -Wshadow \
 577                         -Wpointer-arith \
 578                         -Wbad-function-cast \
 579                         -Wwrite-strings \
 580                         -Wlogical-op \
 581                         -Waggregate-return \
 582                         -Wstrict-prototypes \
 583                         -Wold-style-definition \
 584                         -Wmissing-prototypes \
 585                         -Wmissing-declarations \
 586                         -Wmissing-noreturn \
 587                         -Wredundant-decls
 588         do
 589                 AC_MSG_CHECKING([if $CC accepts $NEW_FLAG])
 590                 OLD_CFLAGS="$CFLAGS"
 591                 CFLAGS="$CFLAGS $NEW_FLAG"
 592                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([void foo(void) { }])], [
 593                         AM_CFLAGS="$AM_CFLAGS $NEW_FLAG"
 594                         AC_MSG_RESULT([yes])
 595                 ], [
 596                         AC_MSG_RESULT([no])
 597                 ])
 598                 CFLAGS="$OLD_CFLAGS"
 599         done
 600
 601         AC_ARG_ENABLE([werror],
 602                 AC_HELP_STRING([--enable-werror], [Enable -Werror to abort
 603                         compilation on all compiler warnings.]),
 604                 [], [enable_werror=no])
 605         if test "x$enable_werror" = "xyes"; then
 606                 AM_CFLAGS="$AM_CFLAGS -Werror"
 607         fi
 608 fi
 609
 610
 611 ###############################################################################
 612 # Create the makefiles and config.h
 613 ###############################################################################
 614
 615 echo
 616
 617 # Don't build the lib directory at all if we don't need any replacement
 618 # functions.
 619 AM_CONDITIONAL([COND_GNULIB], test -n "$LIBOBJS")
 620
 621 # Add default AM_CFLAGS.
 622 AC_SUBST([AM_CFLAGS])
 623
 624 # This is needed for src/scripts.
 625 xz=`echo xz | sed "$program_transform_name"`
 626 AC_SUBST([xz])
 627
 628 AC_CONFIG_FILES([
 629         Doxyfile
 630         Makefile
 631         po/Makefile.in
 632         lib/Makefile
 633         src/Makefile
 634         src/liblzma/Makefile
 635         src/liblzma/api/Makefile
 636         src/xz/Makefile
 637         src/xzdec/Makefile
 638         src/lzmainfo/Makefile
 639         src/scripts/Makefile
 640         tests/Makefile
 641         debug/Makefile
 642 ])
 643 AC_CONFIG_FILES([src/scripts/xzdiff], [chmod +x src/scripts/xzdiff])
 644 AC_CONFIG_FILES([src/scripts/xzgrep], [chmod +x src/scripts/xzgrep])
 645 AC_CONFIG_FILES([src/scripts/xzmore], [chmod +x src/scripts/xzmore])
 646 AC_CONFIG_FILES([src/scripts/xzless], [chmod +x src/scripts/xzless])
 647
 648 AC_OUTPUT
 649
 650 # Some warnings
 651 if test x$tuklib_cv_physmem_method = xunknown; then
 652         echo
 653         echo "WARNING:"
 654         echo "No supported method to detect the amount of RAM."
 655         echo "Consider using --enable-assume-ram (if you didn't already)"
 656         echo "or make a patch to add support for this operating system."
 657 fi
 658
 659 # Not threading yet so don't warn.
 660 #if test x$tuklib_cv_cpucores_method = xunknown; then
 661 #       echo
 662 #       echo "WARNING:"
 663 #       echo "No supported method to detect the number of CPU cores."
 664 #fi