configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 ###############################################################################
   5 #
   6 # Author: Lasse Collin
   7 #
   8 # This file has been put into the public domain.
   9 # You can do whatever you want with this file.
  10 #
  11 ###############################################################################
  12
  13 # NOTE: Don't add useless checks. autoscan detects this and that, but don't
  14 # let it confuse you. For example, we don't care about checking for behavior
  15 # of malloc(), stat(), or lstat(), since we don't use those functions in
  16 # a way that would cause the problems the autoconf macros check.
  17
  18 AC_PREREQ([2.64])
  19
  20 AC_INIT([XZ Utils], m4_esyscmd([/bin/sh build-aux/version.sh]),
  21         [lasse.collin@tukaani.org], [xz], [http://tukaani.org/xz/])
  22 AC_CONFIG_SRCDIR([src/liblzma/common/common.h])
  23 AC_CONFIG_AUX_DIR([build-aux])
  24 AC_CONFIG_MACRO_DIR([m4])
  25 AC_CONFIG_HEADER([config.h])
  26
  27 echo
  28 echo "$PACKAGE_STRING"
  29
  30 echo
  31 echo "System type:"
  32 # This is needed to know if assembler optimizations can be used.
  33 AC_CANONICAL_HOST
  34
  35 # We do some special things on Windows (32-bit or 64-bit) builds.
  36 case $host_os in
  37         mingw* | cygwin*) is_w32=yes ;;
  38         *)                is_w32=no ;;
  39 esac
  40 AM_CONDITIONAL([COND_W32], [test "$is_w32" = yes])
  41
  42 # We need to use $EXEEXT with $(LN_S) when creating symlinks to
  43 # executables. Cygwin is an exception to this, since it is recommended
  44 # that symlinks don't have the .exe suffix. To make this work, we
  45 # define LN_EXEEXT.
  46 case $host_os in
  47         cygwin)  LN_EXEEXT= ;;
  48         *)       LN_EXEEXT='$(EXEEXT)' ;;
  49 esac
  50 AC_SUBST([LN_EXEEXT])
  51
  52 echo
  53 echo "Configure options:"
  54 AM_CFLAGS=
  55
  56
  57 #############
  58 # Debugging #
  59 #############
  60
  61 AC_MSG_CHECKING([if debugging code should be compiled])
  62 AC_ARG_ENABLE([debug], AC_HELP_STRING([--enable-debug], [Enable debugging code.]),
  63         [], enable_debug=no)
  64 if test "x$enable_debug" = xyes; then
  65         AC_MSG_RESULT([yes])
  66 else
  67         AC_DEFINE([NDEBUG], [1], [Define to 1 to disable debugging code.])
  68         AC_MSG_RESULT([no])
  69 fi
  70
  71
  72 ###########
  73 # Filters #
  74 ###########
  75
  76 m4_define([SUPPORTED_FILTERS], [lzma1,lzma2,delta,x86,powerpc,ia64,arm,armthumb,sparc])dnl
  77 m4_define([SIMPLE_FILTERS], [x86,powerpc,ia64,arm,armthumb,sparc])
  78 m4_define([LZ_FILTERS], [lzma1,lzma2])
  79
  80 m4_foreach([NAME], [SUPPORTED_FILTERS],
  81 [enable_filter_[]NAME=no
  82 enable_encoder_[]NAME=no
  83 enable_decoder_[]NAME=no
  84 ])dnl
  85
  86 AC_MSG_CHECKING([which encoders to build])
  87 AC_ARG_ENABLE([encoders], AC_HELP_STRING([--enable-encoders=LIST],
  88                 [Comma-separated list of encoders to build. Default=all.
  89                 Available encoders:]
  90                         m4_translit(m4_defn([SUPPORTED_FILTERS]), [,], [ ])),
  91         [], [enable_encoders=SUPPORTED_FILTERS])
  92 enable_encoders=`echo "$enable_encoders" | sed 's/,/ /g'`
  93 if test "x$enable_encoders" = xno || test "x$enable_encoders" = x; then
  94         AC_MSG_RESULT([(none)])
  95 else
  96         for arg in $enable_encoders
  97         do
  98                 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
  99                         NAME)
 100                                 enable_filter_[]NAME=yes
 101                                 enable_encoder_[]NAME=yes
 102                                 AC_DEFINE(HAVE_ENCODER_[]m4_toupper(NAME), [1],
 103                                 [Define to 1 if] NAME [encoder is enabled.])
 104                                 ;;])
 105                         *)
 106                                 AC_MSG_RESULT([])
 107                                 AC_MSG_ERROR([unknown filter: $arg])
 108                                 ;;
 109                 esac
 110         done
 111         AC_MSG_RESULT([$enable_encoders])
 112 fi
 113
 114 AC_MSG_CHECKING([which decoders to build])
 115 AC_ARG_ENABLE([decoders], AC_HELP_STRING([--enable-decoders=LIST],
 116                 [Comma-separated list of decoders to build. Default=all.
 117                 Available decoders are the same as available encoders.]),
 118         [], [enable_decoders=SUPPORTED_FILTERS])
 119 enable_decoders=`echo "$enable_decoders" | sed 's/,/ /g'`
 120 if test "x$enable_decoders" = xno || test "x$enable_decoders" = x; then
 121         AC_MSG_RESULT([(none)])
 122 else
 123         for arg in $enable_decoders
 124         do
 125                 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
 126                         NAME)
 127                                 enable_filter_[]NAME=yes
 128                                 enable_decoder_[]NAME=yes
 129                                 AC_DEFINE(HAVE_DECODER_[]m4_toupper(NAME), [1],
 130                                 [Define to 1 if] NAME [decoder is enabled.])
 131                                 ;;])
 132                         *)
 133                                 AC_MSG_RESULT([])
 134                                 AC_MSG_ERROR([unknown filter: $arg])
 135                                 ;;
 136                 esac
 137         done
 138
 139         # LZMA2 requires that LZMA1 is enabled.
 140         test "x$enable_encoder_lzma2" = xyes && enable_encoder_lzma1=yes
 141         test "x$enable_decoder_lzma2" = xyes && enable_decoder_lzma1=yes
 142
 143         AC_MSG_RESULT([$enable_decoders])
 144 fi
 145
 146 if test "x$enable_encoder_lzma2$enable_encoder_lzma1" = xyesno \
 147                 || test "x$enable_decoder_lzma2$enable_decoder_lzma1" = xyesno; then
 148         AC_MSG_ERROR([LZMA2 requires that LZMA1 is also enabled.])
 149 fi
 150
 151 AM_CONDITIONAL(COND_MAIN_ENCODER, test "x$enable_encoders" != xno && test "x$enable_encoders" != x)
 152 AM_CONDITIONAL(COND_MAIN_DECODER, test "x$enable_decoders" != xno && test "x$enable_decoders" != x)
 153
 154 m4_foreach([NAME], [SUPPORTED_FILTERS],
 155 [AM_CONDITIONAL(COND_FILTER_[]m4_toupper(NAME), test "x$enable_filter_[]NAME" = xyes)
 156 AM_CONDITIONAL(COND_ENCODER_[]m4_toupper(NAME), test "x$enable_encoder_[]NAME" = xyes)
 157 AM_CONDITIONAL(COND_DECODER_[]m4_toupper(NAME), test "x$enable_decoder_[]NAME" = xyes)
 158 ])dnl
 159
 160 # The so called "simple filters" share common code.
 161 enable_filter_simple=no
 162 enable_encoder_simple=no
 163 enable_decoder_simple=no
 164 m4_foreach([NAME], [SIMPLE_FILTERS],
 165 [test "x$enable_filter_[]NAME" = xyes && enable_filter_simple=yes
 166 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_simple=yes
 167 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_simple=yes
 168 ])dnl
 169 AM_CONDITIONAL(COND_FILTER_SIMPLE, test "x$enable_filter_simple" = xyes)
 170 AM_CONDITIONAL(COND_ENCODER_SIMPLE, test "x$enable_encoder_simple" = xyes)
 171 AM_CONDITIONAL(COND_DECODER_SIMPLE, test "x$enable_decoder_simple" = xyes)
 172
 173 # LZ-based filters share common code.
 174 enable_filter_lz=no
 175 enable_encoder_lz=no
 176 enable_decoder_lz=no
 177 m4_foreach([NAME], [LZ_FILTERS],
 178 [test "x$enable_filter_[]NAME" = xyes && enable_filter_lz=yes
 179 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_lz=yes
 180 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_lz=yes
 181 ])dnl
 182 AM_CONDITIONAL(COND_FILTER_LZ, test "x$enable_filter_lz" = xyes)
 183 AM_CONDITIONAL(COND_ENCODER_LZ, test "x$enable_encoder_lz" = xyes)
 184 AM_CONDITIONAL(COND_DECODER_LZ, test "x$enable_decoder_lz" = xyes)
 185
 186
 187 #################
 188 # Match finders #
 189 #################
 190
 191 m4_define([SUPPORTED_MATCH_FINDERS], [hc3,hc4,bt2,bt3,bt4])
 192
 193 m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS],
 194 [enable_match_finder_[]NAME=no
 195 ])
 196
 197 AC_MSG_CHECKING([which match finders to build])
 198 AC_ARG_ENABLE([match-finders], AC_HELP_STRING([--enable-match-finders=LIST],
 199                 [Comma-separated list of match finders to build. Default=all.
 200                 At least one match finder is required for encoding with
 201                 the LZMA1 and LZMA2 filters. Available match finders:]
 202                 m4_translit(m4_defn([SUPPORTED_MATCH_FINDERS]), [,], [ ])), [],
 203         [enable_match_finders=SUPPORTED_MATCH_FINDERS])
 204 enable_match_finders=`echo "$enable_match_finders" | sed 's/,/ /g'`
 205 if test "x$enable_encoder_lz" = xyes ; then
 206         for arg in $enable_match_finders
 207                 do
 208                 case $arg in m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS], [
 209                         NAME)
 210                                 enable_match_finder_[]NAME=yes
 211                                 AC_DEFINE(HAVE_MF_[]m4_toupper(NAME), [1],
 212                                 [Define to 1 to enable] NAME [match finder.])
 213                                 ;;])
 214                         *)
 215                                 AC_MSG_RESULT([])
 216                                 AC_MSG_ERROR([unknown match finder: $arg])
 217                                 ;;
 218                 esac
 219         done
 220         AC_MSG_RESULT([$enable_match_finders])
 221 else
 222         AC_MSG_RESULT([(none because not building any LZ-based encoder)])
 223 fi
 224
 225
 226 ####################
 227 # Integrity checks #
 228 ####################
 229
 230 m4_define([SUPPORTED_CHECKS], [crc32,crc64,sha256])
 231
 232 m4_foreach([NAME], [SUPPORTED_FILTERS],
 233 [enable_check_[]NAME=no
 234 ])dnl
 235
 236 AC_MSG_CHECKING([which integrity checks to build])
 237 AC_ARG_ENABLE([checks], AC_HELP_STRING([--enable-checks=LIST],
 238                 [Comma-separated list of integrity checks to build.
 239                 Default=all. Available integrity checks:]
 240                 m4_translit(m4_defn([SUPPORTED_CHECKS]), [,], [ ])),
 241         [], [enable_checks=SUPPORTED_CHECKS])
 242 enable_checks=`echo "$enable_checks" | sed 's/,/ /g'`
 243 if test "x$enable_checks" = xno || test "x$enable_checks" = x; then
 244         AC_MSG_RESULT([(none)])
 245 else
 246         for arg in $enable_checks
 247         do
 248                 case $arg in m4_foreach([NAME], [SUPPORTED_CHECKS], [
 249                         NAME)
 250                                 enable_check_[]NAME=yes
 251                                 AC_DEFINE(HAVE_CHECK_[]m4_toupper(NAME), [1],
 252                                 [Define to 1 if] NAME
 253                                 [integrity check is enabled.])
 254                                 ;;])
 255                         *)
 256                                 AC_MSG_RESULT([])
 257                                 AC_MSG_ERROR([unknown integrity check: $arg])
 258                                 ;;
 259                 esac
 260         done
 261         AC_MSG_RESULT([$enable_checks])
 262 fi
 263 if test "x$enable_checks_crc32" = xno ; then
 264         AC_MSG_ERROR([For now, the CRC32 check must always be enabled.])
 265 fi
 266
 267 m4_foreach([NAME], [SUPPORTED_CHECKS],
 268 [AM_CONDITIONAL(COND_CHECK_[]m4_toupper(NAME), test "x$enable_check_[]NAME" = xyes)
 269 ])dnl
 270
 271
 272 ###########################
 273 # Assembler optimizations #
 274 ###########################
 275
 276 AC_MSG_CHECKING([if assembler optimizations should be used])
 277 AC_ARG_ENABLE([assembler], AC_HELP_STRING([--disable-assembler],
 278                 [Do not use assembler optimizations even if such exist
 279                 for the architecture.]),
 280         [], [enable_assembler=yes])
 281 if test "x$enable_assembler" = xyes; then
 282         enable_assembler=no
 283         case $host_os in
 284                 # Darwin should work too but only if not creating universal
 285                 # binaries. Solaris x86 could work too but I cannot test.
 286                 linux* | *bsd* | mingw* | cygwin* | *djgpp*)
 287                         case $host_cpu in
 288                                 i?86)   enable_assembler=x86 ;;
 289                                 x86_64) enable_assembler=x86_64 ;;
 290                         esac
 291                         ;;
 292         esac
 293 fi
 294 case $enable_assembler in
 295         x86 | x86_64 | no)
 296                 AC_MSG_RESULT([$enable_assembler])
 297                 ;;
 298         *)
 299                 AC_MSG_RESULT([])
 300                 AC_MSG_ERROR([--enable-assembler accepts only \`yes', \`no', \`x86', or \`x86_64'.])
 301                 ;;
 302 esac
 303 AM_CONDITIONAL(COND_ASM_X86, test "x$enable_assembler" = xx86)
 304 AM_CONDITIONAL(COND_ASM_X86_64, test "x$enable_assembler" = xx86_64)
 305
 306
 307 #####################
 308 # Size optimization #
 309 #####################
 310
 311 AC_MSG_CHECKING([if small size is preferred over speed])
 312 AC_ARG_ENABLE([small], AC_HELP_STRING([--enable-small],
 313                 [Make liblzma smaller and a little slower.
 314                 This is disabled by default to optimize for speed.]),
 315         [], [enable_small=no])
 316 if test "x$enable_small" = xyes; then
 317         AC_DEFINE([HAVE_SMALL], [1], [Define to 1 if optimizing for size.])
 318 elif test "x$enable_small" != xno; then
 319         AC_MSG_RESULT([])
 320         AC_MSG_ERROR([--enable-small accepts only \`yes' or \`no'])
 321 fi
 322 AC_MSG_RESULT([$enable_small])
 323 AM_CONDITIONAL(COND_SMALL, test "x$enable_small" = xyes)
 324
 325
 326 #############
 327 # Threading #
 328 #############
 329
 330 AC_MSG_CHECKING([if threading support is wanted])
 331 AC_ARG_ENABLE([threads], AC_HELP_STRING([--disable-threads],
 332                 [Disable threading support.
 333                 This makes some things thread-unsafe.]),
 334         [], [enable_threads=yes])
 335 if test "x$enable_threads" != xyes && test "x$enable_threads" != xno; then
 336         AC_MSG_RESULT([])
 337         AC_MSG_ERROR([--enable-threads accepts only \`yes' or \`no'])
 338 fi
 339 AC_MSG_RESULT([$enable_threads])
 340 # We use the actual result a little later.
 341
 342
 343 #########################
 344 # Assumed amount of RAM #
 345 #########################
 346
 347 # We use 128 MiB as default, because it will allow decompressing files
 348 # created with "xz -9". It would be slightly safer to guess a lower value,
 349 # but most systems, on which we don't have any way to determine the amount
 350 # of RAM, will probably have at least 128 MiB of RAM.
 351 AC_MSG_CHECKING([how much RAM to assume if the real amount is unknown])
 352 AC_ARG_ENABLE([assume-ram], AC_HELP_STRING([--enable-assume-ram=SIZE],
 353                 [If and only if the real amount of RAM cannot be determined,
 354                 assume SIZE MiB. The default is 128 MiB. This affects the
 355                 default memory usage limit.]),
 356         [], [enable_assume_ram=128])
 357 assume_ram_check=`echo "$enable_assume_ram" | tr -d 0123456789`
 358 if test -z "$enable_assume_ram" || test -n "$assume_ram_check"; then
 359         AC_MSG_RESULT([])
 360         AC_MSG_ERROR([--enable-assume-ram accepts only an integer argument])
 361 fi
 362 AC_MSG_RESULT([$enable_assume_ram MiB])
 363 AC_DEFINE_UNQUOTED([ASSUME_RAM], [$enable_assume_ram],
 364                 [How many MiB of RAM to assume if the real amount cannot
 365                 be determined.])
 366
 367
 368 #########################
 369 # Components to install #
 370 #########################
 371
 372 AC_ARG_ENABLE([xz], [AC_HELP_STRING([--disable-xz],
 373                 [do not build the xz tool])],
 374         [], [enable_xz=yes])
 375 AM_CONDITIONAL([COND_XZ], [test x$enable_xz != xno])
 376
 377 AC_ARG_ENABLE([xzdec], [AC_HELP_STRING([--disable-xzdec],
 378                 [do not build xzdec])],
 379         [], [enable_xzdec=yes])
 380 AM_CONDITIONAL([COND_XZDEC], [test x$enable_xzdec != xno])
 381
 382 AC_ARG_ENABLE([lzmadec], [AC_HELP_STRING([--disable-lzmadec],
 383                 [do not build lzmadec
 384                 (it exists primarily for LZMA Utils compatibility)])],
 385         [], [enable_lzmadec=yes])
 386 AM_CONDITIONAL([COND_LZMADEC], [test x$enable_lzmadec != xno])
 387
 388 AC_ARG_ENABLE([lzmainfo], [AC_HELP_STRING([--disable-lzmainfo],
 389                 [do not build lzmainfo
 390                 (it exists primarily for LZMA Utils compatibility)])],
 391         [], [enable_lzmainfo=yes])
 392 AM_CONDITIONAL([COND_LZMAINFO], [test x$enable_lzmainfo != xno])
 393
 394 AC_ARG_ENABLE([lzma-links], [AC_HELP_STRING([--disable-lzma-links],
 395                 [do not create symlinks for LZMA Utils compatibility])],
 396         [], [enable_lzma_links=yes])
 397 AM_CONDITIONAL([COND_LZMALINKS], [test x$enable_lzma_links != xno])
 398
 399 AC_ARG_ENABLE([scripts], [AC_HELP_STRING([--disable-scripts],
 400                 [do not install the scripts xzdiff, xzgrep, xzless, xzmore,
 401                 and their symlinks])],
 402         [], [enable_scripts=yes])
 403 AM_CONDITIONAL([COND_SCRIPTS], [test x$enable_scripts != xno])
 404
 405
 406 ###############################################################################
 407 # Checks for programs.
 408 ###############################################################################
 409
 410 echo
 411 gl_POSIX_SHELL
 412 if test -z "$POSIX_SHELL" ; then
 413         AC_MSG_ERROR([No POSIX conforming shell (sh) was found.])
 414 fi
 415
 416 echo
 417 echo "Initializing Automake:"
 418
 419 AM_INIT_AUTOMAKE([1.10 foreign tar-v7 filename-length-max=99])
 420 AC_PROG_LN_S
 421
 422 AC_PROG_CC_C99
 423 if test x$ac_cv_prog_cc_c99 = xno ; then
 424         AC_MSG_ERROR([No C99 compiler was found.])
 425 fi
 426
 427 AM_PROG_CC_C_O
 428 AM_PROG_AS
 429 AC_USE_SYSTEM_EXTENSIONS
 430
 431 if test "x$enable_threads" = xyes; then
 432         echo
 433         echo "Threading support:"
 434         AX_PTHREAD
 435         LIBS="$LIBS $PTHREAD_LIBS"
 436         AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"
 437         CC="$PTHREAD_CC"
 438         AC_SEARCH_LIBS([clock_gettime], [rt])
 439 fi
 440 AM_CONDITIONAL([COND_THREADS], [test "x$ax_pthread_ok" = xyes])
 441
 442 echo
 443 echo "Initializing Libtool:"
 444 LT_PREREQ([2.2])
 445 LT_INIT([win32-dll])
 446 LT_LANG([Windows Resource])
 447
 448 # This is a bit wrong since it is possible to request that only some libs
 449 # are built as shared. Using that feature isn't so common though, and this
 450 # breaks only on Windows (at least for now) if the user enables only some
 451 # libs as shared.
 452 AM_CONDITIONAL([COND_SHARED], [test "x$enable_shared" != xno])
 453
 454
 455 ###############################################################################
 456 # Checks for libraries.
 457 ###############################################################################
 458
 459 echo
 460 echo "Initializing gettext:"
 461 AM_GNU_GETTEXT_VERSION([0.16.1])
 462 AM_GNU_GETTEXT([external])
 463
 464 ###############################################################################
 465 # Checks for header files.
 466 ###############################################################################
 467
 468 echo
 469 echo "System headers and functions:"
 470
 471 # There is currently no workarounds in this package if some of
 472 # these headers are missing.
 473 AC_CHECK_HEADERS([fcntl.h limits.h sys/time.h],
 474         [],
 475         [AC_MSG_ERROR([Required header file(s) are missing.])])
 476
 477
 478 ###############################################################################
 479 # Checks for typedefs, structures, and compiler characteristics.
 480 ###############################################################################
 481
 482 dnl We don't need these as long as we need a C99 compiler anyway.
 483 dnl AC_C_INLINE
 484 dnl AC_C_RESTRICT
 485
 486 AC_HEADER_STDBOOL
 487
 488 AC_TYPE_UINT8_T
 489 AC_TYPE_UINT16_T
 490 AC_TYPE_INT32_T
 491 AC_TYPE_UINT32_T
 492 AC_TYPE_INT64_T
 493 AC_TYPE_UINT64_T
 494 AC_TYPE_UINTPTR_T
 495
 496 AC_CHECK_SIZEOF([size_t])
 497
 498 # The command line tool can copy high resolution timestamps if such
 499 # information is availabe in struct stat. Otherwise one second accuracy
 500 # is used.
 501 AC_CHECK_MEMBERS([
 502         struct stat.st_atim.tv_nsec,
 503         struct stat.st_atimespec.tv_nsec,
 504         struct stat.st_atimensec,
 505         struct stat.st_uatime,
 506         struct stat.st_atim.st__tim.tv_nsec])
 507
 508 AC_SYS_LARGEFILE
 509 AC_C_BIGENDIAN
 510
 511
 512 ###############################################################################
 513 # Checks for library functions.
 514 ###############################################################################
 515
 516 # Gnulib replacements as needed
 517 gl_GETOPT
 518
 519 # Find the best function to set timestamps.
 520 AC_CHECK_FUNCS([futimens futimes futimesat utimes utime], [break])
 521
 522 # This is nice to have but not mandatory.
 523 AC_CHECK_FUNCS([posix_fadvise])
 524
 525 TUKLIB_PROGNAME
 526 TUKLIB_INTEGER
 527 TUKLIB_PHYSMEM
 528 TUKLIB_CPUCORES
 529 TUKLIB_MBSTR
 530
 531
 532 ###############################################################################
 533 # If using GCC, set some additional AM_CFLAGS:
 534 ###############################################################################
 535
 536 if test "$GCC" = yes ; then
 537         echo
 538         echo "GCC extensions:"
 539 fi
 540
 541 # Always do the visibility check but don't set AM_CFLAGS on Windows.
 542 # This way things get set properly even on Windows.
 543 gl_VISIBILITY
 544 if test -n "$CFLAG_VISIBILITY" && test "$is_w32" = no; then
 545         AM_CFLAGS="$AM_CFLAGS $CFLAG_VISIBILITY"
 546 fi
 547
 548 if test "$GCC" = yes ; then
 549         # Enable as much warnings as possible. These commented warnings won't
 550         # work for this package though:
 551         #   * -Wunreachable-code breaks several assert(0) cases, which are
 552         #     backed up with "return LZMA_PROG_ERROR".
 553         #   * -Wcast-qual would break various things where we need a non-const
 554         #     pointer although we don't modify anything through it.
 555         #   * -Wcast-align breaks optimized CRC32 and CRC64 implementation
 556         #     on some architectures (not on x86), where this warning is bogus,
 557         #     because we take care of correct alignment.
 558         #   * -Winline, -Wdisabled-optimization, -Wunsafe-loop-optimizations
 559         #     don't seem so useful here; at least the last one gives some
 560         #     warnings which are not bugs.
 561         for NEW_FLAG in \
 562                         -Wall \
 563                         -Wextra \
 564                         -Wformat=2 \
 565                         -Winit-self \
 566                         -Wmissing-include-dirs \
 567                         -Wstrict-aliasing \
 568                         -Wfloat-equal \
 569                         -Wundef \
 570                         -Wshadow \
 571                         -Wpointer-arith \
 572                         -Wbad-function-cast \
 573                         -Wwrite-strings \
 574                         -Wlogical-op \
 575                         -Waggregate-return \
 576                         -Wstrict-prototypes \
 577                         -Wold-style-definition \
 578                         -Wmissing-prototypes \
 579                         -Wmissing-declarations \
 580                         -Wmissing-noreturn \
 581                         -Wredundant-decls
 582         do
 583                 AC_MSG_CHECKING([if $CC accepts $NEW_FLAG])
 584                 OLD_CFLAGS="$CFLAGS"
 585                 CFLAGS="$CFLAGS $NEW_FLAG"
 586                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([void foo(void) { }])], [
 587                         AM_CFLAGS="$AM_CFLAGS $NEW_FLAG"
 588                         AC_MSG_RESULT([yes])
 589                 ], [
 590                         AC_MSG_RESULT([no])
 591                 ])
 592                 CFLAGS="$OLD_CFLAGS"
 593         done
 594
 595         AC_ARG_ENABLE([werror],
 596                 AC_HELP_STRING([--enable-werror], [Enable -Werror to abort
 597                         compilation on all compiler warnings.]),
 598                 [], [enable_werror=no])
 599         if test "x$enable_werror" = "xyes"; then
 600                 AM_CFLAGS="$AM_CFLAGS -Werror"
 601         fi
 602 fi
 603
 604
 605 ###############################################################################
 606 # Create the makefiles and config.h
 607 ###############################################################################
 608
 609 echo
 610
 611 # Don't build the lib directory at all if we don't need any replacement
 612 # functions.
 613 AM_CONDITIONAL([COND_GNULIB], test -n "$LIBOBJS")
 614
 615 # Add default AM_CFLAGS.
 616 AC_SUBST([AM_CFLAGS])
 617
 618 # This is needed for src/scripts.
 619 xz=`echo xz | sed "$program_transform_name"`
 620 AC_SUBST([xz])
 621
 622 AC_CONFIG_FILES([
 623         Doxyfile
 624         Makefile
 625         po/Makefile.in
 626         lib/Makefile
 627         src/Makefile
 628         src/liblzma/liblzma.pc
 629         src/liblzma/Makefile
 630         src/liblzma/api/Makefile
 631         src/xz/Makefile
 632         src/xzdec/Makefile
 633         src/lzmainfo/Makefile
 634         src/scripts/Makefile
 635         src/scripts/xzdiff
 636         src/scripts/xzgrep
 637         src/scripts/xzmore
 638         src/scripts/xzless
 639         tests/Makefile
 640         debug/Makefile
 641 ])
 642
 643 AC_OUTPUT
 644
 645 # Some warnings
 646 if test x$tuklib_cv_physmem_method = xunknown; then
 647         echo
 648         echo "WARNING:"
 649         echo "No supported method to detect the amount of RAM."
 650         echo "Consider using --enable-assume-ram (if you didn't already)"
 651         echo "or make a patch to add support for this operating system."
 652 fi
 653
 654 # Not threading yet so don't warn.
 655 #if test x$tuklib_cv_cpucores_method = xunknown; then
 656 #       echo
 657 #       echo "WARNING:"
 658 #       echo "No supported method to detect the number of CPU cores."
 659 #fi