| blob | 905d717f0f478edb52ee31b704f26118018bc590 |
1 # -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
4 ###############################################################################
5 #
6 # Author: Lasse Collin
7 #
8 # This file has been put into the public domain.
9 # You can do whatever you want with this file.
10 #
11 ###############################################################################
13 # NOTE: Don't add useless checks. autoscan detects this and that, but don't
14 # let it confuse you. For example, we don't care about checking for behavior
15 # of malloc(), stat(), or lstat(), since we don't use those functions in
16 # a way that would cause the problems the autoconf macros check.
18 AC_PREREQ([2.69])
20 AC_INIT([XZ Utils], m4_esyscmd([/bin/sh build-aux/version.sh]),
21 [xz@tukaani.org], [xz], [https://tukaani.org/xz/])
22 AC_CONFIG_SRCDIR([src/liblzma/common/common.h])
23 AC_CONFIG_AUX_DIR([build-aux])
24 AC_CONFIG_MACRO_DIR([m4])
25 AC_CONFIG_HEADERS([config.h])
27 echo
28 echo "$PACKAGE_STRING"
30 echo
31 echo "System type:"
32 # This is needed to know if assembler optimizations can be used.
33 AC_CANONICAL_HOST
35 # We do some special things on Windows (32-bit or 64-bit) builds.
36 case $host_os in
37 mingw* | cygwin | msys) is_w32=yes ;;
38 *) is_w32=no ;;
39 esac
40 AM_CONDITIONAL([COND_W32], [test "$is_w32" = yes])
42 # We need to use $EXEEXT with $(LN_S) when creating symlinks to
43 # executables. Cygwin is an exception to this, since it is recommended
44 # that symlinks don't have the .exe suffix. To make this work, we
45 # define LN_EXEEXT.
46 #
47 # MSYS2 is treated the same way as Cygwin. It uses plain "msys" like
48 # the original MSYS when building MSYS/MSYS2-binaries. Hopefully this
49 # doesn't break things for the original MSYS developers. Note that this
50 # doesn't affect normal MSYS/MSYS2 users building non-MSYS/MSYS2 binaries
51 # since in that case the $host_os is usually mingw32.
52 case $host_os in
53 cygwin | msys) LN_EXEEXT= ;;
54 *) LN_EXEEXT='$(EXEEXT)' ;;
55 esac
56 AC_SUBST([LN_EXEEXT])
58 echo
59 echo "Configure options:"
60 AM_CFLAGS=
63 #############
64 # Debugging #
65 #############
67 AC_MSG_CHECKING([if debugging code should be compiled])
68 AC_ARG_ENABLE([debug], AS_HELP_STRING([--enable-debug], [Enable debugging code.]),
69 [], enable_debug=no)
70 if test "x$enable_debug" = xyes; then
71 AC_MSG_RESULT([yes])
72 else
73 AC_DEFINE([NDEBUG], [1], [Define to 1 to disable debugging code.])
74 AC_MSG_RESULT([no])
75 fi
78 ###########
79 # Filters #
80 ###########
82 m4_define([SUPPORTED_FILTERS], [lzma1,lzma2,delta,x86,powerpc,ia64,arm,armthumb,arm64,sparc])dnl
83 m4_define([SIMPLE_FILTERS], [x86,powerpc,ia64,arm,armthumb,arm64,sparc])
84 m4_define([LZ_FILTERS], [lzma1,lzma2])
86 m4_foreach([NAME], [SUPPORTED_FILTERS],
87 [enable_filter_[]NAME=no
88 enable_encoder_[]NAME=no
89 enable_decoder_[]NAME=no
90 ])dnl
92 AC_MSG_CHECKING([which encoders to build])
93 AC_ARG_ENABLE([encoders], AS_HELP_STRING([--enable-encoders=LIST],
94 [Comma-separated list of encoders to build. Default=all.
95 Available encoders:]
96 m4_translit(m4_defn([SUPPORTED_FILTERS]), [,], [ ])),
97 [], [enable_encoders=SUPPORTED_FILTERS])
98 enable_encoders=`echo "$enable_encoders" | sed 's/,/ /g'`
99 if test "x$enable_encoders" = xno || test "x$enable_encoders" = x; then
100 enable_encoders=no
101 AC_MSG_RESULT([(none)])
102 else
103 for arg in $enable_encoders
104 do
105 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
106 NAME)
107 enable_filter_[]NAME=yes
108 enable_encoder_[]NAME=yes
109 AC_DEFINE(HAVE_ENCODER_[]m4_toupper(NAME), [1],
110 [Define to 1 if] NAME [encoder is enabled.])
111 ;;])
112 *)
113 AC_MSG_RESULT([])
114 AC_MSG_ERROR([unknown filter: $arg])
115 ;;
116 esac
117 done
118 AC_DEFINE([HAVE_ENCODERS], [1],
119 [Define to 1 if any of HAVE_ENCODER_foo have been defined.])
120 AC_MSG_RESULT([$enable_encoders])
121 fi
123 AC_MSG_CHECKING([which decoders to build])
124 AC_ARG_ENABLE([decoders], AS_HELP_STRING([--enable-decoders=LIST],
125 [Comma-separated list of decoders to build. Default=all.
126 Available decoders are the same as available encoders.]),
127 [], [enable_decoders=SUPPORTED_FILTERS])
128 enable_decoders=`echo "$enable_decoders" | sed 's/,/ /g'`
129 if test "x$enable_decoders" = xno || test "x$enable_decoders" = x; then
130 enable_decoders=no
131 AC_MSG_RESULT([(none)])
132 else
133 for arg in $enable_decoders
134 do
135 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
136 NAME)
137 enable_filter_[]NAME=yes
138 enable_decoder_[]NAME=yes
139 AC_DEFINE(HAVE_DECODER_[]m4_toupper(NAME), [1],
140 [Define to 1 if] NAME [decoder is enabled.])
141 ;;])
142 *)
143 AC_MSG_RESULT([])
144 AC_MSG_ERROR([unknown filter: $arg])
145 ;;
146 esac
147 done
148 AC_DEFINE([HAVE_DECODERS], [1],
149 [Define to 1 if any of HAVE_DECODER_foo have been defined.])
150 AC_MSG_RESULT([$enable_decoders])
151 fi
153 if test "x$enable_encoder_lzma2$enable_encoder_lzma1" = xyesno \
154 || test "x$enable_decoder_lzma2$enable_decoder_lzma1" = xyesno; then
155 AC_MSG_ERROR([LZMA2 requires that LZMA1 is also enabled.])
156 fi
158 AM_CONDITIONAL(COND_MAIN_ENCODER, test "x$enable_encoders" != xno)
159 AM_CONDITIONAL(COND_MAIN_DECODER, test "x$enable_decoders" != xno)
161 m4_foreach([NAME], [SUPPORTED_FILTERS],
162 [AM_CONDITIONAL(COND_FILTER_[]m4_toupper(NAME), test "x$enable_filter_[]NAME" = xyes)
163 AM_CONDITIONAL(COND_ENCODER_[]m4_toupper(NAME), test "x$enable_encoder_[]NAME" = xyes)
164 AM_CONDITIONAL(COND_DECODER_[]m4_toupper(NAME), test "x$enable_decoder_[]NAME" = xyes)
165 ])dnl
167 # The so called "simple filters" share common code.
168 enable_filter_simple=no
169 enable_encoder_simple=no
170 enable_decoder_simple=no
171 m4_foreach([NAME], [SIMPLE_FILTERS],
172 [test "x$enable_filter_[]NAME" = xyes && enable_filter_simple=yes
173 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_simple=yes
174 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_simple=yes
175 ])dnl
176 AM_CONDITIONAL(COND_FILTER_SIMPLE, test "x$enable_filter_simple" = xyes)
177 AM_CONDITIONAL(COND_ENCODER_SIMPLE, test "x$enable_encoder_simple" = xyes)
178 AM_CONDITIONAL(COND_DECODER_SIMPLE, test "x$enable_decoder_simple" = xyes)
180 # LZ-based filters share common code.
181 enable_filter_lz=no
182 enable_encoder_lz=no
183 enable_decoder_lz=no
184 m4_foreach([NAME], [LZ_FILTERS],
185 [test "x$enable_filter_[]NAME" = xyes && enable_filter_lz=yes
186 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_lz=yes
187 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_lz=yes
188 ])dnl
189 AM_CONDITIONAL(COND_FILTER_LZ, test "x$enable_filter_lz" = xyes)
190 AM_CONDITIONAL(COND_ENCODER_LZ, test "x$enable_encoder_lz" = xyes)
191 AM_CONDITIONAL(COND_DECODER_LZ, test "x$enable_decoder_lz" = xyes)
194 #################
195 # Match finders #
196 #################
198 m4_define([SUPPORTED_MATCH_FINDERS], [hc3,hc4,bt2,bt3,bt4])
200 m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS],
201 [enable_match_finder_[]NAME=no
202 ])
204 AC_MSG_CHECKING([which match finders to build])
205 AC_ARG_ENABLE([match-finders], AS_HELP_STRING([--enable-match-finders=LIST],
206 [Comma-separated list of match finders to build. Default=all.
207 At least one match finder is required for encoding with
208 the LZMA1 and LZMA2 filters. Available match finders:]
209 m4_translit(m4_defn([SUPPORTED_MATCH_FINDERS]), [,], [ ])), [],
210 [enable_match_finders=SUPPORTED_MATCH_FINDERS])
211 enable_match_finders=`echo "$enable_match_finders" | sed 's/,/ /g'`
212 if test "x$enable_encoder_lz" = xyes ; then
213 if test -z "$enable_match_finders"; then
214 AC_MSG_ERROR([At least one match finder is required for an LZ-based encoder.])
215 fi
217 for arg in $enable_match_finders
218 do
219 case $arg in m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS], [
220 NAME)
221 enable_match_finder_[]NAME=yes
222 AC_DEFINE(HAVE_MF_[]m4_toupper(NAME), [1],
223 [Define to 1 to enable] NAME [match finder.])
224 ;;])
225 *)
226 AC_MSG_RESULT([])
227 AC_MSG_ERROR([unknown match finder: $arg])
228 ;;
229 esac
230 done
231 AC_MSG_RESULT([$enable_match_finders])
232 else
233 AC_MSG_RESULT([(none because not building any LZ-based encoder)])
234 fi
237 ####################
238 # Integrity checks #
239 ####################
241 m4_define([SUPPORTED_CHECKS], [crc32,crc64,sha256])
243 m4_foreach([NAME], [SUPPORTED_CHECKS],
244 [enable_check_[]NAME=no
245 ])dnl
247 AC_MSG_CHECKING([which integrity checks to build])
248 AC_ARG_ENABLE([checks], AS_HELP_STRING([--enable-checks=LIST],
249 [Comma-separated list of integrity checks to build.
250 Default=all. Available integrity checks:]
251 m4_translit(m4_defn([SUPPORTED_CHECKS]), [,], [ ])),
252 [], [enable_checks=SUPPORTED_CHECKS])
253 enable_checks=`echo "$enable_checks" | sed 's/,/ /g'`
254 if test "x$enable_checks" = xno || test "x$enable_checks" = x; then
255 AC_MSG_RESULT([(none)])
256 else
257 for arg in $enable_checks
258 do
259 case $arg in m4_foreach([NAME], [SUPPORTED_CHECKS], [
260 NAME)
261 enable_check_[]NAME=yes
262 AC_DEFINE(HAVE_CHECK_[]m4_toupper(NAME), [1],
263 [Define to 1 if] NAME
264 [integrity check is enabled.])
265 ;;])
266 *)
267 AC_MSG_RESULT([])
268 AC_MSG_ERROR([unknown integrity check: $arg])
269 ;;
270 esac
271 done
272 AC_MSG_RESULT([$enable_checks])
273 fi
274 if test "x$enable_check_crc32" = xno ; then
275 AC_MSG_ERROR([For now, the CRC32 check must always be enabled.])
276 fi
278 m4_foreach([NAME], [SUPPORTED_CHECKS],
279 [AM_CONDITIONAL(COND_CHECK_[]m4_toupper(NAME), test "x$enable_check_[]NAME" = xyes)
280 ])dnl
282 AC_MSG_CHECKING([if external SHA-256 should be used])
283 AC_ARG_ENABLE([external-sha256], AS_HELP_STRING([--enable-external-sha256],
284 [Use SHA-256 code from the operating system.
285 See INSTALL for possible subtle problems.]),
286 [], [enable_external_sha256=no])
287 if test "x$enable_check_sha256" != "xyes"; then
288 enable_external_sha256=no
289 fi
290 if test "x$enable_external_sha256" = xyes; then
291 AC_MSG_RESULT([yes])
292 else
293 AC_MSG_RESULT([no])
294 fi
297 #############
298 # MicroLZMA #
299 #############
301 AC_MSG_CHECKING([if MicroLZMA support should be built])
302 AC_ARG_ENABLE([microlzma], AS_HELP_STRING([--disable-microlzma],
303 [Do not build MicroLZMA encoder and decoder.
304 It is needed by specific applications only,
305 for example, erofs-utils.]),
306 [], [enable_microlzma=yes])
307 case $enable_microlzma in
308 yes | no)
309 AC_MSG_RESULT([$enable_microlzma])
310 ;;
311 *)
312 AC_MSG_RESULT([])
313 AC_MSG_ERROR([--enable-microlzma accepts only `yes' or `no'.])
314 ;;
315 esac
316 AM_CONDITIONAL(COND_MICROLZMA, test "x$enable_microlzma" = xyes)
319 #############################
320 # .lz (lzip) format support #
321 #############################
323 AC_MSG_CHECKING([if .lz (lzip) decompression support should be built])
324 AC_ARG_ENABLE([lzip-decoder], AS_HELP_STRING([--disable-lzip-decoder],
325 [Disable decompression support for .lz (lzip) files.]),
326 [], [enable_lzip_decoder=yes])
327 if test "x$enable_decoder_lzma1" != xyes; then
328 enable_lzip_decoder=no
329 AC_MSG_RESULT([no because LZMA1 decoder is disabled])
330 elif test "x$enable_lzip_decoder" = xyes; then
331 AC_DEFINE([HAVE_LZIP_DECODER], [1],
332 [Define to 1 if .lz (lzip) decompression support is enabled.])
333 AC_MSG_RESULT([yes])
334 else
335 AC_MSG_RESULT([no])
336 fi
337 AM_CONDITIONAL(COND_LZIP_DECODER, test "x$enable_lzip_decoder" = xyes)
340 ###########################
341 # Assembler optimizations #
342 ###########################
344 AC_MSG_CHECKING([if assembler optimizations should be used])
345 AC_ARG_ENABLE([assembler], AS_HELP_STRING([--disable-assembler],
346 [Do not use assembler optimizations even if such exist
347 for the architecture.]),
348 [], [enable_assembler=yes])
349 if test "x$enable_assembler" = xyes; then
350 enable_assembler=no
351 case $host_os in
352 # Darwin should work too but only if not creating universal
353 # binaries. Solaris x86 could work too but I cannot test.
354 linux* | *bsd* | mingw* | cygwin | msys | *djgpp*)
355 case $host_cpu in
356 i?86) enable_assembler=x86 ;;
357 esac
358 ;;
359 esac
360 fi
361 case $enable_assembler in
362 x86 | no)
363 AC_MSG_RESULT([$enable_assembler])
364 ;;
365 *)
366 AC_MSG_RESULT([])
367 AC_MSG_ERROR([--enable-assembler accepts only `yes', `no', or `x86' (32-bit).])
368 ;;
369 esac
370 AM_CONDITIONAL(COND_ASM_X86, test "x$enable_assembler" = xx86)
373 #############
374 # CLMUL CRC #
375 #############
377 AC_ARG_ENABLE([clmul-crc], AS_HELP_STRING([--disable-clmul-crc],
378 [Do not use carryless multiplication for CRC calculation
379 even if support for it is detected.]),
380 [], [enable_clmul_crc=yes])
383 #####################
384 # Size optimization #
385 #####################
387 AC_MSG_CHECKING([if small size is preferred over speed])
388 AC_ARG_ENABLE([small], AS_HELP_STRING([--enable-small],
389 [Make liblzma smaller and a little slower.
390 This is disabled by default to optimize for speed.]),
391 [], [enable_small=no])
392 if test "x$enable_small" = xyes; then
393 AC_DEFINE([HAVE_SMALL], [1], [Define to 1 if optimizing for size.])
394 elif test "x$enable_small" != xno; then
395 AC_MSG_RESULT([])
396 AC_MSG_ERROR([--enable-small accepts only `yes' or `no'])
397 fi
398 AC_MSG_RESULT([$enable_small])
399 AM_CONDITIONAL(COND_SMALL, test "x$enable_small" = xyes)
402 #############
403 # Threading #
404 #############
406 AC_MSG_CHECKING([if threading support is wanted])
407 AC_ARG_ENABLE([threads], AS_HELP_STRING([--enable-threads=METHOD],
408 [Supported METHODS are `yes', `no', `posix', `win95', and
409 `vista'. The default is `yes'. Using `no' together with
410 --enable-small makes liblzma thread unsafe.]),
411 [], [enable_threads=yes])
413 if test "x$enable_threads" = xyes; then
414 case $host_os in
415 mingw*)
416 case $host_cpu in
417 i?86) enable_threads=win95 ;;
418 *) enable_threads=vista ;;
419 esac
420 ;;
421 *)
422 enable_threads=posix
423 ;;
424 esac
425 fi
427 case $enable_threads in
428 posix | win95 | vista)
429 AC_MSG_RESULT([yes, $enable_threads])
430 ;;
431 no)
432 AC_MSG_RESULT([no])
433 ;;
434 *)
435 AC_MSG_RESULT([])
436 AC_MSG_ERROR([--enable-threads only accepts `yes', `no', `posix', `win95', or `vista'])
437 ;;
438 esac
440 # We use the actual result a little later.
443 #########################
444 # Assumed amount of RAM #
445 #########################
447 # We use 128 MiB as default, because it will allow decompressing files
448 # created with "xz -9". It would be slightly safer to guess a lower value,
449 # but most systems, on which we don't have any way to determine the amount
450 # of RAM, will probably have at least 128 MiB of RAM.
451 AC_MSG_CHECKING([how much RAM to assume if the real amount is unknown])
452 AC_ARG_ENABLE([assume-ram], AS_HELP_STRING([--enable-assume-ram=SIZE],
453 [If and only if the real amount of RAM cannot be determined,
454 assume SIZE MiB. The default is 128 MiB. This affects the
455 default memory usage limit.]),
456 [], [enable_assume_ram=128])
457 assume_ram_check=`echo "$enable_assume_ram" | tr -d 0123456789`
458 if test -z "$enable_assume_ram" || test -n "$assume_ram_check"; then
459 AC_MSG_RESULT([])
460 AC_MSG_ERROR([--enable-assume-ram accepts only an integer argument])
461 fi
462 AC_MSG_RESULT([$enable_assume_ram MiB])
463 AC_DEFINE_UNQUOTED([ASSUME_RAM], [$enable_assume_ram],
464 [How many MiB of RAM to assume if the real amount cannot
465 be determined.])
468 #########################
469 # Components to install #
470 #########################
472 AC_ARG_ENABLE([xz], [AS_HELP_STRING([--disable-xz],
473 [do not build the xz tool])],
474 [], [enable_xz=yes])
475 AM_CONDITIONAL([COND_XZ], [test x$enable_xz != xno])
477 AC_ARG_ENABLE([xzdec], [AS_HELP_STRING([--disable-xzdec],
478 [do not build xzdec])],
479 [], [enable_xzdec=yes])
480 test "x$enable_decoders" = xno && enable_xzdec=no
481 AM_CONDITIONAL([COND_XZDEC], [test x$enable_xzdec != xno])
483 AC_ARG_ENABLE([lzmadec], [AS_HELP_STRING([--disable-lzmadec],
484 [do not build lzmadec
485 (it exists primarily for LZMA Utils compatibility)])],
486 [], [enable_lzmadec=yes])
487 test "x$enable_decoder_lzma1" = xno && enable_lzmadec=no
488 AM_CONDITIONAL([COND_LZMADEC], [test x$enable_lzmadec != xno])
490 AC_ARG_ENABLE([lzmainfo], [AS_HELP_STRING([--disable-lzmainfo],
491 [do not build lzmainfo
492 (it exists primarily for LZMA Utils compatibility)])],
493 [], [enable_lzmainfo=yes])
494 test "x$enable_decoder_lzma1" = xno && enable_lzmainfo=no
495 AM_CONDITIONAL([COND_LZMAINFO], [test x$enable_lzmainfo != xno])
497 AC_ARG_ENABLE([lzma-links], [AS_HELP_STRING([--disable-lzma-links],
498 [do not create symlinks for LZMA Utils compatibility])],
499 [], [enable_lzma_links=yes])
500 AM_CONDITIONAL([COND_LZMALINKS], [test x$enable_lzma_links != xno])
502 AC_ARG_ENABLE([scripts], [AS_HELP_STRING([--disable-scripts],
503 [do not install the scripts xzdiff, xzgrep, xzless, xzmore,
504 and their symlinks])],
505 [], [enable_scripts=yes])
506 AM_CONDITIONAL([COND_SCRIPTS], [test x$enable_scripts != xno])
508 AC_ARG_ENABLE([doc], [AS_HELP_STRING([--disable-doc],
509 [do not install documentation files to docdir
510 (man pages will still be installed)])],
511 [], [enable_doc=yes])
512 AM_CONDITIONAL([COND_DOC], [test x$enable_doc != xno])
515 ##############
516 # Sandboxing #
517 ##############
519 AC_MSG_CHECKING([if sandboxing should be used])
520 AC_ARG_ENABLE([sandbox], [AS_HELP_STRING([--enable-sandbox=METHOD],
521 [Sandboxing METHOD can be
522 `auto', `no', `capsicum', or `pledge'.
523 The default is `auto' which enables sandboxing if
524 a supported sandboxing method is found.])],
525 [], [enable_sandbox=auto])
526 case $enable_sandbox in
527 auto)
528 AC_MSG_RESULT([maybe (autodetect)])
529 ;;
530 no | capsicum | pledge)
531 AC_MSG_RESULT([$enable_sandbox])
532 ;;
533 *)
534 AC_MSG_RESULT([])
535 AC_MSG_ERROR([--enable-sandbox only accepts `auto', `no', `capsicum', or `pledge'.])
536 ;;
537 esac
540 ###########################
541 # PATH prefix for scripts #
542 ###########################
544 # The scripts can add a prefix to the search PATH so that POSIX tools
545 # or the xz binary is always in the PATH.
546 AC_ARG_ENABLE([path-for-scripts],
547 [AS_HELP_STRING([--enable-path-for-scripts=PREFIX],
548 [If PREFIX isn't empty, PATH=PREFIX:$PATH will be set in
549 the beginning of the scripts (xzgrep and others).
550 The default is empty except on Solaris the default is
551 /usr/xpg4/bin.])],
552 [], [
553 case $host_os in
554 solaris*) enable_path_for_scripts=/usr/xpg4/bin ;;
555 *) enable_path_for_scripts= ;;
556 esac
557 ])
558 if test -n "$enable_path_for_scripts" && test "x$enable_path_for_scripts" != xno ; then
559 enable_path_for_scripts="PATH=$enable_path_for_scripts:\$PATH"
560 else
561 enable_path_for_scripts=
562 fi
563 AC_SUBST([enable_path_for_scripts])
566 ###############################################################################
567 # Checks for programs.
568 ###############################################################################
570 echo
571 case $host_os in
572 solaris*)
573 # The gnulib POSIX shell macro below may pick a shell that
574 # doesn't work with xzgrep. Workaround by picking a shell
575 # that is known to work.
576 if test -z "$gl_cv_posix_shell" && test -x /usr/xpg4/bin/sh; then
577 gl_cv_posix_shell=/usr/xpg4/bin/sh
578 fi
579 ;;
580 esac
581 gl_POSIX_SHELL
582 if test -z "$POSIX_SHELL" && test "x$enable_scripts" = xyes ; then
583 AC_MSG_ERROR([No POSIX conforming shell (sh) was found.])
584 fi
586 echo
587 echo "Initializing Automake:"
589 # We don't use "subdir-objects" yet because it breaks "make distclean" when
590 # dependencies are enabled (as of Automake 1.14.1) due to this bug:
591 # https://debbugs.gnu.org/cgi/bugreport.cgi?bug=17354
592 # The -Wno-unsupported is used to silence warnings about missing
593 # "subdir-objects".
594 AM_INIT_AUTOMAKE([1.12 foreign tar-v7 filename-length-max=99 -Wno-unsupported])
595 AC_PROG_LN_S
597 dnl # Autoconf >= 2.70 warns that AC_PROG_CC_C99 is obsolete. However,
598 dnl # we have to keep using AC_PROG_CC_C99 instead of AC_PROG_CC
599 dnl # as long as we try to be compatible with Autoconf 2.69.
600 AC_PROG_CC_C99
601 if test x$ac_cv_prog_cc_c99 = xno ; then
602 AC_MSG_ERROR([No C99 compiler was found.])
603 fi
605 AM_PROG_CC_C_O
606 AM_PROG_AS
607 AC_USE_SYSTEM_EXTENSIONS
609 AS_CASE([$enable_threads],
610 [posix], [
611 echo
612 echo "POSIX threading support:"
613 AX_PTHREAD([:]) dnl We don't need the HAVE_PTHREAD macro.
614 LIBS="$LIBS $PTHREAD_LIBS"
615 AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"
617 dnl NOTE: PTHREAD_CC is ignored. It would be useful on AIX,
618 dnl but it's tricky to get it right together with
619 dnl AC_PROG_CC_C99. Thus, this is handled by telling the
620 dnl user in INSTALL to set the correct CC manually.
622 AC_DEFINE([MYTHREAD_POSIX], [1],
623 [Define to 1 when using POSIX threads (pthreads).])
625 # These are nice to have but not mandatory.
626 #
627 # FIXME: xz uses clock_gettime if it is available and can do
628 # it even when threading is disabled. Moving this outside
629 # of pthread detection may be undesirable because then
630 # liblzma may get linked against librt even when librt isn't
631 # needed by liblzma.
632 OLD_CFLAGS=$CFLAGS
633 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
634 AC_SEARCH_LIBS([clock_gettime], [rt])
635 AC_CHECK_FUNCS([clock_gettime pthread_condattr_setclock])
636 AC_CHECK_DECL([CLOCK_MONOTONIC], [AC_DEFINE(
637 [HAVE_CLOCK_MONOTONIC], [1], [Define to 1 if
638 `CLOCK_MONOTONIC' is declared in <time.h>.])], [],
639 [[#include <time.h>]])
640 CFLAGS=$OLD_CFLAGS
641 ],
642 [win95], [
643 AC_DEFINE([MYTHREAD_WIN95], [1], [Define to 1 when using
644 Windows 95 (and thus XP) compatible threads.
645 This avoids use of features that were added in
646 Windows Vista.])
647 ],
648 [vista], [
649 AC_DEFINE([MYTHREAD_VISTA], [1], [Define to 1 when using
650 Windows Vista compatible threads. This uses
651 features that are not available on Windows XP.])
652 ]
653 )
654 AM_CONDITIONAL([COND_THREADS], [test "x$enable_threads" != xno])
656 echo
657 echo "Initializing Libtool:"
658 LT_PREREQ([2.4])
659 LT_INIT([win32-dll])
660 LT_LANG([Windows Resource])
662 # This is a bit wrong since it is possible to request that only some libs
663 # are built as shared. Using that feature isn't so common though, and this
664 # breaks only on Windows (at least for now) if the user enables only some
665 # libs as shared.
666 AM_CONDITIONAL([COND_SHARED], [test "x$enable_shared" != xno])
668 #####################
669 # Symbol versioning #
670 #####################
672 # NOTE: This checks if we are building shared or static library
673 # and if --with-pic or --without-pic was used. Thus this check
674 # must be after Libtool initialization.
675 AC_MSG_CHECKING([if library symbol versioning should be used])
676 AC_ARG_ENABLE([symbol-versions], [AS_HELP_STRING([--enable-symbol-versions],
677 [Use symbol versioning for liblzma. Enabled by default on
678 GNU/Linux, other GNU-based systems, and FreeBSD.])],
679 [], [enable_symbol_versions=auto])
680 if test "x$enable_symbol_versions" = xauto; then
681 case $host_os in
682 # NOTE: Even if one omits -gnu on GNU/Linux (e.g.
683 # i486-slackware-linux), configure will (via config.sub)
684 # append -gnu (e.g. i486-slackware-linux-gnu), and this
685 # test will work correctly.
686 gnu* | *-gnu* | freebsd*)
687 enable_symbol_versions=yes
688 ;;
689 *)
690 enable_symbol_versions=no
691 ;;
692 esac
693 fi
695 # There are two variants for symbol versioning.
696 # See src/liblzma/validate_map.sh for details.
697 #
698 # On GNU/Linux, extra symbols are added in the C code. These extra symbols
699 # must not be put into a static library as they can cause problems (and
700 # even if they didn't cause problems, they would be useless). On other
701 # systems symbol versioning may be used too but there is no problem as only
702 # a linker script is specified in src/liblzma/Makefile.am and that isn't
703 # used when creating a static library.
704 #
705 # Libtool always uses -DPIC when building shared libraries by default and
706 # doesn't use it for static libs by default. This can be overridden with
707 # --with-pic and --without-pic though. As long as neither --with-pic nor
708 # --without-pic is used then we can use #ifdef PIC to detect if the file is
709 # being built for a shared library.
710 if test "x$enable_symbol_versions" = xno ; then
711 enable_symbol_versions=no
712 AC_MSG_RESULT([no])
713 elif test "x$enable_shared" = xno ; then
714 enable_symbol_versions=no
715 AC_MSG_RESULT([no (not building a shared library)])
716 else
717 case "$host_cpu-$host_os" in
718 microblaze*)
719 # GCC 12 on MicroBlaze doesn't support __symver__
720 # attribute. It's simplest and safest to use the
721 # generic version on that platform since then only
722 # the linker script is needed. The RHEL/CentOS 7
723 # compatibility symbols don't matter on MicroBlaze.
724 enable_symbol_versions=generic
725 ;;
726 *-linux*)
727 case "$pic_mode-$enable_static" in
728 default-*)
729 # Use symvers if PIC is defined.
730 have_symbol_versions_linux=2
731 ;;
732 *-no)
733 # Not building static library.
734 # Use symvers unconditionally.
735 have_symbol_versions_linux=1
736 ;;
737 *)
738 AC_MSG_RESULT([])
739 AC_MSG_ERROR([
740 On GNU/Linux, building both shared and static library at the same time
741 is not supported if --with-pic or --without-pic is used.
742 Use either --disable-shared or --disable-static to build one type
743 of library at a time. If both types are needed, build one at a time,
744 possibly picking only src/liblzma/.libs/liblzma.a from the static build.])
745 ;;
746 esac
747 enable_symbol_versions=linux
748 AC_DEFINE_UNQUOTED([HAVE_SYMBOL_VERSIONS_LINUX],
749 [$have_symbol_versions_linux],
750 [Define to 1 to if GNU/Linux-specific details
751 are unconditionally wanted for symbol
752 versioning. Define to 2 to if these are wanted
753 only if also PIC is defined (allows building
754 both shared and static liblzma at the same
755 time with Libtool if neither --with-pic nor
756 --without-pic is used). This define must be
757 used together with liblzma_linux.map.])
758 ;;
759 *)
760 enable_symbol_versions=generic
761 ;;
762 esac
763 AC_MSG_RESULT([yes ($enable_symbol_versions)])
764 fi
766 AM_CONDITIONAL([COND_SYMVERS_LINUX],
767 [test "x$enable_symbol_versions" = xlinux])
768 AM_CONDITIONAL([COND_SYMVERS_GENERIC],
769 [test "x$enable_symbol_versions" = xgeneric])
772 ###############################################################################
773 # Checks for libraries.
774 ###############################################################################
776 dnl Support for _REQUIRE_VERSION was added in gettext 0.19.6. If both
777 dnl _REQUIRE_VERSION and _VERSION are present, the _VERSION is ignored.
778 dnl We use both for compatibility with other programs in the Autotools family.
779 echo
780 echo "Initializing gettext:"
781 AM_GNU_GETTEXT_REQUIRE_VERSION([0.19.6])
782 AM_GNU_GETTEXT_VERSION([0.19.6])
783 AM_GNU_GETTEXT([external])
786 ###############################################################################
787 # Checks for header files.
788 ###############################################################################
790 echo
791 echo "System headers and functions:"
793 # There is currently no workarounds in this package if some of
794 # these headers are missing.
795 AC_CHECK_HEADERS([fcntl.h limits.h sys/time.h],
796 [],
797 [AC_MSG_ERROR([Required header file(s) are missing.])])
799 # immintrin.h allows the use of the intrinsic functions if they are available.
800 # cpuid.h may be used for detecting x86 processor features at runtime.
801 AC_CHECK_HEADERS([immintrin.h cpuid.h])
804 ###############################################################################
805 # Checks for typedefs, structures, and compiler characteristics.
806 ###############################################################################
808 AC_HEADER_STDBOOL
810 AC_TYPE_UINT8_T
811 AC_TYPE_UINT16_T
812 AC_TYPE_INT32_T
813 AC_TYPE_UINT32_T
814 AC_TYPE_INT64_T
815 AC_TYPE_UINT64_T
816 AC_TYPE_UINTPTR_T
818 AC_CHECK_SIZEOF([size_t])
820 # The command line tool can copy high resolution timestamps if such
821 # information is available in struct stat. Otherwise one second accuracy
822 # is used.
823 AC_CHECK_MEMBERS([
824 struct stat.st_atim.tv_nsec,
825 struct stat.st_atimespec.tv_nsec,
826 struct stat.st_atimensec,
827 struct stat.st_uatime,
828 struct stat.st_atim.st__tim.tv_nsec])
830 AC_SYS_LARGEFILE
831 AC_C_BIGENDIAN
833 # __attribute__((__constructor__)) can be used for one-time initializations.
834 # Use -Werror because some compilers accept unknown attributes and just
835 # give a warning. If it works this should give no warnings, even
836 # clang -Weverything should be fine.
837 # dnl This doesn't need AC_LANG_SOURCE, minimal code is enough.
838 AC_MSG_CHECKING([if __attribute__((__constructor__)) can be used])
839 have_func_attribute_constructor=no
840 OLD_CFLAGS="$CFLAGS"
841 CFLAGS="$CFLAGS -Werror"
842 AC_COMPILE_IFELSE([
843 __attribute__((__constructor__))
844 static void my_constructor_func(void) { return; }
845 ], [
846 AC_DEFINE([HAVE_FUNC_ATTRIBUTE_CONSTRUCTOR], [1],
847 [Define to 1 if __attribute__((__constructor__))
848 is supported for functions.])
849 have_func_attribute_constructor=yes
850 AC_MSG_RESULT([yes])
851 ], [
852 AC_MSG_RESULT([no])
853 ])
854 CFLAGS="$OLD_CFLAGS"
856 # The Win95 threading lacks a thread-safe one-time initialization function.
857 # The one-time initialization is needed for crc32_small.c and crc64_small.c
858 # create the CRC tables. So if small mode is enabled, the threading mode is
859 # win95, and the compiler does not support attribute constructor, then we
860 # would end up with a multithreaded build that is thread-unsafe. As a
861 # result this configuration is not allowed.
862 if test "x$enable_small$enable_threads$have_func_attribute_constructor"\
863 = xyeswin95no; then
864 AC_MSG_ERROR([--enable-threads=win95 and --enable-small cannot be
865 used at the same time with a compiler that doesn't support
866 __attribute__((__constructor__))])
867 fi
869 # __attribute__((__ifunc__())) can be used to choose between different
870 # implementations of the same function at runtime. This is slightly more
871 # efficient than using __attribute__((__constructor__)) and setting
872 # a function pointer.
873 AC_ARG_ENABLE([ifunc], [AS_HELP_STRING([--disable-ifunc],
874 [do not use __attribute__((__ifunc__()))])],
875 [], [enable_ifunc=yes])
877 if test "x$enable_ifunc" = xyes ; then
878 OLD_CFLAGS="$CFLAGS"
879 CFLAGS="$CFLAGS -Werror"
880 AC_MSG_CHECKING([if __attribute__((__ifunc__())) can be used])
881 AC_COMPILE_IFELSE([
882 static void func(void) { return; }
883 static void (*resolve_func (void)) (void) { return func; }
884 void func_ifunc (void)
885 __attribute__((__ifunc__("resolve_func")));
886 ], [
887 AC_DEFINE([HAVE_FUNC_ATTRIBUTE_IFUNC], [1],
888 [Define to 1 if __attribute__((__ifunc__()))
889 is supported for functions.])
890 AC_MSG_RESULT([yes])
891 ], [
892 AC_MSG_RESULT([no])
893 ])
895 CFLAGS="$OLD_CFLAGS"
896 fi
899 ###############################################################################
900 # Checks for library functions.
901 ###############################################################################
903 # Gnulib replacements as needed
904 gl_GETOPT
906 # Find the best function to set timestamps.
907 AC_CHECK_FUNCS([futimens futimes futimesat utimes _futime utime], [break])
909 # This is nice to have but not mandatory.
910 AC_CHECK_FUNCS([posix_fadvise])
912 TUKLIB_PROGNAME
913 TUKLIB_INTEGER
914 TUKLIB_PHYSMEM
915 TUKLIB_CPUCORES
916 TUKLIB_MBSTR
918 # If requested, check for system-provided SHA-256. At least the following
919 # implementations are supported:
920 #
921 # OS Headers Library Type Function
922 # FreeBSD sys/types.h + sha256.h libmd SHA256_CTX SHA256_Init
923 # NetBSD sys/types.h + sha2.h SHA256_CTX SHA256_Init
924 # OpenBSD sys/types.h + sha2.h SHA2_CTX SHA256Init
925 # Solaris sys/types.h + sha2.h libmd SHA256_CTX SHA256Init
926 # MINIX 3 sys/types.h + sha2.h SHA256_CTX SHA256_Init
927 # Darwin CommonCrypto/CommonDigest.h CC_SHA256_CTX CC_SHA256_Init
928 #
929 # Note that Darwin's CC_SHA256_Update takes buffer size as uint32_t instead
930 # of size_t.
931 #
932 sha256_header_found=no
933 sha256_type_found=no
934 sha256_func_found=no
935 AS_IF([test "x$enable_external_sha256" = "xyes"], [
936 # Test for Common Crypto before others, because Darwin has sha256.h
937 # too and we don't want to use that, because on older versions it
938 # uses OpenSSL functions, whose SHA256_Init is not guaranteed to
939 # succeed.
940 AC_CHECK_HEADERS(
941 [CommonCrypto/CommonDigest.h sha256.h sha2.h],
942 [sha256_header_found=yes ; break])
943 if test "x$sha256_header_found" = xyes; then
944 AC_CHECK_TYPES([CC_SHA256_CTX, SHA256_CTX, SHA2_CTX],
945 [sha256_type_found=yes], [],
946 [[#ifdef HAVE_SYS_TYPES_H
947 # include <sys/types.h>
948 #endif
949 #ifdef HAVE_COMMONCRYPTO_COMMONDIGEST_H
950 # include <CommonCrypto/CommonDigest.h>
951 #endif
952 #ifdef HAVE_SHA256_H
953 # include <sha256.h>
954 #endif
955 #ifdef HAVE_SHA2_H
956 # include <sha2.h>
957 #endif]])
958 if test "x$sha256_type_found" = xyes ; then
959 AC_SEARCH_LIBS([SHA256Init], [md])
960 AC_SEARCH_LIBS([SHA256_Init], [md])
961 AC_CHECK_FUNCS([CC_SHA256_Init SHA256Init SHA256_Init],
962 [sha256_func_found=yes ; break])
963 fi
964 fi
965 ])
966 AM_CONDITIONAL([COND_INTERNAL_SHA256], [test "x$sha256_func_found" = xno])
967 if test "x$enable_external_sha256$sha256_func_found" = xyesno; then
968 AC_MSG_ERROR([--enable-external-sha256 was specified but no supported external SHA-256 implementation was found])
969 fi
971 # Check for SSE2 intrinsics. There is no run-time detection for SSE2 so if
972 # compiler options enable SSE2 then SSE2 support is required by the binaries.
973 # The compile-time check for SSE2 is done with #ifdefs because some compilers
974 # (ICC, MSVC) allow SSE2 intrinsics even when SSE2 isn't enabled.
975 AC_CHECK_DECL([_mm_movemask_epi8],
976 [AC_DEFINE([HAVE__MM_MOVEMASK_EPI8], [1],
977 [Define to 1 if _mm_movemask_epi8 is available.])],
978 [],
979 [#ifdef HAVE_IMMINTRIN_H
980 #include <immintrin.h>
981 #endif])
983 # For faster CRC on 32/64-bit x86 and E2K (see also crc64_fast.c):
984 #
985 # - Check for the CLMUL intrinsic _mm_clmulepi64_si128 in <immintrin.h>.
986 # Check also for _mm_set_epi64x for consistency with CMake build
987 # where it's needed to disable CLMUL with VS2013.
988 #
989 # - Check that __attribute__((__target__("ssse3,sse4.1,pclmul"))) works
990 # together with _mm_clmulepi64_si128 from <immintrin.h>. The attribute
991 # was added in GCC 4.4 but some GCC 4.x versions don't allow intrinsics
992 # with it. Exception: it must be not be used with EDG-based compilers
993 # like ICC and the compiler on E2K.
994 #
995 # If everything above is supported, runtime detection will be used to keep the
996 # binaries working on systems that don't support the required extensions.
997 AC_MSG_CHECKING([if _mm_clmulepi64_si128 is usable])
998 AS_IF([test "x$enable_clmul_crc" = xno], [
999 AC_MSG_RESULT([no, --disable-clmul-crc was used])
1000 ], [
1001 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1002 #include <immintrin.h>
1004 // CLMUL works on older E2K instruction set but it is slow due to emulation.
1005 #if defined(__e2k__) && __iset__ < 6
1006 # error
1007 #endif
1009 // Intel's old compiler (ICC) can define __GNUC__ but the attribute must not
1010 // be used with it. The new Clang-based ICX needs the attribute.
1011 // Checking for !defined(__EDG__) catches ICC and other EDG-based compilers.
1012 #if (defined(__GNUC__) || defined(__clang__)) && !defined(__EDG__)
1013 __attribute__((__target__("ssse3,sse4.1,pclmul")))
1014 #endif
1015 __m128i my_clmul(__m128i a)
1016 {
1017 const __m128i b = _mm_set_epi64x(1, 2);
1018 return _mm_clmulepi64_si128(a, b, 0);
1019 }
1020 ]])], [
1021 AC_DEFINE([HAVE_USABLE_CLMUL], [1],
1022 [Define to 1 if _mm_set_epi64x and
1023 _mm_clmulepi64_si128 are usable.
1024 See configure.ac for details.])
1025 AC_MSG_RESULT([yes])
1026 ], [
1027 AC_MSG_RESULT([no])
1028 ])
1029 ])
1031 # Check for sandbox support. If one is found, set enable_sandbox=found.
1032 AS_CASE([$enable_sandbox],
1033 [auto | capsicum], [
1034 AX_CHECK_CAPSICUM([enable_sandbox=found], [:])
1035 ]
1036 )
1037 AS_CASE([$enable_sandbox],
1038 [auto | pledge], [
1039 AC_CHECK_FUNCS([pledge], [enable_sandbox=found ; break])
1040 ]
1041 )
1043 # If a specific sandboxing method was explicitly requested and it wasn't
1044 # found, give an error.
1045 case $enable_sandbox in
1046 auto | no | found)
1047 ;;
1048 *)
1049 AC_MSG_ERROR([$enable_sandbox support not found])
1050 ;;
1051 esac
1054 ###############################################################################
1055 # If using GCC, set some additional AM_CFLAGS:
1056 ###############################################################################
1058 if test "$GCC" = yes ; then
1059 echo
1060 echo "GCC extensions:"
1061 fi
1063 # Always do the visibility check but don't set AM_CFLAGS on Windows.
1064 # This way things get set properly even on Windows.
1065 gl_VISIBILITY
1066 if test -n "$CFLAG_VISIBILITY" && test "$is_w32" = no; then
1067 AM_CFLAGS="$AM_CFLAGS $CFLAG_VISIBILITY"
1068 fi
1070 AS_IF([test "$GCC" = yes], [
1071 # Enable as much warnings as possible. These commented warnings won't
1072 # work for this package though:
1073 # * -Wunreachable-code breaks several assert(0) cases, which are
1074 # backed up with "return LZMA_PROG_ERROR".
1075 # * -Wcast-qual would break various things where we need a non-const
1076 # pointer although we don't modify anything through it.
1077 # * -Winline, -Wdisabled-optimization, -Wunsafe-loop-optimizations
1078 # don't seem so useful here; at least the last one gives some
1079 # warnings which are not bugs.
1080 # * -Wconversion still shows too many warnings.
1081 #
1082 # The flags before the empty line are for GCC and many of them
1083 # are supported by Clang too. The flags after the empty line are
1084 # for Clang.
1085 for NEW_FLAG in \
1086 -Wall \
1087 -Wextra \
1088 -Wvla \
1089 -Wc99-c11-compat \
1090 -Wformat=2 \
1091 -Winit-self \
1092 -Wmissing-include-dirs \
1093 -Wshift-overflow=2 \
1094 -Wstrict-overflow=3 \
1095 -Walloc-zero \
1096 -Wduplicated-cond \
1097 -Wfloat-equal \
1098 -Wundef \
1099 -Wshadow \
1100 -Wpointer-arith \
1101 -Wbad-function-cast \
1102 -Wwrite-strings \
1103 -Wdate-time \
1104 -Wsign-conversion \
1105 -Wfloat-conversion \
1106 -Wlogical-op \
1107 -Waggregate-return \
1108 -Wstrict-prototypes \
1109 -Wold-style-definition \
1110 -Wmissing-prototypes \
1111 -Wmissing-declarations \
1112 -Wredundant-decls \
1113 \
1114 -Wc99-compat \
1115 -Wc11-extensions \
1116 -Wc2x-compat \
1117 -Wc2x-extensions \
1118 -Wpre-c2x-compat \
1119 -Warray-bounds-pointer-arithmetic \
1120 -Wassign-enum \
1121 -Wconditional-uninitialized \
1122 -Wdocumentation \
1123 -Wduplicate-enum \
1124 -Wempty-translation-unit \
1125 -Wflexible-array-extensions \
1126 -Wmissing-variable-declarations \
1127 -Wnewline-eof \
1128 -Wshift-sign-overflow \
1129 -Wstring-conversion
1130 do
1131 AC_MSG_CHECKING([if $CC accepts $NEW_FLAG])
1132 OLD_CFLAGS="$CFLAGS"
1133 CFLAGS="$CFLAGS $NEW_FLAG -Werror"
1134 AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1135 [void foo(void); void foo(void) { }])], [
1136 AM_CFLAGS="$AM_CFLAGS $NEW_FLAG"
1137 AC_MSG_RESULT([yes])
1138 ], [
1139 AC_MSG_RESULT([no])
1140 ])
1141 CFLAGS="$OLD_CFLAGS"
1142 done
1144 AC_ARG_ENABLE([werror],
1145 AS_HELP_STRING([--enable-werror], [Enable -Werror to abort
1146 compilation on all compiler warnings.]),
1147 [], [enable_werror=no])
1148 if test "x$enable_werror" = "xyes"; then
1149 AM_CFLAGS="$AM_CFLAGS -Werror"
1150 fi
1151 ])
1154 ###############################################################################
1155 # Create the makefiles and config.h
1156 ###############################################################################
1158 echo
1160 # Don't build the lib directory at all if we don't need any replacement
1161 # functions.
1162 AM_CONDITIONAL([COND_GNULIB], test -n "$LIBOBJS")
1164 # Add default AM_CFLAGS.
1165 AC_SUBST([AM_CFLAGS])
1167 # This is needed for src/scripts.
1168 xz=`echo xz | sed "$program_transform_name"`
1169 AC_SUBST([xz])
1171 AC_CONFIG_FILES([
1172 Makefile
1173 po/Makefile.in
1174 lib/Makefile
1175 src/Makefile
1176 src/liblzma/Makefile
1177 src/liblzma/api/Makefile
1178 src/xz/Makefile
1179 src/xzdec/Makefile
1180 src/lzmainfo/Makefile
1181 src/scripts/Makefile
1182 tests/Makefile
1183 debug/Makefile
1184 ])
1185 AC_CONFIG_FILES([src/scripts/xzdiff], [chmod +x src/scripts/xzdiff])
1186 AC_CONFIG_FILES([src/scripts/xzgrep], [chmod +x src/scripts/xzgrep])
1187 AC_CONFIG_FILES([src/scripts/xzmore], [chmod +x src/scripts/xzmore])
1188 AC_CONFIG_FILES([src/scripts/xzless], [chmod +x src/scripts/xzless])
1190 AC_OUTPUT
1192 # Some warnings
1193 if test x$tuklib_cv_physmem_method = xunknown; then
1194 echo
1195 echo "WARNING:"
1196 echo "No supported method to detect the amount of RAM."
1197 echo "Consider using --enable-assume-ram (if you didn't already)"
1198 echo "or make a patch to add support for this operating system."
1199 fi
1201 if test x$tuklib_cv_cpucores_method = xunknown; then
1202 echo
1203 echo "WARNING:"
1204 echo "No supported method to detect the number of CPU cores."
1205 fi
1207 if test "x$enable_threads$enable_small$have_func_attribute_constructor" \
1208 = xnoyesno; then
1209 echo
1210 echo "NOTE:"
1211 echo "liblzma will be thread-unsafe due to the combination"
1212 echo "of --disable-threads --enable-small when using a compiler"
1213 echo "that doesn't support __attribute__((__constructor__))."
1214 fi