| blob | 3676cd037de51bad69f7ef70d41c1a723b794940 |
1 # -*- Autoconf -*-
2 # SPDX-License-Identifier: 0BSD
4 ###############################################################################
5 #
6 # Process this file with autoconf to produce a configure script.
7 #
8 # Author: Lasse Collin
9 #
10 ###############################################################################
12 # NOTE: Don't add useless checks. autoscan detects this and that, but don't
13 # let it confuse you. For example, we don't care about checking for behavior
14 # of malloc(), stat(), or lstat(), since we don't use those functions in
15 # a way that would cause the problems the autoconf macros check.
17 AC_PREREQ([2.69])
19 AC_INIT([XZ Utils], m4_esyscmd([/bin/sh build-aux/version.sh]),
20 [xz@tukaani.org], [xz], [https://xz.tukaani.org/xz-utils/])
21 AC_CONFIG_SRCDIR([src/liblzma/common/common.h])
22 AC_CONFIG_AUX_DIR([build-aux])
23 AC_CONFIG_MACRO_DIR([m4])
24 AC_CONFIG_HEADERS([config.h])
26 echo
27 echo "$PACKAGE_STRING"
29 echo
30 echo "System type:"
31 # This is needed to know if assembler optimizations can be used.
32 AC_CANONICAL_HOST
34 # We do some special things on Windows (32-bit or 64-bit) builds.
35 case $host_os in
36 mingw* | cygwin | msys) is_w32=yes ;;
37 *) is_w32=no ;;
38 esac
39 AM_CONDITIONAL([COND_W32], [test "$is_w32" = yes])
41 # We need to use $EXEEXT with $(LN_S) when creating symlinks to
42 # executables. Cygwin is an exception to this, since it is recommended
43 # that symlinks don't have the .exe suffix. To make this work, we
44 # define LN_EXEEXT.
45 #
46 # MSYS2 is treated the same way as Cygwin. It uses plain "msys" like
47 # the original MSYS when building MSYS/MSYS2-binaries. Hopefully this
48 # doesn't break things for the original MSYS developers. Note that this
49 # doesn't affect normal MSYS/MSYS2 users building non-MSYS/MSYS2 binaries
50 # since in that case the $host_os is usually mingw32.
51 case $host_os in
52 cygwin | msys) LN_EXEEXT= ;;
53 *) LN_EXEEXT='$(EXEEXT)' ;;
54 esac
55 AC_SUBST([LN_EXEEXT])
57 echo
58 echo "Configure options:"
59 AM_CFLAGS=
62 #############
63 # Debugging #
64 #############
66 AC_MSG_CHECKING([if debugging code should be compiled])
67 AC_ARG_ENABLE([debug], AS_HELP_STRING([--enable-debug], [Enable debugging code.]),
68 [], enable_debug=no)
69 if test "x$enable_debug" = xyes; then
70 AC_MSG_RESULT([yes])
71 else
72 AC_DEFINE([NDEBUG], [1], [Define to 1 to disable debugging code.])
73 AC_MSG_RESULT([no])
74 fi
77 ###########
78 # Filters #
79 ###########
81 m4_define([SUPPORTED_FILTERS], [lzma1,lzma2,delta,x86,powerpc,ia64,arm,armthumb,arm64,sparc,riscv])dnl
82 m4_define([SIMPLE_FILTERS], [x86,powerpc,ia64,arm,armthumb,arm64,sparc,riscv])
83 m4_define([LZ_FILTERS], [lzma1,lzma2])
85 m4_foreach([NAME], [SUPPORTED_FILTERS],
86 [enable_filter_[]NAME=no
87 enable_encoder_[]NAME=no
88 enable_decoder_[]NAME=no
89 ])dnl
91 AC_MSG_CHECKING([which encoders to build])
92 AC_ARG_ENABLE([encoders], AS_HELP_STRING([--enable-encoders=LIST],
93 [Comma-separated list of encoders to build. Default=all.
94 Available encoders:]
95 m4_translit(m4_defn([SUPPORTED_FILTERS]), [,], [ ])),
96 [], [enable_encoders=SUPPORTED_FILTERS])
97 enable_encoders=`echo "$enable_encoders" | sed 's/,/ /g'`
98 if test "x$enable_encoders" = xno || test "x$enable_encoders" = x; then
99 enable_encoders=no
100 AC_MSG_RESULT([(none)])
101 else
102 for arg in $enable_encoders
103 do
104 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
105 NAME)
106 enable_filter_[]NAME=yes
107 enable_encoder_[]NAME=yes
108 AC_DEFINE(HAVE_ENCODER_[]m4_toupper(NAME), [1],
109 [Define to 1 if] NAME [encoder is enabled.])
110 ;;])
111 *)
112 AC_MSG_RESULT([])
113 AC_MSG_ERROR([unknown filter: $arg])
114 ;;
115 esac
116 done
117 AC_DEFINE([HAVE_ENCODERS], [1],
118 [Define to 1 if any of HAVE_ENCODER_foo have been defined.])
119 AC_MSG_RESULT([$enable_encoders])
120 fi
122 AC_MSG_CHECKING([which decoders to build])
123 AC_ARG_ENABLE([decoders], AS_HELP_STRING([--enable-decoders=LIST],
124 [Comma-separated list of decoders to build. Default=all.
125 Available decoders are the same as available encoders.]),
126 [], [enable_decoders=SUPPORTED_FILTERS])
127 enable_decoders=`echo "$enable_decoders" | sed 's/,/ /g'`
128 if test "x$enable_decoders" = xno || test "x$enable_decoders" = x; then
129 enable_decoders=no
130 AC_MSG_RESULT([(none)])
131 else
132 for arg in $enable_decoders
133 do
134 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
135 NAME)
136 enable_filter_[]NAME=yes
137 enable_decoder_[]NAME=yes
138 AC_DEFINE(HAVE_DECODER_[]m4_toupper(NAME), [1],
139 [Define to 1 if] NAME [decoder is enabled.])
140 ;;])
141 *)
142 AC_MSG_RESULT([])
143 AC_MSG_ERROR([unknown filter: $arg])
144 ;;
145 esac
146 done
147 AC_DEFINE([HAVE_DECODERS], [1],
148 [Define to 1 if any of HAVE_DECODER_foo have been defined.])
149 AC_MSG_RESULT([$enable_decoders])
150 fi
152 if test "x$enable_encoder_lzma2$enable_encoder_lzma1" = xyesno \
153 || test "x$enable_decoder_lzma2$enable_decoder_lzma1" = xyesno; then
154 AC_MSG_ERROR([LZMA2 requires that LZMA1 is also enabled.])
155 fi
157 AM_CONDITIONAL(COND_MAIN_ENCODER, test "x$enable_encoders" != xno)
158 AM_CONDITIONAL(COND_MAIN_DECODER, test "x$enable_decoders" != xno)
160 m4_foreach([NAME], [SUPPORTED_FILTERS],
161 [AM_CONDITIONAL(COND_FILTER_[]m4_toupper(NAME), test "x$enable_filter_[]NAME" = xyes)
162 AM_CONDITIONAL(COND_ENCODER_[]m4_toupper(NAME), test "x$enable_encoder_[]NAME" = xyes)
163 AM_CONDITIONAL(COND_DECODER_[]m4_toupper(NAME), test "x$enable_decoder_[]NAME" = xyes)
164 ])dnl
166 # The so called "simple filters" share common code.
167 enable_filter_simple=no
168 enable_encoder_simple=no
169 enable_decoder_simple=no
170 m4_foreach([NAME], [SIMPLE_FILTERS],
171 [test "x$enable_filter_[]NAME" = xyes && enable_filter_simple=yes
172 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_simple=yes
173 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_simple=yes
174 ])dnl
175 AM_CONDITIONAL(COND_FILTER_SIMPLE, test "x$enable_filter_simple" = xyes)
176 AM_CONDITIONAL(COND_ENCODER_SIMPLE, test "x$enable_encoder_simple" = xyes)
177 AM_CONDITIONAL(COND_DECODER_SIMPLE, test "x$enable_decoder_simple" = xyes)
179 # LZ-based filters share common code.
180 enable_filter_lz=no
181 enable_encoder_lz=no
182 enable_decoder_lz=no
183 m4_foreach([NAME], [LZ_FILTERS],
184 [test "x$enable_filter_[]NAME" = xyes && enable_filter_lz=yes
185 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_lz=yes
186 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_lz=yes
187 ])dnl
188 AM_CONDITIONAL(COND_FILTER_LZ, test "x$enable_filter_lz" = xyes)
189 AM_CONDITIONAL(COND_ENCODER_LZ, test "x$enable_encoder_lz" = xyes)
190 AM_CONDITIONAL(COND_DECODER_LZ, test "x$enable_decoder_lz" = xyes)
193 #################
194 # Match finders #
195 #################
197 m4_define([SUPPORTED_MATCH_FINDERS], [hc3,hc4,bt2,bt3,bt4])
199 m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS],
200 [enable_match_finder_[]NAME=no
201 ])
203 AC_MSG_CHECKING([which match finders to build])
204 AC_ARG_ENABLE([match-finders], AS_HELP_STRING([--enable-match-finders=LIST],
205 [Comma-separated list of match finders to build. Default=all.
206 At least one match finder is required for encoding with
207 the LZMA1 and LZMA2 filters. Available match finders:]
208 m4_translit(m4_defn([SUPPORTED_MATCH_FINDERS]), [,], [ ])), [],
209 [enable_match_finders=SUPPORTED_MATCH_FINDERS])
210 enable_match_finders=`echo "$enable_match_finders" | sed 's/,/ /g'`
211 if test "x$enable_encoder_lz" = xyes ; then
212 if test -z "$enable_match_finders"; then
213 AC_MSG_ERROR([At least one match finder is required for an LZ-based encoder.])
214 fi
216 for arg in $enable_match_finders
217 do
218 case $arg in m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS], [
219 NAME)
220 enable_match_finder_[]NAME=yes
221 AC_DEFINE(HAVE_MF_[]m4_toupper(NAME), [1],
222 [Define to 1 to enable] NAME [match finder.])
223 ;;])
224 *)
225 AC_MSG_RESULT([])
226 AC_MSG_ERROR([unknown match finder: $arg])
227 ;;
228 esac
229 done
230 AC_MSG_RESULT([$enable_match_finders])
231 else
232 AC_MSG_RESULT([(none because not building any LZ-based encoder)])
233 fi
236 ####################
237 # Integrity checks #
238 ####################
240 m4_define([SUPPORTED_CHECKS], [crc32,crc64,sha256])
242 m4_foreach([NAME], [SUPPORTED_CHECKS],
243 [enable_check_[]NAME=no
244 ])dnl
246 AC_MSG_CHECKING([which integrity checks to build])
247 AC_ARG_ENABLE([checks], AS_HELP_STRING([--enable-checks=LIST],
248 [Comma-separated list of integrity checks to build.
249 Default=all. Available integrity checks:]
250 m4_translit(m4_defn([SUPPORTED_CHECKS]), [,], [ ])),
251 [], [enable_checks=SUPPORTED_CHECKS])
252 enable_checks=`echo "$enable_checks" | sed 's/,/ /g'`
253 if test "x$enable_checks" = xno || test "x$enable_checks" = x; then
254 AC_MSG_RESULT([(none)])
255 else
256 for arg in $enable_checks
257 do
258 case $arg in m4_foreach([NAME], [SUPPORTED_CHECKS], [
259 NAME)
260 enable_check_[]NAME=yes
261 AC_DEFINE(HAVE_CHECK_[]m4_toupper(NAME), [1],
262 [Define to 1 if] NAME
263 [integrity check is enabled.])
264 ;;])
265 *)
266 AC_MSG_RESULT([])
267 AC_MSG_ERROR([unknown integrity check: $arg])
268 ;;
269 esac
270 done
271 AC_MSG_RESULT([$enable_checks])
272 fi
273 if test "x$enable_check_crc32" = xno ; then
274 AC_MSG_ERROR([For now, the CRC32 check must always be enabled.])
275 fi
277 m4_foreach([NAME], [SUPPORTED_CHECKS],
278 [AM_CONDITIONAL(COND_CHECK_[]m4_toupper(NAME), test "x$enable_check_[]NAME" = xyes)
279 ])dnl
281 AC_MSG_CHECKING([if external SHA-256 should be used])
282 AC_ARG_ENABLE([external-sha256], AS_HELP_STRING([--enable-external-sha256],
283 [Use SHA-256 code from the operating system.
284 See INSTALL for possible subtle problems.]),
285 [], [enable_external_sha256=no])
286 if test "x$enable_check_sha256" != "xyes"; then
287 enable_external_sha256=no
288 fi
289 if test "x$enable_external_sha256" = xyes; then
290 AC_MSG_RESULT([yes])
291 else
292 AC_MSG_RESULT([no])
293 fi
296 #############
297 # MicroLZMA #
298 #############
300 AC_MSG_CHECKING([if MicroLZMA support should be built])
301 AC_ARG_ENABLE([microlzma], AS_HELP_STRING([--disable-microlzma],
302 [Do not build MicroLZMA encoder and decoder.
303 It is needed by specific applications only,
304 for example, erofs-utils.]),
305 [], [enable_microlzma=yes])
306 case $enable_microlzma in
307 yes)
308 AC_DEFINE([HAVE_MICROLZMA], [1],
309 [Define to 1 if MicroLZMA support is enabled.])
310 AC_MSG_RESULT([yes])
311 ;;
312 no)
313 AC_MSG_RESULT([no])
314 ;;
315 *)
316 AC_MSG_RESULT([])
317 AC_MSG_ERROR([--enable-microlzma accepts only 'yes' or 'no'.])
318 ;;
319 esac
320 AM_CONDITIONAL(COND_MICROLZMA, test "x$enable_microlzma" = xyes)
323 #############################
324 # .lz (lzip) format support #
325 #############################
327 AC_MSG_CHECKING([if .lz (lzip) decompression support should be built])
328 AC_ARG_ENABLE([lzip-decoder], AS_HELP_STRING([--disable-lzip-decoder],
329 [Disable decompression support for .lz (lzip) files.]),
330 [], [enable_lzip_decoder=yes])
331 if test "x$enable_decoder_lzma1" != xyes; then
332 enable_lzip_decoder=no
333 AC_MSG_RESULT([no because LZMA1 decoder is disabled])
334 elif test "x$enable_lzip_decoder" = xyes; then
335 AC_DEFINE([HAVE_LZIP_DECODER], [1],
336 [Define to 1 if .lz (lzip) decompression support is enabled.])
337 AC_MSG_RESULT([yes])
338 else
339 AC_MSG_RESULT([no])
340 fi
341 AM_CONDITIONAL(COND_LZIP_DECODER, test "x$enable_lzip_decoder" = xyes)
344 ###########################
345 # Assembler optimizations #
346 ###########################
348 AC_MSG_CHECKING([if assembler optimizations should be used])
349 AC_ARG_ENABLE([assembler], AS_HELP_STRING([--disable-assembler],
350 [Do not use assembler optimizations even if such exist
351 for the architecture.]),
352 [], [enable_assembler=yes])
353 if test "x$enable_assembler" = xyes; then
354 enable_assembler=no
355 case $host_os in
356 # Darwin should work too but only if not creating universal
357 # binaries. Solaris x86 could work too but I cannot test.
358 linux* | *bsd* | mingw* | cygwin | msys | *djgpp*)
359 case $host_cpu in
360 i?86) enable_assembler=x86 ;;
361 esac
362 ;;
363 esac
364 fi
365 case $enable_assembler in
366 x86 | no)
367 AC_MSG_RESULT([$enable_assembler])
368 ;;
369 *)
370 AC_MSG_RESULT([])
371 AC_MSG_ERROR([--enable-assembler accepts only 'yes', 'no', or 'x86' (32-bit).])
372 ;;
373 esac
374 AM_CONDITIONAL(COND_ASM_X86, test "x$enable_assembler" = xx86)
377 #############
378 # CLMUL CRC #
379 #############
381 AC_ARG_ENABLE([clmul-crc], AS_HELP_STRING([--disable-clmul-crc],
382 [Do not use carryless multiplication for CRC calculation
383 even if support for it is detected.]),
384 [], [enable_clmul_crc=yes])
387 ############################
388 # ARM64 CRC32 Instructions #
389 ############################
391 AC_ARG_ENABLE([arm64-crc32], AS_HELP_STRING([--disable-arm64-crc32],
392 [Do not use ARM64 CRC32 instructions even if support for it
393 is detected.]),
394 [], [enable_arm64_crc32=yes])
397 #####################
398 # Size optimization #
399 #####################
401 AC_MSG_CHECKING([if small size is preferred over speed])
402 AC_ARG_ENABLE([small], AS_HELP_STRING([--enable-small],
403 [Make liblzma smaller and a little slower.
404 This is disabled by default to optimize for speed.]),
405 [], [enable_small=no])
406 if test "x$enable_small" = xyes; then
407 AC_DEFINE([HAVE_SMALL], [1], [Define to 1 if optimizing for size.])
408 elif test "x$enable_small" != xno; then
409 AC_MSG_RESULT([])
410 AC_MSG_ERROR([--enable-small accepts only 'yes' or 'no'])
411 fi
412 AC_MSG_RESULT([$enable_small])
413 AM_CONDITIONAL(COND_SMALL, test "x$enable_small" = xyes)
416 #############
417 # Threading #
418 #############
420 AC_MSG_CHECKING([if threading support is wanted])
421 AC_ARG_ENABLE([threads], AS_HELP_STRING([--enable-threads=METHOD],
422 [Supported METHODS are 'yes', 'no', 'posix', 'win95', and
423 'vista'. The default is 'yes'. Using 'no' together with
424 --enable-small makes liblzma thread unsafe.]),
425 [], [enable_threads=yes])
427 if test "x$enable_threads" = xyes; then
428 case $host_os in
429 mingw*)
430 case $host_cpu in
431 i?86) enable_threads=win95 ;;
432 *) enable_threads=vista ;;
433 esac
434 ;;
435 *)
436 enable_threads=posix
437 ;;
438 esac
439 fi
441 case $enable_threads in
442 posix | win95 | vista)
443 AC_MSG_RESULT([yes, $enable_threads])
444 ;;
445 no)
446 AC_MSG_RESULT([no])
447 ;;
448 *)
449 AC_MSG_RESULT([])
450 AC_MSG_ERROR([--enable-threads only accepts 'yes', 'no', 'posix', 'win95', or 'vista'])
451 ;;
452 esac
454 # We use the actual result a little later.
457 #########################
458 # Assumed amount of RAM #
459 #########################
461 # We use 128 MiB as default, because it will allow decompressing files
462 # created with "xz -9". It would be slightly safer to guess a lower value,
463 # but most systems, on which we don't have any way to determine the amount
464 # of RAM, will probably have at least 128 MiB of RAM.
465 AC_MSG_CHECKING([how much RAM to assume if the real amount is unknown])
466 AC_ARG_ENABLE([assume-ram], AS_HELP_STRING([--enable-assume-ram=SIZE],
467 [If and only if the real amount of RAM cannot be determined,
468 assume SIZE MiB. The default is 128 MiB. This affects the
469 default memory usage limit.]),
470 [], [enable_assume_ram=128])
471 assume_ram_check=`echo "$enable_assume_ram" | tr -d 0123456789`
472 if test -z "$enable_assume_ram" || test -n "$assume_ram_check"; then
473 AC_MSG_RESULT([])
474 AC_MSG_ERROR([--enable-assume-ram accepts only an integer argument])
475 fi
476 AC_MSG_RESULT([$enable_assume_ram MiB])
477 AC_DEFINE_UNQUOTED([ASSUME_RAM], [$enable_assume_ram],
478 [How many MiB of RAM to assume if the real amount cannot
479 be determined.])
482 #########################
483 # Components to install #
484 #########################
486 AC_ARG_ENABLE([xz], [AS_HELP_STRING([--disable-xz],
487 [do not build the xz tool])],
488 [], [enable_xz=yes])
489 AM_CONDITIONAL([COND_XZ], [test x$enable_xz != xno])
491 AC_ARG_ENABLE([xzdec], [AS_HELP_STRING([--disable-xzdec],
492 [do not build xzdec])],
493 [], [enable_xzdec=yes])
494 test "x$enable_decoders" = xno && enable_xzdec=no
495 AM_CONDITIONAL([COND_XZDEC], [test x$enable_xzdec != xno])
497 AC_ARG_ENABLE([lzmadec], [AS_HELP_STRING([--disable-lzmadec],
498 [do not build lzmadec
499 (it exists primarily for LZMA Utils compatibility)])],
500 [], [enable_lzmadec=yes])
501 test "x$enable_decoder_lzma1" = xno && enable_lzmadec=no
502 AM_CONDITIONAL([COND_LZMADEC], [test x$enable_lzmadec != xno])
504 AC_ARG_ENABLE([lzmainfo], [AS_HELP_STRING([--disable-lzmainfo],
505 [do not build lzmainfo
506 (it exists primarily for LZMA Utils compatibility)])],
507 [], [enable_lzmainfo=yes])
508 test "x$enable_decoder_lzma1" = xno && enable_lzmainfo=no
509 AM_CONDITIONAL([COND_LZMAINFO], [test x$enable_lzmainfo != xno])
511 AC_ARG_ENABLE([lzma-links], [AS_HELP_STRING([--disable-lzma-links],
512 [do not create symlinks for LZMA Utils compatibility])],
513 [], [enable_lzma_links=yes])
514 AM_CONDITIONAL([COND_LZMALINKS], [test x$enable_lzma_links != xno])
516 AC_ARG_ENABLE([scripts], [AS_HELP_STRING([--disable-scripts],
517 [do not install the scripts xzdiff, xzgrep, xzless, xzmore,
518 and their symlinks])],
519 [], [enable_scripts=yes])
520 AM_CONDITIONAL([COND_SCRIPTS], [test x$enable_scripts != xno])
522 AC_ARG_ENABLE([doc], [AS_HELP_STRING([--disable-doc],
523 [do not install documentation files to docdir
524 (man pages will still be installed)])],
525 [], [enable_doc=yes])
526 AM_CONDITIONAL([COND_DOC], [test x$enable_doc != xno])
529 ##############
530 # Sandboxing #
531 ##############
533 AC_MSG_CHECKING([if sandboxing should be used])
534 AC_ARG_ENABLE([sandbox], [AS_HELP_STRING([--enable-sandbox=METHOD],
535 [Sandboxing METHOD can be
536 'auto', 'no', 'capsicum', 'pledge', or 'landlock'.
537 The default is 'auto' which enables sandboxing if
538 a supported sandboxing method is found.])],
539 [], [enable_sandbox=auto])
540 case $enable_xzdec-$enable_xz-$enable_sandbox in
541 no-no-*)
542 enable_sandbox=no
543 AC_MSG_RESULT([no, --disable-xz and --disable-xzdec was used])
544 ;;
545 *-*-auto)
546 AC_MSG_RESULT([maybe (autodetect)])
547 ;;
548 *-*-no | *-*-capsicum | *-*-pledge | *-*-landlock)
549 AC_MSG_RESULT([$enable_sandbox])
550 ;;
551 *)
552 AC_MSG_RESULT([])
553 AC_MSG_ERROR([--enable-sandbox only accepts 'auto', 'no', 'capsicum', 'pledge', or 'landlock'.])
554 ;;
555 esac
558 ###########################
559 # PATH prefix for scripts #
560 ###########################
562 # The scripts can add a prefix to the search PATH so that POSIX tools
563 # or the xz binary is always in the PATH.
564 AC_ARG_ENABLE([path-for-scripts],
565 [AS_HELP_STRING([--enable-path-for-scripts=PREFIX],
566 [If PREFIX isn't empty, PATH=PREFIX:$PATH will be set in
567 the beginning of the scripts (xzgrep and others).
568 The default is empty except on Solaris the default is
569 /usr/xpg4/bin.])],
570 [], [
571 case $host_os in
572 solaris*) enable_path_for_scripts=/usr/xpg4/bin ;;
573 *) enable_path_for_scripts= ;;
574 esac
575 ])
576 if test -n "$enable_path_for_scripts" && test "x$enable_path_for_scripts" != xno ; then
577 enable_path_for_scripts="PATH=$enable_path_for_scripts:\$PATH"
578 else
579 enable_path_for_scripts=
580 fi
581 AC_SUBST([enable_path_for_scripts])
584 ###############################################################################
585 # Checks for programs.
586 ###############################################################################
588 echo
589 case $host_os in
590 solaris*)
591 # The gnulib POSIX shell macro below may pick a shell that
592 # doesn't work with xzgrep. Workaround by picking a shell
593 # that is known to work.
594 if test -z "$gl_cv_posix_shell" && test -x /usr/xpg4/bin/sh; then
595 gl_cv_posix_shell=/usr/xpg4/bin/sh
596 fi
597 ;;
598 esac
599 gl_POSIX_SHELL
600 if test -z "$POSIX_SHELL" && test "x$enable_scripts" = xyes ; then
601 AC_MSG_ERROR([No POSIX conforming shell (sh) was found.])
602 fi
604 echo
605 echo "Initializing Automake:"
607 # We don't use "subdir-objects" yet because it breaks "make distclean" when
608 # dependencies are enabled (as of Automake 1.14.1) due to this bug:
609 # https://debbugs.gnu.org/cgi/bugreport.cgi?bug=17354
610 # The -Wno-unsupported is used to silence warnings about missing
611 # "subdir-objects".
612 AM_INIT_AUTOMAKE([1.12 foreign tar-v7 filename-length-max=99 -Wno-unsupported])
613 AC_PROG_LN_S
615 dnl # Autoconf >= 2.70 warns that AC_PROG_CC_C99 is obsolete. However,
616 dnl # we have to keep using AC_PROG_CC_C99 instead of AC_PROG_CC
617 dnl # as long as we try to be compatible with Autoconf 2.69.
618 AC_PROG_CC_C99
619 if test x$ac_cv_prog_cc_c99 = xno ; then
620 AC_MSG_ERROR([No C99 compiler was found.])
621 fi
623 AM_PROG_CC_C_O
624 AM_PROG_AS
625 AC_USE_SYSTEM_EXTENSIONS
627 AS_CASE([$enable_threads],
628 [posix], [
629 echo
630 echo "POSIX threading support:"
631 AX_PTHREAD([:]) dnl We don't need the HAVE_PTHREAD macro.
632 LIBS="$LIBS $PTHREAD_LIBS"
633 AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"
635 dnl NOTE: PTHREAD_CC is ignored. It would be useful on AIX,
636 dnl but it's tricky to get it right together with
637 dnl AC_PROG_CC_C99. Thus, this is handled by telling the
638 dnl user in INSTALL to set the correct CC manually.
640 AC_DEFINE([MYTHREAD_POSIX], [1],
641 [Define to 1 when using POSIX threads (pthreads).])
643 # This is nice to have but not mandatory.
644 OLD_CFLAGS=$CFLAGS
645 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
646 AC_CHECK_FUNCS([pthread_condattr_setclock])
647 CFLAGS=$OLD_CFLAGS
648 ],
649 [win95], [
650 AC_DEFINE([MYTHREAD_WIN95], [1], [Define to 1 when using
651 Windows 95 (and thus XP) compatible threads.
652 This avoids use of features that were added in
653 Windows Vista.])
654 ],
655 [vista], [
656 AC_DEFINE([MYTHREAD_VISTA], [1], [Define to 1 when using
657 Windows Vista compatible threads. This uses
658 features that are not available on Windows XP.])
659 ]
660 )
661 AM_CONDITIONAL([COND_THREADS], [test "x$enable_threads" != xno])
663 echo
664 echo "Initializing Libtool:"
665 LT_PREREQ([2.4])
666 LT_INIT([win32-dll])
667 LT_LANG([Windows Resource])
669 # This is a bit wrong since it is possible to request that only some libs
670 # are built as shared. Using that feature isn't so common though, and this
671 # breaks only on Windows (at least for now) if the user enables only some
672 # libs as shared.
673 AM_CONDITIONAL([COND_SHARED], [test "x$enable_shared" != xno])
675 #####################
676 # Symbol versioning #
677 #####################
679 # NOTE: This checks if we are building shared or static library
680 # and if --with-pic or --without-pic was used. Thus this check
681 # must be after Libtool initialization.
682 AC_MSG_CHECKING([if library symbol versioning should be used])
683 AC_ARG_ENABLE([symbol-versions], [AS_HELP_STRING([--enable-symbol-versions],
684 [Use symbol versioning for liblzma. Enabled by default on
685 GNU/Linux, other GNU-based systems, and FreeBSD.])],
686 [], [enable_symbol_versions=auto])
687 if test "x$enable_symbol_versions" = xauto; then
688 case $host_os in
689 # NOTE: Even if one omits -gnu on GNU/Linux (e.g.
690 # i486-slackware-linux), configure will (via config.sub)
691 # append -gnu (e.g. i486-slackware-linux-gnu), and this
692 # test will work correctly.
693 gnu* | *-gnu* | freebsd*)
694 enable_symbol_versions=yes
695 ;;
696 *)
697 enable_symbol_versions=no
698 ;;
699 esac
700 fi
702 # There are two variants for symbol versioning.
703 # See src/liblzma/validate_map.sh for details.
704 #
705 # On GNU/Linux, extra symbols are added in the C code. These extra symbols
706 # must not be put into a static library as they can cause problems (and
707 # even if they didn't cause problems, they would be useless). On other
708 # systems symbol versioning may be used too but there is no problem as only
709 # a linker script is specified in src/liblzma/Makefile.am and that isn't
710 # used when creating a static library.
711 #
712 # Libtool always uses -DPIC when building shared libraries by default and
713 # doesn't use it for static libs by default. This can be overridden with
714 # --with-pic and --without-pic though. As long as neither --with-pic nor
715 # --without-pic is used then we can use #ifdef PIC to detect if the file is
716 # being built for a shared library.
717 if test "x$enable_symbol_versions" = xno ; then
718 enable_symbol_versions=no
719 AC_MSG_RESULT([no])
720 elif test "x$enable_shared" = xno ; then
721 enable_symbol_versions=no
722 AC_MSG_RESULT([no (not building a shared library)])
723 else
724 case "$host_cpu-$host_os" in
725 microblaze*)
726 # GCC 12 on MicroBlaze doesn't support __symver__
727 # attribute. It's simplest and safest to use the
728 # generic version on that platform since then only
729 # the linker script is needed. The RHEL/CentOS 7
730 # compatibility symbols don't matter on MicroBlaze.
731 enable_symbol_versions=generic
732 ;;
733 *-linux*)
734 case "$pic_mode-$enable_static" in
735 default-*)
736 # Use symvers if PIC is defined.
737 have_symbol_versions_linux=2
738 ;;
739 *-no)
740 # Not building static library.
741 # Use symvers unconditionally.
742 have_symbol_versions_linux=1
743 ;;
744 *)
745 AC_MSG_RESULT([])
746 AC_MSG_ERROR([
747 On GNU/Linux, building both shared and static library at the same time
748 is not supported if --with-pic or --without-pic is used.
749 Use either --disable-shared or --disable-static to build one type
750 of library at a time. If both types are needed, build one at a time,
751 possibly picking only src/liblzma/.libs/liblzma.a from the static build.])
752 ;;
753 esac
754 enable_symbol_versions=linux
755 AC_DEFINE_UNQUOTED([HAVE_SYMBOL_VERSIONS_LINUX],
756 [$have_symbol_versions_linux],
757 [Define to 1 to if GNU/Linux-specific details
758 are unconditionally wanted for symbol
759 versioning. Define to 2 to if these are wanted
760 only if also PIC is defined (allows building
761 both shared and static liblzma at the same
762 time with Libtool if neither --with-pic nor
763 --without-pic is used). This define must be
764 used together with liblzma_linux.map.])
765 ;;
766 *)
767 enable_symbol_versions=generic
768 ;;
769 esac
770 AC_MSG_RESULT([yes ($enable_symbol_versions)])
771 fi
773 AM_CONDITIONAL([COND_SYMVERS_LINUX],
774 [test "x$enable_symbol_versions" = xlinux])
775 AM_CONDITIONAL([COND_SYMVERS_GENERIC],
776 [test "x$enable_symbol_versions" = xgeneric])
779 ###############################################################################
780 # Checks for libraries.
781 ###############################################################################
783 dnl Support for _REQUIRE_VERSION was added in gettext 0.19.6. If both
784 dnl _REQUIRE_VERSION and _VERSION are present, the _VERSION is ignored.
785 dnl We use both for compatibility with other programs in the Autotools family.
786 echo
787 echo "Initializing gettext:"
788 AM_GNU_GETTEXT_REQUIRE_VERSION([0.19.6])
789 AM_GNU_GETTEXT_VERSION([0.19.6])
790 AM_GNU_GETTEXT([external])
793 ###############################################################################
794 # Checks for header files.
795 ###############################################################################
797 echo
798 echo "System headers and functions:"
800 # There is currently no workarounds in this package if some of
801 # these headers are missing.
802 AC_CHECK_HEADERS([fcntl.h limits.h sys/time.h],
803 [],
804 [AC_MSG_ERROR([Required header file(s) are missing.])])
806 # immintrin.h allows the use of the intrinsic functions if they are available.
807 # cpuid.h may be used for detecting x86 processor features at runtime.
808 AC_CHECK_HEADERS([immintrin.h cpuid.h])
811 ###############################################################################
812 # Checks for typedefs, structures, and compiler characteristics.
813 ###############################################################################
815 AC_HEADER_STDBOOL
817 AC_TYPE_UINT8_T
818 AC_TYPE_UINT16_T
819 AC_TYPE_INT32_T
820 AC_TYPE_UINT32_T
821 AC_TYPE_INT64_T
822 AC_TYPE_UINT64_T
823 AC_TYPE_UINTPTR_T
825 AC_CHECK_SIZEOF([size_t])
827 # The command line tool can copy high resolution timestamps if such
828 # information is available in struct stat. Otherwise one second accuracy
829 # is used.
830 AC_CHECK_MEMBERS([
831 struct stat.st_atim.tv_nsec,
832 struct stat.st_atimespec.tv_nsec,
833 struct stat.st_atimensec,
834 struct stat.st_uatime,
835 struct stat.st_atim.st__tim.tv_nsec])
837 AC_SYS_LARGEFILE
838 AC_C_BIGENDIAN
840 # __attribute__((__constructor__)) can be used for one-time initializations.
841 # Use -Werror because some compilers accept unknown attributes and just
842 # give a warning.
843 #
844 # FIXME? Unfortunately -Werror can cause trouble if CFLAGS contains options
845 # that produce warnings for unrelated reasons. For example, GCC and Clang
846 # support -Wunused-macros which will warn about "#define _GNU_SOURCE 1"
847 # which will be among the #defines that Autoconf inserts to the beginning of
848 # the test program. There seems to be no nice way to prevent Autoconf from
849 # inserting the any defines to the test program.
850 AC_MSG_CHECKING([if __attribute__((__constructor__)) can be used])
851 have_func_attribute_constructor=no
852 OLD_CFLAGS="$CFLAGS"
853 CFLAGS="$CFLAGS -Werror"
854 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
855 __attribute__((__constructor__))
856 static void my_constructor_func(void) { return; }
857 ]])], [
858 AC_DEFINE([HAVE_FUNC_ATTRIBUTE_CONSTRUCTOR], [1],
859 [Define to 1 if __attribute__((__constructor__))
860 is supported for functions.])
861 have_func_attribute_constructor=yes
862 AC_MSG_RESULT([yes])
863 ], [
864 AC_MSG_RESULT([no])
865 ])
866 CFLAGS="$OLD_CFLAGS"
868 # The Win95 threading lacks a thread-safe one-time initialization function.
869 # The one-time initialization is needed for crc32_small.c and crc64_small.c
870 # create the CRC tables. So if small mode is enabled, the threading mode is
871 # win95, and the compiler does not support attribute constructor, then we
872 # would end up with a multithreaded build that is thread-unsafe. As a
873 # result this configuration is not allowed.
874 if test "x$enable_small$enable_threads$have_func_attribute_constructor" \
875 = xyeswin95no; then
876 AC_MSG_ERROR([
877 --enable-threads=win95 and --enable-small cannot be used
878 at the same time with a compiler that doesn't support
879 __attribute__((__constructor__))])
880 fi
882 # __attribute__((__ifunc__())) can be used to choose between different
883 # implementations of the same function at runtime. This is slightly more
884 # efficient than using __attribute__((__constructor__)) and setting
885 # a function pointer.
886 AC_ARG_ENABLE([ifunc], [AS_HELP_STRING([--enable-ifunc],
887 [Use __attribute__((__ifunc__())). Enabled by default on
888 GNU/Linux (glibc) and FreeBSD.])],
889 [], [enable_ifunc=auto])
891 # When enable_ifunc is 'auto', allow the use of __attribute__((__ifunc__()))
892 # if compiler support is detected and we are building for GNU/Linux (glibc)
893 # or FreeBSD. uClibc and musl don't support ifunc in their dynamic linkers
894 # but some compilers still accept the attribute when compiling for these
895 # C libraries, which results in broken binaries. That's why we need to
896 # check which libc is being used.
897 if test "x$enable_ifunc" = xauto ; then
898 OLD_CFLAGS="$CFLAGS"
899 CFLAGS="$CFLAGS -Werror"
900 AC_MSG_CHECKING([if __attribute__((__ifunc__())) can be used])
901 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
902 /*
903 * Force a compilation error when not using glibc on Linux
904 * or if we are not using FreeBSD. uClibc will define
905 * __GLIBC__ but does not support ifunc, so we must have
906 * an extra check to disable with uClibc.
907 */
908 #if defined(__linux__)
909 # include <features.h>
910 # if !defined(__GLIBC__) || defined(__UCLIBC__)
911 compile error
912 # endif
913 #elif !defined(__FreeBSD__)
914 compile error
915 #endif
917 static void func(void) { return; }
918 static void (*resolve_func (void)) (void) { return func; }
919 void func_ifunc (void)
920 __attribute__((__ifunc__("resolve_func")));
921 /*
922 * 'clang -Wall' incorrectly warns that resolve_func is
923 * unused (-Wunused-function). Correct assembly output is
924 * still produced. This problem exists at least in Clang
925 * versions 4 to 17. The following silences the bogus warning:
926 */
927 void make_clang_quiet(void);
928 void make_clang_quiet(void) { resolve_func()(); }
929 ]])], [
930 enable_ifunc=yes
931 ], [
932 enable_ifunc=no
933 ])
935 AC_MSG_RESULT([$enable_ifunc])
937 CFLAGS="$OLD_CFLAGS"
938 fi
940 if test "x$enable_ifunc" = xyes ; then
941 AC_DEFINE([HAVE_FUNC_ATTRIBUTE_IFUNC], [1],
942 [Define to 1 if __attribute__((__ifunc__()))
943 is supported for functions.])
945 # ifunc explicitly does not work with -fsanitize=address.
946 # If configured, it will result in a liblzma build that will fail
947 # when liblzma is loaded at runtime (when the ifunc resolver
948 # executes).
949 AS_CASE([$CFLAGS], [*-fsanitize=*], [AC_MSG_ERROR([
950 CFLAGS contains '-fsanitize=' which is incompatible with ifunc.
951 Use --disable-ifunc when using '-fsanitize'.])])
952 fi
955 ###############################################################################
956 # Checks for library functions.
957 ###############################################################################
959 # Gnulib replacements as needed
960 gl_GETOPT
962 # If clock_gettime() is available, liblzma with pthreads may use it, and
963 # xz may use it even when threading support is disabled. In XZ Utils 5.4.x
964 # and older, configure checked for clock_gettime() only when using pthreads.
965 # This way non-threaded builds of liblzma didn't get a useless dependency on
966 # librt which further had a dependency on libpthread. Avoiding these was
967 # useful when a small build was needed, for example, for initramfs use.
968 #
969 # The above reasoning is thoroughly obsolete: On GNU/Linux, librt hasn't
970 # been needed for clock_gettime() since glibc 2.17 (2012-12-25).
971 # Solaris 10 needs librt but Solaris 11 doesn't anymore.
972 AC_SEARCH_LIBS([clock_gettime], [rt])
973 AC_CHECK_FUNCS([clock_gettime])
974 AC_CHECK_DECL([CLOCK_MONOTONIC], [AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1],
975 [Define to 1 if 'CLOCK_MONOTONIC' is declared in <time.h>.])], [],
976 [[#include <time.h>]])
978 # Find the best function to set timestamps.
979 AC_CHECK_FUNCS([futimens futimes futimesat utimes _futime utime], [break])
981 # This is nice to have but not mandatory.
982 AC_CHECK_FUNCS([posix_fadvise])
984 TUKLIB_PROGNAME
985 TUKLIB_INTEGER
986 TUKLIB_PHYSMEM
987 TUKLIB_CPUCORES
988 TUKLIB_MBSTR
990 # If requested, check for system-provided SHA-256. At least the following
991 # implementations are supported:
992 #
993 # OS Headers Library Type Function
994 # FreeBSD sys/types.h + sha256.h libmd SHA256_CTX SHA256_Init
995 # NetBSD sys/types.h + sha2.h SHA256_CTX SHA256_Init
996 # OpenBSD sys/types.h + sha2.h SHA2_CTX SHA256Init
997 # Solaris sys/types.h + sha2.h libmd SHA256_CTX SHA256Init
998 # MINIX 3 sys/types.h + sha2.h SHA256_CTX SHA256_Init
999 # Darwin CommonCrypto/CommonDigest.h CC_SHA256_CTX CC_SHA256_Init
1000 #
1001 # Note that Darwin's CC_SHA256_Update takes buffer size as uint32_t instead
1002 # of size_t.
1003 #
1004 sha256_header_found=no
1005 sha256_type_found=no
1006 sha256_func_found=no
1007 AS_IF([test "x$enable_external_sha256" = "xyes"], [
1008 # Test for Common Crypto before others, because Darwin has sha256.h
1009 # too and we don't want to use that, because on older versions it
1010 # uses OpenSSL functions, whose SHA256_Init is not guaranteed to
1011 # succeed.
1012 AC_CHECK_HEADERS(
1013 [CommonCrypto/CommonDigest.h sha256.h sha2.h],
1014 [sha256_header_found=yes ; break])
1015 if test "x$sha256_header_found" = xyes; then
1016 AC_CHECK_TYPES([CC_SHA256_CTX, SHA256_CTX, SHA2_CTX],
1017 [sha256_type_found=yes], [],
1018 [[#ifdef HAVE_SYS_TYPES_H
1019 # include <sys/types.h>
1020 #endif
1021 #ifdef HAVE_COMMONCRYPTO_COMMONDIGEST_H
1022 # include <CommonCrypto/CommonDigest.h>
1023 #endif
1024 #ifdef HAVE_SHA256_H
1025 # include <sha256.h>
1026 #endif
1027 #ifdef HAVE_SHA2_H
1028 # include <sha2.h>
1029 #endif]])
1030 if test "x$sha256_type_found" = xyes ; then
1031 AC_SEARCH_LIBS([SHA256Init], [md])
1032 AC_SEARCH_LIBS([SHA256_Init], [md])
1033 AC_CHECK_FUNCS([CC_SHA256_Init SHA256Init SHA256_Init],
1034 [sha256_func_found=yes ; break])
1035 fi
1036 fi
1037 ])
1038 AM_CONDITIONAL([COND_INTERNAL_SHA256], [test "x$sha256_func_found" = xno])
1039 if test "x$enable_external_sha256$sha256_func_found" = xyesno; then
1040 AC_MSG_ERROR([--enable-external-sha256 was specified but no supported external SHA-256 implementation was found])
1041 fi
1043 # Check for SSE2 intrinsics. There is no run-time detection for SSE2 so if
1044 # compiler options enable SSE2 then SSE2 support is required by the binaries.
1045 # The compile-time check for SSE2 is done with #ifdefs because some compilers
1046 # (ICC, MSVC) allow SSE2 intrinsics even when SSE2 isn't enabled.
1047 AC_CHECK_DECL([_mm_movemask_epi8],
1048 [AC_DEFINE([HAVE__MM_MOVEMASK_EPI8], [1],
1049 [Define to 1 if _mm_movemask_epi8 is available.])],
1050 [],
1051 [#ifdef HAVE_IMMINTRIN_H
1052 #include <immintrin.h>
1053 #endif])
1055 # For faster CRC on 32/64-bit x86 and E2K (see also crc64_fast.c):
1056 #
1057 # - Check for the CLMUL intrinsic _mm_clmulepi64_si128 in <immintrin.h>.
1058 # Check also for _mm_set_epi64x for consistency with CMake build
1059 # where it's needed to disable CLMUL with VS2013.
1060 #
1061 # - Check that __attribute__((__target__("ssse3,sse4.1,pclmul"))) works
1062 # together with _mm_clmulepi64_si128 from <immintrin.h>. The attribute
1063 # was added in GCC 4.4 but some GCC 4.x versions don't allow intrinsics
1064 # with it. Exception: it must be not be used with EDG-based compilers
1065 # like ICC and the compiler on E2K.
1066 #
1067 # If everything above is supported, runtime detection will be used to keep the
1068 # binaries working on systems that don't support the required extensions.
1069 AC_MSG_CHECKING([if _mm_clmulepi64_si128 is usable])
1070 AS_IF([test "x$enable_clmul_crc" = xno], [
1071 AC_MSG_RESULT([no, --disable-clmul-crc was used])
1072 ], [
1073 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1074 #include <immintrin.h>
1076 // CLMUL works on older E2K instruction set but it is slow due to emulation.
1077 #if defined(__e2k__) && __iset__ < 6
1078 # error
1079 #endif
1081 // Intel's old compiler (ICC) can define __GNUC__ but the attribute must not
1082 // be used with it. The new Clang-based ICX needs the attribute.
1083 // Checking for !defined(__EDG__) catches ICC and other EDG-based compilers.
1084 #if (defined(__GNUC__) || defined(__clang__)) && !defined(__EDG__)
1085 __attribute__((__target__("ssse3,sse4.1,pclmul")))
1086 #endif
1087 __m128i my_clmul(__m128i a)
1088 {
1089 const __m128i b = _mm_set_epi64x(1, 2);
1090 return _mm_clmulepi64_si128(a, b, 0);
1091 }
1092 ]])], [
1093 AC_DEFINE([HAVE_USABLE_CLMUL], [1],
1094 [Define to 1 if _mm_set_epi64x and
1095 _mm_clmulepi64_si128 are usable.
1096 See configure.ac for details.])
1097 enable_clmul_crc=yes
1098 ], [
1099 enable_clmul_crc=no
1100 ])
1101 AC_MSG_RESULT([$enable_clmul_crc])
1102 ])
1104 # ARM64 C Language Extensions define CRC32 functions in arm_acle.h.
1105 # These are supported by at least GCC and Clang which both need
1106 # __attribute__((__target__("+crc"))), unless the needed compiler flags
1107 # are used to support the CRC instruction.
1108 AC_MSG_CHECKING([if ARM64 CRC32 instruction is usable])
1109 AS_IF([test "x$enable_arm64_crc32" = xno], [
1110 AC_MSG_RESULT([no, --disable-arm64-crc32 was used])
1111 ], [
1112 # Set -Werror here because some versions of Clang (14 and older)
1113 # do not report the unsupported __attribute__((__target__("+crc")))
1114 # or __crc32d() as an error, only as a warning. This does not need
1115 # to be done with CMake because tests will attempt to link and the
1116 # error will be reported then.
1117 OLD_CFLAGS="$CFLAGS"
1118 CFLAGS="$CFLAGS -Werror"
1120 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1121 #include <arm_acle.h>
1122 #include <stdint.h>
1124 #if (defined(__GNUC__) || defined(__clang__)) && !defined(__EDG__)
1125 __attribute__((__target__("+crc")))
1126 #endif
1127 uint32_t my_crc(uint32_t a, uint64_t b)
1128 {
1129 return __crc32d(a, b);
1130 }
1131 ]])], [
1132 AC_DEFINE([HAVE_ARM64_CRC32], [1],
1133 [Define to 1 if ARM64 CRC32 instruction is supported.
1134 See configure.ac for details.])
1135 enable_arm64_crc32=yes
1136 ], [
1137 enable_arm64_crc32=no
1138 ])
1139 AC_MSG_RESULT([$enable_arm64_crc32])
1141 CFLAGS="$OLD_CFLAGS"
1142 ])
1144 # Check for ARM64 CRC32 instruction runtime detection.
1145 # getauxval() is supported on Linux, elf_aux_info() on FreeBSD, and
1146 # sysctlbyname("hw.optional.armv8_crc32", ...) is supported on Darwin
1147 # (macOS, iOS, etc.). Note that sysctlbyname() is supported on FreeBSD,
1148 # NetBSD, and possibly others too but the string is specific to Apple OSes.
1149 # The C code is responsible for checking defined(__APPLE__) before using
1150 # sysctlbyname("hw.optional.armv8_crc32", ...).
1151 AS_IF([test "x$enable_arm64_crc32" = xyes], [
1152 AC_CHECK_FUNCS([getauxval elf_aux_info sysctlbyname])
1153 ])
1156 # Check for sandbox support. If one is found, set enable_sandbox=found.
1157 #
1158 # About -fsanitize: Of our three sandbox methods, only Landlock is
1159 # incompatible with -fsanitize. FreeBSD 13.2 with Capsicum was tested with
1160 # -fsanitize=address,undefined and had no issues. OpenBSD (as of version
1161 # 7.4) has minimal support for process instrumentation. OpenBSD does not
1162 # distribute the additional libraries needed (libasan, libubsan, etc.) with
1163 # GCC or Clang needed for runtime sanitization support and instead only
1164 # support -fsanitize-minimal-runtime for minimal undefined behavior
1165 # sanitization. This minimal support is compatible with our use of the
1166 # Pledge sandbox. So only Landlock will result in a build that cannot
1167 # compress or decompress a single file to standard out.
1168 AS_CASE([$enable_sandbox],
1169 [auto | capsicum], [
1170 AC_CHECK_FUNCS([cap_rights_limit], [enable_sandbox=found])
1171 ]
1172 )
1173 AS_CASE([$enable_sandbox],
1174 [auto | pledge], [
1175 AC_CHECK_FUNCS([pledge], [enable_sandbox=found])
1176 ]
1177 )
1178 AS_CASE([$enable_sandbox],
1179 [auto | landlock], [
1180 AC_CHECK_HEADERS([linux/landlock.h], [
1181 enable_sandbox=found
1183 AS_CASE([$CFLAGS], [*-fsanitize=*], [AC_MSG_ERROR([
1184 CFLAGS contains '-fsanitize=' which is incompatible with the Landlock
1185 sandboxing. Use --disable-sandbox when using '-fsanitize'.])])
1186 ])
1187 ]
1188 )
1190 # If a specific sandboxing method was explicitly requested and it wasn't
1191 # found, give an error.
1192 case $enable_sandbox in
1193 auto | no | found)
1194 ;;
1195 *)
1196 AC_MSG_ERROR([$enable_sandbox support not found])
1197 ;;
1198 esac
1201 ###############################################################################
1202 # If using GCC, set some additional AM_CFLAGS:
1203 ###############################################################################
1205 if test "$GCC" = yes ; then
1206 echo
1207 echo "GCC extensions:"
1208 fi
1210 # Always do the visibility check but don't set AM_CFLAGS on Windows.
1211 # This way things get set properly even on Windows.
1212 gl_VISIBILITY
1213 if test -n "$CFLAG_VISIBILITY" && test "$is_w32" = no; then
1214 AM_CFLAGS="$AM_CFLAGS $CFLAG_VISIBILITY"
1215 fi
1217 AS_IF([test "$GCC" = yes], [
1218 # Enable as much warnings as possible. These commented warnings won't
1219 # work for this package though:
1220 # * -Wunreachable-code breaks several assert(0) cases, which are
1221 # backed up with "return LZMA_PROG_ERROR".
1222 # * -Wcast-qual would break various things where we need a non-const
1223 # pointer although we don't modify anything through it.
1224 # * -Winline, -Wdisabled-optimization, -Wunsafe-loop-optimizations
1225 # don't seem so useful here; at least the last one gives some
1226 # warnings which are not bugs.
1227 # * -Wconversion still shows too many warnings.
1228 #
1229 # The flags before the empty line are for GCC and many of them
1230 # are supported by Clang too. The flags after the empty line are
1231 # for Clang.
1232 for NEW_FLAG in \
1233 -Wall \
1234 -Wextra \
1235 -Wvla \
1236 -Wformat=2 \
1237 -Winit-self \
1238 -Wmissing-include-dirs \
1239 -Wshift-overflow=2 \
1240 -Wstrict-overflow=3 \
1241 -Walloc-zero \
1242 -Wduplicated-cond \
1243 -Wfloat-equal \
1244 -Wundef \
1245 -Wshadow \
1246 -Wpointer-arith \
1247 -Wbad-function-cast \
1248 -Wwrite-strings \
1249 -Wdate-time \
1250 -Wsign-conversion \
1251 -Wfloat-conversion \
1252 -Wlogical-op \
1253 -Waggregate-return \
1254 -Wstrict-prototypes \
1255 -Wold-style-definition \
1256 -Wmissing-prototypes \
1257 -Wmissing-declarations \
1258 -Wredundant-decls \
1259 \
1260 -Wc99-compat \
1261 -Wc11-extensions \
1262 -Wc2x-compat \
1263 -Wc2x-extensions \
1264 -Wpre-c2x-compat \
1265 -Warray-bounds-pointer-arithmetic \
1266 -Wassign-enum \
1267 -Wconditional-uninitialized \
1268 -Wdocumentation \
1269 -Wduplicate-enum \
1270 -Wempty-translation-unit \
1271 -Wflexible-array-extensions \
1272 -Wmissing-variable-declarations \
1273 -Wnewline-eof \
1274 -Wshift-sign-overflow \
1275 -Wstring-conversion
1276 do
1277 AC_MSG_CHECKING([if $CC accepts $NEW_FLAG])
1278 OLD_CFLAGS="$CFLAGS"
1279 CFLAGS="$CFLAGS $NEW_FLAG -Werror"
1280 AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1281 [[void foo(void); void foo(void) { }]])], [
1282 AM_CFLAGS="$AM_CFLAGS $NEW_FLAG"
1283 AC_MSG_RESULT([yes])
1284 ], [
1285 AC_MSG_RESULT([no])
1286 ])
1287 CFLAGS="$OLD_CFLAGS"
1288 done
1290 AC_ARG_ENABLE([werror],
1291 AS_HELP_STRING([--enable-werror], [Enable -Werror to abort
1292 compilation on all compiler warnings.]),
1293 [], [enable_werror=no])
1294 if test "x$enable_werror" = "xyes"; then
1295 AM_CFLAGS="$AM_CFLAGS -Werror"
1296 fi
1297 ])
1300 ###############################################################################
1301 # Create the makefiles and config.h
1302 ###############################################################################
1304 echo
1306 # Don't build the lib directory at all if we don't need any replacement
1307 # functions.
1308 AM_CONDITIONAL([COND_GNULIB], test -n "$LIBOBJS")
1310 # Add default AM_CFLAGS.
1311 AC_SUBST([AM_CFLAGS])
1313 # This is needed for src/scripts.
1314 xz=`echo xz | sed "$program_transform_name"`
1315 AC_SUBST([xz])
1317 AC_CONFIG_FILES([
1318 Makefile
1319 po/Makefile.in
1320 lib/Makefile
1321 src/Makefile
1322 src/liblzma/Makefile
1323 src/liblzma/api/Makefile
1324 src/xz/Makefile
1325 src/xzdec/Makefile
1326 src/lzmainfo/Makefile
1327 src/scripts/Makefile
1328 tests/Makefile
1329 debug/Makefile
1330 ])
1331 AC_CONFIG_FILES([src/scripts/xzdiff], [chmod +x src/scripts/xzdiff])
1332 AC_CONFIG_FILES([src/scripts/xzgrep], [chmod +x src/scripts/xzgrep])
1333 AC_CONFIG_FILES([src/scripts/xzmore], [chmod +x src/scripts/xzmore])
1334 AC_CONFIG_FILES([src/scripts/xzless], [chmod +x src/scripts/xzless])
1336 AC_OUTPUT
1338 # Some warnings
1339 if test x$tuklib_cv_physmem_method = xunknown; then
1340 echo
1341 echo "WARNING:"
1342 echo "No supported method to detect the amount of RAM."
1343 echo "Consider using --enable-assume-ram (if you didn't already)"
1344 echo "or make a patch to add support for this operating system."
1345 fi
1347 if test x$tuklib_cv_cpucores_method = xunknown; then
1348 echo
1349 echo "WARNING:"
1350 echo "No supported method to detect the number of CPU cores."
1351 fi
1353 if test "x$enable_threads$enable_small$have_func_attribute_constructor" \
1354 = xnoyesno; then
1355 echo
1356 echo "NOTE:"
1357 echo "liblzma will be thread-unsafe due to the combination"
1358 echo "of --disable-threads --enable-small when using a compiler"
1359 echo "that doesn't support __attribute__((__constructor__))."
1360 fi