m4/tuklib_physmem.m4

   1 # SPDX-License-Identifier: 0BSD
   2
   3 #############################################################################
   4 #
   5 # SYNOPSIS
   6 #
   7 #   TUKLIB_PHYSMEM
   8 #
   9 # DESCRIPTION
  10 #
  11 #   Check how to get the amount of physical memory.
  12 #   This information is used in tuklib_physmem.c.
  13 #
  14 #   Supported methods:
  15 #
  16 #     - Windows (including Cygwin), OS/2, DJGPP (DOS), OpenVMS, AROS,
  17 #       and QNX have operating-system specific functions.
  18 #
  19 #     - AIX has _system_configuration.physmem.
  20 #
  21 #     - sysconf() works on GNU/Linux and Solaris, and possibly on
  22 #       some BSDs.
  23 #
  24 #     - BSDs use sysctl().
  25 #
  26 #     - Tru64 uses getsysinfo().
  27 #
  28 #     - HP-UX uses pstat_getstatic().
  29 #
  30 #     - IRIX has setinvent_r(), getinvent_r(), and endinvent_r().
  31 #
  32 #     - sysinfo() works on Linux/dietlibc and probably on other Linux
  33 #       systems whose libc may lack sysconf().
  34 #
  35 #############################################################################
  36 #
  37 # Author: Lasse Collin
  38 #
  39 #############################################################################
  40
  41 AC_DEFUN_ONCE([TUKLIB_PHYSMEM], [
  42 AC_REQUIRE([TUKLIB_COMMON])
  43
  44 # sys/param.h might be needed by sys/sysctl.h.
  45 AC_CHECK_HEADERS([sys/param.h])
  46
  47 AC_CACHE_CHECK([how to detect the amount of physical memory],
  48         [tuklib_cv_physmem_method], [
  49
  50 # Maybe checking $host_os would be enough but this matches what
  51 # tuklib_physmem.c does.
  52 #
  53 # NOTE: IRIX has a compiler that doesn't error out with #error, so use
  54 # a non-compilable text instead of #error to generate an error.
  55 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
  56 #if defined(_WIN32) || defined(__CYGWIN__) || defined(__OS2__) \
  57                 || defined(__DJGPP__) || defined(__VMS) \
  58                 || defined(AMIGA) || defined(__AROS__) || defined(__QNX__)
  59 int main(void) { return 0; }
  60 #else
  61 compile error
  62 #endif
  63 ]])], [tuklib_cv_physmem_method=special], [
  64
  65 # Look for AIX-specific solution before sysconf(), because the test
  66 # for sysconf() will pass on AIX but won't actually work
  67 # (sysconf(_SC_PHYS_PAGES) compiles but always returns -1 on AIX).
  68 #
  69 # NOTE: There is no need to link the check program because it's not calling
  70 # any functions and thus implicit function declarations aren't a problem.
  71 # The unused reference to _system_configuration.physmem might get optimized
  72 # away, and thus the linker might not see that symbol anyway.
  73 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
  74 #include <sys/systemcfg.h>
  75
  76 int
  77 main(void)
  78 {
  79         (void)_system_configuration.physmem;
  80         return 0;
  81 }
  82 ]])], [tuklib_cv_physmem_method=aix], [
  83
  84 AC_LINK_IFELSE([AC_LANG_SOURCE([[
  85 #include <unistd.h>
  86 int
  87 main(void)
  88 {
  89         long i;
  90         i = sysconf(_SC_PAGESIZE);
  91         i = sysconf(_SC_PHYS_PAGES);
  92         return 0;
  93 }
  94 ]])], [tuklib_cv_physmem_method=sysconf], [
  95
  96 AC_LINK_IFELSE([AC_LANG_SOURCE([[
  97 #ifdef HAVE_SYS_PARAM_H
  98 #       include <sys/param.h>
  99 #endif
 100 #include <sys/sysctl.h>
 101 int
 102 main(void)
 103 {
 104         int name[2] = { CTL_HW, HW_PHYSMEM };
 105         unsigned long mem;
 106         size_t mem_ptr_size = sizeof(mem);
 107         sysctl(name, 2, &mem, &mem_ptr_size, NULL, 0);
 108         return 0;
 109 }
 110 ]])], [tuklib_cv_physmem_method=sysctl], [
 111
 112 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 113 #include <sys/sysinfo.h>
 114 #include <machine/hal_sysinfo.h>
 115
 116 int
 117 main(void)
 118 {
 119         int memkb;
 120         int start = 0;
 121         getsysinfo(GSI_PHYSMEM, (caddr_t)&memkb, sizeof(memkb), &start);
 122         return 0;
 123 }
 124 ]])], [tuklib_cv_physmem_method=getsysinfo],[
 125
 126 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 127 #include <sys/param.h>
 128 #include <sys/pstat.h>
 129
 130 int
 131 main(void)
 132 {
 133         struct pst_static pst;
 134         pstat_getstatic(&pst, sizeof(pst), 1, 0);
 135         (void)pst.physical_memory;
 136         (void)pst.page_size;
 137         return 0;
 138 }
 139 ]])], [tuklib_cv_physmem_method=pstat_getstatic],[
 140
 141 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 142 #include <invent.h>
 143 int
 144 main(void)
 145 {
 146         inv_state_t *st = NULL;
 147         setinvent_r(&st);
 148         getinvent_r(st);
 149         endinvent_r(st);
 150         return 0;
 151 }
 152 ]])], [tuklib_cv_physmem_method=getinvent_r], [
 153
 154 # This version of sysinfo() is Linux-specific. Some non-Linux systems have
 155 # different sysinfo() so we must check $host_os.
 156 case $host_os in
 157         linux*)
 158                 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 159 #include <sys/sysinfo.h>
 160 int
 161 main(void)
 162 {
 163         struct sysinfo si;
 164         sysinfo(&si);
 165         return 0;
 166 }
 167                 ]])], [
 168                         tuklib_cv_physmem_method=sysinfo
 169                 ], [
 170                         tuklib_cv_physmem_method=unknown
 171                 ])
 172                 ;;
 173         *)
 174                 tuklib_cv_physmem_method=unknown
 175                 ;;
 176 esac
 177 ])])])])])])])])
 178
 179 case $tuklib_cv_physmem_method in
 180         aix)
 181                 AC_DEFINE([TUKLIB_PHYSMEM_AIX], [1],
 182                         [Define to 1 if the amount of physical memory
 183                         can be detected with _system_configuration.physmem.])
 184                 ;;
 185         sysconf)
 186                 AC_DEFINE([TUKLIB_PHYSMEM_SYSCONF], [1],
 187                         [Define to 1 if the amount of physical memory can
 188                         be detected with sysconf(_SC_PAGESIZE) and
 189                         sysconf(_SC_PHYS_PAGES).])
 190                 ;;
 191         sysctl)
 192                 AC_DEFINE([TUKLIB_PHYSMEM_SYSCTL], [1],
 193                         [Define to 1 if the amount of physical memory can
 194                         be detected with sysctl().])
 195                 ;;
 196         getsysinfo)
 197                 AC_DEFINE([TUKLIB_PHYSMEM_GETSYSINFO], [1],
 198                         [Define to 1 if the amount of physical memory can
 199                         be detected with getsysinfo().])
 200                 ;;
 201         pstat_getstatic)
 202                 AC_DEFINE([TUKLIB_PHYSMEM_PSTAT_GETSTATIC], [1],
 203                         [Define to 1 if the amount of physical memory can
 204                         be detected with pstat_getstatic().])
 205                 ;;
 206         getinvent_r)
 207                 AC_DEFINE([TUKLIB_PHYSMEM_GETINVENT_R], [1],
 208                         [Define to 1 if the amount of physical memory
 209                         can be detected with getinvent_r().])
 210                 ;;
 211         sysinfo)
 212                 AC_DEFINE([TUKLIB_PHYSMEM_SYSINFO], [1],
 213                         [Define to 1 if the amount of physical memory
 214                         can be detected with Linux sysinfo().])
 215                 ;;
 216 esac
 217 ])dnl