| blob | 36ceeef302dcaa6599631732589eca1a8e8cd2e4 |
1 # -*- Autoconf -*-
2 # SPDX-License-Identifier: 0BSD
4 ###############################################################################
5 #
6 # Process this file with autoconf to produce a configure script.
7 #
8 # Author: Lasse Collin
9 #
10 ###############################################################################
12 # NOTE: Don't add useless checks. autoscan detects this and that, but don't
13 # let it confuse you. For example, we don't care about checking for behavior
14 # of malloc(), stat(), or lstat(), since we don't use those functions in
15 # a way that would cause the problems the autoconf macros check.
17 AC_PREREQ([2.69])
19 AC_INIT([XZ Utils], m4_esyscmd([/bin/sh build-aux/version.sh]),
20 [xz@tukaani.org], [xz], [https://xz.tukaani.org/xz-utils/])
21 AC_CONFIG_SRCDIR([src/liblzma/common/common.h])
22 AC_CONFIG_AUX_DIR([build-aux])
23 AC_CONFIG_MACRO_DIR([m4])
24 AC_CONFIG_HEADERS([config.h])
26 echo
27 echo "$PACKAGE_STRING"
29 echo
30 echo "System type:"
31 # This is needed to know if assembler optimizations can be used.
32 AC_CANONICAL_HOST
34 # We do some special things on Windows (32-bit or 64-bit) builds.
35 case $host_os in
36 mingw* | cygwin | msys) is_w32=yes ;;
37 *) is_w32=no ;;
38 esac
39 AM_CONDITIONAL([COND_W32], [test "$is_w32" = yes])
41 # We need to use $EXEEXT with $(LN_S) when creating symlinks to
42 # executables. Cygwin is an exception to this, since it is recommended
43 # that symlinks don't have the .exe suffix. To make this work, we
44 # define LN_EXEEXT.
45 #
46 # MSYS2 is treated the same way as Cygwin. It uses plain "msys" like
47 # the original MSYS when building MSYS/MSYS2-binaries. Hopefully this
48 # doesn't break things for the original MSYS developers. Note that this
49 # doesn't affect normal MSYS/MSYS2 users building non-MSYS/MSYS2 binaries
50 # since in that case the $host_os is usually mingw32.
51 case $host_os in
52 cygwin | msys) LN_EXEEXT= ;;
53 *) LN_EXEEXT='$(EXEEXT)' ;;
54 esac
55 AC_SUBST([LN_EXEEXT])
57 echo
58 echo "Configure options:"
59 AM_CFLAGS=
62 #############
63 # Debugging #
64 #############
66 AC_MSG_CHECKING([if debugging code should be compiled])
67 AC_ARG_ENABLE([debug], AS_HELP_STRING([--enable-debug], [Enable debugging code.]),
68 [], enable_debug=no)
69 if test "x$enable_debug" = xyes; then
70 AC_MSG_RESULT([yes])
71 else
72 AC_DEFINE([NDEBUG], [1], [Define to 1 to disable debugging code.])
73 AC_MSG_RESULT([no])
74 fi
77 ###########
78 # Filters #
79 ###########
81 m4_define([SUPPORTED_FILTERS], [lzma1,lzma2,delta,x86,powerpc,ia64,arm,armthumb,arm64,sparc,riscv])dnl
82 m4_define([SIMPLE_FILTERS], [x86,powerpc,ia64,arm,armthumb,arm64,sparc,riscv])
83 m4_define([LZ_FILTERS], [lzma1,lzma2])
85 m4_foreach([NAME], [SUPPORTED_FILTERS],
86 [enable_filter_[]NAME=no
87 enable_encoder_[]NAME=no
88 enable_decoder_[]NAME=no
89 ])dnl
91 AC_MSG_CHECKING([which encoders to build])
92 AC_ARG_ENABLE([encoders], AS_HELP_STRING([--enable-encoders=LIST],
93 [Comma-separated list of encoders to build. Default=all.
94 Available encoders:]
95 m4_translit(m4_defn([SUPPORTED_FILTERS]), [,], [ ])),
96 [], [enable_encoders=SUPPORTED_FILTERS])
97 enable_encoders=`echo "$enable_encoders" | sed 's/,/ /g'`
98 if test "x$enable_encoders" = xno || test "x$enable_encoders" = x; then
99 enable_encoders=no
100 AC_MSG_RESULT([(none)])
101 else
102 for arg in $enable_encoders
103 do
104 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
105 NAME)
106 enable_filter_[]NAME=yes
107 enable_encoder_[]NAME=yes
108 AC_DEFINE(HAVE_ENCODER_[]m4_toupper(NAME), [1],
109 [Define to 1 if] NAME [encoder is enabled.])
110 ;;])
111 *)
112 AC_MSG_RESULT([])
113 AC_MSG_ERROR([unknown filter: $arg])
114 ;;
115 esac
116 done
117 AC_DEFINE([HAVE_ENCODERS], [1],
118 [Define to 1 if any of HAVE_ENCODER_foo have been defined.])
119 AC_MSG_RESULT([$enable_encoders])
120 fi
122 AC_MSG_CHECKING([which decoders to build])
123 AC_ARG_ENABLE([decoders], AS_HELP_STRING([--enable-decoders=LIST],
124 [Comma-separated list of decoders to build. Default=all.
125 Available decoders are the same as available encoders.]),
126 [], [enable_decoders=SUPPORTED_FILTERS])
127 enable_decoders=`echo "$enable_decoders" | sed 's/,/ /g'`
128 if test "x$enable_decoders" = xno || test "x$enable_decoders" = x; then
129 enable_decoders=no
130 AC_MSG_RESULT([(none)])
131 else
132 for arg in $enable_decoders
133 do
134 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
135 NAME)
136 enable_filter_[]NAME=yes
137 enable_decoder_[]NAME=yes
138 AC_DEFINE(HAVE_DECODER_[]m4_toupper(NAME), [1],
139 [Define to 1 if] NAME [decoder is enabled.])
140 ;;])
141 *)
142 AC_MSG_RESULT([])
143 AC_MSG_ERROR([unknown filter: $arg])
144 ;;
145 esac
146 done
147 AC_DEFINE([HAVE_DECODERS], [1],
148 [Define to 1 if any of HAVE_DECODER_foo have been defined.])
149 AC_MSG_RESULT([$enable_decoders])
150 fi
152 if test "x$enable_encoder_lzma2$enable_encoder_lzma1" = xyesno \
153 || test "x$enable_decoder_lzma2$enable_decoder_lzma1" = xyesno; then
154 AC_MSG_ERROR([LZMA2 requires that LZMA1 is also enabled.])
155 fi
157 AM_CONDITIONAL(COND_MAIN_ENCODER, test "x$enable_encoders" != xno)
158 AM_CONDITIONAL(COND_MAIN_DECODER, test "x$enable_decoders" != xno)
160 m4_foreach([NAME], [SUPPORTED_FILTERS],
161 [AM_CONDITIONAL(COND_FILTER_[]m4_toupper(NAME), test "x$enable_filter_[]NAME" = xyes)
162 AM_CONDITIONAL(COND_ENCODER_[]m4_toupper(NAME), test "x$enable_encoder_[]NAME" = xyes)
163 AM_CONDITIONAL(COND_DECODER_[]m4_toupper(NAME), test "x$enable_decoder_[]NAME" = xyes)
164 ])dnl
166 # The so called "simple filters" share common code.
167 enable_filter_simple=no
168 enable_encoder_simple=no
169 enable_decoder_simple=no
170 m4_foreach([NAME], [SIMPLE_FILTERS],
171 [test "x$enable_filter_[]NAME" = xyes && enable_filter_simple=yes
172 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_simple=yes
173 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_simple=yes
174 ])dnl
175 AM_CONDITIONAL(COND_FILTER_SIMPLE, test "x$enable_filter_simple" = xyes)
176 AM_CONDITIONAL(COND_ENCODER_SIMPLE, test "x$enable_encoder_simple" = xyes)
177 AM_CONDITIONAL(COND_DECODER_SIMPLE, test "x$enable_decoder_simple" = xyes)
179 # LZ-based filters share common code.
180 enable_filter_lz=no
181 enable_encoder_lz=no
182 enable_decoder_lz=no
183 m4_foreach([NAME], [LZ_FILTERS],
184 [test "x$enable_filter_[]NAME" = xyes && enable_filter_lz=yes
185 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_lz=yes
186 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_lz=yes
187 ])dnl
188 AM_CONDITIONAL(COND_FILTER_LZ, test "x$enable_filter_lz" = xyes)
189 AM_CONDITIONAL(COND_ENCODER_LZ, test "x$enable_encoder_lz" = xyes)
190 AM_CONDITIONAL(COND_DECODER_LZ, test "x$enable_decoder_lz" = xyes)
193 #################
194 # Match finders #
195 #################
197 m4_define([SUPPORTED_MATCH_FINDERS], [hc3,hc4,bt2,bt3,bt4])
199 m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS],
200 [enable_match_finder_[]NAME=no
201 ])
203 AC_MSG_CHECKING([which match finders to build])
204 AC_ARG_ENABLE([match-finders], AS_HELP_STRING([--enable-match-finders=LIST],
205 [Comma-separated list of match finders to build. Default=all.
206 At least one match finder is required for encoding with
207 the LZMA1 and LZMA2 filters. Available match finders:]
208 m4_translit(m4_defn([SUPPORTED_MATCH_FINDERS]), [,], [ ])), [],
209 [enable_match_finders=SUPPORTED_MATCH_FINDERS])
210 enable_match_finders=`echo "$enable_match_finders" | sed 's/,/ /g'`
211 if test "x$enable_encoder_lz" = xyes ; then
212 if test -z "$enable_match_finders"; then
213 AC_MSG_ERROR([At least one match finder is required for an LZ-based encoder.])
214 fi
216 for arg in $enable_match_finders
217 do
218 case $arg in m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS], [
219 NAME)
220 enable_match_finder_[]NAME=yes
221 AC_DEFINE(HAVE_MF_[]m4_toupper(NAME), [1],
222 [Define to 1 to enable] NAME [match finder.])
223 ;;])
224 *)
225 AC_MSG_RESULT([])
226 AC_MSG_ERROR([unknown match finder: $arg])
227 ;;
228 esac
229 done
230 AC_MSG_RESULT([$enable_match_finders])
231 else
232 AC_MSG_RESULT([(none because not building any LZ-based encoder)])
233 fi
236 ####################
237 # Integrity checks #
238 ####################
240 m4_define([SUPPORTED_CHECKS], [crc32,crc64,sha256])
242 m4_foreach([NAME], [SUPPORTED_CHECKS],
243 [enable_check_[]NAME=no
244 ])dnl
246 AC_MSG_CHECKING([which integrity checks to build])
247 AC_ARG_ENABLE([checks], AS_HELP_STRING([--enable-checks=LIST],
248 [Comma-separated list of integrity checks to build.
249 Default=all. Available integrity checks:]
250 m4_translit(m4_defn([SUPPORTED_CHECKS]), [,], [ ])),
251 [], [enable_checks=SUPPORTED_CHECKS])
252 enable_checks=`echo "$enable_checks" | sed 's/,/ /g'`
253 if test "x$enable_checks" = xno || test "x$enable_checks" = x; then
254 AC_MSG_RESULT([(none)])
255 else
256 for arg in $enable_checks
257 do
258 case $arg in m4_foreach([NAME], [SUPPORTED_CHECKS], [
259 NAME)
260 enable_check_[]NAME=yes
261 AC_DEFINE(HAVE_CHECK_[]m4_toupper(NAME), [1],
262 [Define to 1 if] NAME
263 [integrity check is enabled.])
264 ;;])
265 *)
266 AC_MSG_RESULT([])
267 AC_MSG_ERROR([unknown integrity check: $arg])
268 ;;
269 esac
270 done
271 AC_MSG_RESULT([$enable_checks])
272 fi
273 if test "x$enable_check_crc32" = xno ; then
274 AC_MSG_ERROR([For now, the CRC32 check must always be enabled.])
275 fi
277 m4_foreach([NAME], [SUPPORTED_CHECKS],
278 [AM_CONDITIONAL(COND_CHECK_[]m4_toupper(NAME), test "x$enable_check_[]NAME" = xyes)
279 ])dnl
281 AC_MSG_CHECKING([if external SHA-256 should be used])
282 AC_ARG_ENABLE([external-sha256], AS_HELP_STRING([--enable-external-sha256],
283 [Use SHA-256 code from the operating system.
284 See INSTALL for possible subtle problems.]),
285 [], [enable_external_sha256=no])
286 if test "x$enable_check_sha256" != "xyes"; then
287 enable_external_sha256=no
288 fi
289 if test "x$enable_external_sha256" = xyes; then
290 AC_MSG_RESULT([yes])
291 else
292 AC_MSG_RESULT([no])
293 fi
296 #############
297 # MicroLZMA #
298 #############
300 AC_MSG_CHECKING([if MicroLZMA support should be built])
301 AC_ARG_ENABLE([microlzma], AS_HELP_STRING([--disable-microlzma],
302 [Do not build MicroLZMA encoder and decoder.
303 It is needed by specific applications only,
304 for example, erofs-utils.]),
305 [], [enable_microlzma=yes])
306 case $enable_microlzma in
307 yes | no)
308 AC_MSG_RESULT([$enable_microlzma])
309 ;;
310 *)
311 AC_MSG_RESULT([])
312 AC_MSG_ERROR([--enable-microlzma accepts only 'yes' or 'no'.])
313 ;;
314 esac
315 AM_CONDITIONAL(COND_MICROLZMA, test "x$enable_microlzma" = xyes)
318 #############################
319 # .lz (lzip) format support #
320 #############################
322 AC_MSG_CHECKING([if .lz (lzip) decompression support should be built])
323 AC_ARG_ENABLE([lzip-decoder], AS_HELP_STRING([--disable-lzip-decoder],
324 [Disable decompression support for .lz (lzip) files.]),
325 [], [enable_lzip_decoder=yes])
326 if test "x$enable_decoder_lzma1" != xyes; then
327 enable_lzip_decoder=no
328 AC_MSG_RESULT([no because LZMA1 decoder is disabled])
329 elif test "x$enable_lzip_decoder" = xyes; then
330 AC_DEFINE([HAVE_LZIP_DECODER], [1],
331 [Define to 1 if .lz (lzip) decompression support is enabled.])
332 AC_MSG_RESULT([yes])
333 else
334 AC_MSG_RESULT([no])
335 fi
336 AM_CONDITIONAL(COND_LZIP_DECODER, test "x$enable_lzip_decoder" = xyes)
339 ###########################
340 # Assembler optimizations #
341 ###########################
343 AC_MSG_CHECKING([if assembler optimizations should be used])
344 AC_ARG_ENABLE([assembler], AS_HELP_STRING([--disable-assembler],
345 [Do not use assembler optimizations even if such exist
346 for the architecture.]),
347 [], [enable_assembler=yes])
348 if test "x$enable_assembler" = xyes; then
349 enable_assembler=no
350 case $host_os in
351 # Darwin should work too but only if not creating universal
352 # binaries. Solaris x86 could work too but I cannot test.
353 linux* | *bsd* | mingw* | cygwin | msys | *djgpp*)
354 case $host_cpu in
355 i?86) enable_assembler=x86 ;;
356 esac
357 ;;
358 esac
359 fi
360 case $enable_assembler in
361 x86 | no)
362 AC_MSG_RESULT([$enable_assembler])
363 ;;
364 *)
365 AC_MSG_RESULT([])
366 AC_MSG_ERROR([--enable-assembler accepts only 'yes', 'no', or 'x86' (32-bit).])
367 ;;
368 esac
369 AM_CONDITIONAL(COND_ASM_X86, test "x$enable_assembler" = xx86)
372 #############
373 # CLMUL CRC #
374 #############
376 AC_ARG_ENABLE([clmul-crc], AS_HELP_STRING([--disable-clmul-crc],
377 [Do not use carryless multiplication for CRC calculation
378 even if support for it is detected.]),
379 [], [enable_clmul_crc=yes])
382 ############################
383 # ARM64 CRC32 Instructions #
384 ############################
386 AC_ARG_ENABLE([arm64-crc32], AS_HELP_STRING([--disable-arm64-crc32],
387 [Do not use ARM64 CRC32 instructions even if support for it
388 is detected.]),
389 [], [enable_arm64_crc32=yes])
392 #####################
393 # Size optimization #
394 #####################
396 AC_MSG_CHECKING([if small size is preferred over speed])
397 AC_ARG_ENABLE([small], AS_HELP_STRING([--enable-small],
398 [Make liblzma smaller and a little slower.
399 This is disabled by default to optimize for speed.]),
400 [], [enable_small=no])
401 if test "x$enable_small" = xyes; then
402 AC_DEFINE([HAVE_SMALL], [1], [Define to 1 if optimizing for size.])
403 elif test "x$enable_small" != xno; then
404 AC_MSG_RESULT([])
405 AC_MSG_ERROR([--enable-small accepts only 'yes' or 'no'])
406 fi
407 AC_MSG_RESULT([$enable_small])
408 AM_CONDITIONAL(COND_SMALL, test "x$enable_small" = xyes)
411 #############
412 # Threading #
413 #############
415 AC_MSG_CHECKING([if threading support is wanted])
416 AC_ARG_ENABLE([threads], AS_HELP_STRING([--enable-threads=METHOD],
417 [Supported METHODS are 'yes', 'no', 'posix', 'win95', and
418 'vista'. The default is 'yes'. Using 'no' together with
419 --enable-small makes liblzma thread unsafe.]),
420 [], [enable_threads=yes])
422 if test "x$enable_threads" = xyes; then
423 case $host_os in
424 mingw*)
425 case $host_cpu in
426 i?86) enable_threads=win95 ;;
427 *) enable_threads=vista ;;
428 esac
429 ;;
430 *)
431 enable_threads=posix
432 ;;
433 esac
434 fi
436 case $enable_threads in
437 posix | win95 | vista)
438 AC_MSG_RESULT([yes, $enable_threads])
439 ;;
440 no)
441 AC_MSG_RESULT([no])
442 ;;
443 *)
444 AC_MSG_RESULT([])
445 AC_MSG_ERROR([--enable-threads only accepts 'yes', 'no', 'posix', 'win95', or 'vista'])
446 ;;
447 esac
449 # We use the actual result a little later.
452 #########################
453 # Assumed amount of RAM #
454 #########################
456 # We use 128 MiB as default, because it will allow decompressing files
457 # created with "xz -9". It would be slightly safer to guess a lower value,
458 # but most systems, on which we don't have any way to determine the amount
459 # of RAM, will probably have at least 128 MiB of RAM.
460 AC_MSG_CHECKING([how much RAM to assume if the real amount is unknown])
461 AC_ARG_ENABLE([assume-ram], AS_HELP_STRING([--enable-assume-ram=SIZE],
462 [If and only if the real amount of RAM cannot be determined,
463 assume SIZE MiB. The default is 128 MiB. This affects the
464 default memory usage limit.]),
465 [], [enable_assume_ram=128])
466 assume_ram_check=`echo "$enable_assume_ram" | tr -d 0123456789`
467 if test -z "$enable_assume_ram" || test -n "$assume_ram_check"; then
468 AC_MSG_RESULT([])
469 AC_MSG_ERROR([--enable-assume-ram accepts only an integer argument])
470 fi
471 AC_MSG_RESULT([$enable_assume_ram MiB])
472 AC_DEFINE_UNQUOTED([ASSUME_RAM], [$enable_assume_ram],
473 [How many MiB of RAM to assume if the real amount cannot
474 be determined.])
477 #########################
478 # Components to install #
479 #########################
481 AC_ARG_ENABLE([xz], [AS_HELP_STRING([--disable-xz],
482 [do not build the xz tool])],
483 [], [enable_xz=yes])
484 AM_CONDITIONAL([COND_XZ], [test x$enable_xz != xno])
486 AC_ARG_ENABLE([xzdec], [AS_HELP_STRING([--disable-xzdec],
487 [do not build xzdec])],
488 [], [enable_xzdec=yes])
489 test "x$enable_decoders" = xno && enable_xzdec=no
490 AM_CONDITIONAL([COND_XZDEC], [test x$enable_xzdec != xno])
492 AC_ARG_ENABLE([lzmadec], [AS_HELP_STRING([--disable-lzmadec],
493 [do not build lzmadec
494 (it exists primarily for LZMA Utils compatibility)])],
495 [], [enable_lzmadec=yes])
496 test "x$enable_decoder_lzma1" = xno && enable_lzmadec=no
497 AM_CONDITIONAL([COND_LZMADEC], [test x$enable_lzmadec != xno])
499 AC_ARG_ENABLE([lzmainfo], [AS_HELP_STRING([--disable-lzmainfo],
500 [do not build lzmainfo
501 (it exists primarily for LZMA Utils compatibility)])],
502 [], [enable_lzmainfo=yes])
503 test "x$enable_decoder_lzma1" = xno && enable_lzmainfo=no
504 AM_CONDITIONAL([COND_LZMAINFO], [test x$enable_lzmainfo != xno])
506 AC_ARG_ENABLE([lzma-links], [AS_HELP_STRING([--disable-lzma-links],
507 [do not create symlinks for LZMA Utils compatibility])],
508 [], [enable_lzma_links=yes])
509 AM_CONDITIONAL([COND_LZMALINKS], [test x$enable_lzma_links != xno])
511 AC_ARG_ENABLE([scripts], [AS_HELP_STRING([--disable-scripts],
512 [do not install the scripts xzdiff, xzgrep, xzless, xzmore,
513 and their symlinks])],
514 [], [enable_scripts=yes])
515 AM_CONDITIONAL([COND_SCRIPTS], [test x$enable_scripts != xno])
517 AC_ARG_ENABLE([doc], [AS_HELP_STRING([--disable-doc],
518 [do not install documentation files to docdir
519 (man pages will still be installed)])],
520 [], [enable_doc=yes])
521 AM_CONDITIONAL([COND_DOC], [test x$enable_doc != xno])
524 ##############
525 # Sandboxing #
526 ##############
528 AC_MSG_CHECKING([if sandboxing should be used])
529 AC_ARG_ENABLE([sandbox], [AS_HELP_STRING([--enable-sandbox=METHOD],
530 [Sandboxing METHOD can be
531 'auto', 'no', 'capsicum', 'pledge', or 'landlock'.
532 The default is 'auto' which enables sandboxing if
533 a supported sandboxing method is found.])],
534 [], [enable_sandbox=auto])
535 case $enable_xzdec-$enable_xz-$enable_sandbox in
536 no-no-*)
537 enable_sandbox=no
538 AC_MSG_RESULT([no, --disable-xz and --disable-xzdec was used])
539 ;;
540 *-*-auto)
541 AC_MSG_RESULT([maybe (autodetect)])
542 ;;
543 *-*-no | *-*-capsicum | *-*-pledge | *-*-landlock)
544 AC_MSG_RESULT([$enable_sandbox])
545 ;;
546 *)
547 AC_MSG_RESULT([])
548 AC_MSG_ERROR([--enable-sandbox only accepts 'auto', 'no', 'capsicum', 'pledge', or 'landlock'.])
549 ;;
550 esac
553 ###########################
554 # PATH prefix for scripts #
555 ###########################
557 # The scripts can add a prefix to the search PATH so that POSIX tools
558 # or the xz binary is always in the PATH.
559 AC_ARG_ENABLE([path-for-scripts],
560 [AS_HELP_STRING([--enable-path-for-scripts=PREFIX],
561 [If PREFIX isn't empty, PATH=PREFIX:$PATH will be set in
562 the beginning of the scripts (xzgrep and others).
563 The default is empty except on Solaris the default is
564 /usr/xpg4/bin.])],
565 [], [
566 case $host_os in
567 solaris*) enable_path_for_scripts=/usr/xpg4/bin ;;
568 *) enable_path_for_scripts= ;;
569 esac
570 ])
571 if test -n "$enable_path_for_scripts" && test "x$enable_path_for_scripts" != xno ; then
572 enable_path_for_scripts="PATH=$enable_path_for_scripts:\$PATH"
573 else
574 enable_path_for_scripts=
575 fi
576 AC_SUBST([enable_path_for_scripts])
579 ###############################################################################
580 # Checks for programs.
581 ###############################################################################
583 echo
584 case $host_os in
585 solaris*)
586 # The gnulib POSIX shell macro below may pick a shell that
587 # doesn't work with xzgrep. Workaround by picking a shell
588 # that is known to work.
589 if test -z "$gl_cv_posix_shell" && test -x /usr/xpg4/bin/sh; then
590 gl_cv_posix_shell=/usr/xpg4/bin/sh
591 fi
592 ;;
593 esac
594 gl_POSIX_SHELL
595 if test -z "$POSIX_SHELL" && test "x$enable_scripts" = xyes ; then
596 AC_MSG_ERROR([No POSIX conforming shell (sh) was found.])
597 fi
599 echo
600 echo "Initializing Automake:"
602 # We don't use "subdir-objects" yet because it breaks "make distclean" when
603 # dependencies are enabled (as of Automake 1.14.1) due to this bug:
604 # https://debbugs.gnu.org/cgi/bugreport.cgi?bug=17354
605 # The -Wno-unsupported is used to silence warnings about missing
606 # "subdir-objects".
607 AM_INIT_AUTOMAKE([1.12 foreign tar-v7 filename-length-max=99 -Wno-unsupported])
608 AC_PROG_LN_S
610 dnl # Autoconf >= 2.70 warns that AC_PROG_CC_C99 is obsolete. However,
611 dnl # we have to keep using AC_PROG_CC_C99 instead of AC_PROG_CC
612 dnl # as long as we try to be compatible with Autoconf 2.69.
613 AC_PROG_CC_C99
614 if test x$ac_cv_prog_cc_c99 = xno ; then
615 AC_MSG_ERROR([No C99 compiler was found.])
616 fi
618 AM_PROG_CC_C_O
619 AM_PROG_AS
620 AC_USE_SYSTEM_EXTENSIONS
622 AS_CASE([$enable_threads],
623 [posix], [
624 echo
625 echo "POSIX threading support:"
626 AX_PTHREAD([:]) dnl We don't need the HAVE_PTHREAD macro.
627 LIBS="$LIBS $PTHREAD_LIBS"
628 AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"
630 dnl NOTE: PTHREAD_CC is ignored. It would be useful on AIX,
631 dnl but it's tricky to get it right together with
632 dnl AC_PROG_CC_C99. Thus, this is handled by telling the
633 dnl user in INSTALL to set the correct CC manually.
635 AC_DEFINE([MYTHREAD_POSIX], [1],
636 [Define to 1 when using POSIX threads (pthreads).])
638 # This is nice to have but not mandatory.
639 OLD_CFLAGS=$CFLAGS
640 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
641 AC_CHECK_FUNCS([pthread_condattr_setclock])
642 CFLAGS=$OLD_CFLAGS
643 ],
644 [win95], [
645 AC_DEFINE([MYTHREAD_WIN95], [1], [Define to 1 when using
646 Windows 95 (and thus XP) compatible threads.
647 This avoids use of features that were added in
648 Windows Vista.])
649 ],
650 [vista], [
651 AC_DEFINE([MYTHREAD_VISTA], [1], [Define to 1 when using
652 Windows Vista compatible threads. This uses
653 features that are not available on Windows XP.])
654 ]
655 )
656 AM_CONDITIONAL([COND_THREADS], [test "x$enable_threads" != xno])
658 echo
659 echo "Initializing Libtool:"
660 LT_PREREQ([2.4])
661 LT_INIT([win32-dll])
662 LT_LANG([Windows Resource])
664 # This is a bit wrong since it is possible to request that only some libs
665 # are built as shared. Using that feature isn't so common though, and this
666 # breaks only on Windows (at least for now) if the user enables only some
667 # libs as shared.
668 AM_CONDITIONAL([COND_SHARED], [test "x$enable_shared" != xno])
670 #####################
671 # Symbol versioning #
672 #####################
674 # NOTE: This checks if we are building shared or static library
675 # and if --with-pic or --without-pic was used. Thus this check
676 # must be after Libtool initialization.
677 AC_MSG_CHECKING([if library symbol versioning should be used])
678 AC_ARG_ENABLE([symbol-versions], [AS_HELP_STRING([--enable-symbol-versions],
679 [Use symbol versioning for liblzma. Enabled by default on
680 GNU/Linux, other GNU-based systems, and FreeBSD.])],
681 [], [enable_symbol_versions=auto])
682 if test "x$enable_symbol_versions" = xauto; then
683 case $host_os in
684 # NOTE: Even if one omits -gnu on GNU/Linux (e.g.
685 # i486-slackware-linux), configure will (via config.sub)
686 # append -gnu (e.g. i486-slackware-linux-gnu), and this
687 # test will work correctly.
688 gnu* | *-gnu* | freebsd*)
689 enable_symbol_versions=yes
690 ;;
691 *)
692 enable_symbol_versions=no
693 ;;
694 esac
695 fi
697 # There are two variants for symbol versioning.
698 # See src/liblzma/validate_map.sh for details.
699 #
700 # On GNU/Linux, extra symbols are added in the C code. These extra symbols
701 # must not be put into a static library as they can cause problems (and
702 # even if they didn't cause problems, they would be useless). On other
703 # systems symbol versioning may be used too but there is no problem as only
704 # a linker script is specified in src/liblzma/Makefile.am and that isn't
705 # used when creating a static library.
706 #
707 # Libtool always uses -DPIC when building shared libraries by default and
708 # doesn't use it for static libs by default. This can be overridden with
709 # --with-pic and --without-pic though. As long as neither --with-pic nor
710 # --without-pic is used then we can use #ifdef PIC to detect if the file is
711 # being built for a shared library.
712 if test "x$enable_symbol_versions" = xno ; then
713 enable_symbol_versions=no
714 AC_MSG_RESULT([no])
715 elif test "x$enable_shared" = xno ; then
716 enable_symbol_versions=no
717 AC_MSG_RESULT([no (not building a shared library)])
718 else
719 case "$host_cpu-$host_os" in
720 microblaze*)
721 # GCC 12 on MicroBlaze doesn't support __symver__
722 # attribute. It's simplest and safest to use the
723 # generic version on that platform since then only
724 # the linker script is needed. The RHEL/CentOS 7
725 # compatibility symbols don't matter on MicroBlaze.
726 enable_symbol_versions=generic
727 ;;
728 *-linux*)
729 case "$pic_mode-$enable_static" in
730 default-*)
731 # Use symvers if PIC is defined.
732 have_symbol_versions_linux=2
733 ;;
734 *-no)
735 # Not building static library.
736 # Use symvers unconditionally.
737 have_symbol_versions_linux=1
738 ;;
739 *)
740 AC_MSG_RESULT([])
741 AC_MSG_ERROR([
742 On GNU/Linux, building both shared and static library at the same time
743 is not supported if --with-pic or --without-pic is used.
744 Use either --disable-shared or --disable-static to build one type
745 of library at a time. If both types are needed, build one at a time,
746 possibly picking only src/liblzma/.libs/liblzma.a from the static build.])
747 ;;
748 esac
749 enable_symbol_versions=linux
750 AC_DEFINE_UNQUOTED([HAVE_SYMBOL_VERSIONS_LINUX],
751 [$have_symbol_versions_linux],
752 [Define to 1 to if GNU/Linux-specific details
753 are unconditionally wanted for symbol
754 versioning. Define to 2 to if these are wanted
755 only if also PIC is defined (allows building
756 both shared and static liblzma at the same
757 time with Libtool if neither --with-pic nor
758 --without-pic is used). This define must be
759 used together with liblzma_linux.map.])
760 ;;
761 *)
762 enable_symbol_versions=generic
763 ;;
764 esac
765 AC_MSG_RESULT([yes ($enable_symbol_versions)])
766 fi
768 AM_CONDITIONAL([COND_SYMVERS_LINUX],
769 [test "x$enable_symbol_versions" = xlinux])
770 AM_CONDITIONAL([COND_SYMVERS_GENERIC],
771 [test "x$enable_symbol_versions" = xgeneric])
774 ###############################################################################
775 # Checks for libraries.
776 ###############################################################################
778 dnl Support for _REQUIRE_VERSION was added in gettext 0.19.6. If both
779 dnl _REQUIRE_VERSION and _VERSION are present, the _VERSION is ignored.
780 dnl We use both for compatibility with other programs in the Autotools family.
781 echo
782 echo "Initializing gettext:"
783 AM_GNU_GETTEXT_REQUIRE_VERSION([0.19.6])
784 AM_GNU_GETTEXT_VERSION([0.19.6])
785 AM_GNU_GETTEXT([external])
788 ###############################################################################
789 # Checks for header files.
790 ###############################################################################
792 echo
793 echo "System headers and functions:"
795 # There is currently no workarounds in this package if some of
796 # these headers are missing.
797 AC_CHECK_HEADERS([fcntl.h limits.h sys/time.h],
798 [],
799 [AC_MSG_ERROR([Required header file(s) are missing.])])
801 # immintrin.h allows the use of the intrinsic functions if they are available.
802 # cpuid.h may be used for detecting x86 processor features at runtime.
803 AC_CHECK_HEADERS([immintrin.h cpuid.h])
806 ###############################################################################
807 # Checks for typedefs, structures, and compiler characteristics.
808 ###############################################################################
810 AC_HEADER_STDBOOL
812 AC_TYPE_UINT8_T
813 AC_TYPE_UINT16_T
814 AC_TYPE_INT32_T
815 AC_TYPE_UINT32_T
816 AC_TYPE_INT64_T
817 AC_TYPE_UINT64_T
818 AC_TYPE_UINTPTR_T
820 AC_CHECK_SIZEOF([size_t])
822 # The command line tool can copy high resolution timestamps if such
823 # information is available in struct stat. Otherwise one second accuracy
824 # is used.
825 AC_CHECK_MEMBERS([
826 struct stat.st_atim.tv_nsec,
827 struct stat.st_atimespec.tv_nsec,
828 struct stat.st_atimensec,
829 struct stat.st_uatime,
830 struct stat.st_atim.st__tim.tv_nsec])
832 AC_SYS_LARGEFILE
833 AC_C_BIGENDIAN
835 # __attribute__((__constructor__)) can be used for one-time initializations.
836 # Use -Werror because some compilers accept unknown attributes and just
837 # give a warning.
838 #
839 # FIXME? Unfortunately -Werror can cause trouble if CFLAGS contains options
840 # that produce warnings for unrelated reasons. For example, GCC and Clang
841 # support -Wunused-macros which will warn about "#define _GNU_SOURCE 1"
842 # which will be among the #defines that Autoconf inserts to the beginning of
843 # the test program. There seems to be no nice way to prevent Autoconf from
844 # inserting the any defines to the test program.
845 AC_MSG_CHECKING([if __attribute__((__constructor__)) can be used])
846 have_func_attribute_constructor=no
847 OLD_CFLAGS="$CFLAGS"
848 CFLAGS="$CFLAGS -Werror"
849 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
850 __attribute__((__constructor__))
851 static void my_constructor_func(void) { return; }
852 ]])], [
853 AC_DEFINE([HAVE_FUNC_ATTRIBUTE_CONSTRUCTOR], [1],
854 [Define to 1 if __attribute__((__constructor__))
855 is supported for functions.])
856 have_func_attribute_constructor=yes
857 AC_MSG_RESULT([yes])
858 ], [
859 AC_MSG_RESULT([no])
860 ])
861 CFLAGS="$OLD_CFLAGS"
863 # The Win95 threading lacks a thread-safe one-time initialization function.
864 # The one-time initialization is needed for crc32_small.c and crc64_small.c
865 # create the CRC tables. So if small mode is enabled, the threading mode is
866 # win95, and the compiler does not support attribute constructor, then we
867 # would end up with a multithreaded build that is thread-unsafe. As a
868 # result this configuration is not allowed.
869 if test "x$enable_small$enable_threads$have_func_attribute_constructor" \
870 = xyeswin95no; then
871 AC_MSG_ERROR([
872 --enable-threads=win95 and --enable-small cannot be used
873 at the same time with a compiler that doesn't support
874 __attribute__((__constructor__))])
875 fi
877 # __attribute__((__ifunc__())) can be used to choose between different
878 # implementations of the same function at runtime. This is slightly more
879 # efficient than using __attribute__((__constructor__)) and setting
880 # a function pointer.
881 AC_ARG_ENABLE([ifunc], [AS_HELP_STRING([--enable-ifunc],
882 [Use __attribute__((__ifunc__())). Enabled by default on
883 GNU/Linux (glibc) and FreeBSD.])],
884 [], [enable_ifunc=auto])
886 # When enable_ifunc is 'auto', allow the use of __attribute__((__ifunc__()))
887 # if compiler support is detected and we are building for GNU/Linux (glibc)
888 # or FreeBSD. uClibc and musl don't support ifunc in their dynamic linkers
889 # but some compilers still accept the attribute when compiling for these
890 # C libraries, which results in broken binaries. That's why we need to
891 # check which libc is being used.
892 if test "x$enable_ifunc" = xauto ; then
893 OLD_CFLAGS="$CFLAGS"
894 CFLAGS="$CFLAGS -Werror"
895 AC_MSG_CHECKING([if __attribute__((__ifunc__())) can be used])
896 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
897 /*
898 * Force a compilation error when not using glibc on Linux
899 * or if we are not using FreeBSD. uClibc will define
900 * __GLIBC__ but does not support ifunc, so we must have
901 * an extra check to disable with uClibc.
902 */
903 #if defined(__linux__)
904 # include <features.h>
905 # if !defined(__GLIBC__) || defined(__UCLIBC__)
906 compile error
907 # endif
908 #elif !defined(__FreeBSD__)
909 compile error
910 #endif
912 static void func(void) { return; }
913 static void (*resolve_func (void)) (void) { return func; }
914 void func_ifunc (void)
915 __attribute__((__ifunc__("resolve_func")));
916 /*
917 * 'clang -Wall' incorrectly warns that resolve_func is
918 * unused (-Wunused-function). Correct assembly output is
919 * still produced. This problem exists at least in Clang
920 * versions 4 to 17. The following silences the bogus warning:
921 */
922 void make_clang_quiet(void);
923 void make_clang_quiet(void) { resolve_func()(); }
924 ]])], [
925 enable_ifunc=yes
926 ], [
927 enable_ifunc=no
928 ])
930 AC_MSG_RESULT([$enable_ifunc])
932 CFLAGS="$OLD_CFLAGS"
933 fi
935 if test "x$enable_ifunc" = xyes ; then
936 AC_DEFINE([HAVE_FUNC_ATTRIBUTE_IFUNC], [1],
937 [Define to 1 if __attribute__((__ifunc__()))
938 is supported for functions.])
940 # ifunc explicitly does not work with -fsanitize=address.
941 # If configured, it will result in a liblzma build that will fail
942 # when liblzma is loaded at runtime (when the ifunc resolver
943 # executes).
944 AS_CASE([$CFLAGS], [*-fsanitize=*], [AC_MSG_ERROR([
945 CFLAGS contains '-fsanitize=' which is incompatible with ifunc.
946 Use --disable-ifunc when using '-fsanitize'.])])
947 fi
950 ###############################################################################
951 # Checks for library functions.
952 ###############################################################################
954 # Gnulib replacements as needed
955 gl_GETOPT
957 # If clock_gettime() is available, liblzma with pthreads may use it, and
958 # xz may use it even when threading support is disabled. In XZ Utils 5.4.x
959 # and older, configure checked for clock_gettime() only when using pthreads.
960 # This way non-threaded builds of liblzma didn't get a useless dependency on
961 # librt which further had a dependency on libpthread. Avoiding these was
962 # useful when a small build was needed, for example, for initramfs use.
963 #
964 # The above reasoning is thoroughly obsolete: On GNU/Linux, librt hasn't
965 # been needed for clock_gettime() since glibc 2.17 (2012-12-25).
966 # Solaris 10 needs librt but Solaris 11 doesn't anymore.
967 AC_SEARCH_LIBS([clock_gettime], [rt])
968 AC_CHECK_FUNCS([clock_gettime])
969 AC_CHECK_DECL([CLOCK_MONOTONIC], [AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1],
970 [Define to 1 if 'CLOCK_MONOTONIC' is declared in <time.h>.])], [],
971 [[#include <time.h>]])
973 # Find the best function to set timestamps.
974 AC_CHECK_FUNCS([futimens futimes futimesat utimes _futime utime], [break])
976 # This is nice to have but not mandatory.
977 AC_CHECK_FUNCS([posix_fadvise])
979 TUKLIB_PROGNAME
980 TUKLIB_INTEGER
981 TUKLIB_PHYSMEM
982 TUKLIB_CPUCORES
983 TUKLIB_MBSTR
985 # If requested, check for system-provided SHA-256. At least the following
986 # implementations are supported:
987 #
988 # OS Headers Library Type Function
989 # FreeBSD sys/types.h + sha256.h libmd SHA256_CTX SHA256_Init
990 # NetBSD sys/types.h + sha2.h SHA256_CTX SHA256_Init
991 # OpenBSD sys/types.h + sha2.h SHA2_CTX SHA256Init
992 # Solaris sys/types.h + sha2.h libmd SHA256_CTX SHA256Init
993 # MINIX 3 sys/types.h + sha2.h SHA256_CTX SHA256_Init
994 # Darwin CommonCrypto/CommonDigest.h CC_SHA256_CTX CC_SHA256_Init
995 #
996 # Note that Darwin's CC_SHA256_Update takes buffer size as uint32_t instead
997 # of size_t.
998 #
999 sha256_header_found=no
1000 sha256_type_found=no
1001 sha256_func_found=no
1002 AS_IF([test "x$enable_external_sha256" = "xyes"], [
1003 # Test for Common Crypto before others, because Darwin has sha256.h
1004 # too and we don't want to use that, because on older versions it
1005 # uses OpenSSL functions, whose SHA256_Init is not guaranteed to
1006 # succeed.
1007 AC_CHECK_HEADERS(
1008 [CommonCrypto/CommonDigest.h sha256.h sha2.h],
1009 [sha256_header_found=yes ; break])
1010 if test "x$sha256_header_found" = xyes; then
1011 AC_CHECK_TYPES([CC_SHA256_CTX, SHA256_CTX, SHA2_CTX],
1012 [sha256_type_found=yes], [],
1013 [[#ifdef HAVE_SYS_TYPES_H
1014 # include <sys/types.h>
1015 #endif
1016 #ifdef HAVE_COMMONCRYPTO_COMMONDIGEST_H
1017 # include <CommonCrypto/CommonDigest.h>
1018 #endif
1019 #ifdef HAVE_SHA256_H
1020 # include <sha256.h>
1021 #endif
1022 #ifdef HAVE_SHA2_H
1023 # include <sha2.h>
1024 #endif]])
1025 if test "x$sha256_type_found" = xyes ; then
1026 AC_SEARCH_LIBS([SHA256Init], [md])
1027 AC_SEARCH_LIBS([SHA256_Init], [md])
1028 AC_CHECK_FUNCS([CC_SHA256_Init SHA256Init SHA256_Init],
1029 [sha256_func_found=yes ; break])
1030 fi
1031 fi
1032 ])
1033 AM_CONDITIONAL([COND_INTERNAL_SHA256], [test "x$sha256_func_found" = xno])
1034 if test "x$enable_external_sha256$sha256_func_found" = xyesno; then
1035 AC_MSG_ERROR([--enable-external-sha256 was specified but no supported external SHA-256 implementation was found])
1036 fi
1038 # Check for SSE2 intrinsics. There is no run-time detection for SSE2 so if
1039 # compiler options enable SSE2 then SSE2 support is required by the binaries.
1040 # The compile-time check for SSE2 is done with #ifdefs because some compilers
1041 # (ICC, MSVC) allow SSE2 intrinsics even when SSE2 isn't enabled.
1042 AC_CHECK_DECL([_mm_movemask_epi8],
1043 [AC_DEFINE([HAVE__MM_MOVEMASK_EPI8], [1],
1044 [Define to 1 if _mm_movemask_epi8 is available.])],
1045 [],
1046 [#ifdef HAVE_IMMINTRIN_H
1047 #include <immintrin.h>
1048 #endif])
1050 # For faster CRC on 32/64-bit x86 and E2K (see also crc64_fast.c):
1051 #
1052 # - Check for the CLMUL intrinsic _mm_clmulepi64_si128 in <immintrin.h>.
1053 # Check also for _mm_set_epi64x for consistency with CMake build
1054 # where it's needed to disable CLMUL with VS2013.
1055 #
1056 # - Check that __attribute__((__target__("ssse3,sse4.1,pclmul"))) works
1057 # together with _mm_clmulepi64_si128 from <immintrin.h>. The attribute
1058 # was added in GCC 4.4 but some GCC 4.x versions don't allow intrinsics
1059 # with it. Exception: it must be not be used with EDG-based compilers
1060 # like ICC and the compiler on E2K.
1061 #
1062 # If everything above is supported, runtime detection will be used to keep the
1063 # binaries working on systems that don't support the required extensions.
1064 AC_MSG_CHECKING([if _mm_clmulepi64_si128 is usable])
1065 AS_IF([test "x$enable_clmul_crc" = xno], [
1066 AC_MSG_RESULT([no, --disable-clmul-crc was used])
1067 ], [
1068 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1069 #include <immintrin.h>
1071 // CLMUL works on older E2K instruction set but it is slow due to emulation.
1072 #if defined(__e2k__) && __iset__ < 6
1073 # error
1074 #endif
1076 // Intel's old compiler (ICC) can define __GNUC__ but the attribute must not
1077 // be used with it. The new Clang-based ICX needs the attribute.
1078 // Checking for !defined(__EDG__) catches ICC and other EDG-based compilers.
1079 #if (defined(__GNUC__) || defined(__clang__)) && !defined(__EDG__)
1080 __attribute__((__target__("ssse3,sse4.1,pclmul")))
1081 #endif
1082 __m128i my_clmul(__m128i a)
1083 {
1084 const __m128i b = _mm_set_epi64x(1, 2);
1085 return _mm_clmulepi64_si128(a, b, 0);
1086 }
1087 ]])], [
1088 AC_DEFINE([HAVE_USABLE_CLMUL], [1],
1089 [Define to 1 if _mm_set_epi64x and
1090 _mm_clmulepi64_si128 are usable.
1091 See configure.ac for details.])
1092 enable_clmul_crc=yes
1093 ], [
1094 enable_clmul_crc=no
1095 ])
1096 AC_MSG_RESULT([$enable_clmul_crc])
1097 ])
1099 # ARM64 C Language Extensions define CRC32 functions in arm_acle.h.
1100 # These are supported by at least GCC and Clang which both need
1101 # __attribute__((__target__("+crc"))), unless the needed compiler flags
1102 # are used to support the CRC instruction.
1103 AC_MSG_CHECKING([if ARM64 CRC32 instruction is usable])
1104 AS_IF([test "x$enable_arm64_crc32" = xno], [
1105 AC_MSG_RESULT([no, --disable-arm64-crc32 was used])
1106 ], [
1107 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1108 #include <arm_acle.h>
1109 #include <stdint.h>
1111 #if (defined(__GNUC__) || defined(__clang__)) && !defined(__EDG__)
1112 __attribute__((__target__("+crc")))
1113 #endif
1114 uint32_t my_crc(uint32_t a, uint64_t b)
1115 {
1116 return __crc32d(a, b);
1117 }
1118 ]])], [
1119 AC_DEFINE([HAVE_ARM64_CRC32], [1],
1120 [Define to 1 if ARM64 CRC32 instruction is supported.
1121 See configure.ac for details.])
1122 enable_arm64_crc32=yes
1123 ], [
1124 enable_arm64_crc32=no
1125 ])
1126 AC_MSG_RESULT([$enable_arm64_crc32])
1127 ])
1129 # Check for ARM64 CRC32 instruction runtime detection.
1130 # getauxval() is supported on Linux, elf_aux_info() on FreeBSD, and
1131 # sysctlbyname("hw.optional.armv8_crc32", ...) is supported on Darwin
1132 # (macOS, iOS, etc.). Note that sysctlbyname() is supported on FreeBSD,
1133 # NetBSD, and possibly others too but the string is specific to Apple OSes.
1134 # The C code is responsible for checking defined(__APPLE__) before using
1135 # sysctlbyname("hw.optional.armv8_crc32", ...).
1136 AS_IF([test "x$enable_arm64_crc32" = xyes], [
1137 AC_CHECK_FUNCS([getauxval elf_aux_info sysctlbyname])
1138 ])
1141 # Check for sandbox support. If one is found, set enable_sandbox=found.
1142 #
1143 # About -fsanitize: Of our three sandbox methods, only Landlock is
1144 # incompatible with -fsanitize. FreeBSD 13.2 with Capsicum was tested with
1145 # -fsanitize=address,undefined and had no issues. OpenBSD (as of version
1146 # 7.4) has minimal support for process instrumentation. OpenBSD does not
1147 # distribute the additional libraries needed (libasan, libubsan, etc.) with
1148 # GCC or Clang needed for runtime sanitization support and instead only
1149 # support -fsanitize-minimal-runtime for minimal undefined behavior
1150 # sanitization. This minimal support is compatible with our use of the
1151 # Pledge sandbox. So only Landlock will result in a build that cannot
1152 # compress or decompress a single file to standard out.
1153 AS_CASE([$enable_sandbox],
1154 [auto | capsicum], [
1155 AC_CHECK_FUNCS([cap_rights_limit], [enable_sandbox=found])
1156 ]
1157 )
1158 AS_CASE([$enable_sandbox],
1159 [auto | pledge], [
1160 AC_CHECK_FUNCS([pledge], [enable_sandbox=found])
1161 ]
1162 )
1163 AS_CASE([$enable_sandbox],
1164 [auto | landlock], [
1165 AC_CHECK_HEADERS([linux/landlock.h], [
1166 enable_sandbox=found
1168 AS_CASE([$CFLAGS], [*-fsanitize=*], [AC_MSG_ERROR([
1169 CFLAGS contains '-fsanitize=' which is incompatible with the Landlock
1170 sandboxing. Use --disable-sandbox when using '-fsanitize'.])])
1171 ])
1172 ]
1173 )
1175 # If a specific sandboxing method was explicitly requested and it wasn't
1176 # found, give an error.
1177 case $enable_sandbox in
1178 auto | no | found)
1179 ;;
1180 *)
1181 AC_MSG_ERROR([$enable_sandbox support not found])
1182 ;;
1183 esac
1186 ###############################################################################
1187 # If using GCC, set some additional AM_CFLAGS:
1188 ###############################################################################
1190 if test "$GCC" = yes ; then
1191 echo
1192 echo "GCC extensions:"
1193 fi
1195 # Always do the visibility check but don't set AM_CFLAGS on Windows.
1196 # This way things get set properly even on Windows.
1197 gl_VISIBILITY
1198 if test -n "$CFLAG_VISIBILITY" && test "$is_w32" = no; then
1199 AM_CFLAGS="$AM_CFLAGS $CFLAG_VISIBILITY"
1200 fi
1202 AS_IF([test "$GCC" = yes], [
1203 # Enable as much warnings as possible. These commented warnings won't
1204 # work for this package though:
1205 # * -Wunreachable-code breaks several assert(0) cases, which are
1206 # backed up with "return LZMA_PROG_ERROR".
1207 # * -Wcast-qual would break various things where we need a non-const
1208 # pointer although we don't modify anything through it.
1209 # * -Winline, -Wdisabled-optimization, -Wunsafe-loop-optimizations
1210 # don't seem so useful here; at least the last one gives some
1211 # warnings which are not bugs.
1212 # * -Wconversion still shows too many warnings.
1213 #
1214 # The flags before the empty line are for GCC and many of them
1215 # are supported by Clang too. The flags after the empty line are
1216 # for Clang.
1217 for NEW_FLAG in \
1218 -Wall \
1219 -Wextra \
1220 -Wvla \
1221 -Wformat=2 \
1222 -Winit-self \
1223 -Wmissing-include-dirs \
1224 -Wshift-overflow=2 \
1225 -Wstrict-overflow=3 \
1226 -Walloc-zero \
1227 -Wduplicated-cond \
1228 -Wfloat-equal \
1229 -Wundef \
1230 -Wshadow \
1231 -Wpointer-arith \
1232 -Wbad-function-cast \
1233 -Wwrite-strings \
1234 -Wdate-time \
1235 -Wsign-conversion \
1236 -Wfloat-conversion \
1237 -Wlogical-op \
1238 -Waggregate-return \
1239 -Wstrict-prototypes \
1240 -Wold-style-definition \
1241 -Wmissing-prototypes \
1242 -Wmissing-declarations \
1243 -Wredundant-decls \
1244 \
1245 -Wc99-compat \
1246 -Wc11-extensions \
1247 -Wc2x-compat \
1248 -Wc2x-extensions \
1249 -Wpre-c2x-compat \
1250 -Warray-bounds-pointer-arithmetic \
1251 -Wassign-enum \
1252 -Wconditional-uninitialized \
1253 -Wdocumentation \
1254 -Wduplicate-enum \
1255 -Wempty-translation-unit \
1256 -Wflexible-array-extensions \
1257 -Wmissing-variable-declarations \
1258 -Wnewline-eof \
1259 -Wshift-sign-overflow \
1260 -Wstring-conversion
1261 do
1262 AC_MSG_CHECKING([if $CC accepts $NEW_FLAG])
1263 OLD_CFLAGS="$CFLAGS"
1264 CFLAGS="$CFLAGS $NEW_FLAG -Werror"
1265 AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1266 [[void foo(void); void foo(void) { }]])], [
1267 AM_CFLAGS="$AM_CFLAGS $NEW_FLAG"
1268 AC_MSG_RESULT([yes])
1269 ], [
1270 AC_MSG_RESULT([no])
1271 ])
1272 CFLAGS="$OLD_CFLAGS"
1273 done
1275 AC_ARG_ENABLE([werror],
1276 AS_HELP_STRING([--enable-werror], [Enable -Werror to abort
1277 compilation on all compiler warnings.]),
1278 [], [enable_werror=no])
1279 if test "x$enable_werror" = "xyes"; then
1280 AM_CFLAGS="$AM_CFLAGS -Werror"
1281 fi
1282 ])
1285 ###############################################################################
1286 # Create the makefiles and config.h
1287 ###############################################################################
1289 echo
1291 # Don't build the lib directory at all if we don't need any replacement
1292 # functions.
1293 AM_CONDITIONAL([COND_GNULIB], test -n "$LIBOBJS")
1295 # Add default AM_CFLAGS.
1296 AC_SUBST([AM_CFLAGS])
1298 # This is needed for src/scripts.
1299 xz=`echo xz | sed "$program_transform_name"`
1300 AC_SUBST([xz])
1302 AC_CONFIG_FILES([
1303 Makefile
1304 po/Makefile.in
1305 lib/Makefile
1306 src/Makefile
1307 src/liblzma/Makefile
1308 src/liblzma/api/Makefile
1309 src/xz/Makefile
1310 src/xzdec/Makefile
1311 src/lzmainfo/Makefile
1312 src/scripts/Makefile
1313 tests/Makefile
1314 debug/Makefile
1315 ])
1316 AC_CONFIG_FILES([src/scripts/xzdiff], [chmod +x src/scripts/xzdiff])
1317 AC_CONFIG_FILES([src/scripts/xzgrep], [chmod +x src/scripts/xzgrep])
1318 AC_CONFIG_FILES([src/scripts/xzmore], [chmod +x src/scripts/xzmore])
1319 AC_CONFIG_FILES([src/scripts/xzless], [chmod +x src/scripts/xzless])
1321 AC_OUTPUT
1323 # Some warnings
1324 if test x$tuklib_cv_physmem_method = xunknown; then
1325 echo
1326 echo "WARNING:"
1327 echo "No supported method to detect the amount of RAM."
1328 echo "Consider using --enable-assume-ram (if you didn't already)"
1329 echo "or make a patch to add support for this operating system."
1330 fi
1332 if test x$tuklib_cv_cpucores_method = xunknown; then
1333 echo
1334 echo "WARNING:"
1335 echo "No supported method to detect the number of CPU cores."
1336 fi
1338 if test "x$enable_threads$enable_small$have_func_attribute_constructor" \
1339 = xnoyesno; then
1340 echo
1341 echo "NOTE:"
1342 echo "liblzma will be thread-unsafe due to the combination"
1343 echo "of --disable-threads --enable-small when using a compiler"
1344 echo "that doesn't support __attribute__((__constructor__))."
1345 fi