| blob | 1fe6101675b2b67cac8fc091463da6dfc8cb81ff |
1 # -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
4 ###############################################################################
5 #
6 # Author: Lasse Collin
7 #
8 # This file has been put into the public domain.
9 # You can do whatever you want with this file.
10 #
11 ###############################################################################
13 # NOTE: Don't add useless checks. autoscan detects this and that, but don't
14 # let it confuse you. For example, we don't care about checking for behavior
15 # of malloc(), stat(), or lstat(), since we don't use those functions in
16 # a way that would cause the problems the autoconf macros check.
18 AC_PREREQ([2.69])
20 AC_INIT([XZ Utils], m4_esyscmd([/bin/sh build-aux/version.sh]),
21 [xz@tukaani.org], [xz], [https://tukaani.org/xz/])
22 AC_CONFIG_SRCDIR([src/liblzma/common/common.h])
23 AC_CONFIG_AUX_DIR([build-aux])
24 AC_CONFIG_MACRO_DIR([m4])
25 AC_CONFIG_HEADERS([config.h])
27 echo
28 echo "$PACKAGE_STRING"
30 echo
31 echo "System type:"
32 # This is needed to know if assembler optimizations can be used.
33 AC_CANONICAL_HOST
35 # We do some special things on Windows (32-bit or 64-bit) builds.
36 case $host_os in
37 mingw* | cygwin | msys) is_w32=yes ;;
38 *) is_w32=no ;;
39 esac
40 AM_CONDITIONAL([COND_W32], [test "$is_w32" = yes])
42 # We need to use $EXEEXT with $(LN_S) when creating symlinks to
43 # executables. Cygwin is an exception to this, since it is recommended
44 # that symlinks don't have the .exe suffix. To make this work, we
45 # define LN_EXEEXT.
46 #
47 # MSYS2 is treated the same way as Cygwin. It uses plain "msys" like
48 # the original MSYS when building MSYS/MSYS2-binaries. Hopefully this
49 # doesn't break things for the original MSYS developers. Note that this
50 # doesn't affect normal MSYS/MSYS2 users building non-MSYS/MSYS2 binaries
51 # since in that case the $host_os is usually mingw32.
52 case $host_os in
53 cygwin | msys) LN_EXEEXT= ;;
54 *) LN_EXEEXT='$(EXEEXT)' ;;
55 esac
56 AC_SUBST([LN_EXEEXT])
58 echo
59 echo "Configure options:"
60 AM_CFLAGS=
63 #############
64 # Debugging #
65 #############
67 AC_MSG_CHECKING([if debugging code should be compiled])
68 AC_ARG_ENABLE([debug], AS_HELP_STRING([--enable-debug], [Enable debugging code.]),
69 [], enable_debug=no)
70 if test "x$enable_debug" = xyes; then
71 AC_MSG_RESULT([yes])
72 else
73 AC_DEFINE([NDEBUG], [1], [Define to 1 to disable debugging code.])
74 AC_MSG_RESULT([no])
75 fi
78 ###########
79 # Filters #
80 ###########
82 m4_define([SUPPORTED_FILTERS], [lzma1,lzma2,delta,x86,powerpc,ia64,arm,armthumb,arm64,sparc])dnl
83 m4_define([SIMPLE_FILTERS], [x86,powerpc,ia64,arm,armthumb,arm64,sparc])
84 m4_define([LZ_FILTERS], [lzma1,lzma2])
86 m4_foreach([NAME], [SUPPORTED_FILTERS],
87 [enable_filter_[]NAME=no
88 enable_encoder_[]NAME=no
89 enable_decoder_[]NAME=no
90 ])dnl
92 AC_MSG_CHECKING([which encoders to build])
93 AC_ARG_ENABLE([encoders], AS_HELP_STRING([--enable-encoders=LIST],
94 [Comma-separated list of encoders to build. Default=all.
95 Available encoders:]
96 m4_translit(m4_defn([SUPPORTED_FILTERS]), [,], [ ])),
97 [], [enable_encoders=SUPPORTED_FILTERS])
98 enable_encoders=`echo "$enable_encoders" | sed 's/,/ /g'`
99 if test "x$enable_encoders" = xno || test "x$enable_encoders" = x; then
100 enable_encoders=no
101 AC_MSG_RESULT([(none)])
102 else
103 for arg in $enable_encoders
104 do
105 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
106 NAME)
107 enable_filter_[]NAME=yes
108 enable_encoder_[]NAME=yes
109 AC_DEFINE(HAVE_ENCODER_[]m4_toupper(NAME), [1],
110 [Define to 1 if] NAME [encoder is enabled.])
111 ;;])
112 *)
113 AC_MSG_RESULT([])
114 AC_MSG_ERROR([unknown filter: $arg])
115 ;;
116 esac
117 done
118 AC_DEFINE([HAVE_ENCODERS], [1],
119 [Define to 1 if any of HAVE_ENCODER_foo have been defined.])
120 AC_MSG_RESULT([$enable_encoders])
121 fi
123 AC_MSG_CHECKING([which decoders to build])
124 AC_ARG_ENABLE([decoders], AS_HELP_STRING([--enable-decoders=LIST],
125 [Comma-separated list of decoders to build. Default=all.
126 Available decoders are the same as available encoders.]),
127 [], [enable_decoders=SUPPORTED_FILTERS])
128 enable_decoders=`echo "$enable_decoders" | sed 's/,/ /g'`
129 if test "x$enable_decoders" = xno || test "x$enable_decoders" = x; then
130 enable_decoders=no
131 AC_MSG_RESULT([(none)])
132 else
133 for arg in $enable_decoders
134 do
135 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
136 NAME)
137 enable_filter_[]NAME=yes
138 enable_decoder_[]NAME=yes
139 AC_DEFINE(HAVE_DECODER_[]m4_toupper(NAME), [1],
140 [Define to 1 if] NAME [decoder is enabled.])
141 ;;])
142 *)
143 AC_MSG_RESULT([])
144 AC_MSG_ERROR([unknown filter: $arg])
145 ;;
146 esac
147 done
148 AC_DEFINE([HAVE_DECODERS], [1],
149 [Define to 1 if any of HAVE_DECODER_foo have been defined.])
150 AC_MSG_RESULT([$enable_decoders])
151 fi
153 if test "x$enable_encoder_lzma2$enable_encoder_lzma1" = xyesno \
154 || test "x$enable_decoder_lzma2$enable_decoder_lzma1" = xyesno; then
155 AC_MSG_ERROR([LZMA2 requires that LZMA1 is also enabled.])
156 fi
158 AM_CONDITIONAL(COND_MAIN_ENCODER, test "x$enable_encoders" != xno)
159 AM_CONDITIONAL(COND_MAIN_DECODER, test "x$enable_decoders" != xno)
161 m4_foreach([NAME], [SUPPORTED_FILTERS],
162 [AM_CONDITIONAL(COND_FILTER_[]m4_toupper(NAME), test "x$enable_filter_[]NAME" = xyes)
163 AM_CONDITIONAL(COND_ENCODER_[]m4_toupper(NAME), test "x$enable_encoder_[]NAME" = xyes)
164 AM_CONDITIONAL(COND_DECODER_[]m4_toupper(NAME), test "x$enable_decoder_[]NAME" = xyes)
165 ])dnl
167 # The so called "simple filters" share common code.
168 enable_filter_simple=no
169 enable_encoder_simple=no
170 enable_decoder_simple=no
171 m4_foreach([NAME], [SIMPLE_FILTERS],
172 [test "x$enable_filter_[]NAME" = xyes && enable_filter_simple=yes
173 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_simple=yes
174 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_simple=yes
175 ])dnl
176 AM_CONDITIONAL(COND_FILTER_SIMPLE, test "x$enable_filter_simple" = xyes)
177 AM_CONDITIONAL(COND_ENCODER_SIMPLE, test "x$enable_encoder_simple" = xyes)
178 AM_CONDITIONAL(COND_DECODER_SIMPLE, test "x$enable_decoder_simple" = xyes)
180 # LZ-based filters share common code.
181 enable_filter_lz=no
182 enable_encoder_lz=no
183 enable_decoder_lz=no
184 m4_foreach([NAME], [LZ_FILTERS],
185 [test "x$enable_filter_[]NAME" = xyes && enable_filter_lz=yes
186 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_lz=yes
187 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_lz=yes
188 ])dnl
189 AM_CONDITIONAL(COND_FILTER_LZ, test "x$enable_filter_lz" = xyes)
190 AM_CONDITIONAL(COND_ENCODER_LZ, test "x$enable_encoder_lz" = xyes)
191 AM_CONDITIONAL(COND_DECODER_LZ, test "x$enable_decoder_lz" = xyes)
194 #################
195 # Match finders #
196 #################
198 m4_define([SUPPORTED_MATCH_FINDERS], [hc3,hc4,bt2,bt3,bt4])
200 m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS],
201 [enable_match_finder_[]NAME=no
202 ])
204 AC_MSG_CHECKING([which match finders to build])
205 AC_ARG_ENABLE([match-finders], AS_HELP_STRING([--enable-match-finders=LIST],
206 [Comma-separated list of match finders to build. Default=all.
207 At least one match finder is required for encoding with
208 the LZMA1 and LZMA2 filters. Available match finders:]
209 m4_translit(m4_defn([SUPPORTED_MATCH_FINDERS]), [,], [ ])), [],
210 [enable_match_finders=SUPPORTED_MATCH_FINDERS])
211 enable_match_finders=`echo "$enable_match_finders" | sed 's/,/ /g'`
212 if test "x$enable_encoder_lz" = xyes ; then
213 if test -z "$enable_match_finders"; then
214 AC_MSG_ERROR([At least one match finder is required for an LZ-based encoder.])
215 fi
217 for arg in $enable_match_finders
218 do
219 case $arg in m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS], [
220 NAME)
221 enable_match_finder_[]NAME=yes
222 AC_DEFINE(HAVE_MF_[]m4_toupper(NAME), [1],
223 [Define to 1 to enable] NAME [match finder.])
224 ;;])
225 *)
226 AC_MSG_RESULT([])
227 AC_MSG_ERROR([unknown match finder: $arg])
228 ;;
229 esac
230 done
231 AC_MSG_RESULT([$enable_match_finders])
232 else
233 AC_MSG_RESULT([(none because not building any LZ-based encoder)])
234 fi
237 ####################
238 # Integrity checks #
239 ####################
241 m4_define([SUPPORTED_CHECKS], [crc32,crc64,sha256])
243 m4_foreach([NAME], [SUPPORTED_CHECKS],
244 [enable_check_[]NAME=no
245 ])dnl
247 AC_MSG_CHECKING([which integrity checks to build])
248 AC_ARG_ENABLE([checks], AS_HELP_STRING([--enable-checks=LIST],
249 [Comma-separated list of integrity checks to build.
250 Default=all. Available integrity checks:]
251 m4_translit(m4_defn([SUPPORTED_CHECKS]), [,], [ ])),
252 [], [enable_checks=SUPPORTED_CHECKS])
253 enable_checks=`echo "$enable_checks" | sed 's/,/ /g'`
254 if test "x$enable_checks" = xno || test "x$enable_checks" = x; then
255 AC_MSG_RESULT([(none)])
256 else
257 for arg in $enable_checks
258 do
259 case $arg in m4_foreach([NAME], [SUPPORTED_CHECKS], [
260 NAME)
261 enable_check_[]NAME=yes
262 AC_DEFINE(HAVE_CHECK_[]m4_toupper(NAME), [1],
263 [Define to 1 if] NAME
264 [integrity check is enabled.])
265 ;;])
266 *)
267 AC_MSG_RESULT([])
268 AC_MSG_ERROR([unknown integrity check: $arg])
269 ;;
270 esac
271 done
272 AC_MSG_RESULT([$enable_checks])
273 fi
274 if test "x$enable_check_crc32" = xno ; then
275 AC_MSG_ERROR([For now, the CRC32 check must always be enabled.])
276 fi
278 m4_foreach([NAME], [SUPPORTED_CHECKS],
279 [AM_CONDITIONAL(COND_CHECK_[]m4_toupper(NAME), test "x$enable_check_[]NAME" = xyes)
280 ])dnl
282 AC_MSG_CHECKING([if external SHA-256 should be used])
283 AC_ARG_ENABLE([external-sha256], AS_HELP_STRING([--enable-external-sha256],
284 [Use SHA-256 code from the operating system.
285 See INSTALL for possible subtle problems.]),
286 [], [enable_external_sha256=no])
287 if test "x$enable_check_sha256" != "xyes"; then
288 enable_external_sha256=no
289 fi
290 if test "x$enable_external_sha256" = xyes; then
291 AC_MSG_RESULT([yes])
292 else
293 AC_MSG_RESULT([no])
294 fi
297 #############
298 # MicroLZMA #
299 #############
301 AC_MSG_CHECKING([if MicroLZMA support should be built])
302 AC_ARG_ENABLE([microlzma], AS_HELP_STRING([--disable-microlzma],
303 [Do not build MicroLZMA encoder and decoder.
304 It is needed by specific applications only,
305 for example, erofs-utils.]),
306 [], [enable_microlzma=yes])
307 case $enable_microlzma in
308 yes | no)
309 AC_MSG_RESULT([$enable_microlzma])
310 ;;
311 *)
312 AC_MSG_RESULT([])
313 AC_MSG_ERROR([--enable-microlzma accepts only 'yes' or 'no'.])
314 ;;
315 esac
316 AM_CONDITIONAL(COND_MICROLZMA, test "x$enable_microlzma" = xyes)
319 #############################
320 # .lz (lzip) format support #
321 #############################
323 AC_MSG_CHECKING([if .lz (lzip) decompression support should be built])
324 AC_ARG_ENABLE([lzip-decoder], AS_HELP_STRING([--disable-lzip-decoder],
325 [Disable decompression support for .lz (lzip) files.]),
326 [], [enable_lzip_decoder=yes])
327 if test "x$enable_decoder_lzma1" != xyes; then
328 enable_lzip_decoder=no
329 AC_MSG_RESULT([no because LZMA1 decoder is disabled])
330 elif test "x$enable_lzip_decoder" = xyes; then
331 AC_DEFINE([HAVE_LZIP_DECODER], [1],
332 [Define to 1 if .lz (lzip) decompression support is enabled.])
333 AC_MSG_RESULT([yes])
334 else
335 AC_MSG_RESULT([no])
336 fi
337 AM_CONDITIONAL(COND_LZIP_DECODER, test "x$enable_lzip_decoder" = xyes)
340 ###########################
341 # Assembler optimizations #
342 ###########################
344 AC_MSG_CHECKING([if assembler optimizations should be used])
345 AC_ARG_ENABLE([assembler], AS_HELP_STRING([--disable-assembler],
346 [Do not use assembler optimizations even if such exist
347 for the architecture.]),
348 [], [enable_assembler=yes])
349 if test "x$enable_assembler" = xyes; then
350 enable_assembler=no
351 case $host_os in
352 # Darwin should work too but only if not creating universal
353 # binaries. Solaris x86 could work too but I cannot test.
354 linux* | *bsd* | mingw* | cygwin | msys | *djgpp*)
355 case $host_cpu in
356 i?86) enable_assembler=x86 ;;
357 esac
358 ;;
359 esac
360 fi
361 case $enable_assembler in
362 x86 | no)
363 AC_MSG_RESULT([$enable_assembler])
364 ;;
365 *)
366 AC_MSG_RESULT([])
367 AC_MSG_ERROR([--enable-assembler accepts only 'yes', 'no', or 'x86' (32-bit).])
368 ;;
369 esac
370 AM_CONDITIONAL(COND_ASM_X86, test "x$enable_assembler" = xx86)
373 #############
374 # CLMUL CRC #
375 #############
377 AC_ARG_ENABLE([clmul-crc], AS_HELP_STRING([--disable-clmul-crc],
378 [Do not use carryless multiplication for CRC calculation
379 even if support for it is detected.]),
380 [], [enable_clmul_crc=yes])
383 #####################
384 # Size optimization #
385 #####################
387 AC_MSG_CHECKING([if small size is preferred over speed])
388 AC_ARG_ENABLE([small], AS_HELP_STRING([--enable-small],
389 [Make liblzma smaller and a little slower.
390 This is disabled by default to optimize for speed.]),
391 [], [enable_small=no])
392 if test "x$enable_small" = xyes; then
393 AC_DEFINE([HAVE_SMALL], [1], [Define to 1 if optimizing for size.])
394 elif test "x$enable_small" != xno; then
395 AC_MSG_RESULT([])
396 AC_MSG_ERROR([--enable-small accepts only 'yes' or 'no'])
397 fi
398 AC_MSG_RESULT([$enable_small])
399 AM_CONDITIONAL(COND_SMALL, test "x$enable_small" = xyes)
402 #############
403 # Threading #
404 #############
406 AC_MSG_CHECKING([if threading support is wanted])
407 AC_ARG_ENABLE([threads], AS_HELP_STRING([--enable-threads=METHOD],
408 [Supported METHODS are 'yes', 'no', 'posix', 'win95', and
409 'vista'. The default is 'yes'. Using 'no' together with
410 --enable-small makes liblzma thread unsafe.]),
411 [], [enable_threads=yes])
413 if test "x$enable_threads" = xyes; then
414 case $host_os in
415 mingw*)
416 case $host_cpu in
417 i?86) enable_threads=win95 ;;
418 *) enable_threads=vista ;;
419 esac
420 ;;
421 *)
422 enable_threads=posix
423 ;;
424 esac
425 fi
427 case $enable_threads in
428 posix | win95 | vista)
429 AC_MSG_RESULT([yes, $enable_threads])
430 ;;
431 no)
432 AC_MSG_RESULT([no])
433 ;;
434 *)
435 AC_MSG_RESULT([])
436 AC_MSG_ERROR([--enable-threads only accepts 'yes', 'no', 'posix', 'win95', or 'vista'])
437 ;;
438 esac
440 # We use the actual result a little later.
443 #########################
444 # Assumed amount of RAM #
445 #########################
447 # We use 128 MiB as default, because it will allow decompressing files
448 # created with "xz -9". It would be slightly safer to guess a lower value,
449 # but most systems, on which we don't have any way to determine the amount
450 # of RAM, will probably have at least 128 MiB of RAM.
451 AC_MSG_CHECKING([how much RAM to assume if the real amount is unknown])
452 AC_ARG_ENABLE([assume-ram], AS_HELP_STRING([--enable-assume-ram=SIZE],
453 [If and only if the real amount of RAM cannot be determined,
454 assume SIZE MiB. The default is 128 MiB. This affects the
455 default memory usage limit.]),
456 [], [enable_assume_ram=128])
457 assume_ram_check=`echo "$enable_assume_ram" | tr -d 0123456789`
458 if test -z "$enable_assume_ram" || test -n "$assume_ram_check"; then
459 AC_MSG_RESULT([])
460 AC_MSG_ERROR([--enable-assume-ram accepts only an integer argument])
461 fi
462 AC_MSG_RESULT([$enable_assume_ram MiB])
463 AC_DEFINE_UNQUOTED([ASSUME_RAM], [$enable_assume_ram],
464 [How many MiB of RAM to assume if the real amount cannot
465 be determined.])
468 #########################
469 # Components to install #
470 #########################
472 AC_ARG_ENABLE([xz], [AS_HELP_STRING([--disable-xz],
473 [do not build the xz tool])],
474 [], [enable_xz=yes])
475 AM_CONDITIONAL([COND_XZ], [test x$enable_xz != xno])
477 AC_ARG_ENABLE([xzdec], [AS_HELP_STRING([--disable-xzdec],
478 [do not build xzdec])],
479 [], [enable_xzdec=yes])
480 test "x$enable_decoders" = xno && enable_xzdec=no
481 AM_CONDITIONAL([COND_XZDEC], [test x$enable_xzdec != xno])
483 AC_ARG_ENABLE([lzmadec], [AS_HELP_STRING([--disable-lzmadec],
484 [do not build lzmadec
485 (it exists primarily for LZMA Utils compatibility)])],
486 [], [enable_lzmadec=yes])
487 test "x$enable_decoder_lzma1" = xno && enable_lzmadec=no
488 AM_CONDITIONAL([COND_LZMADEC], [test x$enable_lzmadec != xno])
490 AC_ARG_ENABLE([lzmainfo], [AS_HELP_STRING([--disable-lzmainfo],
491 [do not build lzmainfo
492 (it exists primarily for LZMA Utils compatibility)])],
493 [], [enable_lzmainfo=yes])
494 test "x$enable_decoder_lzma1" = xno && enable_lzmainfo=no
495 AM_CONDITIONAL([COND_LZMAINFO], [test x$enable_lzmainfo != xno])
497 AC_ARG_ENABLE([lzma-links], [AS_HELP_STRING([--disable-lzma-links],
498 [do not create symlinks for LZMA Utils compatibility])],
499 [], [enable_lzma_links=yes])
500 AM_CONDITIONAL([COND_LZMALINKS], [test x$enable_lzma_links != xno])
502 AC_ARG_ENABLE([scripts], [AS_HELP_STRING([--disable-scripts],
503 [do not install the scripts xzdiff, xzgrep, xzless, xzmore,
504 and their symlinks])],
505 [], [enable_scripts=yes])
506 AM_CONDITIONAL([COND_SCRIPTS], [test x$enable_scripts != xno])
508 AC_ARG_ENABLE([doc], [AS_HELP_STRING([--disable-doc],
509 [do not install documentation files to docdir
510 (man pages will still be installed)])],
511 [], [enable_doc=yes])
512 AM_CONDITIONAL([COND_DOC], [test x$enable_doc != xno])
515 ##############
516 # Sandboxing #
517 ##############
519 AC_MSG_CHECKING([if sandboxing should be used])
520 AC_ARG_ENABLE([sandbox], [AS_HELP_STRING([--enable-sandbox=METHOD],
521 [Sandboxing METHOD can be
522 'auto', 'no', 'capsicum', 'pledge', or 'landlock'.
523 The default is 'auto' which enables sandboxing if
524 a supported sandboxing method is found.])],
525 [], [enable_sandbox=auto])
526 case $enable_xz-$enable_sandbox in
527 no-*)
528 enable_sandbox=no
529 AC_MSG_RESULT([no, --disable-xz was used])
530 ;;
531 *-auto)
532 AC_MSG_RESULT([maybe (autodetect)])
533 ;;
534 *-no | *-capsicum | *-pledge | *-landlock)
535 AC_MSG_RESULT([$enable_sandbox])
536 ;;
537 *)
538 AC_MSG_RESULT([])
539 AC_MSG_ERROR([--enable-sandbox only accepts 'auto', 'no', 'capsicum', 'pledge', or 'landlock'.])
540 ;;
541 esac
544 ###########################
545 # PATH prefix for scripts #
546 ###########################
548 # The scripts can add a prefix to the search PATH so that POSIX tools
549 # or the xz binary is always in the PATH.
550 AC_ARG_ENABLE([path-for-scripts],
551 [AS_HELP_STRING([--enable-path-for-scripts=PREFIX],
552 [If PREFIX isn't empty, PATH=PREFIX:$PATH will be set in
553 the beginning of the scripts (xzgrep and others).
554 The default is empty except on Solaris the default is
555 /usr/xpg4/bin.])],
556 [], [
557 case $host_os in
558 solaris*) enable_path_for_scripts=/usr/xpg4/bin ;;
559 *) enable_path_for_scripts= ;;
560 esac
561 ])
562 if test -n "$enable_path_for_scripts" && test "x$enable_path_for_scripts" != xno ; then
563 enable_path_for_scripts="PATH=$enable_path_for_scripts:\$PATH"
564 else
565 enable_path_for_scripts=
566 fi
567 AC_SUBST([enable_path_for_scripts])
570 ###############################################################################
571 # Checks for programs.
572 ###############################################################################
574 echo
575 case $host_os in
576 solaris*)
577 # The gnulib POSIX shell macro below may pick a shell that
578 # doesn't work with xzgrep. Workaround by picking a shell
579 # that is known to work.
580 if test -z "$gl_cv_posix_shell" && test -x /usr/xpg4/bin/sh; then
581 gl_cv_posix_shell=/usr/xpg4/bin/sh
582 fi
583 ;;
584 esac
585 gl_POSIX_SHELL
586 if test -z "$POSIX_SHELL" && test "x$enable_scripts" = xyes ; then
587 AC_MSG_ERROR([No POSIX conforming shell (sh) was found.])
588 fi
590 echo
591 echo "Initializing Automake:"
593 # We don't use "subdir-objects" yet because it breaks "make distclean" when
594 # dependencies are enabled (as of Automake 1.14.1) due to this bug:
595 # https://debbugs.gnu.org/cgi/bugreport.cgi?bug=17354
596 # The -Wno-unsupported is used to silence warnings about missing
597 # "subdir-objects".
598 AM_INIT_AUTOMAKE([1.12 foreign tar-v7 filename-length-max=99 -Wno-unsupported])
599 AC_PROG_LN_S
601 dnl # Autoconf >= 2.70 warns that AC_PROG_CC_C99 is obsolete. However,
602 dnl # we have to keep using AC_PROG_CC_C99 instead of AC_PROG_CC
603 dnl # as long as we try to be compatible with Autoconf 2.69.
604 AC_PROG_CC_C99
605 if test x$ac_cv_prog_cc_c99 = xno ; then
606 AC_MSG_ERROR([No C99 compiler was found.])
607 fi
609 AM_PROG_CC_C_O
610 AM_PROG_AS
611 AC_USE_SYSTEM_EXTENSIONS
613 AS_CASE([$enable_threads],
614 [posix], [
615 echo
616 echo "POSIX threading support:"
617 AX_PTHREAD([:]) dnl We don't need the HAVE_PTHREAD macro.
618 LIBS="$LIBS $PTHREAD_LIBS"
619 AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"
621 dnl NOTE: PTHREAD_CC is ignored. It would be useful on AIX,
622 dnl but it's tricky to get it right together with
623 dnl AC_PROG_CC_C99. Thus, this is handled by telling the
624 dnl user in INSTALL to set the correct CC manually.
626 AC_DEFINE([MYTHREAD_POSIX], [1],
627 [Define to 1 when using POSIX threads (pthreads).])
629 # This is nice to have but not mandatory.
630 OLD_CFLAGS=$CFLAGS
631 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
632 AC_CHECK_FUNCS([pthread_condattr_setclock])
633 CFLAGS=$OLD_CFLAGS
634 ],
635 [win95], [
636 AC_DEFINE([MYTHREAD_WIN95], [1], [Define to 1 when using
637 Windows 95 (and thus XP) compatible threads.
638 This avoids use of features that were added in
639 Windows Vista.])
640 ],
641 [vista], [
642 AC_DEFINE([MYTHREAD_VISTA], [1], [Define to 1 when using
643 Windows Vista compatible threads. This uses
644 features that are not available on Windows XP.])
645 ]
646 )
647 AM_CONDITIONAL([COND_THREADS], [test "x$enable_threads" != xno])
649 echo
650 echo "Initializing Libtool:"
651 LT_PREREQ([2.4])
652 LT_INIT([win32-dll])
653 LT_LANG([Windows Resource])
655 # This is a bit wrong since it is possible to request that only some libs
656 # are built as shared. Using that feature isn't so common though, and this
657 # breaks only on Windows (at least for now) if the user enables only some
658 # libs as shared.
659 AM_CONDITIONAL([COND_SHARED], [test "x$enable_shared" != xno])
661 #####################
662 # Symbol versioning #
663 #####################
665 # NOTE: This checks if we are building shared or static library
666 # and if --with-pic or --without-pic was used. Thus this check
667 # must be after Libtool initialization.
668 AC_MSG_CHECKING([if library symbol versioning should be used])
669 AC_ARG_ENABLE([symbol-versions], [AS_HELP_STRING([--enable-symbol-versions],
670 [Use symbol versioning for liblzma. Enabled by default on
671 GNU/Linux, other GNU-based systems, and FreeBSD.])],
672 [], [enable_symbol_versions=auto])
673 if test "x$enable_symbol_versions" = xauto; then
674 case $host_os in
675 # NOTE: Even if one omits -gnu on GNU/Linux (e.g.
676 # i486-slackware-linux), configure will (via config.sub)
677 # append -gnu (e.g. i486-slackware-linux-gnu), and this
678 # test will work correctly.
679 gnu* | *-gnu* | freebsd*)
680 enable_symbol_versions=yes
681 ;;
682 *)
683 enable_symbol_versions=no
684 ;;
685 esac
686 fi
688 # There are two variants for symbol versioning.
689 # See src/liblzma/validate_map.sh for details.
690 #
691 # On GNU/Linux, extra symbols are added in the C code. These extra symbols
692 # must not be put into a static library as they can cause problems (and
693 # even if they didn't cause problems, they would be useless). On other
694 # systems symbol versioning may be used too but there is no problem as only
695 # a linker script is specified in src/liblzma/Makefile.am and that isn't
696 # used when creating a static library.
697 #
698 # Libtool always uses -DPIC when building shared libraries by default and
699 # doesn't use it for static libs by default. This can be overridden with
700 # --with-pic and --without-pic though. As long as neither --with-pic nor
701 # --without-pic is used then we can use #ifdef PIC to detect if the file is
702 # being built for a shared library.
703 if test "x$enable_symbol_versions" = xno ; then
704 enable_symbol_versions=no
705 AC_MSG_RESULT([no])
706 elif test "x$enable_shared" = xno ; then
707 enable_symbol_versions=no
708 AC_MSG_RESULT([no (not building a shared library)])
709 else
710 case "$host_cpu-$host_os" in
711 microblaze*)
712 # GCC 12 on MicroBlaze doesn't support __symver__
713 # attribute. It's simplest and safest to use the
714 # generic version on that platform since then only
715 # the linker script is needed. The RHEL/CentOS 7
716 # compatibility symbols don't matter on MicroBlaze.
717 enable_symbol_versions=generic
718 ;;
719 *-linux*)
720 case "$pic_mode-$enable_static" in
721 default-*)
722 # Use symvers if PIC is defined.
723 have_symbol_versions_linux=2
724 ;;
725 *-no)
726 # Not building static library.
727 # Use symvers unconditionally.
728 have_symbol_versions_linux=1
729 ;;
730 *)
731 AC_MSG_RESULT([])
732 AC_MSG_ERROR([
733 On GNU/Linux, building both shared and static library at the same time
734 is not supported if --with-pic or --without-pic is used.
735 Use either --disable-shared or --disable-static to build one type
736 of library at a time. If both types are needed, build one at a time,
737 possibly picking only src/liblzma/.libs/liblzma.a from the static build.])
738 ;;
739 esac
740 enable_symbol_versions=linux
741 AC_DEFINE_UNQUOTED([HAVE_SYMBOL_VERSIONS_LINUX],
742 [$have_symbol_versions_linux],
743 [Define to 1 to if GNU/Linux-specific details
744 are unconditionally wanted for symbol
745 versioning. Define to 2 to if these are wanted
746 only if also PIC is defined (allows building
747 both shared and static liblzma at the same
748 time with Libtool if neither --with-pic nor
749 --without-pic is used). This define must be
750 used together with liblzma_linux.map.])
751 ;;
752 *)
753 enable_symbol_versions=generic
754 ;;
755 esac
756 AC_MSG_RESULT([yes ($enable_symbol_versions)])
757 fi
759 AM_CONDITIONAL([COND_SYMVERS_LINUX],
760 [test "x$enable_symbol_versions" = xlinux])
761 AM_CONDITIONAL([COND_SYMVERS_GENERIC],
762 [test "x$enable_symbol_versions" = xgeneric])
765 ###############################################################################
766 # Checks for libraries.
767 ###############################################################################
769 dnl Support for _REQUIRE_VERSION was added in gettext 0.19.6. If both
770 dnl _REQUIRE_VERSION and _VERSION are present, the _VERSION is ignored.
771 dnl We use both for compatibility with other programs in the Autotools family.
772 echo
773 echo "Initializing gettext:"
774 AM_GNU_GETTEXT_REQUIRE_VERSION([0.19.6])
775 AM_GNU_GETTEXT_VERSION([0.19.6])
776 AM_GNU_GETTEXT([external])
779 ###############################################################################
780 # Checks for header files.
781 ###############################################################################
783 echo
784 echo "System headers and functions:"
786 # There is currently no workarounds in this package if some of
787 # these headers are missing.
788 AC_CHECK_HEADERS([fcntl.h limits.h sys/time.h],
789 [],
790 [AC_MSG_ERROR([Required header file(s) are missing.])])
792 # immintrin.h allows the use of the intrinsic functions if they are available.
793 # cpuid.h may be used for detecting x86 processor features at runtime.
794 AC_CHECK_HEADERS([immintrin.h cpuid.h])
797 ###############################################################################
798 # Checks for typedefs, structures, and compiler characteristics.
799 ###############################################################################
801 AC_HEADER_STDBOOL
803 AC_TYPE_UINT8_T
804 AC_TYPE_UINT16_T
805 AC_TYPE_INT32_T
806 AC_TYPE_UINT32_T
807 AC_TYPE_INT64_T
808 AC_TYPE_UINT64_T
809 AC_TYPE_UINTPTR_T
811 AC_CHECK_SIZEOF([size_t])
813 # The command line tool can copy high resolution timestamps if such
814 # information is available in struct stat. Otherwise one second accuracy
815 # is used.
816 AC_CHECK_MEMBERS([
817 struct stat.st_atim.tv_nsec,
818 struct stat.st_atimespec.tv_nsec,
819 struct stat.st_atimensec,
820 struct stat.st_uatime,
821 struct stat.st_atim.st__tim.tv_nsec])
823 AC_SYS_LARGEFILE
824 AC_C_BIGENDIAN
826 # __attribute__((__constructor__)) can be used for one-time initializations.
827 # Use -Werror because some compilers accept unknown attributes and just
828 # give a warning.
829 #
830 # FIXME? Unfortunately -Werror can cause trouble if CFLAGS contains options
831 # that produce warnings for unrelated reasons. For example, GCC and Clang
832 # support -Wunused-macros which will warn about "#define _GNU_SOURCE 1"
833 # which will be among the #defines that Autoconf inserts to the beginning of
834 # the test program. There seems to be no nice way to prevent Autoconf from
835 # inserting the any defines to the test program.
836 AC_MSG_CHECKING([if __attribute__((__constructor__)) can be used])
837 have_func_attribute_constructor=no
838 OLD_CFLAGS="$CFLAGS"
839 CFLAGS="$CFLAGS -Werror"
840 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
841 __attribute__((__constructor__))
842 static void my_constructor_func(void) { return; }
843 ]])], [
844 AC_DEFINE([HAVE_FUNC_ATTRIBUTE_CONSTRUCTOR], [1],
845 [Define to 1 if __attribute__((__constructor__))
846 is supported for functions.])
847 have_func_attribute_constructor=yes
848 AC_MSG_RESULT([yes])
849 ], [
850 AC_MSG_RESULT([no])
851 ])
852 CFLAGS="$OLD_CFLAGS"
854 # The Win95 threading lacks a thread-safe one-time initialization function.
855 # The one-time initialization is needed for crc32_small.c and crc64_small.c
856 # create the CRC tables. So if small mode is enabled, the threading mode is
857 # win95, and the compiler does not support attribute constructor, then we
858 # would end up with a multithreaded build that is thread-unsafe. As a
859 # result this configuration is not allowed.
860 if test "x$enable_small$enable_threads$have_func_attribute_constructor" \
861 = xyeswin95no; then
862 AC_MSG_ERROR([
863 --enable-threads=win95 and --enable-small cannot be used
864 at the same time with a compiler that doesn't support
865 __attribute__((__constructor__))])
866 fi
868 # __attribute__((__ifunc__())) can be used to choose between different
869 # implementations of the same function at runtime. This is slightly more
870 # efficient than using __attribute__((__constructor__)) and setting
871 # a function pointer.
872 AC_ARG_ENABLE([ifunc], [AS_HELP_STRING([--disable-ifunc],
873 [do not use __attribute__((__ifunc__()))])],
874 [], [enable_ifunc=yes])
876 if test "x$enable_ifunc" = xyes ; then
877 OLD_CFLAGS="$CFLAGS"
878 CFLAGS="$CFLAGS -Werror"
879 AC_MSG_CHECKING([if __attribute__((__ifunc__())) can be used])
880 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
881 static void func(void) { return; }
882 static void (*resolve_func (void)) (void) { return func; }
883 void func_ifunc (void)
884 __attribute__((__ifunc__("resolve_func")));
885 /*
886 * 'clang -Wall' incorrectly warns that resolve_func is
887 * unused (-Wunused-function). Correct assembly output is
888 * still produced. This problem exists at least in Clang
889 * versions 4 to 17. The following silences the bogus warning:
890 */
891 void make_clang_quiet(void);
892 void make_clang_quiet(void) { resolve_func()(); }
893 ]])], [
894 AC_DEFINE([HAVE_FUNC_ATTRIBUTE_IFUNC], [1],
895 [Define to 1 if __attribute__((__ifunc__()))
896 is supported for functions.])
897 AC_MSG_RESULT([yes])
899 # ifunc explicitly does not work with -fsanitize=address.
900 # If configured, it will result in a liblzma build that
901 # will fail when liblzma is loaded at runtime (when the
902 # ifunc resolver executes).
903 AS_CASE([$CFLAGS], [*-fsanitize=*], [AC_MSG_ERROR([
904 CFLAGS contains '-fsanitize=' which is incompatible with ifunc.
905 Use --disable-ifunc when using '-fsanitize'.])])
906 ], [
907 AC_MSG_RESULT([no])
908 ])
910 CFLAGS="$OLD_CFLAGS"
911 fi
914 ###############################################################################
915 # Checks for library functions.
916 ###############################################################################
918 # Gnulib replacements as needed
919 gl_GETOPT
921 # If clock_gettime() is available, liblzma with pthreads may use it, and
922 # xz may use it even when threading support is disabled. In XZ Utils 5.4.x
923 # and older, configure checked for clock_gettime() only when using pthreads.
924 # This way non-threaded builds of liblzma didn't get a useless dependency on
925 # librt which further had a dependency on libpthread. Avoiding these was
926 # useful when a small build was needed, for example, for initramfs use.
927 #
928 # The above reasoning is thoroughly obsolete: On GNU/Linux, librt hasn't
929 # been needed for clock_gettime() since glibc 2.17 (2012-12-25).
930 # Solaris 10 needs librt but Solaris 11 doesn't anymore.
931 AC_SEARCH_LIBS([clock_gettime], [rt])
932 AC_CHECK_FUNCS([clock_gettime])
933 AC_CHECK_DECL([CLOCK_MONOTONIC], [AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1],
934 [Define to 1 if 'CLOCK_MONOTONIC' is declared in <time.h>.])], [],
935 [[#include <time.h>]])
937 # Find the best function to set timestamps.
938 AC_CHECK_FUNCS([futimens futimes futimesat utimes _futime utime], [break])
940 # This is nice to have but not mandatory.
941 AC_CHECK_FUNCS([posix_fadvise])
943 TUKLIB_PROGNAME
944 TUKLIB_INTEGER
945 TUKLIB_PHYSMEM
946 TUKLIB_CPUCORES
947 TUKLIB_MBSTR
949 # If requested, check for system-provided SHA-256. At least the following
950 # implementations are supported:
951 #
952 # OS Headers Library Type Function
953 # FreeBSD sys/types.h + sha256.h libmd SHA256_CTX SHA256_Init
954 # NetBSD sys/types.h + sha2.h SHA256_CTX SHA256_Init
955 # OpenBSD sys/types.h + sha2.h SHA2_CTX SHA256Init
956 # Solaris sys/types.h + sha2.h libmd SHA256_CTX SHA256Init
957 # MINIX 3 sys/types.h + sha2.h SHA256_CTX SHA256_Init
958 # Darwin CommonCrypto/CommonDigest.h CC_SHA256_CTX CC_SHA256_Init
959 #
960 # Note that Darwin's CC_SHA256_Update takes buffer size as uint32_t instead
961 # of size_t.
962 #
963 sha256_header_found=no
964 sha256_type_found=no
965 sha256_func_found=no
966 AS_IF([test "x$enable_external_sha256" = "xyes"], [
967 # Test for Common Crypto before others, because Darwin has sha256.h
968 # too and we don't want to use that, because on older versions it
969 # uses OpenSSL functions, whose SHA256_Init is not guaranteed to
970 # succeed.
971 AC_CHECK_HEADERS(
972 [CommonCrypto/CommonDigest.h sha256.h sha2.h],
973 [sha256_header_found=yes ; break])
974 if test "x$sha256_header_found" = xyes; then
975 AC_CHECK_TYPES([CC_SHA256_CTX, SHA256_CTX, SHA2_CTX],
976 [sha256_type_found=yes], [],
977 [[#ifdef HAVE_SYS_TYPES_H
978 # include <sys/types.h>
979 #endif
980 #ifdef HAVE_COMMONCRYPTO_COMMONDIGEST_H
981 # include <CommonCrypto/CommonDigest.h>
982 #endif
983 #ifdef HAVE_SHA256_H
984 # include <sha256.h>
985 #endif
986 #ifdef HAVE_SHA2_H
987 # include <sha2.h>
988 #endif]])
989 if test "x$sha256_type_found" = xyes ; then
990 AC_SEARCH_LIBS([SHA256Init], [md])
991 AC_SEARCH_LIBS([SHA256_Init], [md])
992 AC_CHECK_FUNCS([CC_SHA256_Init SHA256Init SHA256_Init],
993 [sha256_func_found=yes ; break])
994 fi
995 fi
996 ])
997 AM_CONDITIONAL([COND_INTERNAL_SHA256], [test "x$sha256_func_found" = xno])
998 if test "x$enable_external_sha256$sha256_func_found" = xyesno; then
999 AC_MSG_ERROR([--enable-external-sha256 was specified but no supported external SHA-256 implementation was found])
1000 fi
1002 # Check for SSE2 intrinsics. There is no run-time detection for SSE2 so if
1003 # compiler options enable SSE2 then SSE2 support is required by the binaries.
1004 # The compile-time check for SSE2 is done with #ifdefs because some compilers
1005 # (ICC, MSVC) allow SSE2 intrinsics even when SSE2 isn't enabled.
1006 AC_CHECK_DECL([_mm_movemask_epi8],
1007 [AC_DEFINE([HAVE__MM_MOVEMASK_EPI8], [1],
1008 [Define to 1 if _mm_movemask_epi8 is available.])],
1009 [],
1010 [#ifdef HAVE_IMMINTRIN_H
1011 #include <immintrin.h>
1012 #endif])
1014 # For faster CRC on 32/64-bit x86 and E2K (see also crc64_fast.c):
1015 #
1016 # - Check for the CLMUL intrinsic _mm_clmulepi64_si128 in <immintrin.h>.
1017 # Check also for _mm_set_epi64x for consistency with CMake build
1018 # where it's needed to disable CLMUL with VS2013.
1019 #
1020 # - Check that __attribute__((__target__("ssse3,sse4.1,pclmul"))) works
1021 # together with _mm_clmulepi64_si128 from <immintrin.h>. The attribute
1022 # was added in GCC 4.4 but some GCC 4.x versions don't allow intrinsics
1023 # with it. Exception: it must be not be used with EDG-based compilers
1024 # like ICC and the compiler on E2K.
1025 #
1026 # If everything above is supported, runtime detection will be used to keep the
1027 # binaries working on systems that don't support the required extensions.
1028 AC_MSG_CHECKING([if _mm_clmulepi64_si128 is usable])
1029 AS_IF([test "x$enable_clmul_crc" = xno], [
1030 AC_MSG_RESULT([no, --disable-clmul-crc was used])
1031 ], [
1032 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1033 #include <immintrin.h>
1035 // CLMUL works on older E2K instruction set but it is slow due to emulation.
1036 #if defined(__e2k__) && __iset__ < 6
1037 # error
1038 #endif
1040 // Intel's old compiler (ICC) can define __GNUC__ but the attribute must not
1041 // be used with it. The new Clang-based ICX needs the attribute.
1042 // Checking for !defined(__EDG__) catches ICC and other EDG-based compilers.
1043 #if (defined(__GNUC__) || defined(__clang__)) && !defined(__EDG__)
1044 __attribute__((__target__("ssse3,sse4.1,pclmul")))
1045 #endif
1046 __m128i my_clmul(__m128i a)
1047 {
1048 const __m128i b = _mm_set_epi64x(1, 2);
1049 return _mm_clmulepi64_si128(a, b, 0);
1050 }
1051 ]])], [
1052 AC_DEFINE([HAVE_USABLE_CLMUL], [1],
1053 [Define to 1 if _mm_set_epi64x and
1054 _mm_clmulepi64_si128 are usable.
1055 See configure.ac for details.])
1056 enable_clmul_crc=yes
1057 ], [
1058 enable_clmul_crc=no
1059 ])
1060 AC_MSG_RESULT([$enable_clmul_crc])
1061 ])
1062 AM_CONDITIONAL([COND_CRC_CLMUL], [test "x$enable_clmul_crc" = xyes])
1064 # Check for sandbox support. If one is found, set enable_sandbox=found.
1065 #
1066 # About -fsanitize: Of our three sandbox methods, only Landlock is
1067 # incompatible with -fsanitize. FreeBSD 13.2 with Capsicum was tested with
1068 # -fsanitize=address,undefined and had no issues. OpenBSD (as of version
1069 # 7.4) has minimal support for process instrumentation. OpenBSD does not
1070 # distribute the additional libraries needed (libasan, libubsan, etc.) with
1071 # GCC or Clang needed for runtime sanitization support and instead only
1072 # support -fsanitize-minimal-runtime for minimal undefined behavior
1073 # sanitization. This minimal support is compatible with our use of the
1074 # Pledge sandbox. So only Landlock will result in a build that cannot
1075 # compress or decompress a single file to standard out.
1076 AS_CASE([$enable_sandbox],
1077 [auto | capsicum], [
1078 AC_CHECK_FUNCS([cap_rights_limit], [enable_sandbox=found])
1079 ]
1080 )
1081 AS_CASE([$enable_sandbox],
1082 [auto | pledge], [
1083 AC_CHECK_FUNCS([pledge], [enable_sandbox=found])
1084 ]
1085 )
1086 AS_CASE([$enable_sandbox],
1087 [auto | landlock], [
1088 AC_CHECK_HEADERS([linux/landlock.h], [
1089 enable_sandbox=found
1091 AS_CASE([$CFLAGS], [*-fsanitize=*], [AC_MSG_ERROR([
1092 CFLAGS contains '-fsanitize=' which is incompatible with the Landlock
1093 sandboxing. Use --disable-sandbox when using '-fsanitize'.])])
1094 ])
1095 ]
1096 )
1098 # If a specific sandboxing method was explicitly requested and it wasn't
1099 # found, give an error.
1100 case $enable_sandbox in
1101 auto | no | found)
1102 ;;
1103 *)
1104 AC_MSG_ERROR([$enable_sandbox support not found])
1105 ;;
1106 esac
1109 ###############################################################################
1110 # If using GCC, set some additional AM_CFLAGS:
1111 ###############################################################################
1113 if test "$GCC" = yes ; then
1114 echo
1115 echo "GCC extensions:"
1116 fi
1118 # Always do the visibility check but don't set AM_CFLAGS on Windows.
1119 # This way things get set properly even on Windows.
1120 gl_VISIBILITY
1121 if test -n "$CFLAG_VISIBILITY" && test "$is_w32" = no; then
1122 AM_CFLAGS="$AM_CFLAGS $CFLAG_VISIBILITY"
1123 fi
1125 AS_IF([test "$GCC" = yes], [
1126 # Enable as much warnings as possible. These commented warnings won't
1127 # work for this package though:
1128 # * -Wunreachable-code breaks several assert(0) cases, which are
1129 # backed up with "return LZMA_PROG_ERROR".
1130 # * -Wcast-qual would break various things where we need a non-const
1131 # pointer although we don't modify anything through it.
1132 # * -Winline, -Wdisabled-optimization, -Wunsafe-loop-optimizations
1133 # don't seem so useful here; at least the last one gives some
1134 # warnings which are not bugs.
1135 # * -Wconversion still shows too many warnings.
1136 #
1137 # The flags before the empty line are for GCC and many of them
1138 # are supported by Clang too. The flags after the empty line are
1139 # for Clang.
1140 for NEW_FLAG in \
1141 -Wall \
1142 -Wextra \
1143 -Wvla \
1144 -Wformat=2 \
1145 -Winit-self \
1146 -Wmissing-include-dirs \
1147 -Wshift-overflow=2 \
1148 -Wstrict-overflow=3 \
1149 -Walloc-zero \
1150 -Wduplicated-cond \
1151 -Wfloat-equal \
1152 -Wundef \
1153 -Wshadow \
1154 -Wpointer-arith \
1155 -Wbad-function-cast \
1156 -Wwrite-strings \
1157 -Wdate-time \
1158 -Wsign-conversion \
1159 -Wfloat-conversion \
1160 -Wlogical-op \
1161 -Waggregate-return \
1162 -Wstrict-prototypes \
1163 -Wold-style-definition \
1164 -Wmissing-prototypes \
1165 -Wmissing-declarations \
1166 -Wredundant-decls \
1167 \
1168 -Wc99-compat \
1169 -Wc11-extensions \
1170 -Wc2x-compat \
1171 -Wc2x-extensions \
1172 -Wpre-c2x-compat \
1173 -Warray-bounds-pointer-arithmetic \
1174 -Wassign-enum \
1175 -Wconditional-uninitialized \
1176 -Wdocumentation \
1177 -Wduplicate-enum \
1178 -Wempty-translation-unit \
1179 -Wflexible-array-extensions \
1180 -Wmissing-variable-declarations \
1181 -Wnewline-eof \
1182 -Wshift-sign-overflow \
1183 -Wstring-conversion
1184 do
1185 AC_MSG_CHECKING([if $CC accepts $NEW_FLAG])
1186 OLD_CFLAGS="$CFLAGS"
1187 CFLAGS="$CFLAGS $NEW_FLAG -Werror"
1188 AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1189 [[void foo(void); void foo(void) { }]])], [
1190 AM_CFLAGS="$AM_CFLAGS $NEW_FLAG"
1191 AC_MSG_RESULT([yes])
1192 ], [
1193 AC_MSG_RESULT([no])
1194 ])
1195 CFLAGS="$OLD_CFLAGS"
1196 done
1198 AC_ARG_ENABLE([werror],
1199 AS_HELP_STRING([--enable-werror], [Enable -Werror to abort
1200 compilation on all compiler warnings.]),
1201 [], [enable_werror=no])
1202 if test "x$enable_werror" = "xyes"; then
1203 AM_CFLAGS="$AM_CFLAGS -Werror"
1204 fi
1205 ])
1208 ###############################################################################
1209 # Create the makefiles and config.h
1210 ###############################################################################
1212 echo
1214 # Don't build the lib directory at all if we don't need any replacement
1215 # functions.
1216 AM_CONDITIONAL([COND_GNULIB], test -n "$LIBOBJS")
1218 # Add default AM_CFLAGS.
1219 AC_SUBST([AM_CFLAGS])
1221 # This is needed for src/scripts.
1222 xz=`echo xz | sed "$program_transform_name"`
1223 AC_SUBST([xz])
1225 AC_CONFIG_FILES([
1226 Makefile
1227 po/Makefile.in
1228 lib/Makefile
1229 src/Makefile
1230 src/liblzma/Makefile
1231 src/liblzma/api/Makefile
1232 src/xz/Makefile
1233 src/xzdec/Makefile
1234 src/lzmainfo/Makefile
1235 src/scripts/Makefile
1236 tests/Makefile
1237 debug/Makefile
1238 ])
1239 AC_CONFIG_FILES([src/scripts/xzdiff], [chmod +x src/scripts/xzdiff])
1240 AC_CONFIG_FILES([src/scripts/xzgrep], [chmod +x src/scripts/xzgrep])
1241 AC_CONFIG_FILES([src/scripts/xzmore], [chmod +x src/scripts/xzmore])
1242 AC_CONFIG_FILES([src/scripts/xzless], [chmod +x src/scripts/xzless])
1244 AC_OUTPUT
1246 # Some warnings
1247 if test x$tuklib_cv_physmem_method = xunknown; then
1248 echo
1249 echo "WARNING:"
1250 echo "No supported method to detect the amount of RAM."
1251 echo "Consider using --enable-assume-ram (if you didn't already)"
1252 echo "or make a patch to add support for this operating system."
1253 fi
1255 if test x$tuklib_cv_cpucores_method = xunknown; then
1256 echo
1257 echo "WARNING:"
1258 echo "No supported method to detect the number of CPU cores."
1259 fi
1261 if test "x$enable_threads$enable_small$have_func_attribute_constructor" \
1262 = xnoyesno; then
1263 echo
1264 echo "NOTE:"
1265 echo "liblzma will be thread-unsafe due to the combination"
1266 echo "of --disable-threads --enable-small when using a compiler"
1267 echo "that doesn't support __attribute__((__constructor__))."
1268 fi