instructions.lisp

   1 ;;; -*- show-trailing-whitespace: t; indent-tabs-mode: nil -*-
   2
   3 ;;; Copyright (c) 2007,2008 David Lichteblau, Ivan Shvedunov.
   4 ;;; All rights reserved.
   5
   6 ;;; Redistribution and use in source and binary forms, with or without
   7 ;;; modification, are permitted provided that the following conditions
   8 ;;; are met:
   9 ;;;
  10 ;;;   * Redistributions of source code must retain the above copyright
  11 ;;;     notice, this list of conditions and the following disclaimer.
  12 ;;;
  13 ;;;   * Redistributions in binary form must reproduce the above
  14 ;;;     copyright notice, this list of conditions and the following
  15 ;;;     disclaimer in the documentation and/or other materials
  16 ;;;     provided with the distribution.
  17 ;;;
  18 ;;; THIS SOFTWARE IS PROVIDED BY THE AUTHOR 'AS IS' AND ANY EXPRESSED
  19 ;;; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  20 ;;; WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21 ;;; ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY
  22 ;;; DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  23 ;;; DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE
  24 ;;; GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  25 ;;; INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  26 ;;; WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
  27 ;;; NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  28 ;;; SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29
  30 (in-package :xuriella)
  31
  32 #+sbcl
  33 (declaim (optimize (debug 2)))
  34
  35
  36 ;;;; Instructions
  37
  38 (defmacro define-instruction (name (args-var env-var) &body body)
  39   `(setf (get ',name 'xslt-instruction)
  40          (lambda (,args-var ,env-var)
  41            (declare (ignorable ,env-var))
  42            ,@body)))
  43
  44 (define-instruction if (args env)
  45   (destructuring-bind (test then &optional else) args
  46     (let ((test-thunk (compile-xpath test env))
  47           (then-thunk (compile-instruction then env))
  48           (else-thunk (when else (compile-instruction else env))))
  49       (lambda (ctx)
  50         (cond
  51           ((xpath:boolean-value (funcall test-thunk ctx))
  52            (funcall then-thunk ctx))
  53           (else-thunk
  54            (funcall else-thunk ctx)))))))
  55
  56 (define-instruction when (args env)
  57   (destructuring-bind (test &rest body) args
  58     (compile-instruction `(if ,test (progn ,@body)) env)))
  59
  60 (define-instruction unless (args env)
  61   (destructuring-bind (test &rest body) args
  62     (compile-instruction `(if (:not ,test) (progn ,@body)) env)))
  63
  64 (define-instruction cond (args env)
  65   (if args
  66       (destructuring-bind ((test &body body) &rest clauses) args
  67         (compile-instruction (if (eq test t)
  68                                  `(progn ,@body)
  69                                  `(if ,test
  70                                       (progn ,@body)
  71                                       (cond ,@clauses)))
  72                              env))
  73       (constantly nil)))
  74
  75 (define-instruction progn (args env)
  76   (if args
  77       (let ((first-thunk (compile-instruction (first args) env))
  78             (rest-thunk (compile-instruction `(progn ,@(rest args)) env)))
  79         (lambda (ctx)
  80           (funcall first-thunk ctx)
  81           (funcall rest-thunk ctx)))
  82       (constantly nil)))
  83
  84 (defun decode-qname/runtime (qname namespaces attributep)
  85   (handler-case
  86       (multiple-value-bind (prefix local-name)
  87           (split-qname qname)
  88         (values local-name
  89                 (if (or prefix (not attributep))
  90                     (cdr (assoc prefix namespaces :test 'equal))
  91                     "")
  92                 prefix))
  93     (cxml:well-formedness-violation ()
  94       (xslt-error "not a qname: ~A" qname))))
  95
  96 (define-instruction xsl:element (args env)
  97   (destructuring-bind ((name &key namespace use-attribute-sets)
  98                        &body body)
  99       args
 100     (declare (ignore use-attribute-sets)) ;fixme
 101     (multiple-value-bind (name-thunk constant-name-p)
 102         (compile-avt name env)
 103       (multiple-value-bind (ns-thunk constant-ns-p)
 104           (if namespace
 105               (compile-avt namespace env)
 106               (values nil t))
 107         (let ((body-thunk (compile-instruction `(progn ,@body) env)))
 108           (if (and constant-name-p constant-ns-p)
 109               (compile-element/constant-name name namespace env body-thunk)
 110               (compile-element/runtime name-thunk ns-thunk body-thunk)))))))
 111
 112 (defun compile-element/constant-name (qname namespace env body-thunk)
 113   ;; the simple case: compile-time decoding of the QName
 114   (multiple-value-bind (local-name uri prefix)
 115       (decode-qname qname env nil)
 116     (when namespace
 117       (setf uri namespace))
 118     (lambda (ctx)
 119       (with-element (local-name uri :suggested-prefix prefix)
 120         (funcall body-thunk ctx)))))
 121
 122 (defun compile-element/runtime (name-thunk ns-thunk body-thunk)
 123   ;; run-time decoding of the QName, but using the same namespaces
 124   ;; that would have been known at compilation time.
 125   (let ((namespaces *namespaces*))
 126     (lambda (ctx)
 127       (let ((qname (funcall name-thunk ctx)))
 128         (multiple-value-bind (local-name uri prefix)
 129             (decode-qname/runtime qname namespaces nil)
 130           (when ns-thunk
 131             (setf uri (funcall ns-thunk ctx)))
 132           (unless uri
 133             (setf uri ""))
 134           (with-element (local-name uri :suggested-prefix prefix)
 135             (funcall body-thunk ctx)))))))
 136
 137 (define-instruction xsl:use-attribute-sets (args env)
 138   (destructuring-bind (str) args
 139     (let ((sets (mapcar (lambda (qname)
 140                           (multiple-value-list (decode-qname qname env nil)))
 141                         (words str))))
 142       (lambda (ctx)
 143         (loop for (local-name uri nil) in sets do
 144              (dolist (thunk (find-attribute-set local-name uri))
 145                (funcall thunk ctx)))))))
 146
 147 (define-instruction xsl:attribute (args env)
 148   (destructuring-bind ((name &key namespace) &body body) args
 149     (when (null name)
 150       (xslt-error "xsl:attribute: name not specified"))
 151     (multiple-value-bind (name-thunk constant-name-p)
 152         (compile-avt name env)
 153       (multiple-value-bind (ns-thunk constant-ns-p)
 154           (if namespace
 155               (compile-avt namespace env)
 156               (values nil t))
 157         (let ((value-thunk (compile-instruction `(progn ,@body) env)))
 158           (if (and constant-name-p constant-ns-p)
 159               (compile-attribute/constant-name name namespace env value-thunk)
 160               (compile-attribute/runtime name-thunk ns-thunk value-thunk)))))))
 161
 162 (defun compile-attribute/constant-name (qname namespace env value-thunk)
 163   ;; the simple case: compile-time decoding of the QName
 164   (multiple-value-bind (local-name uri prefix)
 165       (decode-qname qname env nil)
 166     (when namespace
 167       (setf uri namespace))
 168     (lambda (ctx)
 169       (write-attribute local-name
 170                        uri
 171                        (with-text-output-sink (s)
 172                          (with-xml-output s
 173                            (funcall value-thunk ctx)))
 174                        :suggested-prefix prefix))))
 175
 176 (defun compile-attribute/runtime (name-thunk ns-thunk value-thunk)
 177   ;; run-time decoding of the QName, but using the same namespaces
 178   ;; that would have been known at compilation time.
 179   (let ((namespaces *namespaces*))
 180     (lambda (ctx)
 181       (let ((qname (funcall name-thunk ctx)))
 182         (multiple-value-bind (local-name uri prefix)
 183             (decode-qname/runtime qname namespaces nil)
 184           (when ns-thunk
 185             (setf uri (funcall ns-thunk ctx)))
 186           (write-attribute local-name
 187                            (or uri "")
 188                            (with-text-output-sink (s)
 189                              (with-xml-output s
 190                                (funcall value-thunk ctx)))
 191                            :suggested-prefix prefix))))))
 192
 193 (defun remove-excluded-namespaces
 194     (namespaces &optional (excluded-uris *excluded-namespaces*))
 195   (let ((koerbchen '())
 196         (kroepfchen '()))
 197     (loop
 198        for cons in namespaces
 199        for (prefix . uri) = cons
 200        do
 201          (cond
 202            ((find prefix kroepfchen :test #'equal))
 203            ((find uri excluded-uris :test #'equal)
 204             (push prefix kroepfchen))
 205            (t
 206             (push cons koerbchen))))
 207     koerbchen))
 208
 209 (define-instruction xsl:literal-element (args env)
 210   (destructuring-bind
 211         ((local-name &optional (uri "") suggested-prefix) &body body)
 212       args
 213     (let ((body-thunk (compile-instruction `(progn ,@body) env))
 214           (namespaces (remove-excluded-namespaces *namespaces*)))
 215       (lambda (ctx)
 216         (with-element (local-name uri
 217                                   :suggested-prefix suggested-prefix
 218                                   :extra-namespaces namespaces)
 219           (funcall body-thunk ctx))))))
 220
 221 (define-instruction xsl:literal-attribute (args env)
 222   (destructuring-bind ((local-name &optional uri suggested-prefix) value) args
 223     (let ((value-thunk (compile-avt value env)))
 224       (lambda (ctx)
 225         (write-attribute local-name
 226                          uri
 227                          (funcall value-thunk ctx)
 228                          :suggested-prefix suggested-prefix)))))
 229
 230 (define-instruction xsl:text (args env)
 231   (destructuring-bind (str) args
 232     (lambda (ctx)
 233       (declare (ignore ctx))
 234       (write-text str))))
 235
 236 (define-instruction xsl:processing-instruction (args env)
 237   (destructuring-bind (name &rest body) args
 238     (let ((name-thunk (compile-avt name env))
 239           (value-thunk (compile-instruction `(progn ,@body) env)))
 240       (lambda (ctx)
 241         (write-processing-instruction
 242          (funcall name-thunk ctx)
 243          (with-text-output-sink (s)
 244            (with-xml-output s
 245              (funcall value-thunk ctx))))))))
 246
 247 (define-instruction xsl:comment (args env)
 248   (let ((value-thunk (compile-instruction `(progn ,@args) env)))
 249     (lambda (ctx)
 250       (write-comment (with-text-output-sink (s)
 251                        (with-xml-output s
 252                          (funcall value-thunk ctx)))))))
 253
 254 (define-instruction xsl:value-of (args env)
 255   (destructuring-bind (xpath) args
 256     (let ((thunk (compile-xpath xpath env)))
 257       (xslt-trace-thunk
 258        (lambda (ctx)
 259          (write-text (xpath:string-value (funcall thunk ctx))))
 260        "value-of ~s = ~s" xpath :result))))
 261
 262 (define-instruction xsl:unescaped-value-of (args env)
 263   (destructuring-bind (xpath) args
 264     (let ((thunk (compile-xpath xpath env)))
 265       (lambda (ctx)
 266         (write-unescaped (xpath:string-value (funcall thunk ctx)))))))
 267
 268 (define-instruction xsl:copy-of (args env)
 269   (destructuring-bind (xpath) args
 270     (let ((thunk (compile-xpath xpath env))
 271           ;; FIXME: what was this for?  --david
 272           #+(or) (v (intern-variable "varName" "")))
 273       (xslt-trace-thunk
 274        (lambda (ctx)
 275          (let ((result (funcall thunk ctx)))
 276            (typecase result
 277              (xpath:node-set ;; FIXME: variables can contain node sets w/fragments inside. Maybe just fragments would do?
 278               (xpath:map-node-set #'copy-into-result (xpath:sort-node-set result)))
 279              (result-tree-fragment
 280               (copy-into-result result))
 281              (t
 282               (write-text (xpath:string-value result))))))
 283        "copy-of ~s" xpath))))
 284
 285 (defun copy-into-result (node)
 286   (cond
 287     ((result-tree-fragment-p node)
 288      (stp:do-children (child (result-tree-fragment-node node))
 289        (copy-into-result child)))
 290     ((xpath-protocol:node-type-p node :element)
 291      (with-element ((xpath-protocol:local-name node)
 292                     (xpath-protocol:namespace-uri node)
 293                     :suggested-prefix (xpath-protocol:namespace-prefix node)
 294                     :extra-namespaces (namespaces-as-alist node))
 295        (map-pipe-eagerly #'copy-into-result
 296                          (xpath-protocol:attribute-pipe node))
 297        (map-pipe-eagerly #'copy-into-result
 298                          (xpath-protocol:child-pipe node))))
 299     ((xpath-protocol:node-type-p node :document)
 300      (map-pipe-eagerly #'copy-into-result
 301                        (xpath-protocol:child-pipe node)))
 302     (t
 303      (copy-leaf-node node))))
 304
 305 (defun make-sorter (spec env)
 306   (destructuring-bind (&key select lang data-type order case-order)
 307       (cdr spec)
 308     ;; FIXME: implement case-order
 309     (declare (ignore lang case-order))
 310     (let ((select-thunk (compile-xpath (or select ".") env))
 311           (numberp (equal data-type "number"))
 312           (f (if (equal order "descending") -1 1)))
 313       (lambda (a b)
 314         (let ((i (xpath:string-value
 315                   (funcall select-thunk (xpath:make-context a))))
 316               (j (xpath:string-value
 317                   (funcall select-thunk (xpath:make-context b)))))
 318           (* f
 319              (if numberp
 320                  (let ((n-a (xpath:number-value i))
 321                        (n-b (xpath:number-value j)))
 322                    (cond ((and (xpath::nan-p a)
 323                                (not (xpath::nan-p b)))
 324                           -1)
 325                          ((and (not (xpath::nan-p a))
 326                                (xpath::nan-p b))
 327                           1)
 328                          ((xpath::compare-numbers '< n-a n-b) -1)
 329                          ((xpath::compare-numbers '> n-a n-b) 1)
 330                          (t 0)))
 331                  (cond
 332                    ((string< i j) -1)
 333                    ((equal i j) 0)
 334                    (t 1)))))))))
 335
 336 (defun compose-sorters (sorters)
 337   (if sorters
 338       (let ((this (car sorters))
 339             (next (compose-sorters (rest sorters))))
 340         (lambda (a b)
 341           (let ((d (funcall this a b)))
 342             (if (zerop d)
 343                 (funcall next a b)
 344                 d))))
 345       (constantly 0)))
 346
 347 (defun make-sort-predicate (decls env)
 348   (let ((sorter
 349          (compose-sorters
 350           (mapcar (lambda (x) (make-sorter x env)) decls))))
 351     (lambda (a b)
 352       (minusp (funcall sorter a b)))))
 353
 354 (define-instruction xsl:for-each (args env)
 355   (destructuring-bind (select &optional decls &rest body) args
 356     (unless (and (consp decls)
 357                  (eq (car decls) 'declare))
 358       (push decls body)
 359       (setf decls nil))
 360     (let ((select-thunk (compile-xpath select env))
 361           (body-thunk (compile-instruction `(progn ,@body) env))
 362           (sort-predicate
 363            (when (cdr decls)
 364              (make-sort-predicate (cdr decls) env))))
 365       (lambda (ctx)
 366         (let ((selected (funcall select-thunk ctx)))
 367           (unless (xpath:node-set-p selected)
 368             (xslt-error "for-each select expression should yield a node-set"))
 369           (let ((nodes (xpath::force
 370                         (xpath::sorted-pipe-of selected))))
 371             (when sort-predicate
 372               (setf nodes (sort (copy-list nodes) sort-predicate)))
 373             (loop
 374               with n = (length nodes)
 375               for node in nodes
 376               for i from 1
 377               do
 378            (funcall body-thunk
 379                     (xpath:make-context node (lambda () n) i)))))))))
 380
 381 (define-instruction xsl:with-namespaces (args env)
 382   (destructuring-bind ((&rest forms) &rest body) args
 383     (let ((*namespaces* *namespaces*))
 384       (dolist (form forms)
 385         (destructuring-bind (prefix uri) form
 386           (push (cons prefix uri) *namespaces*)))
 387       (compile-instruction `(progn ,@body) env))))
 388
 389 (define-instruction xsl:with-excluded-namespaces (args env)
 390   (destructuring-bind ((&rest uris) &rest body) args
 391     (let ((*excluded-namespaces* (append uris *excluded-namespaces*)))
 392       (compile-instruction `(progn ,@body) env))))
 393
 394 ;; XSLT disallows multiple definitions of the same variable within a
 395 ;; template.  Local variables can shadow global variables though.
 396 ;; Since our LET syntax makes it natural to shadow local variables the
 397 ;; Lisp way, we check for duplicate variables only where instructed to
 398 ;; by the XML syntax parser using WITH-DUPLICATES-CHECK:
 399 (defvar *template-variables* nil)
 400
 401 (define-instruction xsl:with-duplicates-check (args env)
 402   (let ((*template-variables* *template-variables*))
 403     (destructuring-bind ((&rest qnames) &rest body) args
 404       (dolist (qname qnames)
 405         (multiple-value-bind (local-name uri)
 406             (decode-qname qname env nil)
 407           (let ((key (cons local-name uri)))
 408             (when (find key *template-variables* :test #'equal)
 409               (xslt-error "duplicate variable: ~A, ~A" local-name uri))
 410             (push key *template-variables*))))
 411       (compile-instruction `(progn ,@body) env))))
 412
 413 (define-instruction xsl:with-base-uri (args env)
 414   (destructuring-bind (uri &rest body) args
 415     (let ((*instruction-base-uri* uri))
 416       (compile-instruction `(progn ,@body) env))))
 417
 418 (defstruct (result-tree-fragment
 419              (:constructor make-result-tree-fragment (node)))
 420   node)
 421
 422 (define-default-method xpath-protocol:node-p
 423     ((node result-tree-fragment))
 424   t)
 425
 426 (define-default-method xpath-protocol:node-text
 427     ((node result-tree-fragment))
 428   (xpath-protocol:node-text (result-tree-fragment-node node)))
 429
 430 (defun apply-to-result-tree-fragment (ctx thunk)
 431   (let ((document
 432          (with-xml-output (stp:make-builder)
 433            (with-element ("fragment" "")
 434              (funcall thunk ctx)))))
 435     (make-result-tree-fragment (stp:document-element document))))
 436
 437 (define-instruction let (args env)
 438   (destructuring-bind ((&rest forms) &rest body) args
 439     (let* ((old-top (length *lexical-variable-declarations*))
 440            (vars-and-names (compile-var-bindings/nointern forms env))
 441            (vars-and-positions
 442             (loop for ((local-name . uri) thunk) in vars-and-names
 443                collect
 444                  (list (push-variable local-name
 445                                       uri
 446                                       *lexical-variable-declarations*)
 447                        thunk))))
 448       (let ((thunk (compile-instruction `(progn ,@body) env)))
 449         (fill *lexical-variable-declarations* nil :start old-top)
 450         (lambda (ctx)
 451           (loop for (index var-thunk) in vars-and-positions
 452              do (setf (lexical-variable-value index)
 453                       (funcall var-thunk ctx)))
 454           (funcall thunk ctx))))))
 455
 456 (define-instruction let* (args env)
 457   (destructuring-bind ((&rest forms) &rest body) args
 458     (if forms
 459         (compile-instruction `(let (,(car forms))
 460                                 (let* (,@(cdr forms))
 461                                   ,@body))
 462                              env)
 463         (compile-instruction `(progn ,@body) env))))
 464
 465 (define-instruction xsl:message (args env)
 466   (compile-message #'warn args env))
 467
 468 (define-instruction xsl:terminate (args env)
 469   (compile-message #'error args env))
 470
 471 (defun namespaces-as-alist (element)
 472   (let ((namespaces '()))
 473     (do-pipe (ns (xpath-protocol:namespace-pipe element))
 474       (push (cons (xpath-protocol:local-name ns)
 475                   (xpath-protocol:namespace-uri ns))
 476             namespaces))
 477     namespaces))
 478
 479 (define-instruction xsl:copy (args env)
 480   (let ((body (compile-instruction `(progn ,@args) env)))
 481     (lambda (ctx)
 482       (let ((node (xpath:context-node ctx)))
 483         (cond
 484           ((xpath-protocol:node-type-p node :element)
 485            (with-element
 486                ((xpath-protocol:local-name node)
 487                 (xpath-protocol:namespace-uri node)
 488                 :suggested-prefix (xpath-protocol:namespace-prefix node)
 489                 :extra-namespaces (namespaces-as-alist node))
 490              (funcall body ctx)))
 491           ((xpath-protocol:node-type-p node :document)
 492            (funcall body ctx))
 493           (t
 494            (copy-leaf-node node)))))))
 495
 496 (defun copy-leaf-node (node)
 497   (cond
 498     ((xpath-protocol:node-type-p node :text)
 499      (write-text (xpath-protocol:node-text node)))
 500     ((xpath-protocol:node-type-p node :comment)
 501      (write-comment (xpath-protocol:node-text node)))
 502     ((xpath-protocol:node-type-p node :processing-instruction)
 503      (write-processing-instruction
 504          (xpath-protocol:processing-instruction-target node)
 505        (xpath-protocol:node-text node)))
 506     ((xpath-protocol:node-type-p node :attribute)
 507      (write-attribute
 508       (xpath-protocol:local-name node)
 509       (xpath-protocol:namespace-uri node)
 510       (xpath-protocol:node-text node)
 511       :suggested-prefix (xpath-protocol:namespace-prefix node)))
 512     ((xpath-protocol:node-type-p node :namespace)
 513      (write-extra-namespace
 514       (xpath-protocol:local-name node)
 515       (xpath-protocol:namespace-uri node)))
 516     (t
 517      (error "don't know how to copy node ~A" node))))
 518
 519 (defun compile-message (fn args env)
 520   (let ((thunk (compile-instruction `(progn ,@args) env)))
 521     (lambda (ctx)
 522       (funcall fn
 523                (with-xml-output (cxml:make-string-sink)
 524                  (funcall thunk ctx))))))
 525
 526 (define-instruction xsl:apply-templates (args env)
 527   (destructuring-bind ((&key select mode) &rest param-binding-specs) args
 528     (let* ((decls
 529             (when (and (consp (car param-binding-specs))
 530                        (eq (caar param-binding-specs) 'declare))
 531               (cdr (pop param-binding-specs))))
 532            (select-thunk
 533             (compile-xpath (or select "child::node()") env))
 534            (param-bindings
 535             (compile-var-bindings param-binding-specs env))
 536            (sort-predicate
 537             (when decls
 538               (make-sort-predicate decls env))))
 539       (multiple-value-bind (mode-local-name mode-uri)
 540           (and mode (decode-qname mode env nil))
 541         (lambda (ctx)
 542           (let ((*mode* (if mode
 543                             (or (find-mode *stylesheet*
 544                                            mode-local-name
 545                                            mode-uri)
 546                                 *empty-mode*)
 547                             *mode*)))
 548             (apply-templates/list
 549              (xpath::force
 550               (xpath::sorted-pipe-of (funcall select-thunk ctx)))
 551              (loop for (name nil value-thunk) in param-bindings
 552                 collect (list name (funcall value-thunk ctx)))
 553              sort-predicate)))))))
 554
 555 (define-instruction xsl:apply-imports (args env)
 556   (declare (ignore args env))
 557   (lambda (ctx)
 558     (declare (ignore ctx))
 559     (funcall *apply-imports*)))
 560
 561 (define-instruction xsl:call-template (args env)
 562   (destructuring-bind (name &rest param-binding-specs) args
 563       (let ((param-bindings
 564              (compile-var-bindings param-binding-specs env)))
 565         (multiple-value-bind (local-name uri)
 566             (decode-qname name env nil)
 567           (setf name (cons local-name uri)))
 568         (lambda (ctx)
 569           (call-template ctx name
 570                          (loop for (name nil value-thunk) in param-bindings
 571                                collect (list name (funcall value-thunk ctx))))))))
 572
 573 ;; fixme: incompatible with XSLT 2.0
 574 (define-instruction xsl:document (args env)
 575   (destructuring-bind ((href &key method indent doctype-public doctype-system)
 576                        &body body)
 577       args
 578     (declare (ignore doctype-public doctype-system)) ;fixme
 579     (let ((thunk (compile-instruction `(progn ,@body) env))
 580           (href-thunk (compile-avt href env)))
 581       (lambda (ctx)
 582         (let ((pathname
 583                (uri-to-pathname
 584                 (puri:merge-uris (funcall href-thunk ctx)
 585                                  (xpath-protocol:base-uri
 586                                   (xpath:context-node ctx))))))
 587           (ensure-directories-exist pathname) ;really?
 588           (invoke-with-output-sink
 589            (lambda ()
 590              (funcall thunk ctx))
 591            (make-output-specification :method (or method "XML") :indent indent)
 592            pathname))))))
 593
 594 (defun compile-instruction (form env)
 595   (xslt-trace-thunk
 596    (funcall (or (get (car form) 'xslt-instruction)
 597                 (error "undefined instruction: ~A" (car form)))
 598             (cdr form)
 599             env)
 600    "instruction ~s" (car form)))
 601
 602 ;;: WTF: "A right curly brace inside a Literal in an expression is not
 603 ;;; recognized as terminating the expression."
 604 ;;;
 605 ;;; Da hilft nur tagbody.
 606 (defun parse-attribute-value-template (template-string)
 607   (with-input-from-string (input template-string)
 608     (let ((ordinary (make-string-output-stream))
 609           (xpath (make-string-output-stream))
 610           (tokens '())
 611           (c (read-char input nil :eof)))
 612       (flet ((emit ()
 613                (let ((o (get-output-stream-string ordinary)))
 614                  (when (plusp (length o))
 615                    (push (list :data o) tokens)))
 616                (let ((x (get-output-stream-string xpath)))
 617                  (when (plusp (length x))
 618                    (push (list :xpath x) tokens))))
 619              (collect-ordinary ()
 620                (write-char c ordinary))
 621              (collect-xpath ()
 622                (write-char c xpath)))
 623         (macrolet ((goto (target)
 624                      `(progn
 625                         (setf c (read-char input nil :eof))
 626                         (go ,target))))
 627           (tagbody
 628            ordinary
 629              (case c
 630                (#\{
 631                 (goto seen{))
 632                (#\}
 633                 (goto seen-stray-}))
 634                (:eof
 635                 (go done)))
 636              (collect-ordinary)
 637              (goto ordinary)
 638
 639            seen{
 640              (case c
 641                (#\{
 642                 (collect-ordinary)
 643                 (goto ordinary))
 644                (#\'
 645                 (collect-xpath)
 646                 (goto in-single-quote))
 647                (:eof
 648                 (xslt-error "unexpected end of avt")))
 649              (emit)
 650              (collect-xpath)
 651              (goto xpath)
 652
 653            xpath
 654              (case c
 655                (#\'
 656                 (collect-xpath)
 657                 (goto in-single-quote))
 658                (#\"
 659                 (collect-xpath)
 660                 (goto in-double-quote))
 661                (#\}
 662                 (goto seen-closing-}))
 663                (:eof
 664                 (xslt-error "unexpected end of avt")))
 665              (collect-xpath)
 666              (goto xpath)
 667
 668            in-single-quote
 669              (case c
 670                (#\'
 671                 (collect-xpath)
 672                 (goto xpath))
 673                (:eof
 674                 (xslt-error "unexpected end of avt")))
 675              (collect-xpath)
 676              (goto in-single-quote)
 677
 678            in-double-quote
 679              (case c
 680                (#\"
 681                 (collect-xpath)
 682                 (goto xpath))
 683                (:eof
 684                 (xslt-error "unexpected end of avt")))
 685              (collect-xpath)
 686              (goto in-double-quote)
 687
 688            seen-closing-}
 689              (case c
 690                (#\}
 691                 (collect-xpath)
 692                 (goto xpath))
 693                (#\{
 694                 (emit)
 695                 (goto xpath))
 696                (:eof
 697                 (goto done)))
 698              (emit)
 699              (collect-ordinary)
 700              (goto ordinary)
 701
 702            seen-stray-}
 703              (case c
 704                (#\}
 705                 (collect-ordinary)
 706                 (goto ordinary)))
 707              (xslt-error "unexpected closing brace in avt")
 708
 709            done
 710              (emit))))
 711       (nreverse tokens))))
 712
 713 (defun compile-avt (template-string env)
 714   (let* ((constantp t)
 715          (fns
 716           (mapcar (lambda (x)
 717                     (ecase (car x)
 718                       (:data
 719                        (constantly (second x)))
 720                       (:xpath
 721                        (setf constantp nil)
 722                        (compile-xpath (second x) env))))
 723                   (parse-attribute-value-template template-string))))
 724     (values (lambda (ctx)
 725               (with-output-to-string (s)
 726                 (dolist (fn fns)
 727                   (write-string (xpath:string-value (funcall fn ctx)) s))))
 728             constantp)))
 729
 730
 731 ;;;; Indentation for slime
 732
 733 (defmacro define-indentation (name (&rest args))
 734   (labels ((collect-variables (list)
 735              (loop
 736                 for sub in list
 737                 append
 738                 (etypecase sub
 739                   (list
 740                    (collect-variables sub))
 741                   (symbol
 742                    (if (eql (mismatch "&" (symbol-name sub)) 1)
 743                        nil
 744                        (list sub)))))))
 745     `(defmacro ,name (,@args)
 746        (declare (ignorable ,@(collect-variables args)))
 747        (error "XSL indentation helper ~A used literally in lisp code"
 748               ',name))))
 749
 750 (define-indentation xsl:element
 751     ((name &key namespace use-attribute-sets) &body body))
 752 (define-indentation xsl:literal-element ((name &optional uri) &body body))
 753 (define-indentation xsl:attribute ((name &key namespace) &body body))
 754 (define-indentation xsl:literal-attribute ((name &optional uri) &body body))
 755 (define-indentation xsl:text (str))
 756 (define-indentation xsl:processing-instruction (name &body body))
 757 (define-indentation xsl:comment (&body body))
 758 (define-indentation xsl:value-of (xpath))
 759 (define-indentation xsl:unescaped-value-of (xpath))
 760 (define-indentation xsl:for-each (select &body decls-and-body))
 761 (define-indentation xsl:message (&body body))
 762 (define-indentation xsl:terminate (&body body))
 763 (define-indentation xsl:apply-templates ((&key select mode) &body decls-and-body))
 764 (define-indentation xsl:call-template (name &rest parameters))
 765 (define-indentation xsl:copy-of (xpath))
 766
 767 ;;;;
 768
 769 (defun test-instruction (form document)
 770   (let ((thunk (compile-instruction form (make-instance 'lexical-environment)))
 771         (root (cxml:parse document (stp:make-builder))))
 772     (with-xml-output (cxml:make-string-sink)
 773       (funcall thunk (xpath:make-context root)))))