unparse.lisp

   1 ;;; -*- show-trailing-whitespace: t; indent-tabs-mode: nil -*-
   2
   3 ;;; Copyright (c) 2007,2008 David Lichteblau, Ivan Shvedunov.
   4 ;;; Copyright (c) 2004 David Lichteblau (for headcraft.de)
   5 ;;; All rights reserved.
   6
   7 ;;; Redistribution and use in source and binary forms, with or without
   8 ;;; modification, are permitted provided that the following conditions
   9 ;;; are met:
  10 ;;;
  11 ;;;   * Redistributions of source code must retain the above copyright
  12 ;;;     notice, this list of conditions and the following disclaimer.
  13 ;;;
  14 ;;;   * Redistributions in binary form must reproduce the above
  15 ;;;     copyright notice, this list of conditions and the following
  16 ;;;     disclaimer in the documentation and/or other materials
  17 ;;;     provided with the distribution.
  18 ;;;
  19 ;;; THIS SOFTWARE IS PROVIDED BY THE AUTHOR 'AS IS' AND ANY EXPRESSED
  20 ;;; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  21 ;;; WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  22 ;;; ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY
  23 ;;; DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  24 ;;; DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE
  25 ;;; GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  26 ;;; INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  27 ;;; WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
  28 ;;; NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  29 ;;; SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  30
  31 (in-package :xuriella)
  32
  33
  34 ;;; Convenience functions for serialization to SAX, similar in syntax
  35 ;;; to what cxml offers, but with namespace handling as required for XSLT.
  36
  37 (defvar *current-element*)
  38 (defvar *sink*)
  39 (defvar *start-tag-written-p*)
  40
  41 (defmacro with-xml-output (sink &body body)
  42   `(invoke-with-xml-output (lambda () ,@body) ,sink))
  43
  44 (defmacro with-output-sink-bound ((var) &body body)
  45   `(invoke-with-output-sink-bound (lambda (,var) ,@body)))
  46
  47 (defun invoke-with-xml-output (fn sink)
  48   (let ((*sink* sink)
  49         (*current-element* nil)
  50         (*start-tag-written-p* t))
  51     (sax:start-document *sink*)
  52     (funcall fn)
  53     (sax:end-document *sink*)))
  54
  55 (defun invoke-with-output-sink-bound (fn)
  56   (maybe-emit-start-tag)
  57   (funcall fn *sink*))
  58
  59 (defun unalias-uri (uri)
  60   (gethash uri (stylesheet-namespace-aliases *stylesheet*)
  61            uri))
  62
  63 (defmacro with-element ((local-name uri &key suggested-prefix extra-namespaces)
  64                         &body body)
  65   `(invoke-with-element (lambda () ,@body)
  66                         ,local-name
  67                         ,uri
  68                         :suggested-prefix ,suggested-prefix
  69                         :extra-namespaces ,extra-namespaces))
  70
  71 (defun doctype (name public-id system-id &optional internal-subset)
  72   (sax:start-dtd *sink* name public-id system-id)
  73   (when internal-subset
  74     (sax:unparsed-internal-subset *sink* internal-subset))
  75   (sax:end-dtd *sink*))
  76
  77 (defun maybe-emit-start-tag ()
  78   (let ((elt *current-element*))
  79     (when (and elt (not *start-tag-written-p*))
  80       (setf *start-tag-written-p* t)
  81       (let* ((local-name (sink-element-local-name elt))
  82              (uri (sink-element-uri elt))
  83              (suggested-prefix (sink-element-suggested-prefix elt))
  84              (prefix (ensure-prefix-for-uri elt uri suggested-prefix))
  85              (qname (if (plusp (length prefix))
  86                         (concatenate 'string prefix ":" local-name)
  87                         local-name))
  88              (attrs '()))
  89         (setf (sink-element-actual-qname elt) qname)
  90         (dolist (attr (sink-element-attributes elt))
  91           (push (convert-attribute elt attr) attrs))
  92         (loop
  93            for (prefix . uri) in (sink-element-new-namespaces elt) do
  94              (sax:start-prefix-mapping *sink* prefix uri)
  95              (push (make-xmlns-attribute prefix uri) attrs))
  96         (sax:start-element *sink* uri local-name qname attrs)))))
  97
  98 (defun convert-attribute (elt attr)
  99   (let* ((local-name (sink-attribute-local-name attr))
 100          (uri (sink-attribute-uri attr))
 101          (suggested-prefix (sink-attribute-suggested-prefix attr))
 102          (prefix (ensure-prefix-for-uri elt uri suggested-prefix))
 103          (qname (if (plusp (length prefix))
 104                     (concatenate 'string prefix ":" local-name)
 105                     local-name)))
 106     (sax:make-attribute :namespace-uri uri
 107                         :local-name local-name
 108                         :qname qname
 109                         :value (sink-attribute-value attr))))
 110
 111 (defun sink-element-find-uri (prefix elt)
 112   (cdr
 113    (find prefix
 114          (sink-element-all-namespaces elt)
 115          :key #'car
 116          :test #'equal)))
 117
 118 (defun ensure-prefix-for-uri (elt uri &optional suggested-prefix)
 119   (let* ((prefix-cons
 120           (find uri
 121                 (sink-element-all-namespaces elt)
 122                 :key #'cdr
 123                 :test #'equal))
 124          (prefix (car prefix-cons))
 125          (cross-check
 126           (when prefix-cons
 127             (sink-element-find-uri prefix elt))))
 128     (if (and prefix-cons (equal cross-check uri))
 129         prefix
 130         (loop
 131            for i from 0
 132            for prefix = suggested-prefix then (format nil "ns-~D" i)
 133            while
 134              (sink-element-find-uri prefix elt)
 135            finally
 136              (push-sink-element-namespace elt prefix uri)
 137              (return prefix)))))
 138
 139 (defun make-xmlns-attribute (prefix uri)
 140   (sax:make-attribute
 141    :namespace-uri #"http://www.w3.org/2000/xmlns/"
 142    :local-name prefix
 143    :qname (if (zerop (length prefix))
 144               "xmlns"
 145               (concatenate 'string "xmlns:" prefix))
 146    :value uri))
 147
 148 (defstruct sink-element
 149   local-name
 150   uri
 151   suggested-prefix
 152   all-namespaces
 153   new-namespaces
 154   attributes
 155   actual-qname)
 156
 157 (defstruct sink-attribute
 158   local-name
 159   uri
 160   suggested-prefix
 161   value)
 162
 163 (defun invoke-with-element
 164     (fn local-name uri &key suggested-prefix extra-namespaces)
 165   (check-type local-name string)
 166   (check-type uri string)
 167   (check-type suggested-prefix (or null string))
 168   (maybe-emit-start-tag)
 169   (setf uri (unalias-uri uri))
 170   (let* ((parent *current-element*)
 171          (elt (make-sink-element
 172                :local-name local-name
 173                :uri uri
 174                :suggested-prefix suggested-prefix
 175                :all-namespaces (if parent
 176                                    (sink-element-all-namespaces parent)
 177                                    *initial-namespaces*)
 178                :new-namespaces nil
 179                :attributes nil))
 180          (*current-element* elt)
 181          (*start-tag-written-p* nil))
 182     (process-extra-namespaces elt extra-namespaces)
 183     (multiple-value-prog1
 184         (funcall fn)
 185       (maybe-emit-start-tag)
 186       (sax:end-element *sink* uri local-name (sink-element-actual-qname elt))
 187       (loop
 188          for (prefix . uri) in (sink-element-new-namespaces elt) do
 189          (sax:end-prefix-mapping *sink* prefix)))))
 190
 191 (defun process-extra-namespaces (elt extra-namespaces)
 192   (loop
 193      for (prefix . auri) in extra-namespaces
 194      for uri = (unalias-uri auri)
 195      do
 196      (unless
 197          ;; allow earlier conses in extra-namespaces to hide later ones.
 198          (find prefix
 199                (sink-element-new-namespaces elt)
 200                :key #'car
 201                :test #'equal)
 202        (let ((previous (sink-element-find-uri prefix elt)))
 203          (unless
 204              ;; no need to declare what has already been done
 205              (equal uri previous)
 206            (push-sink-element-namespace elt prefix uri))))))
 207
 208 (defun push-sink-element-namespace (elt prefix uri)
 209   (cond
 210     ((equal prefix "xml")
 211      (assert (equal uri "http://www.w3.org/XML/1998/namespace")))
 212     ((equal prefix "xmlns")
 213      (assert (equal uri "http://www.w3.org/2000/xmlns/")))
 214     (t
 215      (let ((cons (cons prefix uri)))
 216        (push cons (sink-element-all-namespaces elt))
 217        (push cons (sink-element-new-namespaces elt))))))
 218
 219 (defun write-attribute (local-name uri value &key suggested-prefix)
 220   (check-type local-name string)
 221   (check-type uri string)
 222   (check-type value string)
 223   (check-type suggested-prefix (or null string))
 224   (setf uri (unalias-uri uri))
 225   (cond
 226     ((null *current-element*)
 227      (xslt-error "attribute outside of element"))
 228     (*start-tag-written-p*
 229      (xslt-cerror "attribute after start tag"))
 230     ((equal local-name "xmlns")
 231      (xslt-error "attribute named xmlns"))
 232     (t
 233      (setf (sink-element-attributes *current-element*)
 234            (cons (make-sink-attribute :local-name local-name
 235                                       :uri uri
 236                                       :suggested-prefix suggested-prefix
 237                                       :value value)
 238                  (delete-if (lambda (x)
 239                               (and (equal (sink-attribute-local-name x)
 240                                           local-name)
 241                                    (equal (sink-attribute-uri x) uri)))
 242                             (sink-element-attributes *current-element*)))))))
 243
 244 (defun write-text (data)
 245   (maybe-emit-start-tag)
 246   (sax:characters *sink* data)
 247   data)
 248
 249 (defun write-comment (data)
 250   (maybe-emit-start-tag)
 251   (sax:comment *sink* data)
 252   data)
 253
 254 (defun write-processing-instruction (target data)
 255   (maybe-emit-start-tag)
 256   (sax:processing-instruction *sink* target data)
 257   data)
 258
 259 (defun write-unescaped (str)
 260   (maybe-emit-start-tag)
 261   (sax:unescaped *sink* str))