test.lisp

   1 ;;; -*- show-trailing-whitespace: t; indent-tabs-mode: nil -*-
   2
   3 ;;; Copyright (c) 2007,2008 David Lichteblau, Ivan Shvedunov.
   4 ;;; All rights reserved.
   5
   6 ;;; Redistribution and use in source and binary forms, with or without
   7 ;;; modification, are permitted provided that the following conditions
   8 ;;; are met:
   9 ;;;
  10 ;;;   * Redistributions of source code must retain the above copyright
  11 ;;;     notice, this list of conditions and the following disclaimer.
  12 ;;;
  13 ;;;   * Redistributions in binary form must reproduce the above
  14 ;;;     copyright notice, this list of conditions and the following
  15 ;;;     disclaimer in the documentation and/or other materials
  16 ;;;     provided with the distribution.
  17 ;;;
  18 ;;; THIS SOFTWARE IS PROVIDED BY THE AUTHOR 'AS IS' AND ANY EXPRESSED
  19 ;;; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  20 ;;; WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21 ;;; ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY
  22 ;;; DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  23 ;;; DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE
  24 ;;; GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  25 ;;; INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  26 ;;; WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
  27 ;;; NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  28 ;;; SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29
  30 (in-package :xuriella)
  31
  32 (defparameter *tests-directory*
  33   "/home/david/src/XSLT-testsuite-04/testsuite/TESTS/")
  34
  35 (defclass test-case ()
  36   ((id :initarg :id :accessor test-id)
  37    (category :initarg :category :accessor test-category)
  38    (operation :initarg :operation :accessor test-operation)
  39    (data-pathname :initarg :data-pathname :accessor test-data-pathname)
  40    (stylesheet-pathname :initarg :stylesheet-pathname
  41                         :accessor test-stylesheet-pathname)
  42    (data-pathname-2 :initarg :data-pathname-2 :accessor test-data-pathname-2)
  43    (stylesheet-pathname-2 :initarg :stylesheet-pathname-2
  44                           :accessor test-stylesheet-pathname-2)
  45    (output-pathname :initarg :output-pathname
  46                     :accessor test-official-output-pathname)
  47    (output-compare :initarg :output-compare
  48                    :accessor test-output-compare)))
  49
  50 (defmethod print-object ((object test-case) stream)
  51   (print-unreadable-object (object stream :identity nil :type t)
  52     (format stream "~A ~A/~A"
  53             (test-operation object)
  54             (test-category object)
  55             (test-id object))))
  56
  57
  58 ;;;; SIMPLIFY-TESTS
  59
  60 ;;; Translate catalog.xml into an actually usable katalog.xml
  61 ;;; by running the test cases through xsltproc to see what it thinks
  62 ;;; about them.
  63
  64 (defun simplify-tests (&optional (d *tests-directory*))
  65   (with-open-file (stream (merge-pathnames "katalog.xml" d)
  66                           :direction :output
  67                           :if-exists :supersede
  68                           :element-type '(unsigned-byte 8))
  69     (cxml:with-xml-output (cxml:make-octet-stream-sink stream)
  70       (cxml:with-element "simplified-test-suite"
  71         (klacks:with-open-source
  72             (source (klacks:make-tapping-source
  73                      (cxml:make-source (merge-pathnames "catalog.xml" d))))
  74           (let ((*default-pathname-defaults* (merge-pathnames d)))
  75             (map-original-tests #'simplify-test source)))))))
  76
  77 (defun map-original-tests (run-test source &key (test (constantly t)))
  78   (let ((total 0)
  79         (pass 0)
  80         major-path)
  81     (loop
  82        while (klacks:find-event source :start-element)
  83        for lname = (klacks:current-lname source)
  84        do
  85        (cond
  86          ((equal lname "major-path")
  87           (klacks:skip source :start-element)
  88           (setf major-path
  89                 (namestring
  90                  (merge-pathnames (klacks:consume-characters source)))))
  91          ((equal lname "test-case")
  92           (let* ((<test-case>
  93                   (stp:document-element
  94                    (klacks:serialize-element source (stp:make-builder))))
  95                  (test-case (parse-original-test major-path <test-case>)))
  96             (when (funcall test test-case)
  97               (incf total)
  98               (when (funcall run-test test-case)
  99                 (incf pass)))))
 100          (t
 101           (klacks:skip source :start-element))))
 102     (format t "~&Passed ~D/~D tests.~%" pass total)))
 103
 104 (defun parse-original-test (major-path <test-case>)
 105   (let* ((file-path
 106           (stp:string-value
 107            (stp:find-recursively-if (stp:of-name "file-path") <test-case>)))
 108          (base (concatenate 'string major-path "/" file-path))
 109          (out-base (concatenate 'string major-path "/REF_OUT/" file-path))
 110          (scenario
 111           (stp:find-recursively-if (stp:of-name "scenario") <test-case>))
 112          data
 113          stylesheet
 114          supplemental-stylesheet
 115          supplemental-data
 116          output
 117          compare)
 118     (dolist (<input> (stp:filter-recursively (stp:of-name "input-file")
 119                                              <test-case>))
 120       (let ((role (stp:attribute-value <input> "role"))
 121             (path (concatenate 'string base "/" (stp:string-value <input>))))
 122         (cond
 123           ((equal role "principal-data")
 124            (setf data path))
 125           ((equal role "principal-stylesheet")
 126            (setf stylesheet path))
 127           ((equal role "supplemental-stylesheet")
 128            (setf supplemental-stylesheet path))
 129           ((equal role "supplemental-data")
 130            (setf supplemental-data path))
 131           (t
 132            (error "unrecognized role: ~A" role)))))
 133     (dolist (<output> (stp:filter-recursively (stp:of-name "output-file")
 134                                             <test-case>))
 135       (let ((role (stp:attribute-value <output> "role"))
 136             (path (concatenate 'string out-base
 137                                "/"
 138                                (stp:string-value <output>))))
 139         (cond
 140           ((equal role "principal")
 141            (setf output path)
 142            (setf compare (stp:attribute-value <output> "compare")))
 143           (t
 144            (error "unrecognized role: ~A" role)))))
 145     (make-instance 'test-case
 146                    :id (stp:attribute-value <test-case> "id")
 147                    :category (stp:attribute-value <test-case> "category")
 148                    :operation (stp:attribute-value scenario "operation")
 149                    :data-pathname data
 150                    :stylesheet-pathname stylesheet
 151                    :stylesheet-pathname-2 supplemental-stylesheet
 152                    :data-pathname-2 supplemental-data
 153                    :output-pathname output
 154                    :output-compare compare)))
 155
 156 (defun write-simplified-test (test-case operation)
 157   (cxml:with-element "test-case"
 158     (cxml:attribute "id" (test-id test-case))
 159     (cxml:attribute "category" (test-category test-case))
 160     (flet ((p (l p)
 161              (cxml:attribute l (and p (namestring p)))))
 162       (p "data" (test-data-pathname test-case))
 163       (p "stylesheet" (noindent-stylesheet-pathname test-case))
 164       (p "data-2" (test-data-pathname-2 test-case))
 165       (p "stylesheet-2" (test-stylesheet-pathname-2 test-case))
 166       (p "output" (test-official-output-pathname test-case))
 167       (p "compare" (test-output-compare test-case)))
 168     (cxml:attribute "operation" operation)))
 169
 170 (defun test-output-pathname (test type)
 171   (make-pathname :name (test-id test)
 172                  :type type
 173                  :defaults (test-data-pathname test)))
 174
 175 (defun sanitize-stylesheet (in out)
 176   (if (probe-file in)
 177       (handler-case
 178           (let ((d (cxml:parse (pathname in) (stp:make-builder))))
 179             (xpath:with-namespaces ((nil #.*xsl*))
 180               (xpath:do-node-set (output (xpath:evaluate "//output" d))
 181                 (let ((a (stp:find-attribute-named output "indent")))
 182                   (when a
 183                     (stp:detach a)))))
 184             (with-open-file (s out
 185                                :direction :output
 186                                :if-exists :rename-and-delete
 187                                :element-type '(unsigned-byte 8))
 188               (stp:serialize d (cxml:make-octet-stream-sink s))))
 189         (error (c)
 190           (warn "ignoring bogus stylesheet ~A: ~A" in c)
 191           (copy-file in out)))
 192       (warn "oops, ignoring missing stylesheet: ~A" in)))
 193
 194 (defun noindent-stylesheet-pathname (test-case)
 195   (make-pathname :type "noindent-xsl"
 196                  :defaults (test-stylesheet-pathname test-case)))
 197
 198 (defun simplify-test (test-case)
 199   (flet ((report (status &optional (fmt "") &rest args)
 200            (format t "~&~A ~A [~A]~?~%"
 201                    status
 202                    (test-id test-case)
 203                    (test-category test-case)
 204                    fmt
 205                    args)))
 206     (let* ((data (test-data-pathname test-case))
 207            (stylesheet (test-stylesheet-pathname test-case))
 208            (noindent-stylesheet (noindent-stylesheet-pathname test-case))
 209            #+xuriella::xsltproc
 210            (out (test-output-pathname test-case "xsltproc"))
 211            (saxon-out (test-output-pathname test-case "saxon")))
 212       (sanitize-stylesheet stylesheet noindent-stylesheet)
 213       (if (equal (test-operation test-case) "standard")
 214           (handler-case
 215               (progn
 216                 #+xuriella::xsltproc (xsltproc noindent-stylesheet data out)
 217                 (saxon noindent-stylesheet data saxon-out)
 218                 (report "PASS")
 219                 (write-simplified-test test-case "standard")
 220                 t)
 221             (error (c)
 222               (report "FAIL" ": ~A" c)
 223               (write-simplified-test test-case "execution-error")
 224               nil))
 225           (handler-case
 226               (progn
 227                 #+xuriella::xsltproc
 228                 (xsltproc noindent-stylesheet data "/dev/null")
 229                 (saxon noindent-stylesheet data "/dev/null")
 230                 (report "FAIL" ": expected error not signalled")
 231                 ;; let's ignore unexpected successes for now
 232                 nil)
 233             (error (c)
 234               (report "PASS" ": expected error ~A" c)
 235               (write-simplified-test test-case "execution-error")
 236               t))))))
 237
 238 (defun xsltproc (stylesheet input output)
 239   (flet ((full-namestring (x)
 240            (namestring (merge-pathnames x))))
 241     (let* ((asdf::*verbose-out* (make-string-output-stream))
 242            (code (asdf:run-shell-command
 243                   "cd ~S && xsltproc ~S ~S >~S"
 244                   (full-namestring "")
 245                   (full-namestring stylesheet)
 246                   (full-namestring input)
 247                   (full-namestring output))))
 248       (unless (zerop code)
 249         (error "running xsltproc failed with code ~A [~%~A~%]"
 250                code
 251                (get-output-stream-string asdf::*verbose-out*))))))
 252
 253 (defun saxon (stylesheet input output)
 254   (flet ((full-namestring (x)
 255            (namestring (merge-pathnames x))))
 256     (let* ((asdf::*verbose-out* (make-string-output-stream))
 257            (code (asdf:run-shell-command
 258                   "cd ~S && java -jar /usr/share/java/saxon.jar ~S ~S >~S"
 259                   (full-namestring "")
 260                   (full-namestring input)
 261                   (full-namestring stylesheet)
 262                   (full-namestring output))))
 263       (unless (zerop code)
 264         (error "running saxon failed with code ~A [~%~A~%]"
 265                code
 266                (get-output-stream-string asdf::*verbose-out*))))))
 267
 268
 269 ;;;; RUN-TESTS and DRIBBLE-TESTS
 270
 271 ;;; Process katalog.xml
 272
 273 (defun dribble-tests
 274     (&key filter (directory *tests-directory*) (file "TEST"))
 275   (let ((*package* (find-package 'cl-user))
 276         (*print-circle* nil))
 277     (with-open-file (dribble
 278                      (merge-pathnames file
 279                                       (slot-value (asdf:find-system :xuriella)
 280                                                   'asdf::relative-pathname))
 281                      :direction :output
 282                      :if-exists :supersede
 283                      :external-format :utf-8)
 284       (let* ((dribble (make-broadcast-stream dribble *standard-output*))
 285              (*standard-output* dribble)
 286              (*trace-output* dribble)
 287              (*error-output* dribble)
 288              (*terminal-io* (make-two-way-stream *standard-input* dribble)))
 289         (handler-bind ((warning
 290                         (lambda (c)
 291                           (warn "~A" (replace-junk (princ-to-string c)))
 292                           (muffle-warning c))))
 293           (run-tests :filter filter
 294                      :directory directory))))))
 295
 296 (defparameter *bad-tests*
 297   '(;; Inconsistent tests:
 298     ;;
 299     ;; Some tests wants us to recover from this error, yet this one doesn't:
 300     "copy_copy61"
 301     "copy_copy62"
 302
 303     ;; Should we fix this?
 304     ;;
 305     ;; We signal a run-time error when and if it's actually used.  The test
 306     ;; wants a compilation-time error...
 307     "AttributeSets_RefToUndefinedAttributeSet"
 308
 309     ;; We would pass this:
 310     ;;
 311     ;; We perform recovery, but saxon doesn't.  Recovery results in non-XML
 312     ;; output, which we can't parse for comparison against the official
 313     ;; test case.
 314     "output_output75"
 315     ;;
 316     ;; we'd pass these tests, but the test authors forgot to declare the
 317     ;; entity they're writing, so we can't parse it for comparison.
 318     "output_output06"
 319     "output_output10"
 320     "output_output61"
 321     ;;
 322     ;; another similar test where the output is unparsable, except that
 323     ;; here an entity declaration wouldn't have helped either:
 324     "Copying_ResultTreeFragmentWithEscapedText"
 325
 326     ;; Broken test:
 327     ;;
 328     ;; Input document isn't ns-wf.
 329     "Attributes__78387"
 330     ;;
 331     ;; Someone commented out most of this test...
 332     "BVTs_bvt045"
 333
 334     ;; FIXME: should re-enable these at some point:
 335     ;;
 336     ;; the following tests take a lot of time due to the problems of current matching algorithm:
 337     "impincl_impincl16"
 338     ;; probably the same problem (but I haven't checked):
 339     "Import__91164"
 340
 341     ;; stack exhaustion -- matching problem i think
 342     "Keys_PerfRepro3"
 343
 344     ;; test stylesheet doesn't exist?!
 345     "ConflictResolution__77833"
 346     "Include__77736"))
 347
 348 ;; Tests where the output isn't a match because of extraneous whitespace.
 349 ;; For these tests, we force space normalization before comparing.
 350 ;;
 351 ;; Possible reasons for this problem are:
 352 ;;   a. The output method is declared in an imported stylesheet.
 353 ;;      SANITIZE-STYLESHEET is supposed to get rid of indent="yes", but it
 354 ;;      misses imported stylesheets.
 355 ;;   b. Saxon output isn't a match, but the official output is.
 356 ;;      But the official output is unaffected by SANITIZE-STYLESHEET.
 357 ;;
 358 (defparameter *whitespace-issues*
 359   (cl-ppcre:create-scanner
 360    "(?smx)
 361     ^(BVTs_bvt044$
 362        |Namespace-alias__91782$
 363        |AttributeSets__91038$
 364        |BVTs_bvt041$
 365        |BVTs_bvt042$
 366        |BVTs_bvt054$
 367        |BVTs_bvt058$
 368        |Import__
 369        |Include__
 370        )"))
 371
 372 (defparameter *known-failures*
 373   '(
 374     ;; uses EBCDIC-CP-IT (whatever that is), but Babel's only got EBCDIC-US.
 375     ;; Doesn't actually test any differences between the two, so it's
 376     ;; probably just there to annoy us.
 377     "output_output22"
 378
 379     ;; uses KOI, which Babel doesn't support
 380     "BVTs_bvt019"
 381
 382     ;; shift_jis
 383     "Include__77515"
 384
 385     ;; FIXME?
 386     ;;
 387     ;; This is an HTML output method issue.  The spec says the HTML
 388     ;; output method should output elements with a null namespace URI as
 389     ;; HTML, and if their name isn't recognized, as an inline element.
 390     ;; <xml> here is such an element.  It has an attributes with a
 391     ;; namespace though, and the spec doesn't say what we should do with that
 392     ;; attribute.  We currently output it using Closure HTML, and
 393     ;; lose its namespace.  This test wants the attribute and its
 394     ;; namespace to survive.
 395     "BVTs_bvt054"))
 396
 397 (defun run-tests (&key filter (directory *tests-directory*))
 398   (when (typep filter '(or string cons))
 399     (setf filter (cl-ppcre:create-scanner filter)))
 400   (klacks:with-open-source
 401       (source (klacks:make-tapping-source
 402                (cxml:make-source (merge-pathnames "katalog.xml" directory))))
 403     (let ((*default-pathname-defaults* (merge-pathnames directory)))
 404       (map-tests #'run-test
 405                  source
 406                  :test (lambda (test)
 407                          (and (or (null filter)
 408                                   (cl-ppcre:all-matches
 409                                    filter
 410                                    (format nil "~A/~A"
 411                                            (test-category test)
 412                                            (test-id test))))
 413                               (not (find (test-id test)
 414                                          *bad-tests*
 415                                          :test #'equal))))))))
 416
 417 (defun run-named-test (name &optional (d *tests-directory*))
 418   (let ((*break-on-signals*
 419          '(and error (not babel-encodings:character-encoding-error))))
 420     (run-tests :filter (format nil "/~A$" name) :directory d)))
 421
 422 (defun copy-file (p q)
 423   (with-open-file (in p :element-type '(unsigned-byte 8))
 424     (with-open-file (out q
 425                          :element-type '(unsigned-byte 8)
 426                          :direction :output
 427                          :if-exists :rename-and-delete)
 428       (let ((buf (make-array 8192 :element-type '(unsigned-byte 8))))
 429         (loop for pos = (read-sequence buf in)
 430            until (zerop pos)
 431            do (write-sequence buf out :end pos))))))
 432
 433 (defun find-named-test (name &optional (d *tests-directory*))
 434   (klacks:with-open-source
 435       (source (klacks:make-tapping-source
 436                (cxml:make-source (merge-pathnames "katalog.xml" d))))
 437     (block nil
 438       (map-tests (lambda (test)
 439                    (return test))
 440                  source
 441                  :test (lambda (test) (equal (test-id test) name))))))
 442
 443 (defun copy-test-files (name &optional (d *tests-directory*))
 444   (let* ((test (find-named-test name d))
 445          (*default-pathname-defaults* (merge-pathnames d))
 446          (*break-on-signals*
 447           '(and error (not babel-encodings:character-encoding-error)))
 448          (target-dir (merge-pathnames "copied-test/"
 449                                       (asdf:component-pathname
 450                                        (asdf:find-system :xuriella))))
 451          (xsl (merge-pathnames "test.xsl" target-dir))
 452          (xml (merge-pathnames "test.xml" target-dir))
 453          (txt (merge-pathnames "official-output.txt" target-dir))
 454          (expected (merge-pathnames "expected.xml" target-dir))
 455          (actual (merge-pathnames "actual.xml" target-dir)))
 456     (ensure-directories-exist target-dir)
 457     (copy-file (test-stylesheet-pathname test) xsl)
 458     (copy-file (test-data-pathname test) xml)
 459     (when (test-official-output-pathname test)
 460       (copy-file (test-official-output-pathname test) txt))
 461     (format t "Test stylesheet copied to:~%  ~A~%~%" xsl)
 462     (format t "Test data copied to:~%  ~A~%~%" xml)
 463     (when (test-official-output-pathname test)
 464       (format t "Official output file:~%  ~A~%~%" txt))
 465     (format t "Run xsltproc like this:~%  cd ~A~%  xsltproc ~A ~A >~A~%~%"
 466             (namestring target-dir)
 467             (enough-namestring xsl target-dir)
 468             (enough-namestring xml target-dir)
 469             (enough-namestring expected target-dir))
 470     (format t "Run saxon like this:~%  cd ~A~%  java -jar /usr/share/java/saxon.jar ~A ~A >~A~%~%"
 471             (namestring target-dir)
 472             (enough-namestring xml target-dir)
 473             (enough-namestring xsl target-dir)
 474             (enough-namestring expected target-dir))
 475     (format t "Run MSXSL like this:~%  cd ~A~%  wine msxsl.exe ~A ~A >~A~%~%"
 476             (namestring target-dir)
 477             (enough-namestring xml target-dir)
 478             (enough-namestring xsl target-dir)
 479             (enough-namestring expected target-dir))
 480     (format t "Run xuriella like this:~%")
 481     `(apply-stylesheet ,xsl ,xml :output ,actual)))
 482
 483 (defun map-tests (run-test source &key (test (constantly t)))
 484   (let ((total 0)
 485         (pass 0)
 486         (known 0))
 487     (loop
 488        while (klacks:find-event source :start-element)
 489        for lname = (klacks:current-lname source)
 490        do
 491        (cond
 492          ((equal lname "test-case")
 493           (let* ((<test-case>
 494                   (stp:document-element
 495                    (klacks:serialize-element source (stp:make-builder))))
 496                  (test-case (parse-test <test-case>)))
 497             (when (funcall test test-case)
 498               (incf total)
 499               (ecase (funcall run-test test-case)
 500                 ((nil))
 501                 ((t)
 502                  (incf pass))
 503                 (:known-failure
 504                  (incf known))))))
 505          (t
 506           (klacks:skip source :start-element))))
 507     (format t "~&Passed ~D/~D tests (~D expected failures, ~D unexpected failures).~%"
 508             pass total known (- total pass known))))
 509
 510 (defun parse-test (<test-case>)
 511   (stp:with-attributes (id category operation
 512                            data stylesheet data-2 stylesheet-2
 513                            output compare)
 514       <test-case>
 515     (make-instance 'test-case
 516                    :id id
 517                    :category category
 518                    :operation operation
 519                    :data-pathname data
 520                    :stylesheet-pathname stylesheet
 521                    :data-pathname-2 data-2
 522                    :stylesheet-pathname-2 stylesheet-2
 523                    :output-pathname output
 524                    :output-compare compare)))
 525
 526 ;; read from file P, skipping the XMLDecl or TextDecl and Doctype at the
 527 ;; beginning, if any.
 528 (defun slurp-for-comparison (p)
 529   (with-open-file (s p :element-type '(unsigned-byte 8))
 530     (unless (and (eql (read-byte s nil) #xef)
 531                  (eql (read-byte s nil) #xbb)
 532                  (eql (read-byte s nil) #xbf))
 533       (file-position s 0))
 534     (if (plusp (file-length s))
 535         (slurp-for-comparison-1 p s t)
 536         "<wrapper/>")))
 537
 538 (defun slurp-for-comparison-1 (p s junk-info)
 539   (let ((pos (file-position s))         ;for UTF-8 "BOM"
 540         (xstream (runes:make-xstream s :speed 1))
 541         (prev-pos 0))
 542     (setf (runes:xstream-name xstream)
 543           (cxml::make-stream-name
 544            :entity-name "main document"
 545            :entity-kind :main
 546            :uri (cxml::pathname-to-uri (merge-pathnames p))))
 547     (let ((source
 548            (flet ((er (pub sys)
 549                     pub sys
 550                     (flexi-streams:make-in-memory-input-stream
 551                      #())))
 552              (cxml:make-source xstream
 553                                :pathname p
 554                                :entity-resolver #'er))))
 555       (unless (eq junk-info :nada)
 556         (loop
 557            for key = (progn
 558                        (setf prev-pos (runes:xstream-position xstream))
 559                        (klacks:peek-next source))
 560            until (eq key :start-document))
 561         (cxml::with-source (source cxml::context)
 562           (when (eq (cxml::zstream-token-category
 563                      (cxml::main-zstream cxml::context))
 564                     :NMTOKEN)
 565             ;; oops, doesn't look like XML at all
 566             (file-position s pos)
 567             (return-from slurp-for-comparison-1
 568               (slurp-for-comparison-1 p s :nada)))))
 569       (etypecase junk-info
 570         (integer
 571          (dotimes (x junk-info)
 572            (setf prev-pos (runes:xstream-position xstream))
 573            (klacks:peek-next source)))
 574         ((eql t)
 575          (let ((nskip 0))
 576            (handler-case
 577                (loop
 578                   (case (klacks:peek-next source)
 579                     (:start-element (return))
 580                     (:characters
 581                      (if (whitespacep (klacks:current-characters source))
 582                          (incf nskip)
 583                          (return)))
 584                     (t
 585                      (incf nskip))))
 586              ((or file-error cxml:xml-parse-error) ()
 587                (when (zerop nskip)
 588                  (setf nskip nil))))
 589            ;; retry
 590            (with-open-file (u p :element-type '(unsigned-byte 8))
 591              (file-position u pos)
 592              (return-from slurp-for-comparison-1
 593                (slurp-for-comparison-1 p u nskip)))))
 594         ((member nil :nada)))
 595       (with-output-to-string (r)
 596         (let* ((seen-char
 597                 (cxml::with-source (source cxml::context)
 598                   (ecase (cxml::zstream-token-category
 599                           (cxml::main-zstream cxml::context))
 600                     (:seen-< #\<)
 601                     (:? #\?)
 602                     ((nil :s)
 603                      (setf prev-pos (runes:xstream-position xstream))
 604                      nil))))
 605                (off-by-one-p (or seen-char (eq junk-info :nada)))
 606                (new-pos (- prev-pos (if off-by-one-p 1 0))))
 607           ;; copy doctype over
 608           (with-open-file (u p :element-type '(unsigned-byte 8))
 609             (file-position u pos)
 610             (let ((y (runes:make-xstream u :speed 1)))
 611               (loop
 612                  while (< (runes:xstream-position y) new-pos)
 613                  do (write-char (runes:read-rune y) r))))
 614           (write-line "<wrapper>" r)
 615           (when seen-char
 616             (write-char seen-char r)))
 617         (loop
 618            for char = (runes:read-rune xstream)
 619            until (eq char :eof)
 620            do (write-char char r))
 621         (write-line "</wrapper>" r)))))
 622
 623 (defun parse-for-comparison (p)
 624   (let* ((d (flet ((er (pub sys)
 625                     pub sys
 626                     (flexi-streams:make-in-memory-input-stream
 627                      #())))
 628               (cxml:parse (slurp-for-comparison p)
 629                           (make-text-normalizer (stp:make-builder))
 630                           :entity-resolver #'er)))
 631          (de (stp:document-element d)))
 632     (let ((first (stp:first-child de)))
 633       (when (typep first 'stp:text)
 634         (cond
 635           ((whitespacep (stp:data first))
 636            (stp:delete-child first de))
 637           (t
 638            (setf (stp:data first)
 639                  (cl-ppcre:regex-replace #.(format nil "^[~A]+" *whitespace*)
 640                                          (stp:data first)
 641                                          ""))))))
 642     (let ((last (stp:last-child de)))
 643       (when (typep last 'stp:text)
 644         (cond
 645           ((whitespacep (stp:data last))
 646            (stp:delete-child last de))
 647           (t
 648            (setf (stp:data last)
 649                  (cl-ppcre:regex-replace #.(format nil "[~A]+$" *whitespace*)
 650                                          (stp:data last)
 651                                          ""))))))
 652     d))
 653
 654 (defun output-equal-p (compare p q &key normalize)
 655   (handler-case
 656       (ecase compare
 657         (:xml (xml-output-equal-p p q normalize))
 658         (:html (html-output-equal-p p q))
 659         (:text (text-output-equal-p p q)))
 660     ((or error parse-number::invalid-number) (c)
 661       (warn "comparison failed: ~A" c)
 662       nil)))
 663
 664 ;; Workaround for namespace_namespace23 and other tests:
 665 ;;  - For these tests, saxon and msxsl output a declaration for the XSL
 666 ;;    namespace without using that declaration.
 667 ;;  - I think saxon and msxsl are both wrong.
 668 ;;  - The official test output agrees with my assessment.
 669 ;;    (So does libxslt, but that's not to be trusted. :-))
 670 ;;  - Here's the catch: The official test output is broken in its whitespace
 671 ;;    handling.
 672 ;; So let's normalize spaces in test output that looks like an XSLT
 673 ;; stylesheet, allowing us to pass these tests using the official test output.
 674 (defun maybe-normalize-test-spaces (wrapper force)
 675   (let ((i 0))
 676     (loop while (< i (length (cxml-stp-impl::%children wrapper))) do
 677          (let ((wrapper-child (stp:nth-child i wrapper)))
 678            (cond
 679              ((not (typep wrapper-child 'stp:element))
 680               (if force
 681                   (stp:delete-nth-child i wrapper)
 682                   (incf i)))
 683              ((or (equal (stp:namespace-uri wrapper-child) *xsl*)
 684                   force)
 685               (strip-stylesheet wrapper-child)
 686               (labels ((recurse (e &optional preserve)
 687                          (stp:do-children (child e)
 688                            (typecase child
 689                              (stp:text
 690                               (setf (stp:data child)
 691                                     (normalize-whitespace (stp:data child))))
 692                              (stp:element
 693                                  (stp:with-attributes ((space "space" *xml*))
 694                                      child
 695                                    (let ((new-preserve
 696                                           (cond
 697                                             ((namep child "text") t)
 698                                             ((not space) preserve)
 699                                             ((equal space "preserve") t)
 700                                             (t nil))))
 701                                      (recurse child new-preserve))))))))
 702                 (recurse wrapper-child))
 703               (incf i))
 704              (t
 705               (incf i)))))))
 706
 707 (defun xml-output-equal-p (p q normalize)
 708   (let ((r (parse-for-comparison p))
 709         (s (parse-for-comparison q)))
 710     (maybe-normalize-test-spaces (stp:document-element r) normalize)
 711     (maybe-normalize-test-spaces (stp:document-element s) normalize)
 712     (and (let ((u (stp:document-type r))
 713                (v (stp:document-type s)))
 714            (if u
 715                (and v (node= u v))
 716                (null v)))
 717          (node= (stp:document-element r) (stp:document-element s)))))
 718
 719 ;; FIXME: don't do this in <pre> etc.
 720 (defun normalize-html-whitespace (node)
 721   (when (typep node 'stp:parent-node)
 722     ;; ignore newlines after start tags completely
 723     (let ((first (stp:first-child node)))
 724       (when (and (typep first 'stp:text)
 725                  (alexandria:starts-with #\newline (stp:data first)))
 726         (setf (stp:data first) (subseq (stp:data first) 1))))
 727     ;; ignore newlines before end tags completely
 728     (let ((last (stp:last-child node)))
 729       (when (and (typep last 'stp:text)
 730                  (alexandria:ends-with #\newline (stp:data last)))
 731         (setf (stp:data last)
 732               (subseq (stp:data last) 0 (length (stp:data last))))))
 733     ;; normalize sequences of whitespace
 734     (stp:do-children (child node)
 735       (if (typep child 'stp:text)
 736           (setf (stp:data child)
 737                 (let ((str (normalize-whitespace (stp:data child))))
 738                   (when
 739                       ;; FIXME!  Here we remove whitespace entirely.
 740                       ;; Totally incorrect, but I don't see how we could
 741                       ;; watch Saxon's output otherwise.
 742                       (equal str " ")
 743                     (setf str ""))
 744                   str))
 745           (normalize-html-whitespace child)))
 746     ;; just to be sure, join adjacent nodes
 747     (cxml-stp-impl::normalize-text-nodes! node)))
 748
 749 ;; FIXME: this check is too lenient, because chtml is an error-correcting
 750 ;; parser.
 751 (defun html-output-equal-p (p q)
 752   (let ((r (chtml:parse (pathname p) (stp:make-builder)))
 753         (s (chtml:parse (pathname q) (stp:make-builder))))
 754     (normalize-html-whitespace r)
 755     (normalize-html-whitespace s)
 756     (flet ((fix-case (node)
 757              (xpath:with-namespaces (("xhtml" "http://www.w3.org/1999/xhtml"))
 758                (xpath:do-node-set
 759                    (content (xpath:evaluate "//xhtml:meta/@content" node))
 760                  (setf (stp:value content)
 761                        (string-downcase (stp:value content)))))))
 762       (fix-case r)
 763       (fix-case s))
 764     (node= (stp:document-element r) (stp:document-element s))))
 765
 766 (defun text-output-equal-p (p q)
 767   (with-open-file (a p :element-type '(unsigned-byte 8))
 768     (with-open-file (b q :element-type '(unsigned-byte 8))
 769       (let ((len (file-length a)))
 770         (and (eql len (file-length b))
 771              (let ((d (make-array len :element-type '(unsigned-byte 8)))
 772                    (e (make-array len :element-type '(unsigned-byte 8))))
 773                (read-sequence d a)
 774                (read-sequence e b)
 775                (equalp d e)))))))
 776
 777 (defun strip-addresses (str)
 778   (cl-ppcre:regex-replace-all "{[0-9a-fA-F]+}\\>" str "{xxxxxxxx}>"))
 779
 780 (defun slurp-output-method (p)
 781   (xpath:with-namespaces ((nil #.*xsl*))
 782     (let* ((d (handler-bind
 783                   ((warning #'muffle-warning))
 784                 (cxml:parse (pathname p) (stp:make-builder))))
 785            (output (xpath:first-node (xpath:evaluate "//output" d))))
 786       (if output
 787           (let ((method (stp:attribute-value output "method")))
 788             (if method
 789                 (intern (string-upcase method) :keyword)
 790                 :xml))
 791           :xml))))
 792
 793 (defun replace-junk (str)
 794   (cl-ppcre:regex-replace-all
 795    `(:group ,(namestring *tests-directory*))
 796    (map 'string
 797         (lambda (c)
 798           (if (or (eql c #\newline) (<= 32 (char-code c) 126))
 799               c
 800               #\?))
 801         str)
 802    "..."))
 803
 804 (defun run-test (test)
 805   (let ((expected-saxon (test-output-pathname test "saxon"))
 806         #+xuriella::xsltproc
 807         (expected-xsltproc (test-output-pathname test "xsltproc"))
 808         (actual (test-output-pathname test "xuriella"))
 809         (official (test-official-output-pathname test))
 810         (force-normalization
 811          (cl-ppcre:all-matches *whitespace-issues* (test-id test)))
 812         (output-method nil))
 813     (handler-bind ((|hey test suite, this is an HTML document|
 814                     (lambda (c)
 815                       (declare (ignore c))
 816                       (setf output-method :html))))
 817       (labels ((uri-resolver (uri)
 818                  (let ((str (puri:render-uri uri nil)))
 819                    (cond
 820                      ((search "%5c%5c%5c%5cwebxtest%5c%5cmanagedshadow%5c%5cmanaged_b2%5c%5ctestdata%5c%5cxslt%5c%5celement%5c%5cxslt_element_NSShared.xml"
 821                               str)
 822                       (cxml::pathname-to-uri
 823                        (merge-pathnames
 824                         "MSFT_Conformance_Tests/Elements/xslt_element_NSShared.xml"
 825                         *tests-directory*)))
 826                      ((search "webxtest/testcases/91156a.xsl" str)
 827                       (cxml::pathname-to-uri
 828                        (merge-pathnames
 829                         "MSFT_Conformance_Tests/Import/91156a.xsl"
 830                         *tests-directory*)))
 831                      (t
 832                       uri))))
 833                (doit ()
 834                  (with-open-file (s actual
 835                                     :if-exists :rename-and-delete
 836                                     :direction :output
 837                                     :element-type '(unsigned-byte 8))
 838                    (handler-bind ((xslt-error
 839                                    (lambda (c)
 840                                      (declare (ignore c))
 841                                      (when (find-restart 'recover)
 842                                        (invoke-restart 'recover)))))
 843                      (apply-stylesheet (pathname (test-stylesheet-pathname test))
 844                                        (let ((p (test-data-pathname test)))
 845                                          (if (search "Elements/Plants.xml" p)
 846                                              (merge-pathnames
 847                                               "MSFT_Conformance_Tests/Elements/plants.xml"
 848                                               *tests-directory*)
 849                                              (pathname p)))
 850                                        :output s
 851                                        :uri-resolver #'uri-resolver))))
 852                (pp (label pathname)
 853                  (when pathname
 854                    (format t "  ~A: ~A~%"
 855                            label
 856                            (enough-namestring pathname *tests-directory*))))
 857                (report (ok &optional (fmt "") &rest args)
 858                  (write-string
 859                   (replace-junk
 860                    (strip-addresses
 861                     (format nil "~&~A ~A [~A]~?~%"
 862                             (cond
 863                               (ok "PASS")
 864                               ((find (test-id test)
 865                                      *known-failures*
 866                                      :test #'equal)
 867                                (setf ok :known-failure)
 868                                "KNOWNFAIL")
 869                               (t
 870                                "FAIL"))
 871                             (test-id test)
 872                             (test-category test)
 873                             fmt
 874                             args))))
 875                  (pp "Stylesheet" (test-stylesheet-pathname test))
 876                  (pp "Data" (test-data-pathname test))
 877                  (pp "Supplemental stylesheet"
 878                      (test-stylesheet-pathname-2 test))
 879                  (pp "Supplemental data" (test-data-pathname-2 test))
 880                  (pp "Expected output (1)" expected-saxon)
 881                  #+xuriella::xsltproc
 882                  (pp "Expected output (2)" expected-xsltproc)
 883                  (pp "Actual output" actual)
 884                  (terpri)
 885                  ok))
 886         (cond
 887           ((equal (test-operation test) "standard")
 888            (handler-case
 889                (progn
 890                  (when (find (test-id test)
 891                              nil ;;'("axes_axes47" "attribset_attribset20")
 892                              :test #'equal)
 893                    (error "skipping problematic test"))
 894                  (doit)
 895                  (let* ((output-method
 896                          (or output-method
 897                              (slurp-output-method
 898                               (test-stylesheet-pathname test))))
 899                         (saxon-matches-p
 900                          (output-equal-p output-method
 901                                          expected-saxon
 902                                          actual
 903                                          :normalize force-normalization))
 904                         #+xuriella::xsltproc
 905                         (xsltproc-matches-p
 906                          (output-equal-p output-method
 907                                          expected-xsltproc
 908                                          actual))
 909                         (official-matches-p
 910                          (output-equal-p output-method
 911                                          official
 912                                          actual
 913                                          :normalize force-normalization)))
 914                    (cond
 915                      ((or saxon-matches-p
 916                           #+xuriella::xsltproc xsltproc-matches-p
 917                           official-matches-p)
 918                       (report t)
 919                       #+xuriella::xsltproc
 920                       (report t ": saxon ~A, xsltproc ~A~:[~; (MISMATCH)~]"
 921                               saxon-matches-p
 922                               xsltproc-matches-p
 923                               (if saxon-matches-p
 924                                   (not xsltproc-matches-p)
 925                                   xsltproc-matches-p)))
 926                      (t
 927                       (report nil ": output doesn't match")))))
 928              ((or error parse-number::invalid-number) (c)
 929                (report nil ": ~A" c))))
 930           (t
 931            (handler-case
 932                (doit)
 933              (xslt-error (c)
 934                (report t ": raised an xslt-error as expected" c))
 935              ((or error parse-number::invalid-number) (c)
 936                (report nil ": condition of incorrect type: ~%~A" c))
 937              (:no-error (result)
 938                (cond
 939                  ((not (and official (probe-file official)))
 940                   (report nil ": expected error not signalled: " result))
 941                  ((output-equal-p
 942                    (or output-method
 943                        (slurp-output-method (test-stylesheet-pathname test)))
 944                    official
 945                    actual
 946                    :normalize force-normalization)
 947                   (report t))
 948                  (t
 949                   (report nil ": saxon error not signalled and official output not a match")))))))))))
 950
 951 (defun run-xpath-tests ()
 952   (run-tests :filter "XPath-Expression/|XSLT-Data-Model/"))
 953
 954
 955 ;;;; from cxml-stp-test
 956
 957 (defun assert-node= (a b)
 958   (unless (node= a b)
 959     (error "assertion failed: ~S and ~S are not NODE=" a b)))
 960
 961 (defun child-count (node)
 962   (stp:count-children-if (constantly t) node))
 963
 964 (defun named-node-= (a b)
 965   (and (equal (stp:namespace-uri a) (stp:namespace-uri b))
 966        ;; (equal (stp:namespace-prefix a) (stp:namespace-prefix b))
 967        (equal (stp:local-name a) (stp:local-name b))))
 968
 969 (defun parent-node-= (e f)
 970   (and (eql (child-count e)
 971             (child-count f))
 972        (every #'node= (stp:list-children e) (stp:list-children f))))
 973
 974 (defmethod node= ((e stp:element) (f stp:element))
 975   (and (named-node-= e f)
 976        (parent-node-= e f)
 977        (null
 978         (set-exclusive-or (stp:list-attributes e) (stp:list-attributes f)
 979                           :test #'node=))
 980        (block nil
 981          (flet ((check-namespaces (a b)
 982                   (let ((result ()))
 983                     (stp:map-extra-namespaces
 984                      (lambda (k v)
 985                        (unless (equal v (stp:find-namespace k b))
 986                          (return nil)))
 987                      a)
 988                     result)))
 989            (check-namespaces e f)
 990            (check-namespaces f e))
 991          t)))
 992
 993 (defmethod node= ((a stp:node) (b stp:node))
 994   nil)
 995
 996 (defmethod node= ((e stp:document) (f stp:document))
 997   (parent-node-= e f))
 998
 999 (defmethod node= ((a stp:attribute) (b stp:attribute))
1000   (and (named-node-= a b)
1001        (equal (stp:value a) (stp:value b))))
1002
1003 (defmethod node= ((a stp:comment) (b stp:comment))
1004   (equal (stp:data a) (stp:data b)))
1005
1006 (defmethod node= ((a stp:text) (b stp:text))
1007   (equal (stp:data a) (stp:data b)))
1008
1009 (defmethod node= ((a stp:processing-instruction)
1010                   (b stp:processing-instruction))
1011   (and (equal (stp:data a) (stp:data b))
1012        (equal (stp:target a) (stp:target b))))
1013
1014 (defmethod node= ((a stp:document-type) (b stp:document-type))
1015   (and (equal (stp:root-element-name a) (stp:root-element-name b))
1016        (equal (stp:public-id a) (stp:public-id b))
1017        (equal (stp:system-id a) (stp:system-id b))
1018        (equal (stp:internal-subset a) (stp:internal-subset b))))
1019
1020 (xpath-sys:define-xpath-function/eager
1021     xslt :print
1022     (thing)
1023   (if (xpath:node-set-p thing)
1024       (loop
1025          initially (format t ";;; node set:~%")
1026          for i from 0
1027          for node in (xpath:all-nodes thing)
1028          do
1029            (format t ";;;   ~D: ~A~%" i (type-of node)))
1030       (format t ";;; ~A~%" thing))
1031   thing)