configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20 #
  21 # Process this file with autoconf to produce a configure script
  22
  23 # Initialize Autoconf
  24 AC_PREREQ([2.60])
  25 AC_INIT([xf86-video-sis],
  26         [0.12.1],
  27         [https://gitlab.freedesktop.org/xorg/driver/xf86-video-sis/issues],
  28         [xf86-video-sis])
  29 AC_CONFIG_SRCDIR([Makefile.am])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR(.)
  32
  33 # Initialize Automake
  34 AM_INIT_AUTOMAKE([foreign dist-xz])
  35
  36 # Require X.Org macros 1.8 or later for MAN_SUBSTS set by XORG_MANPAGE_SECTIONS
  37 m4_ifndef([XORG_MACROS_VERSION],
  38           [m4_fatal([must install xorg-macros 1.8 or later before running autoconf/autogen])])
  39 XORG_MACROS_VERSION(1.8)
  40 XORG_DEFAULT_OPTIONS
  41
  42 # Initialize libtool
  43 AC_DISABLE_STATIC
  44 AC_PROG_LIBTOOL
  45
  46 AH_TOP([#include "xorg-server.h"])
  47
  48 # Define a configure option for an alternate module directory
  49 AC_ARG_WITH(xorg-module-dir,
  50             AS_HELP_STRING([--with-xorg-module-dir=DIR],
  51                            [Default xorg module directory [[default=$libdir/xorg/modules]]]),
  52             [moduledir="$withval"],
  53             [moduledir="$libdir/xorg/modules"])
  54
  55 AC_ARG_ENABLE(dri, AS_HELP_STRING([--disable-dri],
  56                                   [Disable DRI support [[default=auto]]]),
  57               [DRI="$enableval"],
  58               [DRI=auto])
  59
  60 # Store the list of server defined optional extensions in REQUIRED_MODULES
  61 XORG_DRIVER_CHECK_EXT(XINERAMA, xineramaproto)
  62 XORG_DRIVER_CHECK_EXT(RANDR, randrproto)
  63 XORG_DRIVER_CHECK_EXT(RENDER, renderproto)
  64 XORG_DRIVER_CHECK_EXT(XV, videoproto)
  65 XORG_DRIVER_CHECK_EXT(DPMSExtension, xextproto)
  66
  67 # Obtain compiler/linker options for the driver dependencies
  68 PKG_CHECK_MODULES(XORG, [xorg-server >= 1.0.99.901 xproto fontsproto xf86dgaproto >= 2.1 $REQUIRED_MODULES])
  69 PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
  70                   HAVE_XEXTPROTO_71="yes"; AC_DEFINE(HAVE_XEXTPROTO_71, 1, [xextproto 7.1 available]),
  71                   HAVE_XEXTPROTO_71="no")
  72 AM_CONDITIONAL(HAVE_XEXTPROTO_71, [ test "$HAVE_XEXTPROTO_71" = "yes" ])
  73 sdkdir=`$PKG_CONFIG --variable=sdkdir xorg-server`
  74
  75 # Checks for libraries.
  76
  77 if test "$DRI" != no; then
  78         if test "$cross_compiling" = "no" ; then
  79                AC_CHECK_FILE([${sdkdir}/dri.h],
  80                              [have_dri_h="yes"], [have_dri_h="no"])
  81                AC_CHECK_FILE([${sdkdir}/sarea.h],
  82                              [have_sarea_h="yes"], [have_sarea_h="no"])
  83                AC_CHECK_FILE([${sdkdir}/dristruct.h],
  84                              [have_dristruct_h="yes"], [have_dristruct_h="no"])
  85         else
  86                 have_dri_h="yes"
  87                 have_sarea_h="yes"
  88                 have_dristruct_h="yes"
  89         fi
  90 fi
  91
  92 AC_MSG_CHECKING([whether to include DRI support])
  93 if test x$DRI = xauto; then
  94         if test "$have_dri_h" = yes -a \
  95                 "$have_sarea_h" = yes -a \
  96                 "$have_dristruct_h" = yes; then
  97                 DRI="yes"
  98         else
  99                 DRI="no"
 100         fi
 101 fi
 102 AC_MSG_RESULT([$DRI])
 103
 104 AM_CONDITIONAL(DRI, test x$DRI = xyes)
 105 if test "$DRI" = yes; then
 106         PKG_CHECK_MODULES(DRI, [libdrm >= 2.0 xf86driproto])
 107         AC_DEFINE(SISDRI,1,[Enable DRI driver support])
 108         AC_DEFINE(SISDRI_DEVEL,1,[Enable developmental DRI driver support])
 109 fi
 110
 111 AC_ARG_ENABLE(xaa,
 112               AS_HELP_STRING([--enable-xaa],
 113                              [Enable legacy X Acceleration Architecture (XAA) [default=auto]]),
 114               [XAA="$enableval"],
 115               [XAA=auto])
 116 if test "x$XAA" != xno; then
 117         save_CFLAGS=$CFLAGS
 118         save_CPPFLAGS=$CPPFLAGS
 119         CFLAGS=$XORG_CFLAGS
 120         CPPFLAGS="$XORG_CFLAGS"
 121         AC_CHECK_HEADERS([xaa.h], XAA=yes, XAA=no)
 122         CFLAGS=$save_CFLAGS
 123         CPPFLAGS=$save_CPPFLAGS
 124 fi
 125 AC_MSG_CHECKING([whether to include XAA support])
 126 AM_CONDITIONAL(XAA, test "x$XAA" = xyes)
 127 AC_MSG_RESULT([$XAA])
 128
 129 # technically this should be a configure flag.  meh.
 130 AC_DEFINE(USE_EXA, 1, [Build support for EXA])
 131
 132 SAVE_CPPFLAGS="$CPPFLAGS"
 133 CPPFLAGS="$CPPFLAGS $XORG_CFLAGS"
 134 AC_CHECK_DECL(XSERVER_LIBPCIACCESS,
 135               [XSERVER_LIBPCIACCESS=yes],[XSERVER_LIBPCIACCESS=no],
 136               [#include "xorg-server.h"])
 137 CPPFLAGS="$SAVE_CPPFLAGS"
 138
 139 if test "x$XSERVER_LIBPCIACCESS" = xyes; then
 140     PKG_CHECK_MODULES([PCIACCESS], [pciaccess >= 0.12.901])
 141     XORG_CFLAGS="$XORG_CFLAGS $PCIACCESS_CFLAGS"
 142 fi
 143 AM_CONDITIONAL(XSERVER_LIBPCIACCESS, test "x$XSERVER_LIBPCIACCESS" = xyes)
 144
 145 AC_SUBST([moduledir])
 146
 147 DRIVER_NAME=sis
 148 AC_SUBST([DRIVER_NAME])
 149
 150 AC_CONFIG_FILES([
 151                 Makefile
 152                 src/Makefile
 153                 man/Makefile
 154 ])
 155 AC_OUTPUT