xapian-core/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl NB When updating the version for a release, update LIBRARY_VERSION_INFO
   4 dnl below too.
   5 AC_INIT([xapian-core], [1.5.0], [https://xapian.org/bugs])
   6 dnl See HACKING document for details of the reasons for required versions.
   7 AC_PREREQ([2.64])
   8 dnl Extract from the libtool info manual:
   9 dnl
  10 dnl Here are a set of rules to help you update your library version information:
  11 dnl
  12 dnl 1. Start with version information of '0:0:0' for each libtool library.
  13 dnl
  14 dnl 2. Update the version information only immediately before a public
  15 dnl    release of your software.  More frequent updates are unnecessary,
  16 dnl    and only guarantee that the current interface number gets larger
  17 dnl    faster.
  18 dnl
  19 dnl 3. If the library source code has changed at all since the last
  20 dnl    update, then increment REVISION ('C:R:A' becomes 'C:r+1:A').
  21 dnl
  22 dnl 4. If any interfaces have been added, removed, or changed since the
  23 dnl    last update, increment CURRENT, and set REVISION to 0.
  24 dnl
  25 dnl 5. If any interfaces have been added since the last public release,
  26 dnl    then increment AGE.
  27 dnl
  28 dnl 6. If any interfaces have been removed since the last public release
  29 dnl    then set AGE to 0.
  30 dnl
  31 dnl LIBRARY_VERSION_INFO for libxapian1.5
  32 dnl 0:0:0 1.5.0 Reset as library renamed
  33 LIBRARY_VERSION_INFO=0:0:0
  34 AC_SUBST([LIBRARY_VERSION_INFO])
  35
  36 LIBRARY_VERSION_SUFFIX=
  37 dnl Where xapian.h, etc go.
  38 incdir=$includedir
  39 case $PACKAGE_VERSION in
  40   [*.*[13579].*])
  41     dnl Development release series:
  42     [dev_series=`echo "$PACKAGE_VERSION"|sed 's/\.[^.]*$//'`]
  43
  44     dnl Append version installed programs by default.  To specify no suffix,
  45     dnl configure with: --program-suffix=
  46     test x"$program_suffix" != xNONE || program_suffix=-$dev_series
  47
  48     incdir=$incdir/xapian-$dev_series
  49
  50     LIBRARY_VERSION_SUFFIX=-$dev_series
  51     ;;
  52 esac
  53
  54 AC_SUBST([LIBRARY_VERSION_SUFFIX])
  55 AC_SUBST([incdir])
  56
  57 dnl Check the build directory doesn't contain a space, so we die early with
  58 dnl a helpful error.
  59 case `pwd` in
  60 *' '*)
  61    AC_MSG_ERROR([You can't build in a directory whose path contains a space])
  62    ;;
  63 esac
  64
  65 dnl Check the source directory doesn't contain a space, so we die early with
  66 dnl a helpful error.  FIXME: Unfortunately, configure seems to choke before
  67 dnl it gets to us so this code doesn't get a chance to fire.
  68 case $0 in
  69 *' '*)
  70    dnl Note: for in-tree builds, the build directory test above will fire
  71    dnl before this can.
  72    AC_MSG_ERROR([You can't build with sources in a directory whose path contains a space])
  73    ;;
  74 esac
  75
  76 dnl Check the prefix to install in doesn't contain a space, so we die early with
  77 dnl a helpful error.
  78 case $prefix in
  79 *' '*)
  80    AC_MSG_ERROR([You can't install in a directory whose path contains a space])
  81    ;;
  82 esac
  83
  84 dnl Note if the user specified a particular C++ compiler so we can give a more
  85 dnl appropriate error message if we can't link a simple C++ program.
  86 original_CXX=
  87 if test -n "$CXX" ; then
  88   original_CXX="CXX=$CXX"
  89 elif test -n "$CCC" ; then
  90   original_CXX="CCC=$CCC"
  91 fi
  92
  93 dnl See HACKING document for details of the reasons for required versions.
  94 AM_INIT_AUTOMAKE([1.13 -Wportability tar-ustar no-dist-gzip dist-xz std-options])
  95 AC_CONFIG_SRCDIR([matcher/multiandpostlist.cc])
  96
  97 AC_CONFIG_HEADERS([config.h])
  98
  99 AC_CONFIG_MACRO_DIRS([m4])
 100
 101 AM_PROG_AR
 102
 103 dnl Use libtool to manage our libraries.
 104 LT_PREREQ([2.2.8])
 105 dnl Default to only building shared libraries.
 106 dnl
 107 dnl Building both shared and static means having to compile the files which
 108 dnl make up the library twice on most platforms.  Shared libraries are the
 109 dnl better option for most users, and if anyone really wants static libraries,
 110 dnl they can configure with --enable-static (or --enable-static=xapian-core if
 111 dnl configuring a combined tree with the bindings).
 112 dnl
 113 dnl We don't export any data items from the library, so it should be safe to
 114 dnl enable win32-dll without decorating any declarations specially.
 115 LT_INIT([disable-static win32-dll])
 116
 117 dnl -no-undefined causes problems on Solaris with Sun CC in C++11 mode, so only
 118 dnl pass -no-undefined on platforms where it is required in order to link a
 119 dnl shared library at all (Windows is the main one).
 120 NO_UNDEFINED=
 121 if test unsupported = "$allow_undefined_flag" ; then
 122   NO_UNDEFINED=-no-undefined
 123 fi
 124 AC_SUBST(NO_UNDEFINED)
 125
 126 AM_CXXFLAGS=
 127
 128 dnl A standard "gotcha" for mingw and cygwin users is to not set up their
 129 dnl PATH correctly, so that MSDOS FIND.EXE is found before Unix find.  Help
 130 dnl them out by checking for this condition, rather than letting libtool
 131 dnl fail in obscure ways.  NB check the *BUILD* OS, not the host one!
 132 case $build_os in
 133   *mingw* | *cygwin* | pw32*)
 134     find /dirunlikelytoexist >/dev/null 2>&1
 135     if test $? = 2 ; then
 136         dnl Unix find will return 1 if the directory didn't exist, or 0 if
 137         dnl it did.
 138         AC_MSG_ERROR([
 139 *** You appear to have an MSDOS-like FIND.EXE in your PATH ahead of any
 140 *** UNIX-like find.  This misconfiguration will confuse libtool - you'll need
 141 *** to make sure you have a UNIX-like find installed and fix your PATH, then
 142 *** rerun configure.  For more information, see:
 143 ***
 144 ***   https://www.cygwin.com/faq/faq.html#faq.using.find
 145 ])
 146     fi
 147   ;;
 148 esac
 149
 150 dnl Add parameters for aclocal
 151 dnl (This must come after AM_INIT_AUTOMAKE, since it modifies ACLOCAL)
 152 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
 153
 154 dnl disable "maintainer only" rules by default
 155 AM_MAINTAINER_MODE
 156
 157 dnl Checks for programs.
 158 AC_PROG_CXX
 159
 160 AC_CANONICAL_HOST
 161
 162 # Checked: freebsd8.0 openbsd4.6 solaris2.9 solaris2.10
 163 case $host_os in
 164   linux* | k*bsd*-gnu | freebsd* | openbsd* | solaris*)
 165     dnl Vanilla libtool sets this to "unknown" which it then handles as "yes".
 166     link_all_deplibs_CXX=no
 167     ;;
 168 esac
 169
 170 case $host_os in
 171   linux*)
 172     dnl Extract search path from ldconfig which is more reliable than the way
 173     dnl vanilla libtool extracts them from ld.so.conf.
 174     d=`/sbin/ldconfig -N -X -v 2>&AS_MESSAGE_LOG_FD|$SED 's,^\(/.*\):\( (.*)\)\?$,\1,p;d'|tr '\n' ' '`
 175     test -z "$d" || sys_lib_dlsearch_path_spec=$d
 176     ;;
 177 esac
 178
 179 case $host in
 180   *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-os2* | *-*-darwin* | *-cegcc*)
 181     dnl On these platforms, libtool emits a warning if -no-install is passed,
 182     dnl and uses -no-fast-install instead - the least ugly way to avoid that
 183     dnl warnings seems to be to duplicate the above list of platforms from
 184     dnl libtool and use -no-fast-install on them directly.
 185     NO_INSTALL=-no-fast-install ;;
 186   *)
 187     NO_INSTALL=-no-install ;;
 188 esac
 189 AC_SUBST([NO_INSTALL])
 190
 191 dnl For reasons which are beyond me, if autoconf can't find a C++ compiler
 192 dnl it will set CXX to g++ (which obviously won't work) rather than actually
 193 dnl telling the user that it couldn't find a C++ compiler and telling them
 194 dnl to either install one or set CXX if there's one configure failed to find.
 195 dnl It's probably worthwhile checking that the C++ compiler actually works
 196 dnl anyway!
 197 if test -n "$CXX" ; then
 198   AC_LANG_CPLUSPLUS
 199   AC_MSG_CHECKING([whether $CXX is a working C++ compiler])
 200   AC_CACHE_VAL([xo_cv_cxx_works],
 201     [
 202     AC_TRY_RUN([int main() {}],
 203                xo_cv_cxx_works=yes,
 204                xo_cv_cxx_works=no,
 205                AC_TRY_LINK([], [], xo_cv_cxx_works=yes, xo_cv_cxx_works=no))
 206     ])
 207   AC_MSG_RESULT([$xo_cv_cxx_works])
 208 else
 209   xo_cv_cxx_works=no
 210 fi
 211 if test no = "$xo_cv_cxx_works" ; then
 212   case $original_CXX in
 213   CCC=*)
 214     dnl CCC is handled in a slightly odd way - if its value isn't an
 215     dnl executable (taking PATH into account) then it is ignored!
 216     test "$original_CXX" = "CCC=$CXX" || original_CXX=
 217     ;;
 218   esac
 219   if test -z "$original_CXX" ; then
 220   AC_MSG_ERROR([
 221 *** You need a working C++ compiler to compile Xapian, but configure failed to
 222 *** find one.  If you have a working C++ compiler, you can tell configure where
 223 *** to find it by invoking it like so:
 224 ***
 225 ***   ./configure CXX=/opt/bin/c++
 226 ])
 227   else
 228   AC_MSG_ERROR([
 229 *** You need a working C++ compiler to compile Xapian, but the compiler you
 230 *** specified (with '$original_CXX') doesn't appear to be able to successfully
 231 *** compile and link a simple program.
 232 ])
 233   fi
 234 fi
 235
 236 dnl Probe for any options needed to enable C++11 support.
 237 AX_CXX_COMPILE_STDCXX_11
 238
 239 dnl We don't use a C compiler to compile Xapian's code, but on some platforms
 240 dnl (e.g. mingw) libtool uses $LTCC which defaults to $CC, and it's also use to
 241 dnl build auxiliary tools like snowball and lemon.
 242 AC_PROG_CC
 243
 244 dnl Check endianness.
 245 AC_C_BIGENDIAN
 246
 247 dnl We want a non-cross-compiling C compiler for building lemon with.
 248 if test -z "$CC_FOR_BUILD" ; then
 249   if test yes = "$cross_compiling"; then
 250     CC_FOR_BUILD=cc
 251   else
 252     CC_FOR_BUILD="$CC"
 253   fi
 254 fi
 255 AC_ARG_VAR([CC_FOR_BUILD], [C compiler command for native compilation (needed to compile build tools during cross-builds)])
 256
 257 dnl Run tests using the C++ compiler.
 258 AC_LANG_CPLUSPLUS
 259
 260 dnl Enable large file support if possible.
 261 AC_SYS_LARGEFILE
 262 dnl With xlC on AIX, -D_LARGE_FILES changes the ABI of std::string, so it
 263 dnl also needs to be used when compiling user code.
 264 abi_affecting_cxxflags=
 265 if $GREP '^#define _LARGE_FILES 1$' confdefs.h > /dev/null 2>&1 ; then
 266   abi_affecting_cxxflags=-D_LARGE_FILES
 267 fi
 268 AC_SUBST([abi_affecting_cxxflags])
 269
 270 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 271 #if defined __WIN32__ || defined _WIN32
 272 #error WIN32
 273 #endif
 274 ]])], [win32=no], [win32=yes])
 275
 276 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[
 277 #ifdef _MSC_VER
 278 #error MSVC
 279 #endif
 280 ]])], [msvc=no], [msvc=yes])
 281
 282 XAPIAN_LDFLAGS=
 283 XAPIAN_LIBS=
 284 AC_SUBST([XAPIAN_LDFLAGS])
 285 AC_SUBST([XAPIAN_LIBS])
 286
 287 AC_DEFUN([XAPIAN_TEST_LINKER_FLAG],
 288   [
 289   AC_MSG_CHECKING([for $CXX -Wl,$1])
 290   AC_CACHE_VAL([xo_cv_ldflag_$2],
 291     [
 292     save_LDFLAGS=$LDFLAGS
 293     LDFLAGS="$LDFLAGS -Wl,$1"
 294     flag=$1
 295     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 296       [xo_cv_ldflag_$2=yes
 297       $3],
 298       [xo_cv_ldflag_$2=no
 299       $4])
 300     LDFLAGS=$save_LDFLAGS
 301     ])
 302   AC_MSG_RESULT([$xo_cv_ldflag_$2])
 303   ])
 304
 305 dnl Test if the compiler works with $1 added to CXXFLAGS; if it does, add $1 to
 306 dnl variable $2.  If the test passes, also do $3; if it fails, also do $4.
 307 AC_DEFUN([XAPIAN_TEST_CXXFLAGS],
 308   [
 309   XTC_save_CXXFLAGS=$CXXFLAGS
 310   CXXFLAGS="$CXXFLAGS $1"
 311   AC_TRY_COMPILE([], [],
 312                  [CXXFLAGS=$XTC_save_CXXFLAGS
 313                   $2="${$2} $1"
 314                   $3],
 315                  [CXXFLAGS=$XTC_save_CXXFLAGS
 316                   $4])
 317   ])
 318
 319 ldflags=
 320 if test yesyes = "$GXX$enable_shared" ; then
 321   case $host_os in
 322     *mingw* | *cygwin*)
 323       XAPIAN_TEST_LINKER_FLAG([--enable-runtime-pseudo-reloc], [enable_runtime_pseudo_reloc],
 324         [ldflags="-Wl,$flag"],
 325         [
 326         dnl Can't use AC_DISABLE_SHARED after AC_PROG_LIBTOOL, but
 327         dnl this test needs to be after AC_PROG_LIBTOOL, so we can't
 328         dnl just disable the shared build automatically...
 329         AC_MSG_ERROR([ld version too old to support a shared build - configure with --disable-shared, or install binutils 2.13.90-20030111-1 or later])
 330         ])
 331     ;;
 332   esac
 333 fi
 334 dnl Only works for ldflags which can be specified anywhere on the link line.
 335 AC_SUBST([ldflags])
 336
 337 dnl Preserve the default CXXFLAGS.
 338 save_CXXFLAGS=$CXXFLAGS
 339
 340 dnl x86 has excess precision issues with 387 FP instructions, which are
 341 dnl avoided by using SSE instructions instead.  This is also faster (~6% in
 342 dnl a CPU bound testcase).
 343 AC_ARG_ENABLE([sse],
 344 [AS_HELP_STRING([--disable-sse],
 345                 [disable use of SSE FP instructions on x86])]
 346 [AS_HELP_STRING([[--enable-sse[=sse|sse2]]],
 347                 [set which SSE FP instructions to use on x86 (default: sse2)])],
 348   [case ${enableval} in
 349     sse|sse2|yes|no) ;;
 350     *) AC_MSG_ERROR([bad value ${enableval} for --enable-sse or --disable-sse]) ;;
 351   esac],
 352   [enable_sse=yes])
 353
 354 dnl Some versions of Sun's C++ compiler reportedly need an explicit -lm.
 355 dnl The maths functions we use include: exp log ceil fabs sqrt
 356 AC_MSG_CHECKING([if -lm is required for maths functions])
 357 dnl Don't use constant arguments as the compiler might simply evaluate the
 358 dnl whole expression at compile time, and it might inline certain functions
 359 dnl so test several functions.  Also write results using printf() so that
 360 dnl the compiler can't optimise away the computations.
 361 AC_TRY_LINK([#ifdef __SUNPRO_CC
 362 #error Need -lm for Sun C++ 5.9 under libtool 2.2.10
 363 #endif
 364 #include <cmath>
 365 #include <cstdio>
 366 #include <ctime>
 367 using namespace std;], [
 368   double a = log(ceil(time(NULL)/7.0));
 369   printf("%f %f %f\n", a, sqrt(a), exp(fabs(a - 12345.6)));
 370   ], [AC_MSG_RESULT([no])], [
 371     LIBS="-lm $LIBS"
 372     AC_TRY_LINK([#include <cmath>
 373 #include <cstdio>
 374 #include <ctime>
 375 using namespace std;], [
 376   double a = log(ceil(time(NULL)/7.0));
 377   printf("%f %f %f\n", a, sqrt(a), exp(fabs(a - 12345.6)));],
 378         [AC_MSG_RESULT([yes])],
 379         [AC_MSG_ERROR([Failed to link a C++ program using <cmath>])
 380     ])
 381 ])
 382
 383 dnl C++11 should have log2(double), but keep this check for now to allow for
 384 dnl compilers with incomplete library support for C++11.
 385 AC_CHECK_DECLS([log2(double)], [], [],
 386 [#include <cmath>
 387 using namespace std;])
 388
 389 dnl exp10() is a GNU libc extension.
 390 AC_CHECK_DECLS([exp10(double)], [], [],
 391 [#include <cmath>
 392 using namespace std;])
 393
 394 dnl Darwin provides __exp10().
 395 AC_CHECK_DECLS([__exp10(double)], [], [],
 396 [#include <cmath>
 397 using namespace std;])
 398
 399 dnl GCC provides __builtin_exp10() (but notably clang doesn't currently).
 400 dnl On mingw, __builtin_exp10() causes GCC to generate a call to exp10() which
 401 dnl then fails to link, so perform a link check here to catch that.
 402 AC_CACHE_CHECK([for __builtin_exp10], ac_cv_link___builtin_exp10, [
 403   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 404 #include <cstdio>
 405 #include <ctime>
 406 using namespace std;]],
 407     [[printf("%f", __builtin_exp10(double(time(NULL)*1e-8)));]])],
 408     [ac_cv_link___builtin_exp10=yes],
 409     [ac_cv_link___builtin_exp10=no])
 410 ])
 411 if test $ac_cv_link___builtin_exp10 = yes ; then
 412   AC_DEFINE([HAVE___BUILTIN_EXP10], [1], [Define to 1 if you have the `__builtin_exp10' function.])
 413 fi
 414
 415 dnl See if <typeinfo> can be used in the testsuite - at least for GCC and xlC,
 416 dnl compilation of the test code below fails if RTTI isn't being generated
 417 dnl (g++ -fno-rtti, or by default with xlC).
 418 AC_MSG_CHECKING([if RTTI is supported])
 419 save_CXXFLAGS=$CXXFLAGS
 420 dnl xlC issues a warning for typeid() being used without RTTI being enabled,
 421 dnl so for this test we pass the xlC option to make that warning into an error.
 422 XAPIAN_TEST_CXXFLAGS([-qhaltonmsg=1540-2412], [CXXFLAGS])
 423 AC_TRY_COMPILE([
 424 #include <exception>
 425 #include <typeinfo>],
 426         [
 427         int f();
 428         try {
 429             return f();
 430         } catch (std::exception & e) {
 431             return typeid(e).name()[0];
 432         }],
 433     AC_MSG_RESULT([yes])
 434     AC_DEFINE([USE_RTTI], [1], [Define if the testsuite can use RTTI]),
 435     AC_MSG_RESULT([no]))
 436 CXXFLAGS=$save_CXXFLAGS
 437
 438 AC_CHECK_DECLS([__builtin_bswap16, __builtin_bswap32], [], [], [ ])
 439 AC_CHECK_DECLS([__builtin_clz, __builtin_clzl, __builtin_clzll], [], [], [ ])
 440 AC_CHECK_DECLS([__builtin_ctz, __builtin_ctzl, __builtin_ctzll], [], [], [ ])
 441 AC_CHECK_DECLS([__builtin_expect], [], [], [ ])
 442 AC_CHECK_DECLS([__builtin_popcount, __builtin_popcountl, __builtin_popcountll], [], [], [ ])
 443 AC_CHECK_DECLS([__popcnt, __popcnt64], [], [], [#include <intrin.h>])
 444
 445 dnl Check for time functions.
 446 AC_CHECK_FUNCS([clock_gettime sleep nanosleep gettimeofday ftime])
 447
 448 case $host_os in
 449   *mingw*)
 450     dnl For _ftime64() on mingw we need to tell it we're happy to require
 451     dnl MSVCRT 6.10 or higher, which isn't too onerous a requirement it seems.
 452     AC_DEFINE([__MSVCRT_VERSION__], [0x0601], [Define on mingw to the minimum msvcrt version to assume])
 453     AC_DEFINE([MINGW_HAS_SECURE_API], [1], [Define on mingw to get _s suffixed "secure" functions declared in headers])
 454     ;;
 455 esac
 456
 457 dnl We use timer_create() if available to implement a search time limit.
 458 SAVE_LIBS=$LIBS
 459 AC_SEARCH_LIBS([timer_create], [rt],
 460                [
 461     AC_MSG_CHECKING([for timer_create() usability])
 462     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 463 [[#if defined _AIX || defined __GNU__
 464 #error timer_create known not to work
 465 #endif]])],
 466         [AC_MSG_RESULT([yes])
 467         XAPIAN_LIBS="$LIBS $XAPIAN_LIBS"
 468         AC_DEFINE([HAVE_TIMER_CREATE], [1], [Define to 1 if you have the 'timer_create' function.])]
 469         ,
 470         [AC_MSG_RESULT([no])
 471     ])
 472 ])
 473 LIBS=$SAVE_LIBS
 474
 475 dnl Used by tests/soaktest/soaktest.cc
 476 AC_CHECK_FUNCS([srandom random])
 477
 478 dnl Used by tests/harness/testsuite.cc
 479 AC_CHECK_FUNCS([sigaction])
 480 AC_MSG_CHECKING([for sigsetjmp and siglongjmp])
 481 AC_TRY_COMPILE([#include <setjmp.h>],
 482   [sigjmp_buf jb; if (sigsetjmp(jb, 1)) { siglongjmp(jb, 1);  }],
 483   AC_DEFINE([HAVE_SIGSETJMP], [1], [Define to 1 if you have the 'sigsetjmp' function])
 484   AC_MSG_RESULT([yes]),
 485   AC_MSG_RESULT([no]))
 486
 487 dnl Used by tests/harness/cputimer.cc:
 488 AC_CHECK_FUNCS([getrusage times sysconf])
 489
 490 dnl Used by tests/api_replicate.cc.
 491 dnl
 492 dnl Solaris < 10 only has putenv().
 493 dnl
 494 dnl Microsoft have marked putenv() as deprecated, so we use _putenv_s() under
 495 dnl MSVC to avoid deprecation warnings.  We probe here since mingw doesn't
 496 dnl currently (v3.20) provide _putenv_s(), so we can't just use it conditional
 497 dnl on __WIN32__ being defined.  We need to check for a declaration rather
 498 dnl than just seeing if the symbol exists, as the symbol will exist in the C
 499 dnl runtime DLL even if mingw doesn't declare it in its headers.
 500 AC_CHECK_FUNCS([setenv])
 501 AC_CHECK_DECLS([_putenv_s(const char *,const char *)], [], [],
 502 [#include <stdlib.h>])
 503
 504 dnl See if we have closefrom(), or some functions that are useful to implement
 505 dnl closefrom() on platforms which don't provide it.
 506 AC_CHECK_FUNCS([closefrom getdirentries getrlimit])
 507
 508 dnl See if ftime returns void (as it does on mingw)
 509 AC_MSG_CHECKING([return type of ftime])
 510 if test $ac_cv_func_ftime = yes ; then
 511   AC_TRY_COMPILE([#include <sys/timeb.h>],
 512     [struct timeb tp; int i = ftime(&tp);],
 513     AC_MSG_RESULT([int]),
 514     AC_MSG_RESULT([void])
 515     AC_DEFINE([FTIME_RETURNS_VOID], [1], [Define if ftime returns void]))
 516 fi
 517
 518 dnl Check how to find the hostname: uname() in sys/utsname.h, or gethostname()
 519 dnl Don't use default includes as inttypes.h is found by Compaq C but not C++
 520 dnl so it causes all header probes to fail.
 521 AC_CHECK_HEADERS([sys/utsname.h], [], [], [ ])
 522 AC_CHECK_FUNCS([gethostname])
 523
 524 dnl mingw (for instance) lacks ssize_t
 525 AC_TYPE_SSIZE_T
 526
 527 AC_TYPE_PID_T
 528
 529 AC_TYPE_MODE_T
 530
 531 AC_CHECK_SIZEOF([short])
 532 AC_CHECK_SIZEOF([int])
 533 AC_CHECK_SIZEOF([long])
 534 AC_CHECK_SIZEOF([long long])
 535
 536 AC_CHECK_HEADERS([sys/types.h])
 537
 538 AC_MSG_CHECKING([for 32 bit integer type])
 539 case 4 in
 540     "$ac_cv_sizeof_int")   INT32_T=int ;;
 541     "$ac_cv_sizeof_long")  INT32_T=long ;;
 542     "$ac_cv_sizeof_short") INT32_T=short ;;
 543     *)
 544       AC_MSG_RESULT([none found])
 545       AC_MSG_ERROR([No 32 bit integer type found])
 546 esac
 547 AC_MSG_RESULT([$INT32_T])
 548
 549 AC_MSG_CHECKING([for 64 bit integer type])
 550 case 8 in
 551     "$ac_cv_sizeof_int")       INT64_T=int ;;
 552     "$ac_cv_sizeof_long")      INT64_T=long ;;
 553     "$ac_cv_sizeof_long_long") INT64_T='long long' ;;
 554     *)
 555       AC_MSG_RESULT([none found])
 556       AC_MSG_ERROR([No 64 bit integer type found])
 557 esac
 558 AC_MSG_RESULT([$INT64_T])
 559
 560 dnl Check for perl (needed to generate some sources and documentation).
 561 AC_PATH_PROG([PERL], [perl], [])
 562 if test x$USE_MAINTAINER_MODE = xyes; then
 563   test -z "$PERL" && AC_MSG_ERROR([perl is required in maintainer mode])
 564 fi
 565
 566 AC_ARG_ENABLE([64bit_docid],
 567   [AS_HELP_STRING([--enable-64bit-docid], [enable 64bit docid [default=no]])],
 568   [case ${enableval} in
 569     yes|no) ;;
 570   *) AC_MSG_ERROR([bad value ${enableval} for --enable-64bit-docid]) ;;
 571   esac],
 572   [enable_64bit_docid=no])
 573
 574 AC_ARG_ENABLE([64bit_termcount],
 575   [AS_HELP_STRING([--enable-64bit-termcount], [enable 64bit termcount [default=no]])],
 576   [case ${enableval} in
 577     yes|no) ;;
 578   *) AC_MSG_ERROR([bad value ${enableval} for --enable-64bit-termcount]) ;;
 579   esac],
 580   [enable_64bit_termcount=no])
 581
 582 AC_ARG_ENABLE([documentation],
 583   [AS_HELP_STRING([--enable-documentation], [enable make rules to rebuild documentation [default=maintainer-mode]])],
 584   [case ${enableval} in
 585     yes|no) ;;
 586     *) AC_MSG_ERROR([bad value ${enableval} for --enable-documentation]) ;;
 587   esac],
 588   [enable_documentation=$USE_MAINTAINER_MODE])
 589 AM_CONDITIONAL([DOCUMENTATION_RULES], [test x"$enable_documentation" = xyes])
 590 AM_CONDITIONAL([MAINTAINER_NO_DOCS], [test x"$USE_MAINTAINER_MODE$enable_documentation" = xyesno])
 591
 592 if test x"$enable_documentation" = xyes ; then
 593   dnl Checks for dot.  (Diagrams in the documentation)
 594   AC_PATH_PROG([DOT], [dot])
 595   test -z "$DOT" && AC_MSG_ERROR([dot (part of the graphviz package) is required to build documentation])
 596   DOXYGEN_DOT_PATH=`echo "$DOT" | sed 's!/dot$!!'`
 597   AC_SUBST([DOXYGEN_DOT_PATH])
 598
 599   dnl Check for doxygen. (Needed to make some more of the documentation)
 600   AC_PATH_PROG([DOXYGEN], [doxygen], [])
 601   test -z "$DOXYGEN" && AC_MSG_ERROR([doxygen is required to build documentation])
 602
 603   dnl Check for help2man. (Needed to make man pages from "--help" output).
 604   AC_PATH_PROG([HELP2MAN], [help2man], [])
 605   test -z "$HELP2MAN" && AC_MSG_ERROR([help2man is required to build documentation])
 606
 607   dnl Check for rst2html. (Needed to make HTML from reStructuredText format)
 608   dnl Also look for rst2html.py, which archlinux reportedly installs it as.
 609   AC_PATH_PROGS([RST2HTML], [rst2html rst2html.py], [])
 610   test -z "$RST2HTML" && AC_MSG_ERROR([rst2html is required to build documentation (try package python-docutils)])
 611
 612   dnl Check for pngcrush, which we optionally use to reduce the size of the
 613   dnl PNG files which doxygen generates.  We can get by without it, so don't
 614   dnl fail here if it's not found.
 615   AC_PATH_PROG([PNGCRUSH], [pngcrush], [])
 616 fi
 617
 618 dnl Checks for header files.
 619 AC_CHECK_HEADERS([fcntl.h limits.h sys/errno.h sys/select.h], [], [], [ ])
 620 AC_CHECK_HEADERS([sys/resource.h],
 621                  [], [], [#include <sys/types.h>])
 622
 623 dnl cxxabi.h was added in GCC 3.1, but clang lies and defines __GNUC__ yet
 624 dnl doesn't seem to reliably provide this header, so probe for it.
 625 AC_CHECK_HEADERS([cxxabi.h], [], [], [ ])
 626
 627 dnl If valgrind is installed and new enough, we use it for leak checking in the
 628 dnl testsuite.  If VALGRIND is set to an empty value, then skip the check and
 629 dnl don't use valgrind.
 630 if test -n "${VALGRIND-unset}" ; then
 631   AC_PATH_PROG([VALGRIND], [valgrind], [])
 632   if test -n "$VALGRIND" ; then
 633     dnl Check that the installed valgrind version works, and supports the
 634     dnl options we use.  This means we won't try to use valgrind < 3.3.0
 635     dnl (released 7/12/2007) since before that --log-file didn't expand
 636     dnl %p (and appended the process id).
 637     dnl
 638     dnl No need to check for VALGRIND_COUNT_LEAKS now - that was added before
 639     dnl 2.0.0.
 640     AC_MSG_CHECKING([if valgrind supports --log-file with %p and --child-silent-after-fork=yes])
 641     vglog=config.vglog.%p.tmp
 642     vglogwild="config.vglog.*.tmp*"
 643     rm -f $vglogwild
 644     if $VALGRIND --log-file="$vglog" --child-silent-after-fork=yes -q true 2>&AS_MESSAGE_LOG_FD ; then
 645       for f in $vglogwild ; do
 646         case $f in
 647         $vglog*) VALGRIND= ;;
 648         esac
 649       done
 650       if test x"$VALGRIND" = x ; then
 651         AC_MSG_RESULT([no])
 652       else
 653         AC_MSG_RESULT([yes])
 654         AC_CHECK_HEADERS([valgrind/memcheck.h], [], [VALGRIND=], [ ])
 655       fi
 656     else
 657       dnl The valgrind detected doesn't seem to work!  Perhaps this is an
 658       dnl x86_64 box with a 32 bit valgrind.
 659       AC_MSG_RESULT([$VALGRIND doesn't work])
 660       VALGRIND=
 661     fi
 662     rm -f $vglogwild
 663   fi
 664 fi
 665
 666 if test -n "$VALGRIND" ; then
 667   AC_DEFINE([HAVE_VALGRIND], [1], [Define if a suitable valgrind is installed])
 668 fi
 669
 670 dnl If eatmydata is installed, we run the testsuite under it to speed it up.
 671 dnl If EATMYDATA is set to an empty value, then skip this check and don't use
 672 dnl eatmydata.
 673 if test -n "${EATMYDATA-unset}" ; then
 674   AC_PATH_PROG([EATMYDATA], [eatmydata], [])
 675 fi
 676
 677 dnl Checks for library functions.
 678 AC_FUNC_MEMCMP
 679 AC_FUNC_STRERROR_R
 680
 681 AC_CACHE_CHECK([for sys_errlist and sys_nerr], ac_cv_sys_errlist_and_sys_nerr, [
 682   AC_LINK_IFELSE([AC_LANG_PROGRAM(
 683 dnl On Linux, sys_errlist and sys_nerr need <stdio.h>, though the man page
 684 dnl says <errno.h>.  The man page seems to match other platforms such as
 685 dnl NetBSD, so include both headers to ensure we get them.
 686 [[#include <errno.h>
 687 #include <stdio.h>]],
 688 [[  printf("%s", sys_errlist[sys_nerr - 1]);]])],
 689   [ ac_cv_sys_errlist_and_sys_nerr=yes ],
 690   [ ac_cv_sys_errlist_and_sys_nerr=no ])
 691 ])
 692 if test "x$ac_cv_sys_errlist_and_sys_nerr" = "xyes" ; then
 693   AC_DEFINE([HAVE_SYS_ERRLIST_AND_SYS_NERR], [1],[Define if you have 'sys_errlist' and 'sys_nerr'])
 694 fi
 695
 696 AC_CACHE_CHECK([for _sys_errlist and _sys_nerr], ac_cv__sys_errlist_and__sys_nerr, [
 697   AC_LINK_IFELSE([AC_LANG_PROGRAM(
 698 [[#include <errno.h>
 699 #include <stdio.h>]],
 700 [[  printf("%s", _sys_errlist[_sys_nerr - 1]);]])],
 701   [ ac_cv__sys_errlist_and__sys_nerr=yes ],
 702   [ ac_cv__sys_errlist_and__sys_nerr=no
 703   ])
 704 ])
 705 if test "x$ac_cv__sys_errlist_and__sys_nerr" = "xyes" ; then
 706   AC_DEFINE([HAVE__SYS_ERRLIST_AND__SYS_NERR], [1],[Define if you have '_sys_errlist' and '_sys_nerr'])
 707 fi
 708
 709 dnl Check that snprintf actually works as it's meant to.
 710 dnl
 711 dnl Linux 'man snprintf' warns:
 712 dnl  Linux libc4.[45] does not have a snprintf, but provides a libbsd that
 713 dnl  contains an snprintf equivalent to sprintf, i.e., one that ignores the
 714 dnl  size argument.  Thus, the use of snprintf with early libc4 leads to
 715 dnl  serious security problems.
 716 dnl
 717 dnl It also warns that glibc < 2.0.6 (and presumably other pre-C99
 718 dnl implementations) return -1 when truncating so check that we get the
 719 dnl ISO C99 semantics for the returned length when truncating.  If we
 720 dnl have a working snprintf but with non-ISO return semantics, handle
 721 dnl that case separately as it may still be useful in many cases.
 722 dnl
 723 dnl mingw has _snprintf so check for that too.
 724 AC_MSG_CHECKING([for working ISO C99 conforming snprintf])
 725 ac_cv_func_snprintf_noniso=no
 726 for func in snprintf _snprintf ; do
 727   AC_RUN_IFELSE([
 728     AC_LANG_PROGRAM(
 729       [[
 730 #include <cstdio>
 731 #include <cstring>
 732 using namespace std;
 733       ]],
 734       dnl Return different exit status for each error so we can see which
 735       dnl check failed by consulting config.log.
 736       [[
 737         char buffer[4] = "abc";
 738         int res1 = $func(buffer, 2, "%s", "XYZ");
 739         if (memcmp(buffer, "X\0c", 4) != 0) return 2;
 740         int res2 = $func(buffer, 2, "%x", 0x12);
 741         if (memcmp(buffer, "1\0c", 4) != 0) return 3;
 742         if (res1 == -1 && res2 == -1) return 15; /* Pre-ISO semantics. */
 743         if (res1 != 3) return 4;
 744         if (res2 != 2) return 5;
 745       ]]
 746     )],
 747     [ac_cv_func_snprintf=$func;break],
 748     [
 749     if test 15no = "$?$ac_cv_func_snprintf_noniso" ; then
 750       ac_cv_func_snprintf_noniso=$func
 751     fi
 752     ac_cv_func_snprintf=no
 753     ],
 754     [ac_cv_func_snprintf=unknown;break]
 755   )
 756 done
 757 AC_MSG_RESULT([$ac_cv_func_snprintf])
 758 case $ac_cv_func_snprintf in
 759   no)
 760     AC_MSG_CHECKING([for working non-ISO C99 conforming snprintf])
 761     AC_MSG_RESULT([$ac_cv_func_snprintf_noniso])
 762     if test no != "$ac_cv_func_snprintf_noniso" ; then
 763       AC_DEFINE_UNQUOTED([SNPRINTF], [$ac_cv_func_snprintf_noniso],
 764         [Define to the name of a function implementing snprintf but not caring about ISO C99 return value semantics (if one exists)])
 765     fi
 766     ;;
 767   unknown)
 768     dnl be conservative when crosscompiling
 769     ;;
 770   *)
 771     AC_DEFINE_UNQUOTED([SNPRINTF_ISO], [$ac_cv_func_snprintf],
 772        [Define to the name of a function implementing snprintf with ISO C99 semantics (if one exists)])
 773     AC_DEFINE_UNQUOTED([SNPRINTF], [$ac_cv_func_snprintf],
 774        [Define to the name of a function implementing snprintf but not caring about ISO C99 return value semantics (if one exists)])
 775     ;;
 776 esac
 777
 778 dnl ***************************
 779 dnl * Select modules to build *
 780 dnl ***************************
 781
 782 dnl Check which database backends should be built.
 783
 784 AC_DEFUN([_XAPIAN_BACKEND_ENABLE],
 785   [AC_ARG_ENABLE([backend_$1],
 786     [AS_HELP_STRING([--enable-backend-$1], [build the $1 database backend [default=$3]])],
 787     [case $enableval in
 788       yes|no) ;;
 789       *) AC_MSG_ERROR([Invalid option: '--enable-backend-$1=$enableval']) ;;
 790     esac], [enable_backend_$1=$2])
 791   ])
 792
 793 AC_DEFUN([XAPIAN_BACKEND_ENABLE],
 794   [_XAPIAN_BACKEND_ENABLE([$1],
 795     m4_default([$2], [yes]),
 796     m4_default([$3], [yes]))
 797   ])
 798
 799 dnl When adding a new backend, update INSTALL too.
 800 XAPIAN_BACKEND_ENABLE([glass])
 801 XAPIAN_BACKEND_ENABLE([honey])
 802 XAPIAN_BACKEND_ENABLE([inmemory])
 803 default_enable_backend_remote=yes
 804 case $host_os in
 805   *djgpp* | *msdos* )
 806     dnl We don't currently support the remote backend on this platform so
 807     dnl disable it by default.
 808     default_enable_backend_remote=no
 809     ;;
 810 esac
 811 XAPIAN_BACKEND_ENABLE([remote], [$default_enable_backend_remote], [yes (except for MSDOS)])
 812
 813 use_proc_for_uuid=0
 814 use_win32_uuid_api=0
 815 win32_need_lws2_32=0
 816 case $enable_backend_glass$enable_backend_honey in
 817 *yes*)
 818   dnl We use zlib for compressing tags in glass and honey.  We could
 819   dnl automatically disable support if zlib isn't found, but overall that
 820   dnl probably does more harm than good - it's most likely that someone just
 821   dnl forgot to install the -dev package for zlib.
 822   dnl
 823   dnl Similarly for uuid support.
 824
 825   dnl Check for zlib.h.
 826   AC_CHECK_HEADERS([zlib.h], [], [
 827     AC_MSG_ERROR([zlib.h not found - required for glass (you may need to install the zlib1g-dev or zlib-devel package)])
 828     ], [ ])
 829
 830   dnl Check for zlibVersion in -lz.
 831   SAVE_LIBS=$LIBS
 832   dnl mingw build needs -lzlib or -lzdll.
 833   AC_SEARCH_LIBS([zlibVersion], [z zlib zdll], [], [
 834     AC_MSG_ERROR([zlibVersion() not found in -lz, -lzlib, or -lzdll - required for glass (you may need to install the zlib1g-dev or zlib-devel package)])
 835     ])
 836   if test x != x"$LIBS" ; then
 837     XAPIAN_LIBS="$XAPIAN_LIBS $LIBS"
 838   fi
 839   LIBS=$SAVE_LIBS
 840
 841   dnl Find the UUID library (from e2fsprogs/util-linux-ng, not the OSSP one).
 842
 843   case $host_os-$win32 in
 844     *-yes | *cygwin*) dnl Use built-in win32 API.
 845       use_win32_uuid_api=1
 846       AC_DEFINE([USE_WIN32_UUID_API], [1],
 847                 [Define to 1 to use UuidCreate(), etc])
 848       if test $win32 = yes ; then
 849         dnl We need -lws2_32 for htonl(), etc, but not for Cygwin which
 850         dnl provides these functions in its libc.
 851         win32_need_lws2_32=1
 852       fi
 853       XAPIAN_LIBS="$XAPIAN_LIBS -lrpcrt4"
 854       ;;
 855     *)
 856       dnl Check for uuid/uuid.h (e2fsprogs/util-linux-ng) or uuid.h
 857       dnl (FreeBSD/NetBSD).
 858       AC_CHECK_HEADERS([uuid/uuid.h], [
 859         dnl util-linux-ng's uuid/uuid.h found - check for uuid_generate in
 860         dnl -luuid.
 861         SAVE_LIBS=$LIBS
 862         AC_SEARCH_LIBS([uuid_generate], [uuid], [], [
 863           AC_MSG_ERROR([uuid_generate() not found in -luuid - required for glass and honey backends (you may need to install the uuid-dev, libuuid-devel or e2fsprogs-devel package)])
 864           ])
 865         if test x != x"$LIBS" ; then
 866           XAPIAN_LIBS="$XAPIAN_LIBS $LIBS"
 867         fi
 868       ], [
 869         dnl Try uuid.h as found on FreeBSD/NetBSD, with associated code in libc.
 870         AC_CHECK_HEADERS([uuid.h], [
 871           dnl Check for uuid_create with no extra libraries required.
 872           AC_CHECK_FUNC([uuid_create], [], [
 873             AC_MSG_ERROR([uuid.h found, but uuid_create() not found.  You probably wants to install libuuid from util-linux-ng or e2fsprogs (you may need to install the uuid-dev, libuuid-devel or e2fsprogs-devel package)])
 874           ])
 875         ], [
 876           dnl Especially useful for Android.
 877           AC_MSG_CHECKING([if host platform supports /proc/sys/kernel/random/uuid])
 878           case $host_os in
 879             linux*)
 880               use_proc_for_uuid=1
 881               AC_DEFINE([USE_PROC_FOR_UUID], [1],
 882                         [Define to 1 to read UUID from '/proc/sys/kernel/random/uuid'])
 883               AC_MSG_RESULT([yes])
 884               ;;
 885             *)
 886               AC_MSG_RESULT([no])
 887               AC_MSG_ERROR([Failed to find a way to generate UUIDs, required for glass and honey backends (you may need to install the uuid-dev, libuuid-devel or e2fsprogs-devel package)])
 888               ;;
 889           esac
 890         ], [ ])
 891       ], [ ])
 892       ;;
 893   esac
 894
 895   dnl Older versions of libuuid (such as that on CentOS 4.7) don't have
 896   dnl uuid_unparse_lower(), only uuid_unparse().
 897   AC_LINK_IFELSE([AC_LANG_CALL([], [uuid_unparse_lower])],
 898     [
 899     AC_DEFINE([HAVE_UUID_UNPARSE_LOWER], [1],
 900               [Define to 1 if you have the 'uuid_unparse_lower' function.])
 901     ])
 902   LIBS=$SAVE_LIBS
 903
 904   case $host_os in
 905     *djgpp* | *msdos* )
 906       dnl DJGPP has a dummy implementation of fork which always fails.
 907       dnl
 908       dnl For disk-based backends, use flock() for locking, which doesn't need
 909       dnl fork() or socketpair().
 910       AC_DEFINE([FLINTLOCK_USE_FLOCK], 1, [Define to use flock() for flint-compatible locking])
 911       ;;
 912   esac
 913   ;;
 914 esac
 915 AM_CONDITIONAL([USE_PROC_FOR_UUID], [test "$use_proc_for_uuid" = 1])
 916 AM_CONDITIONAL([USE_WIN32_UUID_API], [test "$use_win32_uuid_api" = 1])
 917
 918 if test "$enable_backend_remote" = yes ; then
 919   case $host_os-$win32 in
 920     *-yes )
 921       dnl For mingw and msvc we have an alternative implementation which
 922       dnl doesn't need fork() or socketpair().
 923       dnl
 924       dnl We need -lws2_32 for getaddrinfo(), etc.
 925       win32_need_lws2_32=1
 926       dnl Vista is needed for the AI_ADDRCONFIG flag to getaddrinfo().
 927       AC_DEFINE([WINVER], [0x600],
 928                 [Version of Windows to assume (0x600 => Vista).])
 929       AC_DEFINE([_WIN32_WINNT], [WINVER],
 930                 [Version of Windows to assume.])
 931       ;;
 932     *djgpp* | *msdos* )
 933       dnl DJGPP has a dummy implementation of fork which always fails.  If
 934       dnl someone actually wanted remote backend support, then DJGPP has a
 935       dnl pthreads port, so using threads like we do on Windows would make more
 936       dnl sense.
 937       AC_MSG_ERROR([The remote backend is not currently supported on this platform.])
 938       ;;
 939     *)
 940       dnl On Unix, we need fork and socketpair for the remotebackend.
 941       SAVE_LIBS=$LIBS
 942       AC_CHECK_FUNCS([fork], [], [
 943         AC_MSG_ERROR([fork() required for the remote backend - if an extra library is needed, pass LIBS=-lfoo to configure.  Or --disable-backend-remote to disable it.)])
 944       ])
 945       dnl Check if -lsocket is required for socketpair (Solaris needs it).
 946       dnl And on Haiku it's in -lnetwork.
 947       AC_SEARCH_LIBS([socketpair], [socket network], [], [
 948         AC_MSG_ERROR([socketpair() required for the remote backend - if an extra library is needed, pass LIBS=-lfoo to configure.  Or --disable-backend-remote to disable it.)])
 949       ])
 950       AC_DEFINE([HAVE_SOCKETPAIR], [1],
 951                 [Define to 1 if you have the 'socketpair' function.])
 952       dnl Check if extra libraries are needed for getaddrinfo or inet_ntop()
 953       dnl (e.g. on Solaris).
 954       dnl
 955       dnl We're currently assuming that any system that is worth trying to
 956       dnl support has getaddrinfo() and inet_ntop(), since these are the
 957       dnl standard route for supporting IPv6, and that's pretty much essential
 958       dnl for platforms to support now.
 959       AC_SEARCH_LIBS([getaddrinfo], [nsl socket], [], [
 960         AC_MSG_ERROR([getaddrinfo() required for the remote backend - if an extra library is needed, pass LIBS=-lfoo to configure.  Or --disable-backend-remote to disable it.)])
 961       ])
 962       AC_SEARCH_LIBS([inet_ntop], [nsl socket], [], [
 963         AC_MSG_ERROR([inet_ntop() required for the remote backend - if an extra library is needed, pass LIBS=-lfoo to configure.  Or --disable-backend-remote to disable it.)])
 964       ])
 965       XAPIAN_LIBS="$XAPIAN_LIBS $LIBS"
 966       LIBS=$SAVE_LIBS
 967       ;;
 968   esac
 969
 970   TYPE_SOCKLEN_T
 971 fi
 972
 973 if test "$win32_need_lws2_32" = 1 ; then
 974   XAPIAN_LIBS="$XAPIAN_LIBS -lws2_32"
 975 fi
 976
 977 AC_ARG_ENABLE([visibility],
 978   [AS_HELP_STRING([--disable-visibility], [disable use of GCC visibility])],
 979   [case ${enableval} in
 980     yes|no) ;;
 981     *) AC_MSG_ERROR([bad value ${enableval} for --disable-visibility]) ;;
 982   esac])
 983
 984 vpath_build=no
 985 if test "`pwd`" != "`cd $srcdir;pwd`" ; then
 986   vpath_build=yes
 987 fi
 988 AM_CONDITIONAL([VPATH_BUILD], [test yes = "$vpath_build"])
 989
 990 dnl Turn off compilation of anything that we don't have the requirements for
 991
 992 dnl Set conditionals to specify what we compile
 993
 994 AM_CONDITIONAL([BUILD_BACKEND_GLASS], [test yes = "$enable_backend_glass"])
 995 AM_CONDITIONAL([BUILD_BACKEND_HONEY], [test yes = "$enable_backend_honey"])
 996 AM_CONDITIONAL([BUILD_BACKEND_INMEMORY], [test yes = "$enable_backend_inmemory"])
 997 AM_CONDITIONAL([BUILD_BACKEND_REMOTE], [test yes = "$enable_backend_remote"])
 998 AM_CONDITIONAL([BUILD_BACKEND_TOOLS],
 999   [test nono != "$enable_backend_glass$enable_backend_honey"])
1000
1001 dnl Decide if we should use the zlib-vg.so LD_PRELOAD hack.
1002 use_zlib_vg=no
1003 if test -n "$VALGRIND" ; then
1004   case $host_os in
1005     linux*) use_zlib_vg=yes ;;
1006   esac
1007 fi
1008 AM_CONDITIONAL([USE_ZLIB_VG], [test yes = "$use_zlib_vg"])
1009
1010 dnl See if we have fdatasync, and what libraries are needed for it.
1011 dnl We need to actually check for a declaration as OS X has a dummy
1012 dnl implementation in the library which is not prototyped in any header.
1013 AC_CHECK_DECL([fdatasync(int)], [
1014   SAVE_LIBS=$LIBS
1015   AC_SEARCH_LIBS([fdatasync], [rt], [XAPIAN_LIBS="$LIBS $XAPIAN_LIBS"])
1016   LIBS=$SAVE_LIBS
1017   AC_CHECK_FUNCS([fdatasync])
1018   ],
1019   [ac_cv_func_fdatasync=no],
1020   [#include <unistd.h>]
1021 )
1022
1023 AC_CHECK_FUNCS([fsync])
1024 AC_CHECK_FUNCS([posix_fadvise])
1025 if test "$win32" = no ; then
1026   dnl ftruncate() under Wine seems to be buggy and sometimes fails, though
1027   dnl a cut-down reproducer seems fine.  For now just avoid ftruncate()
1028   dnl entirely on this platform - we'll fallback to lseek() + write() of a
1029   dnl single zero byte, which is pretty efficient.
1030   AC_CHECK_FUNCS([ftruncate])
1031 fi
1032
1033 dnl HP-UX has pread and pwrite, but they don't work!  Apparently this problem
1034 dnl manifests when largefile support is enabled, and we definitely want that
1035 dnl so don't use pread or pwrite on HP-UX.
1036 case $host_os in
1037   hpux*)
1038     AC_MSG_CHECKING([for pread])
1039     AC_MSG_RESULT([present but broken on $host_os])
1040     AC_MSG_CHECKING([for pwrite])
1041     AC_MSG_RESULT([present but broken on $host_os])
1042     ;;
1043   *)
1044     AC_CHECK_FUNC([pread],
1045        [AC_DEFINE([HAVE_PREAD], [1],
1046             [Define if pread is available on this system])
1047         AC_MSG_CHECKING([for any prototype needed for pread])
1048         AC_CACHE_VAL([xo_cv_pread_prototype],
1049           [
1050             for p in ' ' \
1051               'extern "C" ssize_t pread(int, void *, size_t, off_t) throw ();' \
1052               'extern "C" ssize_t pread(int, void *, size_t, off_t);' ; do
1053               AC_TRY_COMPILE([
1054 #include <sys/types.h>
1055 #include <unistd.h>
1056 $p
1057               ],[
1058                 char b[256];
1059                 pread(1, b, 256, 20);
1060               ],[
1061                 xo_cv_pread_prototype="$p"
1062                 break
1063               ])
1064             done
1065             if test -z "$xo_cv_pread_prototype"; then
1066               AC_MSG_RESULT([not found])
1067               AC_MSG_ERROR([Failed to find working prototype for pread])
1068             fi
1069           ])
1070           if test " " = "$xo_cv_pread_prototype" ; then
1071             AC_MSG_RESULT([none required])
1072           else
1073             AC_MSG_RESULT([$xo_cv_pread_prototype])
1074             AC_DEFINE_UNQUOTED([PREAD_PROTOTYPE], [$xo_cv_pread_prototype],
1075                                [explicit prototype needed for pread (if any)])
1076           fi
1077         ])
1078     AC_CHECK_FUNC([pwrite],
1079        [AC_DEFINE([HAVE_PWRITE], [1],
1080             [Define if pwrite is available on this system])
1081         AC_MSG_CHECKING([for any prototype needed for pwrite])
1082         AC_CACHE_VAL([xo_cv_pwrite_prototype],
1083           [
1084             for p in ' ' \
1085               'extern "C" ssize_t pwrite(int, const void *, size_t, off_t) throw ();' \
1086               'extern "C" ssize_t pwrite(int, const void *, size_t, off_t);' ; do
1087               AC_TRY_COMPILE([
1088 #include <sys/types.h>
1089 #include <unistd.h>
1090 $p
1091               ],[
1092                 const char *p = "hello";
1093                 pwrite(1, p, 5, 20);
1094               ],[
1095                 xo_cv_pwrite_prototype="$p"
1096                 break
1097               ])
1098             done
1099             if test -z "$xo_cv_pwrite_prototype"; then
1100               AC_MSG_RESULT([not found])
1101               AC_MSG_ERROR([Failed to find working prototype for pwrite])
1102             fi
1103           ])
1104           if test " " = "$xo_cv_pwrite_prototype" ; then
1105             AC_MSG_RESULT([none required])
1106           else
1107             AC_MSG_RESULT([$xo_cv_pwrite_prototype])
1108             AC_DEFINE_UNQUOTED([PWRITE_PROTOTYPE], [$xo_cv_pwrite_prototype],
1109                                [explicit prototype needed for pwrite (if any)])
1110           fi
1111         ])
1112     ;;
1113 esac
1114
1115 AC_MSG_CHECKING([for directory separator(s)])
1116 case $host_os-$win32 in
1117   *-yes | cygwin* | os2* | *djgpp* | *msdos* )
1118     AC_MSG_RESULT([/ and \\])
1119     AC_DEFINE([DIR_SEPS], ["/\\"], [directory separator(s) as a character or string literal])
1120     AC_DEFINE([DIR_SEPS_LIST], [{ '/', '\\' }], [directory separator(s) as an initialiser list])
1121     ;;
1122   *)
1123     AC_MSG_RESULT([/])
1124     AC_DEFINE([DIR_SEPS], ['/'], [directory separator(s) as a character or string literal])
1125     AC_DEFINE([DIR_SEPS_LIST], [{ '/' }], [directory separator(s) as an initialiser list])
1126     ;;
1127 esac
1128
1129 AC_CHECK_FUNCS([link])
1130
1131 dnl *************************
1132 dnl * Set debugging options *
1133 dnl *************************
1134
1135 dnl Which assertion types to enable in the code.
1136
1137 AC_ARG_ENABLE([assertions],
1138   [AS_HELP_STRING([--enable-assertions], [enable debug assertions (no|partial|yes) [default=no]])],
1139   [case $enableval in
1140     yes|partial|no) ;;
1141     *)
1142       AC_MSG_ERROR([Invalid option: '--enable-assertions=$enableval']) ;;
1143   esac])
1144
1145 AC_ARG_ENABLE([log],
1146   [AS_HELP_STRING([--enable-log], [generate a log of methods called, etc (no|yes|profile) [default=no]])],
1147   [case $enableval in
1148     yes|no) ;;
1149     profile)
1150       AC_MSG_ERROR(['--enable-log=profile' is no longer supported - see https://trac.xapian.org/wiki/ProfilingXapian for alternatives.]) ;;
1151     *)
1152       AC_MSG_ERROR([Invalid option: '--enable-log=$enableval']) ;;
1153   esac])
1154
1155 dnl Set defines according to the --enable-assertions and --enable-log options
1156 dnl given.
1157
1158 if test yes = "$enable_assertions" || test partial = "$enable_assertions" ; then
1159   AC_DEFINE([XAPIAN_ASSERTIONS],,
1160     [Define if you want assertions (causes some slow-down)])
1161 fi
1162
1163 if test yes = "$enable_assertions"; then
1164   AC_DEFINE([XAPIAN_ASSERTIONS_PARANOID],,
1165     [Define if you want paranoid assertions (causes significant slow-down)])
1166 fi
1167
1168 if test yes = "$enable_log"; then
1169   AC_DEFINE([XAPIAN_DEBUG_LOG],,
1170     [Define if you want a log of methods called and other debug messages])
1171 fi
1172
1173 dnl ******************************
1174 dnl * Set special compiler flags *
1175 dnl ******************************
1176
1177 dnl Set flags to control warnings (enable more, or disable annoying ones).
1178 dash_d_visibility=
1179 if test yes = "$GXX"; then
1180   dnl Intel's C++ compiler and clang both lie and define __GNUC__, so check which
1181   dnl we actually have, as neither is really 100% compatible.
1182   case `echo __INTEL_COMPILER __clang__|$CXX -E - 2>&AS_MESSAGE_LOG_FD|grep -v '^#'` in
1183     *__INTEL_COMPILER*__clang__*)
1184       dnl GCC (since neither substituted):
1185
1186       dnl The exact format of g++ --version seems to change with almost every
1187       dnl minor release so use the preprocessor macros which should be more
1188       dnl robust.
1189       AC_MSG_CHECKING([for version of $CXX])
1190       gxx_version=`echo __GNUC__.__GNUC_MINOR__.__GNUC_PATCHLEVEL__|$CXX -E -|sed '/^#/d;s/ //g'`
1191       AC_MSG_RESULT([GCC $gxx_version])
1192
1193       case $gxx_version in
1194       [[0123]].*|4.[[0-7]].*)
1195         AC_MSG_ERROR([Xapian requires GCC 4.8 or later])
1196         ;;
1197       esac
1198
1199       dnl -Wundef was supported by g++ 3.0.
1200       dnl
1201       dnl -Wlogical-op and -Wmissing-declarations (for C++) were added in
1202       dnl GCC 4.3.
1203       dnl
1204       dnl -Wdouble-promotion was added in GCC 4.6.
1205       dnl
1206       dnl -Winit-self was added in GCC 3.4, but for GCC < 4.7 g++ always
1207       dnl warns for this case with -Wuninitialized (implied by -W).  We
1208       dnl don't intend to use this idiom, so any instances are bugs we'd
1209       dnl like to know about.
1210       dnl
1211       dnl All the other options were supported by g++ 2.95.
1212       AM_CXXFLAGS="$AM_CXXFLAGS -Wall -W -Wredundant-decls -Wpointer-arith -Wcast-qual -Wcast-align -Wformat-security -fno-gnu-keywords -Wundef -Woverloaded-virtual -Wstrict-null-sentinel -Wshadow -Wstrict-overflow=1 -Wlogical-op -Wmissing-declarations -Wdouble-promotion -Winit-self"
1213
1214       dnl FIXME:
1215       dnl -Wconversion in older GCC versions is intended to help migration
1216       dnl from K&R to ISO C, and isn't useful for us.  In 4.3 it was renamed
1217       dnl to -Wtraditional-conversion and a new -Wconversion added which
1218       dnl sounds useful but is a bit buggy currently.  So we should consider
1219       dnl enabling -Wconversion once it is stabilised (GCC 4.4 or ...)
1220       dnl
1221       dnl -Wold-style-cast is interesting, but triggers for macros from
1222       dnl system headers (e.g. FD_SET).  GCC 4.8 improved this by making
1223       dnl -ftrack-macro-expansion=2 the default, but we still see such
1224       dnl warnings on some platforms for some reason (e.g. Cygwin with GCC
1225       dnl 5.4.0 warns about FD_SET, and on Debian with GCC 4.9.2 we see
1226       dnl warnings from zlib.h).
1227
1228       dnl Automatically add -Werror if maintainer mode is enabled.
1229       if test x$USE_MAINTAINER_MODE = xyes; then
1230         AM_CXXFLAGS="$AM_CXXFLAGS -Werror"
1231       fi
1232       ;;
1233     *__clang__*)
1234       dnl Intel's compiler (since __clang__ not substituted):
1235       dnl
1236       dnl -w1 stops the avalanche of uninteresting "remark" messages.
1237       dnl -wd... disables warnings which don't have good code workarounds.
1238       AM_CXXFLAGS="$AM_CXXFLAGS -Wall -w1 -wd177,1572"
1239
1240       dnl Automatically add -Werror if maintainer mode is enabled.
1241       if test x$USE_MAINTAINER_MODE = xyes; then
1242         AM_CXXFLAGS="$AM_CXXFLAGS -Werror"
1243       fi
1244       ;;
1245     *__INTEL_COMPILER*)
1246       dnl clang (since __INTEL_COMPILER not substituted):
1247
1248       dnl These options all work at least as far back as clang++ 3.0:
1249       AM_CXXFLAGS="$AM_CXXFLAGS -Wall -W -Wredundant-decls -Wpointer-arith -Wcast-qual -Wcast-align -Wformat-security -fno-gnu-keywords -Wundef -Woverloaded-virtual -Wshadow -Wstrict-overflow=1 -Wmissing-declarations -Winit-self"
1250
1251       dnl Automatically add -Werror if maintainer mode is enabled.
1252       if test x$USE_MAINTAINER_MODE = xyes; then
1253         AM_CXXFLAGS="$AM_CXXFLAGS -Werror"
1254       fi
1255       ;;
1256   esac
1257
1258   if test no != "$enable_visibility"; then
1259     dnl GCC doesn't support symbol visibility on all platforms (e.g. it isn't
1260     dnl supported on mingw and visibility attributes result in warnings).
1261     AC_MSG_CHECKING([if $CXX -fvisibility=hidden -fvisibility-inlines-hidden works])
1262     if echo 'int bar() __attribute__((visibility("default"))); int baz() __attribute__((visibility("internal"))); int bar() { return 6; } int baz() { return 7; } int foo() {return 42;}'|$CXX -Werror -fvisibility=hidden -fvisibility-inlines-hidden -c -oconftest.o -xc++ - >&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
1263       AC_MSG_RESULT([yes])
1264       AM_CXXFLAGS="$AM_CXXFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
1265       dash_d_visibility=-DXAPIAN_ENABLE_VISIBILITY
1266     else
1267       AC_MSG_RESULT([no])
1268     fi
1269   fi
1270 else
1271   dnl Not GCC, nor a compiler masquerading as GCC.
1272   case /$CXX in
1273   */aCC)
1274     dnl +w turns on more warnings.
1275     dnl +wlint turns on "lint-like" warnings.
1276     dnl +W<n1>,<n2>,... suppresses warnings n1, n2, ...
1277     dnl 2340 (remark) "value copied to temporary, reference to temporary
1278     dnl use", in: throw Xapian::UnimplementedError("...");
1279     dnl 2401 "destructor for base class ... is non-virtual" (we don't need a
1280     dnl virtual destructor for intrusive_base, since we never delete
1281     dnl       its subclasses by a intrusive_base *).
1282     dnl 3348 "declaration hides constant ..." which seems to misfire!
1283     dnl 4255 (remark) "padding size of struct "..." with ... bytes to
1284     dnl alignment boundary".
1285     dnl 4273 "floating-point equality and inequality comparisons may be
1286     dnl inappropriate due to roundoff common in floating-point computation"
1287     dnl No obvious workaround for when you really do want == or !=.
1288     dnl 20201 "Memory leak is detected" which triggers for "return new Foo;"!
1289     AM_CXXFLAGS="$AM_CXXFLAGS +w +wlint +W2340,2401,3348,4255,4273,20201" ;;
1290   */sunCC|*/CC)
1291     dnl Sun's C++ compiler warns about functions failing to return a value even
1292     dnl when the function ends with a "throw" statement.  That's just unhelpful
1293     dnl noise, and adding a dummy "return" after "throw" seems a worse solution
1294     dnl than simply disabling this warning - any genuinely missing return
1295     dnl statements will get reported by compilers with superior warning
1296     dnl machinery.
1297     XAPIAN_TEST_CXXFLAGS([-erroff=voidretw], [AM_CXXFLAGS])
1298     ;;
1299   esac
1300 fi
1301
1302 XAPIAN_TEST_LINKER_FLAG([-Bsymbolic-functions], [symbolic_functions],
1303   [XAPIAN_LDFLAGS="$XAPIAN_LDFLAGS $flag"])
1304
1305 FP_EXCESS_PRECISION=no
1306 AC_MSG_CHECKING([whether to use SSE instructions on x86])
1307 case $host_cpu in
1308   i*86)
1309     if test "$enable_sse" = no ; then
1310       AC_MSG_RESULT([no])
1311       FP_EXCESS_PRECISION=yes
1312     else
1313       dnl Default to sse2.
1314       test "$enable_sse" != yes || enable_sse=sse2
1315       if test yes = "$GXX"; then
1316         AC_MSG_RESULT([yes (configure with --disable-sse to disable)])
1317         dnl We can unconditionally use -mtune=generic as it was added in GCC
1318         dnl 4.2, and supported at least as far back as clang 3.0.
1319         AM_CXXFLAGS="$AM_CXXFLAGS -mfpmath=sse -m$enable_sse -mtune=generic"
1320       else
1321         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1322 [[#ifndef __SUNPRO_CC
1323 #error Not Sun compiler
1324 #endif]])],
1325           [AC_MSG_RESULT([yes (configure with --disable-sse to disable)])
1326           AM_CXXFLAGS="$AM_CXXFLAGS -xarch=$enable_sse"]
1327           ,
1328           [AC_MSG_RESULT([don't know how to for compiler $CXX])
1329           FP_EXCESS_PRECISION=yes]
1330         )
1331       fi
1332     fi
1333     ;;
1334   *)
1335     AC_MSG_RESULT([non-x86 arch ($host_cpu)]) ;;
1336 esac
1337 AC_SUBST([FP_EXCESS_PRECISION])
1338
1339 AH_BOTTOM(
1340 [/* Disable stupid MSVC warnings. */
1341 #ifdef _MSC_VER
1342 /* Passing an empty parameter to a single parameter macro. */
1343 # pragma warning(disable:4003)
1344 /* A "performance" warning for converting int to bool. */
1345 # pragma warning(disable:4800)
1346
1347 /* Tell MSVC we want M_PI, etc defined. */
1348 # define _USE_MATH_DEFINES
1349
1350 /* Tell MSVC we don't want max() and min() macros defined. */
1351 # define NOMINMAX
1352 #endif
1353
1354 /* Make the POSIX-like functions support large files.  MSVC needs this;
1355  * current mingw32 does too; mingw64 supports _FILE_OFFSET_BITS, which
1356  * AC_SYS_LARGEFILE should discover and enable automatically.
1357  */
1358 #if defined _MSC_VER || \
1359     (defined __MINGW32__ && !defined _FILE_OFFSET_BITS)
1360
1361 # include <sys/stat.h>
1362 # include <sys/types.h>
1363 # include <io.h>
1364 /* zlib.h uses off_t so we need to include it before we redefine off_t. */
1365 # include <zlib.h>
1366
1367 // MSVC needs to call _stat64() instead of stat() and the struct which holds
1368 // the information is "struct _stat64" instead of "struct stat" so we just
1369 // use #define to replace both in one go.  We also want to use _fstat64()
1370 // instead of fstat() but in this case we can use a function-like macro.
1371 //
1372 // Mingw has _stat64() but unhelpfully for our purposes, it has an extra
1373 // underscore prefix on the struct name ("struct __stat64") so there we
1374 // target _stati64 instead.  This has 64-bit file size but the time_t size
1375 // is switchable.  We don't really care about file timestamps in the
1376 // library, so this should be fine.
1377 //
1378 // This hack is a problem is we ever want a method called "stat", or one called
1379 // fstat which takes 2 parameters, but we can probably live with these
1380 // limitations.
1381
1382 # ifdef stat
1383 #  undef stat
1384 # endif
1385
1386 # ifdef fstat
1387 #  undef fstat
1388 # endif
1389
1390 # ifdef _MSC_VER
1391 #  define stat _stat64
1392 #  define fstat(FD, BUF) _fstat64(FD, BUF)
1393 # else
1394 #  define stat _stati64
1395 #  define fstat(FD, BUF) _fstati64(FD, BUF)
1396 # endif
1397
1398 # ifdef lseek
1399 #  undef lseek
1400 # endif
1401
1402 # ifdef off_t
1403 #  undef off_t
1404 # endif
1405
1406 # define lseek(FD, OFF, WHENCE) _lseeki64(FD, OFF, WHENCE)
1407 /* Redefine via a typedef so C++ code off_t(-1) works - it wouldn't if we did:
1408  * #define off_t long long
1409  */
1410 typedef long long off_t_redefinition_typedef;
1411 # define off_t off_t_redefinition_typedef
1412
1413 #endif
1414
1415 /* MSVC defines _WIN32 but not __WIN32__. */
1416 #if !defined __WIN32__ && defined _WIN32 && !defined _WIN64
1417 # define __WIN32__
1418 #endif
1419
1420 /* _FORTIFY_SOURCE is only supported by GCC >= 4.1 and glibc >= 2.3.4, but it
1421  * shouldn't cause a problem to define it where it's not supported and some
1422  * distros may have backported support, so hardcoding version checks is
1423  * counter-productive.
1424  *
1425  * Check if _FORTIFY_SOURCE is already defined to allow the user to override
1426  * our choice with "./configure CPPFLAGS=-D_FORTIFY_SOURCE=0" or "...=1".
1427  */
1428 #if defined __GNUC__ && !defined _FORTIFY_SOURCE
1429 # define _FORTIFY_SOURCE 2
1430 #endif
1431
1432 /* For compilers which support it (such as GCC, clang, Intel's C++ compiler)
1433  * we can use __builtin_expect to give the compiler hints about branch
1434  * prediction.  See HACKING for how to use these.
1435  */
1436 #if HAVE_DECL___BUILTIN_EXPECT
1437 /* The arguments of __builtin_expect() are both long, so use !! to ensure that
1438  * the first argument is always an integer expression, and always 0 or 1, but
1439  * still has the same truth value for the if or while it is used in.
1440  */
1441 # define rare(COND) __builtin_expect(!!(COND), 0)
1442 # define usual(COND) __builtin_expect(!!(COND), 1)
1443 #else
1444 # define rare(COND) (COND)
1445 # define usual(COND) (COND)
1446 #endif
1447
1448 /* Signal we're building the library so it's OK to include headers such as
1449  * xapian/query.h directly.
1450  */
1451 #define XAPIAN_LIB_BUILD 1
1452
1453 /* With Sun CC 5.13 (Studio 12.4) on Solaris 11.2, <math.h> seems to get
1454  * implicitly included somehow before <cmath>, and compilation fails due
1455  * to 'std::exception' colliding with 'struct exception'.  It's not clear
1456  * how to avoid this, so just define the same magic macro which <cmath> does
1457  * before it includes <math.h>.
1458  */
1459 #ifdef __SUNPRO_CC
1460 # define __MATHERR_RENAME_EXCEPTION
1461 #endif
1462 ])
1463
1464 AC_SUBST([AM_CXXFLAGS])
1465
1466 dnl Restore CXXFLAGS to those the user specified or autoconf defaulted to.
1467 CXXFLAGS=$save_CXXFLAGS
1468
1469 dnl Required for auto regeneration to work in a combined maintainer-mode tree.
1470 : ${AUTOM4TE=autom4te}
1471 AC_SUBST([AUTOM4TE])
1472
1473 dnl Libtool sets this (to yes|no|unknown) and we use it in xapian-config.
1474 AC_SUBST([link_all_deplibs_CXX])
1475
1476 dnl Shared library extension.
1477 module=no
1478 eval "SHLIBEXT=$shrext_cmds"
1479 AC_SUBST([SHLIBEXT])
1480
1481 dnl We want to be able to use GNU make % pattern rules in maintainer targets
1482 dnl but automake warns these aren't portable, so we substitute the % to avoid
1483 dnl this warning.
1484 PERCENT='%'
1485 AC_SUBST([PERCENT])
1486
1487 dnl Split up the version number into "MAJOR.MINOR.REVISION".
1488 MAJOR_VERSION=`echo "$VERSION"|sed 's/\..*//'`
1489 [MINOR_VERSION=`echo "$VERSION"|sed 's/[^.]*\.//;s/\..*//'`]
1490 [REVISION=`echo "$VERSION"|sed 's/.*\.//;s/_.*$//'`]
1491
1492 dnl **************************
1493 dnl * Build the output files *
1494 dnl **************************
1495
1496 AC_CONFIG_FILES([
1497  Makefile
1498  tests/Makefile
1499  docs/Makefile
1500  docs/doxygen_api.conf
1501  docs/doxygen_source.conf
1502  xapian-core.spec
1503  cmake/xapian-config.cmake
1504  cmake/xapian-config-version.cmake
1505  pkgconfig/xapian-core"$LIBRARY_VERSION_SUFFIX".pc:pkgconfig/xapian-core.pc.in
1506  ])
1507 AC_CONFIG_FILES([tests/runtest], [chmod +x tests/runtest])
1508 AC_CONFIG_FILES([tests/runsrv], [chmod +x tests/runsrv])
1509 AC_CONFIG_FILES([tests/submitperftest], [chmod +x tests/submitperftest])
1510 AC_CONFIG_FILES([tests/perftest/get_machine_info], [chmod +x tests/perftest/get_machine_info])
1511 AC_CONFIG_FILES([xapian-config], [chmod +x xapian-config])
1512 AC_CONFIG_FILES([makemanpage], [chmod +x makemanpage])
1513 AC_OUTPUT
1514
1515 dnl There are no files generated by AC_OUTPUT in the following directories
1516 dnl and we need to ensure they exist so that the rest of configure or make
1517 dnl won't fail because they don't exist when srcdir != builddir.
1518 if test yes = "$vpath_build" ; then
1519   for dir in include/xapian languages queryparser ; do
1520     AS_MKDIR_P(["$dir"])
1521   done
1522 fi
1523
1524 dnl Generate include/xapian/version.h:
1525
1526 dnl MAIN_VERSION is VERSION without any _git123 suffix.
1527 MAIN_VERSION="$MAJOR_VERSION.$MINOR_VERSION.$REVISION"
1528 cxxcpp_flags=-I.
1529 for backend in GLASS HONEY INMEMORY REMOTE ; do
1530   val=`eval echo "\\\$BUILD_BACKEND_${backend}_TRUE"`
1531   if test -z "$val" ; then
1532     cxxcpp_flags="$cxxcpp_flags -DXAPIAN_HAS_${backend}_BACKEND"
1533   fi
1534 done
1535
1536 if test yes = "$enable_64bit_docid" ; then
1537   cxxcpp_flags="$cxxcpp_flags -DXAPIAN_DOCID_BASE_TYPE="`echo "$INT64_T"|sed 's/ /____/g'`
1538 else
1539   cxxcpp_flags="$cxxcpp_flags -DXAPIAN_DOCID_BASE_TYPE="`echo "$INT32_T"|sed 's/ /____/g'`
1540 fi
1541
1542 if test yes = "$enable_64bit_termcount" ; then
1543   cxxcpp_flags="$cxxcpp_flags -DXAPIAN_TERMCOUNT_BASE_TYPE="`echo "$INT64_T"|sed 's/ /____/g'`
1544 else
1545   cxxcpp_flags="$cxxcpp_flags -DXAPIAN_TERMCOUNT_BASE_TYPE="`echo "$INT32_T"|sed 's/ /____/g'`
1546 fi
1547
1548 dnl Always ought to be 64 bit.
1549 cxxcpp_flags="$cxxcpp_flags -DXAPIAN_TOTALLENGTH_TYPE="`echo "unsigned $INT64_T"|sed 's/ /____/g'`
1550
1551 dnl Make revision numbers in the API 64 bit for future-proofing.
1552 cxxcpp_flags="$cxxcpp_flags -DXAPIAN_REVISION_TYPE="`echo "unsigned $INT64_T"|sed 's/ /____/g'`
1553
1554 dnl For GCC (and compilers which pretend to be GCC) and MSVC, we create some
1555 dnl ABI checks in the generated version.h, and $CXXFLAGS may contain options
1556 dnl which affect the ABI (e.g. -fabi-version for GCC) so we want to use these
1557 dnl options when generating version.h.  For these compilers, CXXCPP="$CXX -E"
1558 dnl so it should understand all compiler options.
1559 dnl
1560 dnl For other compilers, we only pass $CPPFLAGS to $CXXCPP in case it's an
1561 dnl external cpp which doesn't understand flags which might be in $CXXFLAGS.
1562 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[#ifndef __GNUC__
1563 #ifndef _MSC_VER
1564        choke me
1565 #endif
1566 #endif
1567 ]])],
1568         [cxxcpp_flags="$cxxcpp_flags $CPPFLAGS $CXXFLAGS"],
1569         [cxxcpp_flags="$cxxcpp_flags $CPPFLAGS"])
1570 rm -f include/xapian/version.h.tmp
1571 dnl "\r" in sed is a GNUism, but we only need to remove it on MS Windows
1572 dnl where we'll always have GNU sed, and other sed's will just interpret
1573 dnl it as "r" (Solaris sed) or maybe literal "\r" which won't match.
1574 dnl
1575 dnl Use @@ around $MAIN_VERSION so we get " in the final output.
1576 $CXXCPP $cxxcpp_flags\
1577         -DSTRING_VERSION="\"@@$MAIN_VERSION@@\""\
1578         -DMAJOR_VERSION="\"$MAJOR_VERSION\""\
1579         -DMINOR_VERSION="\"$MINOR_VERSION\""\
1580         -DREVISION="\"$REVISION\""\
1581         $dash_d_visibility\
1582         $srcdir/include/xapian/version_h.cc|\
1583         ${SED-sed} '0,/const char \* dummy/d;/"/!d;s/^ *//;/^#/d;s/ *$//;s/" *,//;s/"//g;s/@@/"/g;s/  */ /g;s/ *,\r$//;s/ *,$//;s/____/ /g;s/\\\\$/\\/'\
1584         > include/xapian/version.h.tmp
1585 dnl Only update the file if it has changed, so we don't alter the timestamp
1586 dnl and cause lots of rebuilding needlessly.  However, the build system
1587 dnl needs a timestamp to know when to regenerate version.h because version_h.cc
1588 dnl has changed so we use a separate timestamp file.
1589 touch include/xapian/version.h.timestamp
1590 if cmp include/xapian/version.h.tmp include/xapian/version.h >/dev/null 2>&1
1591 then
1592   rm include/xapian/version.h.tmp
1593 else
1594   mv include/xapian/version.h.tmp include/xapian/version.h
1595 fi