xapian-core/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl NB When updating the version for a release, update LIBRARY_VERSION_INFO
   4 dnl below too.
   5 AC_INIT([xapian-core], [1.5.0], [https://xapian.org/bugs])
   6 dnl See HACKING document for details of the reasons for required versions.
   7 AC_PREREQ([2.64])
   8 dnl Extract from the libtool info manual:
   9 dnl
  10 dnl Here are a set of rules to help you update your library version information:
  11 dnl
  12 dnl 1. Start with version information of '0:0:0' for each libtool library.
  13 dnl
  14 dnl 2. Update the version information only immediately before a public
  15 dnl    release of your software.  More frequent updates are unnecessary,
  16 dnl    and only guarantee that the current interface number gets larger
  17 dnl    faster.
  18 dnl
  19 dnl 3. If the library source code has changed at all since the last
  20 dnl    update, then increment REVISION ('C:R:A' becomes 'C:r+1:A').
  21 dnl
  22 dnl 4. If any interfaces have been added, removed, or changed since the
  23 dnl    last update, increment CURRENT, and set REVISION to 0.
  24 dnl
  25 dnl 5. If any interfaces have been added since the last public release,
  26 dnl    then increment AGE.
  27 dnl
  28 dnl 6. If any interfaces have been removed since the last public release
  29 dnl    then set AGE to 0.
  30 dnl
  31 dnl LIBRARY_VERSION_INFO for libxapian1.5
  32 dnl 0:0:0 1.5.0 Reset as library renamed
  33 LIBRARY_VERSION_INFO=0:0:0
  34 AC_SUBST([LIBRARY_VERSION_INFO])
  35
  36 LIBRARY_VERSION_SUFFIX=
  37 dnl Where xapian.h, etc go.
  38 incdir=$includedir
  39 case $PACKAGE_VERSION in
  40   [*.*[13579].*])
  41     dnl Development release series:
  42     [dev_series=`echo "$PACKAGE_VERSION"|sed 's/\.[^.]*$//'`]
  43
  44     dnl Append version installed programs by default.  To specify no suffix,
  45     dnl configure with: --program-suffix=
  46     test x"$program_suffix" != xNONE || program_suffix=-$dev_series
  47
  48     incdir=$incdir/xapian-$dev_series
  49
  50     LIBRARY_VERSION_SUFFIX=-$dev_series
  51     ;;
  52 esac
  53
  54 AC_SUBST([LIBRARY_VERSION_SUFFIX])
  55 AC_SUBST([incdir])
  56
  57 dnl Check the build directory doesn't contain a space, so we die early with
  58 dnl a helpful error.
  59 case `pwd` in
  60 *' '*)
  61    AC_MSG_ERROR([You can't build in a directory whose path contains a space])
  62    ;;
  63 esac
  64
  65 dnl Check the source directory doesn't contain a space, so we die early with
  66 dnl a helpful error.  FIXME: Unfortunately, configure seems to choke before
  67 dnl it gets to us so this code doesn't get a chance to fire.
  68 case $0 in
  69 *' '*)
  70    dnl Note: for in-tree builds, the build directory test above will fire
  71    dnl before this can.
  72    AC_MSG_ERROR([You can't build with sources in a directory whose path contains a space])
  73    ;;
  74 esac
  75
  76 dnl Check the prefix to install in doesn't contain a space, so we die early with
  77 dnl a helpful error.
  78 case $prefix in
  79 *' '*)
  80    AC_MSG_ERROR([You can't install in a directory whose path contains a space])
  81    ;;
  82 esac
  83
  84 dnl Note if the user specified a particular C++ compiler so we can give a more
  85 dnl appropriate error message if we can't link a simple C++ program.
  86 original_CXX=
  87 if test -n "$CXX" ; then
  88   original_CXX="CXX=$CXX"
  89 elif test -n "$CCC" ; then
  90   original_CXX="CCC=$CCC"
  91 fi
  92
  93 dnl See HACKING document for details of the reasons for required versions.
  94 AM_INIT_AUTOMAKE([1.13 -Wportability tar-ustar no-dist-gzip dist-xz std-options])
  95 AC_CONFIG_SRCDIR([matcher/multiandpostlist.cc])
  96
  97 AC_CONFIG_HEADERS([config.h])
  98
  99 AC_CONFIG_MACRO_DIRS([m4])
 100
 101 AM_PROG_AR
 102
 103 dnl Use libtool to manage our libraries.
 104 LT_PREREQ([2.2.8])
 105 dnl Default to only building shared libraries.
 106 dnl
 107 dnl Building both shared and static means having to compile the files which
 108 dnl make up the library twice on most platforms.  Shared libraries are the
 109 dnl better option for most users, and if anyone really wants static libraries,
 110 dnl they can configure with --enable-static (or --enable-static=xapian-core if
 111 dnl configuring a combined tree with the bindings).
 112 dnl
 113 dnl We don't export any data items from the library, so it should be safe to
 114 dnl enable win32-dll without decorating any declarations specially.
 115 LT_INIT([disable-static win32-dll])
 116
 117 dnl -no-undefined causes problems on Solaris with Sun CC in C++11 mode, so only
 118 dnl pass -no-undefined on platforms where it is required in order to link a
 119 dnl shared library at all (Windows is the main one).
 120 NO_UNDEFINED=
 121 if test unsupported = "$allow_undefined_flag" ; then
 122   NO_UNDEFINED=-no-undefined
 123 fi
 124 AC_SUBST(NO_UNDEFINED)
 125
 126 AM_CXXFLAGS=
 127
 128 dnl A standard "gotcha" for mingw and cygwin users is to not set up their
 129 dnl PATH correctly, so that MSDOS FIND.EXE is found before Unix find.  Help
 130 dnl them out by checking for this condition, rather than letting libtool
 131 dnl fail in obscure ways.  NB check the *BUILD* OS, not the host one!
 132 case $build_os in
 133   *mingw* | *cygwin* | pw32*)
 134     find /dirunlikelytoexist >/dev/null 2>&1
 135     if test $? = 2 ; then
 136         dnl Unix find will return 1 if the directory didn't exist, or 0 if
 137         dnl it did.
 138         AC_MSG_ERROR([
 139 *** You appear to have an MSDOS-like FIND.EXE in your PATH ahead of any
 140 *** UNIX-like find.  This misconfiguration will confuse libtool - you'll need
 141 *** to make sure you have a UNIX-like find installed and fix your PATH, then
 142 *** rerun configure.  For more information, see:
 143 ***
 144 ***   https://www.cygwin.com/faq/faq.html#faq.using.find
 145 ])
 146     fi
 147   ;;
 148 esac
 149
 150 dnl Add parameters for aclocal
 151 dnl (This must come after AM_INIT_AUTOMAKE, since it modifies ACLOCAL)
 152 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
 153
 154 dnl disable "maintainer only" rules by default
 155 AM_MAINTAINER_MODE
 156
 157 dnl Checks for programs.
 158 AC_PROG_CXX
 159
 160 AC_CANONICAL_HOST
 161
 162 # Checked: freebsd8.0 openbsd4.6 solaris2.9 solaris2.10
 163 case $host_os in
 164   linux* | k*bsd*-gnu | freebsd* | openbsd* | solaris*)
 165     dnl Vanilla libtool sets this to "unknown" which it then handles as "yes".
 166     link_all_deplibs_CXX=no
 167     ;;
 168 esac
 169
 170 case $host_os in
 171   linux*)
 172     dnl Extract search path from ldconfig which is more reliable than the way
 173     dnl vanilla libtool extracts them from ld.so.conf.
 174     d=`/sbin/ldconfig -N -X -v 2>&AS_MESSAGE_LOG_FD|$SED 's,^\(/.*\):\( (.*)\)\?$,\1,p;d'|tr '\n' ' '`
 175     test -z "$d" || sys_lib_dlsearch_path_spec=$d
 176     ;;
 177 esac
 178
 179 case $host in
 180   *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-os2* | *-*-darwin* | *-cegcc*)
 181     dnl On these platforms, libtool emits a warning if -no-install is passed,
 182     dnl and uses -no-fast-install instead - the least ugly way to avoid that
 183     dnl warnings seems to be to duplicate the above list of platforms from
 184     dnl libtool and use -no-fast-install on them directly.
 185     NO_INSTALL=-no-fast-install ;;
 186   *)
 187     NO_INSTALL=-no-install ;;
 188 esac
 189 AC_SUBST([NO_INSTALL])
 190
 191 dnl For reasons which are beyond me, if autoconf can't find a C++ compiler
 192 dnl it will set CXX to g++ (which obviously won't work) rather than actually
 193 dnl telling the user that it couldn't find a C++ compiler and telling them
 194 dnl to either install one or set CXX if there's one configure failed to find.
 195 dnl It's probably worthwhile checking that the C++ compiler actually works
 196 dnl anyway!
 197 if test -n "$CXX" ; then
 198   AC_LANG_CPLUSPLUS
 199   AC_MSG_CHECKING([whether $CXX is a working C++ compiler])
 200   AC_CACHE_VAL([xo_cv_cxx_works],
 201     [
 202     AC_TRY_RUN([int main() {}],
 203                xo_cv_cxx_works=yes,
 204                xo_cv_cxx_works=no,
 205                AC_TRY_LINK([], [], xo_cv_cxx_works=yes, xo_cv_cxx_works=no))
 206     ])
 207   AC_MSG_RESULT([$xo_cv_cxx_works])
 208 else
 209   xo_cv_cxx_works=no
 210 fi
 211 if test no = "$xo_cv_cxx_works" ; then
 212   case $original_CXX in
 213   CCC=*)
 214     dnl CCC is handled in a slightly odd way - if its value isn't an
 215     dnl executable (taking PATH into account) then it is ignored!
 216     test "$original_CXX" = "CCC=$CXX" || original_CXX=
 217     ;;
 218   esac
 219   if test -z "$original_CXX" ; then
 220   AC_MSG_ERROR([
 221 *** You need a working C++ compiler to compile Xapian, but configure failed to
 222 *** find one.  If you have a working C++ compiler, you can tell configure where
 223 *** to find it by invoking it like so:
 224 ***
 225 ***   ./configure CXX=/opt/bin/c++
 226 ])
 227   else
 228   AC_MSG_ERROR([
 229 *** You need a working C++ compiler to compile Xapian, but the compiler you
 230 *** specified (with '$original_CXX') doesn't appear to be able to successfully
 231 *** compile and link a simple program.
 232 ])
 233   fi
 234 fi
 235
 236 dnl Probe for any options needed to enable C++11 support.
 237 AX_CXX_COMPILE_STDCXX_11
 238
 239 dnl We don't use a C compiler to compile Xapian's code, but on some platforms
 240 dnl (e.g. mingw) libtool uses $LTCC which defaults to $CC, and it's also use to
 241 dnl build auxiliary tools like snowball and lemon.
 242 AC_PROG_CC
 243
 244 dnl Check endianness.
 245 AC_C_BIGENDIAN
 246
 247 dnl We want a non-cross-compiling C compiler for building lemon with.
 248 if test -z "$CC_FOR_BUILD" ; then
 249   if test yes = "$cross_compiling"; then
 250     CC_FOR_BUILD=cc
 251   else
 252     CC_FOR_BUILD="$CC"
 253   fi
 254 fi
 255 AC_ARG_VAR([CC_FOR_BUILD], [C compiler command for native compilation (needed to compile build tools during cross-builds)])
 256
 257 dnl Run tests using the C++ compiler.
 258 AC_LANG_CPLUSPLUS
 259
 260 dnl Enable large file support if possible.
 261 AC_SYS_LARGEFILE
 262 dnl With xlC on AIX, -D_LARGE_FILES changes the ABI of std::string, so it
 263 dnl also needs to be used when compiling user code.
 264 abi_affecting_cxxflags=
 265 if $GREP '^#define _LARGE_FILES 1$' confdefs.h > /dev/null 2>&1 ; then
 266   abi_affecting_cxxflags=-D_LARGE_FILES
 267 fi
 268 AC_SUBST([abi_affecting_cxxflags])
 269
 270 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 271 #if defined __WIN32__ || defined _WIN32
 272 #error WIN32
 273 #endif
 274 ]])], [win32=no], [win32=yes])
 275
 276 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[
 277 #ifdef _MSC_VER
 278 #error MSVC
 279 #endif
 280 ]])], [msvc=no], [msvc=yes])
 281
 282 XAPIAN_LDFLAGS=
 283 XAPIAN_LIBS=
 284 AC_SUBST([XAPIAN_LDFLAGS])
 285 AC_SUBST([XAPIAN_LIBS])
 286
 287 AC_DEFUN([XAPIAN_TEST_LINKER_FLAG],
 288   [
 289   AC_MSG_CHECKING([for $CXX -Wl,$1])
 290   AC_CACHE_VAL([xo_cv_ldflag_$2],
 291     [
 292     save_LDFLAGS=$LDFLAGS
 293     LDFLAGS="$LDFLAGS -Wl,$1"
 294     flag=$1
 295     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 296       [xo_cv_ldflag_$2=yes
 297       $3],
 298       [xo_cv_ldflag_$2=no
 299       $4])
 300     LDFLAGS=$save_LDFLAGS
 301     ])
 302   AC_MSG_RESULT([$xo_cv_ldflag_$2])
 303   ])
 304
 305 dnl Test if the compiler works with $1 added to CXXFLAGS; if it does, add $1 to
 306 dnl variable $2.  If the test passes, also do $3; if it fails, also do $4.
 307 AC_DEFUN([XAPIAN_TEST_CXXFLAGS],
 308   [
 309   XTC_save_CXXFLAGS=$CXXFLAGS
 310   CXXFLAGS="$CXXFLAGS $1"
 311   AC_TRY_COMPILE([], [],
 312                  [CXXFLAGS=$XTC_save_CXXFLAGS
 313                   $2="${$2} $1"
 314                   $3],
 315                  [CXXFLAGS=$XTC_save_CXXFLAGS
 316                   $4])
 317   ])
 318
 319 ldflags=
 320 if test yesyes = "$GXX$enable_shared" ; then
 321   case $host_os in
 322     *mingw* | *cygwin*)
 323       XAPIAN_TEST_LINKER_FLAG([--enable-runtime-pseudo-reloc], [enable_runtime_pseudo_reloc],
 324         [ldflags="-Wl,$flag"],
 325         [
 326         dnl Can't use AC_DISABLE_SHARED after AC_PROG_LIBTOOL, but
 327         dnl this test needs to be after AC_PROG_LIBTOOL, so we can't
 328         dnl just disable the shared build automatically...
 329         AC_MSG_ERROR([ld version too old to support a shared build - configure with --disable-shared, or install binutils 2.13.90-20030111-1 or later])
 330         ])
 331     ;;
 332   esac
 333 fi
 334 dnl Only works for ldflags which can be specified anywhere on the link line.
 335 AC_SUBST([ldflags])
 336
 337 dnl Preserve the default CXXFLAGS.
 338 save_CXXFLAGS=$CXXFLAGS
 339
 340 dnl x86 has excess precision issues with 387 FP instructions, which are
 341 dnl avoided by using SSE instructions instead.  This is also faster (~6% in
 342 dnl a CPU bound testcase).
 343 AC_ARG_ENABLE([sse],
 344 [AS_HELP_STRING([--disable-sse],
 345                 [disable use of SSE FP instructions on x86])]
 346 [AS_HELP_STRING([[--enable-sse[=sse|sse2]]],
 347                 [set which SSE FP instructions to use on x86 (default: sse2)])],
 348   [case ${enableval} in
 349     sse|sse2|yes|no) ;;
 350     *) AC_MSG_ERROR([bad value ${enableval} for --enable-sse or --disable-sse]) ;;
 351   esac],
 352   [enable_sse=yes])
 353
 354 dnl Some versions of Sun's C++ compiler reportedly need an explicit -lm.
 355 dnl The maths functions we use include: exp log ceil fabs sqrt
 356 AC_MSG_CHECKING([if -lm is required for maths functions])
 357 dnl Don't use constant arguments as the compiler might simply evaluate the
 358 dnl whole expression at compile time, and it might inline certain functions
 359 dnl so test several functions.  Also write results using printf() so that
 360 dnl the compiler can't optimise away the computations.
 361 AC_TRY_LINK([#ifdef __SUNPRO_CC
 362 #error Need -lm for Sun C++ 5.9 under libtool 2.2.10
 363 #endif
 364 #include <cmath>
 365 #include <cstdio>
 366 #include <ctime>
 367 using namespace std;], [
 368   double a = log(ceil(time(NULL)/7.0));
 369   printf("%f %f %f\n", a, sqrt(a), exp(fabs(a - 12345.6)));
 370   ], [AC_MSG_RESULT([no])], [
 371     LIBS="-lm $LIBS"
 372     AC_TRY_LINK([#include <cmath>
 373 #include <cstdio>
 374 #include <ctime>
 375 using namespace std;], [
 376   double a = log(ceil(time(NULL)/7.0));
 377   printf("%f %f %f\n", a, sqrt(a), exp(fabs(a - 12345.6)));],
 378         [AC_MSG_RESULT([yes])],
 379         [AC_MSG_ERROR([Failed to link a C++ program using <cmath>])
 380     ])
 381 ])
 382
 383 dnl C++11 should have log2(double), but keep this check for now to allow for
 384 dnl compilers with incomplete library support for C++11.
 385 AC_CHECK_DECLS([log2(double)], [], [],
 386 [#include <cmath>
 387 using namespace std;])
 388
 389 dnl exp10() is a GNU libc extension.
 390 AC_CHECK_DECLS([exp10(double)], [], [],
 391 [#include <cmath>
 392 using namespace std;])
 393
 394 dnl Darwin provides __exp10().
 395 AC_CHECK_DECLS([__exp10(double)], [], [],
 396 [#include <cmath>
 397 using namespace std;])
 398
 399 dnl GCC provides __builtin_exp10() (but notably clang doesn't currently).
 400 dnl On mingw, __builtin_exp10() causes GCC to generate a call to exp10() which
 401 dnl then fails to link, so perform a link check here to catch that.
 402 AC_CACHE_CHECK([for __builtin_exp10], ac_cv_link___builtin_exp10, [
 403   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 404 #include <cstdio>
 405 #include <ctime>
 406 using namespace std;]],
 407     [[printf("%f", __builtin_exp10(double(time(NULL)*1e-8)));]])],
 408     [ac_cv_link___builtin_exp10=yes],
 409     [ac_cv_link___builtin_exp10=no])
 410 ])
 411 if test $ac_cv_link___builtin_exp10 = yes ; then
 412   AC_DEFINE([HAVE___BUILTIN_EXP10], [1], [Define to 1 if you have the `__builtin_exp10' function.])
 413 fi
 414
 415 dnl See if <typeinfo> can be used in the testsuite - at least for GCC and xlC,
 416 dnl compilation of the test code below fails if RTTI isn't being generated
 417 dnl (g++ -fno-rtti, or by default with xlC).
 418 AC_MSG_CHECKING([if RTTI is supported])
 419 save_CXXFLAGS=$CXXFLAGS
 420 dnl xlC issues a warning for typeid() being used without RTTI being enabled,
 421 dnl so for this test we pass the xlC option to make that warning into an error.
 422 XAPIAN_TEST_CXXFLAGS([-qhaltonmsg=1540-2412], [CXXFLAGS])
 423 AC_TRY_COMPILE([
 424 #include <exception>
 425 #include <typeinfo>],
 426         [
 427         int f();
 428         try {
 429             return f();
 430         } catch (std::exception & e) {
 431             return typeid(e).name()[0];
 432         }],
 433     AC_MSG_RESULT([yes])
 434     AC_DEFINE([USE_RTTI], [1], [Define if the testsuite can use RTTI]),
 435     AC_MSG_RESULT([no]))
 436 CXXFLAGS=$save_CXXFLAGS
 437
 438 AC_CHECK_DECLS([__builtin_bswap16, __builtin_bswap32], [], [], [ ])
 439 AC_CHECK_DECLS([__builtin_clz, __builtin_clzl, __builtin_clzll], [], [], [ ])
 440 AC_CHECK_DECLS([__builtin_ctz, __builtin_ctzl, __builtin_ctzll], [], [], [ ])
 441 AC_CHECK_DECLS([__builtin_expect], [], [], [ ])
 442 AC_CHECK_DECLS([__builtin_popcount, __builtin_popcountl, __builtin_popcountll], [], [], [ ])
 443 AC_CHECK_DECLS([__popcnt, __popcnt64], [], [], [#include <intrin.h>])
 444
 445 dnl Check for time functions.
 446 AC_CHECK_FUNCS([clock_gettime sleep nanosleep gettimeofday ftime])
 447
 448 case $host_os in
 449   *mingw*)
 450     dnl For _ftime64() on mingw we need to tell it we're happy to require
 451     dnl MSVCRT 6.10 or higher, which isn't too onerous a requirement it seems.
 452     AC_DEFINE([__MSVCRT_VERSION__], [0x0601], [Define on mingw to the minimum msvcrt version to assume])
 453     AC_DEFINE([MINGW_HAS_SECURE_API], [1], [Define on mingw to get _s suffixed "secure" functions declared in headers])
 454     ;;
 455 esac
 456
 457 dnl We use timer_create() if available to implement a search time limit.
 458 SAVE_LIBS=$LIBS
 459 AC_SEARCH_LIBS([timer_create], [rt],
 460                [
 461     AC_MSG_CHECKING([for timer_create() usability])
 462     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 463 [[#if defined _AIX || defined __GNU__
 464 #error timer_create known not to work
 465 #endif]])],
 466         [AC_MSG_RESULT([yes])
 467         XAPIAN_LIBS="$LIBS $XAPIAN_LIBS"
 468         AC_DEFINE([HAVE_TIMER_CREATE], [1], [Define to 1 if you have the 'timer_create' function.])]
 469         ,
 470         [AC_MSG_RESULT([no])
 471     ])
 472 ])
 473 LIBS=$SAVE_LIBS
 474
 475 dnl Used by tests/soaktest/soaktest.cc
 476 AC_CHECK_FUNCS([srandom random])
 477
 478 dnl Used by tests/harness/testsuite.cc
 479 AC_CHECK_FUNCS([sigaction])
 480 AC_MSG_CHECKING([for sigsetjmp and siglongjmp])
 481 AC_TRY_COMPILE([#include <setjmp.h>],
 482   [sigjmp_buf jb; if (sigsetjmp(jb, 1)) { siglongjmp(jb, 1);  }],
 483   AC_DEFINE([HAVE_SIGSETJMP], [1], [Define to 1 if you have the 'sigsetjmp' function])
 484   AC_MSG_RESULT([yes]),
 485   AC_MSG_RESULT([no]))
 486
 487 dnl Used by tests/harness/cputimer.cc:
 488 AC_CHECK_FUNCS([getrusage times sysconf])
 489
 490 dnl Used by tests/harness/unixcmd.cc
 491 AC_CHECK_FUNCS([nftw])
 492
 493 dnl Used by tests/api_replicate.cc.
 494 dnl
 495 dnl Solaris < 10 only has putenv().
 496 dnl
 497 dnl Microsoft have marked putenv() as deprecated, so we use _putenv_s() under
 498 dnl MSVC to avoid deprecation warnings.  We probe here since mingw doesn't
 499 dnl currently (v3.20) provide _putenv_s(), so we can't just use it conditional
 500 dnl on __WIN32__ being defined.  We need to check for a declaration rather
 501 dnl than just seeing if the symbol exists, as the symbol will exist in the C
 502 dnl runtime DLL even if mingw doesn't declare it in its headers.
 503 AC_CHECK_FUNCS([setenv])
 504 AC_CHECK_DECLS([_putenv_s(const char *,const char *)], [], [],
 505 [#include <stdlib.h>])
 506
 507 dnl See if we have closefrom(), or some functions that are useful to implement
 508 dnl closefrom() on platforms which don't provide it.
 509 AC_CHECK_FUNCS([closefrom getdirentries getrlimit])
 510
 511 dnl See if ftime returns void (as it does on mingw)
 512 AC_MSG_CHECKING([return type of ftime])
 513 if test $ac_cv_func_ftime = yes ; then
 514   AC_TRY_COMPILE([#include <sys/timeb.h>],
 515     [struct timeb tp; int i = ftime(&tp);],
 516     AC_MSG_RESULT([int]),
 517     AC_MSG_RESULT([void])
 518     AC_DEFINE([FTIME_RETURNS_VOID], [1], [Define if ftime returns void]))
 519 fi
 520
 521 dnl Check how to find the hostname: uname() in sys/utsname.h, or gethostname()
 522 dnl Don't use default includes as inttypes.h is found by Compaq C but not C++
 523 dnl so it causes all header probes to fail.
 524 AC_CHECK_HEADERS([sys/utsname.h], [], [], [ ])
 525 AC_CHECK_FUNCS([gethostname])
 526
 527 dnl mingw (for instance) lacks ssize_t
 528 AC_TYPE_SSIZE_T
 529
 530 AC_TYPE_PID_T
 531
 532 AC_TYPE_MODE_T
 533
 534 AC_CHECK_SIZEOF([short])
 535 AC_CHECK_SIZEOF([int])
 536 AC_CHECK_SIZEOF([long])
 537 AC_CHECK_SIZEOF([long long])
 538
 539 AC_CHECK_HEADERS([sys/types.h])
 540
 541 AC_MSG_CHECKING([for 32 bit integer type])
 542 case 4 in
 543     "$ac_cv_sizeof_int")   INT32_T=int ;;
 544     "$ac_cv_sizeof_long")  INT32_T=long ;;
 545     "$ac_cv_sizeof_short") INT32_T=short ;;
 546     *)
 547       AC_MSG_RESULT([none found])
 548       AC_MSG_ERROR([No 32 bit integer type found])
 549 esac
 550 AC_MSG_RESULT([$INT32_T])
 551
 552 AC_MSG_CHECKING([for 64 bit integer type])
 553 case 8 in
 554     "$ac_cv_sizeof_int")       INT64_T=int ;;
 555     "$ac_cv_sizeof_long")      INT64_T=long ;;
 556     "$ac_cv_sizeof_long_long") INT64_T='long long' ;;
 557     *)
 558       AC_MSG_RESULT([none found])
 559       AC_MSG_ERROR([No 64 bit integer type found])
 560 esac
 561 AC_MSG_RESULT([$INT64_T])
 562
 563 dnl Check for perl (needed to generate some sources and documentation).
 564 AC_PATH_PROG([PERL], [perl], [])
 565 if test x$USE_MAINTAINER_MODE = xyes; then
 566   test -z "$PERL" && AC_MSG_ERROR([perl is required in maintainer mode])
 567 fi
 568
 569 AC_ARG_ENABLE([64bit_docid],
 570   [AS_HELP_STRING([--enable-64bit-docid], [enable 64bit docid [default=no]])],
 571   [case ${enableval} in
 572     yes|no) ;;
 573   *) AC_MSG_ERROR([bad value ${enableval} for --enable-64bit-docid]) ;;
 574   esac],
 575   [enable_64bit_docid=no])
 576
 577 AC_ARG_ENABLE([64bit_termcount],
 578   [AS_HELP_STRING([--enable-64bit-termcount], [enable 64bit termcount [default=no]])],
 579   [case ${enableval} in
 580     yes|no) ;;
 581   *) AC_MSG_ERROR([bad value ${enableval} for --enable-64bit-termcount]) ;;
 582   esac],
 583   [enable_64bit_termcount=no])
 584
 585 AC_ARG_ENABLE([documentation],
 586   [AS_HELP_STRING([--enable-documentation], [enable make rules to rebuild documentation [default=maintainer-mode]])],
 587   [case ${enableval} in
 588     yes|no) ;;
 589     *) AC_MSG_ERROR([bad value ${enableval} for --enable-documentation]) ;;
 590   esac],
 591   [enable_documentation=$USE_MAINTAINER_MODE])
 592 AM_CONDITIONAL([DOCUMENTATION_RULES], [test x"$enable_documentation" = xyes])
 593 AM_CONDITIONAL([MAINTAINER_NO_DOCS], [test x"$USE_MAINTAINER_MODE$enable_documentation" = xyesno])
 594
 595 if test x"$enable_documentation" = xyes ; then
 596   dnl Checks for dot.  (Diagrams in the documentation)
 597   AC_PATH_PROG([DOT], [dot])
 598   test -z "$DOT" && AC_MSG_ERROR([dot (part of the graphviz package) is required to build documentation])
 599   DOXYGEN_DOT_PATH=`echo "$DOT" | sed 's!/dot$!!'`
 600   AC_SUBST([DOXYGEN_DOT_PATH])
 601
 602   dnl Check for doxygen. (Needed to make some more of the documentation)
 603   AC_PATH_PROG([DOXYGEN], [doxygen], [])
 604   test -z "$DOXYGEN" && AC_MSG_ERROR([doxygen is required to build documentation])
 605
 606   dnl Check for help2man. (Needed to make man pages from "--help" output).
 607   AC_PATH_PROG([HELP2MAN], [help2man], [])
 608   test -z "$HELP2MAN" && AC_MSG_ERROR([help2man is required to build documentation])
 609
 610   dnl Check for rst2html. (Needed to make HTML from reStructuredText format)
 611   dnl Also look for rst2html.py, which archlinux reportedly installs it as.
 612   AC_PATH_PROGS([RST2HTML], [rst2html rst2html.py], [])
 613   test -z "$RST2HTML" && AC_MSG_ERROR([rst2html is required to build documentation (try package python-docutils)])
 614
 615   dnl Check for pngcrush, which we optionally use to reduce the size of the
 616   dnl PNG files which doxygen generates.  We can get by without it, so don't
 617   dnl fail here if it's not found.
 618   AC_PATH_PROG([PNGCRUSH], [pngcrush], [])
 619 fi
 620
 621 dnl Checks for header files.
 622 AC_CHECK_HEADERS([fcntl.h limits.h sys/errno.h sys/select.h sys/uio.h], [], [], [ ])
 623 AC_CHECK_HEADERS([sys/resource.h],
 624                  [], [], [#include <sys/types.h>])
 625
 626 dnl cxxabi.h was added in GCC 3.1, but clang lies and defines __GNUC__ yet
 627 dnl doesn't seem to reliably provide this header, so probe for it.
 628 AC_CHECK_HEADERS([cxxabi.h], [], [], [ ])
 629
 630 dnl If valgrind is installed and new enough, we use it for leak checking in the
 631 dnl testsuite.  If VALGRIND is set to an empty value, then skip the check and
 632 dnl don't use valgrind.
 633 if test -n "${VALGRIND-unset}" ; then
 634   AC_PATH_PROG([VALGRIND], [valgrind], [])
 635   if test -n "$VALGRIND" ; then
 636     dnl Check that the installed valgrind version works, and supports the
 637     dnl options we use.  This means we won't try to use valgrind < 3.3.0
 638     dnl (released 7/12/2007) since before that --log-file didn't expand
 639     dnl %p (and appended the process id).
 640     dnl
 641     dnl No need to check for VALGRIND_COUNT_LEAKS now - that was added before
 642     dnl 2.0.0.
 643     AC_MSG_CHECKING([if valgrind supports --log-file with %p and --child-silent-after-fork=yes])
 644     vglog=config.vglog.%p.tmp
 645     vglogwild="config.vglog.*.tmp*"
 646     rm -f $vglogwild
 647     if $VALGRIND --log-file="$vglog" --child-silent-after-fork=yes -q true 2>&AS_MESSAGE_LOG_FD ; then
 648       for f in $vglogwild ; do
 649         case $f in
 650         $vglog*) VALGRIND= ;;
 651         esac
 652       done
 653       if test x"$VALGRIND" = x ; then
 654         AC_MSG_RESULT([no])
 655       else
 656         AC_MSG_RESULT([yes])
 657         AC_CHECK_HEADERS([valgrind/memcheck.h], [], [VALGRIND=], [ ])
 658       fi
 659     else
 660       dnl The valgrind detected doesn't seem to work!  Perhaps this is an
 661       dnl x86_64 box with a 32 bit valgrind.
 662       AC_MSG_RESULT([$VALGRIND doesn't work])
 663       VALGRIND=
 664     fi
 665     rm -f $vglogwild
 666   fi
 667 fi
 668
 669 if test -n "$VALGRIND" ; then
 670   AC_DEFINE([HAVE_VALGRIND], [1], [Define if a suitable valgrind is installed])
 671 fi
 672
 673 dnl If eatmydata is installed, we run the testsuite under it to speed it up.
 674 dnl If EATMYDATA is set to an empty value, then skip this check and don't use
 675 dnl eatmydata.
 676 if test -n "${EATMYDATA-unset}" ; then
 677   AC_PATH_PROG([EATMYDATA], [eatmydata], [])
 678 fi
 679
 680 dnl Checks for library functions.
 681 AC_FUNC_MEMCMP
 682 AC_FUNC_STRERROR_R
 683
 684 AC_CACHE_CHECK([for sys_errlist and sys_nerr], ac_cv_sys_errlist_and_sys_nerr, [
 685   AC_LINK_IFELSE([AC_LANG_PROGRAM(
 686 dnl On Linux, sys_errlist and sys_nerr need <stdio.h>, though the man page
 687 dnl says <errno.h>.  The man page seems to match other platforms such as
 688 dnl NetBSD, so include both headers to ensure we get them.
 689 [[#include <errno.h>
 690 #include <stdio.h>]],
 691 [[  printf("%s", sys_errlist[sys_nerr - 1]);]])],
 692   [ ac_cv_sys_errlist_and_sys_nerr=yes ],
 693   [ ac_cv_sys_errlist_and_sys_nerr=no ])
 694 ])
 695 if test "x$ac_cv_sys_errlist_and_sys_nerr" = "xyes" ; then
 696   AC_DEFINE([HAVE_SYS_ERRLIST_AND_SYS_NERR], [1],[Define if you have 'sys_errlist' and 'sys_nerr'])
 697 fi
 698
 699 AC_CACHE_CHECK([for _sys_errlist and _sys_nerr], ac_cv__sys_errlist_and__sys_nerr, [
 700   AC_LINK_IFELSE([AC_LANG_PROGRAM(
 701 [[#include <errno.h>
 702 #include <stdio.h>]],
 703 [[  printf("%s", _sys_errlist[_sys_nerr - 1]);]])],
 704   [ ac_cv__sys_errlist_and__sys_nerr=yes ],
 705   [ ac_cv__sys_errlist_and__sys_nerr=no
 706   ])
 707 ])
 708 if test "x$ac_cv__sys_errlist_and__sys_nerr" = "xyes" ; then
 709   AC_DEFINE([HAVE__SYS_ERRLIST_AND__SYS_NERR], [1],[Define if you have '_sys_errlist' and '_sys_nerr'])
 710 fi
 711
 712 dnl Check that snprintf actually works as it's meant to.
 713 dnl
 714 dnl Linux 'man snprintf' warns:
 715 dnl  Linux libc4.[45] does not have a snprintf, but provides a libbsd that
 716 dnl  contains an snprintf equivalent to sprintf, i.e., one that ignores the
 717 dnl  size argument.  Thus, the use of snprintf with early libc4 leads to
 718 dnl  serious security problems.
 719 dnl
 720 dnl It also warns that glibc < 2.0.6 (and presumably other pre-C99
 721 dnl implementations) return -1 when truncating so check that we get the
 722 dnl ISO C99 semantics for the returned length when truncating.  If we
 723 dnl have a working snprintf but with non-ISO return semantics, handle
 724 dnl that case separately as it may still be useful in many cases.
 725 dnl
 726 dnl mingw has _snprintf so check for that too.
 727 AC_MSG_CHECKING([for working ISO C99 conforming snprintf])
 728 ac_cv_func_snprintf_noniso=no
 729 for func in snprintf _snprintf ; do
 730   AC_RUN_IFELSE([
 731     AC_LANG_PROGRAM(
 732       [[
 733 #include <cstdio>
 734 #include <cstring>
 735 using namespace std;
 736       ]],
 737       dnl Return different exit status for each error so we can see which
 738       dnl check failed by consulting config.log.
 739       [[
 740         char buffer[4] = "abc";
 741         int res1 = $func(buffer, 2, "%s", "XYZ");
 742         if (memcmp(buffer, "X\0c", 4) != 0) return 2;
 743         int res2 = $func(buffer, 2, "%x", 0x12);
 744         if (memcmp(buffer, "1\0c", 4) != 0) return 3;
 745         if (res1 == -1 && res2 == -1) return 15; /* Pre-ISO semantics. */
 746         if (res1 != 3) return 4;
 747         if (res2 != 2) return 5;
 748       ]]
 749     )],
 750     [ac_cv_func_snprintf=$func;break],
 751     [
 752     if test 15no = "$?$ac_cv_func_snprintf_noniso" ; then
 753       ac_cv_func_snprintf_noniso=$func
 754     fi
 755     ac_cv_func_snprintf=no
 756     ],
 757     [ac_cv_func_snprintf=unknown;break]
 758   )
 759 done
 760 AC_MSG_RESULT([$ac_cv_func_snprintf])
 761 case $ac_cv_func_snprintf in
 762   no)
 763     AC_MSG_CHECKING([for working non-ISO C99 conforming snprintf])
 764     AC_MSG_RESULT([$ac_cv_func_snprintf_noniso])
 765     if test no != "$ac_cv_func_snprintf_noniso" ; then
 766       AC_DEFINE_UNQUOTED([SNPRINTF], [$ac_cv_func_snprintf_noniso],
 767         [Define to the name of a function implementing snprintf but not caring about ISO C99 return value semantics (if one exists)])
 768     fi
 769     ;;
 770   unknown)
 771     dnl be conservative when crosscompiling
 772     ;;
 773   *)
 774     AC_DEFINE_UNQUOTED([SNPRINTF_ISO], [$ac_cv_func_snprintf],
 775        [Define to the name of a function implementing snprintf with ISO C99 semantics (if one exists)])
 776     AC_DEFINE_UNQUOTED([SNPRINTF], [$ac_cv_func_snprintf],
 777        [Define to the name of a function implementing snprintf but not caring about ISO C99 return value semantics (if one exists)])
 778     ;;
 779 esac
 780
 781 dnl ***************************
 782 dnl * Select modules to build *
 783 dnl ***************************
 784
 785 dnl Check if a non-GPL library build is specified.
 786
 787 enable_gpl_libxapian=yes
 788 AC_ARG_ENABLE([gpl-libxapian],
 789   [AS_HELP_STRING([--disable-gpl-libxapian], [disable use of GPL code in libxapian])],
 790   [case ${enableval} in
 791     yes) ;;
 792     no)
 793       AC_DEFINE([DISABLE_GPL_LIBXAPIAN], 1, [Define to error out if we try to include GPL code in libxapian])
 794       ;;
 795     *) AC_MSG_ERROR([bad value ${enableval} for --disable-gpl-libxapian]) ;;
 796   esac])
 797
 798 dnl Check which database backends should be built.
 799
 800 AC_DEFUN([_XAPIAN_BACKEND_ENABLE],
 801   [AC_ARG_ENABLE([backend_$1],
 802     [AS_HELP_STRING([--enable-backend-$1], [build the $1 database backend [default=$3]])],
 803     [case $enableval in
 804       yes|no) ;;
 805       *) AC_MSG_ERROR([Invalid option: '--enable-backend-$1=$enableval']) ;;
 806     esac], [enable_backend_$1=$2])
 807   ])
 808
 809 AC_DEFUN([XAPIAN_BACKEND_ENABLE],
 810   [_XAPIAN_BACKEND_ENABLE([$1],
 811     m4_default([$2], [yes]),
 812     m4_default([$3], [yes]))
 813   ])
 814
 815 dnl When adding a new backend, update INSTALL too.
 816 XAPIAN_BACKEND_ENABLE([glass], [$enable_gpl_libxapian], [yes (unless --disable-gpl-libxapian)])
 817 XAPIAN_BACKEND_ENABLE([honey])
 818 XAPIAN_BACKEND_ENABLE([inmemory], [$enable_gpl_libxapian], [yes (unless --disable-gpl-libxapian)])
 819 default_enable_backend_remote=$enable_gpl_libxapian
 820 case $host_os in
 821   *djgpp* | *msdos* )
 822     dnl We don't currently support the remote backend on this platform so
 823     dnl disable it by default.
 824     default_enable_backend_remote=no
 825     ;;
 826 esac
 827 XAPIAN_BACKEND_ENABLE([remote], [$default_enable_backend_remote], [yes (except for MSDOS; unless --disable-gpl-libxapian)])
 828
 829 use_proc_for_uuid=0
 830 use_win32_uuid_api=0
 831 win32_need_lws2_32=0
 832 case $enable_backend_glass$enable_backend_honey in
 833 *yes*)
 834   dnl We use zlib for compressing tags in glass and honey.  We could
 835   dnl automatically disable support if zlib isn't found, but overall that
 836   dnl probably does more harm than good - it's most likely that someone just
 837   dnl forgot to install the -dev package for zlib.
 838   dnl
 839   dnl Similarly for uuid support.
 840
 841   dnl Check for zlib.h.
 842   AC_CHECK_HEADERS([zlib.h], [], [
 843     AC_MSG_ERROR([zlib.h not found - required for glass (you may need to install the zlib1g-dev or zlib-devel package)])
 844     ], [ ])
 845
 846   dnl Check for zlibVersion in -lz.
 847   SAVE_LIBS=$LIBS
 848   dnl mingw build needs -lzlib or -lzdll.
 849   AC_SEARCH_LIBS([zlibVersion], [z zlib zdll], [], [
 850     AC_MSG_ERROR([zlibVersion() not found in -lz, -lzlib, or -lzdll - required for glass (you may need to install the zlib1g-dev or zlib-devel package)])
 851     ])
 852   if test x != x"$LIBS" ; then
 853     XAPIAN_LIBS="$XAPIAN_LIBS $LIBS"
 854   fi
 855   LIBS=$SAVE_LIBS
 856
 857   dnl Find the UUID library (from e2fsprogs/util-linux-ng, not the OSSP one).
 858
 859   case $host_os-$win32 in
 860     *-yes | *cygwin*) dnl Use built-in win32 API.
 861       use_win32_uuid_api=1
 862       AC_DEFINE([USE_WIN32_UUID_API], [1],
 863                 [Define to 1 to use UuidCreate(), etc])
 864       if test $win32 = yes ; then
 865         dnl We need -lws2_32 for htonl(), etc, but not for Cygwin which
 866         dnl provides these functions in its libc.
 867         win32_need_lws2_32=1
 868       fi
 869       XAPIAN_LIBS="$XAPIAN_LIBS -lrpcrt4"
 870       ;;
 871     *)
 872       dnl Check for uuid/uuid.h (e2fsprogs/util-linux-ng) or uuid.h
 873       dnl (FreeBSD/NetBSD).
 874       AC_CHECK_HEADERS([uuid/uuid.h], [
 875         dnl util-linux-ng's uuid/uuid.h found - check for uuid_generate in
 876         dnl -luuid.
 877         SAVE_LIBS=$LIBS
 878         AC_SEARCH_LIBS([uuid_generate], [uuid], [], [
 879           AC_MSG_ERROR([uuid_generate() not found in -luuid - required for glass and honey backends (you may need to install the uuid-dev, libuuid-devel or e2fsprogs-devel package)])
 880           ])
 881         if test x != x"$LIBS" ; then
 882           XAPIAN_LIBS="$XAPIAN_LIBS $LIBS"
 883         fi
 884       ], [
 885         dnl Try uuid.h as found on FreeBSD/NetBSD, with associated code in libc.
 886         AC_CHECK_HEADERS([uuid.h], [
 887           dnl Check for uuid_create with no extra libraries required.
 888           AC_CHECK_FUNC([uuid_create], [], [
 889             AC_MSG_ERROR([uuid.h found, but uuid_create() not found.  You probably wants to install libuuid from util-linux-ng or e2fsprogs (you may need to install the uuid-dev, libuuid-devel or e2fsprogs-devel package)])
 890           ])
 891         ], [
 892           dnl Especially useful for Android.
 893           AC_MSG_CHECKING([if host platform supports /proc/sys/kernel/random/uuid])
 894           case $host_os in
 895             linux*)
 896               use_proc_for_uuid=1
 897               AC_DEFINE([USE_PROC_FOR_UUID], [1],
 898                         [Define to 1 to read UUID from '/proc/sys/kernel/random/uuid'])
 899               AC_MSG_RESULT([yes])
 900               ;;
 901             *)
 902               AC_MSG_RESULT([no])
 903               AC_MSG_ERROR([Failed to find a way to generate UUIDs, required for glass and honey backends (you may need to install the uuid-dev, libuuid-devel or e2fsprogs-devel package)])
 904               ;;
 905           esac
 906         ], [ ])
 907       ], [ ])
 908       ;;
 909   esac
 910
 911   dnl Older versions of libuuid (such as that on CentOS 4.7) don't have
 912   dnl uuid_unparse_lower(), only uuid_unparse().
 913   AC_LINK_IFELSE([AC_LANG_CALL([], [uuid_unparse_lower])],
 914     [
 915     AC_DEFINE([HAVE_UUID_UNPARSE_LOWER], [1],
 916               [Define to 1 if you have the 'uuid_unparse_lower' function.])
 917     ])
 918   LIBS=$SAVE_LIBS
 919
 920   case $host_os in
 921     *djgpp* | *msdos* )
 922       dnl DJGPP has a dummy implementation of fork which always fails.
 923       dnl
 924       dnl For disk-based backends, use flock() for locking, which doesn't need
 925       dnl fork() or socketpair().
 926       AC_DEFINE([FLINTLOCK_USE_FLOCK], 1, [Define to use flock() for flint-compatible locking])
 927       ;;
 928   esac
 929   ;;
 930 esac
 931 AM_CONDITIONAL([USE_PROC_FOR_UUID], [test "$use_proc_for_uuid" = 1])
 932 AM_CONDITIONAL([USE_WIN32_UUID_API], [test "$use_win32_uuid_api" = 1])
 933
 934 if test "$enable_backend_remote" = yes ; then
 935   case $host_os-$win32 in
 936     *-yes )
 937       dnl For mingw and msvc we have an alternative implementation which
 938       dnl doesn't need fork() or socketpair().
 939       dnl
 940       dnl We need -lws2_32 for getaddrinfo(), etc.
 941       win32_need_lws2_32=1
 942       dnl Vista is needed for the AI_ADDRCONFIG flag to getaddrinfo().
 943       AC_DEFINE([WINVER], [0x600],
 944                 [Version of Windows to assume (0x600 => Vista).])
 945       AC_DEFINE([_WIN32_WINNT], [WINVER],
 946                 [Version of Windows to assume.])
 947       ;;
 948     *djgpp* | *msdos* )
 949       dnl DJGPP has a dummy implementation of fork which always fails.  If
 950       dnl someone actually wanted remote backend support, then DJGPP has a
 951       dnl pthreads port, so using threads like we do on Windows would make more
 952       dnl sense.
 953       AC_MSG_ERROR([The remote backend is not currently supported on this platform.])
 954       ;;
 955     *)
 956       dnl On Unix, we need fork and socketpair for the remotebackend.
 957       SAVE_LIBS=$LIBS
 958       AC_CHECK_FUNCS([fork], [], [
 959         AC_MSG_ERROR([fork() required for the remote backend - if an extra library is needed, pass LIBS=-lfoo to configure.  Or --disable-backend-remote to disable it.)])
 960       ])
 961       dnl Check if -lsocket is required for socketpair (Solaris needs it).
 962       dnl And on Haiku it's in -lnetwork.
 963       AC_SEARCH_LIBS([socketpair], [socket network], [], [
 964         AC_MSG_ERROR([socketpair() required for the remote backend - if an extra library is needed, pass LIBS=-lfoo to configure.  Or --disable-backend-remote to disable it.)])
 965       ])
 966       AC_DEFINE([HAVE_SOCKETPAIR], [1],
 967                 [Define to 1 if you have the 'socketpair' function.])
 968       dnl Check if extra libraries are needed for getaddrinfo or inet_ntop()
 969       dnl (e.g. on Solaris).
 970       dnl
 971       dnl We're currently assuming that any system that is worth trying to
 972       dnl support has getaddrinfo() and inet_ntop(), since these are the
 973       dnl standard route for supporting IPv6, and that's pretty much essential
 974       dnl for platforms to support now.
 975       AC_SEARCH_LIBS([getaddrinfo], [nsl socket], [], [
 976         AC_MSG_ERROR([getaddrinfo() required for the remote backend - if an extra library is needed, pass LIBS=-lfoo to configure.  Or --disable-backend-remote to disable it.)])
 977       ])
 978       AC_SEARCH_LIBS([inet_ntop], [nsl socket], [], [
 979         AC_MSG_ERROR([inet_ntop() required for the remote backend - if an extra library is needed, pass LIBS=-lfoo to configure.  Or --disable-backend-remote to disable it.)])
 980       ])
 981       XAPIAN_LIBS="$XAPIAN_LIBS $LIBS"
 982       LIBS=$SAVE_LIBS
 983       ;;
 984   esac
 985
 986   TYPE_SOCKLEN_T
 987 fi
 988
 989 if test "$win32_need_lws2_32" = 1 ; then
 990   XAPIAN_LIBS="$XAPIAN_LIBS -lws2_32"
 991 fi
 992
 993 AC_ARG_ENABLE([visibility],
 994   [AS_HELP_STRING([--disable-visibility], [disable use of GCC visibility])],
 995   [case ${enableval} in
 996     yes|no) ;;
 997     *) AC_MSG_ERROR([bad value ${enableval} for --disable-visibility]) ;;
 998   esac])
 999
1000 vpath_build=no
1001 if test "`pwd`" != "`cd $srcdir;pwd`" ; then
1002   vpath_build=yes
1003 fi
1004 AM_CONDITIONAL([VPATH_BUILD], [test yes = "$vpath_build"])
1005
1006 dnl Turn off compilation of anything that we don't have the requirements for
1007
1008 dnl Set conditionals to specify what we compile
1009
1010 AM_CONDITIONAL([BUILD_BACKEND_GLASS], [test yes = "$enable_backend_glass"])
1011 AM_CONDITIONAL([BUILD_BACKEND_HONEY], [test yes = "$enable_backend_honey"])
1012 AM_CONDITIONAL([BUILD_BACKEND_INMEMORY], [test yes = "$enable_backend_inmemory"])
1013 AM_CONDITIONAL([BUILD_BACKEND_REMOTE], [test yes = "$enable_backend_remote"])
1014 AM_CONDITIONAL([BUILD_BACKEND_TOOLS],
1015   [test nono != "$enable_backend_glass$enable_backend_honey"])
1016
1017 dnl Decide if we should use the zlib-vg.so LD_PRELOAD hack.
1018 use_zlib_vg=no
1019 if test -n "$VALGRIND" ; then
1020   case $host_os in
1021     linux*) use_zlib_vg=yes ;;
1022   esac
1023 fi
1024 AM_CONDITIONAL([USE_ZLIB_VG], [test yes = "$use_zlib_vg"])
1025
1026 dnl See if we have fdatasync, and what libraries are needed for it.
1027 dnl We need to actually check for a declaration as OS X has a dummy
1028 dnl implementation in the library which is not prototyped in any header.
1029 AC_CHECK_DECL([fdatasync(int)], [
1030   SAVE_LIBS=$LIBS
1031   AC_SEARCH_LIBS([fdatasync], [rt], [XAPIAN_LIBS="$LIBS $XAPIAN_LIBS"])
1032   LIBS=$SAVE_LIBS
1033   AC_CHECK_FUNCS([fdatasync])
1034   ],
1035   [ac_cv_func_fdatasync=no],
1036   [#include <unistd.h>]
1037 )
1038
1039 AC_CHECK_FUNCS([fsync writev])
1040 AC_CHECK_FUNCS([posix_fadvise])
1041 if test "$win32" = no ; then
1042   dnl ftruncate() under Wine seems to be buggy and sometimes fails, though
1043   dnl a cut-down reproducer seems fine.  For now just avoid ftruncate()
1044   dnl entirely on this platform - we'll fallback to lseek() + write() of a
1045   dnl single zero byte, which is pretty efficient.
1046   AC_CHECK_FUNCS([ftruncate])
1047 fi
1048
1049 dnl HP-UX has pread and pwrite, but they don't work!  Apparently this problem
1050 dnl manifests when largefile support is enabled, and we definitely want that
1051 dnl so don't use pread or pwrite on HP-UX.
1052 case $host_os in
1053   hpux*)
1054     AC_MSG_CHECKING([for pread])
1055     AC_MSG_RESULT([present but broken on $host_os])
1056     AC_MSG_CHECKING([for pwrite])
1057     AC_MSG_RESULT([present but broken on $host_os])
1058     ;;
1059   *)
1060     AC_CHECK_FUNC([pread],
1061        [AC_DEFINE([HAVE_PREAD], [1],
1062             [Define if pread is available on this system])
1063         AC_MSG_CHECKING([for any prototype needed for pread])
1064         AC_CACHE_VAL([xo_cv_pread_prototype],
1065           [
1066             for p in ' ' \
1067               'extern "C" ssize_t pread(int, void *, size_t, off_t) throw ();' \
1068               'extern "C" ssize_t pread(int, void *, size_t, off_t);' ; do
1069               AC_TRY_COMPILE([
1070 #include <sys/types.h>
1071 #include <unistd.h>
1072 $p
1073               ],[
1074                 char b[256];
1075                 pread(1, b, 256, 20);
1076               ],[
1077                 xo_cv_pread_prototype="$p"
1078                 break
1079               ])
1080             done
1081             if test -z "$xo_cv_pread_prototype"; then
1082               AC_MSG_RESULT([not found])
1083               AC_MSG_ERROR([Failed to find working prototype for pread])
1084             fi
1085           ])
1086           if test " " = "$xo_cv_pread_prototype" ; then
1087             AC_MSG_RESULT([none required])
1088           else
1089             AC_MSG_RESULT([$xo_cv_pread_prototype])
1090             AC_DEFINE_UNQUOTED([PREAD_PROTOTYPE], [$xo_cv_pread_prototype],
1091                                [explicit prototype needed for pread (if any)])
1092           fi
1093         ])
1094     AC_CHECK_FUNC([pwrite],
1095        [AC_DEFINE([HAVE_PWRITE], [1],
1096             [Define if pwrite is available on this system])
1097         AC_MSG_CHECKING([for any prototype needed for pwrite])
1098         AC_CACHE_VAL([xo_cv_pwrite_prototype],
1099           [
1100             for p in ' ' \
1101               'extern "C" ssize_t pwrite(int, const void *, size_t, off_t) throw ();' \
1102               'extern "C" ssize_t pwrite(int, const void *, size_t, off_t);' ; do
1103               AC_TRY_COMPILE([
1104 #include <sys/types.h>
1105 #include <unistd.h>
1106 $p
1107               ],[
1108                 const char *p = "hello";
1109                 pwrite(1, p, 5, 20);
1110               ],[
1111                 xo_cv_pwrite_prototype="$p"
1112                 break
1113               ])
1114             done
1115             if test -z "$xo_cv_pwrite_prototype"; then
1116               AC_MSG_RESULT([not found])
1117               AC_MSG_ERROR([Failed to find working prototype for pwrite])
1118             fi
1119           ])
1120           if test " " = "$xo_cv_pwrite_prototype" ; then
1121             AC_MSG_RESULT([none required])
1122           else
1123             AC_MSG_RESULT([$xo_cv_pwrite_prototype])
1124             AC_DEFINE_UNQUOTED([PWRITE_PROTOTYPE], [$xo_cv_pwrite_prototype],
1125                                [explicit prototype needed for pwrite (if any)])
1126           fi
1127         ])
1128     ;;
1129 esac
1130
1131 AC_MSG_CHECKING([for directory separator(s)])
1132 case $host_os-$win32 in
1133   *-yes | cygwin* | os2* | *djgpp* | *msdos* )
1134     AC_MSG_RESULT([/ and \\])
1135     AC_DEFINE([DIR_SEPS], ["/\\"], [directory separator(s) as a character or string literal])
1136     AC_DEFINE([DIR_SEPS_LIST], [{ '/', '\\' }], [directory separator(s) as an initialiser list])
1137     ;;
1138   *)
1139     AC_MSG_RESULT([/])
1140     AC_DEFINE([DIR_SEPS], ['/'], [directory separator(s) as a character or string literal])
1141     AC_DEFINE([DIR_SEPS_LIST], [{ '/' }], [directory separator(s) as an initialiser list])
1142     ;;
1143 esac
1144
1145 AC_CHECK_FUNCS([link])
1146
1147 dnl *************************
1148 dnl * Set debugging options *
1149 dnl *************************
1150
1151 dnl Which assertion types to enable in the code.
1152
1153 AC_ARG_ENABLE([assertions],
1154   [AS_HELP_STRING([--enable-assertions], [enable debug assertions (no|partial|yes) [default=no]])],
1155   [case $enableval in
1156     yes|partial|no) ;;
1157     *)
1158       AC_MSG_ERROR([Invalid option: '--enable-assertions=$enableval']) ;;
1159   esac])
1160
1161 AC_ARG_ENABLE([log],
1162   [AS_HELP_STRING([--enable-log], [generate a log of methods called, etc (no|yes|profile) [default=no]])],
1163   [case $enableval in
1164     yes|no) ;;
1165     profile)
1166       AC_MSG_ERROR(['--enable-log=profile' is no longer supported - see https://trac.xapian.org/wiki/ProfilingXapian for alternatives.]) ;;
1167     *)
1168       AC_MSG_ERROR([Invalid option: '--enable-log=$enableval']) ;;
1169   esac])
1170
1171 dnl Set defines according to the --enable-assertions and --enable-log options
1172 dnl given.
1173
1174 if test yes = "$enable_assertions" || test partial = "$enable_assertions" ; then
1175   AC_DEFINE([XAPIAN_ASSERTIONS],,
1176     [Define if you want assertions (causes some slow-down)])
1177 fi
1178
1179 if test yes = "$enable_assertions"; then
1180   AC_DEFINE([XAPIAN_ASSERTIONS_PARANOID],,
1181     [Define if you want paranoid assertions (causes significant slow-down)])
1182 fi
1183
1184 if test yes = "$enable_log"; then
1185   AC_DEFINE([XAPIAN_DEBUG_LOG],,
1186     [Define if you want a log of methods called and other debug messages])
1187 fi
1188
1189 dnl ******************************
1190 dnl * Set special compiler flags *
1191 dnl ******************************
1192
1193 dnl Set flags to control warnings (enable more, or disable annoying ones).
1194 dash_d_visibility=
1195 if test yes = "$GXX"; then
1196   dnl Intel's C++ compiler and clang both lie and define __GNUC__, so check which
1197   dnl we actually have, as neither is really 100% compatible.
1198   case `echo __INTEL_COMPILER __clang__|$CXX -E - 2>&AS_MESSAGE_LOG_FD|grep -v '^#'` in
1199     *__INTEL_COMPILER*__clang__*)
1200       dnl GCC (since neither substituted):
1201
1202       dnl The exact format of g++ --version seems to change with almost every
1203       dnl minor release so use the preprocessor macros which should be more
1204       dnl robust.
1205       AC_MSG_CHECKING([for version of $CXX])
1206       gxx_version=`echo __GNUC__.__GNUC_MINOR__.__GNUC_PATCHLEVEL__|$CXX -E -|sed '/^#/d;s/ //g'`
1207       AC_MSG_RESULT([GCC $gxx_version])
1208
1209       case $gxx_version in
1210       [[0123]].*|4.[[0-7]].*)
1211         AC_MSG_ERROR([Xapian requires GCC 4.8 or later])
1212         ;;
1213       esac
1214
1215       dnl -Wundef was supported by g++ 3.0.
1216       dnl
1217       dnl -Wlogical-op and -Wmissing-declarations (for C++) were added in
1218       dnl GCC 4.3.
1219       dnl
1220       dnl -Wdouble-promotion was added in GCC 4.6.
1221       dnl
1222       dnl -Winit-self was added in GCC 3.4, but for GCC < 4.7 g++ always
1223       dnl warns for this case with -Wuninitialized (implied by -W).  We
1224       dnl don't intend to use this idiom, so any instances are bugs we'd
1225       dnl like to know about.
1226       dnl
1227       dnl All the other options were supported by g++ 2.95.
1228       AM_CXXFLAGS="$AM_CXXFLAGS -Wall -W -Wredundant-decls -Wpointer-arith -Wcast-qual -Wcast-align -Wformat-security -fno-gnu-keywords -Wundef -Woverloaded-virtual -Wstrict-null-sentinel -Wshadow -Wstrict-overflow=1 -Wlogical-op -Wmissing-declarations -Wdouble-promotion -Winit-self"
1229
1230       dnl FIXME:
1231       dnl -Wconversion in older GCC versions is intended to help migration
1232       dnl from K&R to ISO C, and isn't useful for us.  In 4.3 it was renamed
1233       dnl to -Wtraditional-conversion and a new -Wconversion added which
1234       dnl sounds useful but is a bit buggy currently.  So we should consider
1235       dnl enabling -Wconversion once it is stabilised (GCC 4.4 or ...)
1236       dnl
1237       dnl -Wold-style-cast is interesting, but triggers for macros from
1238       dnl system headers (e.g. FD_SET).  GCC 4.8 improved this by making
1239       dnl -ftrack-macro-expansion=2 the default, but we still see such
1240       dnl warnings on some platforms for some reason (e.g. Cygwin with GCC
1241       dnl 5.4.0 warns about FD_SET, and on Debian with GCC 4.9.2 we see
1242       dnl warnings from zlib.h).
1243
1244       dnl Automatically add -Werror if maintainer mode is enabled.
1245       if test x$USE_MAINTAINER_MODE = xyes; then
1246         AM_CXXFLAGS="$AM_CXXFLAGS -Werror"
1247       fi
1248       ;;
1249     *__clang__*)
1250       dnl Intel's compiler (since __clang__ not substituted):
1251       dnl
1252       dnl -w1 stops the avalanche of uninteresting "remark" messages.
1253       dnl -wd... disables warnings which don't have good code workarounds.
1254       AM_CXXFLAGS="$AM_CXXFLAGS -Wall -w1 -wd177,1572"
1255
1256       dnl Automatically add -Werror if maintainer mode is enabled.
1257       if test x$USE_MAINTAINER_MODE = xyes; then
1258         AM_CXXFLAGS="$AM_CXXFLAGS -Werror"
1259       fi
1260       ;;
1261     *__INTEL_COMPILER*)
1262       dnl clang (since __INTEL_COMPILER not substituted):
1263
1264       dnl These options all work at least as far back as clang++ 3.0:
1265       AM_CXXFLAGS="$AM_CXXFLAGS -Wall -W -Wredundant-decls -Wpointer-arith -Wcast-qual -Wcast-align -Wformat-security -fno-gnu-keywords -Wundef -Woverloaded-virtual -Wshadow -Wstrict-overflow=1 -Wmissing-declarations -Winit-self"
1266
1267       dnl Automatically add -Werror if maintainer mode is enabled.
1268       if test x$USE_MAINTAINER_MODE = xyes; then
1269         AM_CXXFLAGS="$AM_CXXFLAGS -Werror"
1270       fi
1271       ;;
1272   esac
1273
1274   if test no != "$enable_visibility"; then
1275     dnl GCC doesn't support symbol visibility on all platforms (e.g. it isn't
1276     dnl supported on mingw and visibility attributes result in warnings).
1277     AC_MSG_CHECKING([if $CXX -fvisibility=hidden -fvisibility-inlines-hidden works])
1278     if echo 'int bar() __attribute__((visibility("default"))); int baz() __attribute__((visibility("internal"))); int bar() { return 6; } int baz() { return 7; } int foo() {return 42;}'|$CXX -Werror -fvisibility=hidden -fvisibility-inlines-hidden -c -oconftest.o -xc++ - >&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
1279       AC_MSG_RESULT([yes])
1280       AM_CXXFLAGS="$AM_CXXFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
1281       dash_d_visibility=-DXAPIAN_ENABLE_VISIBILITY
1282     else
1283       AC_MSG_RESULT([no])
1284     fi
1285   fi
1286 else
1287   dnl Not GCC, nor a compiler masquerading as GCC.
1288   case /$CXX in
1289   */aCC)
1290     dnl +w turns on more warnings.
1291     dnl +wlint turns on "lint-like" warnings.
1292     dnl +W<n1>,<n2>,... suppresses warnings n1, n2, ...
1293     dnl 2340 (remark) "value copied to temporary, reference to temporary
1294     dnl use", in: throw Xapian::UnimplementedError("...");
1295     dnl 2401 "destructor for base class ... is non-virtual" (we don't need a
1296     dnl virtual destructor for intrusive_base, since we never delete
1297     dnl       its subclasses by a intrusive_base *).
1298     dnl 3348 "declaration hides constant ..." which seems to misfire!
1299     dnl 4255 (remark) "padding size of struct "..." with ... bytes to
1300     dnl alignment boundary".
1301     dnl 4273 "floating-point equality and inequality comparisons may be
1302     dnl inappropriate due to roundoff common in floating-point computation"
1303     dnl No obvious workaround for when you really do want == or !=.
1304     dnl 20201 "Memory leak is detected" which triggers for "return new Foo;"!
1305     AM_CXXFLAGS="$AM_CXXFLAGS +w +wlint +W2340,2401,3348,4255,4273,20201" ;;
1306   */sunCC|*/CC)
1307     dnl Sun's C++ compiler warns about functions failing to return a value even
1308     dnl when the function ends with a "throw" statement.  That's just unhelpful
1309     dnl noise, and adding a dummy "return" after "throw" seems a worse solution
1310     dnl than simply disabling this warning - any genuinely missing return
1311     dnl statements will get reported by compilers with superior warning
1312     dnl machinery.
1313     XAPIAN_TEST_CXXFLAGS([-erroff=voidretw], [AM_CXXFLAGS])
1314     ;;
1315   esac
1316 fi
1317
1318 XAPIAN_TEST_LINKER_FLAG([-Bsymbolic-functions], [symbolic_functions],
1319   [XAPIAN_LDFLAGS="$XAPIAN_LDFLAGS $flag"])
1320
1321 FP_EXCESS_PRECISION=no
1322 AC_MSG_CHECKING([whether to use SSE instructions on x86])
1323 case $host_cpu in
1324   i*86)
1325     if test "$enable_sse" = no ; then
1326       AC_MSG_RESULT([no])
1327       FP_EXCESS_PRECISION=yes
1328     else
1329       dnl Default to sse2.
1330       test "$enable_sse" != yes || enable_sse=sse2
1331       if test yes = "$GXX"; then
1332         AC_MSG_RESULT([yes (configure with --disable-sse to disable)])
1333         dnl We can unconditionally use -mtune=generic as it was added in GCC
1334         dnl 4.2, and supported at least as far back as clang 3.0.
1335         AM_CXXFLAGS="$AM_CXXFLAGS -mfpmath=sse -m$enable_sse -mtune=generic"
1336       else
1337         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1338 [[#ifndef __SUNPRO_CC
1339 #error Not Sun compiler
1340 #endif]])],
1341           [AC_MSG_RESULT([yes (configure with --disable-sse to disable)])
1342           AM_CXXFLAGS="$AM_CXXFLAGS -xarch=$enable_sse"]
1343           ,
1344           [AC_MSG_RESULT([don't know how to for compiler $CXX])
1345           FP_EXCESS_PRECISION=yes]
1346         )
1347       fi
1348     fi
1349     ;;
1350   *)
1351     AC_MSG_RESULT([non-x86 arch ($host_cpu)]) ;;
1352 esac
1353 AC_SUBST([FP_EXCESS_PRECISION])
1354
1355 AH_BOTTOM(
1356 [/* Disable stupid MSVC warnings. */
1357 #ifdef _MSC_VER
1358 /* Passing an empty parameter to a single parameter macro. */
1359 # pragma warning(disable:4003)
1360 /* A "performance" warning for converting int to bool. */
1361 # pragma warning(disable:4800)
1362
1363 /* Tell MSVC we want M_PI, etc defined. */
1364 # define _USE_MATH_DEFINES
1365
1366 /* Tell MSVC we don't want max() and min() macros defined. */
1367 # define NOMINMAX
1368 #endif
1369
1370 /* Make the POSIX-like functions support large files.  MSVC needs this;
1371  * current mingw32 does too; mingw64 supports _FILE_OFFSET_BITS, which
1372  * AC_SYS_LARGEFILE should discover and enable automatically.
1373  */
1374 #if defined _MSC_VER || \
1375     (defined __MINGW32__ && !defined _FILE_OFFSET_BITS)
1376
1377 # include <sys/stat.h>
1378 # include <sys/types.h>
1379 # include <io.h>
1380 /* zlib.h uses off_t so we need to include it before we redefine off_t. */
1381 # include <zlib.h>
1382
1383 // MSVC needs to call _stat64() instead of stat() and the struct which holds
1384 // the information is "struct _stat64" instead of "struct stat" so we just
1385 // use #define to replace both in one go.  We also want to use _fstat64()
1386 // instead of fstat() but in this case we can use a function-like macro.
1387 //
1388 // Mingw has _stat64() but unhelpfully for our purposes, it has an extra
1389 // underscore prefix on the struct name ("struct __stat64") so there we
1390 // target _stati64 instead.  This has 64-bit file size but the time_t size
1391 // is switchable.  We don't really care about file timestamps in the
1392 // library, so this should be fine.
1393 //
1394 // This hack is a problem is we ever want a method called "stat", or one called
1395 // fstat which takes 2 parameters, but we can probably live with these
1396 // limitations.
1397
1398 # ifdef stat
1399 #  undef stat
1400 # endif
1401
1402 # ifdef fstat
1403 #  undef fstat
1404 # endif
1405
1406 # ifdef _MSC_VER
1407 #  define stat _stat64
1408 #  define fstat(FD, BUF) _fstat64(FD, BUF)
1409 # else
1410 #  define stat _stati64
1411 #  define fstat(FD, BUF) _fstati64(FD, BUF)
1412 # endif
1413
1414 # ifdef lseek
1415 #  undef lseek
1416 # endif
1417
1418 # ifdef off_t
1419 #  undef off_t
1420 # endif
1421
1422 # define lseek(FD, OFF, WHENCE) _lseeki64(FD, OFF, WHENCE)
1423 /* Redefine via a typedef so C++ code off_t(-1) works - it wouldn't if we did:
1424  * #define off_t long long
1425  */
1426 typedef long long off_t_redefinition_typedef;
1427 # define off_t off_t_redefinition_typedef
1428
1429 #endif
1430
1431 /* MSVC defines _WIN32 but not __WIN32__. */
1432 #if !defined __WIN32__ && defined _WIN32 && !defined _WIN64
1433 # define __WIN32__
1434 #endif
1435
1436 /* _FORTIFY_SOURCE is only supported by GCC >= 4.1 and glibc >= 2.3.4, but it
1437  * shouldn't cause a problem to define it where it's not supported and some
1438  * distros may have backported support, so hardcoding version checks is
1439  * counter-productive.
1440  *
1441  * Check if _FORTIFY_SOURCE is already defined to allow the user to override
1442  * our choice with "./configure CPPFLAGS=-D_FORTIFY_SOURCE=0" or "...=1".
1443  */
1444 #if defined __GNUC__ && !defined _FORTIFY_SOURCE
1445 # define _FORTIFY_SOURCE 2
1446 #endif
1447
1448 /* For compilers which support it (such as GCC, clang, Intel's C++ compiler)
1449  * we can use __builtin_expect to give the compiler hints about branch
1450  * prediction.  See HACKING for how to use these.
1451  */
1452 #if HAVE_DECL___BUILTIN_EXPECT
1453 /* The arguments of __builtin_expect() are both long, so use !! to ensure that
1454  * the first argument is always an integer expression, and always 0 or 1, but
1455  * still has the same truth value for the if or while it is used in.
1456  */
1457 # define rare(COND) __builtin_expect(!!(COND), 0)
1458 # define usual(COND) __builtin_expect(!!(COND), 1)
1459 #else
1460 # define rare(COND) (COND)
1461 # define usual(COND) (COND)
1462 #endif
1463
1464 /* Signal we're building the library so it's OK to include headers such as
1465  * xapian/query.h directly.
1466  */
1467 #define XAPIAN_LIB_BUILD 1
1468
1469 /* With Sun CC 5.13 (Studio 12.4) on Solaris 11.2, <math.h> seems to get
1470  * implicitly included somehow before <cmath>, and compilation fails due
1471  * to 'std::exception' colliding with 'struct exception'.  It's not clear
1472  * how to avoid this, so just define the same magic macro which <cmath> does
1473  * before it includes <math.h>.
1474  */
1475 #ifdef __SUNPRO_CC
1476 # define __MATHERR_RENAME_EXCEPTION
1477 #endif
1478 ])
1479
1480 AC_SUBST([AM_CXXFLAGS])
1481
1482 dnl Restore CXXFLAGS to those the user specified or autoconf defaulted to.
1483 CXXFLAGS=$save_CXXFLAGS
1484
1485 dnl Required for auto regeneration to work in a combined maintainer-mode tree.
1486 : ${AUTOM4TE=autom4te}
1487 AC_SUBST([AUTOM4TE])
1488
1489 dnl Libtool sets this (to yes|no|unknown) and we use it in xapian-config.
1490 AC_SUBST([link_all_deplibs_CXX])
1491
1492 dnl Shared library extension.
1493 module=no
1494 eval "SHLIBEXT=$shrext_cmds"
1495 AC_SUBST([SHLIBEXT])
1496
1497 dnl We want to be able to use GNU make % pattern rules in maintainer targets
1498 dnl but automake warns these aren't portable, so we substitute the % to avoid
1499 dnl this warning.
1500 PERCENT='%'
1501 AC_SUBST([PERCENT])
1502
1503 dnl Split up the version number into "MAJOR.MINOR.REVISION".
1504 MAJOR_VERSION=`echo "$VERSION"|sed 's/\..*//'`
1505 [MINOR_VERSION=`echo "$VERSION"|sed 's/[^.]*\.//;s/\..*//'`]
1506 [REVISION=`echo "$VERSION"|sed 's/.*\.//;s/_.*$//'`]
1507
1508 dnl **************************
1509 dnl * Build the output files *
1510 dnl **************************
1511
1512 AC_CONFIG_FILES([
1513  Makefile
1514  tests/Makefile
1515  docs/Makefile
1516  docs/doxygen_api.conf
1517  docs/doxygen_source.conf
1518  xapian-core.spec
1519  cmake/xapian-config.cmake
1520  cmake/xapian-config-version.cmake
1521  pkgconfig/xapian-core"$LIBRARY_VERSION_SUFFIX".pc:pkgconfig/xapian-core.pc.in
1522  ])
1523 AC_CONFIG_FILES([tests/runtest], [chmod +x tests/runtest])
1524 AC_CONFIG_FILES([tests/runsrv], [chmod +x tests/runsrv])
1525 AC_CONFIG_FILES([tests/submitperftest], [chmod +x tests/submitperftest])
1526 AC_CONFIG_FILES([tests/perftest/get_machine_info], [chmod +x tests/perftest/get_machine_info])
1527 AC_CONFIG_FILES([xapian-config], [chmod +x xapian-config])
1528 AC_CONFIG_FILES([makemanpage], [chmod +x makemanpage])
1529 AC_OUTPUT
1530
1531 dnl There are no files generated by AC_OUTPUT in the following directories
1532 dnl and we need to ensure they exist so that the rest of configure or make
1533 dnl won't fail because they don't exist when srcdir != builddir.
1534 if test yes = "$vpath_build" ; then
1535   for dir in include/xapian languages queryparser ; do
1536     AS_MKDIR_P(["$dir"])
1537   done
1538 fi
1539
1540 dnl Generate include/xapian/version.h:
1541
1542 dnl MAIN_VERSION is VERSION without any _git123 suffix.
1543 MAIN_VERSION="$MAJOR_VERSION.$MINOR_VERSION.$REVISION"
1544 cxxcpp_flags=-I.
1545 for backend in GLASS HONEY INMEMORY REMOTE ; do
1546   val=`eval echo "\\\$BUILD_BACKEND_${backend}_TRUE"`
1547   if test -z "$val" ; then
1548     cxxcpp_flags="$cxxcpp_flags -DXAPIAN_HAS_${backend}_BACKEND"
1549   fi
1550 done
1551
1552 if test yes = "$enable_64bit_docid" ; then
1553   cxxcpp_flags="$cxxcpp_flags -DXAPIAN_DOCID_BASE_TYPE="`echo "$INT64_T"|sed 's/ /____/g'`
1554 else
1555   cxxcpp_flags="$cxxcpp_flags -DXAPIAN_DOCID_BASE_TYPE="`echo "$INT32_T"|sed 's/ /____/g'`
1556 fi
1557
1558 if test yes = "$enable_64bit_termcount" ; then
1559   cxxcpp_flags="$cxxcpp_flags -DXAPIAN_TERMCOUNT_BASE_TYPE="`echo "$INT64_T"|sed 's/ /____/g'`
1560 else
1561   cxxcpp_flags="$cxxcpp_flags -DXAPIAN_TERMCOUNT_BASE_TYPE="`echo "$INT32_T"|sed 's/ /____/g'`
1562 fi
1563
1564 dnl Always ought to be 64 bit.
1565 cxxcpp_flags="$cxxcpp_flags -DXAPIAN_TOTALLENGTH_TYPE="`echo "unsigned $INT64_T"|sed 's/ /____/g'`
1566
1567 dnl Make revision numbers in the API 64 bit for future-proofing.
1568 cxxcpp_flags="$cxxcpp_flags -DXAPIAN_REVISION_TYPE="`echo "unsigned $INT64_T"|sed 's/ /____/g'`
1569
1570 dnl For GCC (and compilers which pretend to be GCC) and MSVC, we create some
1571 dnl ABI checks in the generated version.h, and $CXXFLAGS may contain options
1572 dnl which affect the ABI (e.g. -fabi-version for GCC) so we want to use these
1573 dnl options when generating version.h.  For these compilers, CXXCPP="$CXX -E"
1574 dnl so it should understand all compiler options.
1575 dnl
1576 dnl For other compilers, we only pass $CPPFLAGS to $CXXCPP in case it's an
1577 dnl external cpp which doesn't understand flags which might be in $CXXFLAGS.
1578 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[#ifndef __GNUC__
1579 #ifndef _MSC_VER
1580        choke me
1581 #endif
1582 #endif
1583 ]])],
1584         [cxxcpp_flags="$cxxcpp_flags $CPPFLAGS $CXXFLAGS"],
1585         [cxxcpp_flags="$cxxcpp_flags $CPPFLAGS"])
1586 rm -f include/xapian/version.h.tmp
1587 dnl "\r" in sed is a GNUism, but we only need to remove it on MS Windows
1588 dnl where we'll always have GNU sed, and other sed's will just interpret
1589 dnl it as "r" (Solaris sed) or maybe literal "\r" which won't match.
1590 dnl
1591 dnl Use @@ around $MAIN_VERSION so we get " in the final output.
1592 $CXXCPP $cxxcpp_flags\
1593         -DSTRING_VERSION="\"@@$MAIN_VERSION@@\""\
1594         -DMAJOR_VERSION="\"$MAJOR_VERSION\""\
1595         -DMINOR_VERSION="\"$MINOR_VERSION\""\
1596         -DREVISION="\"$REVISION\""\
1597         $dash_d_visibility\
1598         $srcdir/include/xapian/version_h.cc|\
1599         ${SED-sed} '0,/const char \* dummy/d;/"/!d;s/^ *//;/^#/d;s/ *$//;s/" *,//;s/"//g;s/@@/"/g;s/  */ /g;s/ *,\r$//;s/ *,$//;s/____/ /g;s/\\\\$/\\/'\
1600         > include/xapian/version.h.tmp
1601 dnl Only update the file if it has changed, so we don't alter the timestamp
1602 dnl and cause lots of rebuilding needlessly.  However, the build system
1603 dnl needs a timestamp to know when to regenerate version.h because version_h.cc
1604 dnl has changed so we use a separate timestamp file.
1605 touch include/xapian/version.h.timestamp
1606 if cmp include/xapian/version.h.tmp include/xapian/version.h >/dev/null 2>&1
1607 then
1608   rm include/xapian/version.h.tmp
1609 else
1610   mv include/xapian/version.h.tmp include/xapian/version.h
1611 fi