acinclude.m4

   1 # AC_GNU_SOURCE
   2 # --------------
   3 AC_DEFUN([AC_GNU_SOURCE],
   4 [AH_VERBATIM([_GNU_SOURCE],
   5 [/* Enable GNU extensions on systems that have them.  */
   6 #ifndef _GNU_SOURCE
   7 # undef _GNU_SOURCE
   8 #endif])dnl
   9 AC_BEFORE([$0], [AC_COMPILE_IFELSE])dnl
  10 AC_BEFORE([$0], [AC_RUN_IFELSE])dnl
  11 AC_DEFINE([_GNU_SOURCE])
  12 ])
  13
  14 # AC_PROG_EGREP
  15 # -------------
  16 AC_DEFUN([AC_PROG_EGREP],
  17 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
  18    [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
  19     then ac_cv_prog_egrep='grep -E'
  20     else ac_cv_prog_egrep='egrep'
  21     fi])
  22  EGREP=$ac_cv_prog_egrep
  23  AC_SUBST([EGREP])
  24 ])# AC_PROG_EGREP
  25
  26
  27 # AC_TYPE_MBSTATE_T
  28 # -----------------
  29 AC_DEFUN([AC_TYPE_MBSTATE_T],
  30   [AC_CACHE_CHECK([for mbstate_t], ac_cv_type_mbstate_t,
  31      [AC_COMPILE_IFELSE(
  32         [AC_LANG_PROGRAM(
  33            [AC_INCLUDES_DEFAULT
  34 #           include <wchar.h>],
  35            [mbstate_t x; return sizeof x;])],
  36         [ac_cv_type_mbstate_t=yes],
  37         [ac_cv_type_mbstate_t=no])])
  38    if test $ac_cv_type_mbstate_t = yes; then
  39      AC_DEFINE([HAVE_MBSTATE_T], 1,
  40                [Define to 1 if <wchar.h> declares mbstate_t.])
  41    else
  42      AC_DEFINE([mbstate_t], int,
  43                [Define to a type if <wchar.h> does not define.])
  44    fi])