configure.in

   1 dnl
   2 dnl Window Maker autoconf input.
   3 dnl
   4 dnl Process with: aclocal; autoconf; automake
   5 dnl
   6 dnl
   7
   8
   9 AC_INIT(src/WindowMaker.h)
  10
  11
  12
  13 AM_INIT_AUTOMAKE(WindowMaker, 0.60.0)
  14
  15 AM_PROG_LIBTOOL
  16
  17 # by Marcelo Magallon <mmagallo@efis.ucr.ac.cr>
  18 # Turn around -rpath problem with libtool 1.0c
  19 # This define should be improbable enough to not conflict with anything
  20 case ${host} in
  21   *-pc-linux-gnu)
  22     AC_MSG_RESULT([Fixing libtool for -rpath problems.])
  23     sed < libtool > libtool-2 \
  24     's/^hardcode_libdir_flag_spec.*$/hardcode_libdir_flag_spec=" -D__LIBTOOL_IS_A_FOOL__ "/'
  25     mv libtool-2 libtool
  26     chmod 755 libtool
  27   ;;
  28 esac
  29
  30
  31
  32 AM_CONFIG_HEADER(src/config.h)
  33
  34
  35 dnl Checks for host/os name
  36 dnl =======================
  37 AC_CANONICAL_HOST
  38
  39
  40 dnl Checks for programs.
  41 dnl ===================
  42 AC_ISC_POSIX
  43 AC_PROG_CC
  44 dnl AC_PROG_MAKE_SET -- already done by AM_INIT_AUTOMAKE
  45 #AC_PROG_RANLIB
  46 dnl AC_PROG_INSTALL -- already done by AM_INIT_AUTOMAKE
  47 AC_PROG_LN_S
  48 AC_PROG_GCC_TRADITIONAL
  49
  50
  51 dnl the prefix
  52 dnl ==========
  53 dnl
  54 dnl move this earlier in the script... anyone know why this is handled
  55 dnl in such a bizarre way?
  56
  57 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  58 dnl Let make expand exec_prefix.
  59 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  60
  61
  62 _bindir=`eval echo $bindir`
  63 _bindir=`eval echo $_bindir`
  64
  65 _libdir=`eval echo $libdir`
  66 _libdir=`eval echo $_libdir`
  67 lib_search_path="-L$_libdir"
  68
  69 inc_search_path=`eval echo $includedir`
  70 inc_search_path="-I`eval echo $inc_search_path`"
  71
  72
  73 dnl
  74 dnl Check for RedHat bugs
  75 dnl =====================
  76
  77 WM_CHECK_REDCRAP_BUGS($prefix,$_bindir,$_libdir)
  78
  79
  80 dnl
  81 dnl Specify paths to look for libraries and headers
  82 dnl ===============================================
  83 AC_ARG_WITH(libs-from,
  84 [  --with-libs-from       pass compiler flags to look for libraries],
  85         [lib_search_path="$withval $lib_search_path"])
  86
  87 AC_ARG_WITH(incs-from,
  88 [  --with-incs-from       pass compiler flags to look for header files],
  89         [inc_search_path="$withval $inc_search_path"])
  90
  91
  92
  93 dnl Checks for library functions.
  94 dnl ============================
  95 dnl not used anywhere
  96 dnl AC_FUNC_MEMCMP
  97 AC_FUNC_VPRINTF
  98 AC_FUNC_ALLOCA
  99 AC_CHECK_FUNCS(gethostname select poll strerror strncasecmp setpgid atexit)
 100
 101
 102
 103 dnl Loading of dynamic libraries at runtime
 104 dnl =======================================
 105 DLLIBS=""
 106
 107 AC_CHECK_FUNC(dlopen, [HAVEDL="yes"],
 108         AC_CHECK_LIB(dl, dlopen, [DLLIBS="-ldl" HAVEDL="yes"],
 109                          DLLIBS="" ))
 110
 111 if test "x$HAVEDL" = xyes; then
 112     AC_CHECK_HEADERS(dlfcn.h)
 113 fi
 114
 115
 116
 117 dnl Check CPP
 118 dnl =========
 119 if test "x$CPP_PATH" = x; then
 120     AC_PATH_PROG(CPP_PATH, cpp, notfound,
 121                 $PATH:/lib:/usr/bin:/bin:/usr/lib:/usr/ccs/lib)
 122 fi
 123
 124 dnl
 125 dnl Tell stupid Solaris cpp that the files it will process have C++ like syntax
 126 dnl RedHat 5.x is broken too, so it won't make a symlink from cpp to the
 127 dnl standard locations
 128 dnl
 129 if test "$CPP_PATH" = "/usr/ccs/lib/cpp" -o "$CPP_PATH" = "notfound" ; then
 130     if test "$GCC" = "yes"; then
 131         CPP_PATH="gcc -E -x c"
 132     else
 133         if test "$CPP_PATH" = "/usr/ccs/lib/cpp"; then
 134             CPP_PATH="$CPP_PATH -B"
 135         else
 136             echo "cpp, the C preprocessor was not found in your system."
 137             echo "Create a symbolic link from it to /lib/cpp and rerun configure"
 138             exit
 139         fi
 140     fi
 141 fi
 142 AC_DEFINE_UNQUOTED(CPP_PATH, "$CPP_PATH")
 143
 144
 145
 146 dnl Checks for header files.
 147 dnl =======================
 148 dnl AC_HEADER_STDC
 149 AC_HEADER_SYS_WAIT
 150 AC_HEADER_TIME
 151 AC_CHECK_HEADERS(fcntl.h limits.h sys/ioctl.h sys/time.h sys/types.h\
 152                 libintl.h sys/select.h poll.h)
 153
 154
 155
 156 dnl Checks for typedefs, structures, and compiler characteristics.
 157 dnl ==============================================================
 158 AC_DECL_SYS_SIGLIST
 159 AC_C_CONST
 160 #AC_TYPE_SIZE_T
 161 #AC_TYPE_PID_T
 162 AC_TYPE_SIGNAL
 163
 164
 165 dnl gettext
 166 dnl =======
 167
 168
 169 dnl AM_GNU_GETTEXT
 170
 171
 172
 173 INTLIBS=""
 174
 175 AC_CHECK_FUNC(gettext, [HAVEGETTEXT="yes"],
 176         AC_CHECK_LIB(intl, gettext, [INTLIBS="-lintl" HAVEGETTEXT="yes"],
 177                          INTLIBS="" ))
 178
 179 AC_CHECK_PROG(XGETTEXT, xgettext, xgettext)
 180
 181 if test "$XGETTEXT" != ""; then
 182     if $XGETTEXT --help 2>&1 | grep illegal >/dev/null ; then
 183         echo "xgettext isn't GNU version"
 184         XGETTEXT=""
 185     fi
 186 fi
 187
 188 if test "$LINGUAS" != ""; then
 189     if test "$XGETTEXT" != "" -a "$HAVEGETTEXT" != ""; then
 190         AC_DEFINE(I18N)
 191         PO=""
 192 #       if test "$LINGUAS" = ""; then
 193 #           ling=` (cd src/po; /bin/ls *.po) `
 194 #           for l in $ling; do
 195 #               lcode=`basename $l .po`
 196 #               LINGUAS="$LINGUAS $lcode"
 197 #           done
 198 #       fi
 199         echo "xgettext and gettext() exist; will build i18n support for $LINGUAS"
 200     else
 201         LINGUAS=""
 202         PO=""
 203         echo "xgettext and libintl.a don't both exist; will not build i18n support"
 204     fi
 205 else
 206         INTLIBS=""
 207         MOFILES=""
 208         WPMOFILES=""
 209         PO=""
 210 fi
 211
 212
 213 dnl The Tower of Babel
 214 dnl ==================
 215
 216 dnl List of supported locales
 217 dnl -------------------------
 218 supported_locales="cs de es fr gl it ja ko nl no pt ru se tr fi hr el pl ro da zh_TW.Big5 zh_CN sk"
 219 supported_wprefs_locales="pt hr fr ko ja cs zh_TW.Big5 es zh_CN fi it ru"
 220
 221 for lang in $LINGUAS; do
 222         ok=0
 223         for l in $supported_locales; do
 224                 if test "$l" = "$lang"; then
 225                         ok=1
 226                         break
 227                 fi
 228         done
 229         if test "$ok" = 1; then
 230                 MOFILES="$MOFILES $lang.mo"
 231         else
 232                 echo "Locale $lang is not supported."
 233         fi
 234         ok=0
 235         for l in $supported_wprefs_locales; do
 236                 if test "$l" = "$lang"; then
 237                         ok=1
 238                         break
 239                 fi
 240         done
 241         if test "$ok" = 1; then
 242                 WPMOFILES="$WPMOFILES $lang.mo"
 243         fi
 244 done
 245
 246
 247 dnl Kanji Characters support
 248 dnl ========================
 249
 250 case $host_os in
 251         freebsd*)
 252                 AC_CHECK_LIB(xpg4, setlocale, [LIBS="$LIBS -lxpg4"]);;
 253         *)
 254         ;;
 255 esac
 256
 257
 258
 259 dnl Added by Oliver - Support for NLSDIR option,   Hi Oliver!
 260 dnl ===========================================
 261 AC_ARG_WITH(nlsdir,
 262         [  --with-nlsdir=PATH      specify where the locale stuff should go ])
 263
 264
 265 if test "x$NLSDIR" = "x"; then
 266         if test "x$with_nlsdir" != "x"; then
 267                 NLSDIR=$with_nlsdir
 268         else
 269                 NLSDIR='$(prefix)/lib/locale'
 270         fi
 271 fi
 272
 273
 274
 275 AC_SUBST(DLLIBS)
 276 AC_SUBST(INTLIBS)
 277 AC_SUBST(NLSDIR)
 278 AC_SUBST(MOFILES)
 279 AC_SUBST(WPMOFILES)
 280
 281
 282
 283 dnl Support for various hint things
 284 dnl ===============================
 285
 286
 287 AC_ARG_ENABLE(gnome,
 288   [  --enable-gnome       enable stuff needed for GNOME ],
 289   [if test x$enableval = xyes; then
 290     AC_DEFINE(GNOME_STUFF)
 291     gnome_on=yes
 292   fi])
 293
 294
 295 AC_ARG_ENABLE(kde,
 296   [  --enable-kde                 enable support for KDE window manager (kwm) hints ],
 297   [if test x$enableval = xyes; then
 298     AC_DEFINE(KWM_HINTS)
 299     kde_on=yes
 300   fi])
 301
 302
 303 AC_ARG_ENABLE(openlook,
 304   [  --enable-openlook    enable support for OPEN LOOK(tm) (olwm) hints ],
 305   [if test x$enableval = xyes; then
 306     AC_DEFINE(OLWM_HINTS)
 307     openlook_on=yes
 308   fi])
 309
 310
 311 dnl
 312 dnl Disable some stuff that are duplicated in kde
 313 dnl ---------------------------------------------
 314 AC_ARG_ENABLE(lite,
 315   [  --enable-lite                disable some stuff (dont use it) ],
 316   [if test x$enableval = xyes; then
 317         LITE=yes
 318         AC_DEFINE(LITE)
 319         AC_SUBST(LITE)
 320   fi])
 321
 322
 323
 324 dnl ===========================================
 325 dnl             Stuff that uses X
 326 dnl ===========================================
 327
 328 AC_PATH_XTRA
 329
 330 X_LIBRARY_PATH=$x_libraries
 331
 332 XCFLAGS="$X_CFLAGS"
 333
 334 XLFLAGS="$X_LIBS"
 335
 336 XLIBS="-lX11 $X_EXTRA_LIBS"
 337
 338
 339 lib_search_path="$lib_search_path $XLFLAGS"
 340 inc_search_path="$inc_search_path $XCFLAGS"
 341
 342
 343 AC_SUBST(X_LIBRARY_PATH)
 344
 345
 346
 347 dnl Decide which locale function to use, setlocale() or _Xsetlocale()
 348 dnl by MANOME Tomonori
 349 dnl ===========================================
 350 use_locale=yes
 351 AC_ARG_ENABLE(locale,
 352 [  --disable-locale       disable use of X locale support],
 353                 use_locale=no)
 354
 355 if test "$use_locale" = yes; then
 356   AC_CHECK_LIB(X11, _Xsetlocale, AC_DEFINE(X_LOCALE),, $XLFLAGS $XLIBS)
 357 fi
 358
 359
 360 dnl XKB keyboard language status
 361 dnl ============================
 362 AC_ARG_ENABLE(modelock,
 363 [  --enable-modelock      XKB keyboard language status support],
 364                 AC_DEFINE(XKB_MODELOCK))
 365
 366
 367
 368 dnl Shape support
 369 dnl =============
 370 shape=yes
 371 AC_ARG_ENABLE(shape,
 372 [  --disable-shape        disable shaped window extension support],
 373                 shape=$enableval, shape=yes)
 374
 375 added_xext=no
 376
 377 if test "$shape" = yes; then
 378         AC_CHECK_LIB(Xext, XShapeSelectInput, [XLIBS="-lXext $XLIBS"
 379                 added_xext=yes
 380                 AC_DEFINE(SHAPE)], shape=no, $XLFLAGS $XLIBS)
 381 fi
 382
 383
 384 dnl MIT-SHM support
 385 dnl ===============
 386 shm=yes
 387 AC_ARG_ENABLE(shm,
 388 [  --disable-shm           disable usage of MIT-SHM extension],
 389                 shm=$enableval, shm=yes)
 390
 391 if test "$shm" = yes; then
 392         AC_CHECK_LIB(Xext, XShmAttach, ok=yes, ok=no, $XLFLAGS $XLIBS)
 393
 394         if test "$ok" = yes; then
 395         AC_CHECK_FUNC(shmget, ok=yes, ok=no)
 396         fi
 397
 398         if test "$ok" = yes; then
 399                 if test "$added_xext" = no; then
 400                         XLIBS="-lXext $XLIBS"
 401                 fi
 402                 AC_DEFINE(XSHM)
 403         fi
 404 fi
 405
 406
 407 dnl R6 Style Session Management Support
 408 dnl ===================================
 409
 410 #
 411 #
 412 #AC_DEFINE(R6SM)
 413 #AC_SUBST(XSMPLIBS)
 414 #
 415
 416
 417 dnl Check for libPropList
 418 dnl =====================
 419
 420 LIBPL=""
 421
 422 WM_CHECK_LIB(PropList, PLGetString, $X_EXTRA_LIBS)
 423 if test "x$ac_cv_lib_PropList_PLGetString" = xyes; then
 424     WM_CHECK_HEADER(proplist.h)
 425     if test "x$ac_cv_header_proplist_h" = xyes; then
 426         LIBPL="-lPropList"
 427     fi
 428 fi
 429
 430 if test "x$LIBPL" = "x"; then
 431    echo
 432    echo "ERROR!!! libPropList is not installed, or could not be found."
 433    echo "         Window Maker requires libPropList to build."
 434    echo "         Please read INSTALL to find where you can find libPropList,"
 435    echo "         and install it first."
 436    echo "         If you already have it installed, try using the"
 437    if test "x$ac_cv_lib_PropList_PLGetString" != xyes; then
 438    echo "         --with-libs-from flag to tell configure where the library"
 439    echo "         is installed and"
 440    fi
 441    echo "         --with-incs-from flag to tell configure where the header"
 442    echo "         files are installed"
 443    exit 1
 444 fi
 445
 446
 447 AC_SUBST(LIBPL)
 448
 449
 450 dnl ==============================================
 451 dnl         Graphic Format Libraries
 452 dnl ==============================================
 453
 454
 455
 456
 457
 458 dnl XPM Support
 459 dnl ===========
 460 xpm=yes
 461 AC_ARG_ENABLE(xpm,
 462 [  --disable-xpm                  disable use of XPM pixmaps through libXpm],
 463         xpm=$enableval, xpm=yes)
 464
 465 if test "$xpm" = yes; then
 466     WM_CHECK_LIB(Xpm, XpmCreatePixmapFromData, [$XLFLAGS $XLIBS])
 467
 468     if test "x$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = xyes; then
 469         WM_CHECK_HEADER(X11/xpm.h)
 470         if test "x$ac_cv_header_X11_xpm_h" = xyes; then
 471                 GFXLIBS="$GFXLIBS -lXpm"
 472                 supported_gfx="XPM"
 473                 AC_DEFINE(USE_XPM)
 474         else
 475                 supported_gfx="builtin-XPM"
 476         fi
 477     fi
 478 fi
 479
 480 # for wmlib
 481 AC_SUBST(XCFLAGS)
 482 # for test
 483 AC_SUBST(XLFLAGS)
 484 AC_SUBST(XLIBS)
 485
 486 AC_SUBST(X_EXTRA_LIBS)
 487
 488 dnl ===============================================
 489 dnl             End of stuff that uses X
 490 dnl ===============================================
 491
 492
 493 dnl PNG Support
 494 dnl ===========
 495 png=yes
 496 AC_ARG_ENABLE(png,
 497 [  --disable-png                  disable PNG support through libpng],
 498         png=$enableval, png=yes, png=no)
 499
 500
 501 if test "$png" = yes ; then
 502     WM_CHECK_LIB(png, png_get_valid, [-lz -lm])
 503
 504     if test "x$ac_cv_lib_png_png_get_valid" = xyes; then
 505         WM_CHECK_HEADER(png.h)
 506         if test "x$ac_cv_header_png_h" = xyes; then
 507             GFXLIBS="$GFXLIBS -lpng -lz"
 508             supported_gfx="$supported_gfx PNG"
 509             AC_DEFINE(USE_PNG)
 510         fi
 511     fi
 512 fi
 513
 514
 515 dnl JPEG Support
 516 dnl ============
 517 jpeg=yes
 518 ljpeg=""
 519 AC_ARG_ENABLE(jpeg,
 520 [  --disable-jpeg         disable JPEG support through libjpeg],
 521         jpeg=$enableval, jpeg=yes, jpeg=no)
 522
 523 if test "$jpeg" = yes; then
 524     WM_CHECK_LIB(jpeg, jpeg_destroy_compress)
 525
 526     if test "x$ac_cv_lib_jpeg_jpeg_destroy_compress" = xyes; then
 527
 528         ljpeg="-ljpeg"
 529
 530         WM_CHECK_HEADER(jpeglib.h)
 531         if test "x$ac_cv_header_jpeglib_h" = xyes; then
 532             GFXLIBS="$GFXLIBS -ljpeg"
 533             supported_gfx="$supported_gfx JPEG"
 534             AC_DEFINE(USE_JPEG)
 535         fi
 536     fi
 537 fi
 538
 539
 540 dnl GIF Support
 541 dnl ============
 542 gif=yes
 543 AC_ARG_ENABLE(gif,
 544 [  --disable-gif           disable GIF support through libgif or libungif],
 545         gif=$enableval, gif=yes, gif=no)
 546
 547 if test "$gif" = yes; then
 548     my_libname=""
 549     WM_CHECK_LIB(ungif, DGifOpenFileName, [$XLFLAGS $XLIBS])
 550     if test "x$ac_cv_lib_ungif_DGifOpenFileName" = xyes; then
 551         my_libname=-lungif
 552     fi
 553 dnl
 554 dnl libungif is the same thing as libgif for all practical purposes.
 555 dnl
 556     if test "x$my_libname" = x; then
 557         WM_CHECK_LIB(gif, DGifOpenFileName, [$XLFLAGS $XLIBS])
 558         if test "x$ac_cv_lib_gif_DGifOpenFileName" = xyes; then
 559             my_libname=-lgif
 560         fi
 561     fi
 562
 563     if test "$my_libname" != x; then
 564         WM_CHECK_HEADER(gif_lib.h)
 565         if test "x$ac_cv_header_gif_lib_h" = xyes; then
 566             GFXLIBS="$GFXLIBS $my_libname"
 567             supported_gfx="$supported_gfx GIF"
 568             AC_DEFINE(USE_GIF)
 569         fi
 570     fi
 571 fi
 572
 573
 574
 575 dnl TIFF Support
 576 dnl ============
 577 AC_ARG_ENABLE(tiff,
 578 [  --disable-tiff         disable use of TIFF images through libtiff],
 579         tif=$enableval, tif=yes, tif=no)
 580
 581 #
 582 # TIFF can optionally have JPEG and/or zlib support. Must find out
 583 # when they are supported so that correct library flags are passed during
 584 # detection and linkage
 585 #
 586 #
 587 # By default use xpm icons if tiff is not found.
 588 ICONEXT="xpm"
 589 #
 590
 591 if test "$tif" = yes; then
 592     my_libname=""
 593     WM_CHECK_LIB(tiff, TIFFGetVersion, [-lm])
 594     if test "x$ac_cv_lib_tiff_TIFFGetVersion" = xyes; then
 595         my_libname="-ltiff"
 596     fi
 597 dnl
 598 dnl Retry with zlib
 599 dnl
 600     unset ac_cv_lib_tiff_TIFFGetVersion
 601     if test "x$my_libname" = x; then
 602         WM_CHECK_LIB(tiff, TIFFGetVersion, [$ljpeg -lz -lm])
 603         if test "x$ac_cv_lib_tiff_TIFFGetVersion" = xyes; then
 604             my_libname="-ltiff -lz"
 605         fi
 606     fi
 607
 608     if test "x$my_libname" = x; then
 609         WM_CHECK_LIB(tiff34, TIFFGetVersion, [$ljpeg -lm])
 610         if test "x$ac_cv_lib_tiff34_TIFFGetVersion" = xyes; then
 611             my_libname="-ltiff34"
 612         fi
 613     fi
 614
 615
 616     if test "x$my_libname" != x; then
 617         WM_CHECK_HEADER(tiffio.h)
 618         if test "x$ac_cv_header_tiffio_h" = xyes; then
 619             GFXLIBS="$my_libname $GFXLIBS"
 620             ICONEXT="tiff"
 621             supported_gfx="$supported_gfx TIFF"
 622             AC_DEFINE(USE_TIFF)
 623         fi
 624     fi
 625 fi
 626
 627 LIBRARY_SEARCH_PATH="$lib_search_path"
 628 HEADER_SEARCH_PATH="$inc_search_path"
 629
 630 AC_SUBST(LIBRARY_SEARCH_PATH)
 631 AC_SUBST(HEADER_SEARCH_PATH)
 632
 633
 634 AC_SUBST(GFXLIBS)
 635 AC_SUBST(ICONEXT)
 636
 637
 638 dnl ==============================================
 639 dnl         End of Graphic Format Libraries
 640 dnl ==============================================
 641
 642
 643 dnl Debugging setup
 644 dnl ===============
 645 AC_ARG_ENABLE(debug,
 646 [  --enable-debug         enable debugging ],, enable_debug=no)
 647
 648 if test "$enable_debug" = yes; then
 649     DFLAGS="-g -DDEBUG"
 650 #       Efence makes things too slow. Add it by hand in the Makefiles
 651 #       if it is really needed.
 652 #    AC_CHECK_LIB(efence, malloc, LIBS="$LIBS -lefence")
 653 fi
 654 AC_SUBST(DFLAGS)
 655
 656
 657 dnl Sound support - Dan
 658 dnl =============================================
 659 sound=yes
 660 AC_ARG_ENABLE(sound,
 661 [  --disable-sound        disable sound support ],
 662                 sound=$enableval, sound=yes)
 663 if test "$sound" = yes; then
 664         AC_DEFINE(WMSOUND)
 665 fi
 666
 667
 668 # AC_PREFIX_PROGRAM(wmaker)
 669
 670 dnl Support for PIXMAPDIR option
 671 dnl ============================
 672 AC_ARG_WITH(pixmapdir,
 673 [  --with-pixmapdir=PATH   specify where pixmaps are located [DATADIR/pixmaps]])
 674
 675 if test "x$with_pixmapdir" != "x"; then
 676         pixmapdir=$with_pixmapdir
 677 else
 678         pixmapdir=`eval echo ${datadir}/pixmaps`
 679 fi
 680
 681 AC_DEFINE_UNQUOTED(PIXMAPDIR, "$pixmapdir")
 682
 683 pkgdatadir=`eval echo $datadir`
 684 AC_DEFINE_UNQUOTED(PKGDATADIR, "$pkgdatadir/WindowMaker")
 685
 686 _sysconfdir=`eval echo $sysconfdir`
 687 AC_DEFINE_UNQUOTED(SYSCONFDIR, "$_sysconfdir/WindowMaker")
 688
 689
 690 dnl Support for GNUSTEP_LOCAL_ROOT, for WPrefs.app
 691 dnl ==============================================
 692
 693 appspath=""
 694
 695 AC_ARG_WITH(appspath,
 696 [  --with-appspath=PATH    specify the directory for GNUstep applications], appspath=$withval )
 697
 698 if test "x$appspath" = "x"; then
 699     gnustepdir='$(prefix)/GNUstep'
 700
 701     if test "x$GNUSTEP_LOCAL_ROOT" != "x" ; then
 702         gnustepdir=`echo "$GNUSTEP_LOCAL_ROOT" | sed -e "s|^${prefix}|prefix|"`
 703         gnustepdir=`echo $gnustepdir | sed -e 's|^prefix|${prefix}|'`
 704     fi
 705
 706     with_appspath=$gnustepdir/Apps
 707 fi
 708
 709 wprefsdir=$with_appspath/WPrefs.app
 710
 711 AC_SUBST(wprefsdir)
 712
 713
 714
 715 dnl Enable single appicon per wm instance+class combo -cls
 716 dnl =====================================================
 717 AC_ARG_ENABLE(single-icon,
 718 [  --enable-single-icon    use single application icon per WM_INSTANCE+WM_CLASS
 719 ],
 720 if test "$enableval" = yes; then
 721         AC_DEFINE(REDUCE_APPICONS)
 722 fi
 723 )
 724
 725 dnl Enable User Defined Menu thing
 726 dnl ==================================
 727 AC_ARG_ENABLE(usermenu,
 728 [  --enable-usermenu      user defined menus for applications
 729 ],
 730 if test "$enableval" = yes; then
 731         AC_DEFINE(USER_MENU)
 732 fi
 733 )
 734
 735
 736 dnl
 737 dnl Nicolai:  Program tests for Documentation Section
 738 dnl =================================================
 739 dnl DOCTYPES=""
 740 dnl AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, ,$PATH)
 741 dnl if test "x$MAKEINFO" != "x" ; then
 742 dnl       DOCTYPES="$DOCTYPES info_doc"
 743 dnl fi
 744 dnl AC_CHECK_PROG(TEX, tex, tex, ,$PATH)
 745 dnl if test "x$TEX" != "x" ; then
 746 dnl       DOCTYPES="$DOCTYPES dvi_doc"
 747 dnl fi
 748 dnl AC_CHECK_PROG(DVIPS, dvips, dvips, ,$PATH)
 749 dnl if test "x$DVIPS" != "x" ; then
 750 dnl       DOCTYPES="$DOCTYPES ps_doc"
 751 dnl fi
 752 dnl AC_CHECK_PROG(PERL, perl, perl, ,$PATH)
 753 dnl if test "x$PERL" != "x" ; then
 754 dnl       DOCTYPES="$DOCTYPES html_doc"
 755 dnl fi
 756 dnl AC_PATH_PROG(PERL_PATH, perl, perl, ,$PATH)
 757 dnl AC_CHECK_PROG(TEXI2HTML, texi2html, texi2html, ,$PATH)
 758
 759 dnl AC_SUBST(DOCTYPES)
 760
 761 AC_OUTPUT(Makefile po/Makefile util/Makefile test/Makefile wmlib/Makefile \
 762         WINGs/Makefile WINGs/Resources/Makefile src/Makefile src/wconfig.h \
 763         wrlib/Makefile doc/Makefile WindowMaker/Makefile contrib/Makefile \
 764         WindowMaker/Backgrounds/Makefile WindowMaker/Defaults/Makefile \
 765         WindowMaker/IconSets/Makefile WindowMaker/Icons/Makefile \
 766         WindowMaker/Pixmaps/Makefile WindowMaker/Styles/Makefile \
 767         WindowMaker/Themes/Makefile \
 768         WPrefs.app/Makefile WPrefs.app/tiff/Makefile WPrefs.app/xpm/Makefile \
 769         WPrefs.app/po/Makefile )
 770
 771
 772
 773 dnl
 774 dnl Output some helpfull data for compiling WINGs apps
 775 dnl ==================================================
 776 dnl
 777
 778 dnl echo "WFLAGS=\"$LIBPL_INC_PATH -I$prefix/include\"" > WINGs-flags
 779 dnl echo "WLIBS=\"-L$exec_prefix/lib -lWINGs -lwraster $LIBPL_LIBS $GFXLIBS -lm\""\
 780 dnl     | sed -e 's|\$(prefix)|'"$prefix|" >> WINGs-flags
 781
 782 dnl The #lp# and #rp# stuff below is a hack because [ and ] get lost when
 783 dnl parsed by m4
 784
 785 cat <<EOF >get-wraster-flags
 786 #!/bin/sh
 787
 788 prefix="$prefix"
 789 exec_prefix=\$prefix
 790
 791 WCFLAGS="-I\$prefix/include $inc_search_path"
 792 WLFLAGS="-L\$exec_prefix/lib $lib_search_path"
 793 WLIBS="-lwraster $GFXLIBS $XLIBS -lm"
 794
 795 usage="Usage: get-wraster-flags #lp#--cflags#rp# #lp#--ldflags#rp# #lp#--libs#rp#"
 796
 797 if test \$# -eq 0; then
 798       echo "\${usage}" 1>&2
 799       exit 1
 800 fi
 801
 802 while test \$# -gt 0; do
 803   case \$1 in
 804     --cflags)
 805         echo \$WCFLAGS
 806         ;;
 807     --ldflags|--lflags)
 808         echo \$WLFLAGS
 809         ;;
 810     --libs)
 811         echo \$WLIBS
 812         ;;
 813     *)
 814         echo "\${usage}" 1>&2
 815         exit 1
 816         ;;
 817   esac
 818   shift
 819 done
 820
 821
 822 EOF
 823
 824 sed 's/#lp#/[/g' get-wraster-flags | sed 's/#rp#/]/g' > wrlib/get-wraster-flags
 825
 826 chmod 755 wrlib/get-wraster-flags
 827 rm -f get-wraster-flags
 828
 829
 830 dnl
 831 dnl Spit out the configuration
 832 dnl ==========================
 833
 834 supported_gfx="$supported_gfx builtin-PPM"
 835
 836 if test "x$MOFILES" = "x"; then
 837         mof=none
 838 else
 839         mof=$MOFILES
 840 fi
 841
 842
 843 echo
 844 echo "Window Maker was configured as follows:"
 845 echo
 846 echo "Installation path prefix: $prefix"
 847 echo "Installation path prefix for binaries: $_bindir"
 848 echo "Installation path for WPrefs.app: $wprefsdir" | sed -e 's|\$(prefix)|'"$prefix|"
 849 echo "Graphic format libraries: $supported_gfx"
 850 echo "Sound support: $sound"
 851 echo "Translated message files to install: $mof"
 852 if test "x$MOFILES" != "x"; then
 853         echo "Installation path of translated messages: $NLSDIR" | sed -e 's|\$(prefix)|'"$prefix|"
 854 fi
 855
 856 WM_PRINT_REDCRAP_BUG_STATUS
 857
 858 if test "x$ac_cv_header_jpeglib_h" != xyes; then
 859 echo "WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"
 860 echo
 861 echo "JPEG support will not be included because the JPEG library is"
 862 echo "not installed correctly or was not found. Background images"
 863 echo "from themes will not display as they usually are JPEG files."
 864 echo
 865 echo "To fix, download and install the jpeg library and/or make sure you"
 866 echo "installed all jpeg related packages, like jpeg-devel."
 867 echo
 868 echo "WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"
 869 fi
 870
 871
 872 dnl This is for Emacs.  I'm lazy, I know... (nicolai)
 873 dnl ================================================
 874 dnl Local Variables:
 875 dnl compile-command: "autoconf"
 876 dnl End:
 877