configure.in

   1 dnl
   2 dnl Window Maker autoconf input.
   3 dnl
   4 dnl Process with:
   5 dnl               aclocal
   6 dnl               autoheader
   7 dnl               autoconf
   8 dnl               libtoolize --force --automake
   9 dnl               automake -a --gnu --include-deps
  10 dnl
  11 dnl
  12
  13
  14 AC_INIT(src/WindowMaker.h)
  15
  16
  17
  18 AM_INIT_AUTOMAKE(WindowMaker, 0.80.0)
  19
  20 AM_PROG_LIBTOOL
  21
  22 # by Marcelo Magallon <mmagallo@efis.ucr.ac.cr>
  23 # Turn around -rpath problem with libtool 1.0c
  24 # This define should be improbable enough to not conflict with anything
  25 case ${host} in
  26   *-pc-linux-gnu)
  27     AC_MSG_RESULT([Fixing libtool for -rpath problems.])
  28     sed < libtool > libtool-2 \
  29     's/^hardcode_libdir_flag_spec.*$/hardcode_libdir_flag_spec=" -D__LIBTOOL_IS_A_FOOL__ "/'
  30     mv libtool-2 libtool
  31     chmod 755 libtool
  32   ;;
  33 esac
  34
  35
  36 AM_CONFIG_HEADER(src/config.h)
  37
  38
  39 dnl Checks for host/os name
  40 dnl =======================
  41 AC_CANONICAL_HOST
  42
  43
  44 dnl Checks for programs.
  45 dnl ===================
  46 AC_ISC_POSIX
  47 AC_PROG_CC
  48 dnl AC_PROG_MAKE_SET -- already done by AM_INIT_AUTOMAKE
  49 #AC_PROG_RANLIB
  50 dnl AC_PROG_INSTALL -- already done by AM_INIT_AUTOMAKE
  51 AC_PROG_LN_S
  52 AC_PROG_GCC_TRADITIONAL
  53
  54
  55 dnl the prefix
  56 dnl ==========
  57 dnl
  58 dnl move this earlier in the script... anyone know why this is handled
  59 dnl in such a bizarre way?
  60
  61 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  62 dnl Let make expand exec_prefix.
  63 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  64
  65
  66 _bindir=`eval echo $bindir`
  67 _bindir=`eval echo $_bindir`
  68
  69 _libdir=`eval echo $libdir`
  70 _libdir=`eval echo $_libdir`
  71 lib_search_path="-L$_libdir"
  72
  73 inc_search_path=`eval echo $includedir`
  74 inc_search_path="-I`eval echo $inc_search_path`"
  75
  76
  77 dnl
  78 dnl Check for RedHat bugs
  79 dnl =====================
  80
  81 dnl WM_CHECK_REDCRAP_BUGS($prefix,$_bindir,$_libdir)
  82
  83
  84 dnl
  85 dnl Specify paths to look for libraries and headers
  86 dnl ===============================================
  87 AC_ARG_WITH(libs-from,
  88 [  --with-libs-from       pass compiler flags to look for libraries],
  89         [lib_search_path="$withval $lib_search_path"])
  90
  91 AC_ARG_WITH(incs-from,
  92 [  --with-incs-from       pass compiler flags to look for header files],
  93         [inc_search_path="$withval $inc_search_path"])
  94
  95
  96
  97 dnl Checks for library functions.
  98 dnl ============================
  99 dnl not used anywhere
 100 dnl AC_FUNC_MEMCMP
 101 AC_FUNC_VPRINTF
 102 AC_FUNC_ALLOCA
 103 AC_CHECK_FUNCS(gethostname select poll strerror strcasecmp strncasecmp setpgid atexit mallinfo mkstemp snprintf vsnprintf asprintf vasprintf)
 104
 105
 106 dnl ripped from samba
 107 dnl
 108 AC_CACHE_CHECK([for C99 vsnprintf],_cv_HAVE_C99_VSNPRINTF,[
 109 AC_TRY_RUN([
 110 #include <sys/types.h>
 111 #include <stdarg.h>
 112 void foo(const char *format, ...) {
 113        va_list ap;
 114        int len;
 115        char buf[5];
 116
 117        va_start(ap, format);
 118        len = vsnprintf(0, 0, format, ap);
 119        va_end(ap);
 120        if (len != 5) exit(1);
 121
 122        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 123
 124        exit(0);
 125 }
 126 main() { foo("hello"); }
 127 ],
 128 _cv_HAVE_C99_VSNPRINTF=yes,_cv_HAVE_C99_VSNPRINTF=no,_cv_HAVE_C99_VSNPRINTF=cross)])
 129 if test x"$_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 130     AC_DEFINE(HAVE_C99_VSNPRINTF)
 131 fi
 132
 133 dnl Loading of dynamic libraries at runtime
 134 dnl =======================================
 135 DLLIBS=""
 136
 137 AC_CHECK_FUNC(dlopen, [HAVEDL="yes"],
 138         AC_CHECK_LIB(dl, dlopen, [DLLIBS="-ldl" HAVEDL="yes"],
 139                          DLLIBS="" ))
 140
 141 if test "x$HAVEDL" = xyes; then
 142     AC_CHECK_HEADERS(dlfcn.h)
 143 fi
 144
 145
 146
 147 dnl Check CPP
 148 dnl =========
 149 if test "x$CPP_PATH" = x; then
 150     AC_PATH_PROG(CPP_PATH, cpp, notfound,
 151                 $PATH:/lib:/usr/bin:/bin:/usr/lib:/usr/ccs/lib)
 152 fi
 153
 154 dnl
 155 dnl Tell stupid Solaris cpp that the files it will process have C++ like syntax
 156 dnl RedHat 5.x is broken too, so it won't make a symlink from cpp to the
 157 dnl standard locations
 158 dnl
 159 if test "$CPP_PATH" = "/usr/ccs/lib/cpp" -o "$CPP_PATH" = "notfound" ; then
 160     if test "$GCC" = "yes"; then
 161         CPP_PATH="gcc -E -x c"
 162     else
 163         if test "$CPP_PATH" = "/usr/ccs/lib/cpp"; then
 164             CPP_PATH="$CPP_PATH -B"
 165         else
 166             echo "cpp, the C preprocessor was not found in your system."
 167             echo "Create a symbolic link from it to /lib/cpp and rerun configure"
 168             exit
 169         fi
 170     fi
 171 fi
 172 AC_DEFINE_UNQUOTED(CPP_PATH, "$CPP_PATH")
 173
 174
 175
 176 dnl Checks for header files.
 177 dnl =======================
 178 AC_HEADER_SYS_WAIT
 179 AC_HEADER_TIME
 180 AC_CHECK_HEADERS(fcntl.h limits.h sys/ioctl.h sys/time.h sys/types.h libintl.h sys/select.h poll.h malloc.h ctype.h string.h strings.h)
 181
 182
 183
 184 dnl Checks for typedefs, structures, and compiler characteristics.
 185 dnl ==============================================================
 186 AC_DECL_SYS_SIGLIST
 187 AC_C_CONST
 188 #AC_TYPE_SIZE_T
 189 #AC_TYPE_PID_T
 190 AC_TYPE_SIGNAL
 191
 192
 193
 194 dnl gettext
 195 dnl =======
 196
 197
 198 dnl AM_GNU_GETTEXT
 199
 200
 201
 202 INTLIBS=""
 203
 204 AC_CHECK_FUNC(gettext, [HAVEGETTEXT="yes"],
 205         AC_CHECK_LIB(intl, gettext, [INTLIBS="-lintl" HAVEGETTEXT="yes"],
 206                          INTLIBS="" ))
 207
 208 AC_CHECK_PROG(XGETTEXT, xgettext, xgettext)
 209
 210 if test "$XGETTEXT" != ""; then
 211     if $XGETTEXT --help 2>&1 | grep illegal >/dev/null ; then
 212         echo "xgettext isn't GNU version"
 213         XGETTEXT=""
 214     fi
 215 fi
 216
 217 if test "$LINGUAS" != ""; then
 218     if test "$XGETTEXT" != "" -a "$HAVEGETTEXT" != ""; then
 219         AC_DEFINE(I18N)
 220         PO=""
 221 #       if test "$LINGUAS" = ""; then
 222 #           ling=` (cd src/po; /bin/ls *.po) `
 223 #           for l in $ling; do
 224 #               lcode=`basename $l .po`
 225 #               LINGUAS="$LINGUAS $lcode"
 226 #           done
 227 #       fi
 228         echo "xgettext and gettext() exist; will build i18n support for $LINGUAS"
 229     else
 230         LINGUAS=""
 231         PO=""
 232         echo "xgettext and libintl.a don't both exist; will not build i18n support"
 233     fi
 234 else
 235         INTLIBS=""
 236         MOFILES=""
 237         WPMOFILES=""
 238         PO=""
 239 fi
 240
 241
 242 dnl The Tower of Babel
 243 dnl ==================
 244
 245 dnl List of supported locales
 246 dnl -------------------------
 247 supported_locales="bg cs da de el es et fi fr gl hr hu it ja ko nl no pl pt ro ru sk sv tr zh_CN zh_TW.Big5"
 248 supported_wprefs_locales="bg cs de es et fi fr hr hu it ja ko pt ru sk zh_CN zh_TW.Big5"
 249 supported_wings_locales="cs sk"
 250
 251 for lang in $LINGUAS; do
 252         ok=0
 253         for l in $supported_locales; do
 254                 if test "$l" = "$lang"; then
 255                         ok=1
 256                         break
 257                 fi
 258         done
 259         if test "$ok" = 1; then
 260                 MOFILES="$MOFILES $lang.mo"
 261         else
 262                 echo "Locale $lang is not supported."
 263         fi
 264         ok=0
 265         for l in $supported_wprefs_locales; do
 266                 if test "$l" = "$lang"; then
 267                         ok=1
 268                         break
 269                 fi
 270         done
 271         if test "$ok" = 1; then
 272                 WPMOFILES="$WPMOFILES $lang.mo"
 273         fi
 274         ok=0
 275         for l in $supported_wings_locales; do
 276                 if test "$l" = "$lang"; then
 277                         ok=1
 278                         break
 279                 fi
 280         done
 281         if test "$ok" = 1; then
 282                 WINGSMOFILES="$WINGSMOFILES $lang.mo"
 283         fi
 284 done
 285
 286
 287 dnl Kanji Characters support
 288 dnl ========================
 289
 290 case $host_os in
 291         freebsd*)
 292                 AC_CHECK_LIB(xpg4, setlocale, [LIBS="$LIBS -lxpg4"]);;
 293         *)
 294         ;;
 295 esac
 296
 297
 298
 299 dnl Added by Oliver - Support for NLSDIR option,   Hi Oliver!
 300 dnl ===========================================
 301 AC_ARG_WITH(nlsdir,
 302         [  --with-nlsdir=PATH      specify where the locale stuff should go ])
 303
 304
 305 if test "x$NLSDIR" = "x"; then
 306         if test "x$with_nlsdir" != "x"; then
 307                 NLSDIR=$with_nlsdir
 308         else
 309                 NLSDIR='$(prefix)/lib/locale'
 310         fi
 311 fi
 312
 313
 314
 315 AC_SUBST(DLLIBS)
 316 AC_SUBST(INTLIBS)
 317 AC_SUBST(NLSDIR)
 318 AC_SUBST(MOFILES)
 319 AC_SUBST(WPMOFILES)
 320 AC_SUBST(WINGSMOFILES)
 321 AC_SUBST(supported_locales)
 322
 323
 324
 325 dnl Support for various hint things
 326 dnl ===============================
 327
 328
 329 AC_ARG_ENABLE(gnome,
 330   [  --enable-gnome       enable stuff needed for GNOME ],
 331   [if test x$enableval = xyes; then
 332     AC_DEFINE(GNOME_STUFF)
 333     gnome_on=yes
 334   fi])
 335
 336
 337 AC_ARG_ENABLE(kde,
 338   [  --enable-kde                 enable support for KDE window manager (kwm) hints ],
 339   [if test x$enableval = xyes; then
 340     AC_DEFINE(KWM_HINTS)
 341     kde_on=yes
 342   fi])
 343
 344
 345 AC_ARG_ENABLE(openlook,
 346   [  --enable-openlook    enable support for OPEN LOOK(tm) (olwm) hints ],
 347   [if test x$enableval = xyes; then
 348     AC_DEFINE(OLWM_HINTS)
 349     openlook_on=yes
 350   fi])
 351
 352
 353 dnl
 354 dnl Disable some stuff that are duplicated in kde
 355 dnl ---------------------------------------------
 356 AC_ARG_ENABLE(lite,
 357   [  --enable-lite                disable some stuff (dont use it) ],
 358   [if test x$enableval = xyes; then
 359         LITE=yes
 360         AC_DEFINE(LITE)
 361         AC_SUBST(LITE)
 362   fi])
 363
 364
 365
 366 dnl
 367 dnl Networking stuff
 368 dnl
 369
 370 NETLIBS=""
 371
 372 AC_CHECK_FUNC(connect,,
 373         AC_CHECK_LIB(socket, connect, NETLIBS="$NETLIBS -lsocket"))
 374
 375 AC_CHECK_FUNC(gethostbyname,,
 376         AC_CHECK_LIB(nsl, gethostbyname, NETLIBS="$NETLIBS -lnsl"))
 377
 378 AC_CHECK_FUNC(inet_aton, AC_DEFINE(HAVE_INET_ATON),
 379      for lib in resolv socket inet bsd; do
 380         AC_CHECK_LIB($lib, inet_aton, [AC_DEFINE(HAVE_INET_ATON)
 381                      NETLIBS="$NETLIBS -l$lib"; break],, $NETLIBS)
 382      done)
 383
 384 AC_SUBST(NETLIBS)
 385
 386
 387 dnl ===========================================
 388 dnl             Stuff that uses X
 389 dnl ===========================================
 390
 391 AC_PATH_XTRA
 392
 393 if test $no_x; then
 394     AC_MSG_ERROR([The path for the X11 files not found!
 395 Make sure you have X and it's headers and libraries (the -devel packages
 396 in Linux) installed.])
 397 fi
 398
 399 X_LIBRARY_PATH=$x_libraries
 400
 401 XCFLAGS="$X_CFLAGS"
 402
 403 XLFLAGS="$X_LIBS"
 404
 405 XLIBS="-lX11 $X_EXTRA_LIBS"
 406
 407
 408 lib_search_path="$lib_search_path $XLFLAGS"
 409 inc_search_path="$inc_search_path $XCFLAGS"
 410
 411
 412 AC_SUBST(X_LIBRARY_PATH)
 413
 414
 415
 416 dnl Decide which locale function to use, setlocale() or _Xsetlocale()
 417 dnl by MANOME Tomonori
 418 dnl ===========================================
 419 use_locale=yes
 420 AC_ARG_ENABLE(locale,
 421 [  --disable-locale       disable use of X locale support],
 422                 use_locale=no)
 423
 424 if test "$use_locale" = yes; then
 425   AC_CHECK_LIB(X11, _Xsetlocale, AC_DEFINE(X_LOCALE),, $XLFLAGS $XLIBS)
 426 fi
 427
 428
 429 dnl Check whether XInternAtoms() exist
 430 dnl ==================================
 431 AC_CHECK_LIB(X11, XInternAtoms, AC_DEFINE(HAVE_XINTERNATOMS),,$XLFLAGS $XLIBS)
 432
 433 dnl Check whether XConvertCase() exist
 434 dnl ==================================
 435 AC_CHECK_LIB(X11, XConvertCase, AC_DEFINE(HAVE_XCONVERTCASE),,$XLFLAGS $XLIBS)
 436
 437
 438 dnl XKB keyboard language status
 439 dnl ============================
 440 AC_ARG_ENABLE(modelock,
 441 [  --enable-modelock      XKB keyboard language status support],
 442                 AC_DEFINE(XKB_MODELOCK))
 443
 444
 445
 446 dnl Shape support
 447 dnl =============
 448 shape=yes
 449 AC_ARG_ENABLE(shape,
 450 [  --disable-shape        disable shaped window extension support],
 451                 shape=$enableval, shape=yes)
 452
 453 added_xext=no
 454
 455 if test "$shape" = yes; then
 456         AC_CHECK_LIB(Xext, XShapeSelectInput, [XLIBS="-lXext $XLIBS"
 457                 added_xext=yes
 458                 AC_DEFINE(SHAPE)], shape=no, $XLFLAGS $XLIBS)
 459 fi
 460
 461
 462 dnl XINERAMA support
 463 dnl ================
 464 xinerama=no
 465 #AC_ARG_ENABLE(xinerama,
 466 #[  --disable-xinerama    disable XInerama extension support],
 467 #               xinerama=$enableval, xinerama=yes)
 468
 469 if test "$xinerama" = yes; then
 470         AC_CHECK_LIB(Xinerama, XineramaQueryScreens, [XLIBS="-lXinerama $XLIBS"
 471                 AC_DEFINE(XINERAMA)], xinerama=no, $XLFLAGS $XLIBS)
 472 fi
 473
 474
 475
 476 dnl MIT-SHM support
 477 dnl ===============
 478 shm=yes
 479 AC_ARG_ENABLE(shm,
 480 [  --disable-shm           disable usage of MIT-SHM extension],
 481                 shm=$enableval, shm=yes)
 482
 483 if test "$shm" = yes; then
 484         AC_CHECK_LIB(Xext, XShmAttach, ok=yes, ok=no, $XLFLAGS $XLIBS)
 485
 486         if test "$ok" = yes; then
 487         AC_CHECK_FUNC(shmget, ok=yes, ok=no)
 488         fi
 489
 490         if test "$ok" = yes; then
 491                 if test "$added_xext" = no; then
 492                         XLIBS="-lXext $XLIBS"
 493                 fi
 494                 AC_DEFINE(XSHM)
 495         fi
 496 fi
 497
 498
 499 dnl R6 Style Session Management Support
 500 dnl ===================================
 501
 502 #
 503 #
 504 #AC_DEFINE(R6SM)
 505 #AC_SUBST(XSMPLIBS)
 506 #
 507
 508
 509 dnl ==============================================
 510 dnl         Graphic Format Libraries
 511 dnl ==============================================
 512
 513
 514
 515
 516
 517 dnl XPM Support
 518 dnl ===========
 519 xpm=yes
 520 AC_ARG_ENABLE(xpm,
 521 [  --disable-xpm                  disable use of XPM pixmaps through libXpm],
 522         xpm=$enableval, xpm=yes)
 523
 524 if test "$xpm" = yes; then
 525     WM_CHECK_LIB(Xpm, XpmCreatePixmapFromData, [$XLFLAGS $XLIBS])
 526
 527     if test "x$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = xyes; then
 528         WM_CHECK_HEADER(X11/xpm.h)
 529         if test "x$ac_cv_header_X11_xpm_h" = xyes; then
 530                 GFXLIBS="$GFXLIBS -lXpm"
 531                 supported_gfx="XPM"
 532                 AC_DEFINE(USE_XPM)
 533         else
 534                 supported_gfx="builtin-XPM"
 535         fi
 536     fi
 537 fi
 538
 539 # for wmlib
 540 AC_SUBST(XCFLAGS)
 541 # for test
 542 AC_SUBST(XLFLAGS)
 543 AC_SUBST(XLIBS)
 544
 545 AC_SUBST(X_EXTRA_LIBS)
 546
 547 dnl ===============================================
 548 dnl             End of stuff that uses X
 549 dnl ===============================================
 550
 551
 552
 553 dnl Hermes Support
 554 dnl ==============
 555
 556 AC_ARG_ENABLE(hermes,
 557   [  --disable-hermes     disable Hermes support for wrlib ],
 558      hermes=$enableval, hermes=yes)
 559
 560 if test x$hermes = xyes; then
 561    WM_CHECK_LIB(Hermes, Hermes_ConverterRequest, [])
 562
 563    if test x$ac_cv_lib_Hermes_Hermes_ConverterRequest = xyes; then
 564       WM_CHECK_HEADER(Hermes/Hermes.h)
 565       if test x$ac_cv_header_Hermes_Hermes_h = xyes; then
 566          GFXLIBS="$GFXLIBS -lHermes"
 567          AC_DEFINE(HAVE_HERMES)
 568          hermes_support=yes
 569       fi
 570    fi
 571 fi
 572
 573
 574
 575 dnl PNG Support
 576 dnl ===========
 577 png=yes
 578 AC_ARG_ENABLE(png,
 579 [  --disable-png                  disable PNG support through libpng],
 580         png=$enableval, png=yes, png=no)
 581
 582
 583 if test "$png" = yes ; then
 584     WM_CHECK_LIB(png, png_get_valid, [-lz -lm])
 585
 586     if test "x$ac_cv_lib_png_png_get_valid" = xyes; then
 587         WM_CHECK_HEADER(png.h)
 588         if test "x$ac_cv_header_png_h" = xyes; then
 589             GFXLIBS="$GFXLIBS -lpng -lz"
 590             supported_gfx="$supported_gfx PNG"
 591             AC_DEFINE(USE_PNG)
 592         fi
 593     fi
 594 fi
 595
 596
 597 dnl JPEG Support
 598 dnl ============
 599 jpeg=yes
 600 ljpeg=""
 601 AC_ARG_ENABLE(jpeg,
 602 [  --disable-jpeg         disable JPEG support through libjpeg],
 603         jpeg=$enableval, jpeg=yes, jpeg=no)
 604
 605 if test "$jpeg" = yes; then
 606     WM_CHECK_LIB(jpeg, jpeg_destroy_compress)
 607
 608     if test "x$ac_cv_lib_jpeg_jpeg_destroy_compress" = xyes; then
 609
 610         ljpeg="-ljpeg"
 611
 612         WM_CHECK_HEADER(jpeglib.h)
 613         if test "x$ac_cv_header_jpeglib_h" = xyes; then
 614             GFXLIBS="$GFXLIBS -ljpeg"
 615             supported_gfx="$supported_gfx JPEG"
 616             AC_DEFINE(USE_JPEG)
 617         fi
 618     fi
 619 fi
 620
 621
 622 dnl GIF Support
 623 dnl ============
 624 gif=yes
 625 AC_ARG_ENABLE(gif,
 626 [  --disable-gif           disable GIF support through libgif or libungif],
 627         gif=$enableval, gif=yes, gif=no)
 628
 629 if test "$gif" = yes; then
 630     my_libname=""
 631     WM_CHECK_LIB(ungif, DGifOpenFileName, [$XLFLAGS $XLIBS])
 632     if test "x$ac_cv_lib_ungif_DGifOpenFileName" = xyes; then
 633         my_libname=-lungif
 634     fi
 635 dnl
 636 dnl libungif is the same thing as libgif for all practical purposes.
 637 dnl
 638     if test "x$my_libname" = x; then
 639         WM_CHECK_LIB(gif, DGifOpenFileName, [$XLFLAGS $XLIBS])
 640         if test "x$ac_cv_lib_gif_DGifOpenFileName" = xyes; then
 641             my_libname=-lgif
 642         fi
 643     fi
 644
 645     if test "$my_libname" != x; then
 646         WM_CHECK_HEADER(gif_lib.h)
 647         if test "x$ac_cv_header_gif_lib_h" = xyes; then
 648             GFXLIBS="$GFXLIBS $my_libname"
 649             supported_gfx="$supported_gfx GIF"
 650             AC_DEFINE(USE_GIF)
 651         fi
 652     fi
 653 fi
 654
 655
 656
 657 dnl TIFF Support
 658 dnl ============
 659 AC_ARG_ENABLE(tiff,
 660 [  --disable-tiff         disable use of TIFF images through libtiff],
 661         tif=$enableval, tif=yes, tif=no)
 662
 663 #
 664 # TIFF can optionally have JPEG and/or zlib support. Must find out
 665 # when they are supported so that correct library flags are passed during
 666 # detection and linkage
 667 #
 668 #
 669 # By default use xpm icons if tiff is not found.
 670 ICONEXT="xpm"
 671 #
 672
 673 if test "$tif" = yes; then
 674     my_libname=""
 675     WM_CHECK_LIB(tiff, TIFFGetVersion, [-lm])
 676     if test "x$ac_cv_lib_tiff_TIFFGetVersion" = xyes; then
 677         my_libname="-ltiff"
 678     fi
 679 dnl
 680 dnl Retry with zlib
 681 dnl
 682     unset ac_cv_lib_tiff_TIFFGetVersion
 683     if test "x$my_libname" = x; then
 684         WM_CHECK_LIB(tiff, TIFFGetVersion, [$ljpeg -lz -lm])
 685         if test "x$ac_cv_lib_tiff_TIFFGetVersion" = xyes; then
 686             my_libname="-ltiff -lz"
 687         fi
 688     fi
 689
 690     if test "x$my_libname" = x; then
 691         WM_CHECK_LIB(tiff34, TIFFGetVersion, [$ljpeg -lm])
 692         if test "x$ac_cv_lib_tiff34_TIFFGetVersion" = xyes; then
 693             my_libname="-ltiff34"
 694         fi
 695     fi
 696
 697
 698     if test "x$my_libname" != x; then
 699         WM_CHECK_HEADER(tiffio.h)
 700         if test "x$ac_cv_header_tiffio_h" = xyes; then
 701             GFXLIBS="$my_libname $GFXLIBS"
 702             ICONEXT="tiff"
 703             supported_gfx="$supported_gfx TIFF"
 704             AC_DEFINE(USE_TIFF)
 705         fi
 706     fi
 707 fi
 708
 709 LIBRARY_SEARCH_PATH="$lib_search_path"
 710 HEADER_SEARCH_PATH="$inc_search_path"
 711
 712 AC_SUBST(LIBRARY_SEARCH_PATH)
 713 AC_SUBST(HEADER_SEARCH_PATH)
 714
 715
 716 AC_SUBST(GFXLIBS)
 717 AC_SUBST(ICONEXT)
 718
 719
 720 dnl ==============================================
 721 dnl         End of Graphic Format Libraries
 722 dnl ==============================================
 723
 724
 725 dnl
 726 dnl stdlib.h is checked here, because of conflict in jpeglib.h
 727 AC_CHECK_HEADERS(stdlib.h)
 728
 729 # AC_PREFIX_PROGRAM(wmaker)
 730
 731 dnl Support for PIXMAPDIR option
 732 dnl ============================
 733 AC_ARG_WITH(pixmapdir,
 734 [  --with-pixmapdir=PATH   specify where pixmaps are located [DATADIR/pixmaps]])
 735
 736 if test "x$with_pixmapdir" != "x"; then
 737         pixmapdir=$with_pixmapdir
 738 else
 739         pixmapdir=`eval echo ${datadir}/pixmaps`
 740 fi
 741
 742 AC_DEFINE_UNQUOTED(PIXMAPDIR, "$pixmapdir")
 743
 744 pkgdatadir=`eval echo $datadir`
 745 AC_DEFINE_UNQUOTED(PKGDATADIR, "$pkgdatadir/WindowMaker")
 746
 747 _sysconfdir=`eval echo $sysconfdir`
 748 AC_DEFINE_UNQUOTED(SYSCONFDIR, "$_sysconfdir")
 749
 750
 751 dnl Support for GNUSTEP_LOCAL_ROOT, for WPrefs.app
 752 dnl ==============================================
 753
 754 appspath=""
 755
 756 AC_ARG_WITH(appspath,
 757 [  --with-appspath=PATH    specify the directory for GNUstep applications], appspath=$withval )
 758
 759 if test "x$appspath" = "x"; then
 760     gnustepdir='$(prefix)/GNUstep'
 761
 762     if test "x$GNUSTEP_LOCAL_ROOT" != "x" ; then
 763         gnustepdir=`echo "$GNUSTEP_LOCAL_ROOT" | sed -e "s|^${prefix}|prefix|"`
 764         gnustepdir=`echo $gnustepdir | sed -e 's|^prefix|${prefix}|'`
 765     fi
 766
 767     with_appspath=$gnustepdir/Apps
 768 fi
 769
 770 wprefsdir=$with_appspath/WPrefs.app
 771
 772 AC_SUBST(wprefsdir)
 773
 774
 775 dnl Enable User Defined Menu thing
 776 dnl ==================================
 777 AC_ARG_ENABLE(usermenu,
 778 [  --enable-usermenu       user defined menus for applications
 779 ],
 780 if test "$enableval" = yes; then
 781         AC_DEFINE(USER_MENU)
 782 fi
 783 )
 784
 785
 786 dnl
 787 dnl Nicolai:  Program tests for Documentation Section
 788 dnl =================================================
 789 dnl DOCTYPES=""
 790 dnl AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, ,$PATH)
 791 dnl if test "x$MAKEINFO" != "x" ; then
 792 dnl       DOCTYPES="$DOCTYPES info_doc"
 793 dnl fi
 794 dnl AC_CHECK_PROG(TEX, tex, tex, ,$PATH)
 795 dnl if test "x$TEX" != "x" ; then
 796 dnl       DOCTYPES="$DOCTYPES dvi_doc"
 797 dnl fi
 798 dnl AC_CHECK_PROG(DVIPS, dvips, dvips, ,$PATH)
 799 dnl if test "x$DVIPS" != "x" ; then
 800 dnl       DOCTYPES="$DOCTYPES ps_doc"
 801 dnl fi
 802 dnl AC_CHECK_PROG(PERL, perl, perl, ,$PATH)
 803 dnl if test "x$PERL" != "x" ; then
 804 dnl       DOCTYPES="$DOCTYPES html_doc"
 805 dnl fi
 806 dnl AC_PATH_PROG(PERL_PATH, perl, perl, ,$PATH)
 807 dnl AC_CHECK_PROG(TEXI2HTML, texi2html, texi2html, ,$PATH)
 808
 809 dnl AC_SUBST(DOCTYPES)
 810
 811 AC_OUTPUT(Makefile po/Makefile util/Makefile test/Makefile \
 812         WINGs/Makefile WINGs/WINGs/Makefile WINGs/Documentation/Makefile \
 813         WINGs/Examples/Makefile WINGs/Resources/Makefile WINGs/Tests/Makefile \
 814         WINGs/Extras/Makefile WINGs/po/Makefile \
 815         wmlib/Makefile wrlib/Makefile src/Makefile src/wconfig.h \
 816         doc/Makefile doc/sk/Makefile \
 817         WindowMaker/Makefile WindowMaker/Backgrounds/Makefile \
 818         WindowMaker/Defaults/Makefile WindowMaker/IconSets/Makefile \
 819         WindowMaker/Icons/Makefile WindowMaker/Pixmaps/Makefile \
 820         WindowMaker/Styles/Makefile WindowMaker/Themes/Makefile \
 821         WPrefs.app/Makefile WPrefs.app/tiff/Makefile WPrefs.app/xpm/Makefile \
 822         WPrefs.app/po/Makefile \
 823         contrib/Makefile contrib/WindowMaker.spec )
 824 #       plugins/Makefile plugins/libwmfun/Makefile)
 825
 826
 827
 828 dnl
 829 dnl Output some helpful data for compiling wraster and WINGs/WUtil apps
 830 dnl ===================================================================
 831 dnl
 832
 833 dnl echo "WFLAGS=\"$LIBPL_INC_PATH -I$prefix/include\"" > WINGs-flags
 834 dnl echo "WLIBS=\"-L$exec_prefix/lib -lWINGs -lwraster $LIBPL_LIBS $GFXLIBS -lm\""\
 835 dnl     | sed -e 's|\$(prefix)|'"$prefix|" >> WINGs-flags
 836
 837 dnl The #lp# and #rp# stuff below is a hack because [ and ] get lost when
 838 dnl parsed by m4
 839
 840 cat <<EOF >get-wraster-flags
 841 #!/bin/sh
 842
 843 WCFLAGS="$inc_search_path"
 844 WLFLAGS="$lib_search_path"
 845 WLIBS="-lwraster $GFXLIBS $XLIBS -lm"
 846
 847 usage="Usage: get-wraster-flags #lp#--cflags#rp# #lp#--ldflags#rp# #lp#--libs#rp#"
 848
 849 if test \$# -eq 0; then
 850       echo "\${usage}" 1>&2
 851       exit 1
 852 fi
 853
 854 while test \$# -gt 0; do
 855   case \$1 in
 856     --cflags)
 857         echo \$WCFLAGS
 858         ;;
 859     --ldflags|--lflags)
 860         echo \$WLFLAGS
 861         ;;
 862     --libs)
 863         echo \$WLIBS
 864         ;;
 865     *)
 866         echo "\${usage}" 1>&2
 867         exit 1
 868         ;;
 869   esac
 870   shift
 871 done
 872
 873
 874 EOF
 875
 876 cat <<EOF >get-wings-flags
 877 #!/bin/sh
 878
 879 WCFLAGS="$inc_search_path"
 880 WLFLAGS="$lib_search_path"
 881 WLIBS="-lWINGs -lwraster $GFXLIBS $XLIBS -lm $NETLIBS $INTLIBS"
 882
 883 usage="Usage: get-wings-flags #lp#--cflags#rp# #lp#--ldflags#rp# #lp#--libs#rp#"
 884
 885 if test \$# -eq 0; then
 886       echo "\${usage}" 1>&2
 887       exit 1
 888 fi
 889
 890 while test \$# -gt 0; do
 891   case \$1 in
 892     --cflags)
 893         echo \$WCFLAGS
 894         ;;
 895     --ldflags|--lflags)
 896         echo \$WLFLAGS
 897         ;;
 898     --libs)
 899         echo \$WLIBS
 900         ;;
 901     *)
 902         echo "\${usage}" 1>&2
 903         exit 1
 904         ;;
 905   esac
 906   shift
 907 done
 908
 909
 910 EOF
 911
 912 cat <<EOF >get-wutil-flags
 913 #!/bin/sh
 914
 915 WCFLAGS="-I`eval echo ${includedir}`"
 916 WLFLAGS="-L${_libdir}"
 917 WLIBS="-lWUtil $NETLIBS $INTLIBS"
 918
 919 usage="Usage: get-wutil-flags #lp#--cflags#rp# #lp#--ldflags#rp# #lp#--libs#rp#"
 920
 921 if test \$# -eq 0; then
 922       echo "\${usage}" 1>&2
 923       exit 1
 924 fi
 925
 926 while test \$# -gt 0; do
 927   case \$1 in
 928     --cflags)
 929         echo \$WCFLAGS
 930         ;;
 931     --ldflags|--lflags)
 932         echo \$WLFLAGS
 933         ;;
 934     --libs)
 935         echo \$WLIBS
 936         ;;
 937     *)
 938         echo "\${usage}" 1>&2
 939         exit 1
 940         ;;
 941   esac
 942   shift
 943 done
 944
 945
 946 EOF
 947
 948 sed 's/#lp#/[/g' get-wraster-flags | sed 's/#rp#/]/g' > wrlib/get-wraster-flags
 949 sed 's/#lp#/[/g' get-wings-flags | sed 's/#rp#/]/g' > WINGs/get-wings-flags
 950 sed 's/#lp#/[/g' get-wutil-flags | sed 's/#rp#/]/g' > WINGs/get-wutil-flags
 951
 952 chmod 755 wrlib/get-wraster-flags WINGs/get-wings-flags WINGs/get-wutil-flags
 953
 954 rm -f get-wraster-flags get-wings-flags get-wutil-flags
 955
 956
 957 dnl
 958 dnl Spit out the configuration
 959 dnl ==========================
 960
 961 supported_gfx="$supported_gfx builtin-PPM"
 962
 963 if test "x$MOFILES" = "x"; then
 964         mof=none
 965 else
 966         mof=$MOFILES
 967 fi
 968
 969
 970 echo
 971 echo "Window Maker was configured as follows:"
 972 echo
 973 echo "Installation path prefix: $prefix"
 974 echo "Installation path prefix for binaries: $_bindir"
 975 echo "Installation path for WPrefs.app: $wprefsdir" | sed -e 's|\$(prefix)|'"$prefix|"
 976 echo "Graphic format libraries: $supported_gfx"
 977 if test x$hermes_support = xyes; then
 978     echo "Hermes support for wrlib enabled"
 979 fi
 980 dnl echo "Sound support: yes"
 981 echo "Translated message files to install: $mof"
 982 if test "x$MOFILES" != "x"; then
 983         echo "Installation path of translated messages: $NLSDIR" | sed -e 's|\$(prefix)|'"$prefix|"
 984 fi
 985
 986 dnl WM_PRINT_REDCRAP_BUG_STATUS
 987
 988 if test "x$ac_cv_header_jpeglib_h" != xyes; then
 989 echo "WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"
 990 echo
 991 echo "JPEG support will not be included because the JPEG library is"
 992 echo "not installed correctly or was not found. Background images"
 993 echo "from themes will not display as they usually are JPEG files."
 994 echo
 995 echo "To fix, download and install the jpeg library and/or make sure you"
 996 echo "installed all jpeg related packages, SPECIALLY the development packages"
 997 echo "like jpeg-devel (if you use some prepackaged version of libjpeg)."
 998 echo
 999 echo "WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"
1000 fi
1001
1002
1003 dnl This is for Emacs.  I'm lazy, I know... (nicolai)
1004 dnl ================================================
1005 dnl Local Variables:
1006 dnl compile-command: "autoconf"
1007 dnl End:
1008