configure.ac

   1 dnl ============================================================================
   2 dnl
   3 dnl Window Maker autoconf input
   4 dnl
   5 AC_COPYRIGHT([Copyright (c) 2001-2015 The Window Maker Team])
   6 dnl
   7 dnl ============================================================================
   8 dnl
   9 dnl This program is free software; you can redistribute it and/or modify
  10 dnl it under the terms of the GNU General Public License as published by
  11 dnl the Free Software Foundation; either version 2 of the License, or
  12 dnl (at your option) any later version.
  13 dnl
  14 dnl This program is distributed in the hope that it will be useful,
  15 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 dnl GNU General Public License for more details.
  18 dnl
  19 dnl You should have received a copy of the GNU General Public License along
  20 dnl with this program; see the file COPYING.
  21 dnl
  22 dnl ============================================================================
  23 dnl
  24 dnl Process with: ./autogen.sh
  25
  26
  27 dnl Due to a bug in Autoconf 2.68 (apparently a regression), we need at least
  28 dnl version 2.68b which includes this patch:
  29 dnl   http://git.savannah.gnu.org/gitweb/?p=autoconf.git;a=commit;h=2b0d95faef68d7ed7c08b0edb9ff1c38728376fa
  30 dnl
  31 dnl Because the 2.69 was released only a few month later, let's just ask for it
  32 AC_PREREQ([2.69])
  33
  34
  35 dnl Configuration for Autoconf and Automake
  36 dnl =======================================
  37 AC_INIT([WindowMaker],[0.95.9],[wmaker-dev@googlegroups.com],[WindowMaker],[http://www.windowmaker.org/])
  38 AC_CONFIG_MACRO_DIR([m4])
  39 AC_CONFIG_HEADERS([config.h])
  40
  41 dnl We need the EXTRA_xxx_DEPENDENCIES keyword in Makefiles which have been
  42 dnl introduced in the version 1.11.3; because the 1.12 was realeased shortly
  43 dnl after, we just ask for it
  44 AM_INIT_AUTOMAKE([1.12 silent-rules -Wno-portability])
  45
  46 dnl Reference file used by 'configure' to make sure the path to sources is valid
  47 AC_CONFIG_SRCDIR([src/WindowMaker.h])
  48
  49 dnl Include at the end of 'config.h', this file is generated by top-level Makefile
  50 AH_BOTTOM([@%:@include "config-paths.h"])
  51
  52
  53 dnl libtool library versioning
  54 dnl ==========================
  55 dnl
  56 dnl current
  57 dnl revision
  58 dnl age
  59 dnl
  60 dnl 1. Start with version information of ‘0:0:0’ for each libtool library.
  61 dnl 2. Update the version information only immediately before a public
  62 dnl release of your software. More frequent updates are unnecessary, and
  63 dnl only guarantee that the current interface number gets larger faster.
  64 dnl 3. If the library source code has changed at all since the last
  65 dnl update, then increment revision (‘c:r:a’ becomes ‘c:r+1:a’).
  66 dnl 4. If any interfaces have been added, removed, or changed since the
  67 dnl last update, increment current, and set revision to 0.
  68 dnl 5. If any interfaces have been added since the last public release,
  69 dnl then increment age.
  70 dnl 6. If any interfaces have been removed or changed since the last
  71 dnl public release, then set age to 0.
  72 dnl
  73 dnl libwraster
  74 WRASTER_CURRENT=6
  75 WRASTER_REVISION=0
  76 WRASTER_AGE=0
  77 WRASTER_VERSION=$WRASTER_CURRENT:$WRASTER_REVISION:$WRASTER_AGE
  78 AC_SUBST(WRASTER_VERSION)
  79 dnl
  80 dnl libWINGs
  81 WINGS_CURRENT=4
  82 WINGS_REVISION=0
  83 WINGS_AGE=1
  84 WINGS_VERSION=$WINGS_CURRENT:$WINGS_REVISION:$WINGS_AGE
  85 AC_SUBST(WINGS_VERSION)
  86 dnl
  87 dnl libWUtil
  88 WUTIL_CURRENT=5
  89 WUTIL_REVISION=0
  90 WUTIL_AGE=0
  91 WUTIL_VERSION=$WUTIL_CURRENT:$WUTIL_REVISION:$WUTIL_AGE
  92 AC_SUBST(WUTIL_VERSION)
  93
  94
  95 dnl Checks for programs
  96 dnl ===================
  97 AC_PROG_CC
  98 WM_PROG_CC_C11
  99 AC_PROG_LN_S
 100 AC_PROG_GCC_TRADITIONAL
 101 LT_INIT
 102
 103
 104 dnl Debugging Options
 105 dnl =================
 106 AC_ARG_ENABLE([debug],
 107     [AS_HELP_STRING([--enable-debug], [enable debugging options, @<:@default=no@:>@])],
 108     [AS_CASE(["$enableval"],
 109         [yes], [debug=yes],
 110         [no],  [debug=no],
 111         [AC_MSG_ERROR([bad value $enableval for --enable-debug])] )],
 112     [debug=no])
 113 AS_IF([test "x$debug" = "xyes"],
 114     [dnl This flag should have already been detected and added, but if user
 115      dnl provided an explicit CFLAGS it may not be the case
 116      AS_IF([echo " $CFLAGS " | grep " -g " 2>&1 > /dev/null],
 117            [@%:@ Debug symbol already activated],
 118            [AX_CFLAGS_GCC_OPTION([-g])])
 119      dnl
 120      dnl This flag generally makes debugging nightmarish, remove it if present
 121      CFLAGS="`echo "$CFLAGS" | sed -e 's/-fomit-frame-pointer *//' `"
 122      dnl
 123      dnl Enable internal debug code
 124      CPPFLAGS="$CPPFLAGS -DDEBUG"
 125 ],  [dnl
 126      dnl When debug is not enabled, the user probably does not wants to keep
 127      dnl assertions in the final program
 128      CPPFLAGS="$CPPFLAGS -DNDEBUG"
 129 ])
 130
 131
 132 AX_CFLAGS_GCC_OPTION([-Wall])
 133 AX_CFLAGS_GCC_OPTION([-Wextra -Wno-sign-compare])
 134 dnl
 135 dnl The use of trampolines cause code that can crash on some secured OS, it is
 136 dnl also known to be a source of crash if not used properly, in a more general
 137 dnl way it tends to generate binary code that may not be optimal, and it is
 138 dnl not compatible with the 'nested-func-to-macro' workaround
 139 WM_CFLAGS_CHECK_FIRST([-Wtrampolines],
 140          [-Werror=trampolines  dnl try to generate an error if possible
 141           -Wtrampolines        dnl if not, try to fall back to a simple warning
 142          ])
 143 dnl
 144 AS_IF([test "x$debug" = "xyes"],
 145     [dnl When debug is enabled, we try to activate more checks from
 146      dnl the compiler. They are on independant check because the
 147      dnl macro checks all the options at once, but we may have cases
 148      dnl where some options are not supported and we don't want to
 149      dnl loose all of them.
 150      dnl
 151      dnl clang, suggest parenthesis on bit operations that could be
 152      dnl misunderstood due to C operator precedence
 153      AX_CFLAGS_GCC_OPTION([-Wbitwise-op-parentheses])
 154      dnl
 155      dnl Points at code that gcc thinks is so complicated that gcc
 156      dnl gives up trying to optimize, which probably also means it is
 157      dnl too complicated to maintain
 158      AX_CFLAGS_GCC_OPTION([-Wdisabled-optimization])
 159      dnl
 160      dnl Because of C's type promotion, the compiler has to generate
 161      dnl less optimal code when a double constant is used in a
 162      dnl float expression
 163      AX_CFLAGS_GCC_OPTION([-Wdouble-promotion])
 164      dnl
 165      dnl Floating-point comparison is not a good idea
 166      AX_CFLAGS_GCC_OPTION([-Wfloat-equal])
 167      dnl
 168      dnl clang warns about constants that may have portability issues due
 169      dnl to the endianness of the host
 170      AX_CFLAGS_GCC_OPTION([-Wfour-char-constants])
 171      dnl
 172      dnl clang warns about constant that may be too big to be portable
 173      AX_CFLAGS_GCC_OPTION([-Wliteral-range])
 174      dnl
 175      dnl Try to report misuses of '&' versus '&&' and similar
 176      AX_CFLAGS_GCC_OPTION([-Wlogical-op])
 177      dnl
 178      dnl clang, reports cases where the code assumes everyone is an
 179      dnl expert in C operator precedence... which is unlikely!
 180      AX_CFLAGS_GCC_OPTION([-Wlogical-op-parentheses])
 181      dnl
 182      dnl Reports declaration of global things that are done inside
 183      dnl a local environment, instead of using the appropriate
 184      dnl header
 185      AX_CFLAGS_GCC_OPTION([-Wnested-externs])
 186      dnl
 187      dnl Warn about constant strings that could pose portability issues
 188      AX_CFLAGS_GCC_OPTION([-Woverlength-strings])
 189      dnl
 190      dnl Use of 'sizeof()' on inappropriate pointer types
 191      AX_CFLAGS_GCC_OPTION([-Wpointer-arith])
 192      dnl
 193      dnl Having more than 1 prototype for a function makes code updates
 194      dnl more difficult, so try to avoid it
 195      AX_CFLAGS_GCC_OPTION([-Wredundant-decls])
 196      dnl
 197      dnl clang, detect some misuses of sizeof. We also count in our code
 198      dnl on the use of the macro 'wlength' which contains a check if the
 199      dnl compiler support C11's static_assert
 200      AX_CFLAGS_GCC_OPTION([-Wsizeof-array-argument])
 201      dnl
 202      dnl Prototype of function must be explicit, no deprecated K&R syntax
 203      dnl and no empty argument list which prevents compiler from doing
 204      dnl type checking when using the function
 205      WM_CFLAGS_GCC_OPTION_STRICTPROTO
 206      dnl
 207      dnl Proper attributes helps the compiler to produce better code
 208      WM_CFLAGS_CHECK_FIRST([format attribute suggest],
 209          [-Wsuggest-attribute=format  dnl new gcc syntax
 210           -Wmissing-format-attribute  dnl old gcc syntax, clang
 211          ])
 212      WM_CFLAGS_CHECK_FIRST([no-return attribute suggest],
 213          [-Wsuggest-attribute=noreturn  dnl gcc syntax
 214           -Wmissing-noreturn            dnl clang syntax
 215          ])
 216      dnl
 217      dnl GCC provides a couple of checks to detect incorrect macro uses
 218      AX_CFLAGS_GCC_OPTION([-Wundef])
 219      WM_CFLAGS_GCC_OPTION_UNUSEDMACROS
 220      dnl
 221      dnl clang reports stuff marked unused but which is actually used
 222      AX_CFLAGS_GCC_OPTION([-Wused-but-marked-unused])
 223 ], [dnl
 224      dnl When debug not enabled, we try to avoid some non-necessary
 225      dnl messages from the compiler
 226      dnl
 227      dnl To support legacy X servers, we have sometime to use
 228      dnl functions marked as deprecated. We do not wish our users
 229      dnl to be worried about it
 230      AX_CFLAGS_GCC_OPTION([-Wno-deprecated])
 231      AX_CFLAGS_GCC_OPTION([-Wno-deprecated-declarations])
 232 ])
 233
 234
 235 dnl Support for Nested Functions by the compiler
 236 dnl ============================================
 237 WM_PROG_CC_NESTEDFUNC
 238
 239
 240 dnl Posix thread
 241 dnl ============
 242 dnl they are used by util/wmiv
 243 AX_PTHREAD
 244
 245
 246 dnl Tracking on what is detected for final status
 247 dnl =============================================
 248 unsupported=""
 249 supported_core=""
 250 supported_xext=""
 251 supported_gfx=""
 252
 253
 254 dnl Platform-specific Makefile setup
 255 dnl ================================
 256 AS_CASE(["$host"],
 257     [*-*-linux*|*-*-cygwin*|*-gnu*], [WM_OSDEP="linux" ; CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=600"],
 258     [*-*-freebsd*|*-k*bsd-gnu*],     [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=600 -DFREEBSD"],
 259     [*-*-netbsd*],                   [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -DNETBSD"],
 260     [*-*-openbsd*],                  [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -DOPENBSD"],
 261     [*-*-dragonfly*],                [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -DDRAGONFLYBSD"],
 262     [*-apple-darwin*],               [WM_OSDEP="darwin"],
 263     [*-*-solaris*],                  [WM_OSDEP="stub"],  dnl  solaris.c when done
 264     [WM_OSDEP="stub"])
 265 AM_CONDITIONAL([WM_OSDEP_LINUX],   [test "x$WM_OSDEP" = "xlinux"])
 266 AM_CONDITIONAL([WM_OSDEP_BSD],     [test "x$WM_OSDEP" = "xbsd"])
 267 AM_CONDITIONAL([WM_OSDEP_DARWIN],  [test "x$WM_OSDEP" = "xdarwin"])
 268 AM_CONDITIONAL([WM_OSDEP_GENERIC], [test "x$WM_OSDEP" = "xstub"])
 269
 270
 271 dnl the prefix
 272 dnl ==========
 273 dnl
 274 dnl move this earlier in the script... anyone know why this is handled
 275 dnl in such a bizarre way?
 276
 277 test "x$prefix" = xNONE && prefix=$ac_default_prefix
 278 dnl Let make expand exec_prefix.
 279 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 280
 281
 282 _bindir=`eval echo $bindir`
 283 _bindir=`eval echo $_bindir`
 284 _libdir=`eval echo $libdir`
 285 _libdir=`eval echo $_libdir`
 286
 287 dnl ===============================================
 288 dnl Specify paths to look for libraries and headers
 289 dnl ===============================================
 290 AC_ARG_WITH(libs-from, AS_HELP_STRING([--with-libs-from], [pass compiler flags to look for libraries]),
 291         [lib_search_path="$withval"], [lib_search_path='-L${libdir}'])
 292
 293 AC_ARG_WITH(incs-from, AS_HELP_STRING([--with-incs-from], [pass compiler flags to look for header files]),
 294         [inc_search_path="$withval"], [inc_search_path='-I${includedir}'])
 295
 296
 297 dnl Features Configuration
 298 dnl ======================
 299 AC_ARG_ENABLE([animations],
 300     [AS_HELP_STRING([--disable-animations], [disable permanently animations @<:@default=enabled@:>@])],
 301     [AS_CASE(["$enableval"],
 302         [yes|no], [],
 303         [AC_MSG_ERROR([bad value $enableval for --enable-animations])])],
 304     [enable_animations="yes"])
 305 AS_IF([test "x$enable_animations" = "xno"],
 306     [unsupported="$unsupported Animations"],
 307     [AC_DEFINE([USE_ANIMATIONS], [1], [Defined when user did not request to disable animations])
 308      supported_core="$supported_core Animations"])
 309
 310
 311 AC_ARG_ENABLE([mwm-hints],
 312     [AS_HELP_STRING([--disable-mwm-hints], [disable support for Motif WM hints @<:@default=enabled@:>@])],
 313     [AS_CASE(["$enableval"],
 314         [yes|no], [],
 315         [AC_MSG_ERROR([bad value $enableval for --enable-mwm-hints])])],
 316     [enable_mwm_hints="yes"])
 317 AS_IF([test "x$enable_mwm_hints" = "xno"],
 318     [unsupported="$unsupported MWMHints"],
 319     [AC_DEFINE([USE_MWM_HINTS], [1], [Defined when used did not request to disable Motif WM hints])
 320      supported_core="$supported_core MWMHints"])
 321 AM_CONDITIONAL([USE_MWM_HINTS], [test "x$enable_mwm_hints" != "xno"])
 322
 323
 324 dnl Boehm GC
 325 dnl ========
 326 AC_ARG_ENABLE([boehm-gc],
 327     [AS_HELP_STRING([--enable-boehm-gc], [use Boehm GC instead of the default libc malloc() [default=no]])],
 328     [AS_CASE(["$enableval"],
 329         [yes], [with_boehm_gc=yes],
 330         [no],  [with_boehm_gc=no],
 331         [AC_MSG_ERROR([bad value $enableval for --enable-boehm-gc])] )],
 332     [with_boehm_gc=no])
 333 AS_IF([test "x$with_boehm_gc" = "xyes"],
 334     AC_SEARCH_LIBS([GC_malloc], [gc],
 335         [AC_DEFINE(USE_BOEHM_GC, 1, [Define if Boehm GC is to be used])],
 336         [AC_MSG_FAILURE([--enable-boehm-gc specified but test for libgc failed])]))
 337
 338
 339 dnl LCOV
 340 dnl ====
 341 AC_ARG_ENABLE([lcov],
 342     [AS_HELP_STRING([--enable-lcov[=output-directory]], [enable coverage data generation using LCOV (GCC only) [default=no]])],
 343     [],
 344     [enable_lcov=no])
 345
 346 AS_IF([test "x$enable_lcov" != "xno"],
 347     [AX_CFLAGS_GCC_OPTION(-fprofile-arcs -ftest-coverage)
 348     AS_IF([test "x$enable_lcov" = "xyes"],
 349         [lcov_output_directory="coverage-report"],
 350         [lcov_output_directory="${enable_lcov}/coverage-report"])
 351     AC_SUBST(lcov_output_directory)])
 352
 353 AM_CONDITIONAL([USE_LCOV], [test "x$enable_lcov" != "xno"])
 354
 355
 356 dnl ============================
 357 dnl Checks for library functions
 358 dnl ============================
 359 AC_FUNC_MEMCMP
 360 AC_FUNC_VPRINTF
 361 WM_FUNC_SECURE_GETENV
 362 AC_CHECK_FUNCS(gethostname select poll strcasecmp strncasecmp \
 363                setsid mallinfo mkstemp sysconf)
 364 AC_SEARCH_LIBS([strerror], [cposix])
 365
 366 dnl nanosleep is generally available in standard libc, although not always the
 367 dnl case. One known example is Solaris which needs -lrt
 368 AC_SEARCH_LIBS([nanosleep], [rt], [],
 369     [AC_MSG_ERROR([function 'nanosleep' not found, please report to wmaker-dev@googlegroups.com])])
 370
 371 dnl the flag 'O_NOFOLLOW' for 'open' is used in WINGs
 372 WM_FUNC_OPEN_NOFOLLOW
 373
 374
 375 dnl Check for strlcat/strlcpy
 376 dnl =========================
 377 AC_ARG_WITH([libbsd],
 378   [AS_HELP_STRING([--without-libbsd], [do not use libbsd for strlcat and strlcpy [default=check]])],
 379   [AS_IF([test "x$with_libbsd" != "xno"],
 380     [with_libbsd=bsd]
 381     [with_libbsd=]
 382   )],
 383   [with_libbsd=bsd])
 384
 385 tmp_libs=$LIBS
 386 AC_SEARCH_LIBS([strlcat],[$with_libbsd],
 387   [AC_DEFINE(HAVE_STRLCAT, 1, [Define if strlcat is available])],
 388   [],
 389   []
 390 )
 391 AC_SEARCH_LIBS([strlcpy],[$with_libbsd],
 392   [AC_DEFINE(HAVE_STRLCAT, 1, [Define if strlcpy is available])],
 393   [],
 394   []
 395 )
 396 LIBS=$tmp_libs
 397
 398 LIBBSD=
 399 AS_IF([test "x$ac_cv_search_strlcat" = "x-lbsd" -o "x$ac_cv_search_strlcpy" = "x-lbsd"],
 400   [LIBBSD=-lbsd
 401    AC_CHECK_HEADERS([bsd/string.h])]
 402 )
 403 AC_SUBST(LIBBSD)
 404
 405
 406 dnl Check for OpenBSD kernel memory interface - kvm(3)
 407 dnl ==================================================
 408 AS_IF([test "x$WM_OSDEP" = "xbsd"],
 409   AC_SEARCH_LIBS([kvm_openfiles], [kvm]) )
 410
 411
 412 dnl Check for inotify
 413 dnl =================
 414 dnl It is used by WindowMaker to reload automatically the configuration when the
 415 dnl user changed it using WPref or wdwrite
 416 AC_CHECK_HEADERS([sys/inotify.h],
 417     [AC_DEFINE([HAVE_INOTIFY], [1], [Check for inotify])])
 418
 419
 420 dnl Check for syslog
 421 dnl ================
 422 dnl It is used by WUtil to log the wwarning, werror and wfatal
 423 AC_CHECK_HEADERS([syslog.h], [AC_DEFINE([HAVE_SYSLOG], [1], [Check for syslog])])
 424
 425
 426 dnl Checks for header files
 427 dnl =======================
 428 AC_HEADER_SYS_WAIT
 429 AC_HEADER_TIME
 430 AC_CHECK_HEADERS(fcntl.h limits.h sys/ioctl.h libintl.h poll.h malloc.h ctype.h \
 431                  string.h strings.h)
 432
 433
 434 dnl Checks for typedefs, structures, and compiler characteristics
 435 dnl =============================================================
 436 AC_C_CONST
 437 AC_C_INLINE
 438 WM_C_NORETURN
 439 AC_TYPE_SIZE_T
 440 AC_TYPE_PID_T
 441 WM_TYPE_SIGNAL
 442
 443
 444 dnl pkg-config
 445 dnl ==========
 446 PKG_PROG_PKG_CONFIG
 447 AS_IF([test -z "$PKG_CONFIG"],[AC_MSG_ERROR([pkg-config is required.])])
 448
 449
 450
 451 dnl Internationalization
 452 dnl ====================
 453 dnl Detect the language for translations to be installed and check
 454 dnl that the gettext environment works
 455 WM_I18N_LANGUAGES
 456 WM_I18N_XGETTEXT
 457 WM_I18N_MENUTEXTDOMAIN
 458 WM_LIBRARY_CONSTRUCTORS
 459
 460 dnl ===========================================
 461 dnl             Stuff that uses X
 462 dnl ===========================================
 463
 464 AC_PATH_XTRA
 465
 466 AS_IF([test "x$no_x" = "xyes"],
 467     [AC_MSG_ERROR([The path for the X11 files not found!
 468 Make sure you have X and its headers and libraries (the -devel packages
 469 in Linux) installed.])])
 470
 471 X_LIBRARY_PATH=$x_libraries
 472 XCFLAGS="$X_CFLAGS"
 473 XLFLAGS="$X_LIBS"
 474 XLIBS="-lX11 $X_EXTRA_LIBS"
 475
 476 lib_search_path="$lib_search_path $XLFLAGS"
 477 inc_search_path="$inc_search_path $XCFLAGS"
 478
 479 AC_SUBST(X_LIBRARY_PATH)
 480
 481
 482 dnl Decide which locale function to use, setlocale() or _Xsetlocale()
 483 dnl by MANOME Tomonori
 484 dnl ===========================================
 485 WM_I18N_XLOCALE
 486
 487
 488
 489 dnl Check whether XInternAtoms() exist
 490 dnl ==================================
 491 AC_CHECK_LIB([X11], [XInternAtoms],
 492     [AC_DEFINE([HAVE_XINTERNATOMS], [1],
 493         [define if your X server has XInternAtoms() (set by configure)])],
 494     [], [$XLFLAGS $XLIBS])
 495
 496
 497 dnl Check whether XConvertCase() exist
 498 dnl ==================================
 499 AC_CHECK_LIB([X11], [XConvertCase],
 500     [AC_DEFINE([HAVE_XCONVERTCASE], [1],
 501         [define if your X server has XConvertCase() (set by configure)])],
 502     [], [$XLFLAGS $XLIBS])
 503
 504
 505 dnl XKB keyboard language status
 506 dnl ============================
 507 AC_ARG_ENABLE([modelock],
 508     [AS_HELP_STRING([--enable-modelock], [XKB keyboard language status support])],
 509     [AS_CASE([$enableval],
 510         [yes|no], [],
 511         [AC_MSG_ERROR([bad value '$enableval' for --enable-modelock])])],
 512     [enable_modelock=no])
 513 AS_IF([test "x$enable_modelock" = "xyes"],
 514     [AC_DEFINE([XKB_MODELOCK], [1], [whether XKB language MODELOCK should be enabled]) ])
 515
 516
 517 dnl XDND Drag-nd-Drop support
 518 dnl =========================
 519 AC_ARG_ENABLE([xdnd],
 520     [AS_HELP_STRING([--disable-xdnd], [disable support for Drag-and-Drop on the dock @<:@default=enabled@:>@])],
 521     [AS_CASE(["$enableval"],
 522         [yes|no], [],
 523         [AC_MSG_ERROR([bad value $enableval for --disable-xdnd]) ]) ],
 524     [enable_xdnd=yes])
 525 AS_IF([test "x$enable_xdnd" = "xyes"],
 526     [supported_core="$supported_core XDnD"
 527      AC_DEFINE([USE_DOCK_XDND], [1], [whether Drag-and-Drop on the dock should be enabled])],
 528     [unsupported="$unsupported XDnd"])
 529 AM_CONDITIONAL([USE_DOCK_XDND], [test "x$enable_xdnd" != "xno"])
 530
 531
 532 dnl Support for ICCCM 2.0 Window Manager replacement
 533 dnl ================================================
 534 AC_ARG_ENABLE([wmreplace],
 535     [AS_HELP_STRING([--enable-wmreplace], [support for ICCCM window manager replacement])],
 536     [AS_CASE([$enableval],
 537         [yes|no], [],
 538         [AC_MSG_ERROR([bad value '$enableval' for --enable-wmreplace])])],
 539     [enable_wmreplace=no])
 540 AS_IF([test "x$enable_wmreplace" = "xyes"],
 541     [AC_DEFINE([USE_ICCCM_WMREPLACE], [1],
 542        [define to support ICCCM protocol for window manager replacement])
 543      supported_xext="$supported_xext WMReplace"])
 544
 545
 546 dnl XShape support
 547 dnl ==============
 548 AC_ARG_ENABLE([shape],
 549     [AS_HELP_STRING([--disable-shape], [disable shaped window extension support])],
 550     [AS_CASE(["$enableval"],
 551         [yes|no], [],
 552         [AC_MSG_ERROR([bad value $enableval for --enable-shape]) ]) ],
 553     [enable_shape=auto])
 554 WM_XEXT_CHECK_XSHAPE
 555
 556
 557 dnl MIT-SHM support
 558 dnl ===============
 559 AC_ARG_ENABLE([shm],
 560     [AS_HELP_STRING([--disable-shm], [disable usage of MIT-SHM extension])],
 561     [AS_CASE(["$enableval"],
 562         [yes|no], [],
 563         [AC_MSG_ERROR([bad value $enableval for --enable-shm]) ]) ],
 564     [enable_shm=auto])
 565 WM_XEXT_CHECK_XSHM
 566
 567
 568 dnl X Misceleanous Utility
 569 dnl ======================
 570 dnl the libXmu is used in WRaster
 571 WM_EXT_CHECK_XMU
 572
 573
 574 dnl XINERAMA support
 575 dnl ================
 576 AC_ARG_ENABLE([xinerama],
 577     [AS_HELP_STRING([--enable-xinerama], [enable Xinerama extension support])],
 578     [AS_CASE(["$enableval"],
 579         [yes|no], [],
 580         [AC_MSG_ERROR([bad value $enableval for --enable-xinerama]) ]) ],
 581     [enable_xinerama=auto])
 582 WM_XEXT_CHECK_XINERAMA
 583
 584
 585 dnl RandR support
 586 dnl =============
 587 AC_ARG_ENABLE([randr],
 588     [AS_HELP_STRING([--enable-randr], [enable RandR extension support (NOT recommended, buggy)])],
 589     [AS_CASE(["$enableval"],
 590         [yes|no], [],
 591         [AC_MSG_ERROR([bad value $enableval for --enable-randr]) ]) ],
 592     [enable_randr=no])
 593 WM_XEXT_CHECK_XRANDR
 594
 595
 596 dnl Math library
 597 dnl ============
 598 dnl libWINGS uses math functions, check whether usage requires linking
 599 dnl against libm
 600 WM_CHECK_LIBM
 601
 602
 603 dnl FontConfig
 604 dnl ==========
 605 dnl libWINGS uses FcPatternDel from libfontconfig
 606 AC_MSG_CHECKING([for fontconfig library])
 607 FCLIBS=`$PKG_CONFIG fontconfig --libs`
 608 if test "x$FCLIBS" = "x" ; then
 609         AC_MSG_RESULT([not found])
 610 else
 611         AC_MSG_RESULT([found])
 612 fi
 613 AC_SUBST(FCLIBS)
 614
 615
 616 dnl Xft2 antialiased font support
 617 dnl =============================
 618
 619 xft=yes
 620 XFTLIBS=""
 621
 622 if test "x$PKG_CONFIG" != x -a "`$PKG_CONFIG xft; echo $?`" = 0; then
 623         XFTCONFIG="$PKG_CONFIG xft"
 624         pkgconfig_xft=yes
 625 else
 626         AC_CHECK_PROG(XFTCONFIG, xft-config, xft-config)
 627 fi
 628
 629 AC_MSG_CHECKING([for the Xft2 library])
 630
 631 if test "x$XFTCONFIG" != x; then
 632         XFTLIBS=`$XFTCONFIG --libs`
 633         XFTFLAGS=`$XFTCONFIG --cflags`
 634         AC_MSG_RESULT([found])
 635 else
 636         AC_MSG_RESULT([not found])
 637         echo
 638         echo "ERROR!!! libXft2 is not installed or could not be found."
 639         echo "         Xft2 is a requirement for building Window Maker."
 640         echo "         Please install it (along with fontconfig) before continuing."
 641         echo
 642         exit 1
 643 fi
 644
 645 minXFT="2.1.0"
 646 goodxft="no"
 647
 648 dnl
 649 dnl The macro below will use $XFTFLAGS (defined above) to find Xft.h
 650 dnl
 651 WM_CHECK_XFT_VERSION($minXFT, goodxft=yes, goodxft=no)
 652
 653 if test "$goodxft" = no; then
 654         echo
 655         echo "ERROR!!! libXft on this system is an old version."
 656         echo "         Please consider upgrading to at least version ${minXFT}."
 657         echo
 658         exit 1
 659 fi
 660
 661 AC_SUBST(XFTFLAGS)
 662 AC_SUBST(XFTLIBS)
 663
 664 dnl PANGO support
 665 dnl =============
 666 pango=no
 667 AC_ARG_ENABLE(pango, AS_HELP_STRING([--enable-pango], [enable Pango text layout support]),
 668                 pango=$enableval, pango=no)
 669
 670 PANGOFLAGS=
 671 PANGOLIBS=
 672 if test "$pango" = yes; then
 673         PANGOLIBS=`$PKG_CONFIG pangoxft --libs`
 674         PANGOFLAGS=`$PKG_CONFIG pangoxft --cflags`
 675         if test "x$PANGOLIBS" = "x" ; then
 676                 AC_MSG_RESULT([not found])
 677         else
 678                 AC_DEFINE(USE_PANGO, 1, [Define if Pango is to be used])
 679                 AC_MSG_RESULT([found])
 680         fi
 681 fi
 682 inc_search_path="$inc_search_path $PANGOFLAGS"
 683 AC_SUBST(PANGOLIBS)
 684
 685 dnl ==============================================
 686 dnl         Graphic Format Libraries
 687 dnl ==============================================
 688
 689 dnl XPM Support
 690 dnl ===========
 691 AC_ARG_ENABLE([xpm],
 692     [AS_HELP_STRING([--disable-xpm], [disable use of XPM pixmaps through libXpm])],
 693     [AS_CASE(["$enableval"],
 694         [yes|no], [],
 695         [AC_MSG_ERROR([bad value $enableval for --enable-xpm])] )],
 696     [enable_xpm=auto])
 697 WM_IMGFMT_CHECK_XPM
 698
 699
 700 # for wmlib
 701 AC_SUBST(XCFLAGS)
 702 # for test
 703 AC_SUBST(XLFLAGS)
 704 AC_SUBST(XLIBS)
 705 AC_SUBST(X_EXTRA_LIBS)
 706
 707 dnl ===============================================
 708 dnl             End of stuff that uses X
 709 dnl ===============================================
 710
 711 dnl EXIF Support
 712 dnl ============
 713 WM_CHECK_LIBEXIF
 714 AS_IF([test "x$LIBEXIF" != "x"],
 715         [AC_DEFINE(HAVE_EXIF, 1, [Define if EXIF can be used])])
 716
 717
 718 dnl PNG Support
 719 dnl ===========
 720 AC_ARG_ENABLE([png],
 721     [AS_HELP_STRING([--disable-png], [disable PNG support through libpng])],
 722     [AS_CASE(["$enableval"],
 723         [yes|no], [],
 724         [AC_MSG_ERROR([bad value $enableval for --enable-png])] )],
 725     [enable_png=auto])
 726 WM_IMGFMT_CHECK_PNG
 727
 728
 729 dnl JPEG Support
 730 dnl ============
 731 AC_ARG_ENABLE([jpeg],
 732     [AS_HELP_STRING([--disable-jpeg], [disable JPEG support through libjpeg])],
 733     [AS_CASE(["$enableval"],
 734         [yes|no], [],
 735         [AC_MSG_ERROR([bad value $enableval for --enable-jpeg])] )],
 736     [enable_jpeg=auto])
 737 WM_IMGFMT_CHECK_JPEG
 738
 739
 740 dnl GIF Support
 741 dnl ============
 742 AC_ARG_ENABLE(gif,
 743     [AS_HELP_STRING([--disable-gif], [disable GIF support through libgif or libungif])],
 744     [AS_CASE(["$enableval"],
 745         [yes|no], [],
 746         [AC_MSG_ERROR([bad value $enableval for --enable-gif])] )],
 747     [enable_gif=auto])
 748 WM_IMGFMT_CHECK_GIF
 749
 750
 751 dnl TIFF Support
 752 dnl ============
 753 AC_ARG_ENABLE([tiff],
 754     [AS_HELP_STRING([--disable-tiff], [disable use of TIFF images through libtiff])],
 755     [AS_CASE(["$enableval"],
 756         [yes|no], [],
 757         [AC_MSG_ERROR([bad value $enableval for --enable-tiff])] )],
 758     [enable_tiff=auto])
 759 WM_IMGFMT_CHECK_TIFF
 760
 761
 762 dnl WEBP Support
 763 dnl ============
 764 AC_ARG_ENABLE([webp],
 765     [AS_HELP_STRING([--disable-webp], [disable WEBP support through libwebp])],
 766     [AS_CASE(["$enableval"],
 767         [yes|no], [],
 768         [AC_MSG_ERROR([bad value $enableval for --enable-webp])] )],
 769     [enable_webp=auto])
 770 WM_IMGFMT_CHECK_WEBP
 771
 772
 773 dnl MagicK Support
 774 dnl ==============
 775 AC_ARG_ENABLE([magick],
 776     [AS_HELP_STRING([--disable-magick], [disable MAGICK support through libMagickWand])],
 777     [AS_CASE(["$enableval"],
 778         [yes|no], [],
 779         [AC_MSG_ERROR([bad value $enableval for --enable-magick])] )],
 780     [enable_magick=auto])
 781 WM_IMGFMT_CHECK_MAGICK
 782
 783
 784 dnl PPM Support
 785 dnl ===========
 786 # The PPM format is always enabled because we have built-in support for the format
 787 # We are not using any external library like libppm
 788 supported_gfx="$supported_gfx builtin-PPM"
 789
 790
 791 # Choice of the default format for icons
 792 AS_IF([test "x$enable_tiff" != "xno"],
 793     [ICONEXT="tiff"],
 794     [ICONEXT="xpm"])
 795
 796
 797 LIBRARY_SEARCH_PATH="$lib_search_path"
 798 HEADER_SEARCH_PATH="$inc_search_path"
 799
 800 AC_SUBST(LIBRARY_SEARCH_PATH)
 801 AC_SUBST(HEADER_SEARCH_PATH)
 802
 803
 804 AC_SUBST(GFXLIBS)
 805 AC_SUBST(ICONEXT)
 806 AM_CONDITIONAL([ICON_EXT_XPM],  [test "x$ICONEXT" = "xxpm"])
 807 AM_CONDITIONAL([ICON_EXT_TIFF], [test "x$ICONEXT" = "xtiff"])
 808
 809
 810 dnl ==============================================
 811 dnl         End of Graphic Format Libraries
 812 dnl ==============================================
 813
 814
 815 dnl
 816 dnl stdlib.h is checked here, because of conflict in jpeglib.h
 817 AC_CHECK_HEADERS(stdlib.h)
 818
 819
 820 dnl Support for PIXMAPDIR option
 821 dnl ============================
 822 AC_ARG_WITH([pixmapdir],
 823     [AS_HELP_STRING([--with-pixmapdir=PATH], [specify where pixmaps are located [DATADIR/pixmaps]])],
 824     [AS_CASE([$withval],
 825         [yes|no], [AC_MSG_ERROR([bad value '$withval' for --with-pixmapdir, expected a path]) ],
 826         [/*],  [], dnl Absolute path, ok
 827         [\$*], [], dnl Assumes it starts with a reference to $prefix or a similar variable, ok
 828         [AC_MSG_ERROR([bad path '$withval' for pixmapdir, expecting an absolute path])])],
 829     [with_pixmapdir=""])
 830
 831 AS_IF([test "x$with_pixmapdir" != "x"],
 832     [pixmapdir="$with_pixmapdir"],
 833     [pixmapdir='${datadir}/pixmaps'])
 834 AC_SUBST([pixmapdir])dnl
 835
 836
 837 dnl Support for GNUSTEP_LOCAL_ROOT, for WPrefs.app
 838 dnl ==============================================
 839 AC_ARG_WITH([gnustepdir],
 840     [AS_HELP_STRING([--with-gnustepdir=PATH], [specify the directory for GNUstep applications])],
 841     [AS_CASE([$withval],
 842         [yes|no], [AC_MSG_ERROR([bad value '$withval' for --with-gnustepdir, expected a path]) ],
 843         [/*],  [], dnl Absolute path, ok
 844         [\$*], [], dnl Assumes it starts with a reference to $prefix or a similar variable, ok
 845         [AC_MSG_ERROR([bad path '$withval' for gnustepdir, expecting an absolute path])])],
 846     [dnl If no command-line option was given, we use $GNUSTEP_LOCAL_ROOT if it was set
 847      with_gnustepdir="$GNUSTEP_LOCAL_ROOT"])
 848
 849 AS_IF([test "x$with_gnustepdir" = "x"],
 850     [dnl No path specified, use default
 851      wprefs_base_dir=${prefix}
 852      wprefs_datadir="${datadir}/WPrefs"
 853      wprefs_bindir="${bindir}"],
 854     [dnl User specified base path
 855      wprefs_base_dir="$with_gnustepdir/Applications"
 856      wprefs_datadir="$wprefs_base_dir/WPrefs.app"
 857      wprefs_bindir="$wprefs_base_dir/WPrefs.app"])
 858 AC_SUBST([wprefs_datadir])dnl
 859 AC_SUBST([wprefs_bindir])dnl
 860
 861 dnl Support for DEFSDATADIR option
 862 dnl ============================
 863 AC_ARG_WITH([defsdatadir],
 864     [AS_HELP_STRING([--with-defsdatadir=PATH], [specify where global defaults are located [SYSCONFDIR/WindowMaker]])],
 865     [AS_CASE([$withval],
 866         [yes|no], [AC_MSG_ERROR([bad value '$withval' for --with-defsdatadir, expected a path]) ],
 867         [/*],  [], dnl Absolute path, ok
 868         [\$*], [], dnl Assumes it starts with a reference to $prefix or a similar variable, ok
 869         [AC_MSG_ERROR([bad path '$withval' for defsdatadir, expecting an absolute path])])],
 870     [with_defsdatadir=""])
 871
 872 AS_IF([test "x$with_defsdatadir" != "x"],
 873     [defsdatadir="$with_defsdatadir"],
 874     [defsdatadir='${sysconfdir}/WindowMaker'])
 875 AC_SUBST([defsdatadir])dnl
 876
 877 dnl Enable User Defined Menu thing
 878 dnl ==============================
 879 AC_ARG_ENABLE([usermenu],
 880     [AS_HELP_STRING([--enable-usermenu], [user defined menus for applications])],
 881     [AS_CASE([$enableval],
 882         [yes|no], [],
 883         [AC_MSG_ERROR([bad value '$enableval' for --enable-usermenu])])],
 884     [enable_usermenu=no])
 885 AS_IF([test "x$enable_usermenu" = "xyes"],
 886     [AC_DEFINE([USER_MENU], [1],
 887         [define if you want user defined menus for applications])])
 888
 889
 890 dnl Support for removing non-public symbols from a library
 891 dnl ======================================================
 892 gl_LD_VERSION_SCRIPT
 893
 894
 895 dnl Add the post-poned compilation options
 896 dnl ======================================
 897 WM_CFLAGS_GCC_OPTION_POSTPONED
 898
 899
 900 AC_SUBST(lib_search_path)
 901 AC_SUBST(inc_search_path)
 902
 903
 904 dnl Spit out the configuration
 905 dnl ==========================
 906 AC_CONFIG_FILES(
 907     Makefile
 908
 909     dnl WRaster Library
 910     wrlib/Makefile wrlib/po/Makefile
 911     wrlib/tests/Makefile
 912
 913     dnl WINGs toolkit
 914     WINGs/Makefile WINGs/WINGs/Makefile WINGs/po/Makefile
 915     WINGs/Documentation/Makefile WINGs/Resources/Makefile WINGs/Extras/Makefile
 916     WINGs/Examples/Makefile WINGs/Tests/Makefile
 917
 918     dnl Window Maker's core
 919     src/Makefile src/wconfig.h po/Makefile
 920     doc/Makefile doc/build/Makefile
 921     doc/sk/Makefile doc/cs/Makefile doc/ru/Makefile
 922     WindowMaker/Makefile WindowMaker/Backgrounds/Makefile
 923     WindowMaker/Defaults/Makefile WindowMaker/IconSets/Makefile
 924     WindowMaker/Icons/Makefile WindowMaker/Pixmaps/Makefile
 925     WindowMaker/Styles/Makefile WindowMaker/Themes/Makefile
 926
 927     dnl Preference GUI
 928     WPrefs.app/Makefile WPrefs.app/po/Makefile
 929     WPrefs.app/tiff/Makefile WPrefs.app/xpm/Makefile
 930
 931     dnl Command-line utilities
 932     util/Makefile util/po/Makefile
 933
 934     dnl Misceleanous stuff
 935     wmlib/Makefile
 936     test/Makefile
 937 )
 938
 939 AC_OUTPUT
 940
 941
 942 dnl Provide a summary of the config
 943 dnl ===============================
 944 echo
 945 echo "Window Maker was configured as follows:"
 946 echo
 947 echo "Installation path prefix            : $prefix"
 948 echo "Installation path for binaries      : $_bindir"
 949 echo "Installation path for libraries     : $_libdir"
 950 echo "Installation path for WPrefs.app    : $wprefs_base_dir" | sed -e 's|\${prefix}|'"$prefix|"
 951 echo "Supported core features:            :$supported_core"
 952 echo "Supported X extensions:             :$supported_xext"
 953 echo "Supported graphic format libraries  :$supported_gfx"
 954 echo "Unsupported features                :$unsupported"
 955 echo "Antialiased text support in WINGs   : $xft"
 956 echo "Pango text layout support in WINGs  : $pango"
 957 echo "Translated languages to support     :$supported_locales"
 958 AS_IF([test "x$debug" = "xyes"],
 959     [AS_ECHO(["Debug enabled: CFLAGS = $CFLAGS"]) ])
 960 echo
 961
 962 AS_IF([test "x$wm_cv_prog_cc_nestedfunc" != "xyes"],
 963     [AC_MSG_WARN([[Your compiler does not support Nested Function, work-around enabled]])])
 964
 965 AS_IF([test "x$supported_locales" = "x"],
 966     [AC_MSG_WARN([[No language from \$LINGUAS are supported]])])
 967
 968 AS_IF([test "x$enable_jpeg" = xno], [dnl
 969     AS_ECHO(["WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"])
 970     AS_ECHO([])
 971     AS_ECHO(["JPEG support will not be included because the JPEG library is"])
 972     AS_ECHO(["not installed correctly or was not found. Background images"])
 973     AS_ECHO(["from themes will not display as they usually are JPEG files."])
 974     AS_ECHO([])
 975     AS_ECHO(["To fix, download and install the jpeg library and/or make sure you"])
 976     AS_ECHO(["installed all jpeg related packages, SPECIALLY the development packages"])
 977     AS_ECHO(["like jpeg-dev (if you use some prepackaged version of libjpeg)."])
 978     AS_ECHO([])
 979     AS_ECHO(["WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"])dnl
 980 ])
 981
 982 AS_IF([test "x$LINGUAS" != "x"],
 983     [AS_IF([test "X$wm_cv_library_constructors" = "Xlegacy"],
 984         [AC_MSG_WARN([I18N is enabled, but library constructor attribute is not supported])
 985          AS_ECHO(["   If you have translation problems in lib WRaster, yet you know that the translation"])
 986          AS_ECHO(["   file (po) is valid, this could be a cause."])
 987          AS_ECHO([])dnl
 988         ])dnl
 989     ])
 990
 991
 992 dnl This is for Emacs.  I'm lazy, I know... (nicolai)
 993 dnl ================================================
 994 dnl Local Variables:
 995 dnl compile-command: "autoconf"
 996 dnl End: