configure.ac

   1 dnl ============================================================================
   2 dnl
   3 dnl Window Maker autoconf input
   4 dnl
   5 AC_COPYRIGHT([Copyright (c) 2001-2015 The Window Maker Team])
   6 dnl
   7 dnl ============================================================================
   8 dnl
   9 dnl This program is free software; you can redistribute it and/or modify
  10 dnl it under the terms of the GNU General Public License as published by
  11 dnl the Free Software Foundation; either version 2 of the License, or
  12 dnl (at your option) any later version.
  13 dnl
  14 dnl This program is distributed in the hope that it will be useful,
  15 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 dnl GNU General Public License for more details.
  18 dnl
  19 dnl You should have received a copy of the GNU General Public License along
  20 dnl with this program; see the file COPYING.
  21 dnl
  22 dnl ============================================================================
  23 dnl
  24 dnl Process with: ./autogen.sh
  25
  26
  27 dnl Due to a bug in Autoconf 2.68 (apparently a regression), we need at least
  28 dnl version 2.68b which includes this patch:
  29 dnl   http://git.savannah.gnu.org/gitweb/?p=autoconf.git;a=commit;h=2b0d95faef68d7ed7c08b0edb9ff1c38728376fa
  30 dnl
  31 dnl Because the 2.69 was released only a few month later, let's just ask for it
  32 AC_PREREQ([2.69])
  33
  34
  35 dnl Configuration for Autoconf and Automake
  36 dnl =======================================
  37 AC_INIT([WindowMaker],[0.95.6],[wmaker-dev@lists.windowmaker.org],[WindowMaker],[http://www.windowmaker.org/])
  38 AC_CONFIG_MACRO_DIR([m4])
  39 AC_CONFIG_HEADERS([config.h])
  40
  41 dnl We need the EXTRA_xxx_DEPENDENCIES keyword in Makefiles which have been
  42 dnl introduced in the version 1.11.3; because the 1.12 was realeased shortly
  43 dnl after, we just ask for it
  44 AM_INIT_AUTOMAKE([1.12 silent-rules])
  45
  46 dnl Reference file used by 'configure' to make sure the path to sources is valid
  47 AC_CONFIG_SRCDIR([src/WindowMaker.h])
  48
  49 dnl Include at the end of 'config.h', this file is generated by top-level Makefile
  50 AH_BOTTOM([@%:@include "config-paths.h"])
  51
  52
  53 dnl libtool library versioning
  54 dnl ==========================
  55 dnl
  56 dnl current
  57 dnl revision
  58 dnl age
  59 dnl
  60 dnl 1. Start with version information of ‘0:0:0’ for each libtool library.
  61 dnl 2. Update the version information only immediately before a public
  62 dnl release of your software. More frequent updates are unnecessary, and
  63 dnl only guarantee that the current interface number gets larger faster.
  64 dnl 3. If the library source code has changed at all since the last
  65 dnl update, then increment revision (‘c:r:a’ becomes ‘c:r+1:a’).
  66 dnl 4. If any interfaces have been added, removed, or changed since the
  67 dnl last update, increment current, and set revision to 0.
  68 dnl 5. If any interfaces have been added since the last public release,
  69 dnl then increment age.
  70 dnl 6. If any interfaces have been removed or changed since the last
  71 dnl public release, then set age to 0.
  72 dnl
  73 dnl libwraster
  74 WRASTER_CURRENT=5
  75 WRASTER_REVISION=0
  76 WRASTER_AGE=0
  77 WRASTER_VERSION=$WRASTER_CURRENT:$WRASTER_REVISION:$WRASTER_AGE
  78 AC_SUBST(WRASTER_VERSION)
  79 dnl
  80 dnl libWINGs
  81 WINGS_CURRENT=4
  82 WINGS_REVISION=0
  83 WINGS_AGE=1
  84 WINGS_VERSION=$WINGS_CURRENT:$WINGS_REVISION:$WINGS_AGE
  85 AC_SUBST(WINGS_VERSION)
  86 dnl
  87 dnl libWUtil
  88 WUTIL_CURRENT=5
  89 WUTIL_REVISION=0
  90 WUTIL_AGE=0
  91 WUTIL_VERSION=$WUTIL_CURRENT:$WUTIL_REVISION:$WUTIL_AGE
  92 AC_SUBST(WUTIL_VERSION)
  93
  94
  95 dnl Checks for programs
  96 dnl ===================
  97 AC_PROG_CC
  98 WM_PROG_CC_C11
  99 AC_PROG_LN_S
 100 AC_PROG_GCC_TRADITIONAL
 101 LT_INIT
 102
 103
 104 dnl Debugging Options
 105 dnl =================
 106 AC_ARG_ENABLE([debug],
 107     [AS_HELP_STRING([--enable-debug], [enable debugging options, @<:@default=no@:>@])],
 108     [AS_CASE(["$enableval"],
 109         [yes], [debug=yes],
 110         [no],  [debug=no],
 111         [AC_MSG_ERROR([bad value $enableval for --enable-debug])] )],
 112     [debug=no])
 113 AS_IF([test "x$debug" = "xyes"],
 114     [dnl This flag should have already been detected and added, but if user
 115      dnl provided an explicit CFLAGS it may not be the case
 116      AS_IF([echo " $CFLAGS " | grep " -g " 2>&1 > /dev/null],
 117            [@%:@ Debug symbol already activated],
 118            [AX_CFLAGS_GCC_OPTION([-g])])
 119      dnl
 120      dnl This flag generally makes debugging nightmarish, remove it if present
 121      CFLAGS="`echo "$CFLAGS" | sed -e 's/-fomit-frame-pointer *//' `"
 122      dnl
 123      dnl Enable internal debug code
 124      CPPFLAGS="$CPPFLAGS -DDEBUG"
 125 ],  [dnl
 126      dnl When debug is not enabled, the user probably does not wants to keep
 127      dnl assertions in the final program
 128      CPPFLAGS="$CPPFLAGS -DNDEBUG"
 129 ])
 130
 131
 132 AX_CFLAGS_GCC_OPTION([-Wall])
 133 AX_CFLAGS_GCC_OPTION([-Wextra -Wno-sign-compare])
 134 dnl
 135 dnl The use of trampolines cause code that can crash on some secured OS, it is
 136 dnl also known to be a source of crash if not used properly, in a more general
 137 dnl way it tends to generate binary code that may not be optimal, and it is
 138 dnl not compatible with the 'nested-func-to-macro' workaround
 139 WM_CFLAGS_CHECK_FIRST([-Wtrampolines],
 140          [-Werror=trampolines  dnl try to generate an error if possible
 141           -Wtrampolines        dnl if not, try to fall back to a simple warning
 142          ])
 143 dnl
 144 AS_IF([test "x$debug" = "xyes"],
 145     [dnl When debug is enabled, we try to activate more checks from
 146      dnl the compiler. They are on independant check because the
 147      dnl macro checks all the options at once, but we may have cases
 148      dnl where some options are not supported and we don't want to
 149      dnl loose all of them.
 150      dnl
 151      dnl clang, suggest parenthesis on bit operations that could be
 152      dnl misunderstood due to C operator precedence
 153      AX_CFLAGS_GCC_OPTION([-Wbitwise-op-parentheses])
 154      dnl
 155      dnl Points at code that gcc thinks is so complicated that gcc
 156      dnl gives up trying to optimize, which probably also means it is
 157      dnl too complicated to maintain
 158      AX_CFLAGS_GCC_OPTION([-Wdisabled-optimization])
 159      dnl
 160      dnl Because of C's type promotion, the compiler has to generate
 161      dnl less optimal code when a double constant is used in a
 162      dnl float expression
 163      AX_CFLAGS_GCC_OPTION([-Wdouble-promotion])
 164      dnl
 165      dnl Floating-point comparison is not a good idea
 166      AX_CFLAGS_GCC_OPTION([-Wfloat-equal])
 167      dnl
 168      dnl clang warns about constants that may have portability issues due
 169      dnl to the endianness of the host
 170      AX_CFLAGS_GCC_OPTION([-Wfour-char-constants])
 171      dnl
 172      dnl clang warns about constant that may be too big to be portable
 173      AX_CFLAGS_GCC_OPTION([-Wliteral-range])
 174      dnl
 175      dnl Try to report misuses of '&' versus '&&' and similar
 176      AX_CFLAGS_GCC_OPTION([-Wlogical-op])
 177      dnl
 178      dnl clang, reports cases where the code assumes everyone is an
 179      dnl expert in C operator precedence... which is unlikely!
 180      AX_CFLAGS_GCC_OPTION([-Wlogical-op-parentheses])
 181      dnl
 182      dnl Reports declaration of global things that are done inside
 183      dnl a local environment, instead of using the appropriate
 184      dnl header
 185      AX_CFLAGS_GCC_OPTION([-Wnested-externs])
 186      dnl
 187      dnl Warn about constant strings that could pose portability issues
 188      AX_CFLAGS_GCC_OPTION([-Woverlength-strings])
 189      dnl
 190      dnl Use of 'sizeof()' on inappropriate pointer types
 191      AX_CFLAGS_GCC_OPTION([-Wpointer-arith])
 192      dnl
 193      dnl Having more than 1 prototype for a function makes code updates
 194      dnl more difficult, so try to avoid it
 195      AX_CFLAGS_GCC_OPTION([-Wredundant-decls])
 196      dnl
 197      dnl clang, detect some misuses of sizeof. We also count in our code
 198      dnl on the use of the macro 'wlength' which contains a check if the
 199      dnl compiler support C11's static_assert
 200      AX_CFLAGS_GCC_OPTION([-Wsizeof-array-argument])
 201      dnl
 202      dnl Prototype of function must be explicit, no deprecated K&R syntax
 203      dnl and no empty argument list which prevents compiler from doing
 204      dnl type checking when using the function
 205      WM_CFLAGS_GCC_OPTION_STRICTPROTO
 206      dnl
 207      dnl Proper attributes helps the compiler to produce better code
 208      WM_CFLAGS_CHECK_FIRST([format attribute suggest],
 209          [-Wsuggest-attribute=format  dnl new gcc syntax
 210           -Wmissing-format-attribute  dnl old gcc syntax, clang
 211          ])
 212      WM_CFLAGS_CHECK_FIRST([no-return attribute suggest],
 213          [-Wsuggest-attribute=noreturn  dnl gcc syntax
 214           -Wmissing-noreturn            dnl clang syntax
 215          ])
 216      dnl
 217      dnl GCC provides a couple of checks to detect incorrect macro uses
 218      AX_CFLAGS_GCC_OPTION([-Wundef])
 219      WM_CFLAGS_GCC_OPTION_UNUSEDMACROS
 220      dnl
 221      dnl clang reports stuff marked unused but which is actually used
 222      AX_CFLAGS_GCC_OPTION([-Wused-but-marked-unused])
 223 ], [dnl
 224      dnl When debug not enabled, we try to avoid some non-necessary
 225      dnl messages from the compiler
 226      dnl
 227      dnl To support legacy X servers, we have sometime to use
 228      dnl functions marked as deprecated. We do not wish our users
 229      dnl to be worried about it
 230      AX_CFLAGS_GCC_OPTION([-Wno-deprecated])
 231      AX_CFLAGS_GCC_OPTION([-Wno-deprecated-declarations])
 232 ])
 233
 234
 235 dnl Support for Nested Functions by the compiler
 236 dnl ============================================
 237 WM_PROG_CC_NESTEDFUNC
 238
 239
 240 dnl Posix thread
 241 dnl ============
 242 dnl they are used by util/wmiv
 243 AX_PTHREAD
 244
 245
 246 dnl Tracking on what is detected for final status
 247 dnl =============================================
 248 unsupported=""
 249 supported_core=""
 250 supported_xext=""
 251 supported_gfx=""
 252
 253
 254 dnl Platform-specific Makefile setup
 255 dnl ================================
 256 AS_CASE(["$host"],
 257     [*-*-linux*|*-*-cygwin*|*-gnu*], [WM_OSDEP="linux" ; CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=600"],
 258     [*-*-freebsd*|*-k*bsd-gnu*],     [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=600 -DFREEBSD"],
 259     [*-*-netbsd*],                   [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -DNETBSD"],
 260     [*-*-openbsd*],                  [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -DOPENBSD"],
 261     [*-*-dragonfly*],                [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -DDRAGONFLYBSD"],
 262     [*-apple-darwin*],               [WM_OSDEP="darwin"],
 263     [*-*-solaris*],                  [WM_OSDEP="stub"],  dnl  solaris.c when done
 264     [WM_OSDEP="stub"])
 265 AM_CONDITIONAL([WM_OSDEP_LINUX],   [test "x$WM_OSDEP" = "xlinux"])
 266 AM_CONDITIONAL([WM_OSDEP_BSD],     [test "x$WM_OSDEP" = "xbsd"])
 267 AM_CONDITIONAL([WM_OSDEP_DARWIN],  [test "x$WM_OSDEP" = "xdarwin"])
 268 AM_CONDITIONAL([WM_OSDEP_GENERIC], [test "x$WM_OSDEP" = "xstub"])
 269
 270
 271 dnl the prefix
 272 dnl ==========
 273 dnl
 274 dnl move this earlier in the script... anyone know why this is handled
 275 dnl in such a bizarre way?
 276
 277 test "x$prefix" = xNONE && prefix=$ac_default_prefix
 278 dnl Let make expand exec_prefix.
 279 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 280
 281
 282 _bindir=`eval echo $bindir`
 283 _bindir=`eval echo $_bindir`
 284 _libdir=`eval echo $libdir`
 285 _libdir=`eval echo $_libdir`
 286
 287 lib_search_path='-L${libdir}'
 288
 289 inc_search_path='-I${includedir}'
 290
 291 dnl ===============================================
 292 dnl Specify paths to look for libraries and headers
 293 dnl ===============================================
 294 AC_ARG_WITH(libs-from, AS_HELP_STRING([--with-libs-from], [pass compiler flags to look for libraries]),
 295         [lib_search_path="$withval $lib_search_path"])
 296
 297 AC_ARG_WITH(incs-from, AS_HELP_STRING([--with-incs-from], [pass compiler flags to look for header files]),
 298         [inc_search_path="$withval $inc_search_path"])
 299
 300
 301 dnl Features Configuration
 302 dnl ======================
 303 AC_ARG_ENABLE([animations],
 304     [AS_HELP_STRING([--disable-animations], [disable permanently animations @<:@default=enabled@:>@])],
 305     [AS_CASE(["$enableval"],
 306         [yes|no], [],
 307         [AC_MSG_ERROR([bad value $enableval for --enable-animations])])],
 308     [enable_animations="yes"])
 309 AS_IF([test "x$enable_animations" = "xno"],
 310     [unsupported="$unsupported Animations"],
 311     [AC_DEFINE([USE_ANIMATIONS], [1], [Defined when user did not request to disable animations])
 312      supported_core="$supported_core Animations"])
 313
 314
 315 AC_ARG_ENABLE([mwm-hints],
 316     [AS_HELP_STRING([--disable-mwm-hints], [disable support for Motif WM hints @<:@default=enabled@:>@])],
 317     [AS_CASE(["$enableval"],
 318         [yes|no], [],
 319         [AC_MSG_ERROR([bad value $enableval for --enable-mwm-hints])])],
 320     [enable_mwm_hints="yes"])
 321 AS_IF([test "x$enable_mwm_hints" = "xno"],
 322     [unsupported="$unsupported MWMHints"],
 323     [AC_DEFINE([USE_MWM_HINTS], [1], [Defined when used did not request to disable Motif WM hints])
 324      supported_core="$supported_core MWMHints"])
 325 AM_CONDITIONAL([USE_MWM_HINTS], [test "x$enable_mwm_hints" != "xno"])
 326
 327
 328 dnl Boehm GC
 329 dnl ========
 330 AC_ARG_ENABLE([boehm-gc],
 331     [AS_HELP_STRING([--enable-boehm-gc], [use Boehm GC instead of the default libc malloc() [default=no]])],
 332     [AS_CASE(["$enableval"],
 333         [yes], [with_boehm_gc=yes],
 334         [no],  [with_boehm_gc=no],
 335         [AC_MSG_ERROR([bad value $enableval for --enable-boehm-gc])] )],
 336     [with_boehm_gc=no])
 337 AS_IF([test "x$with_boehm_gc" = "xyes"],
 338     AC_SEARCH_LIBS([GC_malloc], [gc],
 339         [AC_DEFINE(USE_BOEHM_GC, 1, [Define if Boehm GC is to be used])],
 340         [AC_MSG_FAILURE([--enable-boehm-gc specified but test for libgc failed])]))
 341
 342
 343 dnl LCOV
 344 dnl ====
 345 AC_ARG_ENABLE([lcov],
 346     [AS_HELP_STRING([--enable-lcov[=output-directory]], [enable coverage data generation using LCOV (GCC only) [default=no]])],
 347     [],
 348     [enable_lcov=no])
 349
 350 AS_IF([test "x$enable_lcov" != "xno"],
 351     [AX_CFLAGS_GCC_OPTION(-fprofile-arcs -ftest-coverage)
 352     AS_IF([test "x$enable_lcov" = "xyes"],
 353         [lcov_output_directory="coverage-report"],
 354         [lcov_output_directory="${enable_lcov}/coverage-report"])
 355     AC_SUBST(lcov_output_directory)])
 356
 357 AM_CONDITIONAL([USE_LCOV], [test "x$enable_lcov" != "xno"])
 358
 359
 360 dnl ============================
 361 dnl Checks for library functions
 362 dnl ============================
 363 AC_FUNC_MEMCMP
 364 AC_FUNC_VPRINTF
 365 WM_FUNC_SECURE_GETENV
 366 AC_CHECK_FUNCS(gethostname select poll strcasecmp strncasecmp \
 367                setsid mallinfo mkstemp sysconf)
 368 AC_SEARCH_LIBS([strerror], [cposix])
 369
 370 dnl nanosleep is generally available in standard libc, although not always the
 371 dnl case. One known example is Solaris which needs -lrt
 372 AC_SEARCH_LIBS([nanosleep], [rt], [],
 373     [AC_MSG_ERROR([function 'nanosleep' not found, please report to wmaker-dev@lists.windowmaker.org])])
 374
 375 dnl the flag 'O_NOFOLLOW' for 'open' is used in WINGs
 376 WM_FUNC_OPEN_NOFOLLOW
 377
 378
 379 dnl Check for strlcat/strlcpy
 380 dnl =========================
 381 AC_ARG_WITH([libbsd],
 382   [AS_HELP_STRING([--without-libbsd], [do not use libbsd for strlcat and strlcpy [default=check]])],
 383   [AS_IF([test "x$with_libbsd" != "xno"],
 384     [with_libbsd=bsd]
 385     [with_libbsd=]
 386   )],
 387   [with_libbsd=bsd])
 388
 389 tmp_libs=$LIBS
 390 AC_SEARCH_LIBS([strlcat],[$with_libbsd],
 391   [AC_DEFINE(HAVE_STRLCAT, 1, [Define if strlcat is available])],
 392   [],
 393   []
 394 )
 395 AC_SEARCH_LIBS([strlcpy],[$with_libbsd],
 396   [AC_DEFINE(HAVE_STRLCAT, 1, [Define if strlcpy is available])],
 397   [],
 398   []
 399 )
 400 LIBS=$tmp_libs
 401
 402 LIBBSD=
 403 AS_IF([test "x$ac_cv_search_strlcat" = "x-lbsd" -o "x$ac_cv_search_strlcpy" = "x-lbsd"],
 404   [LIBBSD=-lbsd
 405    AC_CHECK_HEADERS([bsd/string.h])]
 406 )
 407 AC_SUBST(LIBBSD)
 408
 409
 410 dnl Check for OpenBSD kernel memory interface - kvm(3)
 411 dnl ==================================================
 412 AS_IF([test "x$WM_OSDEP" = "xbsd"],
 413   AC_SEARCH_LIBS([kvm_openfiles], [kvm]) )
 414
 415
 416 dnl Check for inotify
 417 dnl =================
 418 dnl It is used by WindowMaker to reload automatically the configuration when the
 419 dnl user changed it using WPref or wdwrite
 420 AC_CHECK_HEADERS([sys/inotify.h],
 421     [AC_DEFINE([HAVE_INOTIFY], [1], [Check for inotify])])
 422
 423
 424 dnl Check for syslog
 425 dnl ================
 426 dnl It is used by WUtil to log the wwarning, werror and wfatal
 427 AC_CHECK_HEADERS([syslog.h], [AC_DEFINE([HAVE_SYSLOG], [1], [Check for syslog])])
 428
 429
 430 dnl Checks for header files
 431 dnl =======================
 432 AC_HEADER_SYS_WAIT
 433 AC_HEADER_TIME
 434 AC_CHECK_HEADERS(fcntl.h limits.h sys/ioctl.h libintl.h poll.h malloc.h ctype.h \
 435                  string.h strings.h)
 436
 437
 438 dnl Checks for typedefs, structures, and compiler characteristics
 439 dnl =============================================================
 440 AC_C_CONST
 441 AC_C_INLINE
 442 WM_C_NORETURN
 443 AC_TYPE_SIZE_T
 444 AC_TYPE_PID_T
 445 WM_TYPE_SIGNAL
 446
 447
 448 dnl pkg-config
 449 dnl ==========
 450 AC_CHECK_PROG([PKGCONFIG], [pkg-config], [pkg-config])
 451
 452
 453
 454 dnl Internationalization
 455 dnl ====================
 456 dnl Detect the language for translations to be installed and check
 457 dnl that the gettext environment works
 458 WM_I18N_LANGUAGES
 459 WM_I18N_XGETTEXT
 460 WM_I18N_MENUTEXTDOMAIN
 461
 462 dnl 2014/12/29: The option is deprecated, we should keep this message for at
 463 dnl least 2 years to ensure users see it and update their build scripts
 464 AC_ARG_WITH([nlsdir], [],
 465     [AC_MSG_ERROR([option '--with-nlsdir' is deprecated, please use autoconf's standard '--localedir' instead])])
 466
 467
 468 dnl ===========================================
 469 dnl             Stuff that uses X
 470 dnl ===========================================
 471
 472 AC_PATH_XTRA
 473
 474 AS_IF([test "x$no_x" = "xyes"],
 475     [AC_MSG_ERROR([The path for the X11 files not found!
 476 Make sure you have X and it's headers and libraries (the -devel packages
 477 in Linux) installed.])])
 478
 479 X_LIBRARY_PATH=$x_libraries
 480 XCFLAGS="$X_CFLAGS"
 481 XLFLAGS="$X_LIBS"
 482 XLIBS="-lX11 $X_EXTRA_LIBS"
 483
 484 lib_search_path="$lib_search_path $XLFLAGS"
 485 inc_search_path="$inc_search_path $XCFLAGS"
 486
 487 AC_SUBST(X_LIBRARY_PATH)
 488
 489
 490 dnl Decide which locale function to use, setlocale() or _Xsetlocale()
 491 dnl by MANOME Tomonori
 492 dnl ===========================================
 493 WM_I18N_XLOCALE
 494
 495
 496
 497 dnl Check whether XInternAtoms() exist
 498 dnl ==================================
 499 AC_CHECK_LIB([X11], [XInternAtoms],
 500     [AC_DEFINE([HAVE_XINTERNATOMS], [1],
 501         [define if your X server has XInternAtoms() (set by configure)])],
 502     [], [$XLFLAGS $XLIBS])
 503
 504
 505 dnl Check whether XConvertCase() exist
 506 dnl ==================================
 507 AC_CHECK_LIB([X11], [XConvertCase],
 508     [AC_DEFINE([HAVE_XCONVERTCASE], [1],
 509         [define if your X server has XConvertCase() (set by configure)])],
 510     [], [$XLFLAGS $XLIBS])
 511
 512
 513 dnl XKB keyboard language status
 514 dnl ============================
 515 AC_ARG_ENABLE([modelock],
 516     [AS_HELP_STRING([--enable-modelock], [XKB keyboard language status support])],
 517     [AS_CASE([$enableval],
 518         [yes|no], [],
 519         [AC_MSG_ERROR([bad value '$enableval' for --enable-modelock])])],
 520     [enable_modelock=no])
 521 AS_IF([test "x$enable_modelock" = "xyes"],
 522     [AC_DEFINE([XKB_MODELOCK], [1], [whether XKB language MODELOCK should be enabled]) ])
 523
 524
 525 dnl XDND Drag-nd-Drop support
 526 dnl =========================
 527 AC_ARG_ENABLE([xdnd],
 528     [AS_HELP_STRING([--disable-xdnd], [disable support for Drag-and-Drop on the dock @<:@default=enabled@:>@])],
 529     [AS_CASE(["$enableval"],
 530         [yes|no], [],
 531         [AC_MSG_ERROR([bad value $enableval for --disable-xdnd]) ]) ],
 532     [enable_xdnd=yes])
 533 AS_IF([test "x$enable_xdnd" = "xyes"],
 534     [supported_core="$supported_core XDnD"
 535      AC_DEFINE([USE_DOCK_XDND], [1], [whether Drag-and-Drop on the dock should be enabled])],
 536     [unsupported="$unsupported XDnd"])
 537 AM_CONDITIONAL([USE_DOCK_XDND], [test "x$enable_dock_xdnd" != "xno"])
 538
 539
 540 dnl Support for ICCCM 2.0 Window Manager replacement
 541 dnl ================================================
 542 AC_ARG_ENABLE([wmreplace],
 543     [AS_HELP_STRING([--enable-wmreplace], [support for ICCCM window manager replacement])],
 544     [AS_CASE([$enableval],
 545         [yes|no], [],
 546         [AC_MSG_ERROR([bad value '$enableval' for --enable-wmreplace])])],
 547     [enable_wmreplace=no])
 548 AS_IF([test "x$enable_wmreplace" = "xyes"],
 549     [AC_DEFINE([USE_ICCCM_WMREPLACE], [1],
 550        [define to support ICCCM protocol for window manager replacement])
 551      supported_xext="$supported_xext WMReplace"])
 552
 553
 554 dnl XShape support
 555 dnl ==============
 556 AC_ARG_ENABLE([shape],
 557     [AS_HELP_STRING([--disable-shape], [disable shaped window extension support])],
 558     [AS_CASE(["$enableval"],
 559         [yes|no], [],
 560         [AC_MSG_ERROR([bad value $enableval for --enable-shape]) ]) ],
 561     [enable_shape=auto])
 562 WM_XEXT_CHECK_XSHAPE
 563
 564
 565 dnl MIT-SHM support
 566 dnl ===============
 567 AC_ARG_ENABLE([shm],
 568     [AS_HELP_STRING([--disable-shm], [disable usage of MIT-SHM extension])],
 569     [AS_CASE(["$enableval"],
 570         [yes|no], [],
 571         [AC_MSG_ERROR([bad value $enableval for --enable-shm]) ]) ],
 572     [enable_shm=auto])
 573 WM_XEXT_CHECK_XSHM
 574
 575
 576 dnl X Misceleanous Utility
 577 dnl ======================
 578 dnl the libXmu is used in WRaster
 579 WM_EXT_CHECK_XMU
 580
 581
 582 dnl XINERAMA support
 583 dnl ================
 584 AC_ARG_ENABLE([xinerama],
 585     [AS_HELP_STRING([--enable-xinerama], [enable Xinerama extension support])],
 586     [AS_CASE(["$enableval"],
 587         [yes|no], [],
 588         [AC_MSG_ERROR([bad value $enableval for --enable-xinerama]) ]) ],
 589     [enable_xinerama=auto])
 590 WM_XEXT_CHECK_XINERAMA
 591
 592
 593 dnl RandR support
 594 dnl =============
 595 AC_ARG_ENABLE([randr],
 596     [AS_HELP_STRING([--enable-randr], [enable RandR extension support (NOT recommended, buggy)])],
 597     [AS_CASE(["$enableval"],
 598         [yes|no], [],
 599         [AC_MSG_ERROR([bad value $enableval for --enable-randr]) ]) ],
 600     [enable_randr=no])
 601 WM_XEXT_CHECK_XRANDR
 602
 603
 604 dnl Math library
 605 dnl ============
 606 dnl libWINGS uses math functions, check whether usage requires linking
 607 dnl against libm
 608 WM_CHECK_LIBM
 609
 610
 611 dnl FontConfig
 612 dnl ==========
 613 dnl libWINGS uses FcPatternDel from libfontconfig
 614 AC_MSG_CHECKING([for fontconfig library])
 615 FCLIBS=`$PKGCONFIG fontconfig --libs`
 616 if test "x$FCLIBS" = "x" ; then
 617         AC_MSG_RESULT([not found])
 618 else
 619         AC_MSG_RESULT([found])
 620 fi
 621 AC_SUBST(FCLIBS)
 622
 623
 624 dnl Xft2 antialiased font support
 625 dnl =============================
 626
 627 xft=yes
 628 XFTLIBS=""
 629
 630 if test "x$PKGCONFIG" != x -a "`$PKGCONFIG xft; echo $?`" = 0; then
 631         XFTCONFIG="$PKGCONFIG xft"
 632         pkgconfig_xft=yes
 633 else
 634         AC_CHECK_PROG(XFTCONFIG, xft-config, xft-config)
 635 fi
 636
 637 AC_MSG_CHECKING([for the Xft2 library])
 638
 639 if test "x$XFTCONFIG" != x; then
 640         XFTLIBS=`$XFTCONFIG --libs`
 641         XFTFLAGS=`$XFTCONFIG --cflags`
 642         AC_MSG_RESULT([found])
 643 else
 644         AC_MSG_RESULT([not found])
 645         echo
 646         echo "ERROR!!! libXft2 is not installed or could not be found."
 647         echo "         Xft2 is a requirement for building Window Maker."
 648         echo "         Please install it (along with fontconfig) before continuing."
 649         echo
 650         exit 1
 651 fi
 652
 653 minXFT="2.1.0"
 654 goodxft="no"
 655
 656 dnl
 657 dnl The macro below will use $XFTFLAGS (defined above) to find Xft.h
 658 dnl
 659 WM_CHECK_XFT_VERSION($minXFT, goodxft=yes, goodxft=no)
 660
 661 if test "$goodxft" = no; then
 662         echo
 663         echo "ERROR!!! libXft on this system is an old version."
 664         echo "         Please consider upgrading to at least version ${minXFT}."
 665         echo
 666         exit 1
 667 fi
 668
 669 AC_SUBST(XFTFLAGS)
 670 AC_SUBST(XFTLIBS)
 671
 672 dnl PANGO support
 673 dnl =============
 674 pango=no
 675 AC_ARG_ENABLE(pango, AS_HELP_STRING([--enable-pango], [enable Pango text layout support]),
 676                 pango=$enableval, pango=no)
 677
 678 PANGOFLAGS=
 679 PANGOLIBS=
 680 if test "$pango" = yes; then
 681         PANGOLIBS=`$PKGCONFIG pangoxft --libs`
 682         PANGOFLAGS=`$PKGCONFIG pangoxft --cflags`
 683         if test "x$PANGOLIBS" = "x" ; then
 684                 AC_MSG_RESULT([not found])
 685         else
 686                 AC_DEFINE(USE_PANGO, 1, [Define if Pango is to be used])
 687                 AC_MSG_RESULT([found])
 688         fi
 689 fi
 690 inc_search_path="$inc_search_path $PANGOFLAGS"
 691 AC_SUBST(PANGOLIBS)
 692
 693 dnl ==============================================
 694 dnl         Graphic Format Libraries
 695 dnl ==============================================
 696
 697 dnl XPM Support
 698 dnl ===========
 699 AC_ARG_ENABLE([xpm],
 700     [AS_HELP_STRING([--disable-xpm], [disable use of XPM pixmaps through libXpm])],
 701     [AS_CASE(["$enableval"],
 702         [yes|no], [],
 703         [AC_MSG_ERROR([bad value $enableval for --enable-xpm])] )],
 704     [enable_xpm=auto])
 705 WM_IMGFMT_CHECK_XPM
 706
 707
 708 # for wmlib
 709 AC_SUBST(XCFLAGS)
 710 # for test
 711 AC_SUBST(XLFLAGS)
 712 AC_SUBST(XLIBS)
 713 AC_SUBST(X_EXTRA_LIBS)
 714
 715 dnl ===============================================
 716 dnl             End of stuff that uses X
 717 dnl ===============================================
 718
 719 dnl EXIF Support
 720 dnl ============
 721 WM_CHECK_LIBEXIF
 722 AS_IF([test "x$LIBEXIF" != "x"],
 723         [AC_DEFINE(HAVE_EXIF, 1, [Define if EXIF can be used])])
 724
 725
 726 dnl PNG Support
 727 dnl ===========
 728 AC_ARG_ENABLE([png],
 729     [AS_HELP_STRING([--disable-png], [disable PNG support through libpng])],
 730     [AS_CASE(["$enableval"],
 731         [yes|no], [],
 732         [AC_MSG_ERROR([bad value $enableval for --enable-png])] )],
 733     [enable_png=auto])
 734 WM_IMGFMT_CHECK_PNG
 735
 736
 737 dnl JPEG Support
 738 dnl ============
 739 AC_ARG_ENABLE([jpeg],
 740     [AS_HELP_STRING([--disable-jpeg], [disable JPEG support through libjpeg])],
 741     [AS_CASE(["$enableval"],
 742         [yes|no], [],
 743         [AC_MSG_ERROR([bad value $enableval for --enable-jpeg])] )],
 744     [enable_jpeg=auto])
 745 WM_IMGFMT_CHECK_JPEG
 746
 747
 748 dnl GIF Support
 749 dnl ============
 750 AC_ARG_ENABLE(gif,
 751     [AS_HELP_STRING([--disable-gif], [disable GIF support through libgif or libungif])],
 752     [AS_CASE(["$enableval"],
 753         [yes|no], [],
 754         [AC_MSG_ERROR([bad value $enableval for --enable-gif])] )],
 755     [enable_gif=auto])
 756 WM_IMGFMT_CHECK_GIF
 757
 758
 759 dnl TIFF Support
 760 dnl ============
 761 AC_ARG_ENABLE([tiff],
 762     [AS_HELP_STRING([--disable-tiff], [disable use of TIFF images through libtiff])],
 763     [AS_CASE(["$enableval"],
 764         [yes|no], [],
 765         [AC_MSG_ERROR([bad value $enableval for --enable-tiff])] )],
 766     [enable_tiff=auto])
 767 WM_IMGFMT_CHECK_TIFF
 768
 769
 770 dnl WEBP Support
 771 dnl ============
 772 AC_ARG_ENABLE([webp],
 773     [AS_HELP_STRING([--disable-webp], [disable WEBP support through libwebp])],
 774     [AS_CASE(["$enableval"],
 775         [yes|no], [],
 776         [AC_MSG_ERROR([bad value $enableval for --enable-webp])] )],
 777     [enable_webp=auto])
 778 WM_IMGFMT_CHECK_WEBP
 779
 780
 781 dnl MagicK Support
 782 dnl ==============
 783 AC_ARG_ENABLE([magick],
 784     [AS_HELP_STRING([--disable-magick], [disable MAGICK support through libMagickWand])],
 785     [AS_CASE(["$enableval"],
 786         [yes|no], [],
 787         [AC_MSG_ERROR([bad value $enableval for --enable-magick])] )],
 788     [enable_magick=auto])
 789 WM_IMGFMT_CHECK_MAGICK
 790
 791
 792 dnl PPM Support
 793 dnl ===========
 794 # The PPM format is always enabled because we have built-in support for the format
 795 # We are not using any external library like libppm
 796 supported_gfx="$supported_gfx builtin-PPM"
 797
 798
 799 # Choice of the default format for icons
 800 AS_IF([test "x$enable_tiff" != "xno"],
 801     [ICONEXT="tiff"],
 802     [ICONEXT="xpm"])
 803
 804
 805 LIBRARY_SEARCH_PATH="$lib_search_path"
 806 HEADER_SEARCH_PATH="$inc_search_path"
 807
 808 AC_SUBST(LIBRARY_SEARCH_PATH)
 809 AC_SUBST(HEADER_SEARCH_PATH)
 810
 811
 812 AC_SUBST(GFXLIBS)
 813 AC_SUBST(ICONEXT)
 814 AM_CONDITIONAL([ICON_EXT_XPM],  [test "x$ICONEXT" = "xxpm"])
 815 AM_CONDITIONAL([ICON_EXT_TIFF], [test "x$ICONEXT" = "xtiff"])
 816
 817
 818 dnl ==============================================
 819 dnl         End of Graphic Format Libraries
 820 dnl ==============================================
 821
 822
 823 dnl
 824 dnl stdlib.h is checked here, because of conflict in jpeglib.h
 825 AC_CHECK_HEADERS(stdlib.h)
 826
 827
 828 dnl Support for PIXMAPDIR option
 829 dnl ============================
 830 AC_ARG_WITH([pixmapdir],
 831     [AS_HELP_STRING([--with-pixmapdir=PATH], [specify where pixmaps are located [DATADIR/pixmaps]])],
 832     [AS_CASE([$withval],
 833         [yes|no], [AC_MSG_ERROR([bad value '$withval' for --with-pixmapdir, expected a path]) ],
 834         [/*],  [], dnl Absolute path, ok
 835         [\$*], [], dnl Assumes it starts with a reference to $prefix or a similar variable, ok
 836         [AC_MSG_ERROR([bad path '$withval' for pixmapdir, expecting an absolute path])])],
 837     [with_pixmapdir=""])
 838
 839 AS_IF([test "x$with_pixmapdir" != "x"],
 840     [pixmapdir="$with_pixmapdir"],
 841     [pixmapdir='${datadir}/pixmaps'])
 842 AC_SUBST([pixmapdir])dnl
 843
 844
 845 dnl Support for GNUSTEP_LOCAL_ROOT, for WPrefs.app
 846 dnl ==============================================
 847 AC_ARG_WITH([gnustepdir],
 848     [AS_HELP_STRING([--with-gnustepdir=PATH], [specify the directory for GNUstep applications])],
 849     [AS_CASE([$withval],
 850         [yes|no], [AC_MSG_ERROR([bad value '$withval' for --with-gnustepdir, expected a path]) ],
 851         [/*],  [], dnl Absolute path, ok
 852         [\$*], [], dnl Assumes it starts with a reference to $prefix or a similar variable, ok
 853         [AC_MSG_ERROR([bad path '$withval' for gnustepdir, expecting an absolute path])])],
 854     [dnl If no command-line option was given, we use $GNUSTEP_LOCAL_ROOT if it was set
 855      with_gnustepdir="$GNUSTEP_LOCAL_ROOT"])
 856
 857 AS_IF([test "x$with_gnustepdir" = "x"],
 858     [dnl No path specified, use default
 859      wprefs_base_dir=${prefix}
 860      wprefs_datadir="${datadir}/WPrefs"
 861      wprefs_bindir="${bindir}"],
 862     [dnl User specified base path
 863      wprefs_base_dir="$with_gnustepdir/Applications"
 864      wprefs_datadir="$wprefs_base_dir/WPrefs.app"
 865      wprefs_bindir="$wprefs_base_dir/WPrefs.app"])
 866 AC_SUBST([wprefs_datadir])dnl
 867 AC_SUBST([wprefs_bindir])dnl
 868
 869
 870 dnl Enable User Defined Menu thing
 871 dnl ==============================
 872 AC_ARG_ENABLE([usermenu],
 873     [AS_HELP_STRING([--enable-usermenu], [user defined menus for applications])],
 874     [AS_CASE([$enableval],
 875         [yes|no], [],
 876         [AC_MSG_ERROR([bad value '$enableval' for --enable-usermenu])])],
 877     [enable_usermenu=no])
 878 AS_IF([test "x$enable_usermenu" = "xyes"],
 879     [AC_DEFINE([USER_MENU], [1],
 880         [define if you want user defined menus for applications])])
 881
 882
 883 dnl Support for removing non-public symbols from a library
 884 dnl ======================================================
 885 gl_LD_VERSION_SCRIPT
 886
 887
 888 dnl Add the post-poned compilation options
 889 dnl ======================================
 890 WM_CFLAGS_GCC_OPTION_POSTPONED
 891
 892
 893 AC_SUBST(lib_search_path)
 894 AC_SUBST(inc_search_path)
 895
 896
 897 dnl Spit out the configuration
 898 dnl ==========================
 899 AC_CONFIG_FILES(
 900     Makefile
 901
 902     dnl WRaster Library
 903     wrlib/Makefile
 904     wrlib/tests/Makefile
 905
 906     dnl WINGs toolkit
 907     WINGs/Makefile WINGs/WINGs/Makefile WINGs/po/Makefile
 908     WINGs/Documentation/Makefile WINGs/Resources/Makefile WINGs/Extras/Makefile
 909     WINGs/Examples/Makefile WINGs/Tests/Makefile
 910
 911     dnl Window Maker's core
 912     src/Makefile src/wconfig.h po/Makefile
 913     doc/Makefile doc/build/Makefile
 914     doc/sk/Makefile doc/cs/Makefile doc/ru/Makefile
 915     WindowMaker/Makefile WindowMaker/Backgrounds/Makefile
 916     WindowMaker/Defaults/Makefile WindowMaker/IconSets/Makefile
 917     WindowMaker/Icons/Makefile WindowMaker/Pixmaps/Makefile
 918     WindowMaker/Styles/Makefile WindowMaker/Themes/Makefile
 919
 920     dnl Preference GUI
 921     WPrefs.app/Makefile WPrefs.app/po/Makefile
 922     WPrefs.app/tiff/Makefile WPrefs.app/xpm/Makefile
 923
 924     dnl Command-line utilities
 925     util/Makefile util/po/Makefile
 926
 927     dnl Misceleanous stuff
 928     wmlib/Makefile
 929     test/Makefile
 930 )
 931
 932 AC_OUTPUT
 933
 934
 935 dnl Provide a summary of the config
 936 dnl ===============================
 937 echo
 938 echo "Window Maker was configured as follows:"
 939 echo
 940 echo "Installation path prefix            : $prefix"
 941 echo "Installation path for binaries      : $_bindir"
 942 echo "Installation path for libraries     : $_libdir"
 943 echo "Installation path for WPrefs.app    : $wprefs_base_dir" | sed -e 's|\${prefix}|'"$prefix|"
 944 echo "Supported core features:            :$supported_core"
 945 echo "Supported X extensions:             :$supported_xext"
 946 echo "Supported graphic format libraries  :$supported_gfx"
 947 echo "Unsupported features                :$unsupported"
 948 echo "Antialiased text support in WINGs   : $xft"
 949 echo "Pango text layout support in WINGs  : $pango"
 950 echo "Translated languages to support     :$supported_locales"
 951 AS_IF([test "x$debug" = "xyes"],
 952     [AS_ECHO(["Debug enabled: CFLAGS = $CFLAGS"]) ])
 953 echo
 954
 955 AS_IF([test "x$wm_cv_prog_cc_nestedfunc" != "xyes"],
 956     [AC_MSG_WARN([[Your compiler does not support Nested Function, work-around enabled]])])
 957
 958 AS_IF([test "x$supported_locales" = "x"],
 959     [AC_MSG_WARN([[No language from \$LINGUAS are supported]])])
 960
 961 AS_IF([test "x$enable_jpeg" = xno], [dnl
 962     AS_ECHO(["WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"])
 963     AS_ECHO([])
 964     AS_ECHO(["JPEG support will not be included because the JPEG library is"])
 965     AS_ECHO(["not installed correctly or was not found. Background images"])
 966     AS_ECHO(["from themes will not display as they usually are JPEG files."])
 967     AS_ECHO([])
 968     AS_ECHO(["To fix, download and install the jpeg library and/or make sure you"])
 969     AS_ECHO(["installed all jpeg related packages, SPECIALLY the development packages"])
 970     AS_ECHO(["like jpeg-dev (if you use some prepackaged version of libjpeg)."])
 971     AS_ECHO([])
 972     AS_ECHO(["WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"])dnl
 973 ])
 974
 975
 976 dnl This is for Emacs.  I'm lazy, I know... (nicolai)
 977 dnl ================================================
 978 dnl Local Variables:
 979 dnl compile-command: "autoconf"
 980 dnl End: