| blob | 2b257d126419e877c26734db989ba373eff9d639 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53)
8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
18 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
20 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
21 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
24 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
25 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
26 if test "x$enable_win16" = "xno"
27 then
28 WIN16_FILES=""
29 WIN16_INSTALL=""
30 fi
32 AC_SUBST(DLLDEFS,"")
33 if test "x$enable_debug" = "xno"
34 then
35 DLLDEFS="$DLLDEFS -DWINE_NO_DEBUG_MSGS"
36 fi
37 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
38 then
39 DLLDEFS="$DLLDEFS -DWINE_NO_TRACE_MSGS"
40 fi
42 dnl **** Check for some programs ****
44 AC_CANONICAL_HOST
45 case $host in
46 x86_64*linux*)
47 if test "x$enable_win64" != "xyes"
48 then
49 test -n "$CC" || CC="gcc -m32"
50 test -n "$LD" || LD="ld -m elf_i386"
51 test -n "$AS" || AS="as --32"
52 host_cpu="i386"
53 fi
54 ;;
55 esac
57 AC_PROG_MAKE_SET
58 AC_PROG_CC
59 AC_PROG_CXX
60 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
61 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
63 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
64 [if test -z "$with_wine_tools"; then
65 if test "$cross_compiling" = "yes"; then
66 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
67 else
68 wine_cv_toolsdir="\$(TOPOBJDIR)"
69 fi
70 elif test -d "$with_wine_tools/tools/winebuild"; then
71 case $with_wine_tools in
72 /*) wine_cv_toolsdir="$with_wine_tools" ;;
73 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
74 esac
75 else
76 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
77 fi])
78 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
80 AC_PATH_XTRA
81 AC_PROG_LEX
83 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
84 dnl **** without one present.
85 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
86 if test "$XLEX" = "none"
87 then
88 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
89 fi
91 dnl Check for bison
92 AC_CHECK_PROGS(BISON,bison,none)
93 if test "$BISON" = "none"
94 then
95 AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
96 fi
98 AC_CHECK_TOOLS(AS,[gas as],as)
99 AC_CHECK_TOOL(LD,ld,ld)
100 AC_CHECK_TOOL(AR,ar,ar)
101 AC_PROG_RANLIB
102 AC_CHECK_TOOL(STRIP,strip,strip)
103 AC_CHECK_TOOL(WINDRES,windres,false)
104 AC_PROG_LN_S
105 WINE_PROG_LN
106 AC_PROG_EGREP
107 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
108 AC_PROG_INSTALL
109 dnl Prepend src dir to install path dir if it's a relative path
110 case "$INSTALL" in
111 [[\\/$]]* | ?:[[\\/]]* ) ;;
112 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
113 esac
115 dnl Check for lint
116 AC_CHECK_PROGS(LINT, lclint lint)
117 if test "$LINT" = "lint"
118 then
119 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
120 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
121 fi
122 AC_SUBST(LINT)
123 AC_SUBST(LINTFLAGS)
125 dnl Check for various programs
126 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
127 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
128 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
129 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
130 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
132 dnl **** Check for some libraries ****
134 dnl Check for -li386 for NetBSD and OpenBSD
135 AC_CHECK_LIB(i386,i386_set_ldt)
136 dnl Check for -lossaudio for NetBSD
137 AC_CHECK_LIB(ossaudio,_oss_ioctl)
138 dnl Check for -lw for Solaris
139 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
140 dnl Check for -lnsl for Solaris
141 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
142 dnl Check for -lsocket for Solaris
143 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
144 dnl Check for -lresolv for Solaris
145 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
146 dnl Check for -lxpg4 for FreeBSD
147 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
148 dnl Check for -lpoll for Mac OS X/Darwin
149 AC_CHECK_LIB(poll,poll)
150 dnl Check for -lresolv for Mac OS X/Darwin
151 AC_CHECK_LIB(resolv,res_9_init)
152 dnl Check for -lpthread
153 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
155 AC_SUBST(XLIB)
156 AC_SUBST(XFILES)
157 XFILES=""
158 AC_SUBST(OPENGLFILES)
159 OPENGLFILES=""
160 AC_SUBST(GLU32FILES)
161 GLU32FILES=""
162 AC_SUBST(OPENGL_LIBS)
163 OPENGL_LIBS=""
165 dnl **** Check for header files ****
167 AC_CHECK_HEADERS(\
168 arpa/inet.h \
169 arpa/nameser.h \
170 asm/types.h \
171 cups/cups.h \
172 direct.h \
173 elf.h \
174 float.h \
175 fontconfig/fontconfig.h \
176 getopt.h \
177 gif_lib.h \
178 ieeefp.h \
179 io.h \
180 jack/jack.h \
181 jpeglib.h \
182 lcms/lcms.h \
183 lcms.h \
184 link.h \
185 linux/cdrom.h \
186 linux/compiler.h \
187 linux/hdreg.h \
188 linux/input.h \
189 linux/ioctl.h \
190 linux/joystick.h \
191 linux/major.h \
192 linux/param.h \
193 linux/serial.h \
194 linux/ucdrom.h \
195 machine/cpu.h \
196 mntent.h \
197 netdb.h \
198 netinet/in.h \
199 netinet/in_systm.h \
200 netinet/tcp.h \
201 netinet/tcp_fsm.h \
202 openssl/ssl.h \
203 poll.h \
204 process.h \
205 pthread.h \
206 pwd.h \
207 regex.h \
208 sched.h \
209 scsi/sg.h \
210 scsi/scsi.h \
211 scsi/scsi_ioctl.h \
212 stdint.h \
213 strings.h \
214 sys/cdio.h \
215 sys/elf32.h \
216 sys/errno.h \
217 sys/epoll.h \
218 sys/exec_elf.h \
219 sys/filio.h \
220 sys/ioctl.h \
221 sys/ipc.h \
222 sys/link.h \
223 sys/lwp.h \
224 sys/mman.h \
225 sys/modem.h \
226 sys/msg.h \
227 sys/param.h \
228 sys/poll.h \
229 sys/ptrace.h \
230 sys/reg.h \
231 sys/scsiio.h \
232 sys/shm.h \
233 sys/signal.h \
234 sys/socket.h \
235 sys/sockio.h \
236 sys/statfs.h \
237 sys/statvfs.h \
238 sys/strtio.h \
239 sys/syscall.h \
240 sys/sysctl.h \
241 sys/time.h \
242 sys/times.h \
243 sys/uio.h \
244 sys/un.h \
245 sys/vfs.h \
246 sys/vm86.h \
247 sys/wait.h \
248 syscall.h \
249 termios.h \
250 unistd.h \
251 utime.h \
252 valgrind/memcheck.h
253 )
254 AC_HEADER_STAT()
256 dnl **** Check for X11 ****
258 if test "$have_x" = "yes"
259 then
260 XLIB="-lXext -lX11"
261 ac_save_CPPFLAGS="$CPPFLAGS"
262 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
264 dnl *** All of the following tests require X11/Xlib.h
265 AC_CHECK_HEADERS(X11/Xlib.h,
266 [
267 AC_CHECK_HEADERS([X11/XKBlib.h \
268 X11/Xutil.h \
269 X11/extensions/shape.h \
270 X11/extensions/XInput.h \
271 X11/extensions/XShm.h \
272 X11/extensions/Xrandr.h \
273 X11/extensions/Xrender.h \
274 X11/extensions/xf86dga.h \
275 X11/extensions/xf86vmode.h],,,
276 [#include <X11/Xlib.h>
277 #ifdef HAVE_X11_XUTIL_H
278 # include <X11/Xutil.h>
279 #endif])
281 dnl *** Check for X keyboard extension
282 if test "$ac_cv_header_X11_XKBlib_h" = "yes"
283 then
284 AC_CHECK_LIB(X11, XkbQueryExtension,
285 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
286 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
287 fi
289 dnl *** Check for X Shm extension
290 if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
291 then
292 AC_CHECK_LIB(Xext, XShmQueryExtension,
293 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
294 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
295 fi
297 dnl *** Check for X shape extension
298 if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
299 then
300 AC_CHECK_LIB(Xext,XShapeQueryExtension,
301 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
302 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
303 fi
305 dnl *** Check for XFree86 DGA / DGA 2.0 extension
306 if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
307 then
308 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
309 [ AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
310 [Define if you have the Xxf86dga library version 2])
311 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
312 ],,
313 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
314 fi
316 dnl *** Check for XFree86 VMODE extension
317 if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
318 then
319 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
320 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
321 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
322 ],,
323 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
324 fi
326 dnl *** Check for X RandR extension
327 if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
328 then
329 AC_TRY_COMPILE([#include <X11/Xlib.h>
330 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
331 [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
332 fi
334 dnl *** Check for Transform functions in Xrender
335 if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
336 then
337 AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
338 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
339 [Define if Xrender has the XRenderSetPictureTransform function])],,
340 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
341 fi
342 ]
343 ) dnl *** End of X11/Xlib.h check
345 dnl Check for the presence of OpenGL
346 if test "x$with_opengl" != "xno"
347 then
348 if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
349 then
350 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
351 This prevents linking to OpenGL. Delete the file and restart configure.])
352 fi
354 AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
355 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
356 then
357 AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
358 dnl Check for some problems due to old Mesa versions
359 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
360 AC_TRY_COMPILE(
361 [#include <GL/gl.h>],
362 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
363 [wine_cv_opengl_version_OK="yes"],
364 [wine_cv_opengl_version_OK="no"]
365 )
366 )
368 if test "$wine_cv_opengl_version_OK" = "yes"
369 then
370 dnl Check for the presence of the library
371 AC_CHECK_LIB(GL,glXCreateContext,
372 OPENGL_LIBS="-lGL"
373 ,,
374 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
376 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
377 then
378 OPENGLFILES='$(OPENGLFILES)'
379 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
380 fi
381 dnl Check for GLU32 library.
382 AC_CHECK_LIB(GLU,gluLookAt,
383 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
384 GLU32FILES='$(GLU32FILES)']
385 ,,
386 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
387 )
388 fi
390 dnl Check for glut32 library.
391 AC_CHECK_LIB(glut,glutMainLoop,
392 [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
393 AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
394 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
395 fi
396 fi
398 dnl **** Check for NAS ****
399 AC_SUBST(NASLIBS,"")
400 AC_CHECK_HEADERS(audio/audiolib.h,
401 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
402 AC_CHECK_LIB(audio,AuCreateFlow,
403 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
404 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
405 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
407 CPPFLAGS="$ac_save_CPPFLAGS"
408 XFILES='$(XFILES)'
409 else
410 XLIB=""
411 X_CFLAGS=""
412 X_LIBS=""
413 fi
415 dnl **** Check which curses lib to use ***
416 CURSESLIBS=""
417 if test "x$with_curses" != "xno"
418 then
419 AC_CHECK_HEADERS(ncurses.h,
420 [AC_CHECK_LIB(ncurses,waddch,
421 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
422 CURSESLIBS="-lncurses"],
423 [AC_CHECK_HEADERS(curses.h,
424 [AC_CHECK_LIB(curses,waddch,
425 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
426 CURSESLIBS="-lcurses"])])])])
427 fi
428 AC_SUBST(CURSESLIBS)
430 dnl **** Check for SANE ****
431 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
432 if test "$sane_devel" = "no"
433 then
434 SANELIBS=""
435 SANEINCL=""
436 else
437 SANELIBS="`$sane_devel --libs`"
438 SANEINCL="`$sane_devel --cflags`"
439 ac_save_CPPFLAGS="$CPPFLAGS"
440 ac_save_LIBS="$LIBS"
441 CPPFLAGS="$CPPFLAGS $SANEINCL"
442 LIBS="$LIBS $SANELIBS"
443 AC_CHECK_HEADER(sane/sane.h,
444 [AC_CHECK_LIB(sane,sane_open,
445 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
446 [SANELIBS=""
447 SANEINCL=""])],
448 [SANELIBS=""
449 SANEINCL=""])
450 LIBS="$ac_save_LIBS"
451 CPPFLAGS="$ac_save_CPPFLAGS"
452 fi
453 AC_SUBST(SANELIBS)
454 AC_SUBST(SANEINCL)
456 dnl **** Check for the ICU library ****
457 AC_CHECK_HEADERS(unicode/ubidi.h)
458 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
459 then
460 saved_libs="$LIBS"
461 ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
462 ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
463 ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
464 AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
465 LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
466 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
467 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
468 AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
469 AC_MSG_RESULT(yes)],
470 [AC_MSG_RESULT(no)])
471 LIBS="$saved_libs"
472 fi
474 dnl **** Check for FreeType 2 ****
475 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
476 if test "$ft_lib" = "no"
477 then
478 FREETYPELIBS=""
479 FREETYPEINCL=""
480 wine_cv_msg_freetype=no
481 else
482 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
483 if test "$ft_devel" = "no"
484 then
485 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
486 if test "$ft_devel2" = "freetype2-config"
487 then
488 ft_devel=$ft_devel2
489 fi
490 fi
491 if test "$ft_devel" = "no"
492 then
493 FREETYPELIBS=""
494 FREETYPEINCL=""
495 wine_cv_msg_freetype=yes
496 else
497 FREETYPELIBS=`$ft_devel --libs`
498 FREETYPEINCL=`$ft_devel --cflags`
499 ac_save_CPPFLAGS="$CPPFLAGS"
500 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
501 AC_CHECK_HEADERS(ft2build.h \
502 freetype/freetype.h \
503 freetype/ftglyph.h \
504 freetype/tttables.h \
505 freetype/ftnames.h \
506 freetype/ftsnames.h \
507 freetype/ttnameid.h \
508 freetype/ftoutln.h \
509 freetype/ftwinfnt.h \
510 freetype/internal/sfnt.h,,,
511 [#if HAVE_FT2BUILD_H
512 #include <ft2build.h>
513 #endif])
514 AC_TRY_CPP([#include <ft2build.h>
515 #include <freetype/fttrigon.h>],
516 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
517 [Define if you have the <freetype/fttrigon.h> header file.])
518 wine_cv_fttrigon=yes],
519 wine_cv_fttrigon=no)
520 CPPFLAGS="$ac_save_CPPFLAGS"
521 dnl Check that we have at least freetype/freetype.h
522 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
523 then
524 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
525 wine_cv_msg_freetype=no
526 else
527 FREETYPELIBS=""
528 FREETYPEINCL=""
529 wine_cv_msg_freetype=yes
530 fi
531 fi
532 fi
533 AC_SUBST(FREETYPELIBS)
534 AC_SUBST(FREETYPEINCL)
536 dnl Only build the fonts dir if we have both freetype and fontforge
537 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
538 then
539 AC_SUBST(FONTSSUBDIRS,"fonts")
540 fi
542 dnl **** Check for parport (currently Linux only) ****
543 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
544 AC_TRY_COMPILE(
545 [#include <linux/ppdev.h>],
546 [ioctl (1,PPCLAIM,0)],
547 [ac_cv_c_ppdev="yes"],
548 [ac_cv_c_ppdev="no"])
549 )
550 if test "$ac_cv_c_ppdev" = "yes"
551 then
552 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
553 fi
555 dnl **** Check for va_copy ****
556 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
557 AC_TRY_LINK(
558 [#include <stdarg.h>],
559 [va_list ap1, ap2;
560 va_copy(ap1,ap2);
561 ],
562 [ac_cv_c_va_copy="yes"],
563 [ac_cv_c_va_copy="no"])
564 )
565 if test "$ac_cv_c_va_copy" = "yes"
566 then
567 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
568 fi
569 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
570 AC_TRY_LINK(
571 [#include <stdarg.h>],
572 [va_list ap1, ap2;
573 __va_copy(ap1,ap2);
574 ],
575 [ac_cv_c___va_copy="yes"],
576 [ac_cv_c___va_copy="no"])
577 )
578 if test "$ac_cv_c___va_copy" = "yes"
579 then
580 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
581 fi
583 dnl **** Check for sigsetjmp ****
584 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
585 AC_TRY_LINK(
586 [#include <setjmp.h>],
587 [sigjmp_buf buf;
588 sigsetjmp( buf, 1 );
589 siglongjmp( buf, 1 );],
590 [ac_cv_c_sigsetjmp="yes"],
591 [ac_cv_c_sigsetjmp="no"])
592 )
593 if test "$ac_cv_c_sigsetjmp" = "yes"
594 then
595 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
596 fi
598 dnl **** Check for pthread_rwlock_t ****
599 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
600 #include <pthread.h>])
602 dnl **** Check for pthread functions ****
603 ac_save_LIBS="$LIBS"
604 LIBS="$LIBS $LIBPTHREAD"
605 AC_CHECK_FUNCS(\
606 pthread_getattr_np \
607 pthread_get_stackaddr_np \
608 pthread_get_stacksize_np \
609 )
610 LIBS="$ac_save_LIBS"
612 dnl **** Check for Open Sound System ****
613 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
615 AC_CACHE_CHECK([for Open Sound System],
616 ac_cv_c_opensoundsystem,
617 AC_TRY_COMPILE([
618 #if defined(HAVE_SYS_SOUNDCARD_H)
619 #include <sys/soundcard.h>
620 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
621 #include <machine/soundcard.h>
622 #elif defined(HAVE_SOUNDCARD_H)
623 #include <soundcard.h>
624 #endif
625 ],[
627 /* check for one of the Open Sound System specific SNDCTL_ defines */
628 #if !defined(SNDCTL_DSP_STEREO)
629 #error No open sound system
630 #endif
631 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
633 if test "$ac_cv_c_opensoundsystem" = "yes"
634 then
635 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
636 fi
638 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
639 ac_cv_c_opensoundsystem_midi,
640 AC_TRY_COMPILE([
641 #if defined(HAVE_SYS_SOUNDCARD_H)
642 #include <sys/soundcard.h>
643 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
644 #include <machine/soundcard.h>
645 #elif defined(HAVE_SOUNDCARD_H)
646 #include <soundcard.h>
647 #endif
648 ],[
650 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
651 #if !defined(SNDCTL_SEQ_SYNC)
652 #error No open sound system MIDI interface
653 #endif
654 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
656 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
657 then
658 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
659 fi
661 dnl **** Check for aRts Sound Server ****
662 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
663 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
664 then
665 ARTSC_CFLAGS=""
666 for i in `$ARTSCCONFIG --cflags`
667 do
668 case "$i" in
669 -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
670 esac
671 done
672 ARTSC_LIBS=`$ARTSCCONFIG --libs`
673 save_CFLAGS="$CFLAGS"
674 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
675 AC_CHECK_LIB(artsc,arts_init,
676 [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
677 [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
678 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
679 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],)
680 CFLAGS="$save_CFLAGS"
681 fi
683 dnl **** Check for ALSA 1.x ****
684 AC_SUBST(ALSALIBS,"")
685 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
686 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
687 then
688 AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
689 [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
690 #include <alsa/asoundlib.h>
691 #elif defined(HAVE_SYS_ASOUNDLIB_H)
692 #include <sys/asoundlib.h>
693 #endif],
694 [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
695 [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
696 ALSALIBS="-lasound"])])
697 fi
699 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
701 AC_SUBST(AUDIOIOLIBS,"")
702 AC_CHECK_HEADERS(libaudioio.h,
703 [AC_CHECK_LIB(audioio,AudioIOGetVersion,
704 [AUDIOIOLIBS="-laudioio"
705 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
707 dnl **** Check for capi4linux ****
709 AC_CHECK_HEADERS(capi20.h,[
710 AC_CHECK_HEADERS(linux/capi.h,[
711 AC_CHECK_LIB(capi20,capi20_register,[
712 AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
713 ])
714 ])
715 ])
717 dnl **** Check for broken glibc mmap64 ****
719 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
720 AC_TRY_RUN([
721 #define _FILE_OFFSET_BITS 64
722 #include <stdio.h>
723 #include <unistd.h>
724 #include <fcntl.h>
725 #include <sys/mman.h>
726 #include <errno.h>
728 int main(int argc,char **argv) {
729 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
730 if (fd == -1) exit(1);
732 unlink("conftest.map");
734 write(fd,"test",4);
736 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
737 (errno == EINVAL)
738 ) {
739 exit(1);
740 }
741 close(fd);
742 fprintf(stderr,"success!\n");
743 exit(0);
744 }
746 ],
747 ac_cv_mmap64_works="yes",
748 ac_cv_mmap64_works="no",
749 ac_cv_mmap64_works="no") )
751 if test "$ac_cv_mmap64_works" = "yes"
752 then
753 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
754 fi
756 dnl **** Check for gcc specific options ****
758 AC_SUBST(EXTRACFLAGS,"")
759 if test "x${GCC}" = "xyes"
760 then
761 EXTRACFLAGS="-Wall -pipe"
763 dnl Check for strength-reduce bug
764 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
765 AC_TRY_RUN([
766 int L[[4]] = {0,1,2,3};
767 int main(void) {
768 static int Array[[3]];
769 unsigned int B = 3;
770 int i;
771 for(i=0; i<B; i++) Array[[i]] = i - 3;
772 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
773 L[[i]] = 4;
775 exit( Array[[1]] != -2 || L[[2]] != 3);
776 }],
777 ac_cv_c_gcc_strength_bug="no",
778 ac_cv_c_gcc_strength_bug="yes",
779 ac_cv_c_gcc_strength_bug="yes") )
780 if test "$ac_cv_c_gcc_strength_bug" = "yes"
781 then
782 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
783 fi
785 dnl Check for -fshort-wchar
786 AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
787 [WINE_TRY_CFLAGS([-fshort-wchar],
788 ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
789 if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
790 then
791 AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
792 fi
794 dnl Check for -mpreferred-stack-boundary
795 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
796 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
797 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
798 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
799 then
800 EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
801 fi
803 dnl Check for -fno-strict-aliasing
804 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
805 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
806 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
807 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
808 then
809 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
810 fi
812 dnl Check for -gstabs+ option
813 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
814 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
815 if test "$ac_cv_c_gcc_gstabs" = "yes"
816 then
817 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
818 fi
820 dnl Check for noisy string.h
821 saved_CFLAGS="$CFLAGS"
822 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
823 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
824 AC_TRY_COMPILE([#include <string.h>],[],
825 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
826 CFLAGS="$saved_CFLAGS"
827 if test "$ac_cv_c_string_h_warnings" = "no"
828 then
829 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
830 fi
831 fi
833 dnl **** Check how to define a function in assembly code ****
835 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
836 WINE_TRY_ASM_LINK(
837 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
838 ac_cv_asm_func_def=".def",
839 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
840 ac_cv_asm_func_def=".type @function",
841 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
842 ac_cv_asm_func_def=".type 2",
843 ac_cv_asm_func_def="unknown")])]))
845 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
846 case "$ac_cv_asm_func_def" in
847 ".def")
848 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
849 ".type @function")
850 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
851 ".type 2")
852 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
853 *)
854 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
855 esac
857 dnl **** Check for underscore on external symbols ****
859 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
860 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
861 [extern int ac_test;],
862 [if (ac_test) return 1],
863 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
865 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
866 if test "$ac_cv_c_extern_prefix" = "yes"
867 then
868 AC_DEFINE([__ASM_NAME(name)], ["_" name])
869 else
870 AC_DEFINE([__ASM_NAME(name)], [name])
871 fi
873 dnl **** Check how to do strings in assembler ****
875 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
876 WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
877 WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
878 WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
879 AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
881 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
882 [Define to the assembler keyword used to specify an ASCII string])
884 dnl **** Check for .short in assembler ****
886 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
887 WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
888 WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
889 AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
891 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
892 [Define to the assembler keyword used to specify a word value])
894 dnl **** Check for .size in assembler ****
896 AC_CACHE_CHECK([for .size in assembler], ac_cv_c_asm_size,
897 WINE_TRY_ASM_LINK([".globl _ac_test\n.size _ac_test, . - _ac_test"],,,
898 ac_cv_c_asm_size="yes",ac_cv_c_asm_size="no"))
900 if test "$ac_cv_c_asm_size" = "yes"
901 then
902 AC_DEFINE(HAVE_ASM_DOT_SIZE, 1, [Define if the assembler keyword .size is accepted])
903 fi
905 dnl **** Check for working dll ****
907 AC_SUBST(DLLEXT,"")
908 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
909 AC_SUBST(DLLIBS,"")
910 AC_SUBST(LDSHARED,"")
911 AC_SUBST(LDDLLFLAGS,"")
912 AC_SUBST(LIBEXT,"so")
913 AC_SUBST(IMPLIBEXT,"def")
915 case $host_os in
916 cygwin*|mingw32*)
917 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
918 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
919 if test "$DLLWRAP" = "false"; then
920 LIBEXT="a"
921 else
922 dnl FIXME - check whether dllwrap works correctly...
923 LIBEXT="dll"
924 fi
925 IMPLIBEXT="a"
926 dnl We can't build 16-bit NE dlls
927 WIN16_FILES=""
928 WIN16_INSTALL=""
929 ;;
930 *)
931 AC_CHECK_HEADERS(dlfcn.h,
932 [AC_CHECK_FUNCS(dlopen,,
933 [AC_CHECK_LIB(dl,dlopen,
934 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
935 DLLIBS="-ldl"],
936 [LIBEXT="a"])])],
937 [LIBEXT="a"])
939 if test "$LIBEXT" = "so"
940 then
941 DLLFLAGS="$DLLFLAGS -fPIC"
942 DLLEXT=".so"
943 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
944 [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
945 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
946 if test "$ac_cv_c_dll_gnuelf" = "yes"
947 then
948 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
949 LDDLLFLAGS="-shared -Wl,-Bsymbolic"
950 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
951 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
952 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
953 if test "$ac_cv_c_dll_zdefs" = "yes"
954 then
955 LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
956 fi
958 AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
959 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
960 ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
961 if test "$ac_cv_c_dll_init_fini" = "yes"
962 then
963 LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
964 fi
966 AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
967 [echo '{ global: *; };' >conftest.map
968 WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
969 ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
970 rm -f conftest.map])
971 if test "$ac_cv_c_ld_version_scripts" = "yes"
972 then
973 LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
974 fi
976 AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
977 [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
978 ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
979 if test "$ac_cv_c_export_dynamic" = "yes"
980 then
981 AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
982 fi
984 case $host_cpu in
985 *i[[3456789]]86*)
986 AC_CACHE_CHECK([whether we can relocate the executable to 0x77f00000], ac_cv_ld_reloc_exec,
987 [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x77f00400],
988 ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
989 if test "$ac_cv_ld_reloc_exec" = "yes"
990 then
991 LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x77f00400"
992 fi
993 ;;
994 esac
996 else
997 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
998 [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
999 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
1000 if test "$ac_cv_c_dll_unixware" = "yes"
1001 then
1002 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
1003 LDDLLFLAGS="-Wl,-G,-B,symbolic"
1005 else
1006 AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
1007 [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
1008 if test "$ac_cv_c_dll_macho" = "yes"
1009 then
1010 LIBEXT="dylib"
1011 LDDLLFLAGS="-bundle -flat_namespace -undefined suppress -read_only_relocs warning"
1012 LDSHARED="\$(CC) -dynamiclib"
1013 CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
1014 STRIP="$STRIP -u -r"
1015 dnl Relocate wine executable
1016 AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
1017 dnl Relocate libwine.dyld too
1018 AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
1019 dnl declare needed frameworks
1020 AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1021 AC_SUBST(IOKITLIB,"-framework IOKit")
1022 dnl using IOKit imply we use CoreFoundation too
1023 IOKITLIB="$IOKITLIB $COREFOUNDATIONLIB"
1024 else
1025 AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1026 [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1027 if test "$ac_cv_c_dll_hpux" = "yes"
1028 then
1029 LIBEXT="sl"
1030 DLLEXT=".sl"
1031 LDDLLFLAGS="-shared -fPIC"
1032 LDSHARED="\$(CC) -shared"
1033 fi
1034 fi
1035 fi
1036 fi
1037 fi
1039 dnl Check for cross compiler to build test programs
1040 AC_SUBST(CROSSTEST,"")
1041 if test "$cross_compiling" = "no"
1042 then
1043 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1044 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1045 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1046 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1047 fi
1048 ;;
1049 esac
1051 if test "$LIBEXT" = "a"; then
1052 AC_MSG_ERROR(
1053 [could not find a way to build shared libraries.
1054 It is currently not possible to build Wine without shared library
1055 (.so) support to allow transparent switch between .so and .dll files.
1056 If you are using Linux, you will need a newer binutils.]
1057 )
1058 fi
1060 case $build_os in
1061 cygwin*|mingw32*)
1062 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
1063 darwin*|macosx*)
1064 AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1065 *)
1066 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1067 esac
1069 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1070 case $host_os in
1071 mingw32*)
1072 AC_SUBST(CRTLIBS,"-lmsvcrt")
1073 AC_SUBST(SOCKETLIBS,"-lws2_32")
1074 ;;
1075 esac
1077 case $host_os in
1078 linux*)
1079 case $host_cpu in
1080 *i[[3456789]]86*) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader") ;;
1081 *) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread") ;;
1082 esac
1083 AC_SUBST(MAIN_BINARY,"wine-glibc")
1084 ;;
1085 darwin*)
1086 AC_SUBST(WINE_BINARIES,"wine-pthread")
1087 AC_SUBST(MAIN_BINARY,"wine-pthread")
1088 ;;
1089 *)
1090 AC_SUBST(WINE_BINARIES,"wine-kthread")
1091 AC_SUBST(MAIN_BINARY,"wine-kthread")
1092 ;;
1093 esac
1095 dnl **** Get the soname for libraries that we load dynamically ****
1097 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1098 then
1099 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1100 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1101 WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1102 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1103 WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1104 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1105 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1106 WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1107 WINE_GET_SONAME(cups,cupsGetDefault)
1108 WINE_GET_SONAME(jack,jack_client_new)
1109 WINE_GET_SONAME(fontconfig,FcInit)
1110 WINE_GET_SONAME(ssl,SSL_library_init)
1111 WINE_GET_SONAME(crypto,BIO_new_socket)
1112 WINE_GET_SONAME(ncurses,waddch)
1113 WINE_GET_SONAME(curses,waddch)
1114 WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1115 WINE_GET_SONAME(ungif,DGifOpen)
1116 WINE_GET_SONAME(gif,DGifOpen)
1117 WINE_GET_SONAME(lcms,cmsOpenProfileFromFile)
1118 WINE_GET_SONAME(capi20,capi20_isinstalled)
1119 fi
1122 dnl **** Check for functions ****
1124 AC_FUNC_ALLOCA()
1125 AC_CHECK_FUNCS(\
1126 _lwp_create \
1127 _lwp_self \
1128 _pclose \
1129 _popen \
1130 _snprintf \
1131 _spawnvp \
1132 _stricmp \
1133 _strnicmp \
1134 _vsnprintf \
1135 chsize \
1136 clone \
1137 epoll_create \
1138 ffs \
1139 finite \
1140 fork \
1141 fpclass \
1142 fstatfs \
1143 fstatvfs \
1144 ftruncate \
1145 futimes \
1146 futimesat \
1147 getnetbyname \
1148 getopt_long \
1149 getpagesize \
1150 getprotobyname \
1151 getprotobynumber \
1152 getpwuid \
1153 getservbyport \
1154 gettid \
1155 gettimeofday \
1156 getuid \
1157 inet_network \
1158 lstat \
1159 memmove \
1160 mmap \
1161 pclose \
1162 popen \
1163 pread \
1164 pwrite \
1165 readlink \
1166 rfork \
1167 sched_yield \
1168 select \
1169 sendmsg \
1170 settimeofday \
1171 sigaltstack \
1172 sigprocmask \
1173 snprintf \
1174 spawnvp \
1175 statfs \
1176 statvfs \
1177 strcasecmp \
1178 strerror \
1179 strncasecmp \
1180 tcgetattr \
1181 timegm \
1182 usleep \
1183 vsnprintf \
1184 wait4 \
1185 waitpid \
1186 )
1188 dnl **** Checks for headers that depend on other ones ****
1190 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1191 [#include <sys/types.h>
1192 #if HAVE_SYS_PARAM_H
1193 # include <sys/param.h>
1194 #endif])
1196 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1197 [#include <sys/types.h>
1198 #if HAVE_SYS_SOCKET_H
1199 # include <sys/socket.h>
1200 #endif])
1202 AC_CHECK_HEADERS([resolv.h],,,
1203 [#include <sys/types.h>
1204 #if HAVE_SYS_SOCKET_H
1205 # include <sys/socket.h>
1206 #endif
1207 #if HAVE_NETINET_IN_H
1208 # include <netinet/in.h>
1209 #endif
1210 #if HAVE_ARPA_NAMESER_H
1211 # include <arpa/nameser.h>
1212 #endif])
1214 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1216 dnl **** Check for v4l(2) headers ****
1218 AC_CHECK_HEADERS(linux/videodev.h,,,
1219 [#ifdef HAVE_SYS_TIME_H
1220 #include <sys/time.h>
1221 #endif
1222 #ifdef HAVE_ASM_TYPES_H
1223 #include <asm/types.h>
1224 #endif])
1226 dnl **** Check for IPX headers (currently Linux only) ****
1228 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1229 AC_TRY_COMPILE(
1230 [#include <sys/types.h>
1231 #ifdef HAVE_SYS_SOCKET_H
1232 # include <sys/socket.h>
1233 #endif
1234 #include <netipx/ipx.h>],
1235 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1236 [ac_cv_c_ipx_gnu="yes"],
1237 [ac_cv_c_ipx_gnu="no"])
1238 )
1239 if test "$ac_cv_c_ipx_gnu" = "yes"
1240 then
1241 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1242 fi
1244 if test "$ac_cv_c_ipx_gnu" = "no"
1245 then
1246 AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1247 AC_TRY_COMPILE(
1248 [#include <sys/types.h>
1249 #ifdef HAVE_SYS_SOCKET_H
1250 # include <sys/socket.h>
1251 #endif
1252 #include <asm/types.h>
1253 #include <linux/ipx.h>],
1254 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1255 [ac_cv_c_ipx_linux="yes"],
1256 [ac_cv_c_ipx_linux="no"])
1257 )
1258 if test "$ac_cv_c_ipx_linux" = "yes"
1259 then
1260 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1261 fi
1262 fi
1264 dnl **** Check for types ****
1266 AC_C_CONST
1267 AC_C_INLINE
1268 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1269 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1271 AC_CACHE_CHECK([whether linux/input.h is for real],
1272 wine_cv_linux_input_h,
1273 AC_TRY_COMPILE([
1274 #include <linux/input.h>
1275 ] , [
1276 int foo = EVIOCGBIT(EV_ABS,42);
1277 int bar = BTN_PINKIE;
1278 int fortytwo = 42;
1279 ],
1280 wine_cv_linux_input_h=yes,
1281 wine_cv_linux_input_h=no,
1282 no
1283 )
1284 )
1285 if test "$wine_cv_linux_input_h" = "yes"
1286 then
1287 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1288 [Define if we have linux/input.h AND it contains the INPUT event API])
1289 fi
1291 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1292 AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1293 wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1294 if test "$wine_cv_have_sigaddset" = "yes"
1295 then
1296 AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1297 fi
1300 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1301 wine_cv_linux_gethostbyname_r_6,
1302 AC_TRY_LINK([
1303 #include <netdb.h>
1304 ], [
1305 char *name=NULL;
1306 struct hostent he;
1307 struct hostent *result;
1308 char *buf=NULL;
1309 int bufsize=0;
1310 int res,errnr;
1311 char *addr=NULL;
1312 int addrlen=0;
1313 int addrtype=0;
1314 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1315 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1316 ],
1317 wine_cv_linux_gethostbyname_r_6=yes,
1318 wine_cv_linux_gethostbyname_r_6=no
1319 )
1320 )
1321 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1322 then
1323 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1324 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1325 fi
1327 if test "$ac_cv_header_linux_joystick_h" = "yes"
1328 then
1329 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1330 wine_cv_linux_joystick_22_api,
1331 AC_TRY_COMPILE([
1332 #include <sys/ioctl.h>
1333 #include <linux/joystick.h>
1335 struct js_event blub;
1336 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1337 #error "no 2.2 header"
1338 #endif
1339 ],/*empty*/,
1340 wine_cv_linux_joystick_22_api=yes,
1341 wine_cv_linux_joystick_22_api=no,
1342 wine_cv_linux_joystick_22_api=no
1343 )
1344 )
1345 if test "$wine_cv_linux_joystick_22_api" = "yes"
1346 then
1347 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1348 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1349 fi
1350 fi
1352 dnl **** statfs checks ****
1354 if test "$ac_cv_header_sys_vfs_h" = "yes"
1355 then
1356 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1357 wine_cv_sys_vfs_has_statfs,
1358 AC_TRY_COMPILE([
1359 #include <sys/types.h>
1360 #ifdef HAVE_SYS_PARAM_H
1361 # include <sys/param.h>
1362 #endif
1363 #include <sys/vfs.h>
1364 ],[
1365 struct statfs stfs;
1367 memset(&stfs,0,sizeof(stfs));
1368 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1369 )
1370 )
1371 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1372 then
1373 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1374 [Define if the struct statfs is defined by <sys/vfs.h>])
1375 fi
1376 fi
1378 if test "$ac_cv_header_sys_statfs_h" = "yes"
1379 then
1380 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1381 wine_cv_sys_statfs_has_statfs,
1382 AC_TRY_COMPILE([
1383 #include <sys/types.h>
1384 #ifdef HAVE_SYS_PARAM_H
1385 # include <sys/param.h>
1386 #endif
1387 #include <sys/statfs.h>
1388 ],[
1389 struct statfs stfs;
1390 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1391 )
1392 )
1393 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1394 then
1395 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1396 [Define if the struct statfs is defined by <sys/statfs.h>])
1397 fi
1398 fi
1400 if test "$ac_cv_header_sys_mount_h" = "yes"
1401 then
1402 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1403 wine_cv_sys_mount_has_statfs,
1404 AC_TRY_COMPILE([
1405 #include <sys/types.h>
1406 #ifdef HAVE_SYS_PARAM_H
1407 # include <sys/param.h>
1408 #endif
1409 #include <sys/mount.h>
1410 ],[
1411 struct statfs stfs;
1412 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1413 )
1414 )
1415 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1416 then
1417 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1418 [Define if the struct statfs is defined by <sys/mount.h>])
1419 fi
1420 fi
1422 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1424 dnl Check for statfs members
1425 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1426 [#include <sys/types.h>
1427 #ifdef HAVE_SYS_PARAM_H
1428 # include <sys/param.h>
1429 #endif
1430 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1431 # include <sys/mount.h>
1432 #else
1433 # ifdef STATFS_DEFINED_BY_SYS_VFS
1434 # include <sys/vfs.h>
1435 # else
1436 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1437 # include <sys/statfs.h>
1438 # endif
1439 # endif
1440 #endif])
1442 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1443 [#ifdef HAVE_SYS_STATVFS_H
1444 #include <sys/statvfs.h>
1445 #endif])
1447 dnl Check for socket structure members
1448 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1449 [#include <sys/types.h>
1450 #ifdef HAVE_SYS_SOCKET_H
1451 # include <sys/socket.h>
1452 #endif
1453 #ifdef HAVE_SYS_UN_H
1454 # include <sys/un.h>
1455 #endif])
1457 dnl Check for siginfo_t members
1458 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1460 dnl Check for struct option
1461 AC_CHECK_MEMBERS([struct option.name],,,
1462 [#ifdef HAVE_GETOPT_H
1463 #include <getopt.h>
1464 #endif])
1466 dnl Check for stat.st_blocks
1467 AC_CHECK_MEMBERS([struct stat.st_blocks])
1469 dnl *** check for the need to define platform-specific symbols
1471 case $host_cpu in
1472 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1473 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1474 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1475 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1476 esac
1478 case $host_vendor in
1479 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1480 esac
1482 dnl **** Generate output files ****
1484 AH_TOP([#define __WINE_CONFIG_H])
1486 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1487 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1488 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1489 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1490 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1491 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1492 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1493 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1494 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1495 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1496 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1497 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1498 WINE_CONFIG_EXTRA_DIR(include/wine)
1499 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1500 WINE_CONFIG_EXTRA_DIR(windows)
1502 MAKE_RULES=Make.rules
1503 AC_SUBST_FILE(MAKE_RULES)
1505 MAKE_DLL_RULES=dlls/Makedll.rules
1506 AC_SUBST_FILE(MAKE_DLL_RULES)
1508 MAKE_TEST_RULES=dlls/Maketest.rules
1509 AC_SUBST_FILE(MAKE_TEST_RULES)
1511 MAKE_LIB_RULES=libs/Makelib.rules
1512 AC_SUBST_FILE(MAKE_LIB_RULES)
1514 MAKE_PROG_RULES=programs/Makeprog.rules
1515 AC_SUBST_FILE(MAKE_PROG_RULES)
1517 AC_CONFIG_FILES([
1518 Make.rules
1519 dlls/Makedll.rules
1520 dlls/Maketest.rules
1521 libs/Makelib.rules
1522 programs/Makeprog.rules
1523 Makefile
1524 dlls/Makefile
1525 dlls/advapi32/Makefile
1526 dlls/advapi32/tests/Makefile
1527 dlls/advpack/Makefile
1528 dlls/advpack/tests/Makefile
1529 dlls/amstream/Makefile
1530 dlls/atl/Makefile
1531 dlls/avicap32/Makefile
1532 dlls/avifil32/Makefile
1533 dlls/cabinet/Makefile
1534 dlls/capi2032/Makefile
1535 dlls/cards/Makefile
1536 dlls/cfgmgr32/Makefile
1537 dlls/comcat/Makefile
1538 dlls/comctl32/Makefile
1539 dlls/comctl32/tests/Makefile
1540 dlls/commdlg/Makefile
1541 dlls/crtdll/Makefile
1542 dlls/crypt32/Makefile
1543 dlls/cryptdll/Makefile
1544 dlls/ctl3d/Makefile
1545 dlls/d3d8/Makefile
1546 dlls/d3d9/Makefile
1547 dlls/d3dim/Makefile
1548 dlls/d3drm/Makefile
1549 dlls/d3dx8/Makefile
1550 dlls/d3dxof/Makefile
1551 dlls/dbghelp/Makefile
1552 dlls/dciman32/Makefile
1553 dlls/ddraw/Makefile
1554 dlls/ddraw/tests/Makefile
1555 dlls/devenum/Makefile
1556 dlls/dinput/Makefile
1557 dlls/dinput8/Makefile
1558 dlls/dmband/Makefile
1559 dlls/dmcompos/Makefile
1560 dlls/dmime/Makefile
1561 dlls/dmloader/Makefile
1562 dlls/dmscript/Makefile
1563 dlls/dmstyle/Makefile
1564 dlls/dmsynth/Makefile
1565 dlls/dmusic/Makefile
1566 dlls/dmusic32/Makefile
1567 dlls/dplay/Makefile
1568 dlls/dplayx/Makefile
1569 dlls/dpnet/Makefile
1570 dlls/dpnhpast/Makefile
1571 dlls/dsound/Makefile
1572 dlls/dsound/tests/Makefile
1573 dlls/dswave/Makefile
1574 dlls/dxdiagn/Makefile
1575 dlls/dxerr8/Makefile
1576 dlls/dxerr9/Makefile
1577 dlls/dxguid/Makefile
1578 dlls/gdi/Makefile
1579 dlls/gdi/tests/Makefile
1580 dlls/glu32/Makefile
1581 dlls/glut32/Makefile
1582 dlls/hhctrl.ocx/Makefile
1583 dlls/iccvid/Makefile
1584 dlls/icmp/Makefile
1585 dlls/ifsmgr.vxd/Makefile
1586 dlls/imagehlp/Makefile
1587 dlls/imm32/Makefile
1588 dlls/iphlpapi/Makefile
1589 dlls/iphlpapi/tests/Makefile
1590 dlls/itss/Makefile
1591 dlls/kernel/Makefile
1592 dlls/kernel/tests/Makefile
1593 dlls/lzexpand/Makefile
1594 dlls/lzexpand/tests/Makefile
1595 dlls/mapi32/Makefile
1596 dlls/mapi32/tests/Makefile
1597 dlls/mlang/Makefile
1598 dlls/mlang/tests/Makefile
1599 dlls/mmdevldr.vxd/Makefile
1600 dlls/monodebg.vxd/Makefile
1601 dlls/mpr/Makefile
1602 dlls/msacm/Makefile
1603 dlls/msacm/imaadp32/Makefile
1604 dlls/msacm/msadp32/Makefile
1605 dlls/msacm/msg711/Makefile
1606 dlls/msacm/winemp3/Makefile
1607 dlls/msacm/tests/Makefile
1608 dlls/mscms/Makefile
1609 dlls/mscms/tests/Makefile
1610 dlls/msdmo/Makefile
1611 dlls/mshtml/Makefile
1612 dlls/msi/Makefile
1613 dlls/msi/tests/Makefile
1614 dlls/msimg32/Makefile
1615 dlls/msisys/Makefile
1616 dlls/msnet32/Makefile
1617 dlls/msrle32/Makefile
1618 dlls/msvcrt/Makefile
1619 dlls/msvcrt/tests/Makefile
1620 dlls/msvcrt20/Makefile
1621 dlls/msvcrt40/Makefile
1622 dlls/msvcrtd/Makefile
1623 dlls/msvcrtd/tests/Makefile
1624 dlls/msvidc32/Makefile
1625 dlls/msvideo/Makefile
1626 dlls/mswsock/Makefile
1627 dlls/netapi32/Makefile
1628 dlls/netapi32/tests/Makefile
1629 dlls/newdev/Makefile
1630 dlls/ntdll/Makefile
1631 dlls/ntdll/tests/Makefile
1632 dlls/odbc32/Makefile
1633 dlls/ole32/Makefile
1634 dlls/ole32/tests/Makefile
1635 dlls/oleacc/Makefile
1636 dlls/oleaut32/Makefile
1637 dlls/oleaut32/tests/Makefile
1638 dlls/olecli/Makefile
1639 dlls/oledlg/Makefile
1640 dlls/olepro32/Makefile
1641 dlls/olesvr/Makefile
1642 dlls/opengl32/Makefile
1643 dlls/powrprof/Makefile
1644 dlls/psapi/Makefile
1645 dlls/psapi/tests/Makefile
1646 dlls/qcap/Makefile
1647 dlls/quartz/Makefile
1648 dlls/quartz/tests/Makefile
1649 dlls/rasapi32/Makefile
1650 dlls/riched20/Makefile
1651 dlls/richedit/Makefile
1652 dlls/rpcrt4/Makefile
1653 dlls/rpcrt4/tests/Makefile
1654 dlls/rsabase/Makefile
1655 dlls/rsabase/tests/Makefile
1656 dlls/rsaenh/Makefile
1657 dlls/rsaenh/tests/Makefile
1658 dlls/secur32/Makefile
1659 dlls/sensapi/Makefile
1660 dlls/serialui/Makefile
1661 dlls/setupapi/Makefile
1662 dlls/shdocvw/Makefile
1663 dlls/shell32/Makefile
1664 dlls/shell32/tests/Makefile
1665 dlls/shfolder/Makefile
1666 dlls/shlwapi/Makefile
1667 dlls/shlwapi/tests/Makefile
1668 dlls/snmpapi/Makefile
1669 dlls/stdole32.tlb/Makefile
1670 dlls/sti/Makefile
1671 dlls/strmiids/Makefile
1672 dlls/tapi32/Makefile
1673 dlls/ttydrv/Makefile
1674 dlls/twain/Makefile
1675 dlls/unicows/Makefile
1676 dlls/url/Makefile
1677 dlls/urlmon/Makefile
1678 dlls/urlmon/tests/Makefile
1679 dlls/user/Makefile
1680 dlls/user/tests/Makefile
1681 dlls/uuid/Makefile
1682 dlls/uxtheme/Makefile
1683 dlls/vdhcp.vxd/Makefile
1684 dlls/vdmdbg/Makefile
1685 dlls/version/Makefile
1686 dlls/version/tests/Makefile
1687 dlls/vmm.vxd/Makefile
1688 dlls/vnbt.vxd/Makefile
1689 dlls/vnetbios.vxd/Makefile
1690 dlls/vtdapi.vxd/Makefile
1691 dlls/vwin32.vxd/Makefile
1692 dlls/win32s/Makefile
1693 dlls/winaspi/Makefile
1694 dlls/wined3d/Makefile
1695 dlls/winedos/Makefile
1696 dlls/wineps/Makefile
1697 dlls/wininet/Makefile
1698 dlls/wininet/tests/Makefile
1699 dlls/winmm/Makefile
1700 dlls/winmm/joystick/Makefile
1701 dlls/winmm/mcianim/Makefile
1702 dlls/winmm/mciavi/Makefile
1703 dlls/winmm/mcicda/Makefile
1704 dlls/winmm/mciseq/Makefile
1705 dlls/winmm/mciwave/Makefile
1706 dlls/winmm/midimap/Makefile
1707 dlls/winmm/tests/Makefile
1708 dlls/winmm/wavemap/Makefile
1709 dlls/winmm/winealsa/Makefile
1710 dlls/winmm/winearts/Makefile
1711 dlls/winmm/wineaudioio/Makefile
1712 dlls/winmm/winejack/Makefile
1713 dlls/winmm/winenas/Makefile
1714 dlls/winmm/wineoss/Makefile
1715 dlls/winnls/Makefile
1716 dlls/winsock/Makefile
1717 dlls/winsock/tests/Makefile
1718 dlls/winspool/Makefile
1719 dlls/winspool/tests/Makefile
1720 dlls/wintab32/Makefile
1721 dlls/wintrust/Makefile
1722 dlls/wow32/Makefile
1723 dlls/wsock32/Makefile
1724 dlls/wtsapi32/Makefile
1725 dlls/x11drv/Makefile
1726 documentation/Makefile
1727 fonts/Makefile
1728 include/Makefile
1729 libs/Makefile
1730 libs/port/Makefile
1731 libs/unicode/Makefile
1732 libs/wine/Makefile
1733 libs/wpp/Makefile
1734 loader/Makefile
1735 programs/Makefile
1736 programs/avitools/Makefile
1737 programs/clock/Makefile
1738 programs/cmdlgtst/Makefile
1739 programs/control/Makefile
1740 programs/expand/Makefile
1741 programs/msiexec/Makefile
1742 programs/notepad/Makefile
1743 programs/progman/Makefile
1744 programs/regedit/Makefile
1745 programs/regsvr32/Makefile
1746 programs/rpcss/Makefile
1747 programs/rundll32/Makefile
1748 programs/start/Makefile
1749 programs/taskmgr/Makefile
1750 programs/uninstaller/Makefile
1751 programs/view/Makefile
1752 programs/wcmd/Makefile
1753 programs/wineboot/Makefile
1754 programs/winebrowser/Makefile
1755 programs/winecfg/Makefile
1756 programs/wineconsole/Makefile
1757 programs/winedbg/Makefile
1758 programs/winefile/Makefile
1759 programs/winemenubuilder/Makefile
1760 programs/winemine/Makefile
1761 programs/winepath/Makefile
1762 programs/winetest/Makefile
1763 programs/winevdm/Makefile
1764 programs/winhelp/Makefile
1765 programs/winver/Makefile
1766 server/Makefile
1767 tools/Makefile
1768 tools/widl/Makefile
1769 tools/winapi/Makefile
1770 tools/winebuild/Makefile
1771 tools/winedump/Makefile
1772 tools/winegcc/Makefile
1773 tools/wmc/Makefile
1774 tools/wrc/Makefile])
1776 AC_OUTPUT
1778 if test "$have_x" = "no"
1779 then
1780 echo
1781 echo "*** Warning: X development files not found. Wine will be built without"
1782 echo "*** X support, which currently does not work, and would probably not be"
1783 echo "*** what you want anyway. You will need to install devel packages of"
1784 echo "*** Xlib/Xfree86 at the very least."
1785 fi
1787 if test "$wine_cv_opengl_version_OK" = "no"
1788 then
1789 echo
1790 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1791 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1792 fi
1794 if test "$wine_cv_msg_freetype" = "yes"
1795 then
1796 echo
1797 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1798 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1799 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1800 echo "*** enable Wine to use TrueType fonts."
1801 fi
1803 if test -z "$ALSALIBS" -a -z "$ARTSC_LIBS" -a -z "$AUDIOIOLIBS" -a \
1804 -z "$ac_cv_lib_soname_jack" -a -z "$NASLIBS" -a \
1805 "$ac_cv_c_opensoundsystem" = "no"
1806 then
1807 echo "*** No sound system was found. Windows applications will be silent."
1808 echo "*** The currently supported sound systems are:"
1809 echo "*** ALSA, ARTS, AudioIO, Jack, NAS and OSS"
1810 fi
1812 echo
1813 echo "Configure finished. Do '${ac_make} depend && ${ac_make}' to compile Wine."
1814 echo
1816 dnl Local Variables:
1817 dnl comment-start: "dnl "
1818 dnl comment-end: ""
1819 dnl comment-start-skip: "\\bdnl\\b\\s *"
1820 dnl compile-command: "autoconf"
1821 dnl End: