| blob | bddc309554c7668b004bdd36d8ed200c54691907 |
1 /* -*-C-*-
2 *
3 * Copyright 1998-2000 Bertho A. Stultiens (BS)
4 *
5 * This library is free software; you can redistribute it and/or
6 * modify it under the terms of the GNU Lesser General Public
7 * License as published by the Free Software Foundation; either
8 * version 2.1 of the License, or (at your option) any later version.
9 *
10 * This library is distributed in the hope that it will be useful,
11 * but WITHOUT ANY WARRANTY; without even the implied warranty of
12 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 * Lesser General Public License for more details.
14 *
15 * You should have received a copy of the GNU Lesser General Public
16 * License along with this library; if not, write to the Free Software
17 * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
18 *
19 * History:
20 * 21-May-2000 BS - Fixed the ident requirement of resource names
21 * which can be keywords.
22 * 30-Apr-2000 BS - Reintegration into the wine-tree
23 * 11-Jan-2000 BS - Very drastic cleanup because we don't have a
24 * preprocessor in here anymore.
25 * 02-Jan-2000 BS - Removed the preprocessor code
26 * 23-Dec-1999 BS - Removed the copyright for Martin von Loewis.
27 * There is really nothing left of his code in
28 * this parser.
29 * 20-Jun-1998 BS - Changed the filename conversion. Filenames are
30 * case-sensitive inder *nix, but not under dos.
31 * default behaviour is to convert to lower case.
32 * - All backslashes are converted to forward and
33 * both single and double slash is recognized as
34 * MS/Borland does.
35 * - Fixed a bug in 'yywf' case that prevented
36 * double quoted names to be scanned propperly.
37 *
38 * 19-May-1998 BS - Started to build a preprocessor.
39 * - Changed keyword processing completely to
40 * table-lookups.
41 *
42 * 20-Apr-1998 BS - Added ';' comment stripping
43 *
44 * 17-Apr-1998 BS - Made the win32 keywords optional when compiling in
45 * 16bit mode
46 *
47 * 15-Apr-1998 BS - Changed string handling to include escapes
48 * - Added unicode string handling (no codepage
49 * translation though).
50 * - 'Borrowed' the main idea of string scanning from
51 * the flex manual pages.
52 * - Added conditional handling of scanning depending
53 * on the state of the parser. This was mainly required
54 * to distinguish a file to load or raw data that
55 * follows. MS's definition of filenames is rather
56 * complex... It can be unquoted or double quoted. If
57 * double quoted, then the '\\' char is not automatically
58 * escaped according to Borland's rc compiler, but it
59 * accepts both "\\path\\file.rc" and "\path\file.rc".
60 * This makes life very hard! I go for the escaped
61 * version, as this seems to be the documented way...
62 * - Single quoted strings are now parsed and converted
63 * here.
64 * - Added comment stripping. The implementation is
65 * 'borrowed' from the flex manpages.
66 * - Rebuild string processing so that it may contain
67 * escaped '\0'.
68 */
70 /* Exclusive string handling */
71 %x tkstr
72 /* Exclusive unicode string handling */
73 %x tklstr
74 /* Exclusive rcdata single quoted data handling */
75 %x tkrcd
76 /* Exclusive comment eating... */
77 %x comment
78 /* Set when stripping c-junk */
79 %x pp_cstrip
80 /* Set when scanning #line style directives */
81 %x pp_line
82 /* Set when scanning #pragma */
83 %x pp_pragma
84 %x pp_code_page
86 %option stack
87 %option noinput nounput noyy_top_state noyywrap
88 %option 8bit never-interactive
89 %option prefix="parser_"
91 /* Some shortcut definitions */
92 ws [ \f\t\r]
93 cident [a-zA-Z_][0-9a-zA-Z_]*
95 %{
97 /*#define LEX_DEBUG*/
99 #include "config.h"
101 #include <stdio.h>
102 #include <stdlib.h>
103 #include <string.h>
104 #include <ctype.h>
105 #include <assert.h>
106 #include <errno.h>
107 #include <limits.h>
109 #ifndef HAVE_UNISTD_H
110 #define YY_NO_UNISTD_H
111 #endif
113 #include "wine/unicode.h"
114 #include "wrc.h"
115 #include "utils.h"
116 #include "parser.h"
117 #include "newstruc.h"
119 #include "parser.tab.h"
121 /* Always update the current character position within a line */
122 #define YY_USER_ACTION char_number+=yyleng; wanted_id = want_id; want_id = 0;
124 static void addcchar(char c);
125 static void addwchar(WCHAR s);
126 static string_t *get_buffered_cstring(void);
127 static string_t *get_buffered_wstring(void);
128 static string_t *make_string(char *s);
130 static char *cbuffer; /* Buffers for string collection */
131 static int cbufidx;
132 static int cbufalloc = 0;
133 static WCHAR *wbuffer;
134 static int wbufidx;
135 static int wbufalloc = 0;
137 static int current_codepage = -1; /* use language default */
139 /*
140 * This one is a bit tricky.
141 * We set 'want_id' in the parser to get the first
142 * identifier we get across in the scanner, but we
143 * also want it to be reset at nearly any token we
144 * see. Exceptions are:
145 * - newlines
146 * - comments
147 * - whitespace
148 *
149 * The scanner will automatically reset 'want_id'
150 * after *each* scanner reduction and puts is value
151 * into the var below. In this way we can see the
152 * state after the YY_RULE_SETUP (i.e. the user action;
153 * see above) and don't have to worry too much when
154 * it needs to be reset.
155 */
156 static int wanted_id = 0;
157 static int save_wanted_id; /* To save across comment reductions */
159 struct keyword {
160 const char *keyword;
161 int token;
162 int isextension;
163 int needcase;
164 int alwayskw;
165 };
167 static struct keyword keywords[] = {
168 { "ACCELERATORS", tACCELERATORS, 0, 0, 0},
169 { "ALT", tALT, 0, 0, 0},
170 { "ASCII", tASCII, 0, 0, 0},
171 { "AUTO3STATE", tAUTO3STATE, 1, 0, 0},
172 { "AUTOCHECKBOX", tAUTOCHECKBOX, 1, 0, 0},
173 { "AUTORADIOBUTTON", tAUTORADIOBUTTON, 1, 0, 0},
174 { "BEGIN", tBEGIN, 0, 0, 0},
175 { "BITMAP", tBITMAP, 0, 0, 0},
176 { "BLOCK", tBLOCK, 0, 0, 0},
177 { "BUTTON", tBUTTON, 1, 0, 0},
178 { "CAPTION", tCAPTION, 0, 0, 0},
179 { "CHARACTERISTICS", tCHARACTERISTICS, 1, 0, 0},
180 { "CHECKBOX", tCHECKBOX, 0, 0, 0},
181 { "CHECKED", tCHECKED, 0, 0, 0},
182 { "CLASS", tCLASS, 0, 0, 0},
183 { "COMBOBOX", tCOMBOBOX, 0, 0, 0},
184 { "CONTROL", tCONTROL, 0, 0, 0},
185 { "CTEXT", tCTEXT, 0, 0, 0},
186 { "CURSOR", tCURSOR, 0, 0, 0},
187 { "DEFPUSHBUTTON", tDEFPUSHBUTTON, 0, 0, 0},
188 { "DIALOG", tDIALOG, 0, 0, 0},
189 { "DIALOGEX", tDIALOGEX, 1, 0, 0},
190 { "DISCARDABLE", tDISCARDABLE, 0, 0, 0},
191 { "DLGINIT", tDLGINIT, 0, 0, 0},
192 { "EDITTEXT", tEDITTEXT, 0, 0, 0},
193 { "END", tEND, 0, 0, 0},
194 { "EXSTYLE", tEXSTYLE, 0, 0, 0},
195 { "FILEFLAGS", tFILEFLAGS, 0, 0, 0},
196 { "FILEFLAGSMASK", tFILEFLAGSMASK, 0, 0, 0},
197 { "FILEOS", tFILEOS, 0, 0, 0},
198 { "FILESUBTYPE", tFILESUBTYPE, 0, 0, 0},
199 { "FILETYPE", tFILETYPE, 0, 0, 0},
200 { "FILEVERSION", tFILEVERSION, 0, 0, 0},
201 { "FIXED", tFIXED, 0, 0, 0},
202 { "FONT", tFONT, 0, 0, 0},
203 { "FONTDIR", tFONTDIR, 0, 0, 0}, /* This is a Borland BRC extension */
204 { "GRAYED", tGRAYED, 0, 0, 0},
205 { "GROUPBOX", tGROUPBOX, 0, 0, 0},
206 { "HELP", tHELP, 0, 0, 0},
207 { "HTML", tHTML, 0, 0, 0},
208 { "ICON", tICON, 0, 0, 0},
209 { "IMPURE", tIMPURE, 0, 0, 0},
210 { "INACTIVE", tINACTIVE, 0, 0, 0},
211 { "LANGUAGE", tLANGUAGE, 1, 0, 1},
212 { "LISTBOX", tLISTBOX, 0, 0, 0},
213 { "LOADONCALL", tLOADONCALL, 0, 0, 0},
214 { "LTEXT", tLTEXT, 0, 0, 0},
215 { "MENU", tMENU, 0, 0, 0},
216 { "MENUBARBREAK", tMENUBARBREAK, 0, 0, 0},
217 { "MENUBREAK", tMENUBREAK, 0, 0, 0},
218 { "MENUEX", tMENUEX, 1, 0, 0},
219 { "MENUITEM", tMENUITEM, 0, 0, 0},
220 { "MESSAGETABLE", tMESSAGETABLE, 1, 0, 0},
221 { "MOVEABLE", tMOVEABLE, 0, 0, 0},
222 { "NOINVERT", tNOINVERT, 0, 0, 0},
223 { "NOT", tNOT, 0, 0, 0},
224 { "POPUP", tPOPUP, 0, 0, 0},
225 { "PRELOAD", tPRELOAD, 0, 0, 0},
226 { "PRODUCTVERSION", tPRODUCTVERSION, 0, 0, 0},
227 { "PURE", tPURE, 0, 0, 0},
228 { "PUSHBUTTON", tPUSHBUTTON, 0, 0, 0},
229 { "RADIOBUTTON", tRADIOBUTTON, 0, 0, 0},
230 { "RCDATA", tRCDATA, 0, 0, 0},
231 { "RTEXT", tRTEXT, 0, 0, 0},
232 { "SCROLLBAR", tSCROLLBAR, 0, 0, 0},
233 { "SEPARATOR", tSEPARATOR, 0, 0, 0},
234 { "SHIFT", tSHIFT, 0, 0, 0},
235 { "STATE3", tSTATE3, 1, 0, 0},
236 { "STRING", tSTRING, 0, 0, 0},
237 { "STRINGTABLE", tSTRINGTABLE, 0, 0, 1},
238 { "STYLE", tSTYLE, 0, 0, 0},
239 { "TOOLBAR", tTOOLBAR, 1, 0, 0},
240 { "VALUE", tVALUE, 0, 0, 0},
241 { "VERSION", tVERSION, 1, 0, 0},
242 { "VERSIONINFO", tVERSIONINFO, 0, 0, 0},
243 { "VIRTKEY", tVIRTKEY, 0, 0, 0}
244 };
246 #define NKEYWORDS (sizeof(keywords)/sizeof(keywords[0]))
247 #define KWP(p) ((const struct keyword *)(p))
248 static int kw_cmp_func(const void *s1, const void *s2)
249 {
250 int ret;
251 ret = strcasecmp(KWP(s1)->keyword, KWP(s2)->keyword);
252 if(!ret && (KWP(s1)->needcase || KWP(s2)->needcase))
253 return strcmp(KWP(s1)->keyword, KWP(s2)->keyword);
254 else
255 return ret;
256 }
258 #define KW_BSEARCH
259 #define DO_SORT
260 static struct keyword *iskeyword(char *kw)
261 {
262 struct keyword *kwp;
263 struct keyword key;
264 key.keyword = kw;
265 key.needcase = 0;
266 #ifdef DO_SORT
267 {
268 /* Make sure that it is sorted for bsearsh */
269 static int sorted = 0;
270 if(!sorted)
271 {
272 qsort(keywords, NKEYWORDS, sizeof(keywords[0]), kw_cmp_func);
273 sorted = 1;
274 }
275 }
276 #endif
277 #ifdef KW_BSEARCH
278 kwp = bsearch(&key, keywords, NKEYWORDS, sizeof(keywords[0]), kw_cmp_func);
279 #else
280 {
281 int i;
282 for(i = 0; i < NKEYWORDS; i++)
283 {
284 if(!kw_cmp_func(&key, &keywords[i]))
285 break;
286 }
287 if(i < NKEYWORDS)
288 kwp = &keywords[i];
289 else
290 kwp = NULL;
291 }
292 #endif
294 if(kwp == NULL || (kwp->isextension && !extensions))
295 return NULL;
296 else
297 return kwp;
298 }
300 /* converts an integer in string form to an unsigned long and prints an error
301 * on overflow */
302 static unsigned long xstrtoul(const char *nptr, char **endptr, int base)
303 {
304 unsigned long l;
306 errno = 0;
307 l = strtoul(nptr, endptr, base);
308 if (l == ULONG_MAX && errno == ERANGE)
309 parser_error("integer constant %s is too large", nptr);
310 return l;
311 }
313 %}
315 /*
316 **************************************************************************
317 * The flexer starts here
318 **************************************************************************
319 */
320 %%
321 /*
322 * Catch the GCC-style line statements here and parse them.
323 * This has the advantage that you can #include at any
324 * stage in the resource file.
325 * The preprocessor generates line directives in the format:
326 * # <linenum> "filename" <codes>
327 *
328 * Codes can be a sequence of:
329 * - 1 start of new file
330 * - 2 returning to previous
331 * - 3 system header
332 * - 4 interpret as C-code
333 *
334 * 4 is not used and 1 mutually excludes 2
335 * Anyhow, we are not really interested in these at all
336 * because we only want to know the linenumber and
337 * filename.
338 */
339 <INITIAL,pp_cstrip>^{ws}*\#{ws}*pragma{ws}+ yy_push_state(pp_pragma);
340 <INITIAL,pp_cstrip>^{ws}*\#{ws}* yy_push_state(pp_line);
341 <pp_line>[^\n]* {
342 int lineno, len;
343 char *cptr;
344 char *fname;
345 yy_pop_state();
346 lineno = (int)strtol(yytext, &cptr, 10);
347 if(!lineno)
348 parser_error("Malformed '#...' line-directive; invalid linenumber");
349 fname = strchr(cptr, '"');
350 if(!fname)
351 parser_error("Malformed '#...' line-directive; missing filename");
352 fname++;
353 cptr = strchr(fname, '"');
354 if(!cptr)
355 parser_error("Malformed '#...' line-directive; missing terminating \"");
356 *cptr = '\0';
357 line_number = lineno - 1; /* We didn't read the newline */
358 input_name = xstrdup(fname);
359 /* ignore contents of C include files */
360 len = strlen(input_name);
361 if (len > 1 && !strcasecmp( input_name + len - 2, ".h" ))
362 BEGIN(pp_cstrip);
363 else
364 BEGIN(INITIAL);
365 }
367 <pp_pragma>code_page[^\n]* yyless(9); yy_pop_state(); yy_push_state(pp_code_page);
368 <pp_pragma>[^\n]* yy_pop_state(); if (pedantic) parser_warning("Unrecognized #pragma directive '%s'\n",yytext);
370 <pp_code_page>\({ws}*default{ws}*\)[^\n]* current_codepage = -1; yy_pop_state();
371 <pp_code_page>\({ws}*utf8{ws}*\)[^\n]* current_codepage = CP_UTF8; yy_pop_state();
372 <pp_code_page>\({ws}*[0-9]+{ws}*\)[^\n]* {
373 char *p = yytext;
374 yy_pop_state();
375 while (*p < '0' || *p > '9') p++;
376 current_codepage = strtol( p, NULL, 10 );
377 if (current_codepage != CP_UTF8 && !wine_cp_get_table( current_codepage ))
378 {
379 parser_error("Codepage %d not supported", current_codepage);
380 current_codepage = 0;
381 }
382 }
383 <pp_code_page>[^\n]* yy_pop_state(); parser_error("Malformed #pragma code_page directive");
385 /*
386 * Strip everything until a ';' taking
387 * into account braces {} for structures,
388 * classes and enums.
389 */
390 <pp_cstrip>\n line_number++; char_number = 1;
391 <pp_cstrip>. ; /* ignore */
393 \{ return tBEGIN;
394 \} return tEND;
396 [0-9]+[lL]? { parser_lval.num = xstrtoul(yytext, 0, 10); return toupper(yytext[yyleng-1]) == 'L' ? tLNUMBER : tNUMBER; }
397 0[xX][0-9A-Fa-f]+[lL]? { parser_lval.num = xstrtoul(yytext, 0, 16); return toupper(yytext[yyleng-1]) == 'L' ? tLNUMBER : tNUMBER; }
398 0[oO][0-7]+[lL]? { parser_lval.num = xstrtoul(yytext+2, 0, 8); return toupper(yytext[yyleng-1]) == 'L' ? tLNUMBER : tNUMBER; }
400 /*
401 * The next two rules scan identifiers and filenames.
402 * This is achieved by using the priority ruling
403 * of the scanner where a '.' is valid in a filename
404 * and *only* in a filename. In this case, the second
405 * rule will be reduced because it is longer.
406 */
407 [A-Za-z_0-9.]+ {
408 struct keyword *tok = iskeyword(yytext);
410 if(tok)
411 {
412 if(wanted_id && !tok->alwayskw)
413 {
414 parser_lval.str = make_string(yytext);
415 return tIDENT;
416 }
417 else
418 return tok->token;
419 }
420 else
421 {
422 parser_lval.str = make_string(yytext);
423 return tIDENT;
424 }
425 }
426 [A-Za-z_0-9./\\]+ parser_lval.str = make_string(yytext); return tFILENAME;
428 /*
429 * Wide string scanning
430 */
431 L\" {
432 yy_push_state(tklstr);
433 wbufidx = 0;
434 if(!win32)
435 parser_warning("16bit resource contains unicode strings\n");
436 }
437 <tklstr>\"{ws}+ |
438 <tklstr>\" {
439 yy_pop_state();
440 parser_lval.str = get_buffered_wstring();
441 return tSTRING;
442 }
443 <tklstr>\\[0-7]{1,6} { /* octal escape sequence */
444 unsigned int result;
445 result = strtoul(yytext+1, 0, 8);
446 if ( result > 0xffff )
447 parser_error("Character constant out of range");
448 addwchar((WCHAR)result);
449 }
450 <tklstr>\\x[0-9a-fA-F]{4} { /* hex escape sequence */
451 unsigned int result;
452 result = strtoul(yytext+2, 0, 16);
453 addwchar((WCHAR)result);
454 }
455 <tklstr>\\x[0-9a-fA-F]{1,3} { parser_error("Invalid hex escape sequence '%s'", yytext); }
457 <tklstr>\\[0-9]+ parser_error("Bad escape sequence");
458 <tklstr>\\\n{ws}* line_number++; char_number = 1; /* backslash at EOL continues string after leading whitespace on next line */
459 <tklstr>\\a addwchar('\a');
460 <tklstr>\\b addwchar('\b');
461 <tklstr>\\f addwchar('\f');
462 <tklstr>\\n addwchar('\n');
463 <tklstr>\\r addwchar('\r');
464 <tklstr>\\t addwchar('\t');
465 <tklstr>\\v addwchar('\v');
466 <tklstr>\\. addwchar(yytext[1]);
467 <tklstr>\\\r\n addwchar(yytext[2]); line_number++; char_number = 1;
468 <tklstr>\"\" addwchar('\"'); /* "bla""bla" -> "bla\"bla" */
469 <tklstr>\\\"\" addwchar('\"'); /* "bla\""bla" -> "bla\"bla" */
470 <tklstr>\"{ws}+\" ; /* "bla" "bla" -> "blabla" */
471 <tklstr>[^\\\n\"]+ {
472 char *yptr = yytext;
473 while(*yptr) /* FIXME: codepage translation */
474 addwchar(*yptr++ & 0xff);
475 }
476 <tklstr>\n parser_error("Unterminated string");
478 /*
479 * Normal string scanning
480 */
481 \" yy_push_state(tkstr); cbufidx = 0;
482 <tkstr>\"{ws}+ |
483 <tkstr>\" {
484 yy_pop_state();
485 parser_lval.str = get_buffered_cstring();
486 return tSTRING;
487 }
488 <tkstr>\\[0-7]{1,3} { /* octal escape sequence */
489 int result;
490 result = strtol(yytext+1, 0, 8);
491 if ( result > 0xff )
492 parser_error("Character constant out of range");
493 addcchar((char)result);
494 }
495 <tkstr>\\x[0-9a-fA-F]{2} { /* hex escape sequence */
496 int result;
497 result = strtol(yytext+2, 0, 16);
498 addcchar((char)result);
499 }
500 <tkstr>\\x[0-9a-fA-F] { parser_error("Invalid hex escape sequence '%s'", yytext); }
502 <tkstr>\\[0-9]+ parser_error("Bad escape sequence");
503 <tkstr>\\\n{ws}* line_number++; char_number = 1; /* backslash at EOL continues string after leading whitespace on next line */
504 <tkstr>\\a addcchar('\a');
505 <tkstr>\\b addcchar('\b');
506 <tkstr>\\f addcchar('\f');
507 <tkstr>\\n addcchar('\n');
508 <tkstr>\\r addcchar('\r');
509 <tkstr>\\t addcchar('\t');
510 <tkstr>\\v addcchar('\v');
511 <tkstr>\\. addcchar(yytext[1]);
512 <tkstr>\\\r\n addcchar(yytext[2]); line_number++; char_number = 1;
513 <tkstr>[^\\\n\"]+ {
514 char *yptr = yytext;
515 while(*yptr)
516 addcchar(*yptr++);
517 }
518 <tkstr>\"\" addcchar('\"'); /* "bla""bla" -> "bla\"bla" */
519 <tkstr>\\\"\" addcchar('\"'); /* "bla\""bla" -> "bla\"bla" */
520 <tkstr>\"{ws}+\" ; /* "bla" "bla" -> "blabla" */
521 <tkstr>\n parser_error("Unterminated string");
523 /*
524 * Raw data scanning
525 */
526 \' yy_push_state(tkrcd); cbufidx = 0;
527 <tkrcd>\' {
528 yy_pop_state();
529 parser_lval.raw = new_raw_data();
530 parser_lval.raw->size = cbufidx;
531 parser_lval.raw->data = xmalloc(parser_lval.raw->size);
532 memcpy(parser_lval.raw->data, cbuffer, parser_lval.raw->size);
533 return tRAWDATA;
534 }
535 <tkrcd>[0-9a-fA-F]{2} {
536 int result;
537 result = strtol(yytext, 0, 16);
538 addcchar((char)result);
539 }
540 <tkrcd>{ws}+ ; /* Ignore space */
541 <tkrcd>\n line_number++; char_number = 1;
542 <tkrcd>. parser_error("Malformed data-line");
544 /*
545 * Comment stripping
546 * Should never occur after preprocessing
547 */
548 <INITIAL,pp_cstrip>"/*" {
549 yy_push_state(comment);
550 save_wanted_id = wanted_id;
551 if(!no_preprocess)
552 parser_warning("Found comments after preprocessing, please report\n");
553 }
554 <comment>[^*\n]* ;
555 <comment>"*"+[^*/\n]* ;
556 <comment>\n line_number++; char_number = 1;
557 <comment>"*"+"/" yy_pop_state(); want_id = save_wanted_id;
559 ;[^\n]* want_id = wanted_id; /* not really comment, but left-over c-junk */
560 "//"[^\n]* want_id = wanted_id; if(!no_preprocess) parser_warning("Found comments after preprocessing, please report\n");
562 \n {
563 want_id = wanted_id;
564 line_number++;
565 char_number = 1;
566 if(want_nl)
567 {
568 want_nl = 0;
569 return tNL;
570 }
571 }
572 {ws}+ want_id = wanted_id; /* Eat whitespace */
574 <INITIAL>. return yytext[0];
576 <*>.|\n {
577 /* Catch all rule to find any unmatched text */
578 if(*yytext == '\n')
579 {
580 line_number++;
581 char_number = 1;
582 }
583 parser_warning("Unmatched text '%c' (0x%02x) YY_START=%d\n",
584 isprint(*yytext & 0xff) ? *yytext : '.', *yytext, YY_START);
585 }
587 %%
589 /* These dup functions copy the enclosed '\0' from
590 * the resource string.
591 */
592 static void addcchar(char c)
593 {
594 if(cbufidx >= cbufalloc)
595 {
596 cbufalloc += 1024;
597 cbuffer = xrealloc(cbuffer, cbufalloc * sizeof(cbuffer[0]));
598 if(cbufalloc > 65536)
599 parser_warning("Reallocating string buffer larger than 64kB\n");
600 }
601 cbuffer[cbufidx++] = c;
602 }
604 static void addwchar(WCHAR s)
605 {
606 if(wbufidx >= wbufalloc)
607 {
608 wbufalloc += 1024;
609 wbuffer = xrealloc(wbuffer, wbufalloc * sizeof(wbuffer[0]));
610 if(wbufalloc > 65536)
611 parser_warning("Reallocating wide string buffer larger than 64kB\n");
612 }
613 wbuffer[wbufidx++] = s;
614 }
616 static string_t *get_buffered_cstring(void)
617 {
618 string_t *str = new_string();
620 str->size = cbufidx;
621 str->type = str_char;
622 str->str.cstr = xmalloc(cbufidx+1);
623 memcpy(str->str.cstr, cbuffer, cbufidx);
624 str->str.cstr[cbufidx] = '\0';
626 if (!current_codepage || current_codepage == -1 || !win32) /* store as ANSI string */
627 {
628 if (!current_codepage) parser_error("Codepage set to Unicode only, cannot use ASCII string here");
629 return str;
630 }
631 else /* convert to Unicode before storing */
632 {
633 string_t *str_w = convert_string( str, str_unicode, current_codepage );
634 if (!check_unicode_conversion( str, str_w, current_codepage ))
635 parser_error("String %s does not convert identically to Unicode and back in codepage %d. "
636 "Try using a Unicode string instead", str->str.cstr, current_codepage );
637 free_string( str );
638 return str_w;
639 }
640 }
642 static string_t *get_buffered_wstring(void)
643 {
644 string_t *str = new_string();
645 str->size = wbufidx;
646 str->type = str_unicode;
647 str->str.wstr = xmalloc((wbufidx+1)*sizeof(WCHAR));
648 memcpy(str->str.wstr, wbuffer, wbufidx*sizeof(WCHAR));
649 str->str.wstr[wbufidx] = 0;
650 return str;
651 }
653 static string_t *make_string(char *s)
654 {
655 string_t *str = new_string();
656 str->size = strlen(s);
657 str->type = str_char;
658 str->str.cstr = xmalloc(str->size+1);
659 memcpy(str->str.cstr, s, str->size+1);
660 return str;
661 }