tools/wrc/parser.l

   1 /* -*-C-*-
   2  *
   3  * Copyright 1998-2000  Bertho A. Stultiens (BS)
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9  *
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18  *
  19  * History:
  20  * 21-May-2000 BS       - Fixed the ident requirement of resource names
  21  *                        which can be keywords.
  22  * 30-Apr-2000 BS       - Reintegration into the wine-tree
  23  * 11-Jan-2000 BS       - Very drastic cleanup because we don't have a
  24  *                        preprocessor in here anymore.
  25  * 02-Jan-2000 BS       - Removed the preprocessor code
  26  * 23-Dec-1999 BS       - Removed the copyright for Martin von Loewis.
  27  *                        There is really nothing left of his code in
  28  *                        this parser.
  29  * 20-Jun-1998 BS       - Changed the filename conversion. Filenames are
  30  *                        case-sensitive inder *nix, but not under dos.
  31  *                        default behaviour is to convert to lower case.
  32  *                      - All backslashes are converted to forward and
  33  *                        both single and double slash is recognized as
  34  *                        MS/Borland does.
  35  *                      - Fixed a bug in 'yywf' case that prevented
  36  *                        double quoted names to be scanned propperly.
  37  *
  38  * 19-May-1998 BS       - Started to build a preprocessor.
  39  *                      - Changed keyword processing completely to
  40  *                        table-lookups.
  41  *
  42  * 20-Apr-1998 BS       - Added ';' comment stripping
  43  *
  44  * 17-Apr-1998 BS       - Made the win32 keywords optional when compiling in
  45  *                        16bit mode
  46  *
  47  * 15-Apr-1998 BS       - Changed string handling to include escapes
  48  *                      - Added unicode string handling (no codepage
  49  *                        translation though).
  50  *                      - 'Borrowed' the main idea of string scanning from
  51  *                        the flex manual pages.
  52  *                      - Added conditional handling of scanning depending
  53  *                        on the state of the parser. This was mainly required
  54  *                        to distinguish a file to load or raw data that
  55  *                        follows. MS's definition of filenames is rather
  56  *                        complex... It can be unquoted or double quoted. If
  57  *                        double quoted, then the '\\' char is not automatically
  58  *                        escaped according to Borland's rc compiler, but it
  59  *                        accepts both "\\path\\file.rc" and "\path\file.rc".
  60  *                        This makes life very hard! I go for the escaped
  61  *                        version, as this seems to be the documented way...
  62  *                      - Single quoted strings are now parsed and converted
  63  *                        here.
  64  *                      - Added comment stripping. The implementation is
  65  *                        'borrowed' from the flex manpages.
  66  *                      - Rebuild string processing so that it may contain
  67  *                        escaped '\0'.
  68  */
  69
  70 /* Exclusive string handling */
  71 %x tkstr
  72 /* Exclusive unicode string handling */
  73 %x tklstr
  74 /* Exclusive rcdata single quoted data handling */
  75 %x tkrcd
  76 /* Exclusive comment eating... */
  77 %x comment
  78 /* Set when stripping c-junk */
  79 %x pp_cstrip
  80 /* Set when scanning #line style directives */
  81 %x pp_line
  82 /* Set when scanning #pragma */
  83 %x pp_pragma
  84 %x pp_code_page
  85
  86 %option stack
  87 %option noinput nounput noyy_top_state noyywrap
  88 %option 8bit never-interactive
  89 %option prefix="parser_"
  90
  91 /* Some shortcut definitions */
  92 ws      [ \f\t\r]
  93 cident  [a-zA-Z_][0-9a-zA-Z_]*
  94
  95 %{
  96
  97 /*#define LEX_DEBUG*/
  98
  99 #include "config.h"
 100
 101 #include <stdio.h>
 102 #include <stdlib.h>
 103 #include <string.h>
 104 #include <ctype.h>
 105 #include <assert.h>
 106
 107 #ifndef HAVE_UNISTD_H
 108 #define YY_NO_UNISTD_H
 109 #endif
 110
 111 #include "wine/unicode.h"
 112 #include "wrc.h"
 113 #include "utils.h"
 114 #include "parser.h"
 115 #include "newstruc.h"
 116
 117 #include "parser.tab.h"
 118
 119 /* Always update the current character position within a line */
 120 #define YY_USER_ACTION  char_number+=yyleng; wanted_id = want_id; want_id = 0;
 121
 122 static void addcchar(char c);
 123 static void addwchar(WCHAR s);
 124 static string_t *get_buffered_cstring(void);
 125 static string_t *get_buffered_wstring(void);
 126 static string_t *make_string(char *s);
 127
 128 static char *cbuffer;           /* Buffers for string collection */
 129 static int cbufidx;
 130 static int cbufalloc = 0;
 131 static WCHAR *wbuffer;
 132 static int wbufidx;
 133 static int wbufalloc = 0;
 134
 135 static int current_codepage = -1;  /* use language default */
 136
 137 /*
 138  * This one is a bit tricky.
 139  * We set 'want_id' in the parser to get the first
 140  * identifier we get across in the scanner, but we
 141  * also want it to be reset at nearly any token we
 142  * see. Exceptions are:
 143  * - newlines
 144  * - comments
 145  * - whitespace
 146  *
 147  * The scanner will automatically reset 'want_id'
 148  * after *each* scanner reduction and puts is value
 149  * into the var below. In this way we can see the
 150  * state after the YY_RULE_SETUP (i.e. the user action;
 151  * see above) and don't have to worry too much when
 152  * it needs to be reset.
 153  */
 154 static int wanted_id = 0;
 155 static int save_wanted_id;      /* To save across comment reductions */
 156
 157 struct keyword {
 158         const char      *keyword;
 159         int             token;
 160         int             isextension;
 161         int             needcase;
 162         int             alwayskw;
 163 };
 164
 165 static struct keyword keywords[] = {
 166         { "ACCELERATORS",       tACCELERATORS,          0, 0, 0},
 167         { "ALT",                tALT,                   0, 0, 0},
 168         { "ASCII",              tASCII,                 0, 0, 0},
 169         { "AUTO3STATE",         tAUTO3STATE,            1, 0, 0},
 170         { "AUTOCHECKBOX",       tAUTOCHECKBOX,          1, 0, 0},
 171         { "AUTORADIOBUTTON",    tAUTORADIOBUTTON,       1, 0, 0},
 172         { "BEGIN",              tBEGIN,                 0, 0, 0},
 173         { "BITMAP",             tBITMAP,                0, 0, 0},
 174         { "BLOCK",              tBLOCK,                 0, 0, 0},
 175         { "BUTTON",             tBUTTON,                1, 0, 0},
 176         { "CAPTION",            tCAPTION,               0, 0, 0},
 177         { "CHARACTERISTICS",    tCHARACTERISTICS,       1, 0, 0},
 178         { "CHECKBOX",           tCHECKBOX,              0, 0, 0},
 179         { "CHECKED",            tCHECKED,               0, 0, 0},
 180         { "CLASS",              tCLASS,                 0, 0, 0},
 181         { "COMBOBOX",           tCOMBOBOX,              0, 0, 0},
 182         { "CONTROL",            tCONTROL,               0, 0, 0},
 183         { "CTEXT",              tCTEXT,                 0, 0, 0},
 184         { "CURSOR",             tCURSOR,                0, 0, 0},
 185         { "DEFPUSHBUTTON",      tDEFPUSHBUTTON,         0, 0, 0},
 186         { "DIALOG",             tDIALOG,                0, 0, 0},
 187         { "DIALOGEX",           tDIALOGEX,              1, 0, 0},
 188         { "DISCARDABLE",        tDISCARDABLE,           0, 0, 0},
 189         { "DLGINIT",            tDLGINIT,               0, 0, 0},
 190         { "EDITTEXT",           tEDITTEXT,              0, 0, 0},
 191         { "END",                tEND,                   0, 0, 0},
 192         { "EXSTYLE",            tEXSTYLE,               0, 0, 0},
 193         { "FILEFLAGS",          tFILEFLAGS,             0, 0, 0},
 194         { "FILEFLAGSMASK",      tFILEFLAGSMASK,         0, 0, 0},
 195         { "FILEOS",             tFILEOS,                0, 0, 0},
 196         { "FILESUBTYPE",        tFILESUBTYPE,           0, 0, 0},
 197         { "FILETYPE",           tFILETYPE,              0, 0, 0},
 198         { "FILEVERSION",        tFILEVERSION,           0, 0, 0},
 199         { "FIXED",              tFIXED,                 0, 0, 0},
 200         { "FONT",               tFONT,                  0, 0, 0},
 201         { "FONTDIR",            tFONTDIR,               0, 0, 0},       /* This is a Borland BRC extension */
 202         { "GRAYED",             tGRAYED,                0, 0, 0},
 203         { "GROUPBOX",           tGROUPBOX,              0, 0, 0},
 204         { "HELP",               tHELP,                  0, 0, 0},
 205         { "HTML",               tHTML,                  0, 0, 0},
 206         { "ICON",               tICON,                  0, 0, 0},
 207         { "IMPURE",             tIMPURE,                0, 0, 0},
 208         { "INACTIVE",           tINACTIVE,              0, 0, 0},
 209         { "LANGUAGE",           tLANGUAGE,              1, 0, 1},
 210         { "LISTBOX",            tLISTBOX,               0, 0, 0},
 211         { "LOADONCALL",         tLOADONCALL,            0, 0, 0},
 212         { "LTEXT",              tLTEXT,                 0, 0, 0},
 213         { "MENU",               tMENU,                  0, 0, 0},
 214         { "MENUBARBREAK",       tMENUBARBREAK,          0, 0, 0},
 215         { "MENUBREAK",          tMENUBREAK,             0, 0, 0},
 216         { "MENUEX",             tMENUEX,                1, 0, 0},
 217         { "MENUITEM",           tMENUITEM,              0, 0, 0},
 218         { "MESSAGETABLE",       tMESSAGETABLE,          1, 0, 0},
 219         { "MOVEABLE",           tMOVEABLE,              0, 0, 0},
 220         { "NOINVERT",           tNOINVERT,              0, 0, 0},
 221         { "NOT",                tNOT,                   0, 0, 0},
 222         { "POPUP",              tPOPUP,                 0, 0, 0},
 223         { "PRELOAD",            tPRELOAD,               0, 0, 0},
 224         { "PRODUCTVERSION",     tPRODUCTVERSION,        0, 0, 0},
 225         { "PURE",               tPURE,                  0, 0, 0},
 226         { "PUSHBUTTON",         tPUSHBUTTON,            0, 0, 0},
 227         { "RADIOBUTTON",        tRADIOBUTTON,           0, 0, 0},
 228         { "RCDATA",             tRCDATA,                0, 0, 0},
 229         { "RTEXT",              tRTEXT,                 0, 0, 0},
 230         { "SCROLLBAR",          tSCROLLBAR,             0, 0, 0},
 231         { "SEPARATOR",          tSEPARATOR,             0, 0, 0},
 232         { "SHIFT",              tSHIFT,                 0, 0, 0},
 233         { "STATE3",             tSTATE3,                1, 0, 0},
 234         { "STRING",             tSTRING,                0, 0, 0},
 235         { "STRINGTABLE",        tSTRINGTABLE,           0, 0, 1},
 236         { "STYLE",              tSTYLE,                 0, 0, 0},
 237         { "TOOLBAR",            tTOOLBAR,               1, 0, 0},
 238         { "VALUE",              tVALUE,                 0, 0, 0},
 239         { "VERSION",            tVERSION,               1, 0, 0},
 240         { "VERSIONINFO",        tVERSIONINFO,           0, 0, 0},
 241         { "VIRTKEY",            tVIRTKEY,               0, 0, 0}
 242 };
 243
 244 #define NKEYWORDS       (sizeof(keywords)/sizeof(keywords[0]))
 245 #define KWP(p)          ((const struct keyword *)(p))
 246 static int kw_cmp_func(const void *s1, const void *s2)
 247 {
 248         int ret;
 249         ret = strcasecmp(KWP(s1)->keyword, KWP(s2)->keyword);
 250         if(!ret && (KWP(s1)->needcase || KWP(s2)->needcase))
 251                 return strcmp(KWP(s1)->keyword, KWP(s2)->keyword);
 252         else
 253                 return ret;
 254 }
 255
 256 #define KW_BSEARCH
 257 #define DO_SORT
 258 static struct keyword *iskeyword(char *kw)
 259 {
 260         struct keyword *kwp;
 261         struct keyword key;
 262         key.keyword = kw;
 263         key.needcase = 0;
 264 #ifdef DO_SORT
 265         {
 266                 /* Make sure that it is sorted for bsearsh */
 267                 static int sorted = 0;
 268                 if(!sorted)
 269                 {
 270                         qsort(keywords, NKEYWORDS, sizeof(keywords[0]), kw_cmp_func);
 271                         sorted = 1;
 272                 }
 273         }
 274 #endif
 275 #ifdef KW_BSEARCH
 276         kwp = bsearch(&key, keywords, NKEYWORDS, sizeof(keywords[0]), kw_cmp_func);
 277 #else
 278         {
 279                 int i;
 280                 for(i = 0; i < NKEYWORDS; i++)
 281                 {
 282                         if(!kw_cmp_func(&key, &keywords[i]))
 283                                 break;
 284                 }
 285                 if(i < NKEYWORDS)
 286                         kwp = &keywords[i];
 287                 else
 288                         kwp = NULL;
 289         }
 290 #endif
 291
 292         if(kwp == NULL || (kwp->isextension && !extensions))
 293                 return NULL;
 294         else
 295                 return kwp;
 296 }
 297
 298 %}
 299
 300 /*
 301  **************************************************************************
 302  * The flexer starts here
 303  **************************************************************************
 304  */
 305 %%
 306         /*
 307          * Catch the GCC-style line statements here and parse them.
 308          * This has the advantage that you can #include at any
 309          * stage in the resource file.
 310          * The preprocessor generates line directives in the format:
 311          * # <linenum> "filename" <codes>
 312          *
 313          * Codes can be a sequence of:
 314          * - 1 start of new file
 315          * - 2 returning to previous
 316          * - 3 system header
 317          * - 4 interpret as C-code
 318          *
 319          * 4 is not used and 1 mutually excludes 2
 320          * Anyhow, we are not really interested in these at all
 321          * because we only want to know the linenumber and
 322          * filename.
 323          */
 324 <INITIAL,pp_cstrip>^{ws}*\#{ws}*pragma{ws}+     yy_push_state(pp_pragma);
 325 <INITIAL,pp_cstrip>^{ws}*\#{ws}*        yy_push_state(pp_line);
 326 <pp_line>[^\n]* {
 327                 int lineno, len;
 328                 char *cptr;
 329                 char *fname;
 330                 yy_pop_state();
 331                 lineno = (int)strtol(yytext, &cptr, 10);
 332                 if(!lineno)
 333                         parser_error("Malformed '#...' line-directive; invalid linenumber");
 334                 fname = strchr(cptr, '"');
 335                 if(!fname)
 336                         parser_error("Malformed '#...' line-directive; missing filename");
 337                 fname++;
 338                 cptr = strchr(fname, '"');
 339                 if(!cptr)
 340                         parser_error("Malformed '#...' line-directive; missing terminating \"");
 341                 *cptr = '\0';
 342                 line_number = lineno - 1;       /* We didn't read the newline */
 343                 input_name = xstrdup(fname);
 344                 /* ignore contents of C include files */
 345                 len = strlen(input_name);
 346                 if (len > 1 && !strcasecmp( input_name + len - 2, ".h" ))
 347                     BEGIN(pp_cstrip);
 348                 else
 349                     BEGIN(INITIAL);
 350         }
 351
 352 <pp_pragma>code_page[^\n]*      yyless(9); yy_pop_state(); yy_push_state(pp_code_page);
 353 <pp_pragma>[^\n]*               yy_pop_state(); if (pedantic) parser_warning("Unrecognized #pragma directive '%s'\n",yytext);
 354
 355 <pp_code_page>\({ws}*default{ws}*\)[^\n]*       current_codepage = -1; yy_pop_state();
 356 <pp_code_page>\({ws}*utf8{ws}*\)[^\n]*          current_codepage = CP_UTF8; yy_pop_state();
 357 <pp_code_page>\({ws}*[0-9]+{ws}*\)[^\n]* {
 358         char *p = yytext;
 359         yy_pop_state();
 360         while (*p < '0' || *p > '9') p++;
 361         current_codepage = strtol( p, NULL, 10 );
 362         if (current_codepage && current_codepage != CP_UTF8 && !wine_cp_get_table( current_codepage ))
 363         {
 364             parser_error("Codepage %d not supported", current_codepage);
 365             current_codepage = 0;
 366         }
 367     }
 368 <pp_code_page>[^\n]*    yy_pop_state(); parser_error("Malformed #pragma code_page directive");
 369
 370         /*
 371          * Strip everything until a ';' taking
 372          * into account braces {} for structures,
 373          * classes and enums.
 374          */
 375 <pp_cstrip>\n                   line_number++; char_number = 1;
 376 <pp_cstrip>.                    ; /* ignore */
 377
 378 \{                      return tBEGIN;
 379 \}                      return tEND;
 380
 381 [0-9]+[lL]?             { parser_lval.num = strtoul(yytext,  0, 10); return toupper(yytext[yyleng-1]) == 'L' ? tLNUMBER : tNUMBER; }
 382 0[xX][0-9A-Fa-f]+[lL]?  { parser_lval.num = strtoul(yytext,  0, 16); return toupper(yytext[yyleng-1]) == 'L' ? tLNUMBER : tNUMBER; }
 383 0[oO][0-7]+[lL]?        { parser_lval.num = strtoul(yytext+2, 0, 8); return toupper(yytext[yyleng-1]) == 'L' ? tLNUMBER : tNUMBER; }
 384
 385         /*
 386          * The next two rules scan identifiers and filenames.
 387          * This is achieved by using the priority ruling
 388          * of the scanner where a '.' is valid in a filename
 389          * and *only* in a filename. In this case, the second
 390          * rule will be reduced because it is longer.
 391          */
 392 [A-Za-z_0-9.]+          {
 393                                 struct keyword *tok = iskeyword(yytext);
 394
 395                                 if(tok)
 396                                 {
 397                                         if(wanted_id && !tok->alwayskw)
 398                                         {
 399                                                 parser_lval.str = make_string(yytext);
 400                                                 return tIDENT;
 401                                         }
 402                                         else
 403                                                 return tok->token;
 404                                 }
 405                                 else
 406                                 {
 407                                         parser_lval.str = make_string(yytext);
 408                                         return tIDENT;
 409                                 }
 410                         }
 411 [A-Za-z_0-9./\\]+               parser_lval.str = make_string(yytext); return tFILENAME;
 412
 413         /*
 414          * Wide string scanning
 415          */
 416 L\"                     {
 417                                 yy_push_state(tklstr);
 418                                 wbufidx = 0;
 419                                 if(!win32)
 420                                         parser_warning("16bit resource contains unicode strings\n");
 421                         }
 422 <tklstr>\"{ws}+ |
 423 <tklstr>\"              {
 424                                 yy_pop_state();
 425                                 parser_lval.str = get_buffered_wstring();
 426                                 return tSTRING;
 427                         }
 428 <tklstr>\\[0-7]{1,6}    { /* octal escape sequence */
 429                                 unsigned int result;
 430                                 result = strtoul(yytext+1, 0, 8);
 431                                 if ( result > 0xffff )
 432                                         parser_error("Character constant out of range");
 433                                 addwchar((WCHAR)result);
 434                         }
 435 <tklstr>\\x[0-9a-fA-F]{4} {  /* hex escape sequence */
 436                                 unsigned int result;
 437                                 result = strtoul(yytext+2, 0, 16);
 438                                 addwchar((WCHAR)result);
 439                         }
 440 <tklstr>\\x[0-9a-fA-F]{1,3} {  parser_error("Invalid hex escape sequence '%s'", yytext); }
 441
 442 <tklstr>\\[0-9]+        parser_error("Bad escape sequence");
 443 <tklstr>\\\n{ws}*       line_number++; char_number = 1; /* backslash at EOL continues string after leading whitespace on next line */
 444 <tklstr>\\a             addwchar('\a');
 445 <tklstr>\\b             addwchar('\b');
 446 <tklstr>\\f             addwchar('\f');
 447 <tklstr>\\n             addwchar('\n');
 448 <tklstr>\\r             addwchar('\r');
 449 <tklstr>\\t             addwchar('\t');
 450 <tklstr>\\v             addwchar('\v');
 451 <tklstr>\\.             addwchar(yytext[1]);
 452 <tklstr>\\\r\n          addwchar(yytext[2]); line_number++; char_number = 1;
 453 <tklstr>\"\"            addwchar('\"');         /* "bla""bla"  -> "bla\"bla" */
 454 <tklstr>\\\"\"          addwchar('\"');         /* "bla\""bla" -> "bla\"bla" */
 455 <tklstr>\"{ws}+\"       ;                       /* "bla" "bla" -> "blabla" */
 456 <tklstr>[^\\\n\"]+      {
 457                                 char *yptr = yytext;
 458                                 while(*yptr)    /* FIXME: codepage translation */
 459                                         addwchar(*yptr++ & 0xff);
 460                         }
 461 <tklstr>\n              parser_error("Unterminated string");
 462
 463         /*
 464          * Normal string scanning
 465          */
 466 \"                      yy_push_state(tkstr); cbufidx = 0;
 467 <tkstr>\"{ws}+  |
 468 <tkstr>\"               {
 469                                 yy_pop_state();
 470                                 parser_lval.str = get_buffered_cstring();
 471                                 return tSTRING;
 472                         }
 473 <tkstr>\\[0-7]{1,3}     { /* octal escape sequence */
 474                                 int result;
 475                                 result = strtol(yytext+1, 0, 8);
 476                                 if ( result > 0xff )
 477                                         parser_error("Character constant out of range");
 478                                 addcchar((char)result);
 479                         }
 480 <tkstr>\\x[0-9a-fA-F]{2} {  /* hex escape sequence */
 481                                 int result;
 482                                 result = strtol(yytext+2, 0, 16);
 483                                 addcchar((char)result);
 484                         }
 485 <tkstr>\\x[0-9a-fA-F]   {  parser_error("Invalid hex escape sequence '%s'", yytext); }
 486
 487 <tkstr>\\[0-9]+         parser_error("Bad escape sequence");
 488 <tkstr>\\\n{ws}*        line_number++; char_number = 1; /* backslash at EOL continues string after leading whitespace on next line */
 489 <tkstr>\\a              addcchar('\a');
 490 <tkstr>\\b              addcchar('\b');
 491 <tkstr>\\f              addcchar('\f');
 492 <tkstr>\\n              addcchar('\n');
 493 <tkstr>\\r              addcchar('\r');
 494 <tkstr>\\t              addcchar('\t');
 495 <tkstr>\\v              addcchar('\v');
 496 <tkstr>\\.              addcchar(yytext[1]);
 497 <tkstr>\\\r\n           addcchar(yytext[2]); line_number++; char_number = 1;
 498 <tkstr>[^\\\n\"]+       {
 499                                 char *yptr = yytext;
 500                                 while(*yptr)
 501                                         addcchar(*yptr++);
 502                         }
 503 <tkstr>\"\"             addcchar('\"');         /* "bla""bla"   -> "bla\"bla" */
 504 <tkstr>\\\"\"           addcchar('\"');         /* "bla\""bla"  -> "bla\"bla" */
 505 <tkstr>\"{ws}+\"        ;                       /* "bla" "bla"  -> "blabla" */
 506 <tkstr>\n               parser_error("Unterminated string");
 507
 508         /*
 509          * Raw data scanning
 510          */
 511 \'                      yy_push_state(tkrcd); cbufidx = 0;
 512 <tkrcd>\'               {
 513                                 yy_pop_state();
 514                                 parser_lval.raw = new_raw_data();
 515                                 parser_lval.raw->size = cbufidx;
 516                                 parser_lval.raw->data = xmalloc(parser_lval.raw->size);
 517                                 memcpy(parser_lval.raw->data, cbuffer, parser_lval.raw->size);
 518                                 return tRAWDATA;
 519                         }
 520 <tkrcd>[0-9a-fA-F]{2}   {
 521                                 int result;
 522                                 result = strtol(yytext, 0, 16);
 523                                 addcchar((char)result);
 524                         }
 525 <tkrcd>{ws}+            ;       /* Ignore space */
 526 <tkrcd>\n               line_number++; char_number = 1;
 527 <tkrcd>.                parser_error("Malformed data-line");
 528
 529         /*
 530          * Comment stripping
 531          * Should never occur after preprocessing
 532          */
 533 <INITIAL,pp_cstrip>"/*" {
 534                                 yy_push_state(comment);
 535                                 save_wanted_id = wanted_id;
 536                                 if(!no_preprocess)
 537                                         parser_warning("Found comments after preprocessing, please report\n");
 538                         }
 539 <comment>[^*\n]*        ;
 540 <comment>"*"+[^*/\n]*   ;
 541 <comment>\n             line_number++; char_number = 1;
 542 <comment>"*"+"/"        yy_pop_state(); want_id = save_wanted_id;
 543
 544 ;[^\n]*                 want_id = wanted_id; /* not really comment, but left-over c-junk */
 545 "//"[^\n]*              want_id = wanted_id; if(!no_preprocess) parser_warning("Found comments after preprocessing, please report\n");
 546
 547 \n                      {
 548                                 want_id = wanted_id;
 549                                 line_number++;
 550                                 char_number = 1;
 551                                 if(want_nl)
 552                                 {
 553                                         want_nl = 0;
 554                                         return tNL;
 555                                 }
 556                         }
 557 {ws}+                   want_id = wanted_id;    /* Eat whitespace */
 558
 559 <INITIAL>.              return yytext[0];
 560
 561 <*>.|\n                 {
 562                                 /* Catch all rule to find any unmatched text */
 563                                 if(*yytext == '\n')
 564                                 {
 565                                         line_number++;
 566                                         char_number = 1;
 567                                 }
 568                                 parser_warning("Unmatched text '%c' (0x%02x) YY_START=%d\n",
 569                                         isprint(*yytext & 0xff) ? *yytext : '.', *yytext, YY_START);
 570                         }
 571
 572 %%
 573
 574 /* These dup functions copy the enclosed '\0' from
 575  * the resource string.
 576  */
 577 static void addcchar(char c)
 578 {
 579         if(cbufidx >= cbufalloc)
 580         {
 581                 cbufalloc += 1024;
 582                 cbuffer = xrealloc(cbuffer, cbufalloc * sizeof(cbuffer[0]));
 583                 if(cbufalloc > 65536)
 584                         parser_warning("Reallocating string buffer larger than 64kB\n");
 585         }
 586         cbuffer[cbufidx++] = c;
 587 }
 588
 589 static void addwchar(WCHAR s)
 590 {
 591         if(wbufidx >= wbufalloc)
 592         {
 593                 wbufalloc += 1024;
 594                 wbuffer = xrealloc(wbuffer, wbufalloc * sizeof(wbuffer[0]));
 595                 if(wbufalloc > 65536)
 596                         parser_warning("Reallocating wide string buffer larger than 64kB\n");
 597         }
 598         wbuffer[wbufidx++] = s;
 599 }
 600
 601 static string_t *get_buffered_cstring(void)
 602 {
 603     string_t *str = new_string();
 604
 605     str->size = cbufidx;
 606     str->type = str_char;
 607     str->str.cstr = xmalloc(cbufidx+1);
 608     memcpy(str->str.cstr, cbuffer, cbufidx);
 609     str->str.cstr[cbufidx] = '\0';
 610
 611     if (!current_codepage || current_codepage == -1 || !win32)  /* store as ANSI string */
 612     {
 613         if (!current_codepage) parser_error("Codepage set to Unicode only, cannot use ASCII string here");
 614         return str;
 615     }
 616     else  /* convert to Unicode before storing */
 617     {
 618         string_t *str_w = convert_string( str, str_unicode, current_codepage );
 619         if (!check_unicode_conversion( str, str_w, current_codepage ))
 620             parser_error("String %s does not convert identically to Unicode and back in codepage %d. "
 621                     "Try using a Unicode string instead", str->str.cstr, current_codepage );
 622         free_string( str );
 623         return str_w;
 624     }
 625 }
 626
 627 static string_t *get_buffered_wstring(void)
 628 {
 629         string_t *str = new_string();
 630         str->size = wbufidx;
 631         str->type = str_unicode;
 632         str->str.wstr = xmalloc((wbufidx+1)*sizeof(WCHAR));
 633         memcpy(str->str.wstr, wbuffer, wbufidx*sizeof(WCHAR));
 634         str->str.wstr[wbufidx] = 0;
 635         return str;
 636 }
 637
 638 static string_t *make_string(char *s)
 639 {
 640         string_t *str = new_string();
 641         str->size = strlen(s);
 642         str->type = str_char;
 643         str->str.cstr = xmalloc(str->size+1);
 644         memcpy(str->str.cstr, s, str->size+1);
 645         return str;
 646 }