tools/make_requests

   1 #! /usr/bin/perl -w
   2 #
   3 # Build the server/trace.c and server/request.h files
   4 # from the contents of include/wine/server.h.
   5 #
   6 # Copyright (C) 1998 Alexandre Julliard
   7 #
   8 # This library is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU Lesser General Public
  10 # License as published by the Free Software Foundation; either
  11 # version 2.1 of the License, or (at your option) any later version.
  12 #
  13 # This library is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # Lesser General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with this library; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  21 #
  22 use strict;
  23
  24 my %formats =
  25 (
  26     "int"           => "%d",
  27     "short int"     => "%d",
  28     "char"          => "%c",
  29     "unsigned char" => "%02x",
  30     "unsigned short"=> "%04x",
  31     "unsigned int"  => "%08x",
  32     "unsigned long" => "%lx",
  33     "void*"         => "%p",
  34     "time_t"        => "%ld (long)",
  35     "size_t"        => "%lu (unsigned long)",
  36     "data_size_t"   => "%u",
  37     "obj_handle_t"  => "%p",
  38     "atom_t"        => "%04x",
  39     "user_handle_t" => "%p",
  40     "process_id_t"  => "%04x",
  41     "thread_id_t"   => "%04x",
  42     "abs_time_t"    => "&dump_abs_time",
  43     "rectangle_t"   => "&dump_rectangle",
  44     "char_info_t"   => "&dump_char_info",
  45     "apc_call_t"    => "&dump_apc_call",
  46     "apc_result_t"  => "&dump_apc_result",
  47     "async_data_t"  => "&dump_async_data",
  48     "luid_t"        => "&dump_luid",
  49 );
  50
  51 my @requests = ();
  52 my %replies = ();
  53
  54 my @trace_lines = ();
  55
  56
  57
  58 ### Generate a dumping function
  59
  60 sub DO_DUMP_FUNC($$@)
  61 {
  62     my $name = shift;
  63     my $req = shift;
  64     push @trace_lines, "static void dump_${name}_$req( const struct ${name}_$req *req )\n{\n";
  65     while ($#_ >= 0)
  66     {
  67         my $type = shift;
  68         my $var = shift;
  69         if (defined($formats{$type}))
  70         {
  71             if ($formats{$type} =~ /^&(.*)/)
  72             {
  73                 my $func = $1;
  74                 push @trace_lines, "    fprintf( stderr, \" $var=\" );\n";
  75                 push @trace_lines, "    $func( &req->$var );\n";
  76                 push @trace_lines, "    fprintf( stderr, \",\" );\n" if ($#_ > 0);
  77             }
  78             elsif ($formats{$type} =~ /^(%.*)\s+\((.*)\)/)
  79             {
  80                 my ($format, $cast) = ($1, $2);
  81                 push @trace_lines, "    fprintf( stderr, \" $var=$format";
  82                 push @trace_lines, "," if ($#_ > 0);
  83                 push @trace_lines, "\", ($cast)req->$var );\n";
  84             }
  85             else
  86             {
  87                 push @trace_lines, "    fprintf( stderr, \" $var=$formats{$type}";
  88                 push @trace_lines, "," if ($#_ > 0);
  89                 push @trace_lines, "\", req->$var );\n";
  90             }
  91         }
  92         else  # must be some varargs format
  93         {
  94             my $func = $type;
  95             push @trace_lines, "    fprintf( stderr, \" $var=\" );\n";
  96             push @trace_lines, "    $func;\n";
  97             push @trace_lines, "    fputc( ',', stderr );\n" if ($#_ > 0);
  98         }
  99     }
 100     push @trace_lines, "}\n\n";
 101 }
 102
 103 ### Parse the request definitions
 104
 105 sub PARSE_REQUESTS()
 106 {
 107     # states: 0 = header 1 = declarations 2 = inside @REQ 3 = inside @REPLY
 108     my $state = 0;
 109     my $name = "";
 110     my @in_struct = ();
 111     my @out_struct = ();
 112
 113     open(PROTOCOL,"server/protocol.def") or die "Can't open server/protocol.def";
 114
 115     while (<PROTOCOL>)
 116     {
 117         my ($type, $var);
 118         # strip comments
 119         s!/\*.*\*/!!g;
 120         # strip white space at end of line
 121         s/\s+$//;
 122
 123         if (/^\@HEADER/)
 124         {
 125             die "Misplaced \@HEADER" unless $state == 0;
 126             $state++;
 127             next;
 128         }
 129
 130         # ignore everything while in state 0
 131         next if $state == 0;
 132
 133         if (/^\@REQ\(\s*(\w+)\s*\)/)
 134         {
 135             $name = $1;
 136             die "Misplaced \@REQ" unless $state == 1;
 137             # start a new request
 138             @in_struct = ();
 139             @out_struct = ();
 140             print SERVER_PROT "struct ${name}_request\n{\n";
 141             print SERVER_PROT "    struct request_header __header;\n";
 142             $state++;
 143             next;
 144         }
 145
 146         if (/^\@REPLY/)
 147         {
 148             die "Misplaced \@REPLY" unless $state == 2;
 149             print SERVER_PROT "};\n";
 150             print SERVER_PROT "struct ${name}_reply\n{\n";
 151             print SERVER_PROT "    struct reply_header __header;\n";
 152             $state++;
 153             next;
 154         }
 155
 156         if (/^\@END/)
 157         {
 158             die "Misplaced \@END" unless ($state == 2 || $state == 3);
 159             print SERVER_PROT "};\n";
 160
 161             if ($state == 2)  # build dummy reply struct
 162             {
 163                 print SERVER_PROT "struct ${name}_reply\n{\n";
 164                 print SERVER_PROT "    struct reply_header __header;\n";
 165                 print SERVER_PROT "};\n";
 166             }
 167
 168             # got a complete request
 169             push @requests, $name;
 170             DO_DUMP_FUNC( $name, "request", @in_struct);
 171             if ($#out_struct >= 0)
 172             {
 173                 $replies{$name} = 1;
 174                 DO_DUMP_FUNC( $name, "reply", @out_struct);
 175             }
 176             $state = 1;
 177             next;
 178         }
 179
 180         if ($state != 1)
 181         {
 182             # skip empty lines (but keep them in output file)
 183             if (/^$/)
 184             {
 185                 print SERVER_PROT "\n";
 186                 next;
 187             }
 188
 189             if (/^\s*VARARG\((\w+),(\w+),(\w+)\)/)
 190             {
 191                 $var = $1;
 192                 $type = "dump_varargs_" . $2 . "( min(cur_size,req->" . $3 . ") )";
 193                 s!(VARARG\(.*\)\s*;)!/* $1 */!;
 194             }
 195             elsif (/^\s*VARARG\((\w+),(\w+)\)/)
 196             {
 197                 $var = $1;
 198                 $type = "dump_varargs_" . $2 . "( cur_size )";
 199                 s!(VARARG\(.*\)\s*;)!/* $1 */!;
 200             }
 201             elsif (/^\s*(\w+\**(\s+\w+\**)*)\s+(\w+);/)
 202             {
 203                 $type = $1;
 204                 $var = $3;
 205                 die "Unrecognized type $type" unless defined($formats{$type});
 206             }
 207             else
 208             {
 209                 die "Unrecognized syntax $_";
 210             }
 211             if ($state == 2) { push @in_struct, $type, $var; }
 212             if ($state == 3) { push @out_struct, $type, $var; }
 213         }
 214
 215         # Pass it through into the output file
 216         print SERVER_PROT $_ . "\n";
 217     }
 218     close PROTOCOL;
 219 }
 220
 221 ### Retrieve the server protocol version from the existing server_protocol.h file
 222
 223 sub GET_PROTOCOL_VERSION()
 224 {
 225     my $protocol = 0;
 226     open SERVER_PROT, "include/wine/server_protocol.h" or return 0;
 227     while (<SERVER_PROT>)
 228     {
 229         if (/^\#define SERVER_PROTOCOL_VERSION (\d+)/) { $protocol = $1; last; }
 230     }
 231     close SERVER_PROT;
 232     return $protocol;
 233 }
 234
 235 ### Retrieve the list of status and errors used in the server
 236
 237 sub GET_ERROR_NAMES()
 238 {
 239     my %errors = ();
 240     foreach my $f (glob "server/*.c")
 241     {
 242         next if $f eq "server/trace.c";
 243         open FILE, $f or die "Can't open $f";
 244         while (<FILE>)
 245         {
 246             if (/STATUS_(\w+)/)
 247             {
 248                 $errors{$1} = "STATUS_$1" unless $1 eq "SUCCESS";
 249             }
 250             elsif (/set_win32_error\s*\(\s*(\w+)\s*\)/)
 251             {
 252                 $errors{$1} = "0xc0010000 | $1";
 253             }
 254         }
 255         close FILE;
 256     }
 257     return %errors;
 258 }
 259
 260 ### Replace the contents of a file between ### make_requests ### marks
 261
 262 sub REPLACE_IN_FILE($@)
 263 {
 264     my $name = shift;
 265     my @data = @_;
 266     my @lines = ();
 267     open(FILE,$name) or die "Can't open $name";
 268     while (<FILE>)
 269     {
 270         push @lines, $_;
 271         last if /\#\#\# make_requests begin \#\#\#/;
 272     }
 273     push @lines, "\n", @data;
 274     while (<FILE>)
 275     {
 276         if (/\#\#\# make_requests end \#\#\#/) { push @lines, "\n", $_; last; }
 277     }
 278     push @lines, <FILE>;
 279     open(FILE,">$name") or die "Can't modify $name";
 280     print FILE @lines;
 281     close(FILE);
 282 }
 283
 284 ### Main
 285
 286 # Get the server protocol version
 287 my $protocol = GET_PROTOCOL_VERSION();
 288
 289 my %errors = GET_ERROR_NAMES();
 290
 291 ### Create server_protocol.h and print header
 292
 293 open SERVER_PROT, ">include/wine/server_protocol.h" or die "Cannot create include/wine/server_protocol.h";
 294 print SERVER_PROT "/*\n * Wine server protocol definitions\n *\n";
 295 print SERVER_PROT " * This file is automatically generated; DO NO EDIT!\n";
 296 print SERVER_PROT " * Edit server/protocol.def instead and re-run tools/make_requests\n";
 297 print SERVER_PROT " */\n\n";
 298 print SERVER_PROT "#ifndef __WINE_WINE_SERVER_PROTOCOL_H\n";
 299 print SERVER_PROT "#define __WINE_WINE_SERVER_PROTOCOL_H\n";
 300
 301 ### Parse requests to find request/reply structure definitions
 302
 303 PARSE_REQUESTS();
 304
 305 ### Build the request list and structures
 306
 307 print SERVER_PROT "\n\nenum request\n{\n";
 308 foreach my $req (@requests) { print SERVER_PROT "    REQ_$req,\n"; }
 309 print SERVER_PROT "    REQ_NB_REQUESTS\n};\n\n";
 310
 311 print SERVER_PROT "union generic_request\n{\n";
 312 print SERVER_PROT "    struct request_max_size max_size;\n";
 313 print SERVER_PROT "    struct request_header request_header;\n";
 314 foreach my $req (@requests) { print SERVER_PROT "    struct ${req}_request ${req}_request;\n"; }
 315 print SERVER_PROT "};\n";
 316
 317 print SERVER_PROT "union generic_reply\n{\n";
 318 print SERVER_PROT "    struct request_max_size max_size;\n";
 319 print SERVER_PROT "    struct reply_header reply_header;\n";
 320 foreach my $req (@requests) { print SERVER_PROT "    struct ${req}_reply ${req}_reply;\n"; }
 321 print SERVER_PROT "};\n\n";
 322
 323 printf SERVER_PROT "#define SERVER_PROTOCOL_VERSION %d\n\n", $protocol + 1;
 324 print SERVER_PROT "#endif /* __WINE_WINE_SERVER_PROTOCOL_H */\n";
 325 close SERVER_PROT;
 326
 327 ### Output the dumping function tables
 328
 329 push @trace_lines, "static const dump_func req_dumpers[REQ_NB_REQUESTS] = {\n";
 330 foreach my $req (@requests)
 331 {
 332     push @trace_lines, "    (dump_func)dump_${req}_request,\n";
 333 }
 334 push @trace_lines, "};\n\n";
 335
 336 push @trace_lines, "static const dump_func reply_dumpers[REQ_NB_REQUESTS] = {\n";
 337 foreach my $req (@requests)
 338 {
 339     push @trace_lines, "    (dump_func)", $replies{$req} ? "dump_${req}_reply,\n" : "0,\n";
 340 }
 341 push @trace_lines, "};\n\n";
 342
 343 push @trace_lines, "static const char * const req_names[REQ_NB_REQUESTS] = {\n";
 344 foreach my $req (@requests)
 345 {
 346     push @trace_lines, "    \"$req\",\n";
 347 }
 348 push @trace_lines, "};\n\n";
 349
 350 push @trace_lines, "static const struct\n{\n";
 351 push @trace_lines, "    const char  *name;\n";
 352 push @trace_lines, "    unsigned int value;\n";
 353 push @trace_lines, "} status_names[] =\n{\n";
 354
 355 foreach my $err (sort keys %errors)
 356 {
 357     push @trace_lines, sprintf("    { %-30s %s },\n", "\"$err\",", $errors{$err});
 358 }
 359 push @trace_lines, "    { NULL, 0 }\n";
 360 push @trace_lines, "};\n";
 361
 362 REPLACE_IN_FILE( "server/trace.c", @trace_lines );
 363
 364 ### Output the request handlers list
 365
 366 my @request_lines = ();
 367
 368 foreach my $req (@requests) { push @request_lines, "DECL_HANDLER($req);\n"; }
 369 push @request_lines, "\n#ifdef WANT_REQUEST_HANDLERS\n\n";
 370 push @request_lines, "typedef void (*req_handler)( const void *req, void *reply );\n";
 371 push @request_lines, "static const req_handler req_handlers[REQ_NB_REQUESTS] =\n{\n";
 372 foreach my $req (@requests)
 373 {
 374     push @request_lines, "    (req_handler)req_$req,\n";
 375 }
 376 push @request_lines, "};\n#endif  /* WANT_REQUEST_HANDLERS */\n";
 377
 378 REPLACE_IN_FILE( "server/request.h", @request_lines );