| blob | f77459aacc185a7117c3c1329910200494aee0ff |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Author: Michael Patra <micky@marie.physik.tu-berlin.de>
3 dnl <patra@itp1.physik.tu-berlin.de>
4 dnl Ported to autoconf 2.5x by bero@redhat.com
5 AC_REVISION([configure.in 1.00])
6 AC_INIT(controls/edit.c)
7 AC_CONFIG_HEADER(include/config.h)
8 AC_CONFIG_AUX_DIR(tools)
10 dnl **** Command-line arguments ****
12 dnl Default values
13 LIBEXT=so # library type .so or .a
14 TRACE_MSGS=yes # the TRACE() macro
15 DEBUG_MSGS=yes # the TRACE(), WARN(), and FIXME() macros.
16 CURSES=yes
17 OPENGL=normal
19 AC_ARG_ENABLE(debug,
20 [ --disable-debug compile out all debugging messages],
21 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
23 AC_ARG_ENABLE(opengl,
24 [ --enable-opengl force usage of OpenGL even if the latter is thread-safe via pthread],
25 [if test "$enableval" = "no"; then OPENGL="no"; elif test "$enableval" = "yes"; then OPENGL="yes"; fi])
27 AC_ARG_ENABLE(trace,
28 [ --disable-trace compile out TRACE messages],
29 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
31 AC_ARG_WITH(curses,
32 [ --without-curses do not use curses],
33 [if test "$withval" = "no"; then CURSES="no"; fi])
35 AC_ARG_WITH(reentrant-x,
36 [ --without-reentrant-x compile for use with non-reentrant X libraries])
38 AC_SUBST(OPTIONS)
40 if test "$DEBUG_MSGS" = "no"
41 then
42 OPTIONS="$OPTIONS -DNO_DEBUG_MSGS"
43 fi
45 if test "$TRACE_MSGS" = "no" -o "$DEBUG_MSGS" = "no"
46 then
47 OPTIONS="$OPTIONS -DNO_TRACE_MSGS"
48 fi
50 dnl **** Check for some programs ****
52 AC_PROG_MAKE_SET
53 AC_PROG_CC
54 AC_PROG_CPP
55 AC_PATH_XTRA
56 AC_PROG_YACC
57 AC_PROG_LEX
58 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
59 if test "$XLEX" = "none"
60 then
61 echo "*** Error: No suitable lex found. ***"
62 echo " Please install the 'flex' package."
63 exit 1
64 fi
65 AC_PROG_RANLIB
66 AC_PROG_INSTALL
67 AC_PROG_LN_S
68 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
69 AC_PATH_PROG(LDCONFIG, ldconfig, true, /sbin:/usr/sbin:$PATH)
70 AC_CYGWIN
71 AC_CHECK_PROG(DLLWRAP,dllwrap,dllwrap,false)
73 dnl Check for lint
74 AC_CHECK_PROGS(LINT, lclint lint)
75 if test "$LINT" = "lint"
76 then
77 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
78 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
79 fi
80 AC_SUBST(LINT)
81 AC_SUBST(LINTFLAGS)
83 if test "$CYGWIN" = "yes"
84 then
85 LDCOMBINE="ld -r --enable-stdcall-fixup"
86 else
87 LDCOMBINE="ld -r"
88 fi
89 AC_SUBST(LDCOMBINE)
91 dnl **** Check for some libraries ****
93 dnl Check for -lm
94 AC_CHECK_LIB(m,sqrt)
95 dnl Check for -li386 for NetBSD and OpenBSD
96 AC_CHECK_LIB(i386,i386_set_ldt)
97 dnl Check for -lossaudio for NetBSD
98 AC_CHECK_LIB(ossaudio,_oss_ioctl)
99 dnl Check for -lw for Solaris
100 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
101 dnl Check for -lnsl for Solaris
102 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
103 dnl Check for -lsocket for Solaris
104 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
105 dnl Check for -lxpg4 for FreeBSD
106 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
107 dnl Check for -lmmap for OS/2
108 AC_CHECK_LIB(mmap,mmap)
109 dnl Check for openpty
110 AC_CHECK_FUNCS(openpty,,
111 [AC_CHECK_LIB(util,openpty,
112 [AC_DEFINE(HAVE_OPENPTY)
113 LIBS="$LIBS -lutil"]
114 )])
116 AC_CHECK_HEADERS(dlfcn.h,
117 [AC_CHECK_FUNCS(dlopen,,
118 [AC_CHECK_LIB(dl,dlopen,
119 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
120 LIBS="$LIBS -ldl"],
121 LIBEXT="a")]
122 )],
123 LIBEXT="a"
124 )
126 JPEGLIB=""
127 AC_SUBST(JPEGLIB)
128 AC_CHECK_HEADERS(jpeglib.h,
129 AC_CHECK_LIB(jpeg,jpeg_start_decompress,
130 AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
131 JPEGLIB="-ljpeg"
132 )
133 )
136 AC_SUBST(XLIB)
137 AC_SUBST(XFILES)
138 XFILES=""
139 AC_SUBST(OPENGLFILES)
140 OPENGLFILES=""
141 AC_SUBST(GLU32FILES)
142 GLU32FILES=""
143 if test "$have_x" = "yes"
144 then
145 XLIB="-lXext -lX11"
146 ac_save_CPPFLAGS="$CPPFLAGS"
147 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
149 dnl *** Check for -lXpm
150 AC_CHECK_HEADERS(X11/xpm.h,
151 [ dnl *** If X11/xpm.h exists...
152 AC_CHECK_LIB(Xpm, XpmCreatePixmapFromData,
153 [ AC_DEFINE(HAVE_LIBXXPM, 1, [Define if you have the Xpm library])
154 X_PRE_LIBS="$X_PRE_LIBS -lXpm"],,
155 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
156 )
157 ],
158 [ dnl *** If X11/xpm.h does not exist...
159 dnl NOTE: autoconf does not allow commas inside the third
160 dnl parameter to AC_CHECK_HEADERS, due to some quoting
161 dnl magic it does.
162 echo "Couldn't find the xpm development header X11/xpm.h"
163 echo "Install the following packages:"
164 echo "Red Hat < 7.1 : xpm xpm-devel"
165 echo "Red Hat >= 7.1 : XFree86-devel"
166 echo "Caldera OpenLinux : xpm xpm-devel xpm-devel-static"
167 echo "SuSE : xpm"
168 echo "Debian/Corel Linux: xpm4g xpm4g-dev"
169 echo "Solaris 8 : SFWxpm"
170 echo
171 echo "Or get the sources from ftp.x.org and all its mirror sites from "
172 echo "the directory /contrib/libraries."
173 echo
174 exit 1
175 ]
176 )
178 dnl *** All of the following tests require X11/Xlib.h
179 AC_CHECK_HEADERS(X11/Xlib.h,
180 [
181 dnl *** Check for X keyboard extension
182 AC_CHECK_HEADERS(X11/XKBlib.h,
183 [ dnl *** If X11/XKBlib.h exists...
184 AC_CHECK_LIB(X11, XkbQueryExtension,
185 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
186 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
187 ],
188 AC_MSG_WARN([XKB extension not found!!])
189 )
191 dnl *** Check for X Shm extension
192 AC_CHECK_HEADERS(X11/extensions/XShm.h,
193 [ dnl *** If X11/extensions/XShm.h exists...
194 AC_CHECK_LIB(Xext, XShmQueryExtension,
195 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
196 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
197 ],
198 AC_MSG_WARN([Xshm extension not found!!])
199 )
201 dnl *** Check for X shape extension
202 AC_CHECK_HEADERS(X11/extensions/shape.h,
203 [ dnl *** If X11/extensions/shape.h exists...
204 AC_CHECK_LIB(Xext,XShapeQueryExtension,
205 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
206 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
207 ],
208 AC_MSG_WARN([XShape extension not found!!])
209 )
211 dnl *** Check for XFree86 DGA / DGA 2.0 extension
212 AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
213 [ dnl *** If X11/extensions/xf86dga.h exists, check
214 dnl *** for XDGAQueryExtension()...
215 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
216 [ dnl *** If found...
217 AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
218 [Define if you have the Xxf86dga library version 2])
219 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
220 ],
221 [ dnl *** If not found, look for XF86DGAQueryExtension()
222 dnl *** instead (DGA 2.0 not found)...
223 AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
224 [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
225 [Define if you have the Xxf86dga library version 1])
226 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
227 ],,
228 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
229 )
230 ],
231 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
232 )
233 ],
234 AC_MSG_WARN([DGA extension not found!!])
235 )
237 dnl *** Check for XFree86 VMODE extension
238 AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
239 [ dnl *** If X11/extensions/xf86vmode.h exists...
240 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
241 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
242 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
243 ],,
244 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
245 )
246 ],
247 AC_MSG_WARN([XFree86 VMODE extension not found!!])
248 )
250 dnl *** Check for XVideo extension supporting XvImages
251 AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
252 [ dnl *** If X11/extensions/Xvlib.h exists...
253 AC_CHECK_LIB(Xv, XvShmCreateImage,
254 [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
255 X_PRE_LIBS="$X_PRE_LIBS -lXv"
256 ],,
257 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
258 )
259 ],
260 AC_MSG_WARN([XVideo extension not found !!])
261 )
263 dnl *** Check for XRender extension
264 AC_CHECK_HEADERS(X11/extensions/Xrender.h,
265 [ dnl *** If X11/extensions/Xrender.h exists...
266 AC_CHECK_LIB(Xrender, XRenderQueryExtension,
267 [ AC_DEFINE(HAVE_LIBXRENDER, 1, [Define if you have the XRender extension library])
268 X_PRE_LIBS="$X_PRE_LIBS -lXrender"
269 ],,
270 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
271 )
272 ],
273 AC_MSG_WARN([XRender extension not found !!])
274 )
276 ]
277 ) dnl *** End of X11/Xlib.h check
279 dnl Check for the presence of OpenGL
280 if test $OPENGL = "yes" -o $OPENGL = "normal"
281 then
282 AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h)
283 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
284 then
285 dnl Check for some problems due to old Mesa versions
286 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
287 AC_TRY_COMPILE(
288 [#include <GL/gl.h>],
289 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
290 [wine_cv_opengl_version_OK="yes"],
291 [wine_cv_opengl_version_OK="no"]
292 )
293 )
295 dnl Check for the thread-safety of the OpenGL library
296 AC_CACHE_CHECK([for thread-safe OpenGL version],
297 wine_cv_opengl_version_threadsafe,
298 [saved_libs=$LIBS
299 LIBS="$X_LIBS -lGL"
300 AC_TRY_LINK([],[pthread_getspecific();],
301 [wine_cv_opengl_version_threadsafe="yes"],
302 [wine_cv_opengl_version_threadsafe="no"])
303 LIBS=$saved_libs]
304 )
306 if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o $OPENGL = "yes" \)
307 then
308 dnl Check for the presence of the library
309 AC_CHECK_LIB(GL,glXCreateContext,
310 X_PRE_LIBS="$X_PRE_LIBS -lGL"
311 ,,
312 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
314 if test $ac_cv_lib_GL_glXCreateContext = "yes"
315 then
317 OPENGLFILES='$(OPENGLFILES)'
318 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
320 AC_CHECK_LIB(GL,glXGetProcAddressARB,
321 AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
322 [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
323 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
325 if test $ac_cv_lib_GL_glXGetProcAddressARB = "yes"
326 then
327 AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
328 [AC_TRY_COMPILE([#include <GL/gl.h>
329 #ifdef HAVE_GL_GLEXT_H
330 # include <GL/glext.h>
331 #endif
332 ],
333 [PFNGLCOLORTABLEEXTPROC test_proc;],
334 [wine_cv_extension_prototypes="yes"],
335 [wine_cv_extension_prototypes="no"]
336 )]
337 )
338 if test $wine_cv_extension_prototypes = "yes"
339 then
340 AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
341 [Define if the OpenGL headers define extension typedefs])
342 fi
343 fi
345 fi
346 dnl Check for GLU32 library.
347 AC_CHECK_LIB(GLU,gluLookAt,
348 [X_PRE_LIBS="$X_PRE_LIBS -lGLU"
349 GLU32FILES='$(GLU32FILES)']
350 ,,
351 $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
352 )
353 fi
354 fi
355 fi
357 CPPFLAGS="$ac_save_CPPFLAGS"
358 XFILES='$(XFILES)'
359 else
360 XLIB=""
361 X_CFLAGS=""
362 X_LIBS=""
363 fi
365 dnl **** Check which curses lib to use ***
366 if test "$CURSES" = "yes"
367 then
368 AC_CHECK_HEADERS(ncurses.h,
369 AC_CHECK_LIB(ncurses,waddch),
370 [AC_CHECK_HEADERS(curses.h,[AC_CHECK_LIB(curses,waddch)])])
371 AC_CHECK_FUNCS(getbkgd resizeterm)
372 fi
374 CUPSLIBS=""
375 dnl **** Check for CUPS ****
376 wine_cv_warn_cups_h=no
377 AC_CHECK_LIB(cups,cupsGetPPD,
378 [AC_CHECK_HEADER(cups/cups.h,
379 [AC_DEFINE(HAVE_CUPS, 1, [Define if we have CUPS])
380 CUPSLIBS="-lcups"],
381 wine_cv_warn_cups_h=yes)]
382 )
383 AC_SUBST(CUPSLIBS)
385 dnl **** Check for FreeType 2 ****
386 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
387 if test "$ft_lib" = "no"
388 then
389 FREETYPELIBS=""
390 FREETYPEINCL=""
391 wine_cv_msg_freetype=no
392 else
393 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
394 if test "$ft_devel" = "no"
395 then
396 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
397 if test "$ft_devel2" = "freetype2-config"
398 then
399 ft_devel=$ft_devel2
400 fi
401 fi
402 if test "$ft_devel" = "no"
403 then
404 FREETYPELIBS=""
405 FREETYPEINCL=""
406 wine_cv_msg_freetype=yes
407 else
408 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
409 FREETYPELIBS=`$ft_devel --libs`
410 FREETYPEINCL=`$ft_devel --cflags`
411 ac_save_CPPFLAGS="$CPPFLAGS"
412 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
413 AC_CHECK_HEADERS(freetype/freetype.h \
414 freetype/ftglyph.h \
415 freetype/tttables.h \
416 freetype/ftnames.h \
417 freetype/ftsnames.h \
418 freetype/ttnameid.h \
419 freetype/ftoutln.h \
420 freetype/internal/sfnt.h)
421 CPPFLAGS="$ac_save_CPPFLAGS"
422 wine_cv_msg_freetype=no
423 fi
424 fi
425 AC_SUBST(FREETYPELIBS)
426 AC_SUBST(FREETYPEINCL)
428 dnl **** Check for parport (currently Linux only) ****
429 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
430 AC_TRY_COMPILE(
431 [#include <linux/ppdev.h>],
432 [ioctl (1,PPCLAIM,0)],
433 [ac_cv_c_ppdev="yes"],
434 [ac_cv_c_ppdev="no"])
435 )
436 if test "$ac_cv_c_ppdev" = "yes"
437 then
438 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
439 fi
441 dnl **** Check for IPX (currently Linux only) ****
442 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
443 AC_TRY_COMPILE(
444 [#include <sys/socket.h>
445 #include <netipx/ipx.h>],
446 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
447 [ac_cv_c_ipx_gnu="yes"],
448 [ac_cv_c_ipx_gnu="no"])
449 )
450 if test "$ac_cv_c_ipx_gnu" = "yes"
451 then
452 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
453 fi
455 if test "$ac_cv_c_ipx_gnu" = "no"
456 then
457 AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
458 AC_TRY_COMPILE(
459 [#include <sys/socket.h>
460 #include <asm/types.h>
461 #include <linux/ipx.h>],
462 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
463 [ac_cv_c_ipx_linux="yes"],
464 [ac_cv_c_ipx_linux="no"])
465 )
466 if test "$ac_cv_c_ipx_linux" = "yes"
467 then
468 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
469 fi
470 fi
472 dnl **** Check for Open Sound System ****
473 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
475 AC_CACHE_CHECK([for Open Sound System],
476 ac_cv_c_opensoundsystem,
477 AC_TRY_COMPILE([
478 #if defined(HAVE_SYS_SOUNDCARD_H)
479 #include <sys/soundcard.h>
480 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
481 #include <machine/soundcard.h>
482 #elif defined(HAVE_SOUNDCARD_H)
483 #include <soundcard.h>
484 #endif
485 ],[
487 /* check for one of the Open Sound System specific SNDCTL_ defines */
488 #if !defined(SNDCTL_DSP_STEREO)
489 #error No open sound system
490 #endif
491 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
493 if test "$ac_cv_c_opensoundsystem" = "yes"
494 then
495 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
496 fi
498 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
499 ac_cv_c_opensoundsystem_midi,
500 AC_TRY_COMPILE([
501 #if defined(HAVE_SYS_SOUNDCARD_H)
502 #include <sys/soundcard.h>
503 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
504 #include <machine/soundcard.h>
505 #elif defined(HAVE_SOUNDCARD_H)
506 #include <soundcard.h>
507 #endif
508 ],[
510 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
511 #if !defined(SNDCTL_SEQ_SYNC)
512 #error No open sound system MIDI interface
513 #endif
514 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
516 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
517 then
518 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
519 fi
521 dnl **** If ln -s doesn't work, use cp instead ****
522 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
524 dnl **** Check for broken glibc mmap64 ****
526 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
527 AC_TRY_RUN([
528 #define _FILE_OFFSET_BITS 64
529 #include <stdio.h>
530 #include <unistd.h>
531 #include <fcntl.h>
532 #include <sys/mman.h>
533 #include <errno.h>
535 int main(int argc,char **argv) {
536 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
537 if (fd == -1) exit(1);
539 unlink("conftest.map");
541 write(fd,"test",4);
543 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
544 (errno == EINVAL)
545 ) {
546 exit(1);
547 }
548 close(fd);
549 fprintf(stderr,"success!\n");
550 exit(0);
551 }
553 ],
554 ac_cv_mmap64_works="yes",
555 ac_cv_mmap64_works="no",
556 ac_cv_mmap64_works="no") )
558 if test "$ac_cv_mmap64_works" = "yes"
559 then
560 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
561 fi
563 dnl **** Check for gcc strength-reduce bug ****
565 if test "x${GCC}" = "xyes"
566 then
567 CFLAGS="$CFLAGS -Wall"
568 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
569 AC_TRY_RUN([
570 int L[[4]] = {0,1,2,3};
571 int main(void) {
572 static int Array[[3]];
573 unsigned int B = 3;
574 int i;
575 for(i=0; i<B; i++) Array[[i]] = i - 3;
576 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
577 L[[i]] = 4;
579 exit( Array[[1]] != -2 || L[[2]] != 3);
580 }],
581 ac_cv_c_gcc_strength_bug="no",
582 ac_cv_c_gcc_strength_bug="yes",
583 ac_cv_c_gcc_strength_bug="yes") )
584 if test "$ac_cv_c_gcc_strength_bug" = "yes"
585 then
586 CFLAGS="$CFLAGS -fno-strength-reduce"
587 fi
589 dnl Check for -mpreferred-stack-boundary
590 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support],
591 ac_cv_c_gcc_stack_boundary,
592 [saved_cflags=$CFLAGS
593 CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
594 AC_TRY_COMPILE(,[return 0],ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")
595 CFLAGS=$saved_cflags
596 ])
597 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
598 then
599 CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
600 fi
601 fi
603 dnl **** Check if we need to place .type inside a .def directive ****
605 AC_CACHE_CHECK([whether .type must sit inside a .def directive],
606 ac_cv_c_type_in_def,
607 [saved_libs=$LIBS
608 LIBS="conftest_asm.s $LIBS"
609 cat > conftest_asm.s <<EOF
610 .globl _ac_test
611 .def _ac_test; .scl 2; .type 32; .endef
612 _ac_test:
613 .long 0
614 EOF
615 AC_TRY_LINK(,,ac_cv_c_type_in_def="yes",ac_cv_c_type_in_def="no")
616 LIBS=$saved_libs])
617 if test "$ac_cv_c_type_in_def" = "yes"
618 then
619 AC_DEFINE(NEED_TYPE_IN_DEF, 1, [Define if .type asm directive must be inside a .def directive])
620 fi
622 dnl **** Check for underscore on external symbols ****
624 AC_CACHE_CHECK([whether external symbols need an underscore prefix],
625 ac_cv_c_extern_prefix,
626 [saved_libs=$LIBS
627 LIBS="conftest_asm.s $LIBS"
628 cat > conftest_asm.s <<EOF
629 .globl _ac_test
630 _ac_test:
631 .long 0
632 EOF
633 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
634 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
635 LIBS=$saved_libs])
636 if test "$ac_cv_c_extern_prefix" = "yes"
637 then
638 AC_DEFINE(NEED_UNDERSCORE_PREFIX, 1,
639 [Define if symbols declared in assembly code need an underscore prefix])
640 fi
642 dnl **** Check for .string in assembler ****
644 AC_CACHE_CHECK([whether assembler accepts .string],
645 ac_cv_c_asm_string,
646 [saved_libs=$LIBS
647 LIBS="conftest_asm.s $LIBS"
648 cat > conftest_asm.s <<EOF
649 .string "test"
650 EOF
651 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
652 LIBS=$saved_libs])
653 if test "$ac_cv_c_asm_string" = "yes"
654 then
655 AC_DEFINE(HAVE_ASM_STRING, 1, [Define to use .string instead of .ascii])
656 fi
658 dnl **** Check for working dll ****
660 LDSHARED=""
661 LDDLLFLAGS=""
662 if test "$LIBEXT" = "so"
663 then
664 AC_CACHE_CHECK([whether we can build a GNU style ELF dll],
665 ac_cv_c_dll_gnuelf,
666 [saved_cflags=$CFLAGS
667 CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic"
668 AC_TRY_LINK(,[return 1],ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")
669 CFLAGS=$saved_cflags
670 ])
671 if test "$ac_cv_c_dll_gnuelf" = "yes"
672 then
673 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
674 LDDLLFLAGS="-Wl,-Bsymbolic"
675 else
676 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll,
677 ac_cv_c_dll_unixware,
678 [saved_cflags=$CFLAGS
679 CFLAGS="$CFLAGS -fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic"
680 AC_TRY_LINK(,[return 1],ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")
681 CFLAGS=$saved_cflags
682 ])
683 if test "$ac_cv_c_dll_unixware" = "yes"
684 then
685 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
686 LDDLLFLAGS="-Wl,-B,symbolic"
687 fi
688 fi
689 if test "$ac_cv_c_dll_gnuelf" = "no" -a "$ac_cv_c_dll_unixware" = "no"
690 then
691 LIBEXT="a"
692 if test "$DLLWRAP" = "dllwrap"; then
693 dnl FIXME - check whether dllwrap works correctly...
694 if test "$CYGWIN" = "yes"; then
695 echo "*** use dllwrap for building shared library."
696 LIBEXT="dll"
697 fi
698 fi
699 fi
700 fi
702 if test "$LIBEXT" = "a"; then
703 echo "*** It is currently not possible to build WINE without shared"
704 echo "*** library (.so) support to allow transparent switch between .so"
705 echo "*** and .dll files."
706 echo "*** If you are using Linux, you will need a newer binutils."
707 exit 1
708 fi
710 DLLFLAGS=""
711 LDPATH=""
713 if test "$LIBEXT" = "so"; then
714 DLLFLAGS="-fPIC"
715 LDPATH="LD_LIBRARY_PATH=\"\$(TOPOBJDIR)/unicode:\$\$LD_LIBRARY_PATH\""
716 elif test "$LIBEXT" = "dll"; then
717 #DLLFLAGS="-fPIC" # -fPIC doesn't work(at least in cygwin-b20) - FIXME
718 LDPATH="PATH=\"\$(TOPOBJDIR)/unicode:\$\$PATH\""
719 fi
721 AC_SUBST(DLLFLAGS)
722 AC_SUBST(LDSHARED)
723 AC_SUBST(LDDLLFLAGS)
724 AC_SUBST(LIBEXT)
725 AC_SUBST(LDPATH)
727 dnl **** Check for reentrant libc ****
728 dnl
729 dnl For cross-compiling we blindly assume that libc is reentrant. This is
730 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
732 AC_DEFUN([WINE_CHECK_ERRNO],
733 [
734 AC_CACHE_CHECK(for reentrant libc: $1, wine_cv_libc_r_$1,
735 [AC_TRY_RUN([int myerrno = 0;
736 char buf[256];
737 int *$1(){return &myerrno;}
738 main(){connect(0,buf,255); exit(!myerrno);}],
739 wine_cv_libc_r_$1=yes, wine_cv_libc_r_$1=no,
740 wine_cv_libc_r_$1=yes )
741 ])
742 if test "$wine_cv_libc_r_$1" = "yes"
743 then
744 wine_cv_libc_reentrant=$1
745 fi
746 ])
748 wine_cv_libc_reentrant=no
749 dnl Linux style errno location
750 WINE_CHECK_ERRNO(__errno_location)
751 dnl FreeBSD style errno location
752 WINE_CHECK_ERRNO(__error)
753 dnl Solaris style errno location
754 WINE_CHECK_ERRNO(___errno)
755 dnl UnixWare style errno location
756 WINE_CHECK_ERRNO(__thr_errno)
757 dnl NetBSD style errno location
758 WINE_CHECK_ERRNO(__errno)
760 if test "$wine_cv_libc_reentrant" != "no"
761 then
762 AC_DEFINE_UNQUOTED(ERRNO_LOCATION,$wine_cv_libc_reentrant,
763 [Define to the name of the function returning errno for reentrant libc])
764 fi
766 dnl **** Check for reentrant X libraries ****
767 dnl
768 dnl This may fail to determine whether X libraries are reentrant if
769 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
770 dnl is possible with the --without-reentrant-x option.
772 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
773 then
774 AC_CACHE_CHECK( [for reentrant X libraries], wine_cv_x_reentrant,
775 [ if test "x$with_reentrant_x" = "xno"
776 then
777 wine_cv_x_reentrant=no
778 else
779 libX11_check=none
780 for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
781 if test -r $dir/libX11.so; then
782 libX11_check="-D $dir/libX11.so"
783 break 1
784 fi
785 if test -r $dir/libX11.a; then
786 libX11_check="$dir/libX11.a"
787 break 1
788 fi
789 done
790 if test "$libX11_check" != "none"; then
791 if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
792 then
793 wine_cv_x_reentrant=yes
794 else
795 wine_cv_x_reentrant=no
796 fi
797 else
798 wine_cv_x_reentrant=unknown
799 fi
800 fi ] )
801 else
802 wine_cv_x_reentrant=no
803 fi
804 if test "$wine_cv_x_reentrant" = "no"
805 then
806 AC_DEFINE(NO_REENTRANT_X11, 1,
807 [Define if X libraries are not reentrant (compiled without -D_REENTRANT)])
808 fi
811 dnl **** Check for functions ****
813 AC_FUNC_ALLOCA()
814 AC_CHECK_FUNCS(\
815 __libc_fork \
816 _lwp_create \
817 clone \
818 ecvt \
819 finite \
820 fpclass \
821 ftruncate64 \
822 getnetbyaddr \
823 getnetbyname \
824 getpagesize \
825 getprotobyname \
826 getprotobynumber \
827 getrlimit \
828 getservbyport \
829 getsockopt \
830 inet_network \
831 lseek64 \
832 lstat \
833 memmove \
834 mmap \
835 rfork \
836 select \
837 sendmsg \
838 settimeofday \
839 sigaltstack \
840 statfs \
841 strcasecmp \
842 strerror \
843 strncasecmp \
844 tcgetattr \
845 timegm \
846 usleep \
847 vfscanf \
848 wait4 \
849 waitpid \
850 )
852 dnl **** Check for header files ****
854 AC_CHECK_HEADERS(\
855 arpa/inet.h \
856 arpa/nameser.h \
857 elf.h \
858 float.h \
859 ieeefp.h \
860 libio.h \
861 libutil.h \
862 link.h \
863 linux/cdrom.h \
864 linux/input.h \
865 linux/joystick.h \
866 linux/ucdrom.h \
867 net/if.h \
868 netdb.h \
869 netinet/in.h \
870 netinet/in_systm.h \
871 netinet/ip.h \
872 netinet/tcp.h \
873 pty.h \
874 resolv.h \
875 sched.h \
876 socket.h \
877 stdint.h \
878 strings.h \
879 sys/cdio.h \
880 sys/errno.h \
881 sys/file.h \
882 sys/filio.h \
883 sys/ipc.h \
884 sys/link.h \
885 sys/lwp.h \
886 sys/mman.h \
887 sys/modem.h \
888 sys/mount.h \
889 sys/msg.h \
890 sys/param.h \
891 sys/ptrace.h \
892 sys/reg.h \
893 sys/signal.h \
894 sys/shm.h \
895 sys/socket.h \
896 sys/sockio.h \
897 sys/statfs.h \
898 sys/strtio.h \
899 sys/syscall.h \
900 sys/user.h \
901 sys/wait.h \
902 sys/v86.h \
903 sys/v86intr.h \
904 sys/vfs.h \
905 sys/vm86.h \
906 syscall.h \
907 ucontext.h \
908 )
909 AC_HEADER_STAT()
911 dnl **** Check for types ****
913 AC_C_CONST()
914 AC_C_INLINE()
915 AC_TYPE_SIZE_T()
916 AC_CHECK_SIZEOF(long long,0)
918 AC_CACHE_CHECK([whether linux/input.h is for real],
919 wine_cv_linux_input_h,
920 AC_TRY_COMPILE([
921 #include <linux/input.h>
922 ] , [
923 int foo = EVIOCGBIT(EV_ABS,42);
924 int bar = BTN_PINKIE;
925 int fortytwo = 42;
926 ],
927 wine_cv_linux_input_h=yes,
928 wine_cv_linux_input_h=no,
929 no
930 )
931 )
932 if test "$wine_cv_linux_input_h" = "yes"
933 then
934 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
935 [Define if we have linux/input.h AND it contains the INPUT event API])
936 fi
939 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
940 wine_cv_linux_gethostbyname_r_6,
941 AC_TRY_COMPILE([
942 #include <netdb.h>
943 ], [
944 char *name=NULL;
945 struct hostent he;
946 struct hostent *result;
947 char *buf=NULL;
948 int bufsize=0;
949 int res,errnr;
950 char *addr=NULL;
951 int addrlen=0;
952 int addrtype=0;
953 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
954 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
955 ],
956 wine_cv_linux_gethostbyname_r_6=yes,
957 wine_cv_linux_gethostbyname_r_6=no
958 )
959 )
960 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
961 then
962 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
963 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
964 fi
966 if test "$ac_cv_header_linux_joystick_h" = "yes"
967 then
968 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
969 wine_cv_linux_joystick_22_api,
970 AC_TRY_COMPILE([
971 #include <sys/ioctl.h>
972 #include <linux/joystick.h>
974 struct js_event blub;
975 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
976 #error "no 2.2 header"
977 #endif
978 ],/*empty*/,
979 wine_cv_linux_joystick_22_api=yes,
980 wine_cv_linux_joystick_22_api=no,
981 wine_cv_linux_joystick_22_api=no
982 )
983 )
984 if test "$wine_cv_linux_joystick_22_api" = "yes"
985 then
986 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
987 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
988 fi
989 fi
991 dnl **** statfs checks ****
993 if test "$ac_cv_header_sys_vfs_h" = "yes"
994 then
995 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
996 wine_cv_sys_vfs_has_statfs,
997 AC_TRY_COMPILE([
998 #include <sys/types.h>
999 #ifdef HAVE_SYS_PARAM_H
1000 # include <sys/param.h>
1001 #endif
1002 #include <sys/vfs.h>
1003 ],[
1004 struct statfs stfs;
1006 memset(&stfs,0,sizeof(stfs));
1007 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1008 )
1009 )
1010 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1011 then
1012 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1013 [Define if the struct statfs is defined by <sys/vfs.h>])
1014 fi
1015 fi
1017 if test "$ac_cv_header_sys_statfs_h" = "yes"
1018 then
1019 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1020 wine_cv_sys_statfs_has_statfs,
1021 AC_TRY_COMPILE([
1022 #include <sys/types.h>
1023 #ifdef HAVE_SYS_PARAM_H
1024 # include <sys/param.h>
1025 #endif
1026 #include <sys/statfs.h>
1027 ],[
1028 struct statfs stfs;
1029 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1030 )
1031 )
1032 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1033 then
1034 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1035 [Define if the struct statfs is defined by <sys/statfs.h>])
1036 fi
1037 fi
1039 if test "$ac_cv_header_sys_mount_h" = "yes"
1040 then
1041 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1042 wine_cv_sys_mount_has_statfs,
1043 AC_TRY_COMPILE([
1044 #include <sys/types.h>
1045 #ifdef HAVE_SYS_PARAM_H
1046 # include <sys/param.h>
1047 #endif
1048 #include <sys/mount.h>
1049 ],[
1050 struct statfs stfs;
1051 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1052 )
1053 )
1054 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1055 then
1056 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1057 [Define if the struct statfs is defined by <sys/mount.h>])
1058 fi
1059 fi
1061 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1063 AC_CACHE_CHECK( [for statfs.f_bfree], wine_cv_statfs_bfree,
1064 [ if test "x$statfs_bfree" = "xno"
1065 then
1066 wine_cv_statfs_bfree=no
1067 else
1068 AC_TRY_COMPILE([
1069 #include <sys/types.h>
1070 #ifdef HAVE_SYS_PARAM_H
1071 # include <sys/param.h>
1072 #endif
1073 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1074 # include <sys/mount.h>
1075 #else
1076 # ifdef STATFS_DEFINED_BY_SYS_VFS
1077 # include <sys/vfs.h>
1078 # else
1079 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1080 # include <sys/statfs.h>
1081 # endif
1082 # endif
1083 #endif
1084 ],[
1085 struct statfs stfs;
1087 stfs.f_bfree++;
1088 ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
1089 )
1090 fi ] )
1091 if test "$wine_cv_statfs_bfree" = "yes"
1092 then
1093 AC_DEFINE(STATFS_HAS_BFREE, 1, [Define if the struct statfs has the member bfree])
1094 fi
1096 AC_CACHE_CHECK( [for statfs.f_bavail], wine_cv_statfs_bavail,
1097 [ if test "x$statfs_bavail" = "xno"
1098 then
1099 wine_cv_statfs_bavail=no
1100 else
1101 AC_TRY_COMPILE([
1102 #include <sys/types.h>
1103 #ifdef HAVE_SYS_PARAM_H
1104 # include <sys/param.h>
1105 #endif
1106 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1107 # include <sys/mount.h>
1108 #else
1109 # ifdef STATFS_DEFINED_BY_SYS_VFS
1110 # include <sys/vfs.h>
1111 # else
1112 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1113 # include <sys/statfs.h>
1114 # endif
1115 # endif
1116 #endif
1117 ],[
1118 struct statfs stfs;
1120 stfs.f_bavail++;
1121 ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
1122 )
1123 fi ] )
1124 if test "$wine_cv_statfs_bavail" = "yes"
1125 then
1126 AC_DEFINE(STATFS_HAS_BAVAIL, 1, [Define if the struct statfs has the member bavail])
1127 fi
1129 dnl *** check for file descriptor passing with msg_accrights
1131 AC_CACHE_CHECK([for msg_accrights in struct msghdr], ac_cv_c_msg_accrights,
1132 AC_TRY_COMPILE([#include <sys/types.h>
1133 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
1134 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
1135 if test "$ac_cv_c_msg_accrights" = "yes"
1136 then
1137 AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS, 1, [Define if struct msghdr contains msg_accrights])
1138 fi
1140 dnl *** Check for the sa_len member in struct sockaddr
1142 AC_CACHE_CHECK([for sa_len in struct sockaddr], ac_cv_c_sockaddr_sa_len,
1143 AC_TRY_COMPILE([#include <sys/types.h>
1144 #include <sys/socket.h>
1145 ], [static struct sockaddr addr; addr.sa_len = 1],
1146 ac_cv_c_sockaddr_sa_len="yes", ac_cv_c_sockaddr_sa_len="no"))
1147 if test "$ac_cv_c_sockaddr_sa_len" = "yes"
1148 then
1149 AC_DEFINE(HAVE_SOCKADDR_SA_LEN, 1, [Define if struct sockaddr contains sa_len])
1150 fi
1152 dnl *** Check for the sun_len member in struct sockaddr_un
1154 AC_CACHE_CHECK([for sun_len in struct sockaddr_un], ac_cv_c_sockaddr_sun_len,
1155 AC_TRY_COMPILE([#include <sys/types.h>
1156 #include <sys/socket.h>
1157 #include <sys/un.h>], [static struct sockaddr_un addr; addr.sun_len = 1],
1158 ac_cv_c_sockaddr_sun_len="yes", ac_cv_c_sockaddr_sun_len="no"))
1159 if test "$ac_cv_c_sockaddr_sun_len" = "yes"
1160 then
1161 AC_DEFINE(HAVE_SOCKADDR_SUN_LEN, 1, [Define if struct sockaddr_un contains sun_len])
1162 fi
1164 dnl *** check for the need to define __i386__
1166 AC_CACHE_CHECK([whether we need to define __i386__],ac_cv_cpp_def_i386,
1167 AC_EGREP_CPP(yes,[#if (defined(i386) || defined(__i386)) && !defined(__i386__)
1168 yes
1169 #endif],
1170 ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
1171 if test "$ac_cv_cpp_def_i386" = "yes"
1172 then
1173 CFLAGS="$CFLAGS -D__i386__"
1174 LINTFLAGS="$LINTFLAGS -D__i386__"
1175 fi
1177 dnl $GCC is set by autoconf
1178 GCC_NO_BUILTIN=""
1179 if test "$GCC" = "yes"
1180 then
1181 GCC_NO_BUILTIN="-fno-builtin"
1182 fi
1183 AC_SUBST(GCC_NO_BUILTIN)
1185 dnl **** Generate output files ****
1187 AC_DEFINE(__WINE_CONFIG_H, 1,
1188 [This must always be defined to allow checking for config.h inclusion])
1190 AC_OUTPUT_COMMANDS([
1191 extra_subdirs="\
1192 dlls/ddraw/d3ddevice \
1193 dlls/ddraw/dclipper \
1194 dlls/ddraw/ddraw \
1195 dlls/ddraw/direct3d \
1196 dlls/ddraw/dpalette \
1197 dlls/ddraw/dsurface \
1198 dlls/dinput/joystick \
1199 dlls/dinput/keyboard \
1200 dlls/dinput/mouse \
1201 dlls/kernel/messages \
1202 dlls/user/dde \
1203 dlls/user/resources \
1204 dlls/wineps/data \
1205 "
1206 for i in $extra_subdirs; do [ -d $i ] || (echo "creating $i" && mkdir $i); done ])
1208 MAKE_RULES=Make.rules
1209 AC_SUBST_FILE(MAKE_RULES)
1211 MAKE_DLL_RULES=dlls/Makedll.rules
1212 AC_SUBST_FILE(MAKE_DLL_RULES)
1214 MAKE_PROG_RULES=programs/Makeprog.rules
1215 AC_SUBST_FILE(MAKE_PROG_RULES)
1217 AC_OUTPUT([
1218 Make.rules
1219 dlls/Makedll.rules
1220 programs/Makeprog.rules
1221 Makefile
1222 console/Makefile
1223 controls/Makefile
1224 debugger/Makefile
1225 dlls/Makefile
1226 dlls/advapi32/Makefile
1227 dlls/avicap32/Makefile
1228 dlls/avifil32/Makefile
1229 dlls/comctl32/Makefile
1230 dlls/commdlg/Makefile
1231 dlls/crtdll/Makefile
1232 dlls/dciman32/Makefile
1233 dlls/ddraw/Makefile
1234 dlls/devenum/Makefile
1235 dlls/dinput/Makefile
1236 dlls/dplay/Makefile
1237 dlls/dplayx/Makefile
1238 dlls/dsound/Makefile
1239 dlls/gdi/Makefile
1240 dlls/glu32/Makefile
1241 dlls/icmp/Makefile
1242 dlls/imagehlp/Makefile
1243 dlls/imm32/Makefile
1244 dlls/kernel/Makefile
1245 dlls/lzexpand/Makefile
1246 dlls/mapi32/Makefile
1247 dlls/mpr/Makefile
1248 dlls/msacm/Makefile
1249 dlls/msdmo/Makefile
1250 dlls/msimg32/Makefile
1251 dlls/msnet32/Makefile
1252 dlls/msrle32/Makefile
1253 dlls/msvcrt/Makefile
1254 dlls/msvideo/Makefile
1255 dlls/netapi32/Makefile
1256 dlls/ntdll/Makefile
1257 dlls/odbc32/Makefile
1258 dlls/ole32/Makefile
1259 dlls/oleaut32/Makefile
1260 dlls/olecli/Makefile
1261 dlls/oledlg/Makefile
1262 dlls/olepro32/Makefile
1263 dlls/olesvr/Makefile
1264 dlls/opengl32/Makefile
1265 dlls/psapi/Makefile
1266 dlls/qcap/Makefile
1267 dlls/quartz/Makefile
1268 dlls/rasapi32/Makefile
1269 dlls/richedit/Makefile
1270 dlls/rpcrt4/Makefile
1271 dlls/serialui/Makefile
1272 dlls/setupapi/Makefile
1273 dlls/shdocvw/Makefile
1274 dlls/shell32/Makefile
1275 dlls/shfolder/Makefile
1276 dlls/shlwapi/Makefile
1277 dlls/sti/Makefile
1278 dlls/tapi32/Makefile
1279 dlls/ttydrv/Makefile
1280 dlls/url/Makefile
1281 dlls/urlmon/Makefile
1282 dlls/user/Makefile
1283 dlls/version/Makefile
1284 dlls/win32s/Makefile
1285 dlls/winaspi/Makefile
1286 dlls/winedos/Makefile
1287 dlls/wineps/Makefile
1288 dlls/wininet/Makefile
1289 dlls/winmm/Makefile
1290 dlls/winmm/joystick/Makefile
1291 dlls/winmm/mcianim/Makefile
1292 dlls/winmm/mciavi/Makefile
1293 dlls/winmm/mcicda/Makefile
1294 dlls/winmm/mciseq/Makefile
1295 dlls/winmm/mciwave/Makefile
1296 dlls/winmm/midimap/Makefile
1297 dlls/winmm/wavemap/Makefile
1298 dlls/winmm/wineoss/Makefile
1299 dlls/winnls/Makefile
1300 dlls/winsock/Makefile
1301 dlls/winspool/Makefile
1302 dlls/wintrust/Makefile
1303 dlls/wow32/Makefile
1304 dlls/wsock32/Makefile
1305 dlls/x11drv/Makefile
1306 documentation/Makefile
1307 documentation/wine.conf.man
1308 documentation/wine.man
1309 files/Makefile
1310 graphics/Makefile
1311 graphics/enhmetafiledrv/Makefile
1312 graphics/metafiledrv/Makefile
1313 graphics/win16drv/Makefile
1314 graphics/x11drv/Makefile
1315 if1632/Makefile
1316 include/Makefile
1317 library/Makefile
1318 libtest/Makefile
1319 loader/Makefile
1320 loader/dos/Makefile
1321 loader/ne/Makefile
1322 memory/Makefile
1323 misc/Makefile
1324 miscemu/Makefile
1325 msdos/Makefile
1326 objects/Makefile
1327 ole/Makefile
1328 programs/Makefile
1329 programs/avitools/Makefile
1330 programs/clock/Makefile
1331 programs/cmdlgtst/Makefile
1332 programs/control/Makefile
1333 programs/notepad/Makefile
1334 programs/osversioncheck/Makefile
1335 programs/progman/Makefile
1336 programs/regapi/Makefile
1337 programs/regtest/Makefile
1338 programs/uninstaller/Makefile
1339 programs/view/Makefile
1340 programs/wcmd/Makefile
1341 programs/wineconsole/Makefile
1342 programs/winemine/Makefile
1343 programs/winetest/Makefile
1344 programs/winhelp/Makefile
1345 programs/winver/Makefile
1346 relay32/Makefile
1347 scheduler/Makefile
1348 server/Makefile
1349 tools/Makefile
1350 tools/winapi/Makefile
1351 tools/winebuild/Makefile
1352 tools/winedump/Makefile
1353 tools/winelauncher
1354 tools/wmc/Makefile
1355 tools/wrc/Makefile
1356 tsx11/Makefile
1357 unicode/Makefile
1358 win32/Makefile
1359 windows/Makefile
1360 windows/x11drv/Makefile ])
1362 if test "$have_x" = "no"
1363 then
1364 echo
1365 echo "*** Warning: X development files not found. Wine will be built without"
1366 echo "*** X support, which currently does not work, and would probably not be"
1367 echo "*** what you want anyway. You will need to install devel packages of"
1368 echo "*** Xlib/Xfree86 and Xpm at the very least."
1369 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
1370 then
1371 echo
1372 echo "*** Warning: Xpm development files not found. Wine will be built without"
1373 echo "*** Xpm support, which currently does not work. You will need to install"
1374 echo "*** devel packages of Xpm."
1375 fi
1377 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1378 then
1379 echo
1380 echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1381 echo "*** terminal resize support. Consider upgrading ncurses."
1382 fi
1384 if test "$wine_cv_libc_reentrant" = "no"
1385 then
1386 echo
1387 echo "*** Warning: non-reentrant libc detected. Wine will be build without"
1388 echo "*** thread support. Consider upgrading libc to a more recent"
1389 echo "*** reentrant version of libc."
1390 fi
1392 if test "$wine_cv_opengl_version_OK" = "no"
1393 then
1394 echo
1395 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1396 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1397 fi
1399 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "normal"
1400 then
1401 echo
1402 echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1403 echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1404 echo "*** A fix for glibc 2.1.3 that seems to work is included in this version of Wine,"
1405 echo "*** start configure with '--enable-opengl' to force OpenGL support."
1406 fi
1408 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "yes"
1409 then
1410 echo
1411 echo "*** Warning: you explicitly linked in a thread-safe OpenGL version. If you"
1412 echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1413 echo "*** support before reporting bugs."
1414 fi
1416 if test "$wine_cv_warn_cups_h" = "yes"
1417 then
1418 echo
1419 echo "*** Note: You have cups runtime libraries, but no development"
1420 echo "*** libraries. Install the cups-devel package or whichever package"
1421 echo "*** contains cups.h to enable CUPS support in WINE."
1422 fi
1424 if test "$wine_cv_msg_freetype" = "yes"
1425 then
1426 echo
1427 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1428 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1429 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1430 echo "*** enable Wine to use TrueType fonts."
1431 fi
1433 echo
1434 echo "Configure finished. Do 'make depend && make' to compile Wine."
1435 echo
1437 dnl Local Variables:
1438 dnl comment-start: "dnl "
1439 dnl comment-end: ""
1440 dnl comment-start-skip: "\\bdnl\\b\\s *"
1441 dnl compile-command: "autoconf"
1442 dnl End: