| blob | 77d5025ea72fd0199318b30efc0ff66c5c053db6 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53)
8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
18 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
20 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
21 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
24 AC_SUBST(DLLDEFS,"")
25 if test "x$enable_debug" = "xno"
26 then
27 DLLDEFS="$DLLDEFS -DWINE_NO_DEBUG_MSGS"
28 fi
29 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
30 then
31 DLLDEFS="$DLLDEFS -DWINE_NO_TRACE_MSGS"
32 fi
34 AC_CANONICAL_HOST
35 case $host in
36 x86_64*linux*)
37 if test "x$enable_win64" != "xyes"
38 then
39 test -n "$CC" || CC="gcc -m32"
40 test -n "$LD" || LD="ld -m elf_i386"
41 test -n "$AS" || AS="as --32"
42 host_cpu="i386"
43 fi
44 ;;
45 esac
47 dnl enable_win16 defaults to yes on x86, to no on other CPUs
48 case $host_cpu in
49 *i[[3456789]]86*)
50 if test "x$enable_win16" != "xno"
51 then
52 enable_win16="yes"
53 fi
54 ;;
55 esac
57 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
58 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
59 if test "x$enable_win16" != "xyes"
60 then
61 WIN16_FILES=""
62 WIN16_INSTALL=""
63 fi
65 dnl **** Check for some programs ****
67 AC_PROG_MAKE_SET
68 AC_PROG_CC
69 AC_PROG_CXX
70 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
71 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
73 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
74 [if test -z "$with_wine_tools"; then
75 if test "$cross_compiling" = "yes"; then
76 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
77 else
78 wine_cv_toolsdir="\$(TOPOBJDIR)"
79 fi
80 elif test -d "$with_wine_tools/tools/winebuild"; then
81 case $with_wine_tools in
82 /*) wine_cv_toolsdir="$with_wine_tools" ;;
83 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
84 esac
85 else
86 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
87 fi])
88 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
90 AC_PATH_XTRA
91 AC_PROG_LEX
93 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
94 dnl **** without one present.
95 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
96 if test "$XLEX" = "none"
97 then
98 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
99 fi
101 dnl Check for bison
102 AC_CHECK_PROGS(BISON,bison,none)
103 if test "$BISON" = "none"
104 then
105 AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
106 fi
108 AC_CHECK_TOOLS(AS,[gas as],as)
109 AC_CHECK_TOOL(LD,ld,ld)
110 AC_CHECK_TOOL(AR,ar,ar)
111 AC_PROG_RANLIB
112 AC_CHECK_TOOL(STRIP,strip,strip)
113 AC_CHECK_TOOL(WINDRES,windres,false)
114 AC_PROG_LN_S
115 WINE_PROG_LN
116 AC_PROG_EGREP
117 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
118 AC_PROG_INSTALL
119 dnl Prepend src dir to install path dir if it's a relative path
120 case "$INSTALL" in
121 [[\\/$]]* | ?:[[\\/]]* ) ;;
122 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
123 esac
125 dnl Check for lint
126 AC_CHECK_PROGS(LINT, lclint lint)
127 if test "$LINT" = "lint"
128 then
129 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
130 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
131 fi
132 AC_SUBST(LINT)
133 AC_SUBST(LINTFLAGS)
135 dnl Check for various programs
136 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
138 dnl **** Check for some libraries ****
140 dnl Check for -li386 for NetBSD and OpenBSD
141 AC_CHECK_LIB(i386,i386_set_ldt)
142 dnl Check for -lossaudio for NetBSD
143 AC_CHECK_LIB(ossaudio,_oss_ioctl)
144 dnl Check for -lw for Solaris
145 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
146 dnl Check for -lnsl for Solaris
147 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
148 dnl Check for -lsocket for Solaris
149 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
150 dnl Check for -lresolv for Solaris
151 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
152 dnl Check for -lxpg4 for FreeBSD
153 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
154 dnl Check for -lpoll for Mac OS X/Darwin
155 AC_CHECK_LIB(poll,poll)
156 dnl Check for -lresolv for Mac OS X/Darwin
157 AC_CHECK_LIB(resolv,res_9_init)
158 dnl Check for -lpthread
159 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
161 AC_SUBST(XLIB)
162 AC_SUBST(XFILES)
163 XFILES=""
164 AC_SUBST(OPENGLFILES)
165 OPENGLFILES=""
166 AC_SUBST(GLU32FILES)
167 GLU32FILES=""
168 AC_SUBST(OPENGL_LIBS)
169 OPENGL_LIBS=""
171 dnl **** Check for header files ****
173 AC_CHECK_HEADERS(\
174 IOKit/IOKitLib.h \
175 arpa/inet.h \
176 arpa/nameser.h \
177 asm/types.h \
178 cups/cups.h \
179 direct.h \
180 elf.h \
181 float.h \
182 fontconfig/fontconfig.h \
183 getopt.h \
184 gif_lib.h \
185 ieeefp.h \
186 io.h \
187 jack/jack.h \
188 jpeglib.h \
189 lber.h \
190 lcms/lcms.h \
191 lcms.h \
192 ldap.h \
193 link.h \
194 linux/cdrom.h \
195 linux/compiler.h \
196 linux/hdreg.h \
197 linux/input.h \
198 linux/ioctl.h \
199 linux/joystick.h \
200 linux/major.h \
201 linux/param.h \
202 linux/serial.h \
203 linux/ucdrom.h \
204 mach/machine.h \
205 machine/cpu.h \
206 machine/limits.h \
207 mntent.h \
208 netdb.h \
209 netinet/in.h \
210 netinet/in_systm.h \
211 netinet/tcp.h \
212 netinet/tcp_fsm.h \
213 openssl/ssl.h \
214 poll.h \
215 process.h \
216 pthread.h \
217 pwd.h \
218 regex.h \
219 sched.h \
220 scsi/sg.h \
221 scsi/scsi.h \
222 scsi/scsi_ioctl.h \
223 stdint.h \
224 strings.h \
225 sys/cdio.h \
226 sys/elf32.h \
227 sys/errno.h \
228 sys/epoll.h \
229 sys/exec_elf.h \
230 sys/filio.h \
231 sys/ioctl.h \
232 sys/ipc.h \
233 sys/link.h \
234 sys/lwp.h \
235 sys/mman.h \
236 sys/modem.h \
237 sys/msg.h \
238 sys/param.h \
239 sys/poll.h \
240 sys/ptrace.h \
241 sys/reg.h \
242 sys/scsiio.h \
243 sys/shm.h \
244 sys/signal.h \
245 sys/socket.h \
246 sys/sockio.h \
247 sys/statfs.h \
248 sys/statvfs.h \
249 sys/strtio.h \
250 sys/syscall.h \
251 sys/sysctl.h \
252 sys/time.h \
253 sys/times.h \
254 sys/uio.h \
255 sys/un.h \
256 sys/vfs.h \
257 sys/vm86.h \
258 sys/wait.h \
259 syscall.h \
260 termios.h \
261 unistd.h \
262 utime.h \
263 valgrind/memcheck.h
264 )
265 AC_HEADER_STAT()
267 dnl **** Check for X11 ****
269 if test "$have_x" = "yes"
270 then
271 XLIB="-lXext -lX11"
272 ac_save_CPPFLAGS="$CPPFLAGS"
273 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
275 dnl *** All of the following tests require X11/Xlib.h
276 AC_CHECK_HEADERS(X11/Xlib.h,
277 [
278 AC_CHECK_HEADERS([X11/XKBlib.h \
279 X11/Xutil.h \
280 X11/extensions/shape.h \
281 X11/extensions/XInput.h \
282 X11/extensions/XShm.h \
283 X11/extensions/Xrandr.h \
284 X11/extensions/Xrender.h \
285 X11/extensions/xf86dga.h \
286 X11/extensions/xf86vmode.h],,,
287 [#include <X11/Xlib.h>
288 #ifdef HAVE_X11_XUTIL_H
289 # include <X11/Xutil.h>
290 #endif])
292 dnl *** Check for X keyboard extension
293 if test "$ac_cv_header_X11_XKBlib_h" = "yes"
294 then
295 AC_CHECK_LIB(X11, XkbQueryExtension,
296 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
297 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
298 fi
300 dnl *** Check for X Shm extension
301 if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
302 then
303 AC_CHECK_LIB(Xext, XShmQueryExtension,
304 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
305 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
306 fi
308 dnl *** Check for X shape extension
309 if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
310 then
311 AC_CHECK_LIB(Xext,XShapeQueryExtension,
312 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
313 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
314 fi
316 dnl *** Check for XFree86 DGA / DGA 2.0 extension
317 if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
318 then
319 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
320 [ AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
321 [Define if you have the Xxf86dga library version 2])
322 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
323 ],,
324 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
325 fi
327 dnl *** Check for XFree86 VMODE extension
328 if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
329 then
330 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
331 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
332 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
333 ],,
334 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
335 fi
337 dnl *** Check for X RandR extension
338 if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
339 then
340 AC_TRY_COMPILE([#include <X11/Xlib.h>
341 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
342 [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
343 fi
345 dnl *** Check for Transform functions in Xrender
346 if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
347 then
348 AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
349 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
350 [Define if Xrender has the XRenderSetPictureTransform function])],,
351 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
352 fi
353 ]
354 ) dnl *** End of X11/Xlib.h check
356 dnl Check for the presence of OpenGL
357 if test "x$with_opengl" != "xno"
358 then
359 if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so -a ! -f /usr/X11R6/lib/libGL.dylib
360 then
361 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
362 This prevents linking to OpenGL. Delete the file and restart configure.])
363 fi
365 AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
366 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
367 then
368 AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
369 dnl Check for some problems due to old Mesa versions
370 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
371 AC_TRY_COMPILE(
372 [#include <GL/gl.h>],
373 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
374 [wine_cv_opengl_version_OK="yes"],
375 [wine_cv_opengl_version_OK="no"]
376 )
377 )
379 if test "$wine_cv_opengl_version_OK" = "yes"
380 then
381 dnl Check for the presence of the library
382 AC_CHECK_LIB(GL,glXCreateContext,
383 OPENGL_LIBS="-lGL"
384 ,,
385 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
387 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
388 then
389 OPENGLFILES='$(OPENGLFILES)'
390 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
391 fi
392 dnl Check for GLU32 library.
393 AC_CHECK_LIB(GLU,gluLookAt,
394 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
395 GLU32FILES='$(GLU32FILES)']
396 ,,
397 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
398 )
399 fi
401 dnl Check for glut32 library.
402 AC_CHECK_LIB(glut,glutMainLoop,
403 [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
404 AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
405 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
406 fi
407 fi
409 dnl **** Check for NAS ****
410 AC_SUBST(NASLIBS,"")
411 AC_CHECK_HEADERS(audio/audiolib.h,
412 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
413 AC_CHECK_LIB(audio,AuCreateFlow,
414 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
415 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
416 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
418 CPPFLAGS="$ac_save_CPPFLAGS"
419 XFILES='$(XFILES)'
420 else
421 XLIB=""
422 X_CFLAGS=""
423 X_LIBS=""
424 fi
426 dnl **** Check which curses lib to use ***
427 CURSESLIBS=""
428 if test "x$with_curses" != "xno"
429 then
430 AC_CHECK_HEADERS(ncurses.h,
431 [AC_CHECK_LIB(ncurses,waddch,
432 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
433 CURSESLIBS="-lncurses"],
434 [AC_CHECK_HEADERS(curses.h,
435 [AC_CHECK_LIB(curses,waddch,
436 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
437 CURSESLIBS="-lcurses"])])])])
438 fi
439 AC_SUBST(CURSESLIBS)
441 dnl **** Check for SANE ****
442 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
443 if test "$sane_devel" = "no"
444 then
445 SANELIBS=""
446 SANEINCL=""
447 else
448 SANELIBS="`$sane_devel --libs`"
449 SANEINCL="`$sane_devel --cflags`"
450 ac_save_CPPFLAGS="$CPPFLAGS"
451 ac_save_LIBS="$LIBS"
452 CPPFLAGS="$CPPFLAGS $SANEINCL"
453 LIBS="$LIBS $SANELIBS"
454 AC_CHECK_HEADER(sane/sane.h,
455 [AC_CHECK_LIB(sane,sane_open,
456 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
457 [SANELIBS=""
458 SANEINCL=""])],
459 [SANELIBS=""
460 SANEINCL=""])
461 LIBS="$ac_save_LIBS"
462 CPPFLAGS="$ac_save_CPPFLAGS"
463 fi
464 AC_SUBST(SANELIBS)
465 AC_SUBST(SANEINCL)
467 dnl **** Check for the ICU library ****
468 AC_CHECK_HEADERS(unicode/ubidi.h)
469 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
470 then
471 saved_libs="$LIBS"
472 ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
473 ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
474 ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
475 AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
476 LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
477 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
478 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
479 AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
480 AC_MSG_RESULT(yes)],
481 [AC_MSG_RESULT(no)])
482 LIBS="$saved_libs"
483 fi
485 dnl **** Check for LittleCMS ***
486 AC_SUBST(LCMSLIBS,"")
487 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
488 then
489 AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
490 [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
491 LCMSLIBS="-llcms"])
492 fi
494 dnl **** Check for OpenLDAP ***
495 AC_SUBST(LDAPLIBS,"")
496 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
497 then
498 AC_CHECK_LIB(ldap, ldap_init,
499 [AC_CHECK_LIB(lber, ber_init,
500 [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
501 LDAPLIBS="-lldap -llber"])])
502 fi
504 dnl **** Check for FreeType 2 ****
505 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
506 if test "$ft_lib" = "no"
507 then
508 FREETYPELIBS=""
509 FREETYPEINCL=""
510 wine_cv_msg_freetype=no
511 else
512 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
513 if test "$ft_devel" = "no"
514 then
515 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
516 if test "$ft_devel2" = "freetype2-config"
517 then
518 ft_devel=$ft_devel2
519 fi
520 fi
521 if test "$ft_devel" = "no"
522 then
523 FREETYPELIBS=""
524 FREETYPEINCL=""
525 wine_cv_msg_freetype=yes
526 else
527 FREETYPELIBS=`$ft_devel --libs`
528 FREETYPEINCL=`$ft_devel --cflags`
529 ac_save_CPPFLAGS="$CPPFLAGS"
530 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
531 AC_CHECK_HEADERS(ft2build.h \
532 freetype/freetype.h \
533 freetype/ftglyph.h \
534 freetype/tttables.h \
535 freetype/ftnames.h \
536 freetype/ftsnames.h \
537 freetype/ttnameid.h \
538 freetype/ftoutln.h \
539 freetype/ftwinfnt.h \
540 freetype/internal/sfnt.h,,,
541 [#if HAVE_FT2BUILD_H
542 #include <ft2build.h>
543 #endif])
544 AC_TRY_CPP([#include <ft2build.h>
545 #include <freetype/fttrigon.h>],
546 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
547 [Define if you have the <freetype/fttrigon.h> header file.])
548 wine_cv_fttrigon=yes],
549 wine_cv_fttrigon=no)
550 CPPFLAGS="$ac_save_CPPFLAGS"
551 dnl Check that we have at least freetype/freetype.h
552 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
553 then
554 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
555 wine_cv_msg_freetype=no
556 else
557 FREETYPELIBS=""
558 FREETYPEINCL=""
559 wine_cv_msg_freetype=yes
560 fi
561 fi
562 fi
563 AC_SUBST(FREETYPELIBS)
564 AC_SUBST(FREETYPEINCL)
566 dnl Only build the fonts dir if we have both freetype and fontforge
567 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
568 then
569 AC_SUBST(FONTSSUBDIRS,"fonts")
570 fi
572 dnl **** Check for parport (currently Linux only) ****
573 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
574 AC_TRY_COMPILE(
575 [#include <linux/ppdev.h>],
576 [ioctl (1,PPCLAIM,0)],
577 [ac_cv_c_ppdev="yes"],
578 [ac_cv_c_ppdev="no"])
579 )
580 if test "$ac_cv_c_ppdev" = "yes"
581 then
582 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
583 fi
585 dnl **** Check for va_copy ****
586 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
587 AC_TRY_LINK(
588 [#include <stdarg.h>],
589 [va_list ap1, ap2;
590 va_copy(ap1,ap2);
591 ],
592 [ac_cv_c_va_copy="yes"],
593 [ac_cv_c_va_copy="no"])
594 )
595 if test "$ac_cv_c_va_copy" = "yes"
596 then
597 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
598 fi
599 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
600 AC_TRY_LINK(
601 [#include <stdarg.h>],
602 [va_list ap1, ap2;
603 __va_copy(ap1,ap2);
604 ],
605 [ac_cv_c___va_copy="yes"],
606 [ac_cv_c___va_copy="no"])
607 )
608 if test "$ac_cv_c___va_copy" = "yes"
609 then
610 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
611 fi
613 dnl **** Check for sigsetjmp ****
614 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
615 AC_TRY_LINK(
616 [#include <setjmp.h>],
617 [sigjmp_buf buf;
618 sigsetjmp( buf, 1 );
619 siglongjmp( buf, 1 );],
620 [ac_cv_c_sigsetjmp="yes"],
621 [ac_cv_c_sigsetjmp="no"])
622 )
623 if test "$ac_cv_c_sigsetjmp" = "yes"
624 then
625 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
626 fi
628 dnl **** Check for pthread_rwlock_t ****
629 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
630 #include <pthread.h>])
632 dnl **** Check for pthread functions ****
633 ac_save_LIBS="$LIBS"
634 LIBS="$LIBS $LIBPTHREAD"
635 AC_CHECK_FUNCS(\
636 pthread_getattr_np \
637 pthread_get_stackaddr_np \
638 pthread_get_stacksize_np \
639 )
640 LIBS="$ac_save_LIBS"
642 dnl **** Check for Open Sound System ****
643 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
645 AC_CACHE_CHECK([for Open Sound System],
646 ac_cv_c_opensoundsystem,
647 AC_TRY_COMPILE([
648 #if defined(HAVE_SYS_SOUNDCARD_H)
649 #include <sys/soundcard.h>
650 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
651 #include <machine/soundcard.h>
652 #elif defined(HAVE_SOUNDCARD_H)
653 #include <soundcard.h>
654 #endif
655 ],[
657 /* check for one of the Open Sound System specific SNDCTL_ defines */
658 #if !defined(SNDCTL_DSP_STEREO)
659 #error No open sound system
660 #endif
661 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
663 if test "$ac_cv_c_opensoundsystem" = "yes"
664 then
665 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
666 fi
668 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
669 ac_cv_c_opensoundsystem_midi,
670 AC_TRY_COMPILE([
671 #if defined(HAVE_SYS_SOUNDCARD_H)
672 #include <sys/soundcard.h>
673 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
674 #include <machine/soundcard.h>
675 #elif defined(HAVE_SOUNDCARD_H)
676 #include <soundcard.h>
677 #endif
678 ],[
680 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
681 #if !defined(SNDCTL_SEQ_SYNC)
682 #error No open sound system MIDI interface
683 #endif
684 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
686 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
687 then
688 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
689 fi
691 dnl **** Check for aRts Sound Server ****
692 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
693 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
694 then
695 ARTSC_CFLAGS=""
696 for i in `$ARTSCCONFIG --cflags`
697 do
698 case "$i" in
699 -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
700 esac
701 done
702 ARTSC_LIBS=`$ARTSCCONFIG --libs`
703 save_CFLAGS="$CFLAGS"
704 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
705 AC_CHECK_LIB(artsc,arts_init,
706 [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
707 [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
708 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
709 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],,
710 $ARTSC_LIBS)
711 CFLAGS="$save_CFLAGS"
712 fi
714 dnl **** Check for ALSA 1.x ****
715 AC_SUBST(ALSALIBS,"")
716 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
717 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
718 then
719 AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
720 [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
721 #include <alsa/asoundlib.h>
722 #elif defined(HAVE_SYS_ASOUNDLIB_H)
723 #include <sys/asoundlib.h>
724 #endif],
725 [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
726 [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
727 ALSALIBS="-lasound"])])
728 fi
730 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
732 AC_SUBST(AUDIOIOLIBS,"")
733 AC_CHECK_HEADERS(libaudioio.h,
734 [AC_CHECK_LIB(audioio,AudioIOGetVersion,
735 [AUDIOIOLIBS="-laudioio"
736 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
738 dnl **** Check for capi4linux ****
740 AC_CHECK_HEADERS(capi20.h,[
741 AC_CHECK_HEADERS(linux/capi.h,[
742 AC_CHECK_LIB(capi20,capi20_register,[
743 AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
744 ])
745 ])
746 ])
748 dnl **** Check for broken glibc mmap64 ****
750 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
751 AC_TRY_RUN([
752 #define _FILE_OFFSET_BITS 64
753 #include <stdio.h>
754 #include <unistd.h>
755 #include <fcntl.h>
756 #include <sys/mman.h>
757 #include <errno.h>
759 int main(int argc,char **argv) {
760 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
761 if (fd == -1) exit(1);
763 unlink("conftest.map");
765 write(fd,"test",4);
767 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
768 (errno == EINVAL)
769 ) {
770 exit(1);
771 }
772 close(fd);
773 fprintf(stderr,"success!\n");
774 exit(0);
775 }
777 ],
778 ac_cv_mmap64_works="yes",
779 ac_cv_mmap64_works="no",
780 ac_cv_mmap64_works="no") )
782 if test "$ac_cv_mmap64_works" = "yes"
783 then
784 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
785 fi
787 dnl **** Check for gcc specific options ****
789 AC_SUBST(EXTRACFLAGS,"")
790 if test "x${GCC}" = "xyes"
791 then
792 EXTRACFLAGS="-Wall -pipe"
794 dnl Check for strength-reduce bug
795 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
796 AC_TRY_RUN([
797 int L[[4]] = {0,1,2,3};
798 int main(void) {
799 static int Array[[3]];
800 unsigned int B = 3;
801 int i;
802 for(i=0; i<B; i++) Array[[i]] = i - 3;
803 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
804 L[[i]] = 4;
806 exit( Array[[1]] != -2 || L[[2]] != 3);
807 }],
808 ac_cv_c_gcc_strength_bug="no",
809 ac_cv_c_gcc_strength_bug="yes",
810 ac_cv_c_gcc_strength_bug="yes") )
811 if test "$ac_cv_c_gcc_strength_bug" = "yes"
812 then
813 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
814 fi
816 dnl Check for -fshort-wchar
817 AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
818 [WINE_TRY_CFLAGS([-fshort-wchar],
819 ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
820 if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
821 then
822 AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
823 fi
825 dnl Check for -mpreferred-stack-boundary
826 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
827 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
828 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
829 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
830 then
831 EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
832 fi
834 dnl Check for -fno-strict-aliasing
835 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
836 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
837 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
838 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
839 then
840 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
841 fi
843 dnl Check for -gstabs+ option
844 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
845 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
846 if test "$ac_cv_c_gcc_gstabs" = "yes"
847 then
848 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
849 fi
851 dnl Check for noisy string.h
852 saved_CFLAGS="$CFLAGS"
853 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
854 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
855 AC_TRY_COMPILE([#include <string.h>],[],
856 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
857 CFLAGS="$saved_CFLAGS"
858 if test "$ac_cv_c_string_h_warnings" = "no"
859 then
860 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
861 fi
862 fi
864 dnl **** Check how to define a function in assembly code ****
866 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
867 WINE_TRY_ASM_LINK(
868 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
869 ac_cv_asm_func_def=".def",
870 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
871 ac_cv_asm_func_def=".type @function",
872 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
873 ac_cv_asm_func_def=".type 2",
874 ac_cv_asm_func_def="unknown")])]))
876 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
877 case "$ac_cv_asm_func_def" in
878 ".def")
879 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
880 ".type @function")
881 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
882 ".type 2")
883 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
884 *)
885 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
886 esac
888 dnl **** Check for underscore on external symbols ****
890 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
891 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
892 [extern int ac_test;],
893 [if (ac_test) return 1],
894 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
896 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
897 if test "$ac_cv_c_extern_prefix" = "yes"
898 then
899 AC_DEFINE([__ASM_NAME(name)], ["_" name])
900 else
901 AC_DEFINE([__ASM_NAME(name)], [name])
902 fi
904 dnl **** Check for working dll ****
906 AC_SUBST(DLLEXT,"")
907 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
908 AC_SUBST(DLLIBS,"")
909 AC_SUBST(LDSHARED,"")
910 AC_SUBST(LDDLLFLAGS,"")
911 AC_SUBST(LIBEXT,"so")
912 AC_SUBST(IMPLIBEXT,"def")
914 case $host_os in
915 cygwin*|mingw32*)
916 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
917 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
918 if test "$DLLWRAP" = "false"; then
919 LIBEXT="a"
920 else
921 dnl FIXME - check whether dllwrap works correctly...
922 LIBEXT="dll"
923 fi
924 IMPLIBEXT="a"
925 dnl We can't build 16-bit NE dlls
926 WIN16_FILES=""
927 WIN16_INSTALL=""
928 ;;
929 *)
930 AC_CHECK_HEADERS(dlfcn.h,
931 [AC_CHECK_FUNCS(dlopen,,
932 [AC_CHECK_LIB(dl,dlopen,
933 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
934 DLLIBS="-ldl"],
935 [LIBEXT="a"])])],
936 [LIBEXT="a"])
938 if test "$LIBEXT" = "so"
939 then
940 DLLFLAGS="$DLLFLAGS -fPIC"
941 DLLEXT=".so"
942 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
943 [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
944 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
945 if test "$ac_cv_c_dll_gnuelf" = "yes"
946 then
947 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
948 LDDLLFLAGS="-shared -Wl,-Bsymbolic"
949 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
950 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
951 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
952 if test "$ac_cv_c_dll_zdefs" = "yes"
953 then
954 LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
955 fi
957 AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
958 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
959 ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
960 if test "$ac_cv_c_dll_init_fini" = "yes"
961 then
962 LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
963 fi
965 AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
966 [echo '{ global: *; };' >conftest.map
967 WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
968 ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
969 rm -f conftest.map])
970 if test "$ac_cv_c_ld_version_scripts" = "yes"
971 then
972 LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
973 fi
975 AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
976 [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
977 ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
978 if test "$ac_cv_c_export_dynamic" = "yes"
979 then
980 AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
981 fi
983 case $host_cpu in
984 *i[[3456789]]86*)
985 AC_CACHE_CHECK([whether we can relocate the executable to 0x7bf00000], ac_cv_ld_reloc_exec,
986 [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
987 ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
988 if test "$ac_cv_ld_reloc_exec" = "yes"
989 then
990 LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"
991 fi
992 ;;
993 esac
995 else
996 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
997 [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
998 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
999 if test "$ac_cv_c_dll_unixware" = "yes"
1000 then
1001 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
1002 LDDLLFLAGS="-Wl,-G,-B,symbolic"
1004 else
1005 AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
1006 [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
1007 if test "$ac_cv_c_dll_macho" = "yes"
1008 then
1009 LIBEXT="dylib"
1010 LDDLLFLAGS="-bundle -flat_namespace -undefined suppress -read_only_relocs warning"
1011 LDSHARED="\$(CC) -dynamiclib"
1012 CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
1013 STRIP="$STRIP -u -r"
1014 dnl Relocate wine executable
1015 AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
1016 dnl Relocate libwine.dyld too
1017 AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
1018 dnl declare needed frameworks
1019 AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1020 AC_SUBST(IOKITLIB,"-framework IOKit")
1021 dnl using IOKit imply we use CoreFoundation too
1022 IOKITLIB="$IOKITLIB $COREFOUNDATIONLIB"
1023 else
1024 AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1025 [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1026 if test "$ac_cv_c_dll_hpux" = "yes"
1027 then
1028 LIBEXT="sl"
1029 DLLEXT=".sl"
1030 LDDLLFLAGS="-shared -fPIC"
1031 LDSHARED="\$(CC) -shared"
1032 fi
1033 fi
1034 fi
1035 fi
1036 fi
1038 dnl Check for cross compiler to build test programs
1039 AC_SUBST(CROSSTEST,"")
1040 if test "$cross_compiling" = "no"
1041 then
1042 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1043 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1044 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1045 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1046 fi
1047 ;;
1048 esac
1050 if test "$LIBEXT" = "a"; then
1051 AC_MSG_ERROR(
1052 [could not find a way to build shared libraries.
1053 It is currently not possible to build Wine without shared library
1054 (.so) support to allow transparent switch between .so and .dll files.
1055 If you are using Linux, you will need a newer binutils.]
1056 )
1057 fi
1059 case $build_os in
1060 cygwin*|mingw32*)
1061 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
1062 darwin*|macosx*)
1063 AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1064 *)
1065 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1066 esac
1068 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1069 case $host_os in
1070 mingw32*)
1071 AC_SUBST(CRTLIBS,"-lmsvcrt")
1072 AC_SUBST(SOCKETLIBS,"-lws2_32")
1073 ;;
1074 esac
1076 case $host_os in
1077 linux*)
1078 case $host_cpu in
1079 *i[[3456789]]86*) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader") ;;
1080 *) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread") ;;
1081 esac
1082 AC_SUBST(MAIN_BINARY,"wine-glibc")
1083 ;;
1084 darwin*)
1085 AC_SUBST(WINE_BINARIES,"wine-pthread")
1086 AC_SUBST(MAIN_BINARY,"wine-pthread")
1087 ;;
1088 *)
1089 AC_SUBST(WINE_BINARIES,"wine-kthread")
1090 AC_SUBST(MAIN_BINARY,"wine-kthread")
1091 ;;
1092 esac
1094 dnl **** Get the soname for libraries that we load dynamically ****
1096 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1097 then
1098 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1099 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1100 WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1101 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1102 WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1103 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1104 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1105 WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1106 WINE_GET_SONAME(cups,cupsGetDefault)
1107 WINE_GET_SONAME(jack,jack_client_new)
1108 WINE_GET_SONAME(fontconfig,FcInit)
1109 WINE_GET_SONAME(ssl,SSL_library_init)
1110 WINE_GET_SONAME(crypto,BIO_new_socket)
1111 WINE_GET_SONAME(ncurses,waddch)
1112 WINE_GET_SONAME(curses,waddch)
1113 WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1114 WINE_GET_SONAME(ungif,DGifOpen)
1115 WINE_GET_SONAME(gif,DGifOpen)
1116 WINE_GET_SONAME(capi20,capi20_isinstalled)
1117 fi
1120 dnl **** Check for functions ****
1122 AC_FUNC_ALLOCA()
1123 AC_CHECK_FUNCS(\
1124 _lwp_create \
1125 _lwp_self \
1126 _pclose \
1127 _popen \
1128 _snprintf \
1129 _spawnvp \
1130 _stricmp \
1131 _strnicmp \
1132 _vsnprintf \
1133 chsize \
1134 clone \
1135 epoll_create \
1136 ffs \
1137 finite \
1138 fork \
1139 fpclass \
1140 fstatfs \
1141 fstatvfs \
1142 ftruncate \
1143 futimes \
1144 futimesat \
1145 getnetbyname \
1146 getopt_long \
1147 getpagesize \
1148 getprotobyname \
1149 getprotobynumber \
1150 getpwuid \
1151 getservbyport \
1152 gettid \
1153 gettimeofday \
1154 getuid \
1155 inet_network \
1156 lstat \
1157 memmove \
1158 mmap \
1159 pclose \
1160 popen \
1161 pread \
1162 pwrite \
1163 readlink \
1164 rfork \
1165 sched_yield \
1166 select \
1167 sendmsg \
1168 settimeofday \
1169 sigaltstack \
1170 sigprocmask \
1171 snprintf \
1172 spawnvp \
1173 statfs \
1174 statvfs \
1175 strcasecmp \
1176 strerror \
1177 strncasecmp \
1178 tcgetattr \
1179 timegm \
1180 usleep \
1181 vsnprintf \
1182 wait4 \
1183 waitpid \
1184 )
1186 dnl **** Checks for headers that depend on other ones ****
1188 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1189 [#include <sys/types.h>
1190 #if HAVE_SYS_PARAM_H
1191 # include <sys/param.h>
1192 #endif])
1194 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1195 [#include <sys/types.h>
1196 #if HAVE_SYS_SOCKET_H
1197 # include <sys/socket.h>
1198 #endif])
1200 AC_CHECK_HEADERS([resolv.h],,,
1201 [#include <sys/types.h>
1202 #if HAVE_SYS_SOCKET_H
1203 # include <sys/socket.h>
1204 #endif
1205 #if HAVE_NETINET_IN_H
1206 # include <netinet/in.h>
1207 #endif
1208 #if HAVE_ARPA_NAMESER_H
1209 # include <arpa/nameser.h>
1210 #endif])
1212 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1214 dnl **** Check for v4l(2) headers ****
1216 AC_CHECK_HEADERS(linux/videodev.h,,,
1217 [#ifdef HAVE_SYS_TIME_H
1218 #include <sys/time.h>
1219 #endif
1220 #include <sys/types.h>
1221 #ifdef HAVE_ASM_TYPES_H
1222 #include <asm/types.h>
1223 #endif])
1225 dnl **** Check for IPX headers (currently Linux only) ****
1227 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1228 AC_TRY_COMPILE(
1229 [#include <sys/types.h>
1230 #ifdef HAVE_SYS_SOCKET_H
1231 # include <sys/socket.h>
1232 #endif
1233 #include <netipx/ipx.h>],
1234 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1235 [ac_cv_c_ipx_gnu="yes"],
1236 [ac_cv_c_ipx_gnu="no"])
1237 )
1238 if test "$ac_cv_c_ipx_gnu" = "yes"
1239 then
1240 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1241 fi
1243 if test "$ac_cv_c_ipx_gnu" = "no"
1244 then
1245 AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1246 AC_TRY_COMPILE(
1247 [#include <sys/types.h>
1248 #ifdef HAVE_SYS_SOCKET_H
1249 # include <sys/socket.h>
1250 #endif
1251 #include <asm/types.h>
1252 #include <linux/ipx.h>],
1253 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1254 [ac_cv_c_ipx_linux="yes"],
1255 [ac_cv_c_ipx_linux="no"])
1256 )
1257 if test "$ac_cv_c_ipx_linux" = "yes"
1258 then
1259 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1260 fi
1261 fi
1263 dnl **** Check for types ****
1265 AC_C_CONST
1266 AC_C_INLINE
1267 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1268 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1269 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1271 AC_CACHE_CHECK([whether linux/input.h is for real],
1272 wine_cv_linux_input_h,
1273 AC_TRY_COMPILE([
1274 #include <linux/input.h>
1275 ] , [
1276 int foo = EVIOCGBIT(EV_ABS,42);
1277 int bar = BTN_PINKIE;
1278 int fortytwo = 42;
1279 ],
1280 wine_cv_linux_input_h=yes,
1281 wine_cv_linux_input_h=no,
1282 no
1283 )
1284 )
1285 if test "$wine_cv_linux_input_h" = "yes"
1286 then
1287 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1288 [Define if we have linux/input.h AND it contains the INPUT event API])
1289 fi
1291 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1292 AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1293 wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1294 if test "$wine_cv_have_sigaddset" = "yes"
1295 then
1296 AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1297 fi
1300 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1301 wine_cv_linux_gethostbyname_r_6,
1302 AC_TRY_LINK([
1303 #include <netdb.h>
1304 ], [
1305 char *name=NULL;
1306 struct hostent he;
1307 struct hostent *result;
1308 char *buf=NULL;
1309 int bufsize=0;
1310 int res,errnr;
1311 char *addr=NULL;
1312 int addrlen=0;
1313 int addrtype=0;
1314 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1315 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1316 ],
1317 wine_cv_linux_gethostbyname_r_6=yes,
1318 wine_cv_linux_gethostbyname_r_6=no
1319 )
1320 )
1321 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1322 then
1323 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1324 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1325 fi
1327 if test "$ac_cv_header_linux_joystick_h" = "yes"
1328 then
1329 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1330 wine_cv_linux_joystick_22_api,
1331 AC_TRY_COMPILE([
1332 #include <sys/ioctl.h>
1333 #include <linux/joystick.h>
1335 struct js_event blub;
1336 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1337 #error "no 2.2 header"
1338 #endif
1339 ],/*empty*/,
1340 wine_cv_linux_joystick_22_api=yes,
1341 wine_cv_linux_joystick_22_api=no,
1342 wine_cv_linux_joystick_22_api=no
1343 )
1344 )
1345 if test "$wine_cv_linux_joystick_22_api" = "yes"
1346 then
1347 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1348 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1349 fi
1350 fi
1352 dnl **** statfs checks ****
1354 if test "$ac_cv_header_sys_vfs_h" = "yes"
1355 then
1356 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1357 wine_cv_sys_vfs_has_statfs,
1358 AC_TRY_COMPILE([
1359 #include <sys/types.h>
1360 #ifdef HAVE_SYS_PARAM_H
1361 # include <sys/param.h>
1362 #endif
1363 #include <sys/vfs.h>
1364 ],[
1365 struct statfs stfs;
1367 memset(&stfs,0,sizeof(stfs));
1368 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1369 )
1370 )
1371 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1372 then
1373 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1374 [Define if the struct statfs is defined by <sys/vfs.h>])
1375 fi
1376 fi
1378 if test "$ac_cv_header_sys_statfs_h" = "yes"
1379 then
1380 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1381 wine_cv_sys_statfs_has_statfs,
1382 AC_TRY_COMPILE([
1383 #include <sys/types.h>
1384 #ifdef HAVE_SYS_PARAM_H
1385 # include <sys/param.h>
1386 #endif
1387 #include <sys/statfs.h>
1388 ],[
1389 struct statfs stfs;
1390 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1391 )
1392 )
1393 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1394 then
1395 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1396 [Define if the struct statfs is defined by <sys/statfs.h>])
1397 fi
1398 fi
1400 if test "$ac_cv_header_sys_mount_h" = "yes"
1401 then
1402 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1403 wine_cv_sys_mount_has_statfs,
1404 AC_TRY_COMPILE([
1405 #include <sys/types.h>
1406 #ifdef HAVE_SYS_PARAM_H
1407 # include <sys/param.h>
1408 #endif
1409 #include <sys/mount.h>
1410 ],[
1411 struct statfs stfs;
1412 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1413 )
1414 )
1415 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1416 then
1417 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1418 [Define if the struct statfs is defined by <sys/mount.h>])
1419 fi
1420 fi
1422 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1424 dnl Check for statfs members
1425 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1426 [#include <sys/types.h>
1427 #ifdef HAVE_SYS_PARAM_H
1428 # include <sys/param.h>
1429 #endif
1430 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1431 # include <sys/mount.h>
1432 #else
1433 # ifdef STATFS_DEFINED_BY_SYS_VFS
1434 # include <sys/vfs.h>
1435 # else
1436 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1437 # include <sys/statfs.h>
1438 # endif
1439 # endif
1440 #endif])
1442 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1443 [#ifdef HAVE_SYS_STATVFS_H
1444 #include <sys/statvfs.h>
1445 #endif])
1447 dnl Check for socket structure members
1448 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1449 [#include <sys/types.h>
1450 #ifdef HAVE_SYS_SOCKET_H
1451 # include <sys/socket.h>
1452 #endif
1453 #ifdef HAVE_SYS_UN_H
1454 # include <sys/un.h>
1455 #endif])
1457 dnl Check for scsireq_t and sg_io_hdr_t members
1458 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1459 [#include <sys/types.h>
1460 #ifdef HAVE_SCSI_SG_H
1461 #include <scsi/sg.h>
1462 #endif])
1464 dnl Check for siginfo_t members
1465 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1467 dnl Check for struct option
1468 AC_CHECK_MEMBERS([struct option.name],,,
1469 [#ifdef HAVE_GETOPT_H
1470 #include <getopt.h>
1471 #endif])
1473 dnl Check for stat.st_blocks
1474 AC_CHECK_MEMBERS([struct stat.st_blocks])
1476 dnl Check for the external timezone variables timezone and daylight
1477 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1478 AC_TRY_LINK([#include <time.h>],[timezone;],
1479 ac_cv_have_timezone="yes", ac_cv_have_timezone="no"))
1480 if test "$ac_cv_have_timezone" = "yes"
1481 then
1482 AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1483 fi
1484 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1485 AC_TRY_LINK([#include <time.h>],[daylight;],
1486 ac_cv_have_daylight="yes", ac_cv_have_daylight="no"))
1487 if test "$ac_cv_have_daylight" = "yes"
1488 then
1489 AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1490 fi
1492 dnl *** check for the need to define platform-specific symbols
1494 case $host_cpu in
1495 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1496 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1497 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1498 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1499 esac
1501 case $host_vendor in
1502 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1503 esac
1505 dnl **** Generate output files ****
1507 AH_TOP([#define __WINE_CONFIG_H])
1509 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1510 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1511 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1512 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1513 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1514 WINE_CONFIG_EXTRA_DIR(include/wine)
1515 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1517 MAKE_RULES=Make.rules
1518 AC_SUBST_FILE(MAKE_RULES)
1520 MAKE_DLL_RULES=dlls/Makedll.rules
1521 AC_SUBST_FILE(MAKE_DLL_RULES)
1523 MAKE_TEST_RULES=dlls/Maketest.rules
1524 AC_SUBST_FILE(MAKE_TEST_RULES)
1526 MAKE_LIB_RULES=libs/Makelib.rules
1527 AC_SUBST_FILE(MAKE_LIB_RULES)
1529 MAKE_PROG_RULES=programs/Makeprog.rules
1530 AC_SUBST_FILE(MAKE_PROG_RULES)
1532 AC_CONFIG_FILES([
1533 Make.rules
1534 dlls/Makedll.rules
1535 dlls/Maketest.rules
1536 libs/Makelib.rules
1537 programs/Makeprog.rules
1538 Makefile
1539 dlls/Makefile
1540 dlls/activeds/Makefile
1541 dlls/advapi32/Makefile
1542 dlls/advapi32/tests/Makefile
1543 dlls/advpack/Makefile
1544 dlls/advpack/tests/Makefile
1545 dlls/amstream/Makefile
1546 dlls/atl/Makefile
1547 dlls/avicap32/Makefile
1548 dlls/avifil32/Makefile
1549 dlls/cabinet/Makefile
1550 dlls/capi2032/Makefile
1551 dlls/cards/Makefile
1552 dlls/cfgmgr32/Makefile
1553 dlls/comcat/Makefile
1554 dlls/comctl32/Makefile
1555 dlls/comctl32/tests/Makefile
1556 dlls/commdlg/Makefile
1557 dlls/crtdll/Makefile
1558 dlls/crypt32/Makefile
1559 dlls/crypt32/tests/Makefile
1560 dlls/cryptdll/Makefile
1561 dlls/ctl3d/Makefile
1562 dlls/d3d8/Makefile
1563 dlls/d3d9/Makefile
1564 dlls/d3dim/Makefile
1565 dlls/d3drm/Makefile
1566 dlls/d3dx8/Makefile
1567 dlls/d3dxof/Makefile
1568 dlls/dbghelp/Makefile
1569 dlls/dciman32/Makefile
1570 dlls/ddraw/Makefile
1571 dlls/ddraw/tests/Makefile
1572 dlls/devenum/Makefile
1573 dlls/dinput/Makefile
1574 dlls/dinput/tests/Makefile
1575 dlls/dinput8/Makefile
1576 dlls/dmband/Makefile
1577 dlls/dmcompos/Makefile
1578 dlls/dmime/Makefile
1579 dlls/dmloader/Makefile
1580 dlls/dmscript/Makefile
1581 dlls/dmstyle/Makefile
1582 dlls/dmsynth/Makefile
1583 dlls/dmusic/Makefile
1584 dlls/dmusic32/Makefile
1585 dlls/dplay/Makefile
1586 dlls/dplayx/Makefile
1587 dlls/dpnet/Makefile
1588 dlls/dpnhpast/Makefile
1589 dlls/dsound/Makefile
1590 dlls/dsound/tests/Makefile
1591 dlls/dswave/Makefile
1592 dlls/dxdiagn/Makefile
1593 dlls/dxerr8/Makefile
1594 dlls/dxerr9/Makefile
1595 dlls/dxguid/Makefile
1596 dlls/gdi/Makefile
1597 dlls/gdi/tests/Makefile
1598 dlls/glu32/Makefile
1599 dlls/glut32/Makefile
1600 dlls/hhctrl.ocx/Makefile
1601 dlls/iccvid/Makefile
1602 dlls/icmp/Makefile
1603 dlls/ifsmgr.vxd/Makefile
1604 dlls/imagehlp/Makefile
1605 dlls/imm32/Makefile
1606 dlls/iphlpapi/Makefile
1607 dlls/iphlpapi/tests/Makefile
1608 dlls/itss/Makefile
1609 dlls/kernel/Makefile
1610 dlls/kernel/tests/Makefile
1611 dlls/lzexpand/Makefile
1612 dlls/lzexpand/tests/Makefile
1613 dlls/mapi32/Makefile
1614 dlls/mapi32/tests/Makefile
1615 dlls/midimap/Makefile
1616 dlls/mlang/Makefile
1617 dlls/mlang/tests/Makefile
1618 dlls/mmdevldr.vxd/Makefile
1619 dlls/monodebg.vxd/Makefile
1620 dlls/mpr/Makefile
1621 dlls/msacm/Makefile
1622 dlls/msacm/imaadp32/Makefile
1623 dlls/msacm/msadp32/Makefile
1624 dlls/msacm/msg711/Makefile
1625 dlls/msacm/winemp3/Makefile
1626 dlls/msacm/tests/Makefile
1627 dlls/mscms/Makefile
1628 dlls/mscms/tests/Makefile
1629 dlls/msdmo/Makefile
1630 dlls/mshtml/Makefile
1631 dlls/mshtml/tests/Makefile
1632 dlls/msi/Makefile
1633 dlls/msi/tests/Makefile
1634 dlls/msimg32/Makefile
1635 dlls/msisys/Makefile
1636 dlls/msnet32/Makefile
1637 dlls/msrle32/Makefile
1638 dlls/msvcrt/Makefile
1639 dlls/msvcrt/tests/Makefile
1640 dlls/msvcrt20/Makefile
1641 dlls/msvcrt40/Makefile
1642 dlls/msvcrtd/Makefile
1643 dlls/msvcrtd/tests/Makefile
1644 dlls/msvidc32/Makefile
1645 dlls/msvideo/Makefile
1646 dlls/mswsock/Makefile
1647 dlls/netapi32/Makefile
1648 dlls/netapi32/tests/Makefile
1649 dlls/newdev/Makefile
1650 dlls/ntdll/Makefile
1651 dlls/ntdll/tests/Makefile
1652 dlls/odbc32/Makefile
1653 dlls/odbccp32/Makefile
1654 dlls/ole32/Makefile
1655 dlls/ole32/tests/Makefile
1656 dlls/oleacc/Makefile
1657 dlls/oleaut32/Makefile
1658 dlls/oleaut32/tests/Makefile
1659 dlls/olecli/Makefile
1660 dlls/oledlg/Makefile
1661 dlls/olepro32/Makefile
1662 dlls/olesvr/Makefile
1663 dlls/opengl32/Makefile
1664 dlls/powrprof/Makefile
1665 dlls/psapi/Makefile
1666 dlls/psapi/tests/Makefile
1667 dlls/qcap/Makefile
1668 dlls/quartz/Makefile
1669 dlls/quartz/tests/Makefile
1670 dlls/rasapi32/Makefile
1671 dlls/riched20/Makefile
1672 dlls/richedit/Makefile
1673 dlls/rpcrt4/Makefile
1674 dlls/rpcrt4/tests/Makefile
1675 dlls/rsabase/Makefile
1676 dlls/rsabase/tests/Makefile
1677 dlls/rsaenh/Makefile
1678 dlls/rsaenh/tests/Makefile
1679 dlls/secur32/Makefile
1680 dlls/sensapi/Makefile
1681 dlls/serialui/Makefile
1682 dlls/setupapi/Makefile
1683 dlls/shdocvw/Makefile
1684 dlls/shell32/Makefile
1685 dlls/shell32/tests/Makefile
1686 dlls/shfolder/Makefile
1687 dlls/shlwapi/Makefile
1688 dlls/shlwapi/tests/Makefile
1689 dlls/snmpapi/Makefile
1690 dlls/stdole2.tlb/Makefile
1691 dlls/stdole32.tlb/Makefile
1692 dlls/sti/Makefile
1693 dlls/strmiids/Makefile
1694 dlls/tapi32/Makefile
1695 dlls/ttydrv/Makefile
1696 dlls/twain/Makefile
1697 dlls/unicows/Makefile
1698 dlls/url/Makefile
1699 dlls/urlmon/Makefile
1700 dlls/urlmon/tests/Makefile
1701 dlls/user/Makefile
1702 dlls/user/tests/Makefile
1703 dlls/uuid/Makefile
1704 dlls/uxtheme/Makefile
1705 dlls/vdhcp.vxd/Makefile
1706 dlls/vdmdbg/Makefile
1707 dlls/version/Makefile
1708 dlls/version/tests/Makefile
1709 dlls/vmm.vxd/Makefile
1710 dlls/vnbt.vxd/Makefile
1711 dlls/vnetbios.vxd/Makefile
1712 dlls/vtdapi.vxd/Makefile
1713 dlls/vwin32.vxd/Makefile
1714 dlls/win32s/Makefile
1715 dlls/winaspi/Makefile
1716 dlls/wined3d/Makefile
1717 dlls/winedos/Makefile
1718 dlls/wineps/Makefile
1719 dlls/wininet/Makefile
1720 dlls/wininet/tests/Makefile
1721 dlls/winmm/Makefile
1722 dlls/winmm/joystick/Makefile
1723 dlls/winmm/mcianim/Makefile
1724 dlls/winmm/mciavi/Makefile
1725 dlls/winmm/mcicda/Makefile
1726 dlls/winmm/mciseq/Makefile
1727 dlls/winmm/mciwave/Makefile
1728 dlls/winmm/tests/Makefile
1729 dlls/winmm/wavemap/Makefile
1730 dlls/winmm/winealsa/Makefile
1731 dlls/winmm/winearts/Makefile
1732 dlls/winmm/wineaudioio/Makefile
1733 dlls/winmm/winejack/Makefile
1734 dlls/winmm/winenas/Makefile
1735 dlls/winmm/wineoss/Makefile
1736 dlls/winnls/Makefile
1737 dlls/winsock/Makefile
1738 dlls/winsock/tests/Makefile
1739 dlls/winspool/Makefile
1740 dlls/winspool/tests/Makefile
1741 dlls/wintab32/Makefile
1742 dlls/wintrust/Makefile
1743 dlls/wldap32/Makefile
1744 dlls/wow32/Makefile
1745 dlls/wsock32/Makefile
1746 dlls/wtsapi32/Makefile
1747 dlls/x11drv/Makefile
1748 documentation/Makefile
1749 fonts/Makefile
1750 include/Makefile
1751 libs/Makefile
1752 libs/port/Makefile
1753 libs/unicode/Makefile
1754 libs/wine/Makefile
1755 libs/wpp/Makefile
1756 loader/Makefile
1757 programs/Makefile
1758 programs/avitools/Makefile
1759 programs/clock/Makefile
1760 programs/cmdlgtst/Makefile
1761 programs/control/Makefile
1762 programs/expand/Makefile
1763 programs/hh/Makefile
1764 programs/msiexec/Makefile
1765 programs/notepad/Makefile
1766 programs/progman/Makefile
1767 programs/regedit/Makefile
1768 programs/regsvr32/Makefile
1769 programs/rpcss/Makefile
1770 programs/rundll32/Makefile
1771 programs/start/Makefile
1772 programs/taskmgr/Makefile
1773 programs/uninstaller/Makefile
1774 programs/view/Makefile
1775 programs/wcmd/Makefile
1776 programs/wineboot/Makefile
1777 programs/winebrowser/Makefile
1778 programs/winecfg/Makefile
1779 programs/wineconsole/Makefile
1780 programs/winedbg/Makefile
1781 programs/winefile/Makefile
1782 programs/winemenubuilder/Makefile
1783 programs/winemine/Makefile
1784 programs/winepath/Makefile
1785 programs/winetest/Makefile
1786 programs/winevdm/Makefile
1787 programs/winhelp/Makefile
1788 programs/winver/Makefile
1789 server/Makefile
1790 tools/Makefile
1791 tools/widl/Makefile
1792 tools/winapi/Makefile
1793 tools/winebuild/Makefile
1794 tools/winedump/Makefile
1795 tools/winegcc/Makefile
1796 tools/wmc/Makefile
1797 tools/wrc/Makefile])
1799 AC_OUTPUT
1801 if test "$have_x" = "no"
1802 then
1803 echo
1804 echo "*** Warning: X development files not found. Wine will be built without"
1805 echo "*** X support, which currently does not work, and would probably not be"
1806 echo "*** what you want anyway. You will need to install devel packages of"
1807 echo "*** Xlib/Xfree86 at the very least."
1808 fi
1810 if test "$wine_cv_opengl_version_OK" = "no"
1811 then
1812 echo
1813 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1814 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1815 fi
1817 if test "$wine_cv_msg_freetype" = "yes"
1818 then
1819 echo
1820 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1821 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1822 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1823 echo "*** enable Wine to use TrueType fonts."
1824 fi
1826 if test -z "$ALSALIBS" -a -z "$ARTSC_LIBS" -a -z "$AUDIOIOLIBS" -a \
1827 -z "$ac_cv_lib_soname_jack" -a -z "$NASLIBS" -a \
1828 "$ac_cv_c_opensoundsystem" = "no"
1829 then
1830 echo "*** No sound system was found. Windows applications will be silent."
1831 echo "*** The currently supported sound systems are:"
1832 echo "*** ALSA, ARTS, AudioIO, Jack, NAS and OSS"
1833 fi
1835 echo
1836 echo "Configure finished. Do '${ac_make} depend && ${ac_make}' to compile Wine."
1837 echo
1839 dnl Local Variables:
1840 dnl comment-start: "dnl "
1841 dnl comment-end: ""
1842 dnl comment-start-skip: "\\bdnl\\b\\s *"
1843 dnl compile-command: "autoconf"
1844 dnl End: