configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 # We want these before the checks, so the checks can modify their values.
  10 LIBS="$LIBS -lm"
  11 test -z "$PROGEXT" && PROGEXT="" AC_SUBST(PROGEXT)
  12
  13 dnl **** Command-line arguments ****
  14
  15 dnl Default values
  16 MAIN_TARGET=emu
  17 LIB_TARGET=libwine.a
  18 ALT_LINK="-L\$(TOPOBJDIR) -lwine"
  19 TRACE_MSGS=yes  # the TRACE() macro
  20 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  21
  22 AC_ARG_ENABLE(emulator,
  23 [  --disable-emulator      build only the Wine library, not the emulator],
  24 [if test "$enableval" = "no"; then MAIN_TARGET="lib"; fi])
  25
  26 AC_ARG_ENABLE(dll,
  27 [  --enable-dll            build the Wine library as a DLL],
  28 [if test "$enableval" = "no"; then : ; else LIB_TARGET="libwine.so.1.0"; fi])
  29
  30 AC_ARG_ENABLE(lib,
  31 [  --disable-lib           build the Wine without building libwine.a],
  32 [if test "$enableval" = "no"; then ALT_LINK="\$(LIBOBJS) \$(X11OBJS)"; LIB_TARGET=""; fi])
  33
  34 dnl AC_ARG_WITH(ipc,
  35 dnl [  --enable-ipc            use inter-process communication for DDE],
  36 dnl [if test "$enableval" = "no"; then : ; else OPTIONS="-DCONFIG_IPC"; fi])
  37
  38 AC_ARG_ENABLE(debug,
  39 [  --disable-debug         compile out all debugging messages],
  40 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  41
  42 AC_ARG_ENABLE(trace,
  43 [  --disable-trace         compile out TRACE messages],
  44 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  45
  46 AC_ARG_WITH(reentrant-x,
  47 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  48
  49 AC_SUBST(MAIN_TARGET)
  50 AC_SUBST(LIB_TARGET)
  51 AC_SUBST(ALT_LINK)
  52 AC_SUBST(OPTIONS)
  53
  54 if test "$DEBUG_MSGS" = "no"
  55 then
  56     AC_DEFINE(NO_DEBUG_MSGS)
  57     AC_DEFINE(NO_TRACE_MSGS)
  58 else
  59     if test "$TRACE_MSGS" = "no"
  60     then
  61         AC_DEFINE(NO_TRACE_MSGS)
  62     fi
  63 fi
  64
  65 dnl **** Check for some programs ****
  66
  67 AC_PROG_MAKE_SET
  68 AC_PROG_CC
  69 AC_PROG_CPP
  70 AC_PATH_XTRA
  71 AC_PROG_YACC
  72 AC_PROG_LEX
  73 AC_PROG_RANLIB
  74 AC_PROG_INSTALL
  75 AC_PROG_LN_S
  76 AC_CHECK_PROG(C2MAN,c2man,c2man,true)
  77
  78 dnl **** Check for some libraries ****
  79
  80 dnl Check for -li386 for NetBSD and OpenBSD
  81 AC_CHECK_LIB(i386,i386_set_ldt)
  82 dnl Check for -lossaudio for NetBSD
  83 AC_CHECK_LIB(ossaudio,_oss_ioctl)
  84 dnl Check for -lw for Solaris
  85 AC_CHECK_LIB(w,iswalnum)
  86 dnl Check for -lnsl for Solaris
  87 AC_CHECK_FUNCS(gethostbyname)
  88 if test "$ac_cv_func_gethostbyname" = "no"
  89 then
  90     AC_CHECK_LIB(nsl,gethostbyname)
  91 fi
  92 dnl Check for -lxpg4 for FreeBSD
  93 AC_CHECK_LIB(xpg4,setrunelocale)
  94 dnl Check for -ldl
  95 AC_CHECK_LIB(dl,dlopen)
  96 AC_SUBST(XLIB)
  97 if test "$have_x" = "yes"
  98 then
  99     XLIB="-lXext -lX11"
 100     ac_save_CPPFLAGS="$CPPFLAGS"
 101     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 102
 103     dnl Check for -lXpm
 104     AC_CHECK_HEADERS(X11/xpm.h)
 105     if test "$ac_cv_header_X11_xpm_h" = "yes"
 106     then
 107         AC_CHECK_LIB(Xpm,XpmCreatePixmapFromData,AC_DEFINE(HAVE_LIBXXPM) X_PRE_LIBS="$X_PRE_LIBS -lXpm",,$X_LIBS -lXext -lX11)
 108     fi
 109
 110     dnl Check for X Shm extension
 111     AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/XShm.h)
 112     if test "$ac_cv_header_X11_Xlib_h" = "yes" -a "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 113     then
 114         AC_CHECK_LIB(Xext,XShmQueryExtension,AC_DEFINE(HAVE_LIBXXSHM),,$X_LIBS -lXext -lX11)
 115     fi
 116     dnl Check for XFree86 DGA extension
 117     AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/xf86dga.h)
 118     if test "$ac_cv_header_X11_Xlib_h" = "yes" -a "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 119     then
 120          AC_CHECK_LIB(Xxf86dga,XF86DGAQueryExtension,AC_DEFINE(HAVE_LIBXXF86DGA) X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga",,$X_LIBS -lXext -lX11)
 121     fi
 122
 123     dnl Check for XFree86 VMODE extension
 124     AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/xf86vmode.h)
 125     if test "$ac_cv_header_X11_Xlib_h" = "yes" -a "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 126     then
 127         AC_CHECK_LIB(Xxf86vm,XF86VidModeQueryExtension,AC_DEFINE(HAVE_LIBXXF86VM) X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm",,$X_LIBS -lXext -lX11)
 128     fi
 129     dnl Check for the presence of Mesa
 130     AC_CHECK_HEADERS(GL/gl.h GL/osmesa.h)
 131     if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_osmesa_h" = "yes"
 132     then
 133         AC_CHECK_LIB(MesaGL,OSMesaCreateContext,AC_DEFINE(HAVE_LIBMESAGL) X_PRE_LIBS="$X_PRE_LIBS -lMesaGL",,$X_LIBS -lXext -lX11 -lm)
 134     fi
 135
 136     CPPFLAGS="$ac_save_CPPFLAGS"
 137 else
 138     XLIB=""
 139     X_CFLAGS=""
 140     X_LIBS=""
 141 fi
 142
 143 dnl **** Check which curses lib to use ***
 144 AC_CHECK_HEADERS(ncurses.h)
 145 if test "$ac_cv_header_ncurses_h" = "yes"
 146 then
 147     AC_CHECK_LIB(ncurses,waddch)
 148 fi
 149 if test "$ac_cv_lib_ncurses_waddch" = "yes"
 150 then
 151     AC_CHECK_LIB(ncurses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 152 else
 153     AC_CHECK_HEADERS(curses.h)
 154     if test "$ac_cv_header_curses_h" = "yes"
 155     then
 156        AC_CHECK_LIB(curses,waddch)
 157        AC_CHECK_LIB(curses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 158     fi
 159 fi
 160
 161 dnl **** Check for IPX (currently Linux only) ****
 162 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
 163  AC_TRY_COMPILE(
 164    [#include <sys/socket.h>
 165     #include <netipx/ipx.h>],
 166    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 167    [AC_DEFINE(HAVE_IPX_GNU)
 168     ac_cv_c_ipx_gnu="yes"],
 169    [ac_cv_c_ipx_gnu="no"])
 170  )
 171
 172 if test "$ac_cv_c_ipx_gnu" = "no"
 173 then
 174  AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
 175   AC_TRY_COMPILE(
 176     [#include <sys/socket.h>
 177      #include <asm/types.h>
 178      #include <linux/ipx.h>],
 179     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 180     [AC_DEFINE(HAVE_IPX_LINUX)
 181      ac_cv_c_ipx_linux="yes"],
 182     [ac_cv_c_ipx_linux="no"])
 183   )
 184 fi
 185
 186 dnl **** Check for Open Sound System ****
 187 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 188
 189 AC_CACHE_CHECK("for Open Sound System",
 190         ac_cv_c_opensoundsystem,
 191         AC_TRY_COMPILE([
 192         #if defined(HAVE_SYS_SOUNDCARD_H)
 193                 #include <sys/soundcard.h>
 194         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 195                 #include <machine/soundcard.h>
 196         #elif defined(HAVE_SOUNDCARD_H)
 197                 #include <soundcard.h>
 198         #endif
 199         ],[
 200
 201 /* check for one of the Open Sound System specific SNDCTL_ defines */
 202 #if !defined(SNDCTL_DSP_STEREO)
 203 #error No open sound system
 204 #endif
 205 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 206
 207 if test "$ac_cv_c_opensoundsystem" = "yes"
 208 then
 209     AC_DEFINE(HAVE_OSS)
 210 fi
 211
 212 dnl **** Check for union semun ****
 213
 214 AC_CACHE_CHECK("for union semun", ac_cv_c_union_semun,
 215  AC_TRY_COMPILE([#include <sys/types.h>
 216 #include <sys/sem.h>],[union semun foo],
 217                 ac_cv_c_union_semun="yes", ac_cv_c_union_semun="no"))
 218 if test "$ac_cv_c_union_semun" = "yes"
 219 then
 220     AC_DEFINE(HAVE_UNION_SEMUN)
 221 fi
 222
 223 dnl **** If ln -s doesn't work, use cp instead ****
 224 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 225
 226 dnl **** Check for gcc strength-reduce bug ****
 227
 228 if test "x${GCC}" = "xyes"
 229 then
 230   CFLAGS="$CFLAGS -Wall"
 231   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
 232                   AC_TRY_RUN([
 233 int main(void) {
 234   static int Array[[3]];
 235   unsigned int B = 3;
 236   int i;
 237   for(i=0; i<B; i++) Array[[i]] = i - 3;
 238   exit( Array[[1]] != -2 );
 239 }],
 240     ac_cv_c_gcc_strength_bug="no",
 241     ac_cv_c_gcc_strength_bug="yes",
 242     ac_cv_c_gcc_strength_bug="yes") )
 243   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 244   then
 245     CFLAGS="$CFLAGS -fno-strength-reduce"
 246   fi
 247 fi
 248
 249 dnl **** Check for underscore on external symbols ****
 250
 251 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
 252                ac_cv_c_extern_prefix,
 253 [saved_libs=$LIBS
 254 LIBS="conftest_asm.s $LIBS"
 255 cat > conftest_asm.s <<EOF
 256         .globl _ac_test
 257 _ac_test:
 258         .long 0
 259 EOF
 260 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 261             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 262 LIBS=$saved_libs])
 263 if test "$ac_cv_c_extern_prefix" = "yes"
 264 then
 265   AC_DEFINE(NEED_UNDERSCORE_PREFIX)
 266 fi
 267
 268 dnl **** Check for .string in assembler ****
 269
 270 AC_CACHE_CHECK("whether assembler accepts .string",
 271                ac_cv_c_asm_string,
 272 [saved_libs=$LIBS
 273 LIBS="conftest_asm.s $LIBS"
 274 cat > conftest_asm.s <<EOF
 275         .string "test"
 276 EOF
 277 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 278 LIBS=$saved_libs])
 279 if test "$ac_cv_c_asm_string" = "yes"
 280 then
 281   AC_DEFINE(HAVE_ASM_STRING)
 282 fi
 283
 284 dnl **** Check for working dll ****
 285
 286 DLLFLAGS=""
 287 LDSHARED=""
 288 if test "$LIB_TARGET" = "libwine.so.1.0"
 289 then
 290   AC_CACHE_CHECK("whether we can build a Linux dll",
 291                  ac_cv_c_dll_linux,
 292   [saved_cflags=$CFLAGS
 293   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0"
 294   AC_TRY_LINK(,[return 1],ac_cv_c_dll_linux="yes",ac_cv_c_dll_linux="no")
 295   CFLAGS=$saved_cflags
 296   ])
 297   if test "$ac_cv_c_dll_linux" = "yes"
 298   then
 299     DLLFLAGS="-fPIC"
 300     LDSHARED="\$(CC) -shared -Wl,-soname,libwine.so"
 301   else
 302     AC_CACHE_CHECK("whether we can build a NetBSD dll",
 303                    ac_cv_c_dll_netbsd,
 304     [saved_cflags=$CFLAGS
 305     CFLAGS="$CFLAGS -fPIC -Bshareable -Bforcearchive"
 306     AC_TRY_LINK(,[return 1],ac_cv_c_dll_netbsd="yes",ac_cv_c_dll_netbsd="no")
 307     CFLAGS=$saved_cflags
 308     ])
 309     if test "$ac_cv_c_dll_netbsd" = "yes"
 310     then
 311       DLLFLAGS="-fPIC"
 312       LDSHARED="ld -Bshareable -Bforcearchive"
 313     fi
 314   fi
 315   if test "$ac_cv_c_dll_linux" = "no" -a "$ac_cv_c_dll_netbsd" = "no"
 316   then
 317     LIB_TARGET="libwine.a"
 318   fi
 319 fi
 320 AC_SUBST(DLLFLAGS)
 321 AC_SUBST(LDSHARED)
 322
 323 dnl **** Check for reentrant libc ****
 324 dnl
 325 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 326 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 327
 328 AC_CACHE_CHECK("for reentrant libc", wine_cv_libc_reentrant,
 329   [AC_TRY_RUN([int myerrno = 0;
 330 char buf[256];
 331 int *__errno_location(){return &myerrno;}
 332 main(){connect(0,buf,255); exit(!myerrno);}],
 333   wine_cv_libc_reentrant=yes, wine_cv_libc_reentrant=no,
 334   wine_cv_libc_reentrant=yes ) ] )
 335 if test "$wine_cv_libc_reentrant" = "no"
 336 then
 337   AC_DEFINE(NO_REENTRANT_LIBC)
 338 fi
 339
 340 dnl **** Check for reentrant X libraries ****
 341 dnl
 342 dnl This may fail to determine whether X libraries are reentrant if
 343 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 344 dnl is possible with the --without-reentrant-x option.
 345
 346 if test "$have_x" = "yes"
 347 then
 348 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
 349   [ if test "x$with_reentrant_x" = "xno"
 350     then
 351         wine_cv_x_reentrant=no
 352     else
 353         libX11_ckeck=none
 354         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 355             if test -r $dir/libX11.so; then
 356                 libX11_check="-D $dir/libX11.so"
 357                 break 1
 358             fi
 359             if test -r $dir/libX11.a; then
 360                 libX11_check="$dir/libX11.a"
 361                 break 1
 362             fi
 363         done
 364         if test "$libX11_check" != "none"; then
 365             if nm $libX11_check | grep __errno_location >/dev/null 2>&1
 366             then
 367                 wine_cv_x_reentrant=yes
 368             else
 369                 wine_cv_x_reentrant=no
 370             fi
 371         else
 372             wine_cv_x_reentrant=unknown
 373         fi
 374     fi ] )
 375 else
 376     wine_cv_x_reentrant=no
 377 fi
 378 if test "$wine_cv_x_reentrant" = "no"
 379 then
 380   AC_DEFINE(NO_REENTRANT_X11)
 381 fi
 382
 383 dnl **** Check for functions and header files ****
 384
 385 AC_CHECK_FUNCS(clone getpagesize memmove sendmsg sigaltstack strerror stricmp tcgetattr timegm usleep wait4 waitpid vfscanf)
 386 AC_CHECK_HEADERS(wctype.h sys/syscall.h syscall.h sys/param.h sys/vfs.h sys/mount.h sys/statfs.h float.h linux/cdrom.h linux/ucdrom.h sys/cdio.h sys/filio.h sys/modem.h strings.h sys/strtio.h dlfcn.h unistd.h sys/sockio.h net/if.h netinet/in.h sys/file.h libio.h curses.h ncurses.h elf.h)
 387 AC_HEADER_STAT()
 388 AC_C_CONST()
 389 AC_TYPE_SIZE_T()
 390 AC_CHECK_SIZEOF(long long,0)
 391
 392 dnl **** Check for sendmsg in -lsocket if not found above ****
 393
 394 if test $ac_cv_func_sendmsg = no; then
 395     AC_CHECK_LIB(socket,sendmsg)
 396 fi
 397
 398 dnl **** statfs checks ****
 399
 400 if test "$ac_cv_header_sys_vfs_h" = "yes"
 401 then
 402     AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
 403                     wine_cv_sys_vfs_has_statfs,
 404         AC_TRY_COMPILE([
 405         #include <sys/types.h>
 406         #ifdef HAVE_SYS_PARAM_H
 407         # include <sys/param.h>
 408         #endif
 409         #include <sys/vfs.h>
 410         ],[
 411                 struct statfs stfs;
 412
 413                 memset(&stfs,0,sizeof(stfs));
 414         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
 415         )
 416     )
 417     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
 418     then
 419       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS)
 420     fi
 421 fi
 422
 423 if test "$ac_cv_header_sys_statfs_h" = "yes"
 424 then
 425     AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
 426                     wine_cv_sys_statfs_has_statfs,
 427         AC_TRY_COMPILE([
 428         #include <sys/types.h>
 429         #ifdef HAVE_SYS_PARAM_H
 430         # include <sys/param.h>
 431         #endif
 432         #include <sys/statfs.h>
 433         ],[
 434                 struct statfs stfs;
 435         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
 436         )
 437     )
 438     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
 439     then
 440       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS)
 441     fi
 442 fi
 443
 444 if test "$ac_cv_header_sys_mount_h" = "yes"
 445 then
 446     AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
 447                     wine_cv_sys_mount_has_statfs,
 448         AC_TRY_COMPILE([
 449         #include <sys/types.h>
 450         #ifdef HAVE_SYS_PARAM_H
 451         # include <sys/param.h>
 452         #endif
 453         #include <sys/mount.h>
 454         ],[
 455                 struct statfs stfs;
 456         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
 457         )
 458     )
 459     if test "$wine_cv_sys_mount_has_statfs" = "yes"
 460     then
 461       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT)
 462     fi
 463 fi
 464
 465 dnl **** FIXME: what about mixed cases, where we need two of them? ***
 466
 467 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
 468   [ if test "x$statfs_bfree" = "xno"
 469     then
 470         wine_cv_statfs_bfree=no
 471     else
 472         AC_TRY_COMPILE([
 473         #include <sys/types.h>
 474         #ifdef HAVE_SYS_PARAM_H
 475         # include <sys/param.h>
 476         #endif
 477         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 478         # include <sys/mount.h>
 479         #else
 480         # ifdef STATFS_DEFINED_BY_SYS_VFS
 481         #  include <sys/vfs.h>
 482         # else
 483         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 484         #   include <sys/statfs.h>
 485         #  endif
 486         # endif
 487         #endif
 488         ],[
 489                 struct statfs stfs;
 490
 491                 stfs.f_bfree++;
 492         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
 493         )
 494     fi ] )
 495 if test "$wine_cv_statfs_bfree" = "yes"
 496 then
 497   AC_DEFINE(STATFS_HAS_BFREE)
 498 fi
 499
 500 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
 501   [ if test "x$statfs_bavail" = "xno"
 502     then
 503         wine_cv_statfs_bavail=no
 504     else
 505         AC_TRY_COMPILE([
 506         #include <sys/types.h>
 507         #ifdef HAVE_SYS_PARAM_H
 508         # include <sys/param.h>
 509         #endif
 510         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 511         # include <sys/mount.h>
 512         #else
 513         # ifdef STATFS_DEFINED_BY_SYS_VFS
 514         #  include <sys/vfs.h>
 515         # else
 516         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 517         #   include <sys/statfs.h>
 518         #  endif
 519         # endif
 520         #endif
 521         ],[
 522                 struct statfs stfs;
 523
 524                 stfs.f_bavail++;
 525         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
 526         )
 527     fi ] )
 528 if test "$wine_cv_statfs_bavail" = "yes"
 529 then
 530   AC_DEFINE(STATFS_HAS_BAVAIL)
 531 fi
 532
 533 dnl *** check for working sigaltstack
 534 dnl glibc 2.0x defines it, but it always fails... so it is useless for us.
 535
 536 AC_CACHE_CHECK("for working sigaltstack",
 537         ac_cv_c_working_sigaltstack,
 538         AC_TRY_RUN([
 539         #include <stdio.h>
 540         #include <time.h> /* <sys/time.h> ? bad magic without end */
 541         #include <sys/types.h>
 542         #include <sys/signal.h>
 543         #ifdef HAVE_SYS_PARAM_H
 544         # include <sys/param.h>
 545         #endif
 546         #ifdef HAVE_SYSCALL_H
 547         # include <syscall.h>
 548         #else
 549         # ifdef HAVE_SYS_SYSCALL_H
 550         #  include <sys/syscall.h>
 551         # endif
 552         #endif
 553
 554         unsigned char *xaltstack;
 555
 556         int
 557         main(int argc,char **argv) {
 558             struct sigaltstack  ss;
 559
 560             xaltstack = malloc(16384);
 561             ss.ss_sp    = xaltstack;
 562             ss.ss_size  = 16384;
 563             ss.ss_flags = 0;
 564             if (sigaltstack(&ss, NULL) < 0) {
 565                 /* this catches the glibc case */
 566                 perror("sigaltstack");
 567                 return (1); /* aka exit(1) aka fail */
 568             }
 569             /* assume it works. */
 570             return 0; /* OK */
 571         }
 572         ],
 573         ac_cv_c_working_sigaltstack="yes",
 574         ac_cv_c_working_sigaltstack="no",
 575         ac_cv_c_working_sigaltstack="no"
 576 ))
 577
 578 if test "$ac_cv_c_working_sigaltstack" = "yes"
 579 then
 580     AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
 581 fi
 582
 583
 584 dnl *** check for file descriptor passing with msg_accrights
 585
 586 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
 587  AC_TRY_COMPILE([#include <sys/types.h>
 588 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
 589                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
 590 if test "$ac_cv_c_msg_accrights" = "yes"
 591 then
 592     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS)
 593 fi
 594
 595 dnl **** Generate output files ****
 596
 597 MAKE_RULES=Make.rules
 598 AC_SUBST_FILE(MAKE_RULES)
 599
 600 AC_OUTPUT([
 601 Make.rules
 602 Makefile
 603 console/Makefile
 604 controls/Makefile
 605 debugger/Makefile
 606 dlls/Makefile
 607 dlls/advapi32/Makefile
 608 dlls/comctl32/Makefile
 609 dlls/imagehlp/Makefile
 610 dlls/msacm/Makefile
 611 dlls/msacm32/Makefile
 612 dlls/ntdll/Makefile
 613 dlls/psapi/Makefile
 614 dlls/rasapi32/Makefile
 615 dlls/shell32/Makefile
 616 dlls/ver/Makefile
 617 dlls/version/Makefile
 618 dlls/winaspi/Makefile
 619 dlls/wnaspi32/Makefile
 620 documentation/Makefile
 621 files/Makefile
 622 graphics/Makefile
 623 graphics/metafiledrv/Makefile
 624 graphics/psdrv/Makefile
 625 graphics/ttydrv/Makefile
 626 graphics/win16drv/Makefile
 627 graphics/x11drv/Makefile
 628 if1632/Makefile
 629 include/Makefile
 630 ipc/Makefile
 631 library/Makefile
 632 libtest/Makefile
 633 loader/Makefile
 634 loader/ne/Makefile
 635 loader/dos/Makefile
 636 memory/Makefile
 637 misc/Makefile
 638 miscemu/Makefile
 639 msdos/Makefile
 640 multimedia/Makefile
 641 objects/Makefile
 642 ole/Makefile
 643 programs/Makefile
 644 programs/clock/Makefile
 645 programs/cmdlgtst/Makefile
 646 programs/control/Makefile
 647 programs/avitools/Makefile
 648 programs/notepad/Makefile
 649 programs/progman/Makefile
 650 programs/regtest/Makefile
 651 programs/view/Makefile
 652 programs/winhelp/Makefile
 653 programs/winver/Makefile
 654 rc/Makefile
 655 relay32/Makefile
 656 resources/Makefile
 657 scheduler/Makefile
 658 server/Makefile
 659 tools/Makefile
 660 tools/wrc/Makefile
 661 tsx11/Makefile
 662 win32/Makefile
 663 windows/Makefile
 664 windows/ttydrv/Makefile
 665 windows/x11drv/Makefile ])
 666
 667 if test "$have_x" = "no"
 668 then
 669   echo
 670   echo "*** Warning: X development files not found. Wine will be built without"
 671   echo "*** X support, which currently does not work, and would probably not be"
 672   echo "*** what you want anyway. You will need to install devel packages of"
 673   echo "*** Xlib/Xfree86 and Xpm at the very least."
 674 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
 675 then
 676   echo
 677   echo "*** Warning: Xpm development files not found. Wine will be built without"
 678   echo "*** Xpm support, which currently does not work. You will need to install"
 679   echo "*** devel packages of Xpm."
 680 fi
 681
 682 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
 683 then
 684   echo
 685   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
 686   echo "*** terminal resize support. Consider upgrading ncurses."
 687 fi
 688
 689 if test "$wine_cv_libc_reentrant" = "no"
 690 then
 691   echo
 692   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
 693   echo "*** thread support. Consider upgrading libc to a more recent"
 694   echo "*** reentrant version of libc."
 695 fi
 696
 697 echo
 698 echo "Configure finished.  Do 'make depend; make' to compile Wine."
 699 echo
 700
 701 dnl Local Variables:
 702 dnl comment-start: "dnl "
 703 dnl comment-end: ""
 704 dnl comment-start-skip: "\\bdnl\\b\\s *"
 705 dnl compile-command: "autoconf"
 706 dnl End: