configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 # We want these before the checks, so the checks can modify their values.
  10 LIBS="$LIBS -lm"
  11 test -z "$PROGEXT" && PROGEXT="" AC_SUBST(PROGEXT)
  12
  13 dnl **** Command-line arguments ****
  14
  15 dnl Default values
  16 MAIN_TARGET=emu
  17 LIB_TARGET=libwine.a
  18 ALT_LINK="-L\$(TOPOBJDIR) -lwine"
  19 TRACE_MSGS=yes  # the TRACE() macro
  20 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  21
  22 AC_ARG_ENABLE(emulator,
  23 [  --disable-emulator      build only the Wine library, not the emulator],
  24 [if test "$enableval" = "no"; then MAIN_TARGET="lib"; fi])
  25
  26 AC_ARG_ENABLE(dll,
  27 [  --enable-dll            build the Wine library as a DLL],
  28 [if test "$enableval" = "no"; then : ; else LIB_TARGET="libwine.so.1.0"; fi])
  29
  30 AC_ARG_ENABLE(lib,
  31 [  --disable-lib           build the Wine without building libwine.a],
  32 [if test "$enableval" = "no"; then ALT_LINK="\$(LIBOBJS) \$(X11OBJS)"; LIB_TARGET=""; fi])
  33
  34 dnl AC_ARG_WITH(ipc,
  35 dnl [  --enable-ipc            use inter-process communication for DDE],
  36 dnl [if test "$enableval" = "no"; then : ; else OPTIONS="-DCONFIG_IPC"; fi])
  37
  38 AC_ARG_ENABLE(debug,
  39 [  --disable-debug         compile out all debugging messages],
  40 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  41
  42 AC_ARG_ENABLE(trace,
  43 [  --disable-trace         compile out TRACE messages],
  44 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  45
  46 AC_ARG_WITH(reentrant-x,
  47 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  48
  49 AC_SUBST(MAIN_TARGET)
  50 AC_SUBST(LIB_TARGET)
  51 AC_SUBST(ALT_LINK)
  52 AC_SUBST(OPTIONS)
  53
  54 if test "$DEBUG_MSGS" = "no"
  55 then
  56     AC_DEFINE(NO_DEBUG_MSGS)
  57     AC_DEFINE(NO_TRACE_MSGS)
  58 else
  59     if test "$TRACE_MSGS" = "no"
  60     then
  61         AC_DEFINE(NO_TRACE_MSGS)
  62     fi
  63 fi
  64
  65 dnl **** Check for some programs ****
  66
  67 AC_PROG_MAKE_SET
  68 AC_PROG_CC
  69 AC_PROG_CPP
  70 AC_PATH_XTRA
  71 AC_PROG_YACC
  72 AC_PROG_LEX
  73 AC_PROG_RANLIB
  74 AC_PROG_INSTALL
  75 AC_PROG_LN_S
  76 AC_CHECK_PROG(C2MAN,c2man,c2man,true)
  77
  78 dnl **** Check for some libraries ****
  79
  80 dnl Check for -li386 for NetBSD and OpenBSD
  81 AC_CHECK_LIB(i386,i386_set_ldt)
  82 dnl Check for -lossaudio for NetBSD
  83 AC_CHECK_LIB(ossaudio,_oss_ioctl)
  84 dnl Check for -lw for Solaris
  85 AC_CHECK_LIB(w,iswalnum)
  86 dnl Check for -lnsl for Solaris
  87 AC_CHECK_FUNCS(gethostbyname)
  88 if test "$ac_cv_func_gethostbyname" = "no"
  89 then
  90     AC_CHECK_LIB(nsl,gethostbyname)
  91 fi
  92 dnl Check for -lxpg4 for FreeBSD
  93 AC_CHECK_LIB(xpg4,setrunelocale)
  94 dnl Check for -ldl
  95 AC_CHECK_LIB(dl,dlopen)
  96 AC_SUBST(XLIB)
  97 if test "$have_x" = "yes"
  98 then
  99     XLIB="-lXext -lX11"
 100
 101     dnl Check for -lXpm
 102     AC_CHECK_HEADERS(X11/xpm.h)
 103     if test "$ac_cv_header_X11_xpm_h" = "yes"
 104     then
 105         AC_CHECK_LIB(Xpm,XpmCreatePixmapFromData,AC_DEFINE(HAVE_LIBXXPM) X_PRE_LIBS="$X_PRE_LIBS -lXpm",,$X_LIBS -lXext -lX11)
 106     fi
 107
 108     dnl Check for X Shm extension
 109     AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/XShm.h)
 110     if test "$ac_cv_header_X11_Xlib_h" = "yes" -a "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 111     then
 112         AC_CHECK_LIB(Xext,XShmQueryExtension,AC_DEFINE(HAVE_LIBXXSHM),,$X_LIBS -lXext -lX11)
 113     fi
 114     dnl Check for XFree86 DGA extension
 115     AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/xf86dga.h)
 116     if test "$ac_cv_header_X11_Xlib_h" = "yes" -a "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 117     then
 118          AC_CHECK_LIB(Xxf86dga,XF86DGAQueryExtension,AC_DEFINE(HAVE_LIBXXF86DGA) X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga",,$X_LIBS -lXext -lX11)
 119     fi
 120
 121     dnl Check for XFree86 VMODE extension
 122     AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/xf86vmode.h)
 123     if test "$ac_cv_header_X11_Xlib_h" = "yes" -a "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 124     then
 125         AC_CHECK_LIB(Xxf86vm,XF86VidModeQueryExtension,AC_DEFINE(HAVE_LIBXXF86VM) X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm",,$X_LIBS -lXext -lX11)
 126     fi
 127     dnl Check for the presence of Mesa
 128     AC_CHECK_HEADERS(GL/gl.h GL/osmesa.h)
 129     if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_osmesa_h" = "yes"
 130     then
 131         AC_CHECK_LIB(MesaGL,OSMesaCreateContext,AC_DEFINE(HAVE_LIBMESAGL) X_PRE_LIBS="$X_PRE_LIBS -lMesaGL",,$X_LIBS -lXext -lX11 -lm)
 132     fi
 133 else
 134     XLIB=""
 135     X_CFLAGS=""
 136     X_LIBS=""
 137 fi
 138
 139 dnl **** Check which curses lib to use ***
 140 AC_CHECK_HEADERS(ncurses.h)
 141 if test "$ac_cv_header_ncurses_h" = "yes"
 142 then
 143     AC_CHECK_LIB(ncurses,waddch)
 144 fi
 145 if test "$ac_cv_lib_ncurses_waddch" = "yes"
 146 then
 147     AC_CHECK_LIB(ncurses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 148 else
 149     AC_CHECK_HEADERS(curses.h)
 150     if test "$ac_cv_header_curses_h" = "yes"
 151     then
 152        AC_CHECK_LIB(curses,waddch)
 153        AC_CHECK_LIB(curses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 154     fi
 155 fi
 156
 157 dnl **** Check for IPX (currently Linux only) ****
 158 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
 159  AC_TRY_COMPILE(
 160    [#include <sys/socket.h>
 161     #include <netipx/ipx.h>],
 162    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 163    [AC_DEFINE(HAVE_IPX_GNU)
 164     ac_cv_c_ipx_gnu="yes"],
 165    [ac_cv_c_ipx_gnu="no"])
 166  )
 167
 168 if test "$ac_cv_c_ipx_gnu" = "no"
 169 then
 170  AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
 171   AC_TRY_COMPILE(
 172     [#include <sys/socket.h>
 173      #include <asm/types.h>
 174      #include <linux/ipx.h>],
 175     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 176     [AC_DEFINE(HAVE_IPX_LINUX)
 177      ac_cv_c_ipx_linux="yes"],
 178     [ac_cv_c_ipx_linux="no"])
 179   )
 180 fi
 181
 182 dnl **** Check for Open Sound System ****
 183 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 184
 185 AC_CACHE_CHECK("for Open Sound System",
 186         ac_cv_c_opensoundsystem,
 187         AC_TRY_COMPILE([
 188         #if defined(HAVE_SYS_SOUNDCARD_H)
 189                 #include <sys/soundcard.h>
 190         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 191                 #include <machine/soundcard.h>
 192         #elif defined(HAVE_SOUNDCARD_H)
 193                 #include <soundcard.h>
 194         #endif
 195         ],[
 196
 197 /* check for one of the Open Sound System specific SNDCTL_ defines */
 198 #if !defined(SNDCTL_DSP_STEREO)
 199 #error No open sound system
 200 #endif
 201 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 202
 203 if test "$ac_cv_c_opensoundsystem" = "yes"
 204 then
 205     AC_DEFINE(HAVE_OSS)
 206 fi
 207
 208 dnl **** Check for union semun ****
 209
 210 AC_CACHE_CHECK("for union semun", ac_cv_c_union_semun,
 211  AC_TRY_COMPILE([#include <sys/types.h>
 212 #include <sys/sem.h>],[union semun foo],
 213                 ac_cv_c_union_semun="yes", ac_cv_c_union_semun="no"))
 214 if test "$ac_cv_c_union_semun" = "yes"
 215 then
 216     AC_DEFINE(HAVE_UNION_SEMUN)
 217 fi
 218
 219 dnl **** If ln -s doesn't work, use cp instead ****
 220 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 221
 222 dnl **** Check for gcc strength-reduce bug ****
 223
 224 if test "x${GCC}" = "xyes"
 225 then
 226   CFLAGS="$CFLAGS -Wall"
 227   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
 228                   AC_TRY_RUN([
 229 int main(void) {
 230   static int Array[[3]];
 231   unsigned int B = 3;
 232   int i;
 233   for(i=0; i<B; i++) Array[[i]] = i - 3;
 234   exit( Array[[1]] != -2 );
 235 }],
 236     ac_cv_c_gcc_strength_bug="no",
 237     ac_cv_c_gcc_strength_bug="yes",
 238     ac_cv_c_gcc_strength_bug="yes") )
 239   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 240   then
 241     CFLAGS="$CFLAGS -fno-strength-reduce"
 242   fi
 243 fi
 244
 245 dnl **** Check for underscore on external symbols ****
 246
 247 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
 248                ac_cv_c_extern_prefix,
 249 [saved_libs=$LIBS
 250 LIBS="conftest_asm.s $LIBS"
 251 cat > conftest_asm.s <<EOF
 252         .globl _ac_test
 253 _ac_test:
 254         .long 0
 255 EOF
 256 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 257             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 258 LIBS=$saved_libs])
 259 if test "$ac_cv_c_extern_prefix" = "yes"
 260 then
 261   AC_DEFINE(NEED_UNDERSCORE_PREFIX)
 262 fi
 263
 264 dnl **** Check for .string in assembler ****
 265
 266 AC_CACHE_CHECK("whether assembler accepts .string",
 267                ac_cv_c_asm_string,
 268 [saved_libs=$LIBS
 269 LIBS="conftest_asm.s $LIBS"
 270 cat > conftest_asm.s <<EOF
 271         .string "test"
 272 EOF
 273 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 274 LIBS=$saved_libs])
 275 if test "$ac_cv_c_asm_string" = "yes"
 276 then
 277   AC_DEFINE(HAVE_ASM_STRING)
 278 fi
 279
 280 dnl **** Check for working dll ****
 281
 282 DLLFLAGS=""
 283 LDSHARED=""
 284 if test "$LIB_TARGET" = "libwine.so.1.0"
 285 then
 286   AC_CACHE_CHECK("whether we can build a Linux dll",
 287                  ac_cv_c_dll_linux,
 288   [saved_cflags=$CFLAGS
 289   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0"
 290   AC_TRY_LINK(,[return 1],ac_cv_c_dll_linux="yes",ac_cv_c_dll_linux="no")
 291   CFLAGS=$saved_cflags
 292   ])
 293   if test "$ac_cv_c_dll_linux" = "yes"
 294   then
 295     DLLFLAGS="-fPIC"
 296     LDSHARED="\$(CC) -shared -Wl,-soname,libwine.so"
 297   else
 298     AC_CACHE_CHECK("whether we can build a NetBSD dll",
 299                    ac_cv_c_dll_netbsd,
 300     [saved_cflags=$CFLAGS
 301     CFLAGS="$CFLAGS -fPIC -Bshareable -Bforcearchive"
 302     AC_TRY_LINK(,[return 1],ac_cv_c_dll_netbsd="yes",ac_cv_c_dll_netbsd="no")
 303     CFLAGS=$saved_cflags
 304     ])
 305     if test "$ac_cv_c_dll_netbsd" = "yes"
 306     then
 307       DLLFLAGS="-fPIC"
 308       LDSHARED="ld -Bshareable -Bforcearchive"
 309     fi
 310   fi
 311   if test "$ac_cv_c_dll_linux" = "no" -a "$ac_cv_c_dll_netbsd" = "no"
 312   then
 313     LIB_TARGET="libwine.a"
 314   fi
 315 fi
 316 AC_SUBST(DLLFLAGS)
 317 AC_SUBST(LDSHARED)
 318
 319 dnl **** Check for reentrant libc ****
 320 dnl
 321 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 322 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 323
 324 AC_CACHE_CHECK("for reentrant libc", wine_cv_libc_reentrant,
 325   [AC_TRY_RUN([int myerrno = 0;
 326 char buf[256];
 327 int *__errno_location(){return &myerrno;}
 328 main(){connect(0,buf,255); exit(!myerrno);}],
 329   wine_cv_libc_reentrant=yes, wine_cv_libc_reentrant=no,
 330   wine_cv_libc_reentrant=yes ) ] )
 331 if test "$wine_cv_libc_reentrant" = "no"
 332 then
 333   AC_DEFINE(NO_REENTRANT_LIBC)
 334 fi
 335
 336 dnl **** Check for reentrant X libraries ****
 337 dnl
 338 dnl This may fail to determine whether X libraries are reentrant if
 339 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 340 dnl is possible with the --without-reentrant-x option.
 341
 342 if test "$have_x" = "yes"
 343 then
 344 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
 345   [ if test "x$with_reentrant_x" = "xno"
 346     then
 347         wine_cv_x_reentrant=no
 348     else
 349         libX11_ckeck=none
 350         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 351             if test -r $dir/libX11.so; then
 352                 libX11_check="-D $dir/libX11.so"
 353                 break 1
 354             fi
 355             if test -r $dir/libX11.a; then
 356                 libX11_check="$dir/libX11.a"
 357                 break 1
 358             fi
 359         done
 360         if test "$libX11_check" != "none"; then
 361             if nm $libX11_check | grep __errno_location >/dev/null 2>&1
 362             then
 363                 wine_cv_x_reentrant=yes
 364             else
 365                 wine_cv_x_reentrant=no
 366             fi
 367         else
 368             wine_cv_x_reentrant=unknown
 369         fi
 370     fi ] )
 371 else
 372     wine_cv_x_reentrant=no
 373 fi
 374 if test "$wine_cv_x_reentrant" = "no"
 375 then
 376   AC_DEFINE(NO_REENTRANT_X11)
 377 fi
 378
 379 dnl **** Check for functions and header files ****
 380
 381 AC_CHECK_FUNCS(clone getpagesize memmove sendmsg sigaltstack strerror stricmp tcgetattr timegm usleep wait4 waitpid vfscanf)
 382 AC_CHECK_HEADERS(wctype.h sys/syscall.h syscall.h sys/param.h sys/vfs.h sys/mount.h sys/statfs.h float.h linux/cdrom.h linux/ucdrom.h sys/cdio.h sys/filio.h sys/modem.h strings.h sys/strtio.h dlfcn.h unistd.h sys/sockio.h net/if.h netinet/in.h sys/file.h libio.h curses.h ncurses.h elf.h)
 383 AC_HEADER_STAT()
 384 AC_C_CONST()
 385 AC_TYPE_SIZE_T()
 386 AC_CHECK_SIZEOF(long long,0)
 387
 388 dnl **** Check for sendmsg in -lsocket if not found above ****
 389
 390 if test $ac_cv_func_sendmsg = no; then
 391     AC_CHECK_LIB(socket,sendmsg)
 392 fi
 393
 394 dnl **** statfs checks ****
 395
 396 if test "$ac_cv_header_sys_vfs_h" = "yes"
 397 then
 398     AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
 399                     wine_cv_sys_vfs_has_statfs,
 400         AC_TRY_COMPILE([
 401         #include <sys/types.h>
 402         #ifdef HAVE_SYS_PARAM_H
 403         # include <sys/param.h>
 404         #endif
 405         #include <sys/vfs.h>
 406         ],[
 407                 struct statfs stfs;
 408
 409                 memset(&stfs,0,sizeof(stfs));
 410         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
 411         )
 412     )
 413     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
 414     then
 415       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS)
 416     fi
 417 fi
 418
 419 if test "$ac_cv_header_sys_statfs_h" = "yes"
 420 then
 421     AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
 422                     wine_cv_sys_statfs_has_statfs,
 423         AC_TRY_COMPILE([
 424         #include <sys/types.h>
 425         #ifdef HAVE_SYS_PARAM_H
 426         # include <sys/param.h>
 427         #endif
 428         #include <sys/statfs.h>
 429         ],[
 430                 struct statfs stfs;
 431         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
 432         )
 433     )
 434     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
 435     then
 436       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS)
 437     fi
 438 fi
 439
 440 if test "$ac_cv_header_sys_mount_h" = "yes"
 441 then
 442     AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
 443                     wine_cv_sys_mount_has_statfs,
 444         AC_TRY_COMPILE([
 445         #include <sys/types.h>
 446         #ifdef HAVE_SYS_PARAM_H
 447         # include <sys/param.h>
 448         #endif
 449         #include <sys/mount.h>
 450         ],[
 451                 struct statfs stfs;
 452         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
 453         )
 454     )
 455     if test "$wine_cv_sys_mount_has_statfs" = "yes"
 456     then
 457       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT)
 458     fi
 459 fi
 460
 461 dnl **** FIXME: what about mixed cases, where we need two of them? ***
 462
 463 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
 464   [ if test "x$statfs_bfree" = "xno"
 465     then
 466         wine_cv_statfs_bfree=no
 467     else
 468         AC_TRY_COMPILE([
 469         #include <sys/types.h>
 470         #ifdef HAVE_SYS_PARAM_H
 471         # include <sys/param.h>
 472         #endif
 473         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 474         # include <sys/mount.h>
 475         #else
 476         # ifdef STATFS_DEFINED_BY_SYS_VFS
 477         #  include <sys/vfs.h>
 478         # else
 479         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 480         #   include <sys/statfs.h>
 481         #  endif
 482         # endif
 483         #endif
 484         ],[
 485                 struct statfs stfs;
 486
 487                 stfs.f_bfree++;
 488         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
 489         )
 490     fi ] )
 491 if test "$wine_cv_statfs_bfree" = "yes"
 492 then
 493   AC_DEFINE(STATFS_HAS_BFREE)
 494 fi
 495
 496 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
 497   [ if test "x$statfs_bavail" = "xno"
 498     then
 499         wine_cv_statfs_bavail=no
 500     else
 501         AC_TRY_COMPILE([
 502         #include <sys/types.h>
 503         #ifdef HAVE_SYS_PARAM_H
 504         # include <sys/param.h>
 505         #endif
 506         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 507         # include <sys/mount.h>
 508         #else
 509         # ifdef STATFS_DEFINED_BY_SYS_VFS
 510         #  include <sys/vfs.h>
 511         # else
 512         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 513         #   include <sys/statfs.h>
 514         #  endif
 515         # endif
 516         #endif
 517         ],[
 518                 struct statfs stfs;
 519
 520                 stfs.f_bavail++;
 521         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
 522         )
 523     fi ] )
 524 if test "$wine_cv_statfs_bavail" = "yes"
 525 then
 526   AC_DEFINE(STATFS_HAS_BAVAIL)
 527 fi
 528
 529 dnl *** check for working sigaltstack
 530 dnl glibc 2.0x defines it, but it always fails... so it is useless for us.
 531
 532 AC_CACHE_CHECK("for working sigaltstack",
 533         ac_cv_c_working_sigaltstack,
 534         AC_TRY_RUN([
 535         #include <stdio.h>
 536         #include <time.h> /* <sys/time.h> ? bad magic without end */
 537         #include <sys/types.h>
 538         #include <sys/signal.h>
 539         #ifdef HAVE_SYS_PARAM_H
 540         # include <sys/param.h>
 541         #endif
 542         #ifdef HAVE_SYSCALL_H
 543         # include <syscall.h>
 544         #else
 545         # ifdef HAVE_SYS_SYSCALL_H
 546         #  include <sys/syscall.h>
 547         # endif
 548         #endif
 549
 550         unsigned char *xaltstack;
 551
 552         int
 553         main(int argc,char **argv) {
 554             struct sigaltstack  ss;
 555
 556             xaltstack = malloc(16384);
 557             ss.ss_sp    = xaltstack;
 558             ss.ss_size  = 16384;
 559             ss.ss_flags = 0;
 560             if (sigaltstack(&ss, NULL) < 0) {
 561                 /* this catches the glibc case */
 562                 perror("sigaltstack");
 563                 return (1); /* aka exit(1) aka fail */
 564             }
 565             /* assume it works. */
 566             return 0; /* OK */
 567         }
 568         ],
 569         ac_cv_c_working_sigaltstack="yes",
 570         ac_cv_c_working_sigaltstack="no",
 571         ac_cv_c_working_sigaltstack="no"
 572 ))
 573
 574 if test "$ac_cv_c_working_sigaltstack" = "yes"
 575 then
 576     AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
 577 fi
 578
 579
 580 dnl *** check for file descriptor passing with msg_accrights
 581
 582 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
 583  AC_TRY_COMPILE([#include <sys/types.h>
 584 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
 585                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
 586 if test "$ac_cv_c_msg_accrights" = "yes"
 587 then
 588     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS)
 589 fi
 590
 591 dnl **** Generate output files ****
 592
 593 MAKE_RULES=Make.rules
 594 AC_SUBST_FILE(MAKE_RULES)
 595
 596 AC_OUTPUT([
 597 Make.rules
 598 Makefile
 599 console/Makefile
 600 controls/Makefile
 601 debugger/Makefile
 602 dlls/Makefile
 603 dlls/advapi32/Makefile
 604 dlls/comctl32/Makefile
 605 dlls/imagehlp/Makefile
 606 dlls/msacm/Makefile
 607 dlls/msacm32/Makefile
 608 dlls/ntdll/Makefile
 609 dlls/psapi/Makefile
 610 dlls/rasapi32/Makefile
 611 dlls/shell32/Makefile
 612 dlls/ver/Makefile
 613 dlls/version/Makefile
 614 dlls/winaspi/Makefile
 615 dlls/wnaspi32/Makefile
 616 documentation/Makefile
 617 files/Makefile
 618 graphics/Makefile
 619 graphics/metafiledrv/Makefile
 620 graphics/psdrv/Makefile
 621 graphics/ttydrv/Makefile
 622 graphics/win16drv/Makefile
 623 graphics/x11drv/Makefile
 624 if1632/Makefile
 625 ipc/Makefile
 626 library/Makefile
 627 libtest/Makefile
 628 loader/Makefile
 629 loader/ne/Makefile
 630 loader/dos/Makefile
 631 memory/Makefile
 632 misc/Makefile
 633 miscemu/Makefile
 634 msdos/Makefile
 635 multimedia/Makefile
 636 objects/Makefile
 637 ole/Makefile
 638 programs/Makefile
 639 programs/clock/Makefile
 640 programs/cmdlgtst/Makefile
 641 programs/control/Makefile
 642 programs/avitools/Makefile
 643 programs/notepad/Makefile
 644 programs/progman/Makefile
 645 programs/regtest/Makefile
 646 programs/view/Makefile
 647 programs/winhelp/Makefile
 648 programs/winver/Makefile
 649 rc/Makefile
 650 relay32/Makefile
 651 resources/Makefile
 652 scheduler/Makefile
 653 server/Makefile
 654 tools/Makefile
 655 tools/wrc/Makefile
 656 tsx11/Makefile
 657 win32/Makefile
 658 windows/Makefile
 659 windows/ttydrv/Makefile
 660 windows/x11drv/Makefile ])
 661
 662 if test "$have_x" = "no"
 663 then
 664   echo
 665   echo "*** Warning: X development files not found. Wine will be built without"
 666   echo "*** X support, which currently does not work, and would probably not be"
 667   echo "*** what you want anyway. You will need to install devel packages of"
 668   echo "*** Xlib/Xfree86 and Xpm at the very least."
 669 fi
 670
 671 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
 672 then
 673   echo
 674   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
 675   echo "*** terminal resize support. Consider upgrading ncurses."
 676 fi
 677
 678 if test "$wine_cv_libc_reentrant" = "no"
 679 then
 680   echo
 681   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
 682   echo "*** thread support. Consider upgrading libc to a more recent"
 683   echo "*** reentrant version of libc."
 684 fi
 685
 686 echo
 687 echo "Configure finished.  Do 'make depend; make' to compile Wine."
 688 echo
 689
 690 dnl Local Variables:
 691 dnl comment-start: "dnl "
 692 dnl comment-end: ""
 693 dnl comment-start-skip: "\\bdnl\\b\\s *"
 694 dnl compile-command: "autoconf"
 695 dnl End: