debugger/dbg.y

   1 %{
   2 /*
   3  * Parser for command lines in the Wine debugger
   4  *
   5  * Copyright 1993 Eric Youngdale
   6  * Copyright 1995 Morten Welinder
   7  * Copyright 2000 Eric Pouech
   8  *
   9  * This library is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU Lesser General Public
  11  * License as published by the Free Software Foundation; either
  12  * version 2.1 of the License, or (at your option) any later version.
  13  *
  14  * This library is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17  * Lesser General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU Lesser General Public
  20  * License along with this library; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  22  */
  23
  24 #include "config.h"
  25
  26 #include <stdio.h>
  27 #include <stdlib.h>
  28 #include <string.h>
  29 #include <signal.h>
  30 #include <unistd.h>
  31
  32 #include "wine/exception.h"
  33 #include "debugger.h"
  34 #include "expr.h"
  35 #include "msvcrt/excpt.h"
  36
  37 extern FILE * yyin;
  38
  39 static void mode_command(int);
  40 int yylex(void);
  41 int yyerror(char *);
  42
  43 %}
  44
  45 %union
  46 {
  47     DBG_VALUE        value;
  48     char *           string;
  49     int              integer;
  50     struct list_id   listing;
  51     struct expr *    expression;
  52     struct datatype* type;
  53 }
  54
  55 %token tCONT tPASS tSTEP tLIST tNEXT tQUIT tHELP tBACKTRACE tINFO tWALK tUP tDOWN
  56 %token tENABLE tDISABLE tBREAK tWATCH tDELETE tSET tMODE tPRINT tEXAM tABORT tVM86
  57 %token tCLASS tMAPS tMODULE tSTACK tSEGMENTS tREGS tWND tQUEUE tLOCAL
  58 %token tPROCESS tTHREAD tMODREF tEOL
  59 %token tFRAME tSHARE tCOND tDISPLAY tUNDISPLAY tDISASSEMBLE
  60 %token tSTEPI tNEXTI tFINISH tSHOW tDIR tWHATIS
  61 %token <string> tPATH
  62 %token <string> tIDENTIFIER tSTRING tDEBUGSTR tINTVAR
  63 %token <integer> tNUM tFORMAT
  64 %token tSYMBOLFILE tRUN tATTACH tDETACH tNOPROCESS
  65
  66 %token tCHAR tSHORT tINT tLONG tFLOAT tDOUBLE tUNSIGNED tSIGNED
  67 %token tSTRUCT tUNION tENUM
  68
  69 /* %left ',' */
  70 /* %left '=' OP_OR_EQUAL OP_XOR_EQUAL OP_AND_EQUAL OP_SHL_EQUAL \
  71          OP_SHR_EQUAL OP_PLUS_EQUAL OP_MINUS_EQUAL \
  72          OP_TIMES_EQUAL OP_DIVIDE_EQUAL OP_MODULO_EQUAL */
  73 /* %left OP_COND */ /* ... ? ... : ... */
  74 %left OP_LOR
  75 %left OP_LAND
  76 %left '|'
  77 %left '^'
  78 %left '&'
  79 %left OP_EQ OP_NE
  80 %left '<' '>' OP_LE OP_GE
  81 %left OP_SHL OP_SHR
  82 %left '+' '-'
  83 %left '*' '/' '%'
  84 %left OP_SIGN '!' '~' OP_DEREF /* OP_INC OP_DEC OP_ADDR */
  85 %left '.' '[' OP_DRF
  86 %nonassoc ':'
  87
  88 %type <expression> expr lval lvalue
  89 %type <type> type_cast type_expr
  90 %type <value> expr_addr lval_addr
  91 %type <integer> expr_value
  92 %type <string> pathname identifier
  93
  94 %type <listing> list_arg
  95
  96 %%
  97
  98 input: line
  99     | input line
 100
 101 line: command
 102     | tEOL
 103     | error tEOL                { yyerrok; }
 104
 105 command:
 106       tQUIT tEOL                { DEBUG_ExitMode = EXIT_QUIT; return 1; }
 107     | tHELP tEOL                { DEBUG_Help(); }
 108     | tHELP tINFO tEOL          { DEBUG_HelpInfo(); }
 109     | tCONT tEOL                { DEBUG_CurrThread->exec_count = 1;
 110                                   DEBUG_CurrThread->exec_mode = EXEC_CONT; return 1; }
 111     | tPASS tEOL                { DEBUG_ExitMode = EXIT_PASS; return 1; }
 112     | tCONT tNUM tEOL           { DEBUG_CurrThread->exec_count = $2;
 113                                   DEBUG_CurrThread->exec_mode = EXEC_CONT; return 1; }
 114     | tSTEP tEOL                { DEBUG_CurrThread->exec_count = 1;
 115                                   DEBUG_CurrThread->exec_mode = EXEC_STEP_INSTR; return 1; }
 116     | tNEXT tEOL                { DEBUG_CurrThread->exec_count = 1;
 117                                   DEBUG_CurrThread->exec_mode = EXEC_STEP_OVER; return 1; }
 118     | tSTEP tNUM tEOL           { DEBUG_CurrThread->exec_count = $2;
 119                                   DEBUG_CurrThread->exec_mode = EXEC_STEP_INSTR; return 1; }
 120     | tNEXT tNUM tEOL           { DEBUG_CurrThread->exec_count = $2;
 121                                   DEBUG_CurrThread->exec_mode = EXEC_STEP_OVER; return 1; }
 122     | tSTEPI tEOL               { DEBUG_CurrThread->exec_count = 1;
 123                                   DEBUG_CurrThread->exec_mode = EXEC_STEPI_INSTR; return 1; }
 124     | tNEXTI tEOL               { DEBUG_CurrThread->exec_count = 1;
 125                                   DEBUG_CurrThread->exec_mode = EXEC_STEPI_OVER; return 1; }
 126     | tSTEPI tNUM tEOL          { DEBUG_CurrThread->exec_count = $2;
 127                                   DEBUG_CurrThread->exec_mode = EXEC_STEPI_INSTR; return 1; }
 128     | tNEXTI tNUM tEOL          { DEBUG_CurrThread->exec_count = $2;
 129                                   DEBUG_CurrThread->exec_mode = EXEC_STEPI_OVER; return 1; }
 130     | tABORT tEOL               { kill(getpid(), SIGABRT); }
 131     | tMODE tNUM tEOL           { mode_command($2); }
 132     | tMODE tVM86 tEOL          { DEBUG_CurrThread->dbg_mode = MODE_VM86; }
 133     | tENABLE tNUM tEOL         { DEBUG_EnableBreakpoint( $2, TRUE ); }
 134     | tDISABLE tNUM tEOL        { DEBUG_EnableBreakpoint( $2, FALSE ); }
 135     | tDELETE tBREAK tNUM tEOL  { DEBUG_DelBreakpoint( $3 ); }
 136     | tBACKTRACE tEOL           { DEBUG_BackTrace(DEBUG_CurrTid, TRUE); }
 137     | tBACKTRACE tNUM tEOL      { DEBUG_BackTrace($2, TRUE); }
 138     | tUP tEOL                  { DEBUG_SetFrame( curr_frame + 1 );  }
 139     | tUP tNUM tEOL             { DEBUG_SetFrame( curr_frame + $2 ); }
 140     | tDOWN tEOL                { DEBUG_SetFrame( curr_frame - 1 );  }
 141     | tDOWN tNUM tEOL           { DEBUG_SetFrame( curr_frame - $2 ); }
 142     | tFRAME tNUM tEOL          { DEBUG_SetFrame( $2 ); }
 143     | tFINISH tEOL              { DEBUG_CurrThread->exec_count = 0;
 144                                   DEBUG_CurrThread->exec_mode = EXEC_FINISH; return 1; }
 145     | tSHOW tDIR tEOL           { DEBUG_ShowDir(); }
 146     | tDIR pathname tEOL        { DEBUG_AddPath( $2 ); }
 147     | tDIR tEOL                 { DEBUG_NukePath(); }
 148     | tDISPLAY tEOL             { DEBUG_InfoDisplay(); }
 149     | tDISPLAY expr tEOL        { DEBUG_AddDisplay($2, 1, 0); }
 150     | tDISPLAY tFORMAT expr tEOL{ DEBUG_AddDisplay($3, $2 >> 8, $2 & 0xff); }
 151     | tDELETE tDISPLAY tNUM tEOL{ DEBUG_DelDisplay( $3 ); }
 152     | tDELETE tDISPLAY tEOL     { DEBUG_DelDisplay( -1 ); }
 153     | tUNDISPLAY tNUM tEOL      { DEBUG_DelDisplay( $2 ); }
 154     | tUNDISPLAY tEOL           { DEBUG_DelDisplay( -1 ); }
 155     | tCOND tNUM tEOL           { DEBUG_AddBPCondition($2, NULL); }
 156     | tCOND tNUM expr tEOL      { DEBUG_AddBPCondition($2, $3); }
 157     | tSYMBOLFILE pathname tEOL { DEBUG_ReadSymbolTable($2); }
 158     | tWHATIS expr_addr tEOL    { DEBUG_PrintType(&$2); DEBUG_FreeExprMem(); }
 159     | tATTACH tNUM tEOL         { if (DEBUG_Attach($2, FALSE)) return 1; }
 160     | tDETACH tEOL              { DEBUG_ExitMode = EXIT_DETACH; return 1; }
 161     | list_command
 162     | disassemble_command
 163     | set_command
 164     | x_command
 165     | print_command
 166     | break_command
 167     | watch_command
 168     | info_command
 169     | walk_command
 170     | run_command
 171     | noprocess_state
 172
 173 set_command:
 174       tSET lval_addr '=' expr_value tEOL   { DEBUG_WriteMemory( &$2, $4 );
 175                                              DEBUG_FreeExprMem(); }
 176
 177 pathname:
 178       tIDENTIFIER              { $$ = $1; }
 179     | tPATH                    { $$ = $1; }
 180
 181 disassemble_command:
 182       tDISASSEMBLE tEOL              { DEBUG_Disassemble( NULL, NULL, 10 ); }
 183     | tDISASSEMBLE expr_addr tEOL    { DEBUG_Disassemble( & $2, NULL, 10 ); }
 184     | tDISASSEMBLE expr_addr ',' expr_addr tEOL { DEBUG_Disassemble( & $2, & $4, 0 ); }
 185
 186 list_command:
 187       tLIST tEOL               { DEBUG_List( NULL, NULL, 10 ); }
 188     | tLIST '-' tEOL           { DEBUG_List( NULL, NULL, -10 ); }
 189     | tLIST list_arg tEOL      { DEBUG_List( & $2, NULL, 10 ); }
 190     | tLIST ',' list_arg tEOL  { DEBUG_List( NULL, & $3, -10 ); }
 191     | tLIST list_arg ',' list_arg tEOL { DEBUG_List( & $2, & $4, 0 ); }
 192
 193 list_arg:
 194       tNUM                     { $$.sourcefile = NULL; $$.line = $1; }
 195     | pathname ':' tNUM        { $$.sourcefile = $1; $$.line = $3; }
 196     | tIDENTIFIER              { DEBUG_GetFuncInfo( & $$, NULL, $1); }
 197     | pathname ':' tIDENTIFIER { DEBUG_GetFuncInfo( & $$, $1, $3); }
 198     | '*' expr_addr            { DEBUG_FindNearestSymbol( & $2.addr, FALSE, NULL, 0, & $$ );
 199                                  DEBUG_FreeExprMem(); }
 200
 201 x_command:
 202       tEXAM expr_addr tEOL     { DEBUG_ExamineMemory( &$2, 1, 'x'); DEBUG_FreeExprMem(); }
 203     | tEXAM tFORMAT expr_addr tEOL  { DEBUG_ExamineMemory( &$3, $2>>8, $2&0xff );
 204                                       DEBUG_FreeExprMem(); }
 205
 206 print_command:
 207       tPRINT expr_addr tEOL    { DEBUG_Print( &$2, 1, 0, 0 ); DEBUG_FreeExprMem(); }
 208     | tPRINT tFORMAT expr_addr tEOL { DEBUG_Print( &$3, $2 >> 8, $2 & 0xff, 0 );
 209                                       DEBUG_FreeExprMem(); }
 210
 211 break_command:
 212       tBREAK '*' expr_addr tEOL{ DEBUG_AddBreakpoint( &$3, NULL ); DEBUG_FreeExprMem(); }
 213     | tBREAK identifier tEOL   { DEBUG_AddBreakpointFromId($2, -1); }
 214     | tBREAK identifier ':' tNUM tEOL  { DEBUG_AddBreakpointFromId($2, $4); }
 215     | tBREAK tNUM tEOL         { DEBUG_AddBreakpointFromLineno($2); }
 216     | tBREAK tEOL              { DEBUG_AddBreakpointFromLineno(-1); }
 217
 218 watch_command:
 219       tWATCH '*' expr_addr tEOL { DEBUG_AddWatchpoint( &$3, 1 ); DEBUG_FreeExprMem(); }
 220     | tWATCH identifier tEOL    { DEBUG_AddWatchpointFromId($2); }
 221
 222 info_command:
 223       tINFO tBREAK tEOL         { DEBUG_InfoBreakpoints(); }
 224     | tINFO tCLASS tSTRING tEOL { DEBUG_InfoClass( $3 ); }
 225     | tINFO tSHARE tEOL         { DEBUG_InfoShare(); }
 226     | tINFO tMODULE expr_value tEOL   { DEBUG_DumpModule( $3 ); DEBUG_FreeExprMem(); }
 227     | tINFO tQUEUE expr_value tEOL    { DEBUG_DumpQueue( $3 ); DEBUG_FreeExprMem(); }
 228     | tINFO tREGS tEOL          { DEBUG_InfoRegisters(); }
 229     | tINFO tSEGMENTS expr_value tEOL { DEBUG_InfoSegments( $3, 1 ); DEBUG_FreeExprMem(); }
 230     | tINFO tSEGMENTS tEOL      { DEBUG_InfoSegments( 0, -1 ); }
 231     | tINFO tSTACK tEOL         { DEBUG_InfoStack(); }
 232     | tINFO tMAPS tEOL          { DEBUG_InfoVirtual(); }
 233     | tINFO tWND expr_value tEOL{ DEBUG_InfoWindow( (HWND)$3 ); DEBUG_FreeExprMem(); }
 234     | tINFO tLOCAL tEOL         { DEBUG_InfoLocals(); }
 235     | tINFO tDISPLAY tEOL       { DEBUG_InfoDisplay(); }
 236
 237 walk_command:
 238       tWALK tCLASS tEOL         { DEBUG_WalkClasses(); }
 239     | tWALK tMODULE tEOL        { DEBUG_WalkModules(); }
 240     | tWALK tQUEUE tEOL         { DEBUG_WalkQueues(); }
 241     | tWALK tWND tEOL           { DEBUG_WalkWindows( 0, 0 ); }
 242     | tWALK tWND tNUM tEOL      { DEBUG_WalkWindows( (HWND)$3, 0 ); }
 243     | tWALK tPROCESS tEOL       { DEBUG_WalkProcess(); }
 244     | tWALK tTHREAD tEOL        { DEBUG_WalkThreads(); }
 245     | tWALK tMODREF expr_value tEOL   { DEBUG_WalkModref( $3 ); DEBUG_FreeExprMem(); }
 246
 247 run_command:
 248       tRUN tEOL                 { DEBUG_Run(NULL); }
 249     | tRUN tSTRING tEOL         { DEBUG_Run($2); }
 250
 251 noprocess_state:
 252       tNOPROCESS tEOL           {} /* <CR> shall not barf anything */
 253     | tNOPROCESS tSTRING tEOL   { DEBUG_Printf(DBG_CHN_MESG, "No process loaded, cannot execute '%s'\n", $2); }
 254
 255 type_cast:
 256       '(' type_expr ')'         { $$ = $2; }
 257
 258 type_expr:
 259       type_expr '*'             { $$ = DEBUG_FindOrMakePointerType($1); }
 260     | tINT                      { $$ = DEBUG_GetBasicType(DT_BASIC_INT); }
 261     | tCHAR                     { $$ = DEBUG_GetBasicType(DT_BASIC_CHAR); }
 262     | tLONG tINT                { $$ = DEBUG_GetBasicType(DT_BASIC_LONGINT); }
 263     | tUNSIGNED tINT            { $$ = DEBUG_GetBasicType(DT_BASIC_UINT); }
 264     | tLONG tUNSIGNED tINT      { $$ = DEBUG_GetBasicType(DT_BASIC_ULONGINT); }
 265     | tLONG tLONG tINT          { $$ = DEBUG_GetBasicType(DT_BASIC_LONGLONGINT); }
 266     | tLONG tLONG tUNSIGNED tINT{ $$ = DEBUG_GetBasicType(DT_BASIC_ULONGLONGINT); }
 267     | tSHORT tINT               { $$ = DEBUG_GetBasicType(DT_BASIC_SHORTINT); }
 268     | tSHORT tUNSIGNED tINT     { $$ = DEBUG_GetBasicType(DT_BASIC_USHORTINT); }
 269     | tSIGNED tCHAR             { $$ = DEBUG_GetBasicType(DT_BASIC_SCHAR); }
 270     | tUNSIGNED tCHAR           { $$ = DEBUG_GetBasicType(DT_BASIC_UCHAR); }
 271     | tFLOAT                    { $$ = DEBUG_GetBasicType(DT_BASIC_FLOAT); }
 272     | tDOUBLE                   { $$ = DEBUG_GetBasicType(DT_BASIC_DOUBLE); }
 273     | tLONG tDOUBLE             { $$ = DEBUG_GetBasicType(DT_BASIC_LONGDOUBLE); }
 274     | tSTRUCT tIDENTIFIER       { $$ = DEBUG_TypeCast(DT_STRUCT, $2); }
 275     | tUNION tIDENTIFIER        { $$ = DEBUG_TypeCast(DT_STRUCT, $2); }
 276     | tENUM tIDENTIFIER         { $$ = DEBUG_TypeCast(DT_ENUM, $2); }
 277
 278 expr_addr:
 279       expr                      { $$ = DEBUG_EvalExpr($1); }
 280
 281 expr_value:
 282       expr                      { DBG_VALUE     value = DEBUG_EvalExpr($1);
 283                                   /* expr_value is typed as an integer */
 284                                   $$ = DEBUG_ReadMemory(&value); }
 285
 286 /*
 287  * The expr rule builds an expression tree.  When we are done, we call
 288  * EvalExpr to evaluate the value of the expression.  The advantage of
 289  * the two-step approach is that it is possible to save expressions for
 290  * use in 'display' commands, and in conditional watchpoints.
 291  */
 292 expr:
 293       tNUM                       { $$ = DEBUG_ConstExpr($1); }
 294     | tSTRING                    { $$ = DEBUG_StringExpr($1); }
 295     | tINTVAR                    { $$ = DEBUG_IntVarExpr($1); }
 296     | tIDENTIFIER                { $$ = DEBUG_SymbolExpr($1); }
 297     | expr OP_DRF tIDENTIFIER    { $$ = DEBUG_StructPExpr($1, $3); }
 298     | expr '.' tIDENTIFIER       { $$ = DEBUG_StructExpr($1, $3); }
 299     | tIDENTIFIER '(' ')'        { $$ = DEBUG_CallExpr($1, 0); }
 300     | tIDENTIFIER '(' expr ')'   { $$ = DEBUG_CallExpr($1, 1, $3); }
 301     | tIDENTIFIER '(' expr ',' expr ')'  { $$ = DEBUG_CallExpr($1, 2, $3, $5); }
 302     | tIDENTIFIER '(' expr ',' expr ',' expr ')'         { $$ = DEBUG_CallExpr($1, 3, $3, $5, $7); }
 303     | tIDENTIFIER '(' expr ',' expr ',' expr ',' expr ')'        { $$ = DEBUG_CallExpr($1, 4, $3, $5, $7, $9); }
 304     | tIDENTIFIER '(' expr ',' expr ',' expr ',' expr ',' expr ')'       { $$ = DEBUG_CallExpr($1, 5, $3, $5, $7, $9, $11); }
 305     | expr '[' expr ']'          { $$ = DEBUG_BinopExpr(EXP_OP_ARR, $1, $3); }
 306     | expr ':' expr              { $$ = DEBUG_BinopExpr(EXP_OP_SEG, $1, $3); }
 307     | expr OP_LOR expr           { $$ = DEBUG_BinopExpr(EXP_OP_LOR, $1, $3); }
 308     | expr OP_LAND expr          { $$ = DEBUG_BinopExpr(EXP_OP_LAND, $1, $3); }
 309     | expr '|' expr              { $$ = DEBUG_BinopExpr(EXP_OP_OR, $1, $3); }
 310     | expr '&' expr              { $$ = DEBUG_BinopExpr(EXP_OP_AND, $1, $3); }
 311     | expr '^' expr              { $$ = DEBUG_BinopExpr(EXP_OP_XOR, $1, $3); }
 312     | expr OP_EQ expr            { $$ = DEBUG_BinopExpr(EXP_OP_EQ, $1, $3); }
 313     | expr '>' expr              { $$ = DEBUG_BinopExpr(EXP_OP_GT, $1, $3); }
 314     | expr '<' expr              { $$ = DEBUG_BinopExpr(EXP_OP_LT, $1, $3); }
 315     | expr OP_GE expr            { $$ = DEBUG_BinopExpr(EXP_OP_GE, $1, $3); }
 316     | expr OP_LE expr            { $$ = DEBUG_BinopExpr(EXP_OP_LE, $1, $3); }
 317     | expr OP_NE expr            { $$ = DEBUG_BinopExpr(EXP_OP_NE, $1, $3); }
 318     | expr OP_SHL expr           { $$ = DEBUG_BinopExpr(EXP_OP_SHL, $1, $3); }
 319     | expr OP_SHR expr           { $$ = DEBUG_BinopExpr(EXP_OP_SHR, $1, $3); }
 320     | expr '+' expr              { $$ = DEBUG_BinopExpr(EXP_OP_ADD, $1, $3); }
 321     | expr '-' expr              { $$ = DEBUG_BinopExpr(EXP_OP_SUB, $1, $3); }
 322     | expr '*' expr              { $$ = DEBUG_BinopExpr(EXP_OP_MUL, $1, $3); }
 323     | expr '/' expr              { $$ = DEBUG_BinopExpr(EXP_OP_DIV, $1, $3); }
 324     | expr '%' expr              { $$ = DEBUG_BinopExpr(EXP_OP_REM, $1, $3); }
 325     | '-' expr %prec OP_SIGN     { $$ = DEBUG_UnopExpr(EXP_OP_NEG, $2); }
 326     | '+' expr %prec OP_SIGN     { $$ = $2; }
 327     | '!' expr                   { $$ = DEBUG_UnopExpr(EXP_OP_NOT, $2); }
 328     | '~' expr                   { $$ = DEBUG_UnopExpr(EXP_OP_LNOT, $2); }
 329     | '(' expr ')'               { $$ = $2; }
 330     | '*' expr %prec OP_DEREF    { $$ = DEBUG_UnopExpr(EXP_OP_DEREF, $2); }
 331     | '&' expr %prec OP_DEREF    { $$ = DEBUG_UnopExpr(EXP_OP_ADDR, $2); }
 332     | type_cast expr %prec OP_DEREF { $$ = DEBUG_TypeCastExpr($1, $2); }
 333
 334 /*
 335  * The lvalue rule builds an expression tree.  This is a limited form
 336  * of expression that is suitable to be used as an lvalue.
 337  */
 338 lval_addr:
 339     lval                         { $$ = DEBUG_EvalExpr($1); }
 340
 341 lval:
 342       lvalue                     { $$ = $1; }
 343     | '*' expr                   { $$ = DEBUG_UnopExpr(EXP_OP_FORCE_DEREF, $2); }
 344
 345 lvalue:
 346       tNUM                       { $$ = DEBUG_ConstExpr($1); }
 347     | tINTVAR                    { $$ = DEBUG_IntVarExpr($1); }
 348     | tIDENTIFIER                { $$ = DEBUG_SymbolExpr($1); }
 349     | lvalue OP_DRF tIDENTIFIER  { $$ = DEBUG_StructPExpr($1, $3); }
 350     | lvalue '.' tIDENTIFIER     { $$ = DEBUG_StructExpr($1, $3); }
 351     | lvalue '[' expr ']'        { $$ = DEBUG_BinopExpr(EXP_OP_ARR, $1, $3); }
 352
 353 identifier:
 354       tIDENTIFIER                { $$ = $1; }
 355     | identifier '.' tIDENTIFIER { char* ptr = DBG_alloc(strlen($1) + 1 + strlen($3)+ 1);
 356                                    sprintf(ptr, "%s.%s", $1, $3); $$ = DEBUG_MakeSymbol(ptr);
 357                                    DBG_free(ptr); }
 358     | identifier ':' ':' tIDENTIFIER { char* ptr = DBG_alloc(strlen($1) + 2 + strlen($4) + 1);
 359                                    sprintf(ptr, "%s::%s", $1, $4); $$ = DEBUG_MakeSymbol(ptr);
 360                                    DBG_free(ptr); }
 361
 362 %%
 363
 364 static void mode_command(int newmode)
 365 {
 366     switch(newmode)
 367     {
 368     case 16: DEBUG_CurrThread->dbg_mode = MODE_16; break;
 369     case 32: DEBUG_CurrThread->dbg_mode = MODE_32; break;
 370     default: DEBUG_Printf(DBG_CHN_MESG,"Invalid mode (use 16, 32 or vm86)\n");
 371     }
 372 }
 373
 374 void DEBUG_Exit(DWORD ec)
 375 {
 376    ExitProcess(ec);
 377 }
 378
 379 static WINE_EXCEPTION_FILTER(wine_dbg_cmd)
 380 {
 381    DEBUG_Printf(DBG_CHN_MESG, "\nwine_dbg_cmd: ");
 382    switch (GetExceptionCode()) {
 383    case DEBUG_STATUS_INTERNAL_ERROR:
 384       DEBUG_Printf(DBG_CHN_MESG, "WineDbg internal error\n");
 385       break;
 386    case DEBUG_STATUS_NO_SYMBOL:
 387       DEBUG_Printf(DBG_CHN_MESG, "Undefined symbol\n");
 388       break;
 389    case DEBUG_STATUS_DIV_BY_ZERO:
 390       DEBUG_Printf(DBG_CHN_MESG, "Division by zero\n");
 391       break;
 392    case DEBUG_STATUS_BAD_TYPE:
 393       DEBUG_Printf(DBG_CHN_MESG, "No type or type mismatch\n");
 394       break;
 395    case DEBUG_STATUS_NO_FIELD:
 396       DEBUG_Printf(DBG_CHN_MESG, "No such field in structure or union\n");
 397       break;
 398    default:
 399       DEBUG_Printf(DBG_CHN_MESG, "Exception %lx\n", GetExceptionCode());
 400       break;
 401    }
 402
 403    return EXCEPTION_EXECUTE_HANDLER;
 404 }
 405
 406 /***********************************************************************
 407  *           DEBUG_Parser
 408  *
 409  * Debugger editline parser
 410  */
 411 void    DEBUG_Parser(void)
 412 {
 413     BOOL                ret_ok;
 414 #ifdef YYDEBUG
 415     yydebug = 0;
 416 #endif
 417     yyin = stdin;
 418
 419     DEBUG_ExitMode = EXIT_CONTINUE;
 420
 421     ret_ok = FALSE;
 422     do {
 423        __TRY {
 424           ret_ok = TRUE;
 425           yyparse();
 426        } __EXCEPT(wine_dbg_cmd) {
 427           ret_ok = FALSE;
 428        }
 429        __ENDTRY;
 430        DEBUG_FlushSymbols();
 431     } while (!ret_ok);
 432 }
 433
 434 int yyerror(char* s)
 435 {
 436    DEBUG_Printf(DBG_CHN_MESG, "%s\n", s);
 437    return 0;
 438 }