configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17
  18 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  19 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  20 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  21
  22 AC_CANONICAL_HOST
  23 case $host in
  24   x86_64*linux*)
  25     if test "x$enable_win64" != "xyes"
  26     then
  27       test -n "$CC" || CC="gcc -m32"
  28       test -n "$LD" || LD="ld -m elf_i386"
  29       test -n "$AS" || AS="as --32"
  30       host_cpu="i386"
  31     fi
  32     ;;
  33 esac
  34
  35 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  36 case $host_cpu in
  37   *i[[3456789]]86*)
  38     if test "x$enable_win16" != "xno"
  39     then
  40       enable_win16="yes"
  41     fi
  42     ;;
  43 esac
  44
  45 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  46 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  47 if test "x$enable_win16" != "xyes"
  48 then
  49   WIN16_FILES=""
  50   WIN16_INSTALL=""
  51 fi
  52
  53 dnl **** Check for some programs ****
  54
  55 AC_PROG_MAKE_SET
  56 AC_PROG_CC
  57 AC_PROG_CXX
  58 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  59 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  60
  61 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  62   [if test -z "$with_wine_tools"; then
  63      if test "$cross_compiling" = "yes"; then
  64        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  65      else
  66        wine_cv_toolsdir="\$(TOPOBJDIR)"
  67      fi
  68    elif test -d "$with_wine_tools/tools/winebuild"; then
  69      case $with_wine_tools in
  70        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  71        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  72      esac
  73    else
  74      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  75    fi])
  76 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  77
  78 AC_PATH_XTRA
  79 AC_PROG_LEX
  80
  81 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
  82 dnl **** without one present.
  83 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  84 if test "$XLEX" = "none"
  85 then
  86   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  87 fi
  88
  89 dnl Check for bison
  90 AC_CHECK_PROGS(BISON,bison,none)
  91 if test "$BISON" = "none"
  92 then
  93   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
  94 fi
  95
  96 AC_CHECK_TOOLS(AS,[gas as],as)
  97 AC_CHECK_TOOL(LD,ld,ld)
  98 AC_CHECK_TOOL(AR,ar,ar)
  99 AC_PROG_RANLIB
 100 AC_CHECK_TOOL(STRIP,strip,strip)
 101 AC_CHECK_TOOL(WINDRES,windres,false)
 102 AC_PROG_LN_S
 103 WINE_PROG_LN
 104 AC_PROG_EGREP
 105 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 106 AC_PROG_INSTALL
 107 dnl Prepend src dir to install path dir if it's a relative path
 108 case "$INSTALL" in
 109   [[\\/$]]* | ?:[[\\/]]* ) ;;
 110   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 111 esac
 112
 113 dnl Check for lint
 114 AC_CHECK_PROGS(LINT, lclint lint)
 115 if test "$LINT" = "lint"
 116 then
 117   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 118   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 119 fi
 120 AC_SUBST(LINT)
 121 AC_SUBST(LINTFLAGS)
 122
 123 dnl Check for various programs
 124 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 125 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 126
 127 case $host_cpu in
 128   *i[[3456789]]86*)
 129     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 130     ;;
 131 esac
 132
 133 dnl **** Check for some libraries ****
 134
 135 dnl Check for -li386 for NetBSD and OpenBSD
 136 AC_CHECK_LIB(i386,i386_set_ldt)
 137 dnl Check for -lossaudio for NetBSD
 138 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 139 dnl Check for -lxpg4 for FreeBSD
 140 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 141 dnl Check for -lpthread
 142 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 143
 144 AC_SUBST(XLIB,"")
 145 AC_SUBST(XFILES,"")
 146 AC_SUBST(OPENGLFILES,"")
 147 AC_SUBST(GLU32FILES,"")
 148 AC_SUBST(OPENGL_LIBS,"")
 149 AC_SUBST(QUARTZFILES,"")
 150
 151 dnl **** Check for header files ****
 152
 153 AC_CHECK_HEADERS(\
 154         AudioUnit/AudioUnit.h \
 155         Carbon/Carbon.h \
 156         CoreAudio/CoreAudio.h \
 157         IOKit/IOKitLib.h \
 158         alsa/asoundlib.h \
 159         arpa/inet.h \
 160         arpa/nameser.h \
 161         asm/types.h \
 162         capi20.h \
 163         cups/cups.h \
 164         curses.h \
 165         direct.h \
 166         dlfcn.h \
 167         elf.h \
 168         float.h \
 169         fontconfig/fontconfig.h \
 170         getopt.h \
 171         ieeefp.h \
 172         io.h \
 173         jack/jack.h \
 174         jpeglib.h \
 175         lber.h \
 176         lcms.h \
 177         lcms/lcms.h \
 178         ldap.h \
 179         libaudioio.h \
 180         link.h \
 181         linux/cdrom.h \
 182         linux/compiler.h \
 183         linux/hdreg.h \
 184         linux/input.h \
 185         linux/ioctl.h \
 186         linux/joystick.h \
 187         linux/major.h \
 188         linux/param.h \
 189         linux/serial.h \
 190         linux/ucdrom.h \
 191         mach/machine.h \
 192         machine/cpu.h \
 193         machine/limits.h \
 194         machine/soundcard.h \
 195         mntent.h \
 196         ncurses.h \
 197         netdb.h \
 198         netinet/in.h \
 199         netinet/in_systm.h \
 200         netinet/tcp.h \
 201         netinet/tcp_fsm.h \
 202         openssl/err.h \
 203         openssl/ssl.h \
 204         poll.h \
 205         process.h \
 206         pthread.h \
 207         pwd.h \
 208         regex.h \
 209         sched.h \
 210         scsi/scsi.h \
 211         scsi/scsi_ioctl.h \
 212         scsi/sg.h \
 213         soundcard.h \
 214         stdint.h \
 215         strings.h \
 216         sys/asoundlib.h \
 217         sys/cdio.h \
 218         sys/elf32.h \
 219         sys/epoll.h \
 220         sys/errno.h \
 221         sys/event.h \
 222         sys/exec_elf.h \
 223         sys/filio.h \
 224         sys/ioctl.h \
 225         sys/ipc.h \
 226         sys/limits.h \
 227         sys/link.h \
 228         sys/lwp.h \
 229         sys/mman.h \
 230         sys/modem.h \
 231         sys/msg.h \
 232         sys/mtio.h \
 233         sys/param.h \
 234         sys/poll.h \
 235         sys/prctl.h \
 236         sys/ptrace.h \
 237         sys/reg.h \
 238         sys/resource.h \
 239         sys/scsiio.h \
 240         sys/shm.h \
 241         sys/signal.h \
 242         sys/socket.h \
 243         sys/sockio.h \
 244         sys/soundcard.h \
 245         sys/statvfs.h \
 246         sys/strtio.h \
 247         sys/syscall.h \
 248         sys/sysctl.h \
 249         sys/time.h \
 250         sys/times.h \
 251         sys/uio.h \
 252         sys/un.h \
 253         sys/vm86.h \
 254         sys/wait.h \
 255         syscall.h \
 256         termios.h \
 257         unicode/ubidi.h \
 258         unistd.h \
 259         utime.h \
 260         valgrind/memcheck.h
 261 )
 262 AC_HEADER_STAT()
 263
 264 dnl **** Checks for headers that depend on other ones ****
 265
 266 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 267     [#include <sys/types.h>
 268      #if HAVE_SYS_PARAM_H
 269      # include <sys/param.h>
 270      #endif])
 271
 272 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
 273     [#include <sys/types.h>
 274      #if HAVE_SYS_SOCKET_H
 275      # include <sys/socket.h>
 276      #endif])
 277
 278 AC_CHECK_HEADERS([linux/ipx.h],,,
 279     [#include <sys/types.h>
 280      #ifdef HAVE_ASM_TYPES_H
 281      # include <asm/types.h>
 282      #endif
 283      #if HAVE_SYS_SOCKET_H
 284      # include <sys/socket.h>
 285      #endif])
 286
 287 AC_CHECK_HEADERS([resolv.h],,,
 288     [#include <sys/types.h>
 289      #if HAVE_SYS_SOCKET_H
 290      # include <sys/socket.h>
 291      #endif
 292      #if HAVE_NETINET_IN_H
 293      # include <netinet/in.h>
 294      #endif
 295      #if HAVE_ARPA_NAMESER_H
 296      # include <arpa/nameser.h>
 297      #endif])
 298
 299 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 300
 301 AC_CHECK_HEADERS([pthread_np.h],,,
 302 [#ifdef HAVE_PTHREAD_H
 303 #include <pthread.h>
 304 #endif])
 305
 306 AC_CHECK_HEADERS([linux/videodev.h],,,
 307 [#ifdef HAVE_SYS_TIME_H
 308 #include <sys/time.h>
 309 #endif
 310 #include <sys/types.h>
 311 #ifdef HAVE_ASM_TYPES_H
 312 #include <asm/types.h>
 313 #endif])
 314
 315 dnl Check for broken kernel header that doesn't define __user
 316 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 317
 318 dnl **** Check for X11 ****
 319
 320 if test "$have_x" = "yes"
 321 then
 322     XLIB="-lXext -lX11"
 323     ac_save_CPPFLAGS="$CPPFLAGS"
 324     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 325
 326     dnl *** All of the following tests require X11/Xlib.h
 327     AC_CHECK_HEADERS([X11/Xlib.h \
 328                       X11/XKBlib.h \
 329                       X11/Xutil.h \
 330                       X11/extensions/shape.h \
 331                       X11/extensions/XInput.h \
 332                       X11/extensions/XShm.h \
 333                       X11/extensions/Xinerama.h \
 334                       X11/extensions/Xrandr.h \
 335                       X11/extensions/Xrender.h \
 336                       X11/extensions/xf86vmode.h],,,
 337 [#ifdef HAVE_X11_XLIB_H
 338 # include <X11/Xlib.h>
 339 #endif
 340 #ifdef HAVE_X11_XUTIL_H
 341 # include <X11/Xutil.h>
 342 #endif])
 343
 344         dnl *** Check for X keyboard extension
 345         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 346         then
 347               AC_CHECK_LIB(X11, XkbQueryExtension,
 348               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 349               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 350         fi
 351
 352         dnl *** Check for X Shm extension
 353         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 354         then
 355               AC_CHECK_LIB(Xext, XShmQueryExtension,
 356               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 357               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 358         fi
 359
 360         dnl *** Check for X shape extension
 361         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 362         then
 363               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 364               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 365               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 366         fi
 367
 368         dnl *** Check for XFree86 VMODE extension
 369         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 370         then
 371                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 372                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 373                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 374                   ],,
 375                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 376         fi
 377
 378         dnl *** Check for X RandR extension
 379         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 380         then
 381                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 382 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 383                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 384         fi
 385
 386         dnl *** Check for Transform functions in Xrender
 387         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
 388         then
 389               AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
 390                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 391                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 392                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 393         fi
 394
 395         dnl *** Check for Xinerama extension
 396         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 397         then
 398                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 399 #include <X11/extensions/Xinerama.h>],[static typeof(XineramaQueryScreens) * func;],
 400                   [AC_DEFINE(HAVE_LIBXINERAMA, 1, [Define if you have the Xinerama library])])
 401         fi
 402
 403     dnl *** End of X11/Xlib.h check
 404
 405     dnl Check for the presence of OpenGL
 406     if test "x$with_opengl" != "xno"
 407     then
 408         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 409 [#ifdef HAVE_GL_GLX_H
 410 # include <GL/glx.h>
 411 #endif])
 412         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 413         then
 414             dnl Check for some problems due to old Mesa versions
 415             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 416               AC_TRY_COMPILE(
 417                 [#include <GL/gl.h>],
 418                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 419                 [wine_cv_opengl_header_version_OK="yes"],
 420                 [wine_cv_opengl_header_version_OK="no"]
 421               )
 422             )
 423
 424             if test "$wine_cv_opengl_header_version_OK" = "yes"
 425             then
 426                 dnl Check for the presence of the library
 427                 AC_CHECK_LIB(GL,glXCreateContext,
 428                              [OPENGL_LIBS="-lGL"
 429                              OPENGLFILES='$(OPENGLFILES)'
 430                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])]
 431                              ,,
 432                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 433
 434                 dnl Check for GLU32 library.
 435                 AC_CHECK_LIB(GLU,gluLookAt,
 436                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 437                              GLU32FILES='$(GLU32FILES)']
 438                              ,,
 439                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 440                 )
 441              fi
 442
 443              dnl Check for glut32 library.
 444              AC_CHECK_LIB(glut,glutMainLoop,
 445                        [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
 446                         AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
 447                         $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
 448          else
 449              wine_cv_opengl_headers_found="no"
 450          fi
 451     fi
 452     dnl **** Check for NAS ****
 453     AC_SUBST(NASLIBS,"")
 454     AC_CHECK_HEADERS(audio/audiolib.h,
 455          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 456           AC_CHECK_LIB(audio,AuCreateFlow,
 457                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 458                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 459                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 460
 461     CPPFLAGS="$ac_save_CPPFLAGS"
 462     XFILES='$(XFILES)'
 463 else
 464     XLIB=""
 465     X_CFLAGS=""
 466     X_LIBS=""
 467 fi
 468
 469 dnl **** Check for libxml2 ****
 470
 471 AC_SUBST(XML2LIBS,"")
 472 AC_SUBST(XML2INCL,"")
 473 AC_SUBST(XSLTLIBS,"")
 474 AC_SUBST(XSLTINCL,"")
 475 if test "$PKG_CONFIG" != "false"
 476 then
 477     ac_save_CPPFLAGS="$CPPFLAGS"
 478     ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 479     ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 480     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 481     AC_CHECK_HEADERS(libxml/parser.h,
 482         [AC_CHECK_LIB(xml2, xmlParseMemory,
 483             [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 484              XML2LIBS="$ac_xml_libs"
 485              XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 486          AC_CHECK_LIB(xml2, xmlReadMemory,
 487             [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 488         ])
 489     CPPFLAGS="$ac_save_CPPFLAGS"
 490     ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 491     ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 492     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 493     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
 494         [AC_CHECK_LIB(xslt, xsltCompilePattern,
 495             [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 496              XSLTLIBS="$ac_xslt_libs"
 497              XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
 498         ],,
 499 [#ifdef HAVE_LIBXSLT_PATTERN_H
 500 # include <libxslt/pattern.h>
 501 #endif])
 502     CPPFLAGS="$ac_save_CPPFLAGS"
 503 fi
 504
 505 dnl **** Check for libhal ****
 506 AC_SUBST(HALINCL,"")
 507 if test "$PKG_CONFIG" != "false"
 508 then
 509     ac_save_CPPFLAGS="$CPPFLAGS"
 510     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 511     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 512     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 513     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 514     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 515     then
 516         AC_CHECK_LIB(hal, libhal_ctx_new,
 517           [AC_CHECK_LIB(dbus-1, dbus_connection_close,
 518             [AC_DEFINE(HAVE_LIBHAL, 1, [Define if you have the hal library])
 519              HALINCL="$ac_hal_cflags"],,$ac_hal_libs)])
 520     fi
 521     CPPFLAGS="$ac_save_CPPFLAGS"
 522 fi
 523
 524 dnl **** Check which curses lib to use ***
 525 CURSESLIBS=""
 526 if test "x$with_curses" != "xno"
 527 then
 528     if test "$ac_cv_header_ncurses_h" = "yes"
 529     then
 530         AC_CHECK_LIB(ncurses,waddch,
 531             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 532              CURSESLIBS="-lncurses"])
 533     elif test "$ac_cv_header_curses_h" = "yes"
 534     then
 535         AC_CHECK_LIB(curses,waddch,
 536             [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 537              CURSESLIBS="-lcurses"])
 538     fi
 539     ac_save_LIBS="$LIBS"
 540     LIBS="$LIBS $CURSESLIBS"
 541     AC_CHECK_FUNCS(mousemask)
 542     LIBS="$ac_save_LIBS"
 543 fi
 544 AC_SUBST(CURSESLIBS)
 545
 546 dnl **** Check for SANE ****
 547 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 548 AC_SUBST(SANELIBS,"")
 549 AC_SUBST(SANEINCL,"")
 550 if test "$sane_devel" != "no"
 551 then
 552     SANELIBS="`$sane_devel --libs`"
 553     SANEINCL="`$sane_devel --cflags`"
 554     ac_save_CPPFLAGS="$CPPFLAGS"
 555     ac_save_LIBS="$LIBS"
 556     CPPFLAGS="$CPPFLAGS $SANEINCL"
 557     LIBS="$LIBS $SANELIBS"
 558     AC_CHECK_HEADER(sane/sane.h,
 559                     [AC_CHECK_LIB(sane,sane_open,
 560                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 561                                   [SANELIBS=""
 562                                   SANEINCL=""])],
 563                     [SANELIBS=""
 564                     SANEINCL=""])
 565     LIBS="$ac_save_LIBS"
 566     CPPFLAGS="$ac_save_CPPFLAGS"
 567 fi
 568
 569 dnl **** Check for libgphoto2 ****
 570 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 571 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 572 AC_SUBST(GPHOTO2LIBS,"")
 573 AC_SUBST(GPHOTO2INCL,"")
 574 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
 575 then
 576     GPHOTO2INCL="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 577     GPHOTO2LIBS=""
 578     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 579     do
 580       case "$i" in
 581         -L/usr/lib|-L/usr/lib64) ;;
 582         -L*|-l*) GPHOTO2LIBS="$GPHOTO2LIBS $i";;
 583       esac
 584     done
 585     ac_save_CPPFLAGS="$CPPFLAGS"
 586     ac_save_LIBS="$LIBS"
 587     CPPFLAGS="$CPPFLAGS $GPHOTO2INCL"
 588     LIBS="$LIBS $GPHOTO2LIBS"
 589     AC_CHECK_HEADER(gphoto2-camera.h,
 590                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 591                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])],
 592                                   [GPHOTO2LIBS=""
 593                                   GPHOTO2INCL=""])],
 594                     [GPHOTO2LIBS=""
 595                     GPHOTO2INCL=""])
 596     LIBS="$ac_save_LIBS"
 597     CPPFLAGS="$ac_save_CPPFLAGS"
 598 fi
 599
 600 dnl **** Check for the ICU library ****
 601 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 602 then
 603     saved_libs="$LIBS"
 604     for i in ${ICU_LIB_DIR-/usr/lib}/libsicu ${ICU_LIB_DIR-/usr/lib}/libicu
 605     do
 606         TEST_ICUUC_LIB="${ICUUC_LIB-${i}uc.a}"
 607         TEST_ICUDATA_LIB="${ICUDATA_LIB-${i}data.a}"
 608         AC_MSG_CHECKING(whether can link with ICU libraries $TEST_ICUUC_LIB and $TEST_ICUDATA_LIB)
 609         LIBS="$saved_libs $TEST_ICUUC_LIB $TEST_ICUDATA_LIB -lstdc++ -lgcc_s"
 610         AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 611                     [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 612                      AC_SUBST(ICULIBS,"$TEST_ICUUC_LIB $TEST_ICUDATA_LIB -lstdc++ -lgcc_s")
 613                      AC_MSG_RESULT(yes)],
 614                     [AC_MSG_RESULT(no)])
 615     done
 616     LIBS="$saved_libs"
 617 fi
 618
 619 dnl **** Check for resolver library ***
 620 AC_SUBST(RESOLVLIBS,"")
 621 if test "$ac_cv_header_resolv_h" = "yes"
 622 then
 623     AC_CHECK_LIB(resolv, res_query,
 624         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 625          RESOLVLIBS="-lresolv"])
 626 fi
 627
 628 dnl **** Check for LittleCMS ***
 629 AC_SUBST(LCMSLIBS,"")
 630 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 631 then
 632     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 633         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 634          LCMSLIBS="-llcms"])
 635 fi
 636
 637 dnl **** Check for OpenLDAP ***
 638 AC_SUBST(LDAPLIBS,"")
 639 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 640 then
 641     AC_CHECK_LIB(ldap_r, ldap_initialize,
 642         [AC_CHECK_LIB(lber, ber_init,
 643             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 644              LDAPLIBS="-lldap_r -llber"],,
 645              [$LIBPTHREAD])],,
 646              [$LIBPTHREAD])
 647     WINE_CHECK_LIB_FUNCS(\
 648         ldap_count_references \
 649         ldap_first_reference \
 650         ldap_next_reference \
 651         ldap_parse_reference,
 652         [$LDAPLIBS $LIBPTHREAD])
 653 fi
 654
 655 dnl **** Check for FreeType 2 ****
 656 AC_SUBST(FREETYPELIBS,"")
 657 AC_SUBST(FREETYPEINCL,"")
 658 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 659 if test "$ft_devel" = "no"
 660 then
 661     AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 662     if test "$ft_devel2" = "freetype2-config"
 663     then
 664         ft_devel=$ft_devel2
 665     fi
 666 fi
 667
 668 if test "$ft_devel" = "no"
 669 then
 670     wine_cv_msg_freetype=yes
 671 else
 672     FREETYPELIBS=`$ft_devel --libs`
 673     FREETYPEINCL=`$ft_devel --cflags`
 674     AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$FREETYPELIBS)
 675     if test "$ft_lib" = "no"
 676     then
 677         wine_cv_msg_freetype=yes
 678         FREETYPELIBS=""
 679         FREETYPEINCL=""
 680     else
 681         ac_save_CPPFLAGS="$CPPFLAGS"
 682         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 683         AC_CHECK_HEADERS(ft2build.h \
 684                          freetype/freetype.h \
 685                          freetype/ftglyph.h \
 686                          freetype/tttables.h \
 687                          freetype/ftnames.h \
 688                          freetype/ftsnames.h \
 689                          freetype/ttnameid.h \
 690                          freetype/ftoutln.h \
 691                          freetype/ftwinfnt.h \
 692                          freetype/ftmodapi.h \
 693                          freetype/internal/sfnt.h,,,
 694                          [#if HAVE_FT2BUILD_H
 695                           #include <ft2build.h>
 696                           #endif])
 697         AC_TRY_CPP([#include <ft2build.h>
 698                     #include <freetype/fttrigon.h>],
 699                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 700           [Define if you have the <freetype/fttrigon.h> header file.])
 701                     wine_cv_fttrigon=yes],
 702                     wine_cv_fttrigon=no)
 703         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
 704         ac_save_CFLAGS="$CFLAGS"
 705         CFLAGS="$CFLAGS $FREETYPELIBS"
 706         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
 707         CFLAGS="$ac_save_CFLAGS"
 708         CPPFLAGS="$ac_save_CPPFLAGS"
 709         dnl Check that we have at least freetype/freetype.h
 710         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 711         then
 712             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 713             wine_cv_msg_freetype=no
 714         else
 715             FREETYPELIBS=""
 716             FREETYPEINCL=""
 717             wine_cv_msg_freetype=yes
 718         fi
 719     fi
 720 fi
 721
 722 dnl Only build the fonts dir if we have both freetype and fontforge
 723 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 724 then
 725   AC_SUBST(FONTSSUBDIRS,"fonts")
 726 fi
 727
 728 dnl **** Check for parport (currently Linux only) ****
 729 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 730  AC_TRY_COMPILE(
 731    [#include <linux/ppdev.h>],
 732    [ioctl (1,PPCLAIM,0)],
 733    [ac_cv_c_ppdev="yes"],
 734    [ac_cv_c_ppdev="no"])
 735  )
 736 if test "$ac_cv_c_ppdev" = "yes"
 737 then
 738     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 739 fi
 740
 741 dnl **** Check for va_copy ****
 742 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 743  AC_TRY_LINK(
 744    [#include <stdarg.h>],
 745    [va_list ap1, ap2;
 746     va_copy(ap1,ap2);
 747    ],
 748    [ac_cv_c_va_copy="yes"],
 749    [ac_cv_c_va_copy="no"])
 750  )
 751 if test "$ac_cv_c_va_copy" = "yes"
 752 then
 753     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 754 fi
 755 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 756  AC_TRY_LINK(
 757    [#include <stdarg.h>],
 758    [va_list ap1, ap2;
 759     __va_copy(ap1,ap2);
 760    ],
 761    [ac_cv_c___va_copy="yes"],
 762    [ac_cv_c___va_copy="no"])
 763  )
 764 if test "$ac_cv_c___va_copy" = "yes"
 765 then
 766     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 767 fi
 768
 769 dnl **** Check for sigsetjmp ****
 770 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 771  AC_TRY_LINK(
 772    [#include <setjmp.h>],
 773    [sigjmp_buf buf;
 774     sigsetjmp( buf, 1 );
 775     siglongjmp( buf, 1 );],
 776    [ac_cv_c_sigsetjmp="yes"],
 777    [ac_cv_c_sigsetjmp="no"])
 778  )
 779 if test "$ac_cv_c_sigsetjmp" = "yes"
 780 then
 781     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 782 fi
 783
 784 dnl **** Check for pthread_rwlock_t ****
 785 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 786 #include <pthread.h>])
 787
 788 dnl **** Check for pthread functions ****
 789 WINE_CHECK_LIB_FUNCS(\
 790         pthread_attr_get_np \
 791         pthread_getattr_np \
 792         pthread_get_stackaddr_np \
 793         pthread_get_stacksize_np,
 794         [$LIBPTHREAD])
 795
 796 dnl **** Check for aRts Sound Server ****
 797 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 798 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 799 then
 800     ARTSC_CFLAGS=""
 801     for i in `$ARTSCCONFIG --cflags`
 802     do
 803       case "$i" in
 804         -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
 805       esac
 806     done
 807     ARTSC_LIBS=""
 808     for i in `$ARTSCCONFIG --libs`
 809     do
 810       case "$i" in
 811         -L/usr/lib|-L/usr/lib64) ;;
 812         -L*|-l*) ARTSC_LIBS="$ARTSC_LIBS $i";;
 813       esac
 814     done
 815     save_CFLAGS="$CFLAGS"
 816     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 817     AC_CHECK_LIB(artsc,arts_init,
 818         [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 819             [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 820             AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 821             AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],,
 822             $ARTSC_LIBS)
 823     CFLAGS="$save_CFLAGS"
 824 fi
 825
 826 dnl **** Check for EsounD ****
 827 AC_PATH_PROG(ESDCONFIG, esd-config)
 828 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
 829 then
 830     ESD_CFLAGS=""
 831     for i in `$ESDCONFIG --cflags`
 832     do
 833       case "$i" in
 834         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
 835       esac
 836     done
 837     ESD_LIBS=`$ESDCONFIG --libs`
 838     save_CFLAGS="$CFLAGS"
 839     CFLAGS="$CFLAGS $ESD_CFLAGS"
 840     AC_CHECK_LIB(esd,esd_open_sound,
 841         [AC_SUBST(ESDLIBS, $ESD_LIBS)
 842          AC_SUBST(ESDINCL, $ESD_CFLAGS)
 843          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
 844     CFLAGS="$save_CFLAGS"
 845 fi
 846
 847 dnl **** Check for ALSA 1.x ****
 848 AC_SUBST(ALSALIBS,"")
 849 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 850 then
 851     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
 852         [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
 853 #include <alsa/asoundlib.h>
 854 #elif defined(HAVE_SYS_ASOUNDLIB_H)
 855 #include <sys/asoundlib.h>
 856 #endif],
 857                         [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
 858                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
 859                          ALSALIBS="-lasound"])])
 860 fi
 861
 862 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 863
 864 AC_SUBST(AUDIOIOLIBS,"")
 865 if test "$ac_cv_header_libaudioio_h" = "yes"
 866 then
 867     AC_CHECK_LIB(audioio,AudioIOGetVersion,
 868                   [AUDIOIOLIBS="-laudioio"
 869                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
 870 fi
 871
 872 dnl **** Check for capi4linux ****
 873
 874 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
 875 then
 876     AC_CHECK_LIB(capi20,capi20_register,[AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])])
 877 fi
 878
 879 dnl **** Check for gcc specific options ****
 880
 881 AC_SUBST(EXTRACFLAGS,"")
 882 if test "x${GCC}" = "xyes"
 883 then
 884   EXTRACFLAGS="-Wall -pipe"
 885
 886   dnl Check for strength-reduce bug
 887   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 888                   AC_TRY_RUN([
 889 int     L[[4]] = {0,1,2,3};
 890 int main(void) {
 891   static int Array[[3]];
 892   unsigned int B = 3;
 893   int i;
 894   for(i=0; i<B; i++) Array[[i]] = i - 3;
 895   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 896   L[[i]] = 4;
 897
 898   exit( Array[[1]] != -2 || L[[2]] != 3);
 899 }],
 900     ac_cv_c_gcc_strength_bug="no",
 901     ac_cv_c_gcc_strength_bug="yes",
 902     ac_cv_c_gcc_strength_bug="yes") )
 903   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 904   then
 905     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 906   fi
 907
 908   dnl Check for some compiler flags
 909
 910   WINE_TRY_CFLAGS([-fshort-wchar],
 911                   [AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar",
 912                              [Specifies the compiler flag that forces a short wchar_t])])
 913   WINE_TRY_CFLAGS([-fno-strict-aliasing])
 914   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
 915   WINE_TRY_CFLAGS([-Wwrite-strings])
 916
 917   dnl Check for noisy string.h
 918   saved_CFLAGS="$CFLAGS"
 919   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 920   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 921       AC_TRY_COMPILE([#include <string.h>],[],
 922                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 923   CFLAGS="$saved_CFLAGS"
 924   if test "$ac_cv_c_string_h_warnings" = "no"
 925   then
 926     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 927   fi
 928
 929   AC_SUBST(BUILTINFLAG,"")
 930   saved_CFLAGS="$CFLAGS"
 931   CFLAGS="$CFLAGS -Werror"
 932   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
 933       AC_TRY_COMPILE([],
 934                      [int iswlower(unsigned short);],
 935                      [ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
 936   CFLAGS="$saved_CFLAGS"
 937   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
 938   then
 939     BUILTINFLAG="-fno-builtin"
 940   fi
 941 fi
 942
 943 dnl **** Check how to define a function in assembly code ****
 944
 945 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 946   WINE_TRY_ASM_LINK(
 947       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 948       ac_cv_asm_func_def=".def",
 949     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 950       ac_cv_asm_func_def=".type @function",
 951     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 952       ac_cv_asm_func_def=".type 2",
 953       ac_cv_asm_func_def="unknown")])]))
 954
 955 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 956 case "$ac_cv_asm_func_def" in
 957   ".def")
 958      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 959   ".type @function")
 960      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 961   ".type 2")
 962      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 963   *)
 964      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 965 esac
 966
 967 dnl **** Check for underscore on external symbols ****
 968
 969 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 970     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 971                       [extern int ac_test;],
 972                       [if (ac_test) return 1],
 973                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 974
 975 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 976 if test "$ac_cv_c_extern_prefix" = "yes"
 977 then
 978   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 979 else
 980   AC_DEFINE([__ASM_NAME(name)], [name])
 981 fi
 982
 983 dnl **** Check for working dll ****
 984
 985 AC_SUBST(DLLEXT,"")
 986 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 987 AC_SUBST(LDSHARED,"")
 988 AC_SUBST(LDDLLFLAGS,"")
 989 AC_SUBST(LIBEXT,"so")
 990 AC_SUBST(IMPLIBEXT,"def")
 991 AC_SUBST(LIBWINE_LDFLAGS,"")
 992
 993 case $host_os in
 994   cygwin*|mingw32*)
 995     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 996     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 997     if test "$DLLWRAP" = "false"; then
 998       LIBEXT="a"
 999     else
1000       dnl FIXME - check whether dllwrap works correctly...
1001       LIBEXT="dll"
1002     fi
1003     IMPLIBEXT="a"
1004     dnl We can't build 16-bit NE dlls
1005     WIN16_FILES=""
1006     WIN16_INSTALL=""
1007     ;;
1008   darwin*|macosx*)
1009     DLLEXT=".so"
1010     LIBEXT="dylib"
1011     DLLFLAGS="$DLLFLAGS -fPIC"
1012     LDDLLFLAGS="-bundle -multiply_defined suppress"
1013     LIBWINE_LDFLAGS="-multiply_defined suppress"
1014     LDSHARED="\$(CC) -dynamiclib -install_name @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/\$(DYNAME)"
1015     STRIP="$STRIP -u -r"
1016     dnl declare needed frameworks
1017     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1018     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
1019     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
1020     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
1021     then
1022         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
1023         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
1024     fi
1025     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
1026     then
1027         dnl CoreServices needed by AudioUnit
1028         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices")
1029     fi
1030     case $host_cpu in
1031       *powerpc*)
1032         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
1033         ;;
1034     esac
1035     dnl Enable quartz driver on Mac OS X
1036     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
1037     then
1038         QUARTZFILES='$(QUARTZFILES)'
1039     fi
1040     ;;
1041   *)
1042     DLLFLAGS="$DLLFLAGS -fPIC"
1043     DLLEXT=".so"
1044     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
1045         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
1046                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
1047     if test "$ac_cv_c_dll_gnuelf" = "yes"
1048     then
1049       LDSHARED="\$(CC) -shared"
1050       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
1051       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
1052                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
1053                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
1054                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
1055
1056       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
1057
1058       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
1059                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
1060
1061       echo '{ global: *; };' >conftest.map
1062       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
1063                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
1064       rm -f conftest.map
1065
1066       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
1067                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
1068
1069       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
1070                       [LIBWINE_LDFLAGS="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"])
1071
1072       case $host_cpu in
1073         *i[[3456789]]86* | x86_64)
1074           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
1075                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
1076           ;;
1077       esac
1078
1079     else
1080       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
1081           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
1082                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
1083       if test "$ac_cv_c_dll_unixware" = "yes"
1084       then
1085         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
1086         LDDLLFLAGS="-Wl,-G,-B,symbolic"
1087
1088       else
1089         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1090           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1091         if test "$ac_cv_c_dll_hpux" = "yes"
1092         then
1093           LIBEXT="sl"
1094           DLLEXT=".sl"
1095           LDDLLFLAGS="-shared -fPIC"
1096           LDSHARED="\$(CC) -shared"
1097         fi
1098       fi
1099     fi
1100
1101     dnl Check for cross compiler to build test programs
1102     AC_SUBST(CROSSTEST,"")
1103     if test "$cross_compiling" = "no"
1104     then
1105       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw32-gcc mingw-gcc,false)
1106       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw32-dlltool mingw-dlltool,false)
1107       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw32-windres mingw-windres,false)
1108       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1109     fi
1110     ;;
1111 esac
1112
1113 if test "$LIBEXT" = "a"; then
1114   AC_MSG_ERROR(
1115 [could not find a way to build shared libraries.
1116 It is currently not possible to build Wine without shared library
1117 (.so) support to allow transparent switch between .so and .dll files.
1118 If you are using Linux, you will need a newer binutils.]
1119 )
1120 fi
1121
1122 case $build_os in
1123   cygwin*|mingw32*)
1124     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\"") ;;
1125   darwin*|macosx*)
1126     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$DYLD_LIBRARY_PATH\"") ;;
1127   *)
1128     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\"") ;;
1129 esac
1130
1131 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1132 case $host_os in
1133   mingw32*)
1134     AC_SUBST(CRTLIBS,"-lmsvcrt")
1135     AC_SUBST(SOCKETLIBS,"-lws2_32")
1136     ;;
1137 esac
1138
1139 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1140 case $host_cpu in
1141   *i[[3456789]]86*)
1142     case $host_os in
1143       linux* | k*bsd*-gnu)
1144         AC_SUBST(MAIN_BINARY,"wine-glibc")
1145         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1146     esac
1147     ;;
1148 esac
1149
1150 dnl **** Get the soname for libraries that we load dynamically ****
1151
1152 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1153 then
1154   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1155   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1156   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1157   WINE_GET_SONAME(Xinerama,XineramaQueryScreens,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1158   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1159   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1160   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1161   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1162   WINE_GET_SONAME(hal,libhal_ctx_new)
1163   WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1164   WINE_GET_SONAME(cups,cupsGetDefault)
1165   WINE_GET_SONAME(jack,jack_client_new)
1166   WINE_GET_SONAME(fontconfig,FcInit)
1167   WINE_GET_SONAME(ssl,SSL_library_init)
1168   WINE_GET_SONAME(crypto,BIO_new_socket)
1169   WINE_GET_SONAME(ncurses,waddch)
1170   WINE_GET_SONAME(curses,waddch)
1171   WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1172   WINE_GET_SONAME(capi20,capi20_isinstalled)
1173 fi
1174
1175
1176 dnl **** Check for functions ****
1177
1178 AC_CHECK_FUNCS(\
1179         _pclose \
1180         _popen \
1181         _snprintf \
1182         _spawnvp \
1183         _stricmp \
1184         _strnicmp \
1185         _vsnprintf \
1186         asctime_r \
1187         chsize \
1188         clone \
1189         connect \
1190         dlopen \
1191         epoll_create \
1192         ffs \
1193         finite \
1194         fork \
1195         fpclass \
1196         fstatfs \
1197         fstatvfs \
1198         ftruncate \
1199         futimes \
1200         futimesat \
1201         getaddrinfo \
1202         gethostbyname \
1203         getnameinfo \
1204         getnetbyname \
1205         getopt_long \
1206         getpagesize \
1207         getprotobyname \
1208         getprotobynumber \
1209         getpwuid \
1210         getservbyport \
1211         gettid \
1212         gettimeofday \
1213         getuid \
1214         inet_aton \
1215         inet_network \
1216         kqueue \
1217         lstat \
1218         memmove \
1219         mmap \
1220         pclose \
1221         poll \
1222         popen \
1223         prctl \
1224         pread \
1225         pwrite \
1226         readlink \
1227         rfork \
1228         sched_yield \
1229         select \
1230         sendmsg \
1231         setrlimit \
1232         settimeofday \
1233         sigaltstack \
1234         sigprocmask \
1235         snprintf \
1236         spawnvp \
1237         statfs \
1238         statvfs \
1239         strcasecmp \
1240         strerror \
1241         strncasecmp \
1242         tcgetattr \
1243         timegm \
1244         usleep \
1245         vsnprintf \
1246         wait4 \
1247         waitpid \
1248 )
1249
1250 dnl Check for -ldl
1251 if test "$ac_cv_func_dlopen" = no
1252 then
1253     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1254 fi
1255 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1256
1257 dnl Check for -lpoll for Mac OS X/Darwin
1258 if test "$ac_cv_func_poll" = no
1259 then
1260     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1261 fi
1262
1263 dnl Check for -lnsl for Solaris
1264 if test "$ac_cv_func_gethostbyname" = no
1265 then
1266     AC_CHECK_LIB(nsl,gethostbyname)
1267 fi
1268
1269 dnl Check for -lsocket for Solaris
1270 if test "$ac_cv_func_connect" = no
1271 then
1272     AC_CHECK_LIB(socket,connect)
1273 fi
1274
1275 dnl Check for -lresolv for Solaris
1276 if test "$ac_cv_func_inet_aton" = no
1277 then
1278     AC_CHECK_LIB(resolv,inet_aton)
1279 fi
1280
1281 dnl **** Check for types ****
1282
1283 AC_C_CONST
1284 AC_C_INLINE
1285 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1286 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1287 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1288
1289 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1290 [#ifdef HAVE_LINUX_INPUT_H
1291 #include <linux/input.h>
1292 #endif])
1293
1294 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1295                AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1296                            wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1297 if test "$wine_cv_have_sigaddset" = "yes"
1298 then
1299   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1300 fi
1301
1302
1303 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1304         wine_cv_linux_gethostbyname_r_6,
1305         AC_TRY_LINK([
1306 #include <netdb.h>
1307         ], [
1308     char *name=NULL;
1309     struct hostent he;
1310     struct hostent *result;
1311     char *buf=NULL;
1312     int bufsize=0;
1313     int res,errnr;
1314     char *addr=NULL;
1315     int addrlen=0;
1316     int addrtype=0;
1317     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1318     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1319     ],
1320         wine_cv_linux_gethostbyname_r_6=yes,
1321         wine_cv_linux_gethostbyname_r_6=no
1322         )
1323    )
1324    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1325    then
1326       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1327                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1328    fi
1329
1330 if test "$ac_cv_header_linux_joystick_h" = "yes"
1331 then
1332    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1333         wine_cv_linux_joystick_22_api,
1334         AC_TRY_COMPILE([
1335         #include <sys/ioctl.h>
1336         #include <linux/joystick.h>
1337
1338         struct js_event blub;
1339         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1340         #error "no 2.2 header"
1341         #endif
1342         ],/*empty*/,
1343         wine_cv_linux_joystick_22_api=yes,
1344         wine_cv_linux_joystick_22_api=no,
1345         wine_cv_linux_joystick_22_api=no
1346         )
1347    )
1348    if test "$wine_cv_linux_joystick_22_api" = "yes"
1349    then
1350       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1351                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1352    fi
1353 fi
1354
1355 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1356
1357 dnl Check for statfs members
1358 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1359 [#include <sys/types.h>
1360 #ifdef HAVE_SYS_PARAM_H
1361 # include <sys/param.h>
1362 #endif
1363 #ifdef HAVE_SYS_MOUNT_H
1364 # include <sys/mount.h>
1365 #endif
1366 #ifdef HAVE_SYS_VFS_H
1367 # include <sys/vfs.h>
1368 #endif
1369 #ifdef HAVE_SYS_STATFS_H
1370 # include <sys/statfs.h>
1371 #endif])
1372
1373 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1374 [#ifdef HAVE_SYS_STATVFS_H
1375 #include <sys/statvfs.h>
1376 #endif])
1377
1378 dnl Check for socket structure members
1379 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1380 [#include <sys/types.h>
1381 #ifdef HAVE_SYS_SOCKET_H
1382 # include <sys/socket.h>
1383 #endif
1384 #ifdef HAVE_SYS_UN_H
1385 # include <sys/un.h>
1386 #endif])
1387
1388 dnl Check for scsireq_t and sg_io_hdr_t members
1389 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1390 [#include <sys/types.h>
1391 #ifdef HAVE_SCSI_SG_H
1392 #include <scsi/sg.h>
1393 #endif])
1394
1395 dnl Check for siginfo_t members
1396 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1397
1398 dnl Check for struct mtget members
1399 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1400 [#include <sys/types.h>
1401 #ifdef HAVE_SYS_MTIO_H
1402 #include <sys/mtio.h>
1403 #endif])
1404
1405 dnl Check for struct option
1406 AC_CHECK_MEMBERS([struct option.name],,,
1407 [#ifdef HAVE_GETOPT_H
1408 #include <getopt.h>
1409 #endif])
1410
1411 dnl Check for stat.st_blocks
1412 AC_CHECK_MEMBERS([struct stat.st_blocks])
1413
1414 dnl Check for sin6_scope_id
1415 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1416 [#ifdef HAVE_SYS_TYPES_H
1417 #include <sys/types.h>
1418 #endif
1419 #ifdef HAVE_NETINET_IN_H
1420 #include <netinet/in.h>
1421 #endif])
1422
1423 dnl Check for ns_msg ptr member
1424 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1425 [#ifdef HAVE_SYS_TYPES_H
1426 #include <sys/types.h>
1427 #endif
1428 #ifdef HAVE_NETINET_IN_H
1429 # include <netinet/in.h>
1430 #endif
1431 #ifdef HAVE_ARPA_NAMESER_H
1432 # include <arpa/nameser.h>
1433 #endif])
1434
1435 dnl Check for the external timezone variables timezone and daylight
1436 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1437                AC_TRY_LINK([#include <time.h>],[timezone = 1],
1438                            ac_cv_have_timezone="yes", ac_cv_have_timezone="no"))
1439 if test "$ac_cv_have_timezone" = "yes"
1440 then
1441     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1442 fi
1443 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1444                AC_TRY_LINK([#include <time.h>],[daylight = 1],
1445                            ac_cv_have_daylight="yes", ac_cv_have_daylight="no"))
1446 if test "$ac_cv_have_daylight" = "yes"
1447 then
1448     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1449 fi
1450
1451 dnl *** check for the need to define platform-specific symbols
1452
1453 case $host_cpu in
1454   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1455   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1456   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1457   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1458   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1459 esac
1460
1461 case $host_vendor in
1462   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1463 esac
1464
1465 dnl **** Generate output files ****
1466
1467 dnl autoconf versions before 2.59d need backslashes to escape newlines in subst variables
1468 AC_SUBST(DEPENDENCIES,m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]), [2.59d]), -1,
1469 ["### Dependencies:\\
1470 \\
1471 .INIT: Makefile\\
1472 .BEGIN: Makefile\\
1473 Makefile: dummy\\
1474         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)\\
1475 \\
1476 \$(ALL_OBJS): \$(IDL_H_SRCS:.idl=.h)\\
1477 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)\\
1478 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)\\
1479 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"],
1480 ["### Dependencies:
1481
1482 .INIT: Makefile
1483 .BEGIN: Makefile
1484 Makefile: dummy
1485         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)
1486
1487 \$(ALL_OBJS): \$(IDL_H_SRCS:.idl=.h)
1488 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)
1489 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)
1490 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"]))
1491
1492 AH_TOP([#define __WINE_CONFIG_H])
1493
1494 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
1495
1496 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
1497 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
1498 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
1499 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1500 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1501 WINE_CONFIG_EXTRA_DIR(include/wine)
1502
1503 MAKE_RULES=Make.rules
1504 AC_SUBST_FILE(MAKE_RULES)
1505
1506 MAKE_DLL_RULES=dlls/Makedll.rules
1507 AC_SUBST_FILE(MAKE_DLL_RULES)
1508
1509 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1510 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1511
1512 MAKE_TEST_RULES=dlls/Maketest.rules
1513 AC_SUBST_FILE(MAKE_TEST_RULES)
1514
1515 MAKE_PROG_RULES=programs/Makeprog.rules
1516 AC_SUBST_FILE(MAKE_PROG_RULES)
1517
1518 AC_CONFIG_FILES([
1519 Make.rules
1520 dlls/Makedll.rules
1521 dlls/Makeimplib.rules
1522 dlls/Maketest.rules
1523 programs/Makeprog.rules
1524 Makefile
1525 dlls/Makefile
1526 dlls/activeds/Makefile
1527 dlls/advapi32/Makefile
1528 dlls/advapi32/tests/Makefile
1529 dlls/advpack/Makefile
1530 dlls/advpack/tests/Makefile
1531 dlls/amstream/Makefile
1532 dlls/atl/Makefile
1533 dlls/avicap32/Makefile
1534 dlls/avifil32/Makefile
1535 dlls/cabinet/Makefile
1536 dlls/cabinet/tests/Makefile
1537 dlls/capi2032/Makefile
1538 dlls/cards/Makefile
1539 dlls/cfgmgr32/Makefile
1540 dlls/clusapi/Makefile
1541 dlls/comcat/Makefile
1542 dlls/comcat/tests/Makefile
1543 dlls/comctl32/Makefile
1544 dlls/comctl32/tests/Makefile
1545 dlls/comdlg32/Makefile
1546 dlls/comdlg32/tests/Makefile
1547 dlls/compstui/Makefile
1548 dlls/crtdll/Makefile
1549 dlls/crypt32/Makefile
1550 dlls/crypt32/tests/Makefile
1551 dlls/cryptdll/Makefile
1552 dlls/cryptnet/Makefile
1553 dlls/ctl3d32/Makefile
1554 dlls/d3d8/Makefile
1555 dlls/d3d8/tests/Makefile
1556 dlls/d3d9/Makefile
1557 dlls/d3d9/tests/Makefile
1558 dlls/d3dim/Makefile
1559 dlls/d3drm/Makefile
1560 dlls/d3dx8/Makefile
1561 dlls/d3dxof/Makefile
1562 dlls/dbghelp/Makefile
1563 dlls/dciman32/Makefile
1564 dlls/ddraw/Makefile
1565 dlls/ddraw/tests/Makefile
1566 dlls/devenum/Makefile
1567 dlls/dinput/Makefile
1568 dlls/dinput/tests/Makefile
1569 dlls/dinput8/Makefile
1570 dlls/dmband/Makefile
1571 dlls/dmcompos/Makefile
1572 dlls/dmime/Makefile
1573 dlls/dmloader/Makefile
1574 dlls/dmscript/Makefile
1575 dlls/dmstyle/Makefile
1576 dlls/dmsynth/Makefile
1577 dlls/dmusic/Makefile
1578 dlls/dmusic32/Makefile
1579 dlls/dnsapi/Makefile
1580 dlls/dnsapi/tests/Makefile
1581 dlls/dplay/Makefile
1582 dlls/dplayx/Makefile
1583 dlls/dpnet/Makefile
1584 dlls/dpnhpast/Makefile
1585 dlls/dsound/Makefile
1586 dlls/dsound/tests/Makefile
1587 dlls/dswave/Makefile
1588 dlls/dxdiagn/Makefile
1589 dlls/dxerr8/Makefile
1590 dlls/dxerr9/Makefile
1591 dlls/dxguid/Makefile
1592 dlls/gdi32/Makefile
1593 dlls/gdi32/tests/Makefile
1594 dlls/glu32/Makefile
1595 dlls/glut32/Makefile
1596 dlls/gphoto2.ds/Makefile
1597 dlls/hhctrl.ocx/Makefile
1598 dlls/hid/Makefile
1599 dlls/hlink/Makefile
1600 dlls/hlink/tests/Makefile
1601 dlls/iccvid/Makefile
1602 dlls/icmp/Makefile
1603 dlls/ifsmgr.vxd/Makefile
1604 dlls/imaadp32.acm/Makefile
1605 dlls/imagehlp/Makefile
1606 dlls/imm32/Makefile
1607 dlls/infosoft/Makefile
1608 dlls/infosoft/tests/Makefile
1609 dlls/inseng/Makefile
1610 dlls/iphlpapi/Makefile
1611 dlls/iphlpapi/tests/Makefile
1612 dlls/itss/Makefile
1613 dlls/kernel32/Makefile
1614 dlls/kernel32/tests/Makefile
1615 dlls/localspl/Makefile
1616 dlls/localspl/tests/Makefile
1617 dlls/lz32/Makefile
1618 dlls/lz32/tests/Makefile
1619 dlls/mapi32/Makefile
1620 dlls/mapi32/tests/Makefile
1621 dlls/mciavi32/Makefile
1622 dlls/mcicda/Makefile
1623 dlls/mciseq/Makefile
1624 dlls/mciwave/Makefile
1625 dlls/midimap/Makefile
1626 dlls/mlang/Makefile
1627 dlls/mlang/tests/Makefile
1628 dlls/mmdevldr.vxd/Makefile
1629 dlls/monodebg.vxd/Makefile
1630 dlls/mpr/Makefile
1631 dlls/mprapi/Makefile
1632 dlls/msacm32.drv/Makefile
1633 dlls/msacm32/Makefile
1634 dlls/msacm32/tests/Makefile
1635 dlls/msadp32.acm/Makefile
1636 dlls/mscms/Makefile
1637 dlls/mscms/tests/Makefile
1638 dlls/mscoree/Makefile
1639 dlls/msdmo/Makefile
1640 dlls/msftedit/Makefile
1641 dlls/msg711.acm/Makefile
1642 dlls/mshtml/Makefile
1643 dlls/mshtml/tests/Makefile
1644 dlls/msi/Makefile
1645 dlls/msi/tests/Makefile
1646 dlls/msimg32/Makefile
1647 dlls/msisys.ocx/Makefile
1648 dlls/msnet32/Makefile
1649 dlls/msrle32/Makefile
1650 dlls/msvcrt/Makefile
1651 dlls/msvcrt/tests/Makefile
1652 dlls/msvcrt20/Makefile
1653 dlls/msvcrt40/Makefile
1654 dlls/msvcrtd/Makefile
1655 dlls/msvcrtd/tests/Makefile
1656 dlls/msvfw32/Makefile
1657 dlls/msvidc32/Makefile
1658 dlls/mswsock/Makefile
1659 dlls/msxml3/Makefile
1660 dlls/msxml3/tests/Makefile
1661 dlls/nddeapi/Makefile
1662 dlls/netapi32/Makefile
1663 dlls/netapi32/tests/Makefile
1664 dlls/newdev/Makefile
1665 dlls/ntdll/Makefile
1666 dlls/ntdll/tests/Makefile
1667 dlls/ntdsapi/Makefile
1668 dlls/objsel/Makefile
1669 dlls/odbc32/Makefile
1670 dlls/odbccp32/Makefile
1671 dlls/ole32/Makefile
1672 dlls/ole32/tests/Makefile
1673 dlls/oleacc/Makefile
1674 dlls/oleaut32/Makefile
1675 dlls/oleaut32/tests/Makefile
1676 dlls/olecli32/Makefile
1677 dlls/oledlg/Makefile
1678 dlls/olepro32/Makefile
1679 dlls/olesvr32/Makefile
1680 dlls/opengl32/Makefile
1681 dlls/powrprof/Makefile
1682 dlls/psapi/Makefile
1683 dlls/psapi/tests/Makefile
1684 dlls/pstorec/Makefile
1685 dlls/qcap/Makefile
1686 dlls/quartz/Makefile
1687 dlls/quartz/tests/Makefile
1688 dlls/query/Makefile
1689 dlls/rasapi32/Makefile
1690 dlls/resutils/Makefile
1691 dlls/riched20/Makefile
1692 dlls/riched20/tests/Makefile
1693 dlls/riched32/Makefile
1694 dlls/rpcrt4/Makefile
1695 dlls/rpcrt4/tests/Makefile
1696 dlls/rsabase/Makefile
1697 dlls/rsabase/tests/Makefile
1698 dlls/rsaenh/Makefile
1699 dlls/rsaenh/tests/Makefile
1700 dlls/sane.ds/Makefile
1701 dlls/secur32/Makefile
1702 dlls/secur32/tests/Makefile
1703 dlls/security/Makefile
1704 dlls/sensapi/Makefile
1705 dlls/serialui/Makefile
1706 dlls/setupapi/Makefile
1707 dlls/setupapi/tests/Makefile
1708 dlls/sfc/Makefile
1709 dlls/shdocvw/Makefile
1710 dlls/shdocvw/tests/Makefile
1711 dlls/shell32/Makefile
1712 dlls/shell32/tests/Makefile
1713 dlls/shfolder/Makefile
1714 dlls/shlwapi/Makefile
1715 dlls/shlwapi/tests/Makefile
1716 dlls/snmpapi/Makefile
1717 dlls/spoolss/Makefile
1718 dlls/stdole2.tlb/Makefile
1719 dlls/stdole32.tlb/Makefile
1720 dlls/sti/Makefile
1721 dlls/strmiids/Makefile
1722 dlls/svrapi/Makefile
1723 dlls/tapi32/Makefile
1724 dlls/twain_32/Makefile
1725 dlls/unicows/Makefile
1726 dlls/url/Makefile
1727 dlls/urlmon/Makefile
1728 dlls/urlmon/tests/Makefile
1729 dlls/user/Makefile
1730 dlls/user/tests/Makefile
1731 dlls/userenv/Makefile
1732 dlls/usp10/Makefile
1733 dlls/usp10/tests/Makefile
1734 dlls/uuid/Makefile
1735 dlls/uxtheme/Makefile
1736 dlls/uxtheme/tests/Makefile
1737 dlls/vdhcp.vxd/Makefile
1738 dlls/vdmdbg/Makefile
1739 dlls/version/Makefile
1740 dlls/version/tests/Makefile
1741 dlls/vmm.vxd/Makefile
1742 dlls/vnbt.vxd/Makefile
1743 dlls/vnetbios.vxd/Makefile
1744 dlls/vtdapi.vxd/Makefile
1745 dlls/vwin32.vxd/Makefile
1746 dlls/w32skrnl/Makefile
1747 dlls/winecrt0/Makefile
1748 dlls/wined3d/Makefile
1749 dlls/winedos/Makefile
1750 dlls/winemp3.acm/Makefile
1751 dlls/wineps.drv/Makefile
1752 dlls/winequartz.drv/Makefile
1753 dlls/winex11.drv/Makefile
1754 dlls/wininet/Makefile
1755 dlls/wininet/tests/Makefile
1756 dlls/winmm/Makefile
1757 dlls/winmm/joystick/Makefile
1758 dlls/winmm/tests/Makefile
1759 dlls/winmm/winealsa/Makefile
1760 dlls/winmm/winearts/Makefile
1761 dlls/winmm/wineaudioio/Makefile
1762 dlls/winmm/winecoreaudio/Makefile
1763 dlls/winmm/wineesd/Makefile
1764 dlls/winmm/winejack/Makefile
1765 dlls/winmm/winenas/Makefile
1766 dlls/winmm/wineoss/Makefile
1767 dlls/winnls32/Makefile
1768 dlls/winspool.drv/Makefile
1769 dlls/winspool.drv/tests/Makefile
1770 dlls/wintab32/Makefile
1771 dlls/wintrust/Makefile
1772 dlls/wintrust/tests/Makefile
1773 dlls/wldap32/Makefile
1774 dlls/wnaspi32/Makefile
1775 dlls/wow32/Makefile
1776 dlls/ws2_32/Makefile
1777 dlls/ws2_32/tests/Makefile
1778 dlls/wsock32/Makefile
1779 dlls/wtsapi32/Makefile
1780 documentation/Makefile
1781 fonts/Makefile
1782 include/Makefile
1783 libs/Makefile
1784 libs/port/Makefile
1785 libs/wine/Makefile
1786 libs/wpp/Makefile
1787 loader/Makefile
1788 programs/Makefile
1789 programs/clock/Makefile
1790 programs/cmd/Makefile
1791 programs/cmdlgtst/Makefile
1792 programs/control/Makefile
1793 programs/eject/Makefile
1794 programs/expand/Makefile
1795 programs/explorer/Makefile
1796 programs/hh/Makefile
1797 programs/icinfo/Makefile
1798 programs/iexplore/Makefile
1799 programs/msiexec/Makefile
1800 programs/notepad/Makefile
1801 programs/oleview/Makefile
1802 programs/progman/Makefile
1803 programs/regedit/Makefile
1804 programs/regsvr32/Makefile
1805 programs/rpcss/Makefile
1806 programs/rundll32/Makefile
1807 programs/start/Makefile
1808 programs/taskmgr/Makefile
1809 programs/uninstaller/Makefile
1810 programs/view/Makefile
1811 programs/wineboot/Makefile
1812 programs/winebrowser/Makefile
1813 programs/winecfg/Makefile
1814 programs/wineconsole/Makefile
1815 programs/winedbg/Makefile
1816 programs/winefile/Makefile
1817 programs/winemenubuilder/Makefile
1818 programs/winemine/Makefile
1819 programs/winepath/Makefile
1820 programs/winetest/Makefile
1821 programs/winevdm/Makefile
1822 programs/winhelp/Makefile
1823 programs/winver/Makefile
1824 programs/wordpad/Makefile
1825 server/Makefile
1826 tools/Makefile
1827 tools/widl/Makefile
1828 tools/winebuild/Makefile
1829 tools/winedump/Makefile
1830 tools/winegcc/Makefile
1831 tools/wmc/Makefile
1832 tools/wrc/Makefile])
1833
1834 AC_OUTPUT
1835
1836 dnl **** Display messages about additional packages ***
1837
1838 if test "$no_create" = "yes"
1839 then
1840   exit 0
1841 fi
1842
1843 if test "$verbose" = "yes"
1844 then
1845   dnl **** libcapi20-dev devel package ***
1846   if test "$ac_cv_header_capi20_h" != "yes" -o "$ac_cv_header_linux_capi_h" != "yes"
1847   then
1848     echo >&2
1849     AC_MSG_NOTICE([libcapi20 development files not found.])
1850     AC_MSG_NOTICE([Wine will be built without ISDN support. (capi2032.dll)])
1851   fi
1852
1853   dnl **** libcupsys-dev devel package ***
1854   if test "$ac_cv_header_cups_cups_h" != "yes"
1855   then
1856     echo >&2
1857     AC_MSG_NOTICE([libcups development files not found.])
1858     AC_MSG_NOTICE([Wine will be built without CUPS support.])
1859   fi
1860
1861   dnl **** libcurses devel package: see libncurses ***
1862   dnl **** libdbus-1 devel package ***
1863   dnl **** libdbus-1-dev is required for libhal-dev ***
1864
1865   dnl **** libgphoto2 devel package ***
1866   if test "$ac_cv_header_gphoto2_camera_h" != "yes"
1867   then
1868     echo >&2
1869     AC_MSG_NOTICE([libgphoto2 development files not found.])
1870     if test "$ac_cv_header_sane_sane_h" = "yes"
1871     then
1872       AC_MSG_NOTICE([Wine will be built with limited Digital Camera support. (twain_32.dll)])
1873     else
1874       AC_MSG_NOTICE([Wine will be built without Digital Camera support. (gphoto2.ds/twain_32.dll)])
1875     fi
1876   fi
1877
1878   dnl **** libhal devel package ***
1879   dnl **** libhal-dev depends on libdbus-1-dev ***
1880   if test "$ac_cv_header_hal_libhal_h" != "yes"
1881   then
1882     echo >&2
1883     AC_MSG_NOTICE([libhal development files not found.])
1884     AC_MSG_NOTICE([Wine will be built without dynamic device support. (explorer.exe)])
1885   fi
1886
1887   dnl **** libicu devel package ****
1888   if test "$ac_cv_header_unicode_ubidi_h" != "yes"
1889   then
1890     echo >&2
1891     AC_MSG_NOTICE([libicu development files not found.])
1892     AC_MSG_NOTICE([Wine will be built without bidi (Right to Left) support. (gdi32.dll)])
1893   fi
1894
1895   dnl **** liblcms devel package ****
1896   if test "$ac_cv_header_lcms_h" != "yes" -a "$ac_cv_header_lcms_lcms_h" != "yes"
1897   then
1898     echo >&2
1899     AC_MSG_NOTICE([liblcms development files not found.])
1900     AC_MSG_NOTICE([Wine will be built without Color Management support. (mscms.dll)])
1901   fi
1902
1903   dnl **** libldap devel package ****
1904   if test "$ac_cv_header_ldap_h" != "yes" -o "$ac_cv_header_lber_h" != "yes"
1905   then
1906     echo >&2
1907     AC_MSG_NOTICE([libldap (OpenLDAP) development files not found.])
1908     AC_MSG_NOTICE([Wine will be built without LDAP support. (wldap32.dll)])
1909   fi
1910
1911   dnl **** libncurses / libcurses devel package ***
1912   if test "x$with_curses" != "xno" -a "$ac_cv_header_ncurses_h" != "yes" -a "$ac_cv_header_curses_h" != "yes"
1913   then
1914     echo >&2
1915     AC_MSG_NOTICE([lib(n)curses development files not found.])
1916     AC_MSG_NOTICE([Wine will be built without (n)curses support. (wineconsole.exe)])
1917   fi
1918
1919   dnl **** libsane devel package ***
1920   if test "$ac_cv_header_sane_sane_h" != "yes"
1921   then
1922     echo >&2
1923     AC_MSG_NOTICE([libsane development files not found.])
1924     AC_MSG_NOTICE([Wine will be built without Scanner support. (sane.ds/twain_32.dll)])
1925   fi
1926
1927   dnl **** libX11-dev includes Xlib.h and Xutil.h and depends on ***
1928   dnl **** x11proto-input-dev (extensions/XInput.h) and x11proto-kb-dev (XKBlib.h) ***
1929   if test "$have_x" = "yes"
1930   then
1931     dnl **** libX11 - extension: Xext ***
1932     if test "$ac_cv_header_X11_extensions_shape_h" != "yes" -o "$ac_cv_header_X11_extensions_XShm_h" != "yes"
1933     then
1934       echo >&2
1935       AC_MSG_NOTICE([libxext development files not found.])
1936       AC_MSG_NOTICE([Wine will be built without Shm / Shape support. (winex11.drv)])
1937     fi
1938
1939     dnl **** libX11 - extension: Xrandr ***
1940     if test "$ac_cv_header_X11_extensions_Xrandr_h" != "yes"
1941     then
1942       echo >&2
1943       AC_MSG_NOTICE([libXrandr development files not found.])
1944       AC_MSG_NOTICE([Wine will be built without Xrandr support. (winex11.drv)])
1945     fi
1946
1947     dnl **** libX11 - extension: Xrender ***
1948     if test "$ac_cv_header_X11_extensions_Xrender_h" != "yes"
1949     then
1950       echo >&2
1951       AC_MSG_NOTICE([libXrender development files not found.])
1952       AC_MSG_NOTICE([Wine will be built without Xrender support. (winex11.drv)])
1953     fi
1954
1955     dnl **** libX11 - extension: Xxf86vm ***
1956     if test "$ac_cv_header_X11_extensions_xf86vmode_h" != "yes"
1957     then
1958       echo >&2
1959       AC_MSG_NOTICE([libXxf86vm development files not found.])
1960       AC_MSG_NOTICE([Wine will be built without XFree86-VidMode support. (winex11.drv)])
1961     fi
1962   fi
1963
1964   dnl **** libxml2 devel package ***
1965   if test "$ac_cv_header_libxml_parser_h" != "yes"
1966   then
1967     echo >&2
1968     AC_MSG_NOTICE([libxml2 development files not found.])
1969     AC_MSG_NOTICE([Wine will be built without XML support. (msxml.dll)])
1970   fi
1971
1972   dnl **** libxslt devel package ***
1973   if test "$ac_cv_header_libxslt_pattern_h" != "yes" -o "$ac_cv_header_libxslt_transform_h" != "yes"
1974   then
1975     echo >&2
1976     AC_MSG_NOTICE([libxslt development files not found.])
1977     AC_MSG_NOTICE([Wine will be built without xslt support. (msxml.dll)])
1978   fi
1979 fi
1980
1981
1982 dnl **** Display warnings about important packages ***
1983 if test "$have_x" = "no"
1984 then
1985   echo >&2
1986   AC_MSG_WARN([X development files not found. Wine will be built without])
1987   AC_MSG_WARN([X support, which currently does not work, and probably])
1988   AC_MSG_WARN([isn't what you want anyway. You will need to install devel])
1989   AC_MSG_WARN([ packages of Xlib/Xfree86 at the very least.])
1990 fi
1991
1992 if test -z "$OPENGLFILES"
1993 then
1994   echo >&2
1995   AC_MSG_WARN([Wine will be build without OpenGL or Direct3D support])
1996   AC_MSG_WARN([because something is wrong with the OpenGL setup:])
1997   if test "$wine_cv_opengl_headers_found" = "no"
1998   then
1999     AC_MSG_WARN([No OpenGL development headers were found])
2000   fi
2001   if test "$wine_cv_opengl_header_version_OK" = "no"
2002   then
2003     AC_MSG_WARN([Old Mesa headers detected. Consider upgrading your Mesa libraries (http://www.mesa3d.org/).])
2004   elif test "$ac_cv_lib_GL_glXCreateContext" = "no"
2005   then
2006      if test -f /usr/X11R6/lib/libGL.a
2007      then
2008         AC_MSG_WARN([/usr/X11R6/lib/libGL.a is present on your system.
2009 This probably prevents linking to OpenGL. Try deleting the file and restarting configure.])
2010      else
2011         AC_MSG_WARN([No OpenGL library found on this system.])
2012      fi
2013   fi
2014 fi
2015
2016 if test "$wine_cv_msg_freetype" = "yes"
2017 then
2018   echo >&2
2019   AC_MSG_WARN([Your system appears to have the FreeType 2 runtime libraries])
2020   AC_MSG_WARN([installed, but 'freetype-config' is not in your PATH. Install])
2021   AC_MSG_WARN([the freetype-devel package (or its equivalent on your distribution)])
2022   AC_MSG_WARN([to enable Wine to use TrueType fonts.])
2023 fi
2024
2025 if test -z "$FONTSSUBDIRS"
2026 then
2027   echo >&2
2028   if test "$FONTFORGE" = "false"
2029   then
2030     AC_MSG_WARN([FontForge is missing.])
2031   else
2032     AC_MSG_WARN([FreeType is missing.])
2033   fi
2034   AC_MSG_WARN([Fonts will not be built. Dialog text may be invisible or unaligned.])
2035 fi
2036
2037 if test -z "$ALSALIBS" -a \
2038         -z "$ARTSC_LIBS" -a \
2039         -z "$AUDIOIOLIBS" -a \
2040         -z "$NASLIBS" -a \
2041         -z "$ESD_LIBS" -a \
2042         -z "$ac_cv_lib_soname_jack" -a \
2043         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
2044         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
2045         "$ac_cv_header_soundcard_h" != "yes"
2046 then
2047   echo >&2
2048   AC_MSG_WARN([No sound system was found. Windows applications will be silent.])
2049   AC_MSG_WARN([The currently supported sound systems are:])
2050   AC_MSG_WARN([ALSA, ARTS, EsounD, AudioIO, Jack, NAS and OSS])
2051 fi
2052
2053 echo
2054 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
2055 echo
2056
2057 dnl Local Variables:
2058 dnl comment-start: "dnl "
2059 dnl comment-end: ""
2060 dnl comment-start-skip: "\\bdnl\\b\\s *"
2061 dnl compile-command: "autoconf && autoheader"
2062 dnl End: