| blob | bf00ea6bce35e1ca5b11badb746f448db5f836a9 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53)
8 AC_INIT([Wine],WINE_VERSION)
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
19 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
20 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
21 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
23 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
24 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
25 if test "x$enable_win16" = "xno"
26 then
27 WIN16_FILES=""
28 WIN16_INSTALL=""
29 fi
30 if test "x$enable_debug" = "xno"
31 then
32 AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
33 fi
34 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
35 then
36 AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
37 fi
39 dnl **** Check for some programs ****
41 AC_CANONICAL_HOST
42 AC_PROG_MAKE_SET
43 AC_PROG_CC
44 AC_PROG_CPP
46 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
47 [if test -z "$with_wine_tools"; then
48 if test "$cross_compiling" = "yes"; then
49 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
50 else
51 wine_cv_toolsdir="\$(TOPOBJDIR)"
52 fi
53 elif test -d "$with_wine_tools/tools/winebuild"; then
54 case $with_wine_tools in
55 /*) wine_cv_toolsdir="$with_wine_tools" ;;
56 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
57 esac
58 else
59 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
60 fi])
61 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
63 AC_PATH_XTRA
64 AC_PROG_YACC
65 AC_PROG_LEX
67 dnl **** Just additional warning checks, since AC_PROG just sets 'yacc' even
68 dnl **** without one present.
69 AC_CHECK_PROGS(XYACC,$YACC bison yacc,none)
70 if test "$XYACC" = "none"
71 then
72 AC_MSG_ERROR([no suitable bison/yacc found. Please install the 'bison' package.])
73 fi
74 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
75 if test "$XLEX" = "none"
76 then
77 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
78 fi
80 AC_CHECK_TOOLS(AS,[gas as],as)
81 AC_CHECK_TOOL(LD,ld,ld)
82 AC_CHECK_TOOL(AR,ar,ar)
83 AC_PROG_RANLIB
84 AC_CHECK_TOOL(STRIP,strip,strip)
85 AC_CHECK_TOOL(WINDRES,windres,false)
86 AC_PROG_LN_S
87 WINE_PROG_LN
88 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
89 AC_PROG_INSTALL
90 dnl Prepend src dir to install path dir if it's a relative path
91 case "$INSTALL" in
92 [[\\/$]]* | ?:[[\\/]]* ) ;;
93 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
94 esac
96 dnl Check for lint
97 AC_CHECK_PROGS(LINT, lclint lint)
98 if test "$LINT" = "lint"
99 then
100 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
101 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
102 fi
103 AC_SUBST(LINT)
104 AC_SUBST(LINTFLAGS)
106 dnl Check for db2html
107 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
108 AC_SUBST(DB2HTML)
110 dnl Check for db2pdf
111 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
112 AC_SUBST(DB2PDF)
114 dnl Check for db2ps
115 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
116 AC_SUBST(DB2PS)
118 dnl Check for db2txt
119 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
120 AC_SUBST(DB2TXT)
122 dnl **** Check for some libraries ****
124 dnl Check for -lm
125 AC_CHECK_LIB(m,sqrt)
126 dnl Check for -li386 for NetBSD and OpenBSD
127 AC_CHECK_LIB(i386,i386_set_ldt)
128 dnl Check for -lossaudio for NetBSD
129 AC_CHECK_LIB(ossaudio,_oss_ioctl)
130 dnl Check for -lw for Solaris
131 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
132 dnl Check for -lnsl for Solaris
133 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
134 dnl Check for -lsocket for Solaris
135 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
136 dnl Check for -lresolv for Solaris
137 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
138 dnl Check for -lxpg4 for FreeBSD
139 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
140 dnl Check for -lpthread
141 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
143 JPEGLIB=""
144 AC_SUBST(JPEGLIB)
145 AC_CHECK_HEADERS(jpeglib.h,
146 AC_CHECK_LIB(jpeg,jpeg_start_decompress,
147 AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
148 JPEGLIB="-ljpeg"
149 )
150 )
152 AC_SUBST(GIFLIB,"")
153 AC_CHECK_HEADERS(gif_lib.h,
154 AC_CHECK_LIB(ungif,DGifOpen,
155 [AC_DEFINE(HAVE_LIBGIF,1,[Define if you have libgif/libungif including devel headers])
156 GIFLIB="-lungif"],
157 [AC_CHECK_LIB(gif,DGifOpen,
158 [AC_DEFINE(HAVE_LIBGIF,1)
159 GIFLIB="-lgif"])]))
161 AC_SUBST(XLIB)
162 AC_SUBST(XFILES)
163 XFILES=""
164 AC_SUBST(OPENGLFILES)
165 OPENGLFILES=""
166 AC_SUBST(GLU32FILES)
167 GLU32FILES=""
168 AC_SUBST(OPENGL_LIBS)
169 OPENGL_LIBS=""
170 if test "$have_x" = "yes"
171 then
172 XLIB="-lXext -lX11"
173 ac_save_CPPFLAGS="$CPPFLAGS"
174 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
176 dnl *** All of the following tests require X11/Xlib.h
177 AC_CHECK_HEADERS(X11/Xlib.h,
178 [
179 AC_CHECK_HEADERS([X11/XKBlib.h \
180 X11/Xutil.h \
181 X11/extensions/shape.h \
182 X11/extensions/XShm.h \
183 X11/extensions/Xrandr.h \
184 X11/extensions/Xrender.h \
185 X11/extensions/Xvlib.h \
186 X11/extensions/xf86dga.h \
187 X11/extensions/xf86vmode.h],,,
188 [#include <X11/Xlib.h>
189 #ifdef HAVE_X11_XUTIL_H
190 # include <X11/Xutil.h>
191 #endif])
193 dnl *** Check for X keyboard extension
194 if test "$ac_cv_header_X11_XKBlib_h" = "yes"
195 then
196 AC_CHECK_LIB(X11, XkbQueryExtension,
197 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
198 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
199 fi
201 dnl *** Check for X Shm extension
202 if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
203 then
204 AC_CHECK_LIB(Xext, XShmQueryExtension,
205 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
206 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
207 fi
209 dnl *** Check for X shape extension
210 if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
211 then
212 AC_CHECK_LIB(Xext,XShapeQueryExtension,
213 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
214 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
215 fi
217 dnl *** Check for XFree86 DGA / DGA 2.0 extension
218 if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
219 then
220 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
221 [ dnl *** If found...
222 AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
223 [Define if you have the Xxf86dga library version 2])
224 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
225 ],
226 [ dnl *** If not found, look for XF86DGAQueryExtension()
227 dnl *** instead (DGA 2.0 not found)...
228 AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
229 [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
230 [Define if you have the Xxf86dga library version 1])
231 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
232 ],,
233 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
234 )
235 ],
236 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
237 fi
239 dnl *** Check for XFree86 VMODE extension
240 if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
241 then
242 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
243 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
244 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
245 ],,
246 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
247 fi
249 dnl *** Check for X RandR extension
250 if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
251 then
252 AC_CHECK_LIB(Xrandr, XRRSetScreenConfigAndRate,
253 [ AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])
254 X_PRE_LIBS="$X_PRE_LIBS -lXrandr -lXrender"
255 ],,
256 $X_LIBS -lXrender -lXext -lX11 $X_EXTRA_LIBS)
257 fi
259 dnl *** Check for XVideo extension supporting XvImages
260 if test "$ac_cv_header_X11_extensions_Xvlib_h" = "yes"
261 then
262 AC_CHECK_LIB(Xv, XvShmCreateImage,
263 [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
264 X_PRE_LIBS="$X_PRE_LIBS -lXv"
265 ],,
266 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
267 fi
268 ]
269 ) dnl *** End of X11/Xlib.h check
271 dnl Check for the presence of OpenGL
272 if test "x$with_opengl" != "xno"
273 then
274 if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
275 then
276 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
277 This prevents linking to OpenGL. Delete the file and restart configure.])
278 fi
280 AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
281 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
282 then
283 AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
284 dnl Check for some problems due to old Mesa versions
285 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
286 AC_TRY_COMPILE(
287 [#include <GL/gl.h>],
288 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
289 [wine_cv_opengl_version_OK="yes"],
290 [wine_cv_opengl_version_OK="no"]
291 )
292 )
294 if test "$wine_cv_opengl_version_OK" = "yes"
295 then
296 dnl Check for the presence of the library
297 AC_CHECK_LIB(GL,glXCreateContext,
298 OPENGL_LIBS="-lGL"
299 ,,
300 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
302 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
303 then
304 OPENGLFILES='$(OPENGLFILES)'
305 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
307 AC_CHECK_LIB(GL,glXGetProcAddressARB,
308 AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
309 [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
310 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
312 if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
313 then
314 AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
315 [AC_TRY_COMPILE([#include <GL/gl.h>
316 #ifdef HAVE_GL_GLEXT_H
317 # include <GL/glext.h>
318 #endif
319 ],
320 [PFNGLCOLORTABLEEXTPROC test_proc;],
321 [wine_cv_extension_prototypes="yes"],
322 [wine_cv_extension_prototypes="no"]
323 )]
324 )
325 if test "$wine_cv_extension_prototypes" = "yes"
326 then
327 AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
328 [Define if the OpenGL headers define extension typedefs])
329 fi
330 fi
332 fi
333 dnl Check for GLU32 library.
334 AC_CHECK_LIB(GLU,gluLookAt,
335 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
336 GLU32FILES='$(GLU32FILES)']
337 ,,
338 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
339 )
340 fi
341 fi
342 fi
344 dnl **** Check for NAS ****
345 AC_SUBST(NASLIBS,"")
346 AC_CHECK_HEADERS(audio/audiolib.h,
347 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
348 AC_CHECK_LIB(audio,AuCreateFlow,
349 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
350 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
351 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
353 CPPFLAGS="$ac_save_CPPFLAGS"
354 XFILES='$(XFILES)'
355 else
356 XLIB=""
357 X_CFLAGS=""
358 X_LIBS=""
359 fi
361 dnl **** Check which curses lib to use ***
362 CURSESLIBS=""
363 if test "x$with_curses" != "xno"
364 then
365 AC_CHECK_HEADERS(ncurses.h,
366 [AC_CHECK_LIB(ncurses,waddch,
367 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
368 CURSESLIBS="-lncurses"],
369 [AC_CHECK_HEADERS(curses.h,
370 [AC_CHECK_LIB(curses,waddch,
371 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
372 CURSESLIBS="-lcurses"])])])])
373 saved_libs="$LIBS"
374 LIBS="$CURSESLIBS $LIBS"
375 AC_CHECK_FUNCS(getbkgd resizeterm)
376 LIBS="$saved_libs"
377 fi
378 AC_SUBST(CURSESLIBS)
380 dnl **** Check for SANE ****
381 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
382 if test "$sane_devel" = "no"
383 then
384 SANELIBS=""
385 SANEINCL=""
386 else
387 SANELIBS="`$sane_devel --libs`"
388 SANEINCL="`$sane_devel --cflags`"
389 ac_save_CPPFLAGS="$CPPFLAGS"
390 ac_save_LIBS="$LIBS"
391 CPPFLAGS="$CPPFLAGS $SANEINCL"
392 LIBS="$LIBS $SANELIBS"
393 AC_CHECK_HEADER(sane/sane.h,
394 [AC_CHECK_LIB(sane,sane_open,
395 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
396 [SANELIBS=""
397 SANEINCL=""])],
398 [SANELIBS=""
399 SANEINCL=""])
400 LIBS="$ac_save_LIBS"
401 CPPFLAGS="$ac_save_CPPFLAGS"
402 fi
403 AC_SUBST(SANELIBS)
404 AC_SUBST(SANEINCL)
406 dnl **** Check for the ICU library ****
407 AC_CHECK_HEADERS(unicode/ubidi.h)
408 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
409 then
410 AC_CACHE_CHECK([whether we can statically link the ICU libraries], ac_cv_lib_icu,
411 [saved_libs="$LIBS"
412 ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
413 ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libicuuc.a}"
414 ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libicudata.a}"
415 LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
416 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
417 [ac_cv_lib_icu="yes"],[ac_cv_lib_icu="no"])
418 LIBS="$saved_libs"])
419 if test "$ac_cv_lib_icu" = "yes"
420 then
421 AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
422 AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
423 fi
424 fi
426 dnl **** Check for FreeType 2 ****
427 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
428 if test "$ft_lib" = "no"
429 then
430 FREETYPEINCL=""
431 wine_cv_msg_freetype=no
432 else
433 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
434 if test "$ft_devel" = "no"
435 then
436 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
437 if test "$ft_devel2" = "freetype2-config"
438 then
439 ft_devel=$ft_devel2
440 fi
441 fi
442 if test "$ft_devel" = "no"
443 then
444 FREETYPEINCL=""
445 wine_cv_msg_freetype=yes
446 else
447 FREETYPEINCL=`$ft_devel --cflags`
448 ac_save_CPPFLAGS="$CPPFLAGS"
449 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
450 AC_CHECK_HEADERS(ft2build.h \
451 freetype/freetype.h \
452 freetype/ftglyph.h \
453 freetype/tttables.h \
454 freetype/ftnames.h \
455 freetype/ftsnames.h \
456 freetype/ttnameid.h \
457 freetype/ftoutln.h \
458 freetype/internal/sfnt.h)
459 AC_TRY_CPP([#include <ft2build.h>
460 #include <freetype/fttrigon.h>],
461 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
462 [Define if you have the <freetype/fttrigon.h> header file.])
463 wine_cv_fttrigon=yes],
464 wine_cv_fttrigon=no)
465 CPPFLAGS="$ac_save_CPPFLAGS"
466 dnl Check that we have at least freetype/freetype.h
467 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
468 then
469 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
470 wine_cv_msg_freetype=no
471 else
472 FREETYPEINCL=""
473 wine_cv_msg_freetype=yes
474 fi
475 fi
476 fi
477 AC_SUBST(FREETYPEINCL)
479 dnl **** Check for parport (currently Linux only) ****
480 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
481 AC_TRY_COMPILE(
482 [#include <linux/ppdev.h>],
483 [ioctl (1,PPCLAIM,0)],
484 [ac_cv_c_ppdev="yes"],
485 [ac_cv_c_ppdev="no"])
486 )
487 if test "$ac_cv_c_ppdev" = "yes"
488 then
489 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
490 fi
492 dnl **** Check for va_copy ****
493 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
494 AC_TRY_LINK(
495 [#include <stdarg.h>],
496 [va_list ap1, ap2;
497 va_copy(ap1,ap2);
498 ],
499 [ac_cv_c_va_copy="yes"],
500 [ac_cv_c_va_copy="no"])
501 )
502 if test "$ac_cv_c_va_copy" = "yes"
503 then
504 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
505 fi
506 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
507 AC_TRY_LINK(
508 [#include <stdarg.h>],
509 [va_list ap1, ap2;
510 __va_copy(ap1,ap2);
511 ],
512 [ac_cv_c___va_copy="yes"],
513 [ac_cv_c___va_copy="no"])
514 )
515 if test "$ac_cv_c___va_copy" = "yes"
516 then
517 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
518 fi
520 dnl **** Check for sigsetjmp ****
521 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
522 AC_TRY_LINK(
523 [#include <setjmp.h>],
524 [sigjmp_buf buf;
525 sigsetjmp( buf, 1 );
526 siglongjmp( buf, 1 );],
527 [ac_cv_c_sigsetjmp="yes"],
528 [ac_cv_c_sigsetjmp="no"])
529 )
530 if test "$ac_cv_c_sigsetjmp" = "yes"
531 then
532 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
533 fi
535 dnl **** Check for pthread_rwlock_t ****
536 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
537 #include <pthread.h>])
539 dnl **** Check for pthread_getattr_np ****
540 ac_save_LIBS="$LIBS"
541 LIBS="$LIBS $LIBPTHREAD"
542 AC_CHECK_FUNCS(pthread_getattr_np)
543 LIBS="$ac_save_LIBS"
545 dnl **** Check for Open Sound System ****
546 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
548 AC_CACHE_CHECK([for Open Sound System],
549 ac_cv_c_opensoundsystem,
550 AC_TRY_COMPILE([
551 #if defined(HAVE_SYS_SOUNDCARD_H)
552 #include <sys/soundcard.h>
553 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
554 #include <machine/soundcard.h>
555 #elif defined(HAVE_SOUNDCARD_H)
556 #include <soundcard.h>
557 #endif
558 ],[
560 /* check for one of the Open Sound System specific SNDCTL_ defines */
561 #if !defined(SNDCTL_DSP_STEREO)
562 #error No open sound system
563 #endif
564 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
566 if test "$ac_cv_c_opensoundsystem" = "yes"
567 then
568 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
569 fi
571 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
572 ac_cv_c_opensoundsystem_midi,
573 AC_TRY_COMPILE([
574 #if defined(HAVE_SYS_SOUNDCARD_H)
575 #include <sys/soundcard.h>
576 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
577 #include <machine/soundcard.h>
578 #elif defined(HAVE_SOUNDCARD_H)
579 #include <soundcard.h>
580 #endif
581 ],[
583 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
584 #if !defined(SNDCTL_SEQ_SYNC)
585 #error No open sound system MIDI interface
586 #endif
587 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
589 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
590 then
591 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
592 fi
594 dnl **** Check for aRts Sound Server ****
595 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
596 AC_CACHE_CHECK([for aRts Sound server],
597 ac_cv_c_artsserver,
598 if test x$ARTSCCONFIG = x -o x$ARTSCCONFIG = x'"$ARTSCCONFIG"';
599 then
600 ac_cv_c_artsserver=no
601 else
602 ARTSC_CFLAGS=`$ARTSCCONFIG --cflags`
603 ARTSC_LIBS=`$ARTSCCONFIG --libs`
604 ac_cv_c_artsserver=no
605 save_CFLAGS="$CFLAGS"
606 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
607 AC_TRY_COMPILE([
608 #include <artsc.h>
609 ],[
610 arts_stream_t stream;
611 ],[
612 ac_cv_c_artsserver=yes
613 ])
614 CFLAGS="$save_CFLAGS"
615 fi)
617 if test "$ac_cv_c_artsserver" = "yes"
618 then
619 AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
620 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
622 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])
623 fi
625 dnl **** Check for ALSA ****
626 AC_SUBST(ALSALIBS,"")
627 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
628 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
629 then
630 AC_CHECK_LIB(asound,snd_pcm_open,
631 AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
632 ALSALIBS="-lasound")
633 fi
635 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
637 AC_SUBST(AUDIOIOLIBS,"")
638 AC_CHECK_HEADERS(libaudioio.h,
639 [AC_CHECK_LIB(audioio,AudioIOGetVersion,
640 [AUDIOIOLIBS="-laudioio"
641 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
643 dnl **** Check for capi4linux ****
645 AC_CHECK_HEADERS(capi20.h,[
646 AC_CHECK_HEADERS(linux/capi.h,[
647 AC_CHECK_LIB(capi20,capi20_register,[
648 AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
649 AC_SUBST(CAPI4LINUXLIBS,"-lcapi20")
650 ])
651 ])
652 ])
654 dnl **** Check for broken glibc mmap64 ****
656 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
657 AC_TRY_RUN([
658 #define _FILE_OFFSET_BITS 64
659 #include <stdio.h>
660 #include <unistd.h>
661 #include <fcntl.h>
662 #include <sys/mman.h>
663 #include <errno.h>
665 int main(int argc,char **argv) {
666 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
667 if (fd == -1) exit(1);
669 unlink("conftest.map");
671 write(fd,"test",4);
673 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
674 (errno == EINVAL)
675 ) {
676 exit(1);
677 }
678 close(fd);
679 fprintf(stderr,"success!\n");
680 exit(0);
681 }
683 ],
684 ac_cv_mmap64_works="yes",
685 ac_cv_mmap64_works="no",
686 ac_cv_mmap64_works="no") )
688 if test "$ac_cv_mmap64_works" = "yes"
689 then
690 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
691 fi
693 dnl **** Check for gcc specific options ****
695 AC_SUBST(EXTRACFLAGS,"")
696 if test "x${GCC}" = "xyes"
697 then
698 EXTRACFLAGS=-Wall
700 dnl Check for strength-reduce bug
701 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
702 AC_TRY_RUN([
703 int L[[4]] = {0,1,2,3};
704 int main(void) {
705 static int Array[[3]];
706 unsigned int B = 3;
707 int i;
708 for(i=0; i<B; i++) Array[[i]] = i - 3;
709 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
710 L[[i]] = 4;
712 exit( Array[[1]] != -2 || L[[2]] != 3);
713 }],
714 ac_cv_c_gcc_strength_bug="no",
715 ac_cv_c_gcc_strength_bug="yes",
716 ac_cv_c_gcc_strength_bug="yes") )
717 if test "$ac_cv_c_gcc_strength_bug" = "yes"
718 then
719 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
720 fi
722 dnl Check for -mpreferred-stack-boundary
723 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
724 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
725 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
726 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
727 then
728 EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
729 fi
731 dnl Check for -fno-strict-aliasing
732 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
733 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
734 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
735 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
736 then
737 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
738 fi
740 dnl Check for -gstabs+ option
741 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
742 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
743 if test "$ac_cv_c_gcc_gstabs" = "yes"
744 then
745 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
746 fi
748 dnl Check for noisy string.h
749 saved_CFLAGS="$CFLAGS"
750 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
751 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
752 AC_TRY_COMPILE([#include <string.h>],[],
753 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
754 CFLAGS="$saved_CFLAGS"
755 if test "$ac_cv_c_string_h_warnings" = "no"
756 then
757 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
758 fi
759 fi
761 dnl **** Check how to define a function in assembly code ****
763 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
764 WINE_TRY_ASM_LINK(
765 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
766 ac_cv_asm_func_def=".def",
767 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
768 ac_cv_asm_func_def=".type @function",
769 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
770 ac_cv_asm_func_def=".type 2",
771 ac_cv_asm_func_def="unknown")])]))
773 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
774 case "$ac_cv_asm_func_def" in
775 ".def")
776 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
777 ".type @function")
778 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
779 ".type 2")
780 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
781 *)
782 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
783 esac
785 dnl **** Check for underscore on external symbols ****
787 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
788 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
789 [extern int ac_test;],
790 [if (ac_test) return 1],
791 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
793 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
794 if test "$ac_cv_c_extern_prefix" = "yes"
795 then
796 AC_DEFINE([__ASM_NAME(name)], ["_" name])
797 else
798 AC_DEFINE([__ASM_NAME(name)], [name])
799 fi
801 dnl **** Check how to do strings in assembler ****
803 AC_CACHE_CHECK([whether assembler accepts .string], ac_cv_c_asm_string,
804 WINE_TRY_ASM_LINK([".data\n\t.string \"test\"\n\t.text"],,,
805 ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no"))
806 if test "$ac_cv_c_asm_string" = "yes"
807 then
808 AC_DEFINE(__ASM_STRING, [".string"], [Define to the assembler keyword used to specify an ASCII string])
809 else
810 AC_CACHE_CHECK([whether assembler accepts .asciz], ac_cv_c_asm_asciz,
811 WINE_TRY_ASM_LINK([".data\n\t.asciz \"test\"\n\t.text"],,,
812 ac_cv_c_asm_asciz="yes",ac_cv_c_asm_asciz="no"))
813 if test "$ac_cv_c_asm_asciz" = "yes"
814 then
815 AC_DEFINE(__ASM_STRING, [".asciz"])
816 else
817 AC_DEFINE(__ASM_STRING, [".ascii"])
818 fi
819 fi
821 dnl **** Check for .short in assembler ****
823 AC_CACHE_CHECK([whether assembler accepts .short], ac_cv_c_asm_short,
824 WINE_TRY_ASM_LINK([".data\n\t.short 1\n\t.text"],,,
825 ac_cv_c_asm_short="yes",ac_cv_c_asm_short="no"))
826 if test "$ac_cv_c_asm_short" = "yes"
827 then
828 AC_DEFINE(__ASM_SHORT, [".short"], [Define to the assembler keyword used to specify a word value])
829 else
830 AC_DEFINE(__ASM_SHORT, [".half"])
831 fi
833 dnl **** Check for working dll ****
835 AC_SUBST(DLLEXT,"")
836 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
837 AC_SUBST(DLLIBS,"")
838 AC_SUBST(LDSHARED,"")
839 AC_SUBST(LDDLL,"")
840 AC_SUBST(LIBEXT,"so")
841 AC_SUBST(IMPLIBEXT,"def")
843 case $host_os in
844 cygwin*|mingw32*)
845 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
846 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
847 if test "$DLLWRAP" = "false"; then
848 LIBEXT="a"
849 else
850 dnl FIXME - check whether dllwrap works correctly...
851 LIBEXT="dll"
852 fi
853 IMPLIBEXT="a"
854 ;;
855 *)
856 AC_CHECK_HEADERS(dlfcn.h,
857 [AC_CHECK_FUNCS(dlopen,,
858 [AC_CHECK_LIB(dl,dlopen,
859 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
860 DLLIBS="-ldl"],
861 [LIBEXT="a"])])],
862 [LIBEXT="a"])
864 if test "$LIBEXT" = "so"
865 then
866 DLLFLAGS="$DLLFLAGS -fPIC"
867 DLLEXT=".so"
868 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
869 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
870 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
871 if test "$ac_cv_c_dll_gnuelf" = "yes"
872 then
873 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
874 LDDLL="\$(CC) -shared -Wl,-Bsymbolic"
875 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
876 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
877 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
878 if test "$ac_cv_c_dll_zdefs" = "yes"
879 then
880 LDDLL="$LDDLL,-z,defs"
881 fi
882 AC_CACHE_CHECK([whether we can relocate the executable to 0x3c000000], ac_cv_ld_reloc_exec,
883 [saved_CFLAGS="$CFLAGS"
884 CFLAGS="$CFLAGS -Wl,--section-start,.interp=0x3c000100"
885 AC_TRY_RUN([#include <unistd.h>
886 int main() { return (sbrk(32*1024*1024) == (void *)-1); }],
887 ac_cv_ld_reloc_exec="yes",
888 ac_cv_ld_reloc_exec="no",
889 ac_cv_ld_reloc_exec="no")
890 CFLAGS="$saved_CFLAGS"])
891 if test "$ac_cv_ld_reloc_exec" = "yes"
892 then
893 AC_SUBST(LDEXECFLAGS,["-Wl,--section-start,.interp=0x3c000100"])
894 fi
895 AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
896 [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
897 ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
898 if test "$ac_cv_c_export_dynamic" = "yes"
899 then
900 LDEXECFLAGS="$LDEXECFLAGS -Wl,--export-dynamic"
901 fi
902 else
903 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
904 [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
905 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
906 if test "$ac_cv_c_dll_unixware" = "yes"
907 then
908 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
909 LDDLL="\$(CC) -Wl,-G,-B,symbolic"
910 fi
911 fi
912 fi
914 dnl Check for cross compiler to build test programs
915 AC_SUBST(CROSSTEST,"")
916 if test "$cross_compiling" = "no"
917 then
918 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32-gcc,false)
919 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32-dlltool,false)
920 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32-windres,false)
921 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
922 fi
923 ;;
924 esac
926 if test "$LIBEXT" = "a"; then
927 AC_MSG_ERROR(
928 [could not find a way to build shared libraries.
929 It is currently not possible to build Wine without shared library
930 (.so) support to allow transparent switch between .so and .dll files.
931 If you are using Linux, you will need a newer binutils.]
932 )
933 fi
935 case $build_os in
936 cygwin*|mingw32*)
937 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
938 *)
939 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
940 esac
942 dnl Mingw needs explicit msvcrt for linking libwine
943 case $host_os in
944 mingw32*)
945 AC_SUBST(CRTLIBS,"-lmsvcrt") ;;
946 esac
948 case $host_os in
949 linux*)
950 AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread")
951 AC_SUBST(MAIN_BINARY,"wine-glibc")
952 ;;
953 *)
954 AC_SUBST(WINE_BINARIES,"wine-kthread")
955 AC_SUBST(MAIN_BINARY,"wine-kthread")
956 ;;
957 esac
959 dnl **** Get the soname for libraries that we load dynamically ****
961 if test "$LIBEXT" = "so"
962 then
963 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
964 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
965 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
966 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
967 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
968 WINE_GET_SONAME(cups,cupsGetDefault)
969 WINE_GET_SONAME(jack,jack_client_new)
970 WINE_GET_SONAME(fontconfig,FcInit)
971 WINE_GET_SONAME(ssl,SSL_library_init)
972 WINE_GET_SONAME(crypto,BIO_new_socket)
973 WINE_GET_SONAME(ncurses,waddch)
974 WINE_GET_SONAME(curses,waddch)
975 fi
978 dnl **** Check for functions ****
980 AC_FUNC_ALLOCA()
981 AC_CHECK_FUNCS(\
982 _lwp_create \
983 _lwp_self \
984 _pclose \
985 _popen \
986 _snprintf \
987 _spawnvp \
988 _stricmp \
989 _strnicmp \
990 _vsnprintf \
991 chsize \
992 clone \
993 finite \
994 fpclass \
995 ftruncate \
996 ftruncate64 \
997 getnetbyaddr \
998 getnetbyname \
999 getopt_long \
1000 getpagesize \
1001 getprotobyname \
1002 getprotobynumber \
1003 getpwuid \
1004 getservbyport \
1005 gettid \
1006 gettimeofday \
1007 inet_network \
1008 lseek64 \
1009 lstat \
1010 memmove \
1011 mmap \
1012 pclose \
1013 popen \
1014 pread \
1015 pwrite \
1016 rfork \
1017 select \
1018 sendmsg \
1019 settimeofday \
1020 sigaltstack \
1021 snprintf \
1022 spawnvp \
1023 statfs \
1024 strcasecmp \
1025 strerror \
1026 strncasecmp \
1027 tcgetattr \
1028 timegm \
1029 usleep \
1030 vfscanf \
1031 vsnprintf \
1032 wait4 \
1033 waitpid \
1034 )
1036 dnl **** Check for header files ****
1038 AC_CHECK_HEADERS(\
1039 arpa/inet.h \
1040 arpa/nameser.h \
1041 cups/cups.h \
1042 direct.h \
1043 elf.h \
1044 float.h \
1045 fontconfig/fontconfig.h \
1046 getopt.h \
1047 ieeefp.h \
1048 io.h \
1049 jack/jack.h \
1050 libio.h \
1051 libutil.h \
1052 link.h \
1053 linux/cdrom.h \
1054 linux/hdreg.h \
1055 linux/input.h \
1056 linux/joystick.h \
1057 linux/major.h \
1058 linux/param.h \
1059 linux/serial.h \
1060 linux/ucdrom.h \
1061 machine/cpu.h \
1062 netdb.h \
1063 netinet/in.h \
1064 netinet/in_systm.h \
1065 netinet/tcp.h \
1066 netinet/tcp_fsm.h \
1067 openssl/ssl.h \
1068 process.h \
1069 pthread.h \
1070 pty.h \
1071 pwd.h \
1072 regex.h \
1073 sched.h \
1074 scsi/sg.h \
1075 scsi/scsi.h \
1076 scsi/scsi_ioctl.h \
1077 socket.h \
1078 stdint.h \
1079 strings.h \
1080 sys/cdio.h \
1081 sys/errno.h \
1082 sys/file.h \
1083 sys/filio.h \
1084 sys/inttypes.h \
1085 sys/ioctl.h \
1086 sys/ipc.h \
1087 sys/link.h \
1088 sys/lwp.h \
1089 sys/mman.h \
1090 sys/modem.h \
1091 sys/msg.h \
1092 sys/param.h \
1093 sys/poll.h \
1094 sys/ptrace.h \
1095 sys/reg.h \
1096 sys/scsiio.h \
1097 sys/shm.h \
1098 sys/signal.h \
1099 sys/socket.h \
1100 sys/sockio.h \
1101 sys/statfs.h \
1102 sys/strtio.h \
1103 sys/syscall.h \
1104 sys/sysctl.h \
1105 sys/time.h \
1106 sys/times.h \
1107 sys/uio.h \
1108 sys/un.h \
1109 sys/v86.h \
1110 sys/v86intr.h \
1111 sys/vfs.h \
1112 sys/vm86.h \
1113 sys/wait.h \
1114 syscall.h \
1115 termios.h \
1116 unistd.h \
1117 utime.h \
1118 valgrind/memcheck.h
1119 )
1120 AC_HEADER_STAT()
1122 dnl **** Checks for headers that depend on other ones ****
1124 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1125 [#include <sys/types.h>
1126 #if HAVE_SYS_PARAM_H
1127 # include <sys/param.h>
1128 #endif])
1130 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1131 [#include <sys/types.h>
1132 #if HAVE_SYS_SOCKET_H
1133 # include <sys/socket.h>
1134 #endif])
1136 AC_CHECK_HEADERS([resolv.h],,,
1137 [#include <sys/types.h>
1138 #if HAVE_SYS_SOCKET_H
1139 # include <sys/socket.h>
1140 #endif
1141 #if HAVE_NETINET_IN_H
1142 # include <netinet/in.h>
1143 #endif
1144 #if HAVE_ARPA_NAMESER_H
1145 # include <arpa/nameser.h>
1146 #endif])
1148 AC_CHECK_HEADERS(netinet/ip.h,,,
1149 [#include <sys/types.h>
1150 #if HAVE_SYS_SOCKET_H
1151 # include <sys/socket.h>
1152 #endif
1153 #if HAVE_NETINET_IN_SYSTM_H
1154 # include <netinet/in_systm.h>
1155 #endif])
1157 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1159 dnl **** Check for IPX headers (currently Linux only) ****
1161 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1162 AC_TRY_COMPILE(
1163 [#include <sys/types.h>
1164 #ifdef HAVE_SYS_SOCKET_H
1165 # include <sys/socket.h>
1166 #endif
1167 #include <netipx/ipx.h>],
1168 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1169 [ac_cv_c_ipx_gnu="yes"],
1170 [ac_cv_c_ipx_gnu="no"])
1171 )
1172 if test "$ac_cv_c_ipx_gnu" = "yes"
1173 then
1174 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1175 fi
1177 if test "$ac_cv_c_ipx_gnu" = "no"
1178 then
1179 AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1180 AC_TRY_COMPILE(
1181 [#include <sys/types.h>
1182 #ifdef HAVE_SYS_SOCKET_H
1183 # include <sys/socket.h>
1184 #endif
1185 #include <asm/types.h>
1186 #include <linux/ipx.h>],
1187 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1188 [ac_cv_c_ipx_linux="yes"],
1189 [ac_cv_c_ipx_linux="no"])
1190 )
1191 if test "$ac_cv_c_ipx_linux" = "yes"
1192 then
1193 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1194 fi
1195 fi
1197 dnl **** Check for types ****
1199 AC_C_CONST
1200 AC_C_INLINE
1201 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t])
1202 AC_CHECK_SIZEOF(long long,0)
1204 AC_CACHE_CHECK([whether linux/input.h is for real],
1205 wine_cv_linux_input_h,
1206 AC_TRY_COMPILE([
1207 #include <linux/input.h>
1208 ] , [
1209 int foo = EVIOCGBIT(EV_ABS,42);
1210 int bar = BTN_PINKIE;
1211 int fortytwo = 42;
1212 ],
1213 wine_cv_linux_input_h=yes,
1214 wine_cv_linux_input_h=no,
1215 no
1216 )
1217 )
1218 if test "$wine_cv_linux_input_h" = "yes"
1219 then
1220 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1221 [Define if we have linux/input.h AND it contains the INPUT event API])
1222 fi
1225 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1226 wine_cv_linux_gethostbyname_r_6,
1227 AC_TRY_COMPILE([
1228 #include <netdb.h>
1229 ], [
1230 char *name=NULL;
1231 struct hostent he;
1232 struct hostent *result;
1233 char *buf=NULL;
1234 int bufsize=0;
1235 int res,errnr;
1236 char *addr=NULL;
1237 int addrlen=0;
1238 int addrtype=0;
1239 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1240 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1241 ],
1242 wine_cv_linux_gethostbyname_r_6=yes,
1243 wine_cv_linux_gethostbyname_r_6=no
1244 )
1245 )
1246 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1247 then
1248 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1249 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1250 fi
1252 if test "$ac_cv_header_linux_joystick_h" = "yes"
1253 then
1254 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1255 wine_cv_linux_joystick_22_api,
1256 AC_TRY_COMPILE([
1257 #include <sys/ioctl.h>
1258 #include <linux/joystick.h>
1260 struct js_event blub;
1261 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1262 #error "no 2.2 header"
1263 #endif
1264 ],/*empty*/,
1265 wine_cv_linux_joystick_22_api=yes,
1266 wine_cv_linux_joystick_22_api=no,
1267 wine_cv_linux_joystick_22_api=no
1268 )
1269 )
1270 if test "$wine_cv_linux_joystick_22_api" = "yes"
1271 then
1272 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1273 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1274 fi
1275 fi
1277 dnl **** statfs checks ****
1279 if test "$ac_cv_header_sys_vfs_h" = "yes"
1280 then
1281 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1282 wine_cv_sys_vfs_has_statfs,
1283 AC_TRY_COMPILE([
1284 #include <sys/types.h>
1285 #ifdef HAVE_SYS_PARAM_H
1286 # include <sys/param.h>
1287 #endif
1288 #include <sys/vfs.h>
1289 ],[
1290 struct statfs stfs;
1292 memset(&stfs,0,sizeof(stfs));
1293 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1294 )
1295 )
1296 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1297 then
1298 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1299 [Define if the struct statfs is defined by <sys/vfs.h>])
1300 fi
1301 fi
1303 if test "$ac_cv_header_sys_statfs_h" = "yes"
1304 then
1305 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1306 wine_cv_sys_statfs_has_statfs,
1307 AC_TRY_COMPILE([
1308 #include <sys/types.h>
1309 #ifdef HAVE_SYS_PARAM_H
1310 # include <sys/param.h>
1311 #endif
1312 #include <sys/statfs.h>
1313 ],[
1314 struct statfs stfs;
1315 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1316 )
1317 )
1318 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1319 then
1320 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1321 [Define if the struct statfs is defined by <sys/statfs.h>])
1322 fi
1323 fi
1325 if test "$ac_cv_header_sys_mount_h" = "yes"
1326 then
1327 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1328 wine_cv_sys_mount_has_statfs,
1329 AC_TRY_COMPILE([
1330 #include <sys/types.h>
1331 #ifdef HAVE_SYS_PARAM_H
1332 # include <sys/param.h>
1333 #endif
1334 #include <sys/mount.h>
1335 ],[
1336 struct statfs stfs;
1337 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1338 )
1339 )
1340 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1341 then
1342 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1343 [Define if the struct statfs is defined by <sys/mount.h>])
1344 fi
1345 fi
1347 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1349 dnl Check for statfs members
1350 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail],,,
1351 [#include <sys/types.h>
1352 #ifdef HAVE_SYS_PARAM_H
1353 # include <sys/param.h>
1354 #endif
1355 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1356 # include <sys/mount.h>
1357 #else
1358 # ifdef STATFS_DEFINED_BY_SYS_VFS
1359 # include <sys/vfs.h>
1360 # else
1361 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1362 # include <sys/statfs.h>
1363 # endif
1364 # endif
1365 #endif])
1367 dnl Check for socket structure members
1368 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1369 [#include <sys/types.h>
1370 #ifdef HAVE_SYS_SOCKET_H
1371 # include <sys/socket.h>
1372 #endif
1373 #ifdef HAVE_SYS_UN_H
1374 # include <sys/un.h>
1375 #endif])
1377 dnl Check for siginfo_t members
1378 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1380 dnl Check for struct option
1381 AC_CHECK_MEMBERS([struct option.name],,,
1382 [#ifdef HAVE_GETOPT_H
1383 #include <getopt.h>
1384 #endif])
1386 dnl Check for stat.st_blocks
1387 AC_CHECK_MEMBERS([struct stat.st_blocks])
1389 dnl *** check for the need to define platform-specific symbols
1391 case $host_cpu in
1392 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1393 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1394 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1395 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1396 esac
1398 case $host_vendor in
1399 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1400 esac
1402 dnl **** Generate output files ****
1404 AH_TOP([#define __WINE_CONFIG_H])
1406 WINE_CONFIG_EXTRA_DIR(controls)
1407 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1408 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1409 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1410 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1411 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1412 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1413 WINE_CONFIG_EXTRA_DIR(dlls/dinput/joystick)
1414 WINE_CONFIG_EXTRA_DIR(dlls/dinput/keyboard)
1415 WINE_CONFIG_EXTRA_DIR(dlls/dinput/mouse)
1416 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1417 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1418 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1419 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1420 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1421 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1422 WINE_CONFIG_EXTRA_DIR(files)
1423 WINE_CONFIG_EXTRA_DIR(graphics)
1424 WINE_CONFIG_EXTRA_DIR(graphics/x11drv)
1425 WINE_CONFIG_EXTRA_DIR(include/wine)
1426 WINE_CONFIG_EXTRA_DIR(misc)
1427 WINE_CONFIG_EXTRA_DIR(objects)
1428 WINE_CONFIG_EXTRA_DIR(programs/regapi/tests)
1429 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1430 WINE_CONFIG_EXTRA_DIR(windows)
1432 MAKE_RULES=Make.rules
1433 AC_SUBST_FILE(MAKE_RULES)
1435 MAKE_DLL_RULES=dlls/Makedll.rules
1436 AC_SUBST_FILE(MAKE_DLL_RULES)
1438 MAKE_TEST_RULES=dlls/Maketest.rules
1439 AC_SUBST_FILE(MAKE_TEST_RULES)
1441 MAKE_LIB_RULES=libs/Makelib.rules
1442 AC_SUBST_FILE(MAKE_LIB_RULES)
1444 MAKE_PROG_RULES=programs/Makeprog.rules
1445 AC_SUBST_FILE(MAKE_PROG_RULES)
1447 AC_CONFIG_FILES([
1448 Make.rules
1449 dlls/Makedll.rules
1450 dlls/Maketest.rules
1451 libs/Makelib.rules
1452 programs/Makeprog.rules
1453 Makefile
1454 dlls/Makefile
1455 dlls/advapi32/Makefile
1456 dlls/advapi32/tests/Makefile
1457 dlls/avicap32/Makefile
1458 dlls/avifil32/Makefile
1459 dlls/cabinet/Makefile
1460 dlls/capi2032/Makefile
1461 dlls/cfgmgr32/Makefile
1462 dlls/comcat/Makefile
1463 dlls/comctl32/Makefile
1464 dlls/comctl32/tests/Makefile
1465 dlls/commdlg/Makefile
1466 dlls/crtdll/Makefile
1467 dlls/crypt32/Makefile
1468 dlls/ctl3d/Makefile
1469 dlls/wined3d/Makefile
1470 dlls/d3d8/Makefile
1471 dlls/d3d9/Makefile
1472 dlls/d3dim/Makefile
1473 dlls/d3dx8/Makefile
1474 dlls/dciman32/Makefile
1475 dlls/ddraw/Makefile
1476 dlls/ddraw/tests/Makefile
1477 dlls/devenum/Makefile
1478 dlls/dinput/Makefile
1479 dlls/dinput8/Makefile
1480 dlls/dmband/Makefile
1481 dlls/dmcompos/Makefile
1482 dlls/dmime/Makefile
1483 dlls/dmloader/Makefile
1484 dlls/dmscript/Makefile
1485 dlls/dmstyle/Makefile
1486 dlls/dmsynth/Makefile
1487 dlls/dmusic/Makefile
1488 dlls/dmusic32/Makefile
1489 dlls/dplay/Makefile
1490 dlls/dplayx/Makefile
1491 dlls/dpnhpast/Makefile
1492 dlls/dsound/Makefile
1493 dlls/dsound/tests/Makefile
1494 dlls/gdi/Makefile
1495 dlls/gdi/tests/Makefile
1496 dlls/glu32/Makefile
1497 dlls/icmp/Makefile
1498 dlls/imagehlp/Makefile
1499 dlls/imm32/Makefile
1500 dlls/iphlpapi/Makefile
1501 dlls/kernel/Makefile
1502 dlls/kernel/tests/Makefile
1503 dlls/lzexpand/Makefile
1504 dlls/mapi32/Makefile
1505 dlls/mpr/Makefile
1506 dlls/msacm/Makefile
1507 dlls/msacm/imaadp32/Makefile
1508 dlls/msacm/msadp32/Makefile
1509 dlls/msacm/msg711/Makefile
1510 dlls/msacm/winemp3/Makefile
1511 dlls/msdmo/Makefile
1512 dlls/mshtml/Makefile
1513 dlls/msi/Makefile
1514 dlls/msimg32/Makefile
1515 dlls/msisys/Makefile
1516 dlls/msnet32/Makefile
1517 dlls/msvcrt/Makefile
1518 dlls/msvcrt/tests/Makefile
1519 dlls/msvcrt20/Makefile
1520 dlls/msvcrtd/Makefile
1521 dlls/msvideo/Makefile
1522 dlls/msvideo/msrle32/Makefile
1523 dlls/mswsock/Makefile
1524 dlls/netapi32/Makefile
1525 dlls/netapi32/tests/Makefile
1526 dlls/ntdll/Makefile
1527 dlls/ntdll/tests/Makefile
1528 dlls/odbc32/Makefile
1529 dlls/ole32/Makefile
1530 dlls/oleacc/Makefile
1531 dlls/oleaut32/Makefile
1532 dlls/oleaut32/tests/Makefile
1533 dlls/olecli/Makefile
1534 dlls/oledlg/Makefile
1535 dlls/olepro32/Makefile
1536 dlls/olesvr/Makefile
1537 dlls/opengl32/Makefile
1538 dlls/psapi/Makefile
1539 dlls/qcap/Makefile
1540 dlls/quartz/Makefile
1541 dlls/rasapi32/Makefile
1542 dlls/richedit/Makefile
1543 dlls/rpcrt4/Makefile
1544 dlls/rpcrt4/tests/Makefile
1545 dlls/serialui/Makefile
1546 dlls/setupapi/Makefile
1547 dlls/shdocvw/Makefile
1548 dlls/shell32/Makefile
1549 dlls/shell32/tests/Makefile
1550 dlls/shfolder/Makefile
1551 dlls/shlwapi/Makefile
1552 dlls/shlwapi/tests/Makefile
1553 dlls/snmpapi/Makefile
1554 dlls/sti/Makefile
1555 dlls/tapi32/Makefile
1556 dlls/ttydrv/Makefile
1557 dlls/twain/Makefile
1558 dlls/url/Makefile
1559 dlls/urlmon/Makefile
1560 dlls/urlmon/tests/Makefile
1561 dlls/user/Makefile
1562 dlls/user/tests/Makefile
1563 dlls/uxtheme/Makefile
1564 dlls/version/Makefile
1565 dlls/win32s/Makefile
1566 dlls/winaspi/Makefile
1567 dlls/winedos/Makefile
1568 dlls/wineps/Makefile
1569 dlls/wininet/Makefile
1570 dlls/wininet/tests/Makefile
1571 dlls/winmm/Makefile
1572 dlls/winmm/joystick/Makefile
1573 dlls/winmm/mcianim/Makefile
1574 dlls/winmm/mciavi/Makefile
1575 dlls/winmm/mcicda/Makefile
1576 dlls/winmm/mciseq/Makefile
1577 dlls/winmm/mciwave/Makefile
1578 dlls/winmm/midimap/Makefile
1579 dlls/winmm/tests/Makefile
1580 dlls/winmm/wavemap/Makefile
1581 dlls/winmm/winealsa/Makefile
1582 dlls/winmm/winearts/Makefile
1583 dlls/winmm/wineaudioio/Makefile
1584 dlls/winmm/winenas/Makefile
1585 dlls/winmm/winejack/Makefile
1586 dlls/winmm/wineoss/Makefile
1587 dlls/winnls/Makefile
1588 dlls/winsock/Makefile
1589 dlls/winsock/tests/Makefile
1590 dlls/winspool/Makefile
1591 dlls/winspool/tests/Makefile
1592 dlls/wintab32/Makefile
1593 dlls/wintrust/Makefile
1594 dlls/wow32/Makefile
1595 dlls/wsock32/Makefile
1596 dlls/x11drv/Makefile
1597 documentation/Makefile
1598 include/Makefile
1599 libs/Makefile
1600 libs/port/Makefile
1601 libs/unicode/Makefile
1602 libs/uuid/Makefile
1603 libs/wine/Makefile
1604 libs/wpp/Makefile
1605 loader/Makefile
1606 programs/Makefile
1607 programs/avitools/Makefile
1608 programs/clock/Makefile
1609 programs/cmdlgtst/Makefile
1610 programs/control/Makefile
1611 programs/expand/Makefile
1612 programs/notepad/Makefile
1613 programs/osversioncheck/Makefile
1614 programs/progman/Makefile
1615 programs/regapi/Makefile
1616 programs/regedit/Makefile
1617 programs/regsvr32/Makefile
1618 programs/regtest/Makefile
1619 programs/rpcss/Makefile
1620 programs/rundll32/Makefile
1621 programs/start/Makefile
1622 programs/uninstaller/Makefile
1623 programs/view/Makefile
1624 programs/wcmd/Makefile
1625 programs/wineboot/Makefile
1626 programs/winecfg/Makefile
1627 programs/wineconsole/Makefile
1628 programs/winedbg/Makefile
1629 programs/winefile/Makefile
1630 programs/winemenubuilder/Makefile
1631 programs/winemine/Makefile
1632 programs/winepath/Makefile
1633 programs/winevdm/Makefile
1634 programs/winhelp/Makefile
1635 programs/winver/Makefile
1636 server/Makefile
1637 tools/Makefile
1638 tools/widl/Makefile
1639 tools/winapi/Makefile
1640 tools/winebuild/Makefile
1641 tools/winedump/Makefile
1642 tools/winegcc/Makefile
1643 tools/wmc/Makefile
1644 tools/wrc/Makefile])
1646 AC_OUTPUT
1648 if test "$have_x" = "no"
1649 then
1650 echo
1651 echo "*** Warning: X development files not found. Wine will be built without"
1652 echo "*** X support, which currently does not work, and would probably not be"
1653 echo "*** what you want anyway. You will need to install devel packages of"
1654 echo "*** Xlib/Xfree86 at the very least."
1655 fi
1657 if test "$wine_cv_opengl_version_OK" = "no"
1658 then
1659 echo
1660 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1661 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1662 fi
1664 if test "$wine_cv_msg_freetype" = "yes"
1665 then
1666 echo
1667 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1668 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1669 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1670 echo "*** enable Wine to use TrueType fonts."
1671 fi
1673 echo
1674 echo "Configure finished. Do 'make depend && make' to compile Wine."
1675 echo
1677 dnl Local Variables:
1678 dnl comment-start: "dnl "
1679 dnl comment-end: ""
1680 dnl comment-start-skip: "\\bdnl\\b\\s *"
1681 dnl compile-command: "autoconf"
1682 dnl End: