dlls/d3dx9_36/asmshader.l

   1 /*
   2  * Direct3D shader assembler
   3  *
   4  * Copyright 2008 Stefan Dösinger
   5  * Copyright 2009 Matteo Bruni
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  20  */
  21
  22 %{
  23 #include "config.h"
  24 #include "wine/port.h"
  25 #include "wine/debug.h"
  26
  27 #include "d3dx9_36_private.h"
  28 #include "asmshader.tab.h"
  29
  30 WINE_DEFAULT_DEBUG_CHANNEL(asmshader);
  31 %}
  32
  33 %option noyywrap
  34 %option prefix="asmshader_"
  35 %option noinput nounput
  36
  37 /* Swizzles and writemasks consist of a dot and up to 4 x, y, z or w characters,
  38  * or up to 4 a, r, g, b characters. There are different rules for swizzles and
  39  * writemasks wrt repetition, those are handled in the grammar.
  40  */
  41 DOT                     \.
  42 COMPONENT               [xyzw]|[rgba]
  43
  44 /* Registers */
  45 REG_TEMP                r[0-9]+
  46 /* for relative addressing in the form o[x], v[x] and c[x] */
  47 REG_OUTPUT              o[0-9]*
  48 REG_INPUT               v[0-9]*
  49 REG_CONSTFLOAT          c[0-9]*
  50 REG_CONSTINT            i[0-9]+
  51 REG_CONSTBOOL           b[0-9]+
  52 REG_TEXTURE             t[0-9]+
  53 REG_TEXCRDOUT           oT[0-9]+
  54 REG_SAMPLER             s[0-9]+
  55 REG_OPOS                oPos
  56 REG_OFOG                oFog
  57 REG_OPTS                oPts
  58 REG_VERTEXCOLOR         oD[01]
  59 REG_FRAGCOLOR           oC[0-9]+
  60 REG_FRAGDEPTH           oDepth
  61 REG_VPOS                vPos
  62 REG_VFACE               vFace
  63 REG_ADDRESS             a0
  64 REG_LOOP                aL
  65 REG_PREDICATE           p0
  66 /* Not really a register, but it is considered as such */
  67 REG_LABEL               l[0-9]+
  68
  69 DCL_POSITION            _position[0-9]*
  70 DCL_BLENDWEIGHT         _blendweight[0-9]*
  71 DCL_BLENDINDICES        _blendindices[0-9]*
  72 DCL_NORMAL              _normal[0-9]*
  73 DCL_PSIZE               _psize[0-9]*
  74 DCL_TEXCOORD            _texcoord[0-9]*
  75 DCL_TANGENT             _tangent[0-9]*
  76 DCL_BINORMAL            _binormal[0-9]*
  77 DCL_TESSFACTOR          _tessfactor[0-9]*
  78 DCL_POSITIONT           _positiont[0-9]*
  79 DCL_COLOR               _color[0-9]*
  80 DCL_FOG                 _fog[0-9]*
  81 DCL_DEPTH               _depth[0-9]*
  82 DCL_SAMPLE              _sample[0-9]*
  83
  84 DCL_SAMPLER1D           _1d
  85 DCL_SAMPLER2D           _2d
  86 DCL_SAMPLERCUBE         _cube
  87 DCL_SAMPLERVOLUME       _volume
  88
  89 PREPROCESSORDIRECTIVE   #[^\n]*\n
  90
  91 /* Comments */
  92 DOUBLESLASHCOMMENT      "//"[^\n]*
  93 SEMICOLONCOMMENT        ";"[^\n]*
  94
  95 /* Whitespaces are spaces, tabs and newlines */
  96 WHITESPACE              [ \t]+
  97 NEWLINE                 (\n)|(\r\n)
  98
  99 COMMA                   ","
 100
 101 IMMVAL                  \-?(([0-9]+)|([0-9]*\.[0-9]+))(f)?
 102
 103 ANY                     (.)
 104
 105 %%
 106
 107     /* Common instructions(vertex and pixel shaders) */
 108 add                     {return INSTR_ADD;          }
 109 nop                     {return INSTR_NOP;          }
 110 mov                     {return INSTR_MOV;          }
 111 sub                     {return INSTR_SUB;          }
 112 mad                     {return INSTR_MAD;          }
 113 mul                     {return INSTR_MUL;          }
 114 rcp                     {return INSTR_RCP;          }
 115 rsq                     {return INSTR_RSQ;          }
 116 dp3                     {return INSTR_DP3;          }
 117 dp4                     {return INSTR_DP4;          }
 118 min                     {return INSTR_MIN;          }
 119 max                     {return INSTR_MAX;          }
 120 slt                     {return INSTR_SLT;          }
 121 sge                     {return INSTR_SGE;          }
 122 abs                     {return INSTR_ABS;          }
 123 exp                     {return INSTR_EXP;          }
 124 log                     {return INSTR_LOG;          }
 125 expp                    {return INSTR_EXPP;         }
 126 logp                    {return INSTR_LOGP;         }
 127 dst                     {return INSTR_DST;          }
 128 lrp                     {return INSTR_LRP;          }
 129 frc                     {return INSTR_FRC;          }
 130 pow                     {return INSTR_POW;          }
 131 crs                     {return INSTR_CRS;          }
 132 sgn                     {return INSTR_SGN;          }
 133 nrm                     {return INSTR_NRM;          }
 134 sincos                  {return INSTR_SINCOS;       }
 135 m4x4                    {return INSTR_M4x4;         }
 136 m4x3                    {return INSTR_M4x3;         }
 137 m3x4                    {return INSTR_M3x4;         }
 138 m3x3                    {return INSTR_M3x3;         }
 139 m3x2                    {return INSTR_M3x2;         }
 140 dcl                     {return INSTR_DCL;          }
 141 def                     {return INSTR_DEF;          }
 142 rep                     {return INSTR_REP;          }
 143 endrep                  {return INSTR_ENDREP;       }
 144 if                      {return INSTR_IF;           }
 145 else                    {return INSTR_ELSE;         }
 146 endif                   {return INSTR_ENDIF;        }
 147 break                   {return INSTR_BREAK;        }
 148 breakp                  {return INSTR_BREAKP;       }
 149 call                    {return INSTR_CALL;         }
 150 callnz                  {return INSTR_CALLNZ;       }
 151 loop                    {return INSTR_LOOP;         }
 152 ret                     {return INSTR_RET;          }
 153 endloop                 {return INSTR_ENDLOOP;      }
 154 label                   {return INSTR_LABEL;        }
 155 setp                    {return INSTR_SETP;         }
 156 texldl                  {return INSTR_TEXLDL;       }
 157
 158     /* Vertex shader only instructions  */
 159 lit                     {return INSTR_LIT;          }
 160 mova                    {return INSTR_MOVA;         }
 161
 162
 163 {REG_TEMP}              {
 164                             asmshader_lval.regnum = atoi(yytext + 1);
 165                             return REG_TEMP;
 166                         }
 167 {REG_OUTPUT}            {
 168                             asmshader_lval.regnum = atoi(yytext + 1);
 169                             return REG_OUTPUT;
 170                         }
 171 {REG_INPUT}             {
 172                             asmshader_lval.regnum = atoi(yytext + 1);
 173                             return REG_INPUT;
 174                         }
 175 {REG_CONSTFLOAT}        {
 176                             asmshader_lval.regnum = atoi(yytext + 1);
 177                             return REG_CONSTFLOAT;
 178                         }
 179 {REG_CONSTINT}          {
 180                             asmshader_lval.regnum = atoi(yytext + 1);
 181                             return REG_CONSTINT;
 182                         }
 183 {REG_CONSTBOOL}         {
 184                             asmshader_lval.regnum = atoi(yytext + 1);
 185                             return REG_CONSTBOOL;
 186                         }
 187 {REG_TEXTURE}           {
 188                             asmshader_lval.regnum = atoi(yytext + 1);
 189                             return REG_TEXTURE;
 190                         }
 191 {REG_TEXCRDOUT}         {
 192                             asmshader_lval.regnum = atoi(yytext + 2);
 193                             return REG_TEXCRDOUT;
 194                         }
 195 {REG_SAMPLER}           {
 196                             asmshader_lval.regnum = atoi(yytext + 1);
 197                             return REG_SAMPLER;
 198                         }
 199 {REG_OPOS}              {return REG_OPOS;           }
 200 {REG_OFOG}              {return REG_OFOG;           }
 201 {REG_OPTS}              {return REG_OPTS;           }
 202 {REG_VERTEXCOLOR}       {
 203                             asmshader_lval.regnum = atoi(yytext + 2);
 204                             return REG_VERTEXCOLOR;
 205                         }
 206 {REG_FRAGCOLOR}         {
 207                             asmshader_lval.regnum = atoi(yytext + 2);
 208                             return REG_FRAGCOLOR;
 209                         }
 210 {REG_FRAGDEPTH}         {return REG_FRAGDEPTH;      }
 211 {REG_VPOS}              {return REG_VPOS;           }
 212 {REG_VFACE}             {return REG_VFACE;          }
 213 {REG_ADDRESS}           {return REG_ADDRESS;        }
 214 {REG_LOOP}              {return REG_LOOP;           }
 215 {REG_PREDICATE}         {return REG_PREDICATE;      }
 216
 217 {REG_LABEL}             {
 218                             asmshader_lval.regnum = atoi(yytext + 1);
 219                             return REG_LABEL;
 220                         }
 221
 222     /* Shader versions. These are important to select the correct
 223      * parser profile.
 224      */
 225 vs\.1\.0|vs_1_0         {return VER_VS10;       }
 226 vs\.1\.1|vs_1_1         {return VER_VS11;       }
 227
 228 vs_2_0                  {return VER_VS20;       }
 229 vs_2_x                  {return VER_VS2X;       }
 230 vs_3_0                  {return VER_VS30;       }
 231
 232 ps\.1\.0|ps_1_0         {return VER_PS10;       }
 233 ps\.1\.1|ps_1_1         {return VER_PS11;       }
 234 ps\.1\.2|ps_1_2         {return VER_PS12;       }
 235 ps\.1\.3|ps_1_3         {return VER_PS13;       }
 236 ps\.1\.4|ps_1_4         {return VER_PS14;       }
 237
 238 ps_2_0                  {return VER_PS20;       }
 239 ps_2_x                  {return VER_PS2X;       }
 240 ps_3_0                  {return VER_PS30;       }
 241
 242 {DOT}                   {return yytext[0];      }
 243 {COMPONENT}             {
 244                             switch(yytext[0]) {
 245                                 case 'x':
 246                                 case 'r':
 247                                     asmshader_lval.component = 0;
 248                                     break;
 249                                 case 'y':
 250                                 case 'g':
 251                                     asmshader_lval.component = 1;
 252                                     break;
 253                                 case 'z':
 254                                 case 'b':
 255                                     asmshader_lval.component = 2;
 256                                     break;
 257                                 case 'w':
 258                                 case 'a':
 259                                     asmshader_lval.component = 3;
 260                                     break;
 261                             }
 262                             return COMPONENT;
 263                         }
 264
 265     /* Output modifiers */
 266 \_sat                   {return MOD_SAT;            }
 267 \_pp                    {return MOD_PP;             }
 268 \_centroid              {return MOD_CENTROID;       }
 269
 270     /* compare params */
 271 \_gt                    {return COMP_GT;            }
 272 \_lt                    {return COMP_LT;            }
 273 \_ge                    {return COMP_GE;            }
 274 \_le                    {return COMP_LE;            }
 275 \_eq                    {return COMP_EQ;            }
 276 \_ne                    {return COMP_NE;            }
 277
 278 {IMMVAL}                {
 279                             asmshader_lval.immval.val = atof(yytext);
 280                             asmshader_lval.immval.integer = ((strstr(yytext, ".") == NULL) && (strstr(yytext, "f") == NULL));
 281                             return IMMVAL;
 282                         }
 283
 284 {COMMA}                 {return yytext[0];          }
 285 -                       {return yytext[0];          }
 286 \(                      {return yytext[0];          }
 287 \)                      {return yytext[0];          }
 288
 289     /* for relative addressing */
 290 \[|\]|\+                {return yytext[0];          }
 291
 292 \_abs                   {return SMOD_ABS;           }
 293
 294 !                       {return SMOD_NOT;           }
 295
 296 {DCL_POSITION}          {
 297                             if(yytext[strlen("_position")] == '\0') {
 298                                 asmshader_lval.regnum = 0;
 299                             } else {
 300                                 asmshader_lval.regnum = atoi(yytext + strlen("_position"));
 301                             }
 302                             return USAGE_POSITION;
 303                         }
 304 {DCL_BLENDWEIGHT}       {
 305                             if(yytext[strlen("_blendweight")] == '\0') {
 306                                 asmshader_lval.regnum = 0;
 307                             } else {
 308                                 asmshader_lval.regnum = atoi(yytext + strlen("_blendweight"));
 309                             }
 310                             return USAGE_BLENDWEIGHT;
 311                         }
 312 {DCL_BLENDINDICES}      {
 313                             if(yytext[strlen("_blendindices")] == '\0') {
 314                                 asmshader_lval.regnum = 0;
 315                             } else {
 316                                 asmshader_lval.regnum = atoi(yytext + strlen("_blendindices"));
 317                             }
 318                             return USAGE_BLENDINDICES;
 319                         }
 320 {DCL_NORMAL}            {
 321                             if(yytext[strlen("_normal")] == '\0') {
 322                                 asmshader_lval.regnum = 0;
 323                             } else {
 324                                 asmshader_lval.regnum = atoi(yytext + strlen("_normal"));
 325                             }
 326                             return USAGE_NORMAL;
 327                         }
 328 {DCL_PSIZE}             {
 329                             if(yytext[strlen("_psize")] == '\0') {
 330                                 asmshader_lval.regnum = 0;
 331                             } else {
 332                                 asmshader_lval.regnum = atoi(yytext + strlen("_psize"));
 333                             }
 334                             return USAGE_PSIZE;
 335                         }
 336 {DCL_TEXCOORD}          {
 337                             if(yytext[strlen("_texcoord")] == '\0') {
 338                                 asmshader_lval.regnum = 0;
 339                             } else {
 340                                 asmshader_lval.regnum = atoi(yytext + strlen("_texcoord"));
 341                             }
 342                             return USAGE_TEXCOORD;
 343                         }
 344 {DCL_TANGENT}           {
 345                             if(yytext[strlen("_tangent")] == '\0') {
 346                                 asmshader_lval.regnum = 0;
 347                             } else {
 348                                 asmshader_lval.regnum = atoi(yytext + strlen("_tangent"));
 349                             }
 350                             return USAGE_TANGENT;
 351                         }
 352 {DCL_BINORMAL}          {
 353                             if(yytext[strlen("_binormal")] == '\0') {
 354                                 asmshader_lval.regnum = 0;
 355                             } else {
 356                                 asmshader_lval.regnum = atoi(yytext + strlen("_binormal"));
 357                             }
 358                             return USAGE_BINORMAL;
 359                         }
 360 {DCL_TESSFACTOR}        {
 361                             if(yytext[strlen("_tessfactor")] == '\0') {
 362                                 asmshader_lval.regnum = 0;
 363                             } else {
 364                                 asmshader_lval.regnum = atoi(yytext + strlen("_tessfactor"));
 365                             }
 366                             return USAGE_TESSFACTOR;
 367                         }
 368 {DCL_POSITIONT}         {
 369                             if(yytext[strlen("_positiont")] == '\0') {
 370                                 asmshader_lval.regnum = 0;
 371                             } else {
 372                                 asmshader_lval.regnum = atoi(yytext + strlen("_positiont"));
 373                             }
 374                             return USAGE_POSITIONT;
 375                         }
 376 {DCL_COLOR}             {
 377                             if(yytext[strlen("_color")] == '\0') {
 378                                 asmshader_lval.regnum = 0;
 379                             } else {
 380                                 asmshader_lval.regnum = atoi(yytext + strlen("_color"));
 381                             }
 382                             return USAGE_COLOR;
 383                         }
 384 {DCL_FOG}               {
 385                             if(yytext[strlen("_fog")] == '\0') {
 386                                 asmshader_lval.regnum = 0;
 387                             } else {
 388                                 asmshader_lval.regnum = atoi(yytext + strlen("_fog"));
 389                             }
 390                             return USAGE_FOG;
 391                         }
 392 {DCL_DEPTH}             {
 393                             if(yytext[strlen("_depth")] == '\0') {
 394                                 asmshader_lval.regnum = 0;
 395                             } else {
 396                                 asmshader_lval.regnum = atoi(yytext + strlen("_depth"));
 397                             }
 398                             return USAGE_DEPTH;
 399                         }
 400 {DCL_SAMPLE}            {
 401                             if(yytext[strlen("_sample")] == '\0') {
 402                                 asmshader_lval.regnum = 0;
 403                             } else {
 404                                 asmshader_lval.regnum = atoi(yytext + strlen("_sample"));
 405                             }
 406                             return USAGE_SAMPLE;
 407                         }
 408
 409 {DCL_SAMPLER1D}         { return SAMPTYPE_1D;       }
 410 {DCL_SAMPLER2D}         { return SAMPTYPE_2D;       }
 411 {DCL_SAMPLERCUBE}       { return SAMPTYPE_CUBE;     }
 412 {DCL_SAMPLERVOLUME}     { return SAMPTYPE_VOLUME;   }
 413
 414 {PREPROCESSORDIRECTIVE} {
 415                             /* TODO: update current line information */
 416                             TRACE("line info update: %s", yytext);
 417                         }
 418
 419     /* Skip comments */
 420 {DOUBLESLASHCOMMENT}    {                           }
 421 {SEMICOLONCOMMENT}      {                           }
 422
 423 {WHITESPACE}            { /* Do nothing */          }
 424 {NEWLINE}               {
 425                             asm_ctx.line_no++;
 426                         }
 427
 428 {ANY}                   {
 429                             asmparser_message(&asm_ctx, "Line %u: Unexpected input %s\n", asm_ctx.line_no, yytext);
 430                             set_parse_status(&asm_ctx, PARSE_ERR);
 431                         }
 432
 433 %%
 434
 435 struct bwriter_shader *SlAssembleShader(const char *text, char **messages) {
 436     struct bwriter_shader *ret = NULL;
 437     YY_BUFFER_STATE buffer;
 438     TRACE("%p, %p\n", text, messages);
 439
 440     buffer = asmshader__scan_string(text);
 441     asmshader__switch_to_buffer(buffer);
 442
 443     ret = parse_asm_shader(messages);
 444
 445     asmshader__delete_buffer(buffer);
 446
 447     return ret;
 448 }