programs/winedbg/debug.l

   1 /* -*-C-*-
   2  * Lexical scanner for command line parsing
   3  *
   4  * Copyright 1993 Eric Youngdale
   5  *           2000 Eric Pouech
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  20  */
  21
  22 %option noinput nounput interactive 8bit prefix="dbg_"
  23
  24 %{
  25 #include "config.h"
  26 #include <stdlib.h>
  27 #include <string.h>
  28 #include <stdarg.h>
  29
  30 #ifndef HAVE_UNISTD_H
  31 #define YY_NO_UNISTD_H
  32 #endif
  33
  34 #include "debugger.h"
  35 #include "dbg.tab.h"
  36
  37 #undef YY_INPUT
  38
  39 static char** local_lexemes /* = NULL */;
  40 static int next_lexeme /* = 0 */;
  41 static int alloc_lexeme /* = 0 */;
  42
  43 char* lexeme_alloc_size(int size)
  44 {
  45     assert(0 <= next_lexeme && next_lexeme < alloc_lexeme + 1);
  46     if (next_lexeme >= alloc_lexeme)
  47     {
  48         alloc_lexeme += 32;
  49         local_lexemes = dbg_heap_realloc(local_lexemes, alloc_lexeme * sizeof(local_lexemes[0]));
  50         assert(local_lexemes);
  51     }
  52     return local_lexemes[next_lexeme++] = HeapAlloc(GetProcessHeap(), 0, size + 1);
  53 }
  54
  55 static char* lexeme_alloc(const char* lexeme)
  56 {
  57     char*       ptr = lexeme_alloc_size(strlen(lexeme) + 1);
  58     return strcpy(ptr, lexeme);
  59 }
  60
  61 void lexeme_flush(void)
  62 {
  63     while (--next_lexeme >= 0) HeapFree(GetProcessHeap(), 0, local_lexemes[next_lexeme]);
  64     next_lexeme = 0;
  65 }
  66
  67 static int read_input(const char* pfx, char* buf, int size)
  68 {
  69     int len;
  70     static char*  last_line = NULL;
  71     static size_t last_line_idx = 0;
  72
  73     /* try first to fetch the remaining of an existing line */
  74     if (last_line_idx == 0)
  75     {
  76         char* tmp = NULL;
  77         /* no remaining chars to be read from last line, grab a brand new line up to '\n' */
  78         lexeme_flush();
  79         len = input_fetch_entire_line(pfx, &tmp);
  80         if (len < 0) return 0;  /* eof */
  81         /* FIXME: should have a pair of buffers, and switch between the two, instead of
  82          * reallocating a new one for each line
  83          */
  84         if (last_line && (len == 0 || (len == 1 && tmp[0] == '\n') || (len == 2 && tmp[0] == '\r' && tmp[1] == '\n')))
  85         {
  86             HeapFree(GetProcessHeap(), 0, tmp);
  87         }
  88         else
  89         {
  90             HeapFree(GetProcessHeap(), 0, last_line);
  91             last_line = tmp;
  92         }
  93     }
  94
  95     len = min(strlen(last_line + last_line_idx), size - 1);
  96     memcpy(buf, last_line + last_line_idx, len);
  97     buf[len] = '\0';
  98     if ((last_line_idx += len) >= strlen(last_line))
  99         last_line_idx = 0;
 100     return len;
 101 }
 102
 103 #define YY_INPUT(buf,result,max_size) \
 104         if ((result = read_input("Wine-dbg>", buf, max_size)) < 0) \
 105             YY_FATAL_ERROR("read_input in flex scanner failed");
 106
 107 static int syntax_error;
 108 %}
 109
 110 DIGIT      [0-9]
 111 HEXDIGIT   [0-9a-fA-F]
 112 FORMAT     [ubcdgiswx]
 113 IDENTIFIER [_a-zA-Z~?][_a-zA-Z0-9~?@]*
 114 PATHNAME   [\\/-_a-zA-Z0-9\.~@]+
 115 STRING     \"[^\n"]+\"
 116
 117 %s FORMAT_EXPECTED
 118 %s PATH_EXPECTED
 119 %s INFO_CMD
 120 %s HELP_CMD
 121 %s BD_CMD
 122 %s LOCAL_CMD
 123 %s SHOW_CMD
 124 %s MODE_CMD
 125 %s MAINT_CMD
 126 %s NOCMD
 127
 128 %x ASTRING_EXPECTED
 129 %x NOPROCESS
 130 %%
 131                                         /* set to special state when no process is loaded. */
 132                                         if (!dbg_num_processes() && YYSTATE == INITIAL) {BEGIN(NOPROCESS);}
 133
 134 <<EOF>>                                 { return tEOF; }
 135 <*>\n                                   { BEGIN(INITIAL); syntax_error = 0; return tEOL; }
 136                                         /* Indicates end of command. Reset state. */
 137
 138                                         /* This rule must precede the ones below, */
 139                                         /* otherwise paths like '/' or '0x9' would */
 140                                         /* get parsed as an operator or tNUM */
 141 <PATH_EXPECTED>{PATHNAME}               { dbg_lval.string = lexeme_alloc(yytext); return tPATH; }
 142
 143 "||"                                    { return OP_LOR; }
 144 "&&"                                    { return OP_LAND; }
 145 "=="                                    { return OP_EQ; }
 146 "!="                                    { return OP_NE; }
 147 "<="                                    { return OP_LE; }
 148 ">="                                    { return OP_GE; }
 149 "<<"                                    { return OP_SHL; }
 150 ">>"                                    { return OP_SHR; }
 151 "->"                                    { return OP_DRF; }
 152 "::"                                    { return OP_SCOPE; }
 153 [-+<=>|&^()*/%:!~,\.]                   { return *yytext; }
 154 "["                                     { return *yytext; }
 155 "]"                                     { return *yytext; }
 156
 157 "0x"{HEXDIGIT}+                         { sscanf(yytext, "%x", &dbg_lval.integer); return tNUM; }
 158 {DIGIT}+                                { sscanf(yytext, "%d", &dbg_lval.integer); return tNUM; }
 159
 160 <FORMAT_EXPECTED>"/"{DIGIT}+{FORMAT}    { char* last;
 161                                           dbg_lval.integer = strtol(yytext+1, &last, 0) << 8;
 162                                           dbg_lval.integer |= *last;
 163                                           return tFORMAT; }
 164
 165 <FORMAT_EXPECTED>"/"{FORMAT}            { dbg_lval.integer = (1 << 8) | yytext[1]; return tFORMAT; }
 166
 167 {STRING}                                { dbg_lval.string = lexeme_alloc(yytext + 1); dbg_lval.string[strlen(dbg_lval.string) - 1] = '\0'; return tSTRING; }
 168 <ASTRING_EXPECTED>[^\n]+                { char* p = yytext; while (*p == ' ' || *p == '\t') p++;
 169                                           dbg_lval.string = lexeme_alloc(p); return tSTRING; }
 170
 171 <INITIAL,NOPROCESS>info|inf|in          { BEGIN(INFO_CMD); return tINFO; }
 172 <INITIAL>up                             { BEGIN(NOCMD); return tUP; }
 173 <INITIAL>down|dow|do                    { BEGIN(NOCMD); return tDOWN; }
 174 <INITIAL>frame|fram|fra|fr              { BEGIN(NOCMD); return tFRAME; }
 175 <INITIAL>list|lis|li|l                  { BEGIN(PATH_EXPECTED); return tLIST; }
 176 <INITIAL>enable|enabl|enab|ena          { BEGIN(BD_CMD); return tENABLE;}
 177 <INITIAL>disable|disabl|disab|disa|dis  { BEGIN(BD_CMD); return tDISABLE; }
 178 <INITIAL>disassemble|disassembl|disassemb|disassem|disasse|disass|disas { BEGIN(NOCMD); return tDISASSEMBLE; }
 179 <INITIAL>locally|local                  { BEGIN(LOCAL_CMD); return tLOCAL; }
 180 <INITIAL,LOCAL_CMD>display|displa|displ|disp    { BEGIN(FORMAT_EXPECTED); return tDISPLAY; }
 181 <INFO_CMD,BD_CMD>display|displa|displ|disp|dis|di|d     { BEGIN(NOCMD); return tDISPLAY; }
 182 <INITIAL>undisplay|undispla|undispl|undisp|undis|undi|und       { BEGIN(NOCMD); return tUNDISPLAY; }
 183 <INITIAL>delete|delet|dele|del          { BEGIN(BD_CMD); return tDELETE; }
 184 <INITIAL,NOPROCESS>quit|qui|qu|q        { BEGIN(NOCMD); return tQUIT; }
 185 <INITIAL>set|se                         { BEGIN(NOCMD); return tSET; }
 186 <INITIAL>x                              { BEGIN(FORMAT_EXPECTED); return tEXAM; }
 187 <INITIAL,NOPROCESS>help|hel|he|"?"      { BEGIN(HELP_CMD); return tHELP; }
 188
 189 <INITIAL,NOPROCESS>backtrace|backtrac|backtra|backt|back|bac|ba|bt { BEGIN(NOCMD); return tBACKTRACE; }
 190 <INITIAL,NOPROCESS>where|wher|whe       { BEGIN(NOCMD); return tBACKTRACE; }
 191
 192 <INITIAL>cont|con|co|c                  { BEGIN(NOCMD); return tCONT; }
 193 <INITIAL>pass|pas|pa                    { BEGIN(NOCMD); return tPASS; }
 194 <INITIAL>condition|conditio|conditi|condit|condi|cond   { BEGIN(NOCMD); return tCOND; }
 195 <INITIAL>step|ste|st|s                  { BEGIN(NOCMD); return tSTEP; }
 196 <INITIAL>next|nex|ne|n                  { BEGIN(NOCMD); return tNEXT; }
 197 <INITIAL>stepi|si                       { BEGIN(NOCMD); return tSTEPI; }
 198 <INITIAL>nexti|ni                       { BEGIN(NOCMD); return tNEXTI; }
 199 <INITIAL>finish|finis|fini|fin|fi       { BEGIN(NOCMD); return tFINISH; }
 200
 201 <INITIAL>abort|abor|abo                 { BEGIN(NOCMD); return tABORT; }
 202 <INITIAL>print|prin|pri|pr|p            { BEGIN(FORMAT_EXPECTED); return tPRINT; }
 203
 204 <INITIAL>show|sho|sh                    { BEGIN(SHOW_CMD); return tSHOW; }
 205 <INITIAL,NOPROCESS>source|sourc|sour|src { BEGIN(PATH_EXPECTED); return tSOURCE; }
 206 <INITIAL>symbolfile|symbols|symbol|sf   { BEGIN(PATH_EXPECTED); return tSYMBOLFILE; }
 207
 208 <INITIAL,INFO_CMD,BD_CMD>break|brea|bre|br|b    { BEGIN(NOCMD); return tBREAK; }
 209 <INITIAL,INFO_CMD,BD_CMD>hbreak|hbrea|hbre|hbr|hb { BEGIN(NOCMD); return tHBREAK; }
 210 <INITIAL>watch|watc|wat                 { BEGIN(NOCMD); return tWATCH; }
 211 <INITIAL>whatis|whati|what              { BEGIN(NOCMD); return tWHATIS; }
 212 <INITIAL,NOPROCESS>run|ru|r             { BEGIN(ASTRING_EXPECTED); return tRUN;}
 213 <INITIAL>detach|detac|deta|det          { BEGIN(NOCMD); return tDETACH; }
 214 <INITIAL>kill|kil|ki|k                  { BEGIN(NOCMD); return tKILL; }
 215 <INITIAL,NOPROCESS>maintenance|maint    { BEGIN(MAINT_CMD); return tMAINTENANCE; }
 216 <INITIAL>minidump|mdmp                  { BEGIN(PATH_EXPECTED); return tMINIDUMP; }
 217 <INITIAL>echo                           { BEGIN(ASTRING_EXPECTED); return tECHO; }
 218 <NOPROCESS>attach|attac|atta|att        { BEGIN(NOCMD); return tATTACH; }
 219 <INFO_CMD>share|shar|sha                { return tSHARE; }
 220 <MAINT_CMD>module|modul|mod             { BEGIN(ASTRING_EXPECTED); return tMODULE; }
 221 <INFO_CMD>locals|local|loca|loc         { return tLOCAL; }
 222 <INFO_CMD>class|clas|cla                { return tCLASS; }
 223 <INFO_CMD>process|proces|proce|proc     { return tPROCESS; }
 224 <INFO_CMD>threads|thread|threa|thre|thr|th { return tTHREAD; }
 225 <INFO_CMD>exception|except|exc|ex       { return tEXCEPTION; }
 226 <INFO_CMD>registers|regs|reg|re         { return tREGS; }
 227 <INFO_CMD>allregs|allreg|allre          { return tALLREGS; }
 228 <INFO_CMD>"all-registers"|"all-regs"|"all-reg"|"all-re" { return tALLREGS; }
 229 <INFO_CMD>segments|segment|segm|seg|se  { return tSEGMENTS; }
 230 <INFO_CMD>stack|stac|sta|st             { return tSTACK; }
 231 <INFO_CMD>symbol|symbo|symb|sym         { BEGIN(ASTRING_EXPECTED); return tSYMBOL; }
 232 <INFO_CMD>maps|map                      { return tMAPS; }
 233 <INFO_CMD>window|windo|wind|win|wnd     { return tWND; }
 234 <HELP_CMD>info|inf|in                   { return tINFO; }
 235 <MAINT_CMD>type                         { return tTYPE; }
 236
 237 <INITIAL,SHOW_CMD>directories|directorie|directori|director|directo|direct|direc|direc|dir {
 238                                           BEGIN(PATH_EXPECTED); return tDIR; }
 239
 240 char                                    { return tCHAR; }
 241 short                                   { return tSHORT; }
 242 int                                     { return tINT; }
 243 long                                    { return tLONG; }
 244 float                                   { return tFLOAT; }
 245 double                                  { return tDOUBLE; }
 246 unsigned                                { return tUNSIGNED; }
 247 signed                                  { return tSIGNED; }
 248 struct                                  { return tSTRUCT; }
 249 union                                   { return tUNION; }
 250 enum                                    { return tENUM; }
 251 all                                     { return tALL; }
 252
 253 {IDENTIFIER}                            { dbg_lval.string = lexeme_alloc(yytext); return tIDENTIFIER; }
 254 "$"{IDENTIFIER}                         { dbg_lval.string = lexeme_alloc(yytext+1); return tINTVAR; }
 255
 256 <*>[ \t\r]+                             /* Eat up whitespace and DOS LF */
 257
 258 <NOPROCESS>.                            { BEGIN(ASTRING_EXPECTED); yyless(0); return tNOPROCESS;}
 259 <*>.                                    { if (syntax_error == 0) { syntax_error++; dbg_printf("Syntax Error (%s)\n", yytext); } }
 260 %%
 261
 262 #ifndef dbg_wrap
 263 int dbg_wrap(void) { return 1; }
 264 #endif