tools/make_requests

   1 #! /usr/bin/perl -w
   2 #
   3 # Build the server/trace.c and server/request.h files
   4 # from the contents of include/wine/server.h.
   5 #
   6 # Copyright (C) 1998 Alexandre Julliard
   7 #
   8 # This library is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU Lesser General Public
  10 # License as published by the Free Software Foundation; either
  11 # version 2.1 of the License, or (at your option) any later version.
  12 #
  13 # This library is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # Lesser General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with this library; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  21 #
  22 use strict;
  23
  24 my %formats =
  25 (
  26     "int"           => "%d",
  27     "short int"     => "%d",
  28     "char"          => "%c",
  29     "unsigned char" => "%02x",
  30     "unsigned short"=> "%04x",
  31     "unsigned int"  => "%08x",
  32     "unsigned long" => "%lx",
  33     "void*"         => "%p",
  34     "time_t"        => "%ld (long)",
  35     "size_t"        => "%lu (unsigned long)",
  36     "data_size_t"   => "%u",
  37     "obj_handle_t"  => "%p",
  38     "atom_t"        => "%04x",
  39     "user_handle_t" => "%p",
  40     "process_id_t"  => "%04x",
  41     "thread_id_t"   => "%04x",
  42     "abs_time_t"    => "&dump_abs_time",
  43     "rectangle_t"   => "&dump_rectangle",
  44     "char_info_t"   => "&dump_char_info",
  45     "apc_call_t"    => "&dump_apc_call",
  46     "apc_result_t"  => "&dump_apc_result",
  47     "luid_t"        => "&dump_luid",
  48 );
  49
  50 my @requests = ();
  51 my %replies = ();
  52
  53 my @trace_lines = ();
  54
  55
  56
  57 ### Generate a dumping function
  58
  59 sub DO_DUMP_FUNC($$@)
  60 {
  61     my $name = shift;
  62     my $req = shift;
  63     push @trace_lines, "static void dump_${name}_$req( const struct ${name}_$req *req )\n{\n";
  64     while ($#_ >= 0)
  65     {
  66         my $type = shift;
  67         my $var = shift;
  68         if (defined($formats{$type}))
  69         {
  70             if ($formats{$type} =~ /^&(.*)/)
  71             {
  72                 my $func = $1;
  73                 push @trace_lines, "    fprintf( stderr, \" $var=\" );\n";
  74                 push @trace_lines, "    $func( &req->$var );\n";
  75                 push @trace_lines, "    fprintf( stderr, \",\" );\n" if ($#_ > 0);
  76             }
  77             elsif ($formats{$type} =~ /^(%.*)\s+\((.*)\)/)
  78             {
  79                 my ($format, $cast) = ($1, $2);
  80                 push @trace_lines, "    fprintf( stderr, \" $var=$format";
  81                 push @trace_lines, "," if ($#_ > 0);
  82                 push @trace_lines, "\", ($cast)req->$var );\n";
  83             }
  84             else
  85             {
  86                 push @trace_lines, "    fprintf( stderr, \" $var=$formats{$type}";
  87                 push @trace_lines, "," if ($#_ > 0);
  88                 push @trace_lines, "\", req->$var );\n";
  89             }
  90         }
  91         else  # must be some varargs format
  92         {
  93             my $func = $type;
  94             push @trace_lines, "    fprintf( stderr, \" $var=\" );\n";
  95             push @trace_lines, "    $func;\n";
  96             push @trace_lines, "    fputc( ',', stderr );\n" if ($#_ > 0);
  97         }
  98     }
  99     push @trace_lines, "}\n\n";
 100 }
 101
 102 ### Parse the request definitions
 103
 104 sub PARSE_REQUESTS()
 105 {
 106     # states: 0 = header 1 = declarations 2 = inside @REQ 3 = inside @REPLY
 107     my $state = 0;
 108     my $name = "";
 109     my @in_struct = ();
 110     my @out_struct = ();
 111
 112     open(PROTOCOL,"server/protocol.def") or die "Can't open server/protocol.def";
 113
 114     while (<PROTOCOL>)
 115     {
 116         my ($type, $var);
 117         # strip comments
 118         s!/\*.*\*/!!g;
 119         # strip white space at end of line
 120         s/\s+$//;
 121
 122         if (/^\@HEADER/)
 123         {
 124             die "Misplaced \@HEADER" unless $state == 0;
 125             $state++;
 126             next;
 127         }
 128
 129         # ignore everything while in state 0
 130         next if $state == 0;
 131
 132         if (/^\@REQ\(\s*(\w+)\s*\)/)
 133         {
 134             $name = $1;
 135             die "Misplaced \@REQ" unless $state == 1;
 136             # start a new request
 137             @in_struct = ();
 138             @out_struct = ();
 139             print SERVER_PROT "struct ${name}_request\n{\n";
 140             print SERVER_PROT "    struct request_header __header;\n";
 141             $state++;
 142             next;
 143         }
 144
 145         if (/^\@REPLY/)
 146         {
 147             die "Misplaced \@REPLY" unless $state == 2;
 148             print SERVER_PROT "};\n";
 149             print SERVER_PROT "struct ${name}_reply\n{\n";
 150             print SERVER_PROT "    struct reply_header __header;\n";
 151             $state++;
 152             next;
 153         }
 154
 155         if (/^\@END/)
 156         {
 157             die "Misplaced \@END" unless ($state == 2 || $state == 3);
 158             print SERVER_PROT "};\n";
 159
 160             if ($state == 2)  # build dummy reply struct
 161             {
 162                 print SERVER_PROT "struct ${name}_reply\n{\n";
 163                 print SERVER_PROT "    struct reply_header __header;\n";
 164                 print SERVER_PROT "};\n";
 165             }
 166
 167             # got a complete request
 168             push @requests, $name;
 169             DO_DUMP_FUNC( $name, "request", @in_struct);
 170             if ($#out_struct >= 0)
 171             {
 172                 $replies{$name} = 1;
 173                 DO_DUMP_FUNC( $name, "reply", @out_struct);
 174             }
 175             $state = 1;
 176             next;
 177         }
 178
 179         if ($state != 1)
 180         {
 181             # skip empty lines (but keep them in output file)
 182             if (/^$/)
 183             {
 184                 print SERVER_PROT "\n";
 185                 next;
 186             }
 187
 188             if (/^\s*VARARG\((\w+),(\w+),(\w+)\)/)
 189             {
 190                 $var = $1;
 191                 $type = "dump_varargs_" . $2 . "( min(cur_size,req->" . $3 . ") )";
 192                 s!(VARARG\(.*\)\s*;)!/* $1 */!;
 193             }
 194             elsif (/^\s*VARARG\((\w+),(\w+)\)/)
 195             {
 196                 $var = $1;
 197                 $type = "dump_varargs_" . $2 . "( cur_size )";
 198                 s!(VARARG\(.*\)\s*;)!/* $1 */!;
 199             }
 200             elsif (/^\s*(\w+\**(\s+\w+\**)*)\s+(\w+);/)
 201             {
 202                 $type = $1;
 203                 $var = $3;
 204                 die "Unrecognized type $type" unless defined($formats{$type});
 205             }
 206             else
 207             {
 208                 die "Unrecognized syntax $_";
 209             }
 210             if ($state == 2) { push @in_struct, $type, $var; }
 211             if ($state == 3) { push @out_struct, $type, $var; }
 212         }
 213
 214         # Pass it through into the output file
 215         print SERVER_PROT $_ . "\n";
 216     }
 217     close PROTOCOL;
 218 }
 219
 220 ### Retrieve the server protocol version from the existing server_protocol.h file
 221
 222 sub GET_PROTOCOL_VERSION()
 223 {
 224     my $protocol = 0;
 225     open SERVER_PROT, "include/wine/server_protocol.h" or return 0;
 226     while (<SERVER_PROT>)
 227     {
 228         if (/^\#define SERVER_PROTOCOL_VERSION (\d+)/) { $protocol = $1; last; }
 229     }
 230     close SERVER_PROT;
 231     return $protocol;
 232 }
 233
 234 ### Retrieve the list of status and errors used in the server
 235
 236 sub GET_ERROR_NAMES()
 237 {
 238     my %errors = ();
 239     foreach my $f (glob "server/*.c")
 240     {
 241         open FILE, $f or die "Can't open $f";
 242         while (<FILE>)
 243         {
 244             if (/set_error\s*\(\s*STATUS_(\w+)\s*\)/)
 245             {
 246                 $errors{$1} = "STATUS_$1" unless $1 eq "SUCCESS";
 247             }
 248             elsif (/async_terminate_\w+\s*\(.*,\s*STATUS_(\w+)\s*\)/)
 249             {
 250                 $errors{$1} = "STATUS_$1" unless $1 eq "SUCCESS";
 251             }
 252             elsif (/set_win32_error\s*\(\s*(\w+)\s*\)/)
 253             {
 254                 $errors{$1} = "0xc0010000 | $1";
 255             }
 256         }
 257         close FILE;
 258     }
 259     return %errors;
 260 }
 261
 262 ### Replace the contents of a file between ### make_requests ### marks
 263
 264 sub REPLACE_IN_FILE($@)
 265 {
 266     my $name = shift;
 267     my @data = @_;
 268     my @lines = ();
 269     open(FILE,$name) or die "Can't open $name";
 270     while (<FILE>)
 271     {
 272         push @lines, $_;
 273         last if /\#\#\# make_requests begin \#\#\#/;
 274     }
 275     push @lines, "\n", @data;
 276     while (<FILE>)
 277     {
 278         if (/\#\#\# make_requests end \#\#\#/) { push @lines, "\n", $_; last; }
 279     }
 280     push @lines, <FILE>;
 281     open(FILE,">$name") or die "Can't modify $name";
 282     print FILE @lines;
 283     close(FILE);
 284 }
 285
 286 ### Main
 287
 288 # Get the server protocol version
 289 my $protocol = GET_PROTOCOL_VERSION();
 290
 291 my %errors = GET_ERROR_NAMES();
 292
 293 ### Create server_protocol.h and print header
 294
 295 open SERVER_PROT, ">include/wine/server_protocol.h" or die "Cannot create include/wine/server_protocol.h";
 296 print SERVER_PROT "/*\n * Wine server protocol definitions\n *\n";
 297 print SERVER_PROT " * This file is automatically generated; DO NO EDIT!\n";
 298 print SERVER_PROT " * Edit server/protocol.def instead and re-run tools/make_requests\n";
 299 print SERVER_PROT " */\n\n";
 300 print SERVER_PROT "#ifndef __WINE_WINE_SERVER_PROTOCOL_H\n";
 301 print SERVER_PROT "#define __WINE_WINE_SERVER_PROTOCOL_H\n";
 302
 303 ### Parse requests to find request/reply structure definitions
 304
 305 PARSE_REQUESTS();
 306
 307 ### Build the request list and structures
 308
 309 print SERVER_PROT "\n\nenum request\n{\n";
 310 foreach my $req (@requests) { print SERVER_PROT "    REQ_$req,\n"; }
 311 print SERVER_PROT "    REQ_NB_REQUESTS\n};\n\n";
 312
 313 print SERVER_PROT "union generic_request\n{\n";
 314 print SERVER_PROT "    struct request_max_size max_size;\n";
 315 print SERVER_PROT "    struct request_header request_header;\n";
 316 foreach my $req (@requests) { print SERVER_PROT "    struct ${req}_request ${req}_request;\n"; }
 317 print SERVER_PROT "};\n";
 318
 319 print SERVER_PROT "union generic_reply\n{\n";
 320 print SERVER_PROT "    struct request_max_size max_size;\n";
 321 print SERVER_PROT "    struct reply_header reply_header;\n";
 322 foreach my $req (@requests) { print SERVER_PROT "    struct ${req}_reply ${req}_reply;\n"; }
 323 print SERVER_PROT "};\n\n";
 324
 325 printf SERVER_PROT "#define SERVER_PROTOCOL_VERSION %d\n\n", $protocol + 1;
 326 print SERVER_PROT "#endif /* __WINE_WINE_SERVER_PROTOCOL_H */\n";
 327 close SERVER_PROT;
 328
 329 ### Output the dumping function tables
 330
 331 push @trace_lines, "static const dump_func req_dumpers[REQ_NB_REQUESTS] = {\n";
 332 foreach my $req (@requests)
 333 {
 334     push @trace_lines, "    (dump_func)dump_${req}_request,\n";
 335 }
 336 push @trace_lines, "};\n\n";
 337
 338 push @trace_lines, "static const dump_func reply_dumpers[REQ_NB_REQUESTS] = {\n";
 339 foreach my $req (@requests)
 340 {
 341     push @trace_lines, "    (dump_func)", $replies{$req} ? "dump_${req}_reply,\n" : "0,\n";
 342 }
 343 push @trace_lines, "};\n\n";
 344
 345 push @trace_lines, "static const char * const req_names[REQ_NB_REQUESTS] = {\n";
 346 foreach my $req (@requests)
 347 {
 348     push @trace_lines, "    \"$req\",\n";
 349 }
 350 push @trace_lines, "};\n\n";
 351
 352 push @trace_lines, "static const struct\n{\n";
 353 push @trace_lines, "    const char  *name;\n";
 354 push @trace_lines, "    unsigned int value;\n";
 355 push @trace_lines, "} status_names[] =\n{\n";
 356
 357 foreach my $err (sort keys %errors)
 358 {
 359     push @trace_lines, sprintf("    { %-30s %s },\n", "\"$err\",", $errors{$err});
 360 }
 361 push @trace_lines, "    { NULL, 0 }\n";
 362 push @trace_lines, "};\n";
 363
 364 REPLACE_IN_FILE( "server/trace.c", @trace_lines );
 365
 366 ### Output the request handlers list
 367
 368 my @request_lines = ();
 369
 370 foreach my $req (@requests) { push @request_lines, "DECL_HANDLER($req);\n"; }
 371 push @request_lines, "\n#ifdef WANT_REQUEST_HANDLERS\n\n";
 372 push @request_lines, "typedef void (*req_handler)( const void *req, void *reply );\n";
 373 push @request_lines, "static const req_handler req_handlers[REQ_NB_REQUESTS] =\n{\n";
 374 foreach my $req (@requests)
 375 {
 376     push @request_lines, "    (req_handler)req_$req,\n";
 377 }
 378 push @request_lines, "};\n#endif  /* WANT_REQUEST_HANDLERS */\n";
 379
 380 REPLACE_IN_FILE( "server/request.h", @request_lines );