configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 dnl autoconf versions before 2.62 don't handle source dir symlinks correctly
   8 AC_PREREQ(2.62)
   9 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org],[wine],[http://www.winehq.org])
  10 AC_CONFIG_SRCDIR(server/atom.c)
  11 AC_CONFIG_HEADERS(include/config.h)
  12 AC_CONFIG_AUX_DIR(tools)
  13
  14 dnl autoconf versions before 2.63b don't have AS_VAR_APPEND or AS_VAR_IF
  15 m4_ifdef([AS_VAR_APPEND],,[as_fn_append () { eval $[1]=\$$[1]\$[2]; }
  16 AC_DEFUN([AS_VAR_APPEND],[as_fn_append $1 $2])])dnl
  17 m4_ifdef([AS_VAR_IF],,[AC_DEFUN([AS_VAR_IF],
  18 [AS_LITERAL_IF([$1],
  19   [AS_IF([test "x$$1" = x""$2], [$3], [$4])],
  20   [eval as_val=\$$1
  21    AS_IF([test "x$as_val" = x""$2], [$3], [$4])])])])dnl
  22 dnl autoconf versions before 2.64 don't have AC_PACKAGE_URL
  23 m4_ifdef([AC_PACKAGE_URL],,
  24   [AC_DEFINE([PACKAGE_URL], ["http://www.winehq.org"], [Define to the home page for this package.])
  25    AC_SUBST([PACKAGE_URL], ["http://www.winehq.org"])])dnl
  26
  27 dnl **** Command-line arguments ****
  28
  29 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  30 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  31 AC_ARG_ENABLE(tests, AS_HELP_STRING([--disable-tests],[do not build the regression tests]))
  32 AC_ARG_ENABLE(maintainer-mode, AS_HELP_STRING([--enable-maintainer-mode],[enable maintainer-specific build rules]))
  33
  34 AC_ARG_WITH(alsa,      AS_HELP_STRING([--without-alsa],[do not use the Alsa sound support]),
  35             [if test "x$withval" = "xno"; then ac_cv_header_sys_asoundlib_h=no; ac_cv_header_alsa_asoundlib_h=no; fi])
  36 AC_ARG_WITH(audioio,   AS_HELP_STRING([--without-audioio],[do not use the AudioIO sound support]),
  37             [if test "x$withval" = "xno"; then ac_cv_header_libaudioio_h=no; fi])
  38 AC_ARG_WITH(capi,      AS_HELP_STRING([--without-capi],[do not use CAPI (ISDN support)]),
  39             [if test "x$withval" = "xno"; then ac_cv_header_capi20_h=no; ac_cv_header_linux_capi_h=no; fi])
  40 AC_ARG_WITH(cms,       AS_HELP_STRING([--without-cms],[do not use CMS (color management support)]),
  41             [if test "x$withval" = "xno"; then ac_cv_header_lcms_h=no; ac_cv_header_lcms_lcms_h=no; fi])
  42 AC_ARG_WITH(coreaudio, AS_HELP_STRING([--without-coreaudio],[do not use the CoreAudio sound support]),
  43             [if test "x$withval" = "xno"; then ac_cv_header_CoreAudio_CoreAudio_h=no; fi])
  44 AC_ARG_WITH(cups,      AS_HELP_STRING([--without-cups],[do not use CUPS]))
  45 AC_ARG_WITH(curses,    AS_HELP_STRING([--without-curses],[do not use (n)curses]),
  46             [if test "x$withval" = "xno"; then ac_cv_header_ncurses_h=no; ac_cv_header_curses_h=no; fi])
  47 AC_ARG_WITH(esd,       AS_HELP_STRING([--without-esd],[do not use the EsounD sound support]))
  48 AC_ARG_WITH(fontconfig,AS_HELP_STRING([--without-fontconfig],[do not use fontconfig]),
  49             [if test "x$withval" = "xno"; then ac_cv_header_fontconfig_fontconfig_h=no; fi])
  50 AC_ARG_WITH(freetype,  AS_HELP_STRING([--without-freetype],[do not use the FreeType library]))
  51 AC_ARG_WITH(gphoto,    AS_HELP_STRING([--without-gphoto],[do not use gphoto (Digital Camera support)]))
  52 AC_ARG_WITH(glu,       AS_HELP_STRING([--without-glu],[do not use the GLU library]),
  53             [if test "x$withval" = "xno"; then ac_cv_header_GL_glu_h=no; fi])
  54 AC_ARG_WITH(gnutls,    AS_HELP_STRING([--without-gnutls],[do not use GnuTLS (schannel support)]))
  55 AC_ARG_WITH(gsm,       AS_HELP_STRING([--without-gsm],[do not use libgsm (GSM 06.10 codec support)]),
  56             [if test "x$withval" = "xno"; then ac_cv_header_gsm_h=no; ac_cv_header_gsm_gsm_h=no; fi])
  57 AC_ARG_WITH(gstreamer, AS_HELP_STRING([--without-gstreamer],[do not use GStreamer (codecs support)]))
  58 AC_ARG_WITH(hal,       AS_HELP_STRING([--without-hal],[do not use HAL (dynamic device support)]))
  59 AC_ARG_WITH(icns,      AS_HELP_STRING([--without-icns],[do not use ICNS icon support]),
  60             [if test "x$withval" = "xno"; then ac_cv_header_icns_h=no; fi])
  61 AC_ARG_WITH(jack,      AS_HELP_STRING([--without-jack],[do not use the Jack sound support]),
  62             [if test "x$withval" = "xno"; then ac_cv_header_jack_jack_h=no; fi])
  63 AC_ARG_WITH(jpeg,      AS_HELP_STRING([--without-jpeg],[do not use JPEG]),
  64             [if test "x$withval" = "xno"; then ac_cv_header_jpeglib_h=no; fi])
  65 AC_ARG_WITH(ldap,      AS_HELP_STRING([--without-ldap],[do not use LDAP]),
  66             [if test "x$withval" = "xno"; then ac_cv_header_ldap_h=no; ac_cv_header_lber_h=no; fi])
  67 AC_ARG_WITH(mpg123,    AS_HELP_STRING([--without-mpg123],[do not use the mpg123 library]),
  68             [if test "x$withval" = "xno"; then ac_cv_header_mpg123_h=no; fi])
  69 AC_ARG_WITH(nas,       AS_HELP_STRING([--without-nas],[do not use the NAS sound support]),
  70             [if test "x$withval" = "xno"; then ac_cv_header_audio_audiolib_h=no; fi])
  71 AC_ARG_WITH(openal,    AS_HELP_STRING([--without-openal],[do not use OpenAL]),
  72             [if test "x$withval" = "xno"; then ac_cv_header_AL_al_h=no; ac_cv_header_OpenAL_al_h=no; fi])
  73 AC_ARG_WITH(opencl,    AS_HELP_STRING([--without-opencl],[do not use OpenCL]),
  74             [if test "x$withval" = "xno"; then ac_cv_header_CL_opencl_h=no; ac_cv_header_OpenCL_opencl_h=no; fi])
  75 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  76 AC_ARG_WITH(openssl,   AS_HELP_STRING([--without-openssl],[do not use OpenSSL]),
  77             [if test "x$withval" = "xno"; then ac_cv_header_openssl_err_h=no; ac_cv_header_openssl_ssl_h=no; fi])
  78 AC_ARG_WITH(oss,       AS_HELP_STRING([--without-oss],[do not use the OSS sound support]),
  79             [if test "x$withval" = "xno"; then ac_cv_header_soundcard_h=no; ac_cv_header_sys_soundcard_h=no; ac_cv_header_machine_soundcard_h=no; fi])
  80 AC_ARG_WITH(png,       AS_HELP_STRING([--without-png],[do not use PNG]),
  81             [if test "x$withval" = "xno"; then ac_cv_header_png_h=no; fi])
  82 AC_ARG_WITH(pthread,   AS_HELP_STRING([--without-pthread],[do not use the pthread library]),
  83             [if test "x$withval" = "xno"; then ac_cv_header_pthread_h=no; fi])
  84 AC_ARG_WITH(sane,      AS_HELP_STRING([--without-sane],[do not use SANE (scanner support)]))
  85 AC_ARG_WITH(tiff,       AS_HELP_STRING([--without-tiff],[do not use TIFF]),
  86             [if test "x$withval" = "xno"; then ac_cv_header_tiffio_h=no; fi])
  87 AC_ARG_WITH(v4l,       AS_HELP_STRING([--without-v4l],[do not use v4l1 (v4l support)]))
  88 AC_ARG_WITH(xcomposite,AS_HELP_STRING([--without-xcomposite],[do not use the Xcomposite extension]),
  89             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xcomposite_h=no; fi])
  90 AC_ARG_WITH(xcursor,   AS_HELP_STRING([--without-xcursor],[do not use the Xcursor extension]),
  91             [if test "x$withval" = "xno"; then ac_cv_header_X11_Xcursor_Xcursor_h=no; fi])
  92 AC_ARG_WITH(xinerama,  AS_HELP_STRING([--without-xinerama],[do not use Xinerama (multi-monitor support)]),
  93             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xinerama_h=no; fi])
  94 AC_ARG_WITH(xinput,    AS_HELP_STRING([--without-xinput],[do not use the Xinput extension]),
  95             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput_h=no; fi])
  96 AC_ARG_WITH(xml,       AS_HELP_STRING([--without-xml],[do not use XML]))
  97 AC_ARG_WITH(xrandr,    AS_HELP_STRING([--without-xrandr],[do not use Xrandr (resolution changes)]),
  98             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrandr_h=no; fi])
  99 AC_ARG_WITH(xrender,   AS_HELP_STRING([--without-xrender],[do not use the Xrender extension]),
 100             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrender_h=no; fi])
 101 AC_ARG_WITH(xshape,    AS_HELP_STRING([--without-xshape],[do not use the Xshape extension]),
 102             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_shape_h=no; fi])
 103 AC_ARG_WITH(xshm,      AS_HELP_STRING([--without-xshm],[do not use XShm (shared memory extension)]),
 104             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XShm_h=no; fi])
 105 AC_ARG_WITH(xslt,      AS_HELP_STRING([--without-xslt],[do not use XSLT]))
 106 AC_ARG_WITH(xxf86vm,   AS_HELP_STRING([--without-xxf86vm],[do not use XFree video mode extension]),
 107             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_xf86vmode_h=no; ac_cv_header_X11_extensions_xf86vmproto_h=no; fi])
 108
 109 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=DIR],[use Wine tools from directory DIR]))
 110 AC_ARG_WITH(wine64,    AS_HELP_STRING([--with-wine64=DIR],[use the 64-bit Wine in DIR for a Wow64 build]))
 111
 112 AC_CANONICAL_HOST
 113
 114 dnl check for out of tree build with unclean source tree
 115 case "$srcdir" in
 116  .) ;;
 117  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
 118       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
 119 You need to run 'make distclean' in the source tree first.])
 120     fi ;;
 121 esac
 122
 123 dnl **** Check for some programs ****
 124
 125 AC_PROG_MAKE_SET
 126 AC_PROG_CC
 127 AC_PROG_CXX
 128 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
 129 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
 130 AC_DEFINE_UNQUOTED(EXEEXT,["$ac_exeext"],[Define to the file extension for executables.])
 131
 132 case $host in
 133   *-darwin*)
 134     if test "x$enable_win64" = "xyes"
 135     then
 136       CC="$CC -m64"
 137       CXX="$CXX -m64"
 138       LD="${LD:-ld} -arch x86_64"
 139       AS="${AS:-as} -arch x86_64"
 140       host_cpu="x86_64"
 141       notice_platform="64-bit "
 142       AC_SUBST(TARGETFLAGS,"-m64")
 143     else
 144       CC="$CC -m32"
 145       CXX="$CXX -m32"
 146       LD="${LD:-ld} -arch i386"
 147       AS="${AS:-as} -arch i386"
 148       host_cpu="i386"
 149       notice_platform="32-bit "
 150       AC_SUBST(TARGETFLAGS,"-m32")
 151       enable_win16=${enable_win16:-yes}
 152     fi
 153     ;;
 154   x86_64*)
 155     if test "x$enable_win64" != "xyes" -a "$cross_compiling" != "yes"
 156     then
 157       CC="$CC -m32"
 158       CXX="$CXX -m32"
 159       AC_MSG_CHECKING([whether $CC works])
 160       AC_LINK_IFELSE(AC_LANG_PROGRAM(),AC_MSG_RESULT([yes]),
 161                      [AC_MSG_RESULT([no])
 162                       AC_MSG_ERROR([Cannot build a 32-bit program, you need to install 32-bit development libraries.])])
 163       LD="${LD:-ld} -m elf_i386"
 164       AS="${AS:-as} --32"
 165       host_cpu="i386"
 166       notice_platform="32-bit "
 167       AC_SUBST(TARGETFLAGS,"-m32")
 168       enable_win16=${enable_win16:-yes}
 169     else
 170       if test "x${GCC}" = "xyes"
 171       then
 172         AC_MSG_CHECKING([whether $CC supports __builtin_ms_va_list])
 173         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[void func(__builtin_ms_va_list *args);]])],
 174                           [AC_MSG_RESULT([yes])],
 175                           [AC_MSG_RESULT([no])
 176                            AC_MSG_ERROR([You need gcc >= 4.4 to build Wine as 64-bit.])])
 177       fi
 178       AC_SUBST(TARGETFLAGS,"-m64")
 179     fi
 180     ;;
 181   *-mingw32*|*-cygwin*)
 182     enable_win16=${enable_win16:-no}
 183     CFLAGS="$CFLAGS -D_WIN32"
 184     ;;
 185   i[[3456789]]86*)
 186     enable_win16=${enable_win16:-yes}
 187     ;;
 188 esac
 189
 190 dnl enable_win16 defaults to yes on x86, to no on other CPUs
 191 enable_win16=${enable_win16:-no}
 192
 193 dnl Disable winetest too if tests are disabled
 194 enable_winetest=${enable_winetest:-$enable_tests}
 195
 196 dnl Some special cases for the wow64 build
 197 if test -n "$with_wine64"
 198 then
 199     if test "x$enable_win64" = "xyes"
 200     then
 201         AC_MSG_ERROR([--enable-win64 and --with-wine64 are mutually exclusive.
 202 --enable-win64 should be used in the 64-bit build tree, --with-wine64 in the 32-bit Wow64 build tree.])
 203     fi
 204     AC_SUBST([WOW64_DISABLE],[\#])
 205     enable_fonts=${enable_fonts:-no}
 206     enable_server=${enable_server:-no}
 207     enable_tools=${enable_tools:-no}
 208 elif test "x$enable_win64" = "xyes"
 209 then
 210     test "x$libdir" != "x\${exec_prefix}/lib" || libdir="\${exec_prefix}/lib64"
 211 fi
 212
 213 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
 214   [wine_cv_toolsdir="$with_wine_tools"
 215    if test -z "$with_wine_tools"; then
 216      if test "$cross_compiling" = "yes"; then
 217        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
 218      elif test -n "$with_wine64"; then
 219        wine_cv_toolsdir="$with_wine64"
 220      fi
 221    fi
 222    if test -z "$wine_cv_toolsdir"; then
 223      wine_cv_toolsdir="\$(top_builddir)"
 224    elif test -d "$wine_cv_toolsdir/tools/winebuild"; then
 225      case "$wine_cv_toolsdir" in
 226        /*) ;;
 227        *)  wine_cv_toolsdir="\$(top_builddir)/$wine_cv_toolsdir" ;;
 228      esac
 229    else
 230      AC_MSG_ERROR([could not find Wine tools in $wine_cv_toolsdir])
 231    fi])
 232 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
 233 if test -n "$host_alias" -a "$host_alias" != "$build_alias"
 234 then
 235     AC_SUBST(TARGETFLAGS,"-b $host_alias $TARGETFLAGS")
 236 fi
 237
 238 dnl Check for flex
 239 AC_CHECK_PROGS(FLEX,flex,none)
 240 if test "$FLEX" = "none"
 241 then
 242   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
 243 fi
 244 AC_MSG_CHECKING([whether flex is recent enough])
 245 cat >conftest.l <<EOF
 246 %top{
 247 #include "prediluvian.h"
 248 }
 249 %%
 250 EOF
 251 if $FLEX -t conftest.l >/dev/null 2>&AS_MESSAGE_LOG_FD
 252 then
 253   AC_MSG_RESULT([yes])
 254 else
 255   AC_MSG_RESULT([no])
 256   AC_MSG_ERROR([Your flex version is too old. Please install flex version 2.5.33 or newer.])
 257 fi
 258
 259 dnl Check for bison
 260 AC_CHECK_PROGS(BISON,bison,none)
 261 if test "$BISON" = "none"
 262 then
 263   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 264 fi
 265
 266 AC_CHECK_TOOLS(AR,[ar gar],ar)
 267 AC_SUBST(ARFLAGS,rc)
 268 AC_PROG_RANLIB
 269 AC_CHECK_TOOL(STRIP,strip,strip)
 270 AC_PROG_LN_S
 271 AC_PROG_EGREP
 272 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 273 AC_PROG_INSTALL
 274 dnl Prepend src dir to install path dir if it's a relative path
 275 case "$INSTALL" in
 276   [[\\/$]]* | ?:[[\\/]]* ) ;;
 277   *)  INSTALL="\\\$(top_srcdir)/$INSTALL" ;;
 278 esac
 279
 280 dnl Check for lint
 281 AC_CHECK_PROGS(LINT, lclint lint)
 282 if test "$LINT" = "lint"
 283 then
 284   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 285   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 286 fi
 287 AC_SUBST(LINT)
 288 AC_SUBST(LINTFLAGS)
 289
 290 dnl Check for various programs
 291 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 292 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 293 AC_CHECK_PROGS(RSVG, rsvg, false)
 294 AC_CHECK_PROGS(CONVERT, convert, false)
 295 AC_CHECK_PROGS(ICOTOOL, icotool, false)
 296
 297 if test "x$enable_maintainer_mode" != "xyes"
 298 then
 299   AC_SUBST([MAINTAINER_MODE],[\#])
 300 else
 301   if test "$FONTFORGE" = "false"; then AC_MSG_ERROR([You need fontforge to rebuild fonts in maintainer mode.]); fi
 302   if test "$RSVG" = "false"; then AC_MSG_ERROR([You need rsvg to rebuild icons in maintainer mode.]); fi
 303
 304   dnl Check the imagemagick version
 305   if test "$CONVERT" = false
 306   then
 307     AC_MSG_ERROR([You need imagemagick to rebuild icons in maintainer mode.])
 308   else
 309     AC_MSG_CHECKING([for recent enough imagemagick])
 310     convert_version=`convert --version | head -n1`
 311     if test "x$convert_version" != "x"
 312     then
 313       convert_version_major=`expr "$convert_version" : '.* \([[0-9]]*\)\.[[0-9]]*'`
 314       convert_version_minor=`expr "$convert_version" : '.* [[0-9]]*\.\([[0-9]]*\)'`
 315       if test "$convert_version_major" -eq 6 -a "$convert_version_minor" -lt 6
 316       then
 317         CONVERT=false
 318       fi
 319     fi
 320     if test "$CONVERT" = false
 321     then
 322       AC_MSG_RESULT([no ($convert_version_major.$convert_version_minor)])
 323       AC_MSG_ERROR([You need imagemagick version 6.6 or newer to rebuild icons in maintainer mode.])
 324     else
 325       AC_MSG_RESULT([yes ($convert_version_major.$convert_version_minor)])
 326     fi
 327   fi
 328
 329   dnl Check the icotool version
 330   if test "$ICOTOOL" = false
 331   then
 332     AC_MSG_ERROR([You need icotool to rebuild icons in maintainer mode.])
 333   else
 334     AC_MSG_CHECKING([for recent enough icotool])
 335     icotool_version=`icotool --version | head -n1`
 336     if test "x$icotool_version" != "x"
 337     then
 338       icotool_version_major=`expr "$icotool_version" : '.* \([[0-9]]*\)\.[[0-9]]*'`
 339       icotool_version_minor=`expr "$icotool_version" : '.* [[0-9]]*\.\([[0-9]]*\)'`
 340       if test "$icotool_version_major" -eq 0 -a "$icotool_version_minor" -lt 29
 341       then
 342         ICOTOOL=false
 343         WINE_WARNING([icotool version 0.29.0 or newer is needed to rebuild icons.])
 344       fi
 345     fi
 346     if test "$ICOTOOL" = false
 347     then
 348       AC_MSG_RESULT([no ($icotool_version_major.$icotool_version_minor)])
 349       AC_MSG_ERROR([You need icotool version 0.29.0 or newer to rebuild icons in maintainer mode.])
 350     else
 351       AC_MSG_RESULT([yes ($icotool_version_major.$icotool_version_minor)])
 352     fi
 353   fi
 354
 355 fi
 356
 357 dnl **** Check for some libraries ****
 358
 359 dnl Check for -li386 for NetBSD and OpenBSD
 360 AC_CHECK_LIB(i386,i386_set_ldt)
 361 dnl Check for -lossaudio for NetBSD
 362 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 363
 364 AC_SUBST(XLIB,"")
 365 AC_SUBST(OPENGL_LIBS,"")
 366
 367 dnl **** Check for header files ****
 368
 369 AC_SYS_LARGEFILE()
 370
 371 AC_CHECK_HEADERS(\
 372         AL/al.h \
 373         AudioToolbox/AudioConverter.h \
 374         AudioUnit/AudioUnit.h \
 375         CL/opencl.h \
 376         Carbon/Carbon.h \
 377         CoreAudio/CoreAudio.h \
 378         DiskArbitration/DiskArbitration.h \
 379         IOKit/IOKitLib.h \
 380         IOKit/hid/IOHIDLib.h \
 381         OpenAL/al.h \
 382         OpenCL/opencl.h \
 383         alias.h \
 384         alsa/asoundlib.h \
 385         arpa/inet.h \
 386         arpa/nameser.h \
 387         asm/types.h \
 388         capi20.h \
 389         curses.h \
 390         direct.h \
 391         dirent.h \
 392         dlfcn.h \
 393         elf.h \
 394         float.h \
 395         fnmatch.h \
 396         fontconfig/fontconfig.h \
 397         getopt.h \
 398         grp.h \
 399         gsm.h \
 400         gsm/gsm.h \
 401         icns.h \
 402         ieeefp.h \
 403         inet/mib2.h \
 404         io.h \
 405         jack/jack.h \
 406         jpeglib.h \
 407         kstat.h \
 408         lber.h \
 409         lcms.h \
 410         lcms/lcms.h \
 411         ldap.h \
 412         libaudioio.h \
 413         link.h \
 414         linux/cdrom.h \
 415         linux/compiler.h \
 416         linux/hdreg.h \
 417         linux/input.h \
 418         linux/ioctl.h \
 419         linux/joystick.h \
 420         linux/major.h \
 421         linux/param.h \
 422         linux/serial.h \
 423         linux/types.h \
 424         linux/ucdrom.h \
 425         mach-o/nlist.h \
 426         mach-o/loader.h \
 427         mach/mach.h \
 428         mach/machine.h \
 429         machine/cpu.h \
 430         machine/limits.h \
 431         machine/soundcard.h \
 432         machine/sysarch.h \
 433         mntent.h \
 434         mpg123.h \
 435         ncurses.h \
 436         netdb.h \
 437         netinet/in.h \
 438         netinet/in_systm.h \
 439         netinet/tcp.h \
 440         netinet/tcp_fsm.h \
 441         openssl/err.h \
 442         openssl/ssl.h \
 443         png.h \
 444         poll.h \
 445         port.h \
 446         process.h \
 447         pthread.h \
 448         pwd.h \
 449         regex.h \
 450         sched.h \
 451         scsi/scsi.h \
 452         scsi/scsi_ioctl.h \
 453         scsi/sg.h \
 454         soundcard.h \
 455         stdbool.h \
 456         stdint.h \
 457         strings.h \
 458         stropts.h \
 459         sys/asoundlib.h \
 460         sys/cdio.h \
 461         sys/elf32.h \
 462         sys/epoll.h \
 463         sys/errno.h \
 464         sys/event.h \
 465         sys/exec_elf.h \
 466         sys/filio.h \
 467         sys/inotify.h \
 468         sys/ioctl.h \
 469         sys/ipc.h \
 470         sys/limits.h \
 471         sys/link.h \
 472         sys/mman.h \
 473         sys/modem.h \
 474         sys/msg.h \
 475         sys/mtio.h \
 476         sys/param.h \
 477         sys/poll.h \
 478         sys/prctl.h \
 479         sys/protosw.h \
 480         sys/ptrace.h \
 481         sys/resource.h \
 482         sys/scsiio.h \
 483         sys/shm.h \
 484         sys/signal.h \
 485         sys/socket.h \
 486         sys/socketvar.h \
 487         sys/sockio.h \
 488         sys/soundcard.h \
 489         sys/statvfs.h \
 490         sys/strtio.h \
 491         sys/syscall.h \
 492         sys/tihdr.h \
 493         sys/time.h \
 494         sys/timeout.h \
 495         sys/times.h \
 496         sys/uio.h \
 497         sys/un.h \
 498         sys/utsname.h \
 499         sys/vm86.h \
 500         sys/wait.h \
 501         syscall.h \
 502         termios.h \
 503         tiffio.h \
 504         unistd.h \
 505         utime.h \
 506         valgrind/memcheck.h \
 507         valgrind/valgrind.h \
 508         zlib.h
 509 )
 510 AC_HEADER_STAT()
 511
 512 dnl **** Checks for headers that depend on other ones ****
 513
 514 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/sysctl.h sys/user.h sys/vfs.h],,,
 515     [#include <sys/types.h>
 516      #ifdef HAVE_SYS_PARAM_H
 517      # include <sys/param.h>
 518      #endif])
 519
 520 AC_CHECK_HEADERS(\
 521         netinet/ip.h \
 522         net/if.h \
 523         net/if_arp.h \
 524         net/if_dl.h \
 525         net/if_types.h \
 526         net/route.h \
 527         netinet/if_ether.h \
 528         netinet/if_inarp.h \
 529         netinet/in_pcb.h \
 530         netinet/ip_icmp.h \
 531         netinet/ip_var.h \
 532         netinet/udp.h \
 533         netipx/ipx.h \
 534 ,,,[#include <sys/types.h>
 535      #ifdef HAVE_SYS_SOCKET_H
 536      # include <sys/socket.h>
 537      #endif
 538      #ifdef HAVE_SYS_SOCKETVAR_H
 539      # include <sys/socketvar.h>
 540      #endif
 541      #ifdef HAVE_NET_ROUTE_H
 542      # include <net/route.h>
 543      #endif
 544      #ifdef HAVE_NETINET_IN_H
 545      # include <netinet/in.h>
 546      #endif
 547      #ifdef HAVE_NETINET_IN_SYSTM_H
 548      # include <netinet/in_systm.h>
 549      #endif
 550      #ifdef HAVE_NET_IF_H
 551      # include <net/if.h>
 552      #endif
 553      #ifdef HAVE_NETINET_IP_H
 554      # include <netinet/ip.h>
 555      #endif])
 556
 557 AC_CHECK_HEADERS([netinet/tcp_timer.h netinet/udp_var.h netinet/icmp_var.h netinet/tcp_var.h ],,,
 558     [#include <sys/types.h>
 559      #ifdef HAVE_ALIAS_H
 560      # include <alias.h>
 561      #endif
 562      #ifdef HAVE_SYS_SOCKET_H
 563      # include <sys/socket.h>
 564      #endif
 565      #ifdef HAVE_SYS_SOCKETVAR_H
 566      # include <sys/socketvar.h>
 567      #endif
 568      #ifdef HAVE_SYS_TIMEOUT_H
 569      # include <sys/timeout.h>
 570      #endif
 571      #ifdef HAVE_NETINET_IN_H
 572      # include <netinet/in.h>
 573      #endif
 574      #ifdef HAVE_NETINET_IN_SYSTM_H
 575      # include <netinet/in_systm.h>
 576      #endif
 577      #ifdef HAVE_NETINET_IP_H
 578      # include <netinet/ip.h>
 579      #endif
 580      #ifdef HAVE_NETINET_IP_VAR_H
 581      # include <netinet/ip_var.h>
 582      #endif
 583      #ifdef HAVE_NETINET_IP_ICMP_H
 584      # include <netinet/ip_icmp.h>
 585      #endif
 586      #ifdef HAVE_NETINET_UDP_H
 587      # include <netinet/udp.h>
 588      #endif
 589      #ifdef HAVE_NETINET_TCP_H
 590      # include <netinet/tcp.h>
 591      #endif
 592      #ifdef HAVE_NETINET_TCP_TIMER_H
 593      #include <netinet/tcp_timer.h>
 594      #endif])
 595
 596 AC_CHECK_HEADERS([linux/ipx.h linux/irda.h],,,
 597     [#include <sys/types.h>
 598      #ifdef HAVE_ASM_TYPES_H
 599      # include <asm/types.h>
 600      #endif
 601      #ifdef HAVE_SYS_SOCKET_H
 602      # include <sys/socket.h>
 603      #endif
 604      #ifdef HAVE_LINUX_TYPES_H
 605      # include <linux/types.h>
 606      #endif])
 607
 608 AC_CHECK_HEADERS([mach-o/dyld_images.h],,,
 609     [#ifdef HAVE_STDBOOL_H
 610      # include <stdbool.h>
 611      #endif
 612      #ifdef HAVE_STDINT_H
 613      # include <stdint.h>
 614      #endif])
 615
 616 AC_CHECK_HEADERS([resolv.h],,,
 617     [#include <sys/types.h>
 618      #ifdef HAVE_SYS_SOCKET_H
 619      # include <sys/socket.h>
 620      #endif
 621      #ifdef HAVE_NETINET_IN_H
 622      # include <netinet/in.h>
 623      #endif
 624      #ifdef HAVE_ARPA_NAMESER_H
 625      # include <arpa/nameser.h>
 626      #endif])
 627
 628 AC_CHECK_HEADERS([ifaddrs.h],,,[#include <sys/types.h>])
 629
 630 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 631
 632 AC_CHECK_HEADERS([sys/thr.h],,,
 633 [#include <sys/types.h>
 634 #ifdef HAVE_UCONTEXT_H
 635 #include <ucontext.h>
 636 #endif])
 637
 638 AC_CHECK_HEADERS([pthread_np.h],,,
 639 [#ifdef HAVE_PTHREAD_H
 640 #include <pthread.h>
 641 #endif])
 642
 643 AC_CHECK_HEADERS([linux/videodev.h],,,
 644 [#ifdef HAVE_SYS_TIME_H
 645 #include <sys/time.h>
 646 #endif
 647 #include <sys/types.h>
 648 #ifdef HAVE_ASM_TYPES_H
 649 #include <asm/types.h>
 650 #endif])
 651
 652 dnl Check for broken kernel header that doesn't define __user
 653 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 654
 655 dnl **** Check for working dll ****
 656
 657 AC_SUBST(DLLEXT,"")
 658 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 659 AC_SUBST(LDSHARED,"")
 660 AC_SUBST(LDDLLFLAGS,"")
 661 AC_SUBST(LIBEXT,"so")
 662 AC_SUBST(IMPLIBEXT,"def")
 663 AC_SUBST(LDRPATH_INSTALL,"")
 664 AC_SUBST(LDRPATH_LOCAL,"")
 665 STATIC_IMPLIBEXT="def.a"
 666 WINE_PATH_LDD
 667
 668 case $host_os in
 669   cygwin*|mingw32*)
 670     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 671     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 672     if test "$DLLWRAP" = "false"; then
 673       LIBEXT="a"
 674     else
 675       dnl FIXME - check whether dllwrap works correctly...
 676       LIBEXT="dll"
 677     fi
 678     IMPLIBEXT="a"
 679     STATIC_IMPLIBEXT="a"
 680     dnl Disable modules that can't be used on Windows
 681     enable_iphlpapi=${enable_iphlpapi:-no}
 682     enable_kernel32=${enable_kernel32:-no}
 683     enable_msvcrt=${enable_msvcrt:-no}
 684     enable_ntdll=${enable_ntdll:-no}
 685     enable_ws2_32=${enable_ws2_32:-no}
 686     enable_loader=${enable_loader:-no}
 687     enable_server=${enable_server:-no}
 688     dnl Disable dependencies that are not useful on Windows
 689     with_x=${with_x:-no}
 690     with_pthread=${with_pthread:-no}
 691     ;;
 692   darwin*|macosx*)
 693     DLLEXT=".so"
 694     LIBEXT="dylib"
 695     DLLFLAGS="$DLLFLAGS -fPIC"
 696     LDDLLFLAGS="-bundle -multiply_defined suppress"
 697     LIBWINE_LDFLAGS="-multiply_defined suppress"
 698     LDSHARED="\$(CC) -dynamiclib"
 699     STRIP="$STRIP -x"
 700     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(top_builddir)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 701     dnl declare needed frameworks
 702     AC_SUBST(SECURITYLIB,"-framework Security -framework CoreFoundation")
 703     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 704     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 705     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHAREDHEAP,0x7f000000"])
 706     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 707     then
 708         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 709         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 710     fi
 711     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 712     then
 713         dnl CoreServices needed by AudioUnit
 714         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 715     fi
 716     if test "$ac_cv_header_OpenAL_al_h" = "yes"
 717     then
 718         AC_SUBST(FRAMEWORK_OPENAL,"-framework OpenAL")
 719         AC_DEFINE_UNQUOTED(HAVE_OPENAL,1,[Define to 1 if OpenAL is available])
 720         ac_cv_lib_openal=yes
 721     fi
 722     if test "$ac_cv_header_OpenCL_opencl_h" = "yes"
 723     then
 724         AC_SUBST(LIBOPENCL,"-framework OpenCL")
 725         ac_cv_lib_OpenCL_clGetPlatformInfo=yes
 726     fi
 727     if test "$ac_cv_header_IOKit_hid_IOHIDLib_h" = "yes"
 728     then
 729         ac_save_LIBS="$LIBS"
 730         LIBS="$LIBS $IOKITLIB"
 731         AC_CHECK_FUNCS(IOHIDManagerCreate)
 732         LIBS="$ac_save_LIBS"
 733     fi
 734     case $host_cpu in
 735       *powerpc*)
 736         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 737         ;;
 738     esac
 739     dnl Enable quartz driver on Mac OS X
 740     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 741     then
 742         AC_SUBST(CARBONLIB,"-framework Carbon")
 743         enable_winequartz_drv=${enable_winequartz_drv:-yes}
 744     fi
 745     dnl Check for Xcode 3.x broken 16-bit support
 746     if test "x$enable_win16" = "xyes"
 747     then
 748         AC_MSG_CHECKING([whether 16-bit code can be built correctly])
 749         AC_RUN_IFELSE(AC_LANG_PROGRAM([[asm(".text\n"
 750                                             "bad:\tnop;nop\n"
 751                                             "good:\tnop;nop\n\t"
 752                                             ".globl _testfunc\n"
 753                                             "_testfunc:\tcallw good");
 754                                         extern void testfunc();]],
 755                                       [[unsigned short *p = (unsigned short *)testfunc;
 756                                         return p[[0]] != 0xe866 || p[[1]] != 0xfffa]]),
 757                                       AC_MSG_RESULT(yes),
 758                                       [AC_MSG_RESULT(no)
 759                                        AC_MSG_ERROR([Xcode 3.x cannot build 16-bit code correctly. Use --disable-win16 if you don't need 16-bit support.])],
 760                                        AC_MSG_RESULT([[cross-compiling, assuming yes]]))
 761     fi
 762     ;;
 763   *)
 764     DLLFLAGS="$DLLFLAGS -fPIC"
 765     DLLEXT=".so"
 766     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 767         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 768                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 769     if test "$ac_cv_c_dll_gnuelf" = "yes"
 770     then
 771       LDSHARED="\$(CC) -shared"
 772       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 773       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 774                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 775                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 776                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 777
 778       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 779
 780       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 781                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 782
 783       echo '{ global: *; };' >conftest.map
 784       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 785                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 786       rm -f conftest.map
 787
 788       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 789                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 790
 791       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 792                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 793                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(top_builddir)/libs/wine"],
 794           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 795                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 796                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(top_builddir)/libs/wine"])])
 797
 798       WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 799                       [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 800
 801       case $host_cpu in
 802         *i[[3456789]]86* | x86_64)
 803           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 804                           [case $host_os in
 805                            freebsd*)  LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x60000400" ;;
 806                            *) LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400" ;;
 807                            esac
 808                           ])
 809           AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 810           if test "x$PRELINK" = xfalse
 811           then
 812               WINE_WARNING([prelink not found, base address of core dlls won't be set correctly.])
 813           fi
 814           ;;
 815       esac
 816
 817     else
 818       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 819           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 820                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 821       if test "$ac_cv_c_dll_unixware" = "yes"
 822       then
 823         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 824         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 825
 826       else
 827         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 828           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 829         if test "$ac_cv_c_dll_hpux" = "yes"
 830         then
 831           LIBEXT="sl"
 832           DLLEXT=".sl"
 833           LDDLLFLAGS="-shared -fPIC"
 834           LDSHARED="\$(CC) -shared"
 835         fi
 836       fi
 837     fi
 838     ;;
 839 esac
 840
 841 enable_winequartz_drv=${enable_winequartz_drv:-no}
 842
 843 if test "$LIBEXT" = "a"; then
 844   AC_MSG_ERROR(
 845 [could not find a way to build shared libraries.
 846 It is currently not possible to build Wine without shared library
 847 (.so) support to allow transparent switch between .so and .dll files.
 848 If you are using Linux, you will need a newer binutils.]
 849 )
 850 fi
 851
 852 dnl Check for cross compiler to build test programs
 853 AC_SUBST([CROSSTEST_DISABLE],[\#])
 854 if test "$cross_compiling" = "no" -a "x$enable_tests" != xno -a "$LIBEXT" != "dll"
 855 then
 856     WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 857     if test "$CROSSCC" != "false"
 858     then
 859         ac_save_CC="$CC"
 860         CC="$CROSSCC"
 861         AC_MSG_CHECKING([whether $CROSSCC works])
 862         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 863                           [AC_MSG_RESULT([yes])
 864                            set x $CROSSCC
 865                            shift
 866                            target=""
 867                            while test $# -ge 1
 868                            do
 869                                case "$1" in
 870                                  *-gcc) target=`expr "$1" : '\(.*\)-gcc'` ;;
 871                                esac
 872                                shift
 873                            done
 874                            if test -n "$target"
 875                            then
 876                                CROSSTEST_DISABLE=""
 877                                AC_SUBST(CROSSTARGET,"$target")
 878                            fi],
 879                           [AC_MSG_RESULT([no])])
 880         CC="$ac_save_CC"
 881     fi
 882 fi
 883
 884 dnl **** Check for pthread ****
 885
 886 if test "$ac_cv_header_pthread_h" = "yes"
 887 then
 888     AC_CHECK_LIB(pthread,pthread_create,[AC_SUBST(LIBPTHREAD,"-lpthread")])
 889 fi
 890 WINE_ERROR_WITH(pthread,[test "x$LIBPTHREAD" = "x"],[pthread ${notice_platform}development files not found.
 891 Wine cannot support threads without libpthread.])
 892
 893 dnl **** Check for X11 ****
 894
 895 AC_PATH_XTRA
 896
 897 if test "$have_x" = "yes"
 898 then
 899     XLIB="-lX11"
 900     ac_save_CPPFLAGS="$CPPFLAGS"
 901     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 902
 903     WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
 904     WINE_CHECK_SONAME(Xext,XextCreateExtension,[XLIB="-lXext $XLIB"],,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 905
 906     dnl *** All of the following tests require X11/Xlib.h
 907     AC_CHECK_HEADERS([X11/Xlib.h \
 908                       X11/XKBlib.h \
 909                       X11/Xutil.h \
 910                       X11/Xcursor/Xcursor.h \
 911                       X11/extensions/shape.h \
 912                       X11/extensions/XInput.h \
 913                       X11/extensions/XShm.h \
 914                       X11/extensions/Xcomposite.h \
 915                       X11/extensions/Xinerama.h \
 916                       X11/extensions/Xrandr.h \
 917                       X11/extensions/Xrender.h \
 918                       X11/extensions/xf86vmode.h \
 919                       X11/extensions/xf86vmproto.h],,,
 920 [#ifdef HAVE_X11_XLIB_H
 921 # include <X11/Xlib.h>
 922 #endif
 923 #ifdef HAVE_X11_XUTIL_H
 924 # include <X11/Xutil.h>
 925 #endif])
 926
 927         dnl *** Check for X keyboard extension
 928         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 929         then
 930               AC_CHECK_LIB(X11, XkbQueryExtension,
 931               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 932               $X_LIBS $XLIB $X_EXTRA_LIBS)
 933         fi
 934
 935         dnl *** Check for X cursor
 936         if test "$ac_cv_header_X11_Xcursor_Xcursor_h" = "yes"
 937         then
 938             WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
 939         fi
 940         WINE_NOTICE_WITH(xcursor,[test "x$ac_cv_lib_soname_Xcursor" = "x"],
 941                          [libxcursor ${notice_platform}development files not found, the Xcursor extension won't be supported.])
 942
 943         dnl *** Check for X input extension
 944         if test "$ac_cv_header_X11_extensions_XInput_h" = "yes"
 945         then
 946             WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
 947         fi
 948         WINE_NOTICE_WITH(xinput,[test "x$ac_cv_lib_soname_Xi" = "x"],
 949                          [libxi ${notice_platform}development files not found, the Xinput extension won't be supported.])
 950
 951         dnl *** Check for X Shm extension
 952         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 953         then
 954               AC_CHECK_LIB(Xext, XShmQueryExtension,
 955               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 956               $X_LIBS $XLIB $X_EXTRA_LIBS)
 957         fi
 958         WINE_NOTICE_WITH(xshm,[test "$ac_cv_lib_Xext_XShmQueryExtension" != "yes"],
 959                          [XShm ${notice_platform}development files not found, X Shared Memory won't be supported.])
 960
 961         dnl *** Check for X shape extension
 962         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 963         then
 964               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 965               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 966               $X_LIBS $XLIB $X_EXTRA_LIBS)
 967         fi
 968         WINE_NOTICE_WITH(xshape,[test "$ac_cv_lib_Xext_XShapeQueryExtension" != "yes"],
 969                          [XShape ${notice_platform}development files not found, XShape won't be supported.])
 970
 971         dnl *** Check for XFree86 VMODE extension
 972         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes" -o "$ac_cv_header_X11_extensions_xf86vmproto_h" = "yes"
 973         then
 974             WINE_CHECK_SONAME(Xxf86vm,XF86VidModeQueryExtension,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
 975         fi
 976         WINE_NOTICE_WITH(xxf86vm,[test "x$ac_cv_lib_soname_Xxf86vm" = "x"],
 977                          [libXxf86vm ${notice_platform}development files not found, XFree86 Vidmode won't be supported.])
 978
 979         dnl *** Check for Transform functions in Xrender
 980         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes" -a "x$ac_cv_lib_soname_X11" != "x" -a "x$ac_cv_lib_soname_Xext" != "x"
 981         then
 982             WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,
 983               [AC_CHECK_LIB(Xrender,XRenderSetPictureTransform,
 984                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 985                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 986                 [$X_LIBS $XLIB $X_EXTRA_LIBS])],,[$X_LIBS $XLIB $X_EXTRA_LIBS])
 987
 988         fi
 989         WINE_WARNING_WITH(xrender,[test "x$ac_cv_lib_soname_Xrender" = "x"],
 990                          [libxrender ${notice_platform}development files not found, XRender won't be supported.])
 991
 992         dnl *** Check for X RandR extension
 993         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes" -a "x$ac_cv_lib_soname_Xrender" != "x"
 994         then
 995                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 996 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func;]])],
 997                   [WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])])
 998         fi
 999         WINE_NOTICE_WITH(xrandr,[test "x$ac_cv_lib_soname_Xrandr" = "x"],
1000                          [libxrandr ${notice_platform}development files not found, XRandr won't be supported.])
1001
1002         dnl *** Check for Xinerama extension
1003         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
1004         then
1005                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1006 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func;]])],
1007                   [WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])])
1008         fi
1009         WINE_NOTICE_WITH(xinerama,[test "x$ac_cv_lib_soname_Xinerama" = "x"],
1010                          [libxinerama ${notice_platform}development files not found, multi-monitor setups won't be supported.])
1011
1012         dnl *** Check for X Composite extension
1013         if test "$ac_cv_header_X11_extensions_Xcomposite_h" = "yes"
1014         then
1015             WINE_CHECK_SONAME(Xcomposite,XCompositeRedirectWindow,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1016         fi
1017         WINE_NOTICE_WITH(xcomposite,[test "x$ac_cv_lib_soname_Xcomposite" = "x"],
1018                          [libxcomposite ${notice_platform}development files not found, Xcomposite won't be supported.])
1019
1020         dnl *** Check for XICCallback struct
1021         AC_CHECK_MEMBERS([XICCallback.callback],,,
1022 [#ifdef HAVE_X11_XLIB_H
1023 #include <X11/Xlib.h>
1024 #endif])
1025
1026     dnl *** End of X11/Xlib.h check
1027
1028     dnl Check for the presence of OpenGL
1029     opengl_msg=""
1030     if test "x$with_opengl" != "xno"
1031     then
1032         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glu.h,,,
1033 [#ifdef HAVE_GL_GLX_H
1034 # include <GL/glx.h>
1035 #endif])
1036         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
1037         then
1038             dnl Check for some problems due to old Mesa versions
1039             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
1040               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;]])],
1041                 [wine_cv_opengl_header_version_OK="yes"],
1042                 [wine_cv_opengl_header_version_OK="no"]))
1043
1044             if test "$wine_cv_opengl_header_version_OK" = "yes"
1045             then
1046                 dnl Check for the presence of the library
1047                 WINE_CHECK_SONAME(GL,glXCreateContext,
1048                              [OPENGL_LIBS="-lGL"
1049                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
1050                              [WINE_CHECK_SONAME(GL,glXCreateContext,
1051                                     [OPENGL_LIBS="-Xlinker -dylib_file -Xlinker /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -lGL"
1052                                     AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
1053                                     [if test -f /usr/X11R6/lib/libGL.a
1054                                     then
1055                                         opengl_msg="/usr/X11R6/lib/libGL.a is present on your system.
1056 This probably prevents linking to OpenGL. Try deleting the file and restarting configure."
1057                                     else
1058                                         opengl_msg="No OpenGL library found on this system."
1059                                     fi],
1060                                     $X_LIBS $XLIB -lm $X_EXTRA_LIBS -dylib_file /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib)],
1061                              $X_LIBS $XLIB -lm $X_EXTRA_LIBS)
1062                  if test "$ac_cv_header_GL_glu_h" = "yes"
1063                  then
1064                     WINE_CHECK_SONAME(GLU,gluLookAt,,,[$OPENGL_LIBS $X_LIBS $X_PRE_LIBS $XLIB -lm $X_EXTRA_LIBS])
1065                  fi
1066                  WINE_NOTICE_WITH(glu,[test "x$ac_cv_lib_soname_GLU" = "x"],
1067                                  [libGLU ${notice_platform}development files not found, GLU won't be supported.])
1068              else
1069                  opengl_msg="Old Mesa headers detected. Consider upgrading your Mesa libraries."
1070              fi
1071          else
1072              opengl_msg="OpenGL development headers not found."
1073          fi
1074          test -n "$opengl_msg" && enable_opengl32=${enable_opengl32:-no}
1075          test "x$ac_cv_lib_soname_GLU" = "x" && enable_glu32=${enable_glu32:-no}
1076     else
1077          enable_opengl32=${enable_opengl32:-no}
1078          enable_glu32=${enable_glu32:-no}
1079     fi
1080     WINE_WARNING_WITH(opengl,[test -n "$opengl_msg"],[$opengl_msg
1081 OpenGL and Direct3D won't be supported.])
1082
1083     dnl **** Check for NAS ****
1084     AC_SUBST(NASLIBS,"")
1085     AC_CHECK_HEADERS(audio/audiolib.h,
1086          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
1087           AC_CHECK_LIB(audio,AuCreateFlow,
1088                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
1089                         AC_CHECK_LIB(Xau,XauGetBestAuthByAddr,
1090                           [NASLIBS="-lXau -laudio -lXt $X_LIBS $XLIB $X_EXTRA_LIBS"],
1091                           [NASLIBS="-laudio -lXt $X_LIBS $XLIB $X_EXTRA_LIBS"],
1092                           [$X_LIBS])
1093                        ],,
1094                        [-lXt $X_LIBS $XLIB $X_EXTRA_LIBS])])
1095
1096     CPPFLAGS="$ac_save_CPPFLAGS"
1097 else
1098     XLIB=""
1099     X_CFLAGS=""
1100     X_LIBS=""
1101     enable_winex11_drv=${enable_winex11_drv:-no}
1102     enable_opengl32=${enable_opengl32:-no}
1103     enable_glu32=${enable_glu32:-no}
1104 fi
1105 WINE_ERROR_WITH(x,[test "x$XLIB" = "x"],[X ${notice_platform}development files not found. Wine will be built
1106 without X support, which probably isn't what you want. You will need
1107 to install ${notice_platform}development packages of Xlib/Xfree86 at the very least.])
1108
1109 dnl **** Check for OpenCL ****
1110 if test "$ac_cv_header_CL_opencl_h" = "yes"
1111 then
1112     AC_CHECK_LIB(OpenCL,clGetPlatformInfo,[AC_SUBST(LIBOPENCL,["-lOpenCL"])])
1113 fi
1114 WINE_NOTICE_WITH(opencl,[test "x$ac_cv_lib_OpenCL_clGetPlatformInfo" != xyes],
1115                  [OpenCL ${notice_platform}development files not found, OpenCL won't be supported.])
1116 test "x$ac_cv_lib_OpenCL_clGetPlatformInfo" != xyes && enable_opencl=${enable_opencl:-no}
1117
1118 dnl **** Check for libxml2 ****
1119
1120 AC_SUBST(XML2LIBS,"")
1121 AC_SUBST(XML2INCL,"")
1122 AC_SUBST(XSLTINCL,"")
1123 if test "x$with_xml" != "xno"
1124 then
1125     ac_save_CPPFLAGS="$CPPFLAGS"
1126     if test "$PKG_CONFIG" != "false"
1127     then
1128         ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
1129         ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
1130     else
1131         ac_xml_libs="`xml2-config --libs 2>/dev/null`"
1132         ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
1133     fi
1134     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
1135     AC_CHECK_HEADERS(libxml/parser.h,
1136             [AC_CHECK_LIB(xml2, xmlParseMemory,
1137                 [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
1138                  XML2LIBS="$ac_xml_libs"
1139                  XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
1140              AC_CHECK_LIB(xml2, xmlReadMemory,
1141                 [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
1142              AC_CHECK_LIB(xml2, xmlNewDocPI,
1143                 [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
1144              AC_CHECK_LIB(xml2, xmlSchemaSetParserStructuredErrors,
1145                 [AC_DEFINE(HAVE_XMLSCHEMASSETPARSERSTRUCTUREDERRORS,1,[Define if libxml2 has the xmlSchemaSetParserStructuredErrors function])],,$ac_xml_libs)
1146              AC_CHECK_LIB(xml2, xmlSchemaSetValidStructuredErrors,
1147                 [AC_DEFINE(HAVE_XMLSCHEMASSETVALIDSTRUCTUREDERRORS,1,[Define if libxml2 has the xmlSchemaSetValidStructuredErrors function])],,$ac_xml_libs)
1148              AC_CHECK_LIB(xml2, xmlFirstElementChild,
1149                 [AC_DEFINE(HAVE_XMLFIRSTELEMENTCHILD,1,[Define if libxml2 has the xmlFirstElementChild function])],,$ac_xml_libs)
1150              AC_CHECK_TYPE([xmlDocProperties],
1151                 [AC_DEFINE(HAVE_XMLDOC_PROPERTIES,1,[Define if libxml2 has the xmlDocProperties enum])],,[[#include <libxml/tree.h>]])
1152         ])
1153     CPPFLAGS="$ac_save_CPPFLAGS"
1154 fi
1155 WINE_WARNING_WITH(xml,[test "$ac_cv_lib_xml2_xmlParseMemory" != "yes"],
1156                  [libxml2 ${notice_platform}development files not found, XML won't be supported.])
1157
1158 if test "x$with_xslt" != "xno"
1159 then
1160     if test "$PKG_CONFIG" != "false"
1161     then
1162         ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
1163         ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
1164     else
1165         ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
1166         ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
1167     fi
1168     ac_save_CPPFLAGS="$CPPFLAGS"
1169     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
1170     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],,,
1171     [#ifdef HAVE_LIBXSLT_PATTERN_H
1172 # include <libxslt/pattern.h>
1173 #endif])
1174     CPPFLAGS="$ac_save_CPPFLAGS"
1175     if test "$ac_cv_header_libxslt_transform_h" = "yes"
1176     then
1177         WINE_CHECK_SONAME(xslt,xsltCompilePattern,
1178                          [XSLTINCL="$ac_xslt_cflags"],,[$ac_xslt_libs])
1179     fi
1180 fi
1181 WINE_WARNING_WITH(xslt,[test "x$ac_cv_lib_soname_xslt" = "x"],
1182                  [libxslt ${notice_platform}development files not found, xslt won't be supported.])
1183
1184 dnl **** Check for libhal ****
1185 AC_SUBST(HALINCL,"")
1186 if test "x$with_hal" != "xno"
1187 then
1188     ac_save_CPPFLAGS="$CPPFLAGS"
1189     if test "$PKG_CONFIG" != "false"
1190     then
1191         ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
1192         ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
1193         CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
1194     fi
1195     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
1196     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
1197     then
1198         AC_CHECK_LIB(dbus-1, dbus_connection_close,
1199           [WINE_CHECK_SONAME(hal, libhal_ctx_new,
1200             [HALINCL="$ac_hal_cflags"],,[$ac_hal_libs])],,[$ac_hal_libs])
1201     fi
1202     CPPFLAGS="$ac_save_CPPFLAGS"
1203 fi
1204 WINE_NOTICE_WITH(hal,[test "x$ac_cv_lib_soname_hal" = "x" -a "x$ac_cv_header_DiskArbitration_DiskArbitration_h" != "xyes"],
1205                  [libhal/libdbus ${notice_platform}development files not found, no dynamic device support.])
1206
1207 dnl **** Check for libgnutls ****
1208 if test "x$with_gnutls" != "xno"
1209 then
1210     ac_save_CPPFLAGS="$CPPFLAGS"
1211     if test "$PKG_CONFIG" != "false"
1212     then
1213         ac_gnutls_libs="`$PKG_CONFIG --libs gnutls 2>/dev/null`"
1214         ac_gnutls_cflags="`$PKG_CONFIG --cflags gnutls 2>/dev/null`"
1215         CPPFLAGS="$CPPFLAGS $ac_gnutls_cflags"
1216     fi
1217     AC_CHECK_HEADER(gnutls/gnutls.h,
1218         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <gnutls/gnutls.h>]], [[typeof(gnutls_mac_get_key_size) *pfunc;]])],
1219             [WINE_CHECK_SONAME(gnutls,gnutls_global_init,
1220                 [AC_SUBST(GNUTLSINCL,"$ac_gnutls_cflags")],,[$ac_gnutls_libs])])])
1221     CPPFLAGS="$ac_save_CPPFLAGS"
1222 fi
1223 WINE_NOTICE_WITH(gnutls,[test "x$ac_cv_lib_soname_gnutls" = "x"],
1224                  [libgnutls ${notice_platform}development files not found, no schannel support.])
1225
1226 dnl **** Check which curses lib to use ***
1227 CURSESLIBS=""
1228 if test "$ac_cv_header_ncurses_h" = "yes"
1229 then
1230     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
1231 elif test "$ac_cv_header_curses_h" = "yes"
1232 then
1233     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
1234 fi
1235 ac_save_LIBS="$LIBS"
1236 LIBS="$LIBS $CURSESLIBS"
1237 AC_CHECK_FUNCS(mousemask)
1238 LIBS="$ac_save_LIBS"
1239 WINE_NOTICE_WITH(curses,[test "x$ac_cv_lib_soname_curses$ac_cv_lib_soname_ncurses" = "x"],
1240                  [lib(n)curses ${notice_platform}development files not found, curses won't be supported.])
1241
1242 dnl **** Check for SANE ****
1243 if test "x$with_sane" != "xno"
1244 then
1245     ac_save_CPPFLAGS="$CPPFLAGS"
1246     AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
1247     if test "$sane_devel" != "no"
1248     then
1249         ac_sane_incl="`$sane_devel --cflags`"
1250         ac_sane_libs="`$sane_devel --ldflags`"
1251         CPPFLAGS="$CPPFLAGS $ac_sane_incl"
1252     fi
1253     AC_CHECK_HEADER(sane/sane.h,
1254         [WINE_CHECK_SONAME(sane,sane_init,[AC_SUBST(SANEINCL,"$ac_sane_incl")],,[$ac_sane_libs])])
1255     CPPFLAGS="$ac_save_CPPFLAGS"
1256 fi
1257 WINE_NOTICE_WITH(sane,[test "x$ac_cv_lib_soname_sane" = "x"],
1258                  [libsane ${notice_platform}development files not found, scanners won't be supported.])
1259
1260 dnl **** Check for libv4l1 ****
1261 if test "x$with_v4l" != "xno"
1262 then
1263     WINE_CHECK_SONAME(v4l1,v4l1_open,,,)
1264 fi
1265 WINE_NOTICE_WITH(v4l,[test "x$ac_cv_lib_soname_v4l1" = "x"],
1266                  [libv4l ${notice_platform}development files not found.])
1267
1268 dnl **** Check for libgphoto2 ****
1269 if test "x$with_gphoto" != "xno"
1270 then
1271     ac_save_CPPFLAGS="$CPPFLAGS"
1272     AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
1273     AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
1274     if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
1275     then
1276         ac_gphoto2_incl="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
1277         ac_gphoto2_libs=""
1278         for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
1279         do
1280             case "$i" in
1281             -L/usr/lib|-L/usr/lib64) ;;
1282             -L*|-l*) ac_gphoto2_libs="$ac_gphoto2_libs $i";;
1283             esac
1284         done
1285         CPPFLAGS="$CPPFLAGS $ac_gphoto2_incl"
1286     fi
1287     ac_gphoto2_libs=${ac_gphoto2_libs:-"-lgphoto2"}
1288     AC_CHECK_HEADER(gphoto2-camera.h,
1289                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
1290                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])
1291                                    AC_SUBST(GPHOTO2LIBS,"$ac_gphoto2_libs")
1292                                    AC_SUBST(GPHOTO2INCL,"$ac_gphoto2_incl")],,
1293                                   [$ac_gphoto2_libs])])
1294     CPPFLAGS="$ac_save_CPPFLAGS"
1295 fi
1296 WINE_NOTICE_WITH(gphoto,[test "$ac_cv_lib_gphoto2_gp_camera_new" != "yes"],
1297                  [libgphoto2 ${notice_platform}development files not found, digital cameras won't be supported.])
1298
1299
1300 dnl **** Check for resolver library ***
1301 if test "$ac_cv_header_resolv_h" = "yes"
1302 then
1303     ac_save_LIBS="$LIBS"
1304     for lib in '' -lresolv
1305     do
1306       LIBS="$lib $ac_save_LIBS"
1307       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_NETINET_IN_H
1308 #include <netinet/in.h>
1309 #endif
1310 #include <resolv.h>]],[[res_query("foo",ns_c_in,0,0,0);]])],
1311         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
1312          AC_SUBST(RESOLVLIBS,"$lib")])
1313       if test "${RESOLVLIBS+set}" = set; then
1314         break
1315       fi
1316     done
1317     LIBS="$ac_save_LIBS"
1318 fi
1319
1320 dnl **** Check for LittleCMS ***
1321 AC_SUBST(LCMSLIBS,"")
1322 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
1323 then
1324     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
1325         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
1326          LCMSLIBS="-llcms"])
1327 fi
1328 WINE_NOTICE_WITH(cms,[test "$ac_cv_lib_lcms_cmsOpenProfileFromFile" != "yes"],
1329                  [liblcms ${notice_platform}development files not found, Color Management won't be supported.])
1330
1331 dnl **** Check for FreeType 2 ****
1332 if test "x$with_freetype" != "xno"
1333 then
1334     AC_CHECK_PROGS(ft_devel,[freetype-config freetype2-config],no)
1335     if test "$ft_devel" != "no"
1336     then
1337         ac_freetype_incl=`$ft_devel --cflags`
1338         ac_freetype_libs=`$ft_devel --libs`
1339     fi
1340     ac_freetype_libs=${ac_freetype_libs:-"-lfreetype"}
1341     WINE_CHECK_SONAME(freetype,FT_Init_FreeType,[ft_lib=yes],[ft_lib=no],[$ac_freetype_libs])
1342     if test "$ft_lib" = "yes"
1343     then
1344         ac_save_CPPFLAGS="$CPPFLAGS"
1345         CPPFLAGS="$ac_freetype_incl $CPPFLAGS"
1346         AC_CHECK_HEADERS(ft2build.h \
1347                          freetype/freetype.h \
1348                          freetype/ftglyph.h \
1349                          freetype/fttypes.h \
1350                          freetype/tttables.h \
1351                          freetype/ftsnames.h \
1352                          freetype/ttnameid.h \
1353                          freetype/ftoutln.h \
1354                          freetype/ftwinfnt.h \
1355                          freetype/ftmodapi.h \
1356                          freetype/ftlcdfil.h \
1357                          freetype/internal/sfnt.h,,,
1358                          [#ifdef HAVE_FT2BUILD_H
1359                           # include <ft2build.h>
1360                           #endif])
1361         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
1362                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
1363           [Define if you have the <freetype/fttrigon.h> header file.])
1364                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
1365         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
1366         ac_save_CFLAGS="$CFLAGS"
1367         CFLAGS="$CFLAGS $ac_freetype_libs"
1368         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
1369         CFLAGS="$ac_save_CFLAGS"
1370         CPPFLAGS="$ac_save_CPPFLAGS"
1371         dnl Check that we have at least freetype/freetype.h
1372         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
1373         then
1374             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
1375             AC_SUBST(FREETYPELIBS,"$ac_freetype_libs")
1376             AC_SUBST(FREETYPEINCL,"$ac_freetype_incl")
1377         fi
1378     fi
1379 fi
1380 WINE_ERROR_WITH(freetype,[test "x$FREETYPELIBS" = "x"],[FreeType ${notice_platform}development files not found. Fonts will not be built.])
1381 test "x$FREETYPELIBS" = "x" && enable_fonts=${enable_fonts:-no}
1382
1383 dnl **** Check for parport (currently Linux only) ****
1384 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
1385  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_SYS_IOCTL_H
1386 # include <sys/ioctl.h>
1387 #endif
1388 #include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
1389     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
1390 if test "$ac_cv_c_ppdev" = "yes"
1391 then
1392     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
1393 fi
1394
1395 dnl **** Check for pthread functions ****
1396 WINE_CHECK_LIB_FUNCS(\
1397         pthread_attr_get_np \
1398         pthread_getattr_np \
1399         pthread_get_stackaddr_np \
1400         pthread_get_stacksize_np,
1401         [$LIBPTHREAD])
1402
1403 dnl **** Check for zlib ****
1404 if test "$ac_cv_header_zlib_h" = "yes"
1405 then
1406     AC_CHECK_LIB(z,inflate,[AC_DEFINE(HAVE_ZLIB,1,[Define to 1 if you have the `z' library (-lz).])
1407                             AC_SUBST(ZLIB,"-lz")])
1408 fi
1409
1410 dnl **** Check for EsounD ****
1411 if test "x$with_esd" != xno
1412 then
1413     save_CFLAGS="$CFLAGS"
1414     AC_PATH_PROG(ESDCONFIG, esd-config, no)
1415     if test "x$ESDCONFIG" != "xno"
1416     then
1417         ac_esd_incl=""
1418         for i in `$ESDCONFIG --cflags`
1419         do
1420             case "$i" in
1421                 -I*) ac_esd_incl="$ac_esd_incl $i";;
1422             esac
1423         done
1424         ac_esd_libs=`$ESDCONFIG --libs`
1425         CFLAGS="$CFLAGS $ac_esd_incl"
1426     fi
1427     ac_esd_libs=${ac_esd_libs:-"-lesd"}
1428     AC_CHECK_HEADER(esd.h,
1429         [AC_CHECK_LIB(esd,esd_open_sound,
1430             [AC_SUBST(ESDINCL, "$ac_esd_incl")
1431              AC_SUBST(ESDLIBS, "$ac_esd_libs")
1432              AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])],,
1433             [$ac_esd_libs])])
1434     CFLAGS="$save_CFLAGS"
1435 fi
1436
1437 dnl **** Check for gstreamer ****
1438 if test "x$with_gstreamer" != "xno"
1439 then
1440     ac_save_CPPFLAGS="$CPPFLAGS"
1441     if test "$PKG_CONFIG" != "false"; then
1442         ac_gst_incl=""
1443         for i in `$PKG_CONFIG --cflags gstreamer-app-0.10 2>/dev/null`
1444         do
1445             case "$i" in
1446                 -I*) ac_gst_incl="$ac_gst_incl $i";;
1447             esac
1448         done
1449         ac_gst_libs="`$PKG_CONFIG --libs gstreamer-app-0.10 2>/dev/null`"
1450         CPPFLAGS="$CPPFLAGS $ac_gst_incl"
1451         AC_CHECK_HEADER([gst/gstpad.h],
1452           [AC_CHECK_HEADER([gst/app/gstappsink.h],
1453              [AC_CHECK_LIB(gstreamer-0.10,gst_pad_get_caps_reffed,
1454                 [AC_CHECK_LIB(gstapp-0.10,gst_app_buffer_new,
1455                     [AC_SUBST(GSTREAMER_LIBS,"$ac_gst_libs")
1456                      AC_SUBST(GSTREAMER_INCL,"$ac_gst_incl")],,[$ac_gst_libs])])])])
1457     fi
1458     CPPFLAGS="$ac_save_CPPFLAGS"
1459 fi
1460 WINE_NOTICE_WITH(gstreamer,[test "x$ac_cv_lib_gstapp_0_10_gst_app_buffer_new" != xyes],
1461                  [gstreamer-0.10 ${notice_platform}development files not found, gstreamer support disabled])
1462 test "x$ac_cv_lib_gstapp_0_10_gst_app_buffer_new" = xyes || enable_winegstreamer=${enable_winegstreamer:-no}
1463
1464 dnl **** Check for ALSA 1.x ****
1465 AC_SUBST(ALSALIBS,"")
1466 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
1467 then
1468     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
1469         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
1470 #include <alsa/asoundlib.h>
1471 #elif defined(HAVE_SYS_ASOUNDLIB_H)
1472 #include <sys/asoundlib.h>
1473 #endif]], [[int ret = snd_pcm_hw_params_get_access(NULL, NULL)]])],
1474                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
1475                          ALSALIBS="-lasound"],[])])
1476 fi
1477
1478 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
1479 AC_SUBST(AUDIOIOLIBS,"")
1480 if test "$ac_cv_header_libaudioio_h" = "yes"
1481 then
1482     AC_CHECK_LIB(audioio,AudioIOGetVersion,
1483                   [AUDIOIOLIBS="-laudioio"
1484                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
1485 fi
1486
1487 dnl **** Check for capi4linux ****
1488
1489 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
1490 then
1491     WINE_CHECK_SONAME(capi20,capi20_register)
1492 fi
1493 WINE_NOTICE_WITH(capi,[test "x$ac_cv_lib_soname_capi20" = "x"],
1494                  [libcapi20 ${notice_platform}development files not found, ISDN won't be supported.])
1495
1496 dnl **** Check for cups ****
1497 AC_SUBST(CUPSINCL,"")
1498 if test "x$with_cups" != "xno"
1499 then
1500     ac_save_CPPFLAGS="$CPPFLAGS"
1501     ac_cups_cflags=`cups-config --cflags 2>/dev/null`
1502     ac_cups_libs=`cups-config --ldflags 2>/dev/null`
1503     CPPFLAGS="$CPPFLAGS $ac_cups_cflags"
1504     AC_CHECK_HEADERS(cups/cups.h,
1505             [WINE_CHECK_SONAME(cups,cupsGetDefault,
1506                        [CUPSINCL="$ac_cups_cflags"],,
1507                        [$ac_cups_libs])])
1508     CPPFLAGS="$ac_save_CPPFLAGS"
1509 fi
1510 WINE_NOTICE_WITH(cups,[test "x$ac_cv_lib_soname_cups" = "x"],
1511                  [libcups ${notice_platform}development files not found, CUPS won't be supported.])
1512
1513 dnl **** Check for jack ****
1514 if test "$ac_cv_header_jack_jack_h" = "yes"
1515 then
1516     WINE_CHECK_SONAME(jack,jack_client_new,,,,[[libjack-*[[0-9.]]*]])
1517 fi
1518
1519 dnl **** Check for fontconfig ****
1520 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1521 then
1522     WINE_CHECK_SONAME(fontconfig,FcInit)
1523 elif test -n "$X_CFLAGS" -a "x$with_fontconfig" != "xno"
1524 then
1525     dnl fontconfig is in the X directory on Mac OS X
1526     ac_save_CPPFLAGS="$CPPFLAGS"
1527     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1528     $as_unset ac_cv_header_fontconfig_fontconfig_h
1529     AC_CHECK_HEADERS([fontconfig/fontconfig.h])
1530     CPPFLAGS="$ac_save_CPPFLAGS"
1531     if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1532     then
1533         AC_SUBST(FONTCONFIGINCL,"$X_CFLAGS")
1534         WINE_CHECK_SONAME(fontconfig,FcInit,,,[$X_LIBS])
1535     fi
1536 fi
1537 WINE_NOTICE_WITH(fontconfig,[test "x$ac_cv_lib_soname_fontconfig" = "x"],
1538                  [fontconfig ${notice_platform}development files not found, fontconfig won't be supported.])
1539
1540 dnl **** Check for SSL ****
1541 if test "$ac_cv_header_openssl_err_h" = "yes" -a "$ac_cv_header_openssl_ssl_h" = "yes"
1542 then
1543     WINE_CHECK_SONAME(ssl,SSL_library_init)
1544     WINE_CHECK_SONAME(crypto,BIO_new_socket)
1545 fi
1546 WINE_WARNING_WITH(openssl,[test "x$ac_cv_lib_soname_ssl" = "x" -o "x$ac_cv_lib_soname_crypto" = "x"],
1547                  [OpenSSL ${notice_platform}development files not found, SSL won't be supported.])
1548
1549 dnl **** Check for gsm codec ****
1550 if test "$ac_cv_header_gsm_h" = "yes" -o "$ac_cv_header_gsm_gsm_h" = "yes"
1551 then
1552     WINE_CHECK_SONAME(gsm,gsm_create)
1553 fi
1554 WINE_NOTICE_WITH(gsm,[test "x$ac_cv_lib_soname_gsm" = "x"],
1555                  [libgsm ${notice_platform}development files not found, gsm 06.10 codec won't be supported.])
1556
1557 dnl **** Check for libicns ****
1558 if test "$ac_cv_header_icns_h" = "yes"
1559 then
1560     WINE_CHECK_SONAME(icns,icns_write_family_to_file)
1561 fi
1562 case $host_os in
1563   darwin*|macosx*)
1564     WINE_NOTICE_WITH(icns,[test "x$ac_cv_lib_soname_icns" = "x"],
1565                      [libicns ${notice_platform}development files not found, ICNS icons won't be supported.]) ;;
1566 esac
1567
1568 dnl **** Check for libjpeg ****
1569 if test "$ac_cv_header_jpeglib_h" = "yes"
1570 then
1571     WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1572 fi
1573 WINE_WARNING_WITH(jpeg,[test "x$ac_cv_lib_soname_jpeg" = "x"],
1574                  [libjpeg ${notice_platform}development files not found, JPEG won't be supported.])
1575
1576 dnl **** Check for libpng ****
1577 if test "$ac_cv_header_png_h" = "yes"
1578 then
1579     WINE_CHECK_SONAME(png,png_create_read_struct,,,-lm -lz,[[libpng[[0-9]]*]])
1580     AC_CHECK_LIB(png,png_set_expand_gray_1_2_4_to_8,
1581         [AC_DEFINE(HAVE_PNG_SET_EXPAND_GRAY_1_2_4_TO_8,1,[Define to 1 if libpng has the png_set_expand_gray_1_2_4_to_8 function.])]
1582         ,,-lm -lz)
1583 elif test -n "$X_CFLAGS" -a "x$with_png" != "xno"
1584 then
1585     dnl libpng is in the X directory on Mac OS X
1586     ac_save_CPPFLAGS="$CPPFLAGS"
1587     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1588     $as_unset ac_cv_header_png_h
1589     AC_CHECK_HEADERS([png.h])
1590     CPPFLAGS="$ac_save_CPPFLAGS"
1591     if test "$ac_cv_header_png_h" = "yes"
1592     then
1593         AC_SUBST(PNGINCL,"$X_CFLAGS")
1594         WINE_CHECK_SONAME(png,png_create_read_struct,,,[$X_LIBS -lm -lz],[[libpng[[0-9]]*]])
1595         AC_CHECK_LIB(png,png_set_expand_gray_1_2_4_to_8,
1596                 [AC_DEFINE(HAVE_PNG_SET_EXPAND_GRAY_1_2_4_TO_8,1)],,[$X_LIBS -lm -lz])
1597     fi
1598 fi
1599 WINE_WARNING_WITH(png,[test "x$ac_cv_lib_soname_png" = "x"],
1600                  [libpng ${notice_platform}development files not found, PNG won't be supported.])
1601
1602 dnl **** Check for libtiff ****
1603 if test "$ac_cv_header_tiffio_h" = "yes"
1604 then
1605     WINE_CHECK_SONAME(tiff,TIFFClientOpen)
1606 fi
1607 WINE_NOTICE_WITH(tiff,[test "x$ac_cv_lib_soname_tiff" = "x"],
1608                  [libtiff ${notice_platform}development files not found, TIFF won't be supported.])
1609
1610 dnl **** Check for mpg123 ****
1611 if test "$ac_cv_header_mpg123_h" = "yes"
1612 then
1613     AC_CHECK_LIB(mpg123,mpg123_feed,[AC_SUBST(LIBMPG123,"-lmpg123")])
1614 fi
1615 WINE_NOTICE_WITH(mpg123,[test "x$ac_cv_lib_mpg123_mpg123_feed" != xyes -a x"$ac_cv_header_CoreAudio_CoreAudio_h" != xyes],
1616                  [libmpg123 ${notice_platform}development files not found (or too old), mp3 codec won't be supported.])
1617 test "x$ac_cv_lib_mpg123_mpg123_feed" = xyes -o "x$ac_cv_header_AudioToolbox_AudioConverter_h" = xyes || enable_winemp3_acm=${enable_winemp3_acm:-no}
1618
1619 dnl **** Check for OpenAL 1.1 ****
1620 if test "$ac_cv_header_AL_al_h" = "yes"
1621 then
1622     WINE_CHECK_SONAME(openal,alGetSource3i,[AC_SUBST(LIBOPENAL,"-lopenal")
1623                       ac_cv_lib_openal=yes
1624                       AC_DEFINE_UNQUOTED(HAVE_OPENAL,1,[Define to 1 if OpenAL is available])],,)
1625 fi
1626 WINE_NOTICE_WITH(openal,[test "x$ac_cv_lib_openal" != xyes],
1627                  [libopenal ${notice_platform}development files not found (or too old), OpenAL won't be supported.])
1628 test "x$ac_cv_lib_openal" = xyes || enable_openal32=${enable_openal32:-no}
1629
1630 dnl **** Check for libkstat ****
1631 if test "$ac_cv_header_kstat_h" = "yes"
1632 then
1633     AC_CHECK_LIB(kstat,kstat_open,
1634                  [AC_DEFINE(HAVE_LIBKSTAT, 1, [Define to 1 if you have the `kstat' library (-lkstat).])
1635                   AC_SUBST(LIBKSTAT,"-lkstat")])
1636 fi
1637
1638 dnl **** Check for libodbc ****
1639 WINE_CHECK_SONAME(odbc,SQLConnect,,[AC_DEFINE_UNQUOTED(SONAME_LIBODBC,["libodbc.$LIBEXT"])])
1640
1641 dnl **** Check for any sound system ****
1642 if test "x$ALSALIBS$AUDIOIOLIBS$COREAUDIO$NASLIBS$ESDLIBS$ac_cv_lib_soname_jack" = "x" -a \
1643         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1644         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1645         "$ac_cv_header_soundcard_h" != "yes" -a \
1646         "x$with_alsa$with_audioio$with_coreaudio$with_nas$with_esd$with_jack$with_oss" != xnonononononono
1647 then
1648     WINE_WARNING([No sound system was found. Windows applications will be silent.])
1649 fi
1650
1651 dnl **** Check for gcc specific options ****
1652
1653 AC_SUBST(EXTRACFLAGS,"")
1654 if test "x${GCC}" = "xyes"
1655 then
1656   EXTRACFLAGS="-Wall -pipe"
1657
1658   dnl Check for strength-reduce bug
1659   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1660                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1661 [[static int Array[[3]];
1662   unsigned int B = 3;
1663   int i;
1664   for(i=0; i<B; i++) Array[[i]] = i - 3;
1665   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1666   L[[i]] = 4;
1667   return (Array[[1]] != -2 || L[[2]] != 3)]])],
1668     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1669   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1670   then
1671     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1672   fi
1673
1674   dnl Check for some compiler flags
1675   WINE_TRY_CFLAGS([-fno-builtin],[AC_SUBST(BUILTINFLAG,"-fno-builtin")])
1676   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1677   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1678   WINE_TRY_CFLAGS([-Wstrict-prototypes])
1679   WINE_TRY_CFLAGS([-Wtype-limits])
1680   WINE_TRY_CFLAGS([-Wwrite-strings])
1681
1682   dnl Check for noisy string.h
1683   saved_CFLAGS="$CFLAGS"
1684   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1685   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
1686       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1687   CFLAGS="$saved_CFLAGS"
1688   if test "$ac_cv_c_string_h_warnings" = "no"
1689   then
1690     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1691   fi
1692
1693   dnl Enable -Werror for maintainer mode
1694   if test "x$enable_maintainer_mode" = "xyes"
1695   then
1696       WINE_TRY_CFLAGS([-Werror])
1697   fi
1698
1699   dnl Check for ms_hook_prologue support
1700   saved_CFLAGS="$CFLAGS"
1701   CFLAGS="$CFLAGS -Werror"
1702   AC_CACHE_CHECK([for ms_hook_prologue attribute], ac_cv_have_ms_hook_prologue,
1703                  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[int __attribute__((__ms_hook_prologue__)) test(void) { return 0; }]])],
1704                                    [ac_cv_have_ms_hook_prologue="yes"],[ac_cv_have_ms_hook_prologue="no"]))
1705   CFLAGS="$saved_CFLAGS"
1706   if test "$ac_cv_have_ms_hook_prologue" = "yes"
1707   then
1708       AC_DEFINE(DECLSPEC_HOTPATCH, [__attribute__((__ms_hook_prologue__))],
1709                 [Define to a function attribute for Microsoft hotpatch assembly prefix.])
1710   else
1711       AC_DEFINE(DECLSPEC_HOTPATCH, [/* */])
1712   fi
1713 fi
1714
1715 dnl **** Disable Fortify, it has too many false positives
1716
1717 AC_CACHE_CHECK([for the need to disable Fortify], ac_cv_c_fortify_enabled,
1718     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]],
1719 [[#if defined(__USE_FORTIFY_LEVEL) && __USE_FORTIFY_LEVEL > 0
1720 #error Fortify enabled
1721 #endif]])],
1722         [ac_cv_c_fortify_enabled=no],[ac_cv_c_fortify_enabled=yes]))
1723 if test "$ac_cv_c_fortify_enabled" = yes
1724 then
1725     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=0"
1726 fi
1727
1728 dnl **** Check for underscore on external symbols ****
1729
1730 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1731     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1732                       [extern int ac_test;],
1733                       [if (ac_test) return 1],
1734                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1735
1736 case $host_cpu in
1737   *i[[3456789]]86*)
1738     AC_CACHE_CHECK([whether external symbols need stdcall decoration], ac_cv_c_stdcall_suffix,
1739         WINE_TRY_ASM_LINK(["jmp _ac_test@4"],
1740 [#ifndef _MSC_VER
1741 #define __stdcall __attribute__((__stdcall__))
1742 #endif
1743 int __stdcall ac_test(int i) { return i; }],
1744                           [if (ac_test(1)) return 1],
1745                           ac_cv_c_stdcall_suffix="yes",ac_cv_c_stdcall_suffix="no")) ;;
1746   *) ac_cv_c_stdcall_suffix="no" ;;
1747 esac
1748
1749 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1750 if test "$ac_cv_c_extern_prefix" = "yes"
1751 then
1752     AC_DEFINE([__ASM_NAME(name)], ["_" name])
1753     asm_name_prefix="_"
1754 else
1755     AC_DEFINE([__ASM_NAME(name)], [name])
1756     asm_name_prefix=""
1757 fi
1758
1759 AH_TEMPLATE(__ASM_STDCALL,[Define to a macro to generate an stdcall suffix])
1760 if test "$ac_cv_c_stdcall_suffix" = "yes"
1761 then
1762     AC_DEFINE([__ASM_STDCALL(args)],["@" #args])
1763 else
1764     AC_DEFINE([__ASM_STDCALL(args)],[""])
1765 fi
1766
1767 dnl **** Check how to define a function in assembly code ****
1768
1769 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1770   WINE_TRY_ASM_LINK(
1771       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1772       ac_cv_asm_func_def=".def",
1773     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1774       ac_cv_asm_func_def=".type @function",
1775     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1776       ac_cv_asm_func_def=".type 2",
1777       ac_cv_asm_func_def="unknown")])]))
1778
1779 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1780 case "$ac_cv_asm_func_def" in
1781   ".def")
1782      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"])
1783      asm_func_header=".def $asm_name_prefix\" #name suffix \"; .scl 2; .type 32; .endef" ;;
1784   ".type @function")
1785      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"])
1786      asm_func_header=".type $asm_name_prefix\" #name suffix \",@function" ;;
1787   ".type 2")
1788      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"])
1789      asm_func_header=".type $asm_name_prefix\" #name suffix \",2" ;;
1790   *)
1791      AC_DEFINE([__ASM_FUNC(name)], [""])
1792      asm_func_header="" ;;
1793 esac
1794
1795 AC_CACHE_CHECK([whether asm() works outside of functions], ac_cv_c_asm_outside_funcs,
1796     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[asm(".text\n\t.long 0");]],)],
1797                       ac_cv_c_asm_outside_funcs="yes",ac_cv_c_asm_outside_funcs="no"))
1798
1799 AC_CACHE_CHECK([whether .previous is supported in assembly code], ac_cv_c_dot_previous,
1800     WINE_TRY_ASM_LINK([".text\nac_test:\t.long 0\n\t.previous"],,,
1801                       ac_cv_c_dot_previous="yes",ac_cv_c_dot_previous="no"))
1802
1803 AC_CACHE_CHECK([whether CFI directives are supported in assembly code], ac_cv_c_cfi_support,
1804     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[asm(".text\nac_test:\t.cfi_startproc\n\t.long 0\n\t.cfi_endproc");]])],
1805                       ac_cv_c_cfi_support="yes",ac_cv_c_cfi_support="no"))
1806
1807 asm_func_header=".globl $asm_name_prefix\" #name suffix \"\\n\\t$asm_func_header\\n$asm_name_prefix\" #name suffix \":\\n\\t"
1808 asm_func_trailer=""
1809 if test "$ac_cv_c_dot_previous" = "yes"
1810 then
1811    asm_func_trailer="\\n\\t.previous"
1812 fi
1813 if test "$ac_cv_c_cfi_support" = "yes"
1814 then
1815    asm_func_header="$asm_func_header.cfi_startproc\\n\\t"
1816    asm_func_trailer="\\n\\t.cfi_endproc$asm_func_trailer"
1817    AC_DEFINE([__ASM_CFI(str)],[str],[Define to a macro to output a .cfi assembly pseudo-op])
1818    AC_SUBST([UNWINDFLAGS],[-fasynchronous-unwind-tables])
1819 else
1820    AC_DEFINE([__ASM_CFI(str)],[""])
1821 fi
1822
1823 asm_func_code="$asm_func_header\" code \"$asm_func_trailer"
1824
1825 AH_TEMPLATE(__ASM_DEFINE_FUNC,[Define to a macro to define an assembly function])
1826 if test "$ac_cv_c_asm_outside_funcs" = "yes"
1827 then
1828     AC_DEFINE_UNQUOTED([__ASM_DEFINE_FUNC(name,suffix,code)],[asm(".text\n\t.align 4\n\t$asm_func_code");])
1829 else
1830     AC_DEFINE_UNQUOTED([__ASM_DEFINE_FUNC(name,suffix,code)],[void __asm_dummy_##name(void) { asm(".text\n\t.align 4\n\t$asm_func_code"); }])
1831 fi
1832 AC_DEFINE([__ASM_GLOBAL_FUNC(name,code)],[__ASM_DEFINE_FUNC(name,"",code)],
1833           [Define to a macro to generate an assembly function with C calling convention])
1834 AC_DEFINE([__ASM_STDCALL_FUNC(name,args,code)],[__ASM_DEFINE_FUNC(name,__ASM_STDCALL(args),code)],
1835           [Define to a macro to generate an assembly function with stdcall calling convention])
1836
1837 dnl **** Platform-specific checks ****
1838
1839 AC_SUBST(LDPATH,"")
1840 case $build_os in
1841   cygwin*|mingw32*)
1842     AC_SUBST(TOOLSEXT,".exe")
1843     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1844     ;;
1845   darwin*|macosx*)
1846     ;;
1847   *)
1848     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1849     ;;
1850 esac
1851
1852 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1853 case $host_os in
1854   mingw32*)
1855     AC_SUBST(CRTLIBS,"-lmsvcrt")
1856     AC_SUBST(SOCKETLIBS,"-L\$(top_builddir)/dlls/ws2_32 -lws2_32")
1857     ;;
1858 esac
1859
1860 AC_SUBST(MAIN_BINARY,"wine")
1861 test "x$enable_win64" != "xyes" || MAIN_BINARY="wine64"
1862
1863 case $host_cpu in
1864   *i[[3456789]]86*)
1865     case $host_os in
1866       linux*)
1867         AC_SUBST(EXTRA_BINARIES,"wine-preloader") ;;
1868     esac
1869     ;;
1870 esac
1871
1872 dnl **** Check for functions ****
1873
1874 ac_save_CFLAGS="$CFLAGS"
1875 CFLAGS="$CFLAGS $BUILTINFLAG"
1876 AC_CHECK_FUNCS(\
1877         _pclose \
1878         _popen \
1879         _snprintf \
1880         _spawnvp \
1881         _strdup \
1882         _stricmp \
1883         _strnicmp \
1884         _strtoi64 \
1885         _strtoui64 \
1886         _vsnprintf \
1887         asctime_r \
1888         chsize \
1889         dlopen \
1890         epoll_create \
1891         ffs \
1892         finite \
1893         fnmatch \
1894         fork \
1895         fpclass \
1896         fstatfs \
1897         fstatvfs \
1898         ftruncate \
1899         futimes \
1900         futimesat \
1901         getdirentries \
1902         getopt_long \
1903         getpagesize \
1904         getpwuid \
1905         gettid \
1906         gettimeofday \
1907         getuid \
1908         kqueue \
1909         lstat \
1910         memmove \
1911         mmap \
1912         pclose \
1913         pipe2 \
1914         poll \
1915         popen \
1916         port_create \
1917         prctl \
1918         pread \
1919         pwrite \
1920         readdir \
1921         readlink \
1922         sched_setaffinity \
1923         sched_yield \
1924         select \
1925         setproctitle \
1926         setrlimit \
1927         settimeofday \
1928         sigaltstack \
1929         sigprocmask \
1930         snprintf \
1931         spawnvp \
1932         statfs \
1933         statvfs \
1934         strcasecmp \
1935         strdup \
1936         strerror \
1937         strncasecmp \
1938         strtold \
1939         strtoll \
1940         strtoull \
1941         symlink \
1942         tcgetattr \
1943         thr_kill2 \
1944         timegm \
1945         usleep \
1946         vsnprintf \
1947         wait4 \
1948         waitpid \
1949 )
1950 CFLAGS="$ac_save_CFLAGS"
1951
1952 dnl Check for -ldl
1953 if test "$ac_cv_func_dlopen" = no
1954 then
1955     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1956 fi
1957 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1958
1959 dnl Check for -lpoll for Mac OS X/Darwin
1960 if test "$ac_cv_func_poll" = no
1961 then
1962     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1963 fi
1964
1965 dnl Check for -lnsl for Solaris
1966 AC_SEARCH_LIBS(gethostbyname, nsl)
1967
1968 dnl Check for -lsocket for Solaris
1969 AC_SEARCH_LIBS(connect, socket)
1970
1971 dnl Check for -lresolv for Solaris
1972 AC_SEARCH_LIBS(inet_aton, resolv)
1973
1974 dnl **** Check for functions which may rely on -lsocket on Solaris.
1975 AC_CHECK_FUNCS(\
1976         getaddrinfo \
1977         getnameinfo \
1978         getnetbyname \
1979         getprotobyname \
1980         getprotobynumber \
1981         getservbyport \
1982         inet_network \
1983         inet_ntop \
1984         inet_pton \
1985         sendmsg \
1986         socketpair \
1987 )
1988
1989 dnl **** Check for OpenLDAP ***
1990 AC_SUBST(LDAPLIBS,"")
1991 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
1992 then
1993     AC_CHECK_TYPE(LDAPSortKey,
1994         [AC_CHECK_LIB(ldap_r, ldap_initialize,
1995             [AC_CHECK_LIB(lber, ber_init,
1996                 [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
1997                  LDAPLIBS="-lldap_r -llber"],,
1998                  [$LIBPTHREAD])],,
1999                  [$LIBPTHREAD])],,
2000         [#include <ldap.h>])
2001     WINE_CHECK_LIB_FUNCS(\
2002         ldap_count_references \
2003         ldap_first_reference \
2004         ldap_next_reference \
2005         ldap_parse_reference \
2006         ldap_parse_sort_control \
2007         ldap_parse_sortresponse_control \
2008         ldap_parse_vlv_control \
2009         ldap_parse_vlvresponse_control,
2010         [$LDAPLIBS $LIBPTHREAD])
2011 fi
2012 WINE_NOTICE_WITH(ldap,[test "x$LDAPLIBS" = "x"],
2013                  [libldap (OpenLDAP) ${notice_platform}development files not found, LDAP won't be supported.])
2014
2015 AC_CACHE_CHECK([whether mkdir takes only one argument],
2016         wine_cv_one_arg_mkdir,
2017         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/stat.h>]],[[mkdir("foo");]])],
2018                           [wine_cv_one_arg_mkdir=yes],[wine_cv_one_arg_mkdir=no]))
2019 if test "$wine_cv_one_arg_mkdir" = "yes"
2020 then
2021   AC_DEFINE(HAVE_ONE_ARG_MKDIR, 1, [Define if mkdir takes only one argument])
2022 fi
2023
2024 dnl **** Check for types ****
2025
2026 AC_C_CONST
2027 AC_C_INLINE
2028 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
2029 AC_CHECK_TYPES([sigset_t],,,[#include <sys/types.h>
2030 #include <signal.h>])
2031 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
2032
2033 AC_CHECK_TYPES([struct xinpgen],,,
2034 [#include <sys/types.h>
2035 #ifdef HAVE_SYS_SOCKET_H
2036 #include <sys/socket.h>
2037 #endif
2038 #ifdef HAVE_SYS_SOCKETVAR_H
2039 #include <sys/socketvar.h>
2040 #endif
2041 #ifdef HAVE_NET_ROUTE_H
2042 #include <net/route.h>
2043 #endif
2044 #ifdef HAVE_NETINET_IN_H
2045 #include <netinet/in.h>
2046 #endif
2047 #ifdef HAVE_NETINET_IN_SYSTM_H
2048 #include <netinet/in_systm.h>
2049 #endif
2050 #ifdef HAVE_NETINET_IP_H
2051 #include <netinet/ip.h>
2052 #endif
2053 #ifdef HAVE_NETINET_IN_PCB_H
2054 #include <netinet/in_pcb.h>
2055 #endif])
2056
2057 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
2058 [#ifdef HAVE_LINUX_INPUT_H
2059 #include <linux/input.h>
2060 #endif])
2061
2062 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
2063                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
2064 if test "$wine_cv_have_sigaddset" = "yes"
2065 then
2066   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
2067 fi
2068
2069
2070 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
2071         wine_cv_linux_gethostbyname_r_6,
2072         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
2073     char *name=0;
2074     struct hostent he;
2075     struct hostent *result;
2076     char *buf=0;
2077     int bufsize=0;
2078     int res,errnr;
2079     char *addr=0;
2080     int addrlen=0;
2081     int addrtype=0;
2082     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
2083     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
2084     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
2085         ])
2086    )
2087    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
2088    then
2089       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
2090                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
2091    fi
2092
2093 if test "$ac_cv_header_linux_joystick_h" = "yes"
2094 then
2095    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
2096         wine_cv_linux_joystick_22_api,
2097         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2098         #include <sys/ioctl.h>
2099         #include <sys/types.h>
2100         #include <linux/joystick.h>
2101
2102         struct js_event blub;
2103         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
2104         #error "no 2.2 header"
2105         #endif
2106         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
2107    )
2108    if test "$wine_cv_linux_joystick_22_api" = "yes"
2109    then
2110       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
2111                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
2112    fi
2113 fi
2114
2115 dnl **** FIXME: what about mixed cases, where we need two of them? ***
2116
2117 dnl Check for statfs members
2118 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
2119 [#include <sys/types.h>
2120 #ifdef HAVE_SYS_PARAM_H
2121 # include <sys/param.h>
2122 #endif
2123 #ifdef HAVE_SYS_MOUNT_H
2124 # include <sys/mount.h>
2125 #endif
2126 #ifdef HAVE_SYS_VFS_H
2127 # include <sys/vfs.h>
2128 #endif
2129 #ifdef HAVE_SYS_STATFS_H
2130 # include <sys/statfs.h>
2131 #endif])
2132
2133 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
2134 [#ifdef HAVE_SYS_STATVFS_H
2135 #include <sys/statvfs.h>
2136 #endif])
2137
2138 dnl Check for socket structure members
2139 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
2140 [#include <sys/types.h>
2141 #ifdef HAVE_SYS_SOCKET_H
2142 # include <sys/socket.h>
2143 #endif
2144 #ifdef HAVE_SYS_UN_H
2145 # include <sys/un.h>
2146 #endif])
2147
2148 dnl Check for scsireq_t and sg_io_hdr_t members
2149 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
2150 [#include <sys/types.h>
2151 #ifdef HAVE_SCSI_SG_H
2152 #include <scsi/sg.h>
2153 #endif])
2154
2155 dnl Check for siginfo_t members
2156 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
2157
2158 dnl Check for struct mtget members
2159 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
2160 [#include <sys/types.h>
2161 #ifdef HAVE_SYS_MTIO_H
2162 #include <sys/mtio.h>
2163 #endif])
2164
2165 dnl Check for struct option
2166 AC_CHECK_MEMBERS([struct option.name],,,
2167 [#ifdef HAVE_GETOPT_H
2168 #include <getopt.h>
2169 #endif])
2170
2171 dnl Check for stat.st_blocks and ns-resolved times
2172 AC_CHECK_MEMBERS([struct stat.st_blocks,struct stat.st_mtim,struct stat.st_ctim,struct stat.st_atim])
2173
2174 dnl Check for sin6_scope_id
2175 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
2176 [#ifdef HAVE_SYS_TYPES_H
2177 #include <sys/types.h>
2178 #endif
2179 #ifdef HAVE_NETINET_IN_H
2180 #include <netinet/in.h>
2181 #endif])
2182
2183 dnl Check for ns_msg ptr member
2184 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
2185 [#ifdef HAVE_SYS_TYPES_H
2186 #include <sys/types.h>
2187 #endif
2188 #ifdef HAVE_NETINET_IN_H
2189 # include <netinet/in.h>
2190 #endif
2191 #ifdef HAVE_ARPA_NAMESER_H
2192 # include <arpa/nameser.h>
2193 #endif])
2194
2195 dnl Check for struct icmpstat.icps_outhist
2196 AC_CHECK_MEMBERS([struct icmpstat.icps_outhist],,,
2197 [#ifdef HAVE_SYS_TYPES_H
2198 #include <sys/types.h>
2199 #endif
2200 #ifdef HAVE_ALIAS_H
2201 #include <alias.h>
2202 #endif
2203 #ifdef HAVE_SYS_SOCKET_H
2204 #include <sys/socket.h>
2205 #endif
2206 #ifdef HAVE_SYS_SOCKETVAR_H
2207 #include <sys/socketvar.h>
2208 #endif
2209 #ifdef HAVE_SYS_TIMEOUT_H
2210 #include <sys/timeout.h>
2211 #endif
2212 #ifdef HAVE_NETINET_IN_H
2213 #include <netinet/in.h>
2214 #endif
2215 #ifdef HAVE_NETINET_IN_SYSTM_H
2216 #include <netinet/in_systm.h>
2217 #endif
2218 #ifdef HAVE_NETINET_IP_H
2219 #include <netinet/ip.h>
2220 #endif
2221 #ifdef HAVE_NETINET_IP_VAR_H
2222 #include <netinet/ip_var.h>
2223 #endif
2224 #ifdef HAVE_NETINET_IP_ICMP_H
2225 #include <netinet/ip_icmp.h>
2226 #endif
2227 #ifdef HAVE_NETINET_ICMP_VAR
2228 #include <netinet/icmp_var.h>
2229 #endif])
2230
2231 dnl Check for struct ifreq.ifr_hwaddr
2232 AC_CHECK_MEMBERS([struct ifreq.ifr_hwaddr],,,
2233 [#ifdef HAVE_SYS_TYPES_H
2234 #include <sys/types.h>
2235 #endif
2236 #ifdef HAVE_NET_IF_H
2237 # include <net/if.h>
2238 #endif])
2239
2240 dnl Check for the external timezone variables timezone and daylight
2241 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
2242                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
2243 if test "$ac_cv_have_timezone" = "yes"
2244 then
2245     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
2246 fi
2247 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
2248                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
2249 if test "$ac_cv_have_daylight" = "yes"
2250 then
2251     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
2252 fi
2253
2254 dnl Check for isinf
2255 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
2256                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
2257 if test "$ac_cv_have_isinf" = "yes"
2258 then
2259     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
2260 fi
2261
2262 dnl Check for isnan
2263 AC_CACHE_CHECK([for isnan], ac_cv_have_isnan,
2264                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isnan(f)]])],[ac_cv_have_isnan="yes"],[ac_cv_have_isnan="no"]))
2265 if test "$ac_cv_have_isnan" = "yes"
2266 then
2267     AC_DEFINE(HAVE_ISNAN, 1, [Define to 1 if you have the `isnan' function.])
2268 fi
2269
2270 dnl *** check for the need to define platform-specific symbols
2271
2272 case $host_cpu in
2273   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
2274   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
2275   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
2276   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
2277   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
2278 esac
2279
2280 case $host_vendor in
2281   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
2282 esac
2283
2284 dnl **** Generate output files ****
2285
2286 AH_TOP([#ifndef WINE_CROSSTEST
2287 #define __WINE_CONFIG_H])
2288 AH_BOTTOM([#endif /* WINE_CROSSTEST */])
2289
2290 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
2291
2292 WINE_CONFIG_SYMLINK(dlls/shell32/AUTHORS,AUTHORS)
2293 WINE_CONFIG_SYMLINK(dlls/wineps.drv/generic.ppd)
2294 WINE_CONFIG_SYMLINK(fonts/marlett.ttf,,enable_fonts)
2295 WINE_CONFIG_SYMLINK(fonts/symbol.ttf,,enable_fonts)
2296 WINE_CONFIG_SYMLINK(fonts/tahoma.ttf,,enable_fonts)
2297 WINE_CONFIG_SYMLINK(fonts/tahomabd.ttf,,enable_fonts)
2298 WINE_CONFIG_SYMLINK(tools/l_intl.nls)
2299 WINE_CONFIG_SYMLINK(wine,tools/winewrapper)
2300
2301 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
2302 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
2303 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
2304 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
2305 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
2306 WINE_CONFIG_EXTRA_DIR(include/wine)
2307
2308 WINE_CONFIG_MAKERULES([Make.rules],[MAKE_RULES])
2309 WINE_CONFIG_MAKERULES([Maketest.rules],[MAKE_TEST_RULES],[Make.rules])
2310 WINE_CONFIG_MAKERULES([dlls/Makedll.rules],[MAKE_DLL_RULES],[Make.rules])
2311 WINE_CONFIG_MAKERULES([dlls/Makeimplib.rules],[MAKE_IMPLIB_RULES],[Make.rules])
2312 WINE_CONFIG_MAKERULES([programs/Makeprog.rules],[MAKE_PROG_RULES],[Make.rules])
2313
2314 WINE_CONFIG_DLL(acledit)
2315 WINE_CONFIG_DLL(aclui,,[aclui])
2316 WINE_CONFIG_DLL(activeds,,[activeds])
2317 WINE_CONFIG_DLL(actxprxy)
2318 WINE_CONFIG_LIB(adsiid)
2319 WINE_CONFIG_DLL(advapi32,,[advapi32])
2320 WINE_CONFIG_TEST(dlls/advapi32/tests)
2321 WINE_CONFIG_DLL(advpack,,[advpack])
2322 WINE_CONFIG_TEST(dlls/advpack/tests)
2323 WINE_CONFIG_DLL(amstream)
2324 WINE_CONFIG_TEST(dlls/amstream/tests)
2325 WINE_CONFIG_DLL(appwiz.cpl)
2326 WINE_CONFIG_DLL(atl,,[atl])
2327 WINE_CONFIG_TEST(dlls/atl/tests)
2328 WINE_CONFIG_DLL(authz)
2329 WINE_CONFIG_DLL(avicap32,,[avicap32])
2330 WINE_CONFIG_DLL(avifil32,,[avifil32])
2331 WINE_CONFIG_TEST(dlls/avifil32/tests)
2332 WINE_CONFIG_DLL(avifile.dll16,enable_win16)
2333 WINE_CONFIG_DLL(avrt,,[avrt])
2334 WINE_CONFIG_DLL(bcrypt)
2335 WINE_CONFIG_DLL(browseui)
2336 WINE_CONFIG_TEST(dlls/browseui/tests)
2337 WINE_CONFIG_DLL(cabinet,,[cabinet])
2338 WINE_CONFIG_TEST(dlls/cabinet/tests)
2339 WINE_CONFIG_DLL(capi2032,,[capi2032])
2340 WINE_CONFIG_DLL(cards,,[cards])
2341 WINE_CONFIG_DLL(cfgmgr32,,[cfgmgr32])
2342 WINE_CONFIG_DLL(clusapi,,[clusapi])
2343 WINE_CONFIG_DLL(comcat)
2344 WINE_CONFIG_TEST(dlls/comcat/tests)
2345 WINE_CONFIG_DLL(comctl32,,[comctl32])
2346 WINE_CONFIG_TEST(dlls/comctl32/tests)
2347 WINE_CONFIG_DLL(comdlg32,,[comdlg32])
2348 WINE_CONFIG_TEST(dlls/comdlg32/tests)
2349 WINE_CONFIG_DLL(comm.drv16,enable_win16)
2350 WINE_CONFIG_DLL(commdlg.dll16,enable_win16)
2351 WINE_CONFIG_DLL(compobj.dll16,enable_win16)
2352 WINE_CONFIG_DLL(compstui,,[compstui])
2353 WINE_CONFIG_DLL(credui,,[credui])
2354 WINE_CONFIG_TEST(dlls/credui/tests)
2355 WINE_CONFIG_DLL(crtdll,,[crtdll])
2356 WINE_CONFIG_DLL(crypt32,,[crypt32])
2357 WINE_CONFIG_TEST(dlls/crypt32/tests)
2358 WINE_CONFIG_DLL(cryptdlg)
2359 WINE_CONFIG_DLL(cryptdll,,[cryptdll])
2360 WINE_CONFIG_DLL(cryptnet,,[cryptnet])
2361 WINE_CONFIG_TEST(dlls/cryptnet/tests)
2362 WINE_CONFIG_DLL(cryptui,,[cryptui])
2363 WINE_CONFIG_TEST(dlls/cryptui/tests)
2364 WINE_CONFIG_DLL(ctapi32)
2365 WINE_CONFIG_DLL(ctl3d.dll16,enable_win16)
2366 WINE_CONFIG_DLL(ctl3d32,,[ctl3d32])
2367 WINE_CONFIG_DLL(ctl3dv2.dll16,enable_win16)
2368 WINE_CONFIG_DLL(d3d10,,[d3d10])
2369 WINE_CONFIG_TEST(dlls/d3d10/tests)
2370 WINE_CONFIG_DLL(d3d10core,,[d3d10core])
2371 WINE_CONFIG_TEST(dlls/d3d10core/tests)
2372 WINE_CONFIG_DLL(d3d8,,[d3d8])
2373 WINE_CONFIG_TEST(dlls/d3d8/tests)
2374 WINE_CONFIG_DLL(d3d9,,[d3d9])
2375 WINE_CONFIG_TEST(dlls/d3d9/tests)
2376 WINE_CONFIG_DLL(d3dcompiler_33)
2377 WINE_CONFIG_DLL(d3dcompiler_34)
2378 WINE_CONFIG_DLL(d3dcompiler_35)
2379 WINE_CONFIG_DLL(d3dcompiler_36)
2380 WINE_CONFIG_DLL(d3dcompiler_37)
2381 WINE_CONFIG_DLL(d3dcompiler_38)
2382 WINE_CONFIG_DLL(d3dcompiler_39)
2383 WINE_CONFIG_DLL(d3dcompiler_40)
2384 WINE_CONFIG_DLL(d3dcompiler_41)
2385 WINE_CONFIG_DLL(d3dcompiler_42)
2386 WINE_CONFIG_DLL(d3dcompiler_43,,[d3dcompiler])
2387 WINE_CONFIG_TEST(dlls/d3dcompiler_43/tests)
2388 WINE_CONFIG_DLL(d3dim,,[d3dim])
2389 WINE_CONFIG_DLL(d3drm,,[d3drm])
2390 WINE_CONFIG_TEST(dlls/d3drm/tests)
2391 WINE_CONFIG_DLL(d3dx10_33)
2392 WINE_CONFIG_DLL(d3dx10_34)
2393 WINE_CONFIG_DLL(d3dx10_35)
2394 WINE_CONFIG_DLL(d3dx10_36)
2395 WINE_CONFIG_DLL(d3dx10_37)
2396 WINE_CONFIG_DLL(d3dx10_38)
2397 WINE_CONFIG_DLL(d3dx10_39)
2398 WINE_CONFIG_DLL(d3dx10_40)
2399 WINE_CONFIG_DLL(d3dx10_41)
2400 WINE_CONFIG_DLL(d3dx10_42)
2401 WINE_CONFIG_DLL(d3dx10_43)
2402 WINE_CONFIG_DLL(d3dx9_24)
2403 WINE_CONFIG_DLL(d3dx9_25)
2404 WINE_CONFIG_DLL(d3dx9_26)
2405 WINE_CONFIG_DLL(d3dx9_27)
2406 WINE_CONFIG_DLL(d3dx9_28)
2407 WINE_CONFIG_DLL(d3dx9_29)
2408 WINE_CONFIG_DLL(d3dx9_30)
2409 WINE_CONFIG_DLL(d3dx9_31)
2410 WINE_CONFIG_DLL(d3dx9_32)
2411 WINE_CONFIG_DLL(d3dx9_33)
2412 WINE_CONFIG_DLL(d3dx9_34)
2413 WINE_CONFIG_DLL(d3dx9_35)
2414 WINE_CONFIG_DLL(d3dx9_36,,[d3dx9])
2415 WINE_CONFIG_TEST(dlls/d3dx9_36/tests)
2416 WINE_CONFIG_DLL(d3dx9_37)
2417 WINE_CONFIG_DLL(d3dx9_38)
2418 WINE_CONFIG_DLL(d3dx9_39)
2419 WINE_CONFIG_DLL(d3dx9_40)
2420 WINE_CONFIG_DLL(d3dx9_41)
2421 WINE_CONFIG_DLL(d3dx9_42)
2422 WINE_CONFIG_DLL(d3dx9_43)
2423 WINE_CONFIG_DLL(d3dxof,,[d3dxof])
2424 WINE_CONFIG_TEST(dlls/d3dxof/tests)
2425 WINE_CONFIG_DLL(dbgeng,,[dbgeng])
2426 WINE_CONFIG_DLL(dbghelp,,[dbghelp])
2427 WINE_CONFIG_DLL(dciman32,,[dciman32])
2428 WINE_CONFIG_DLL(ddeml.dll16,enable_win16)
2429 WINE_CONFIG_DLL(ddraw,,[ddraw])
2430 WINE_CONFIG_TEST(dlls/ddraw/tests)
2431 WINE_CONFIG_DLL(ddrawex)
2432 WINE_CONFIG_TEST(dlls/ddrawex/tests)
2433 WINE_CONFIG_DLL(devenum)
2434 WINE_CONFIG_DLL(dinput,,[dinput],[data_formats.c])
2435 WINE_CONFIG_TEST(dlls/dinput/tests)
2436 WINE_CONFIG_DLL(dinput8,,[dinput8])
2437 WINE_CONFIG_DLL(dispdib.dll16,enable_win16)
2438 WINE_CONFIG_DLL(dispex)
2439 WINE_CONFIG_TEST(dlls/dispex/tests)
2440 WINE_CONFIG_DLL(display.drv16,enable_win16)
2441 WINE_CONFIG_DLL(dmband)
2442 WINE_CONFIG_DLL(dmcompos)
2443 WINE_CONFIG_DLL(dmime)
2444 WINE_CONFIG_TEST(dlls/dmime/tests)
2445 WINE_CONFIG_DLL(dmloader)
2446 WINE_CONFIG_TEST(dlls/dmloader/tests)
2447 WINE_CONFIG_DLL(dmscript)
2448 WINE_CONFIG_DLL(dmstyle)
2449 WINE_CONFIG_DLL(dmsynth)
2450 WINE_CONFIG_DLL(dmusic)
2451 WINE_CONFIG_DLL(dmusic32,,[dmusic32])
2452 WINE_CONFIG_DLL(dnsapi,,[dnsapi])
2453 WINE_CONFIG_TEST(dlls/dnsapi/tests)
2454 WINE_CONFIG_DLL(dplay,,[dplay])
2455 WINE_CONFIG_DLL(dplayx,,[dplayx])
2456 WINE_CONFIG_TEST(dlls/dplayx/tests)
2457 WINE_CONFIG_DLL(dpnaddr)
2458 WINE_CONFIG_DLL(dpnet,,[dpnet])
2459 WINE_CONFIG_DLL(dpnhpast)
2460 WINE_CONFIG_DLL(dpnlobby)
2461 WINE_CONFIG_DLL(dpwsockx)
2462 WINE_CONFIG_DLL(drmclien)
2463 WINE_CONFIG_DLL(dsound,,[dsound])
2464 WINE_CONFIG_TEST(dlls/dsound/tests)
2465 WINE_CONFIG_DLL(dssenh)
2466 WINE_CONFIG_DLL(dswave)
2467 WINE_CONFIG_DLL(dwmapi,,[dwmapi])
2468 WINE_CONFIG_DLL(dxdiagn)
2469 WINE_CONFIG_TEST(dlls/dxdiagn/tests)
2470 WINE_CONFIG_LIB(dxerr8)
2471 WINE_CONFIG_LIB(dxerr9)
2472 WINE_CONFIG_DLL(dxgi,,[dxgi])
2473 WINE_CONFIG_TEST(dlls/dxgi/tests)
2474 WINE_CONFIG_LIB(dxguid)
2475 WINE_CONFIG_DLL(explorerframe)
2476 WINE_CONFIG_TEST(dlls/explorerframe/tests)
2477 WINE_CONFIG_DLL(faultrep,,[faultrep])
2478 WINE_CONFIG_TEST(dlls/faultrep/tests)
2479 WINE_CONFIG_DLL(fltlib)
2480 WINE_CONFIG_DLL(fusion)
2481 WINE_CONFIG_TEST(dlls/fusion/tests)
2482 WINE_CONFIG_DLL(fwpuclnt)
2483 WINE_CONFIG_DLL(gameux)
2484 WINE_CONFIG_TEST(dlls/gameux/tests)
2485 WINE_CONFIG_DLL(gdi.exe16,enable_win16)
2486 WINE_CONFIG_DLL(gdi32,,[gdi32])
2487 WINE_CONFIG_TEST(dlls/gdi32/tests)
2488 WINE_CONFIG_DLL(gdiplus,,[gdiplus])
2489 WINE_CONFIG_TEST(dlls/gdiplus/tests)
2490 WINE_CONFIG_DLL(glu32,,[glu32])
2491 WINE_CONFIG_DLL(gphoto2.ds)
2492 WINE_CONFIG_DLL(gpkcsp)
2493 WINE_CONFIG_DLL(hal)
2494 WINE_CONFIG_DLL(hhctrl.ocx)
2495 WINE_CONFIG_DLL(hid,,[hid])
2496 WINE_CONFIG_DLL(hlink,,[hlink])
2497 WINE_CONFIG_TEST(dlls/hlink/tests)
2498 WINE_CONFIG_DLL(hnetcfg)
2499 WINE_CONFIG_DLL(httpapi)
2500 WINE_CONFIG_DLL(iccvid)
2501 WINE_CONFIG_DLL(icmp)
2502 WINE_CONFIG_DLL(ifsmgr.vxd,enable_win16)
2503 WINE_CONFIG_DLL(imaadp32.acm)
2504 WINE_CONFIG_DLL(imagehlp,,[imagehlp])
2505 WINE_CONFIG_TEST(dlls/imagehlp/tests)
2506 WINE_CONFIG_DLL(imm.dll16,enable_win16)
2507 WINE_CONFIG_DLL(imm32,,[imm32])
2508 WINE_CONFIG_TEST(dlls/imm32/tests)
2509 WINE_CONFIG_DLL(inetcomm,,[inetcomm])
2510 WINE_CONFIG_TEST(dlls/inetcomm/tests)
2511 WINE_CONFIG_DLL(inetcpl.cpl)
2512 WINE_CONFIG_DLL(inetmib1)
2513 WINE_CONFIG_TEST(dlls/inetmib1/tests)
2514 WINE_CONFIG_DLL(infosoft)
2515 WINE_CONFIG_TEST(dlls/infosoft/tests)
2516 WINE_CONFIG_DLL(initpki)
2517 WINE_CONFIG_DLL(inkobj)
2518 WINE_CONFIG_DLL(inseng)
2519 WINE_CONFIG_DLL(iphlpapi,,[iphlpapi])
2520 WINE_CONFIG_TEST(dlls/iphlpapi/tests)
2521 WINE_CONFIG_DLL(itircl)
2522 WINE_CONFIG_DLL(itss)
2523 WINE_CONFIG_TEST(dlls/itss/tests)
2524 WINE_CONFIG_DLL(jscript)
2525 WINE_CONFIG_TEST(dlls/jscript/tests)
2526 WINE_CONFIG_DLL(kernel32,,[kernel32])
2527 WINE_CONFIG_TEST(dlls/kernel32/tests)
2528 WINE_CONFIG_DLL(keyboard.drv16,enable_win16)
2529 WINE_CONFIG_DLL(krnl386.exe16,enable_win16,[kernel])
2530 WINE_CONFIG_DLL(ktmw32)
2531 WINE_CONFIG_DLL(loadperf,,[loadperf])
2532 WINE_CONFIG_DLL(localspl)
2533 WINE_CONFIG_TEST(dlls/localspl/tests)
2534 WINE_CONFIG_DLL(localui)
2535 WINE_CONFIG_TEST(dlls/localui/tests)
2536 WINE_CONFIG_DLL(lz32,,[lz32])
2537 WINE_CONFIG_TEST(dlls/lz32/tests)
2538 WINE_CONFIG_DLL(lzexpand.dll16,enable_win16)
2539 WINE_CONFIG_DLL(mapi32,,[mapi32])
2540 WINE_CONFIG_TEST(dlls/mapi32/tests)
2541 WINE_CONFIG_DLL(mapistub)
2542 WINE_CONFIG_DLL(mciavi32)
2543 WINE_CONFIG_DLL(mcicda)
2544 WINE_CONFIG_DLL(mciqtz32)
2545 WINE_CONFIG_DLL(mciseq)
2546 WINE_CONFIG_DLL(mciwave)
2547 WINE_CONFIG_DLL(midimap)
2548 WINE_CONFIG_DLL(mlang,,[mlang])
2549 WINE_CONFIG_TEST(dlls/mlang/tests)
2550 WINE_CONFIG_DLL(mmdevapi)
2551 WINE_CONFIG_TEST(dlls/mmdevapi/tests)
2552 WINE_CONFIG_DLL(mmdevldr.vxd,enable_win16)
2553 WINE_CONFIG_DLL(mmsystem.dll16,enable_win16)
2554 WINE_CONFIG_DLL(monodebg.vxd,enable_win16)
2555 WINE_CONFIG_DLL(mountmgr.sys)
2556 WINE_CONFIG_DLL(mouse.drv16,enable_win16)
2557 WINE_CONFIG_DLL(mpr,,[mpr])
2558 WINE_CONFIG_DLL(mprapi,,[mprapi])
2559 WINE_CONFIG_DLL(msacm.dll16,enable_win16)
2560 WINE_CONFIG_DLL(msacm32.drv)
2561 WINE_CONFIG_DLL(msacm32,,[msacm32])
2562 WINE_CONFIG_TEST(dlls/msacm32/tests)
2563 WINE_CONFIG_DLL(msadp32.acm)
2564 WINE_CONFIG_DLL(mscat32)
2565 WINE_CONFIG_DLL(mscms,,[mscms])
2566 WINE_CONFIG_TEST(dlls/mscms/tests)
2567 WINE_CONFIG_DLL(mscoree)
2568 WINE_CONFIG_TEST(dlls/mscoree/tests)
2569 WINE_CONFIG_DLL(msctf)
2570 WINE_CONFIG_TEST(dlls/msctf/tests)
2571 WINE_CONFIG_DLL(msdaps)
2572 WINE_CONFIG_DLL(msdmo,,[msdmo])
2573 WINE_CONFIG_DLL(msftedit)
2574 WINE_CONFIG_DLL(msg711.acm)
2575 WINE_CONFIG_DLL(msgsm32.acm)
2576 WINE_CONFIG_DLL(mshtml.tlb)
2577 WINE_CONFIG_DLL(mshtml,,[mshtml])
2578 WINE_CONFIG_TEST(dlls/mshtml/tests)
2579 WINE_CONFIG_DLL(msi,,[msi])
2580 WINE_CONFIG_TEST(dlls/msi/tests)
2581 WINE_CONFIG_DLL(msimg32,,[msimg32])
2582 WINE_CONFIG_DLL(msimtf)
2583 WINE_CONFIG_DLL(msisip)
2584 WINE_CONFIG_DLL(msisys.ocx)
2585 WINE_CONFIG_DLL(msnet32)
2586 WINE_CONFIG_DLL(msrle32)
2587 WINE_CONFIG_DLL(mssign32)
2588 WINE_CONFIG_DLL(mssip32)
2589 WINE_CONFIG_DLL(mstask)
2590 WINE_CONFIG_TEST(dlls/mstask/tests)
2591 WINE_CONFIG_DLL(msvcirt)
2592 WINE_CONFIG_DLL(msvcp80)
2593 WINE_CONFIG_DLL(msvcp90)
2594 WINE_CONFIG_TEST(dlls/msvcp90/tests)
2595 WINE_CONFIG_DLL(msvcr100)
2596 WINE_CONFIG_DLL(msvcr70,,[msvcr70])
2597 WINE_CONFIG_DLL(msvcr71,,[msvcr71])
2598 WINE_CONFIG_DLL(msvcr80)
2599 WINE_CONFIG_DLL(msvcr90)
2600 WINE_CONFIG_TEST(dlls/msvcr90/tests)
2601 WINE_CONFIG_DLL(msvcrt,,[msvcrt])
2602 WINE_CONFIG_TEST(dlls/msvcrt/tests)
2603 WINE_CONFIG_DLL(msvcrt20,,[msvcrt20])
2604 WINE_CONFIG_DLL(msvcrt40,,[msvcrt40])
2605 WINE_CONFIG_DLL(msvcrtd,,[msvcrtd])
2606 WINE_CONFIG_TEST(dlls/msvcrtd/tests)
2607 WINE_CONFIG_DLL(msvfw32,,[msvfw32])
2608 WINE_CONFIG_TEST(dlls/msvfw32/tests)
2609 WINE_CONFIG_DLL(msvidc32)
2610 WINE_CONFIG_DLL(msvideo.dll16,enable_win16)
2611 WINE_CONFIG_DLL(mswsock,,[mswsock])
2612 WINE_CONFIG_DLL(msxml3)
2613 WINE_CONFIG_TEST(dlls/msxml3/tests)
2614 WINE_CONFIG_DLL(msxml4)
2615 WINE_CONFIG_DLL(msxml6)
2616 WINE_CONFIG_DLL(nddeapi,,[nddeapi])
2617 WINE_CONFIG_DLL(netapi32,,[netapi32])
2618 WINE_CONFIG_TEST(dlls/netapi32/tests)
2619 WINE_CONFIG_DLL(newdev,,[newdev])
2620 WINE_CONFIG_DLL(npmshtml)
2621 WINE_CONFIG_DLL(ntdll,,[ntdll])
2622 WINE_CONFIG_TEST(dlls/ntdll/tests)
2623 WINE_CONFIG_DLL(ntdsapi,,[ntdsapi])
2624 WINE_CONFIG_TEST(dlls/ntdsapi/tests)
2625 WINE_CONFIG_DLL(ntoskrnl.exe,,[ntoskrnl.exe])
2626 WINE_CONFIG_DLL(ntprint)
2627 WINE_CONFIG_TEST(dlls/ntprint/tests)
2628 WINE_CONFIG_DLL(objsel)
2629 WINE_CONFIG_DLL(odbc32,,[odbc32])
2630 WINE_CONFIG_DLL(odbccp32,,[odbccp32])
2631 WINE_CONFIG_TEST(dlls/odbccp32/tests)
2632 WINE_CONFIG_DLL(ole2.dll16,enable_win16)
2633 WINE_CONFIG_DLL(ole2conv.dll16,enable_win16)
2634 WINE_CONFIG_DLL(ole2disp.dll16,enable_win16)
2635 WINE_CONFIG_DLL(ole2nls.dll16,enable_win16)
2636 WINE_CONFIG_DLL(ole2prox.dll16,enable_win16)
2637 WINE_CONFIG_DLL(ole2thk.dll16,enable_win16)
2638 WINE_CONFIG_DLL(ole32,,[ole32])
2639 WINE_CONFIG_TEST(dlls/ole32/tests)
2640 WINE_CONFIG_DLL(oleacc,,[oleacc])
2641 WINE_CONFIG_TEST(dlls/oleacc/tests)
2642 WINE_CONFIG_DLL(oleaut32,,[oleaut32])
2643 WINE_CONFIG_TEST(dlls/oleaut32/tests)
2644 WINE_CONFIG_DLL(olecli.dll16,enable_win16)
2645 WINE_CONFIG_DLL(olecli32,,[olecli32])
2646 WINE_CONFIG_DLL(oledb32)
2647 WINE_CONFIG_TEST(dlls/oledb32/tests)
2648 WINE_CONFIG_DLL(oledlg,,[oledlg])
2649 WINE_CONFIG_DLL(olepro32,,[olepro32])
2650 WINE_CONFIG_DLL(olesvr.dll16,enable_win16)
2651 WINE_CONFIG_DLL(olesvr32,,[olesvr32])
2652 WINE_CONFIG_DLL(olethk32)
2653 WINE_CONFIG_DLL(openal32)
2654 WINE_CONFIG_DLL(opencl)
2655 WINE_CONFIG_DLL(opengl32,,[opengl32])
2656 WINE_CONFIG_TEST(dlls/opengl32/tests)
2657 WINE_CONFIG_DLL(pdh,,[pdh])
2658 WINE_CONFIG_TEST(dlls/pdh/tests)
2659 WINE_CONFIG_DLL(pidgen)
2660 WINE_CONFIG_DLL(powrprof,,[powrprof])
2661 WINE_CONFIG_DLL(printui)
2662 WINE_CONFIG_DLL(propsys,,[propsys])
2663 WINE_CONFIG_TEST(dlls/propsys/tests)
2664 WINE_CONFIG_DLL(psapi,,[psapi])
2665 WINE_CONFIG_TEST(dlls/psapi/tests)
2666 WINE_CONFIG_DLL(pstorec)
2667 WINE_CONFIG_DLL(qcap)
2668 WINE_CONFIG_DLL(qedit)
2669 WINE_CONFIG_TEST(dlls/qedit/tests)
2670 WINE_CONFIG_DLL(qmgr)
2671 WINE_CONFIG_TEST(dlls/qmgr/tests)
2672 WINE_CONFIG_DLL(qmgrprxy)
2673 WINE_CONFIG_DLL(quartz,,[quartz])
2674 WINE_CONFIG_TEST(dlls/quartz/tests)
2675 WINE_CONFIG_DLL(query)
2676 WINE_CONFIG_DLL(rasapi16.dll16,enable_win16)
2677 WINE_CONFIG_DLL(rasapi32,,[rasapi32])
2678 WINE_CONFIG_TEST(dlls/rasapi32/tests)
2679 WINE_CONFIG_DLL(rasdlg,,[rasdlg])
2680 WINE_CONFIG_DLL(resutils,,[resutils])
2681 WINE_CONFIG_DLL(riched20,,[riched20])
2682 WINE_CONFIG_TEST(dlls/riched20/tests)
2683 WINE_CONFIG_DLL(riched32)
2684 WINE_CONFIG_TEST(dlls/riched32/tests)
2685 WINE_CONFIG_DLL(rpcrt4,,[rpcrt4])
2686 WINE_CONFIG_TEST(dlls/rpcrt4/tests)
2687 WINE_CONFIG_DLL(rsabase)
2688 WINE_CONFIG_DLL(rsaenh,,[rsaenh])
2689 WINE_CONFIG_TEST(dlls/rsaenh/tests)
2690 WINE_CONFIG_DLL(rstrtmgr)
2691 WINE_CONFIG_DLL(rtutils,,[rtutils])
2692 WINE_CONFIG_DLL(samlib)
2693 WINE_CONFIG_DLL(sane.ds)
2694 WINE_CONFIG_DLL(sccbase)
2695 WINE_CONFIG_DLL(schannel)
2696 WINE_CONFIG_TEST(dlls/schannel/tests)
2697 WINE_CONFIG_DLL(secur32,,[secur32])
2698 WINE_CONFIG_TEST(dlls/secur32/tests)
2699 WINE_CONFIG_DLL(security)
2700 WINE_CONFIG_DLL(sensapi,,[sensapi])
2701 WINE_CONFIG_DLL(serialui,,[serialui])
2702 WINE_CONFIG_TEST(dlls/serialui/tests)
2703 WINE_CONFIG_DLL(setupapi,,[setupapi])
2704 WINE_CONFIG_TEST(dlls/setupapi/tests)
2705 WINE_CONFIG_DLL(setupx.dll16,enable_win16)
2706 WINE_CONFIG_DLL(sfc,,[sfc])
2707 WINE_CONFIG_DLL(sfc_os,,[sfc_os])
2708 WINE_CONFIG_DLL(shdoclc)
2709 WINE_CONFIG_DLL(shdocvw,,[shdocvw])
2710 WINE_CONFIG_TEST(dlls/shdocvw/tests)
2711 WINE_CONFIG_DLL(shell.dll16,enable_win16)
2712 WINE_CONFIG_DLL(shell32,,[shell32])
2713 WINE_CONFIG_TEST(dlls/shell32/tests)
2714 WINE_CONFIG_DLL(shfolder,,[shfolder])
2715 WINE_CONFIG_DLL(shlwapi,,[shlwapi])
2716 WINE_CONFIG_TEST(dlls/shlwapi/tests)
2717 WINE_CONFIG_DLL(slbcsp)
2718 WINE_CONFIG_DLL(slc,,[slc])
2719 WINE_CONFIG_DLL(snmpapi,,[snmpapi])
2720 WINE_CONFIG_TEST(dlls/snmpapi/tests)
2721 WINE_CONFIG_DLL(softpub)
2722 WINE_CONFIG_DLL(sound.drv16,enable_win16)
2723 WINE_CONFIG_DLL(spoolss,,[spoolss])
2724 WINE_CONFIG_TEST(dlls/spoolss/tests)
2725 WINE_CONFIG_DLL(stdole2.tlb)
2726 WINE_CONFIG_DLL(stdole32.tlb)
2727 WINE_CONFIG_DLL(sti,,[sti])
2728 WINE_CONFIG_TEST(dlls/sti/tests)
2729 WINE_CONFIG_DLL(storage.dll16,enable_win16)
2730 WINE_CONFIG_DLL(stress.dll16,enable_win16)
2731 WINE_CONFIG_LIB(strmbase)
2732 WINE_CONFIG_LIB(strmiids)
2733 WINE_CONFIG_DLL(svrapi)
2734 WINE_CONFIG_DLL(sxs)
2735 WINE_CONFIG_DLL(system.drv16,enable_win16)
2736 WINE_CONFIG_DLL(t2embed)
2737 WINE_CONFIG_DLL(tapi32,,[tapi32])
2738 WINE_CONFIG_DLL(toolhelp.dll16,enable_win16)
2739 WINE_CONFIG_DLL(traffic)
2740 WINE_CONFIG_DLL(twain.dll16,enable_win16)
2741 WINE_CONFIG_DLL(twain_32)
2742 WINE_CONFIG_TEST(dlls/twain_32/tests)
2743 WINE_CONFIG_DLL(typelib.dll16,enable_win16)
2744 WINE_CONFIG_DLL(unicows,,[unicows])
2745 WINE_CONFIG_DLL(updspapi)
2746 WINE_CONFIG_DLL(url,,[url])
2747 WINE_CONFIG_DLL(urlmon,,[urlmon])
2748 WINE_CONFIG_TEST(dlls/urlmon/tests)
2749 WINE_CONFIG_DLL(usbd.sys,,[usbd.sys])
2750 WINE_CONFIG_DLL(user.exe16,enable_win16)
2751 WINE_CONFIG_DLL(user32,,[user32])
2752 WINE_CONFIG_TEST(dlls/user32/tests)
2753 WINE_CONFIG_DLL(userenv,,[userenv])
2754 WINE_CONFIG_TEST(dlls/userenv/tests)
2755 WINE_CONFIG_DLL(usp10,,[usp10])
2756 WINE_CONFIG_TEST(dlls/usp10/tests)
2757 WINE_CONFIG_LIB(uuid)
2758 WINE_CONFIG_DLL(uxtheme,,[uxtheme])
2759 WINE_CONFIG_TEST(dlls/uxtheme/tests)
2760 WINE_CONFIG_DLL(vdhcp.vxd,enable_win16)
2761 WINE_CONFIG_DLL(vdmdbg,,[vdmdbg])
2762 WINE_CONFIG_DLL(ver.dll16,enable_win16)
2763 WINE_CONFIG_DLL(version,,[version])
2764 WINE_CONFIG_TEST(dlls/version/tests)
2765 WINE_CONFIG_DLL(vmm.vxd,enable_win16)
2766 WINE_CONFIG_DLL(vnbt.vxd,enable_win16)
2767 WINE_CONFIG_DLL(vnetbios.vxd,enable_win16)
2768 WINE_CONFIG_DLL(vtdapi.vxd,enable_win16)
2769 WINE_CONFIG_DLL(vwin32.vxd,enable_win16)
2770 WINE_CONFIG_DLL(w32skrnl,enable_win16)
2771 WINE_CONFIG_DLL(w32sys.dll16,enable_win16)
2772 WINE_CONFIG_DLL(wbemprox)
2773 WINE_CONFIG_DLL(wer,,[wer])
2774 WINE_CONFIG_TEST(dlls/wer/tests)
2775 WINE_CONFIG_DLL(wiaservc)
2776 WINE_CONFIG_DLL(win32s16.dll16,enable_win16)
2777 WINE_CONFIG_DLL(win87em.dll16,enable_win16)
2778 WINE_CONFIG_DLL(winaspi.dll16,enable_win16)
2779 WINE_CONFIG_DLL(windebug.dll16,enable_win16)
2780 WINE_CONFIG_DLL(windowscodecs,,[windowscodecs])
2781 WINE_CONFIG_TEST(dlls/windowscodecs/tests)
2782 WINE_CONFIG_DLL(winealsa.drv)
2783 WINE_CONFIG_DLL(wineaudioio.drv)
2784 WINE_CONFIG_DLL(winecoreaudio.drv)
2785 WINE_CONFIG_LIB(winecrt0)
2786 WINE_CONFIG_DLL(wined3d,,[wined3d])
2787 WINE_CONFIG_DLL(wineesd.drv)
2788 WINE_CONFIG_DLL(winegstreamer)
2789 WINE_CONFIG_DLL(winejack.drv)
2790 WINE_CONFIG_DLL(winejoystick.drv)
2791 WINE_CONFIG_DLL(winemapi)
2792 WINE_CONFIG_DLL(winemp3.acm)
2793 WINE_CONFIG_DLL(winenas.drv)
2794 WINE_CONFIG_DLL(wineoss.drv)
2795 WINE_CONFIG_DLL(wineps.drv)
2796 WINE_CONFIG_DLL(wineps16.drv16,enable_win16)
2797 WINE_CONFIG_DLL(winequartz.drv)
2798 WINE_CONFIG_DLL(winex11.drv)
2799 WINE_CONFIG_DLL(wing.dll16,enable_win16)
2800 WINE_CONFIG_DLL(wing32)
2801 WINE_CONFIG_DLL(winhttp,,[winhttp])
2802 WINE_CONFIG_TEST(dlls/winhttp/tests)
2803 WINE_CONFIG_DLL(wininet,,[wininet])
2804 WINE_CONFIG_TEST(dlls/wininet/tests)
2805 WINE_CONFIG_DLL(winmm,,[winmm])
2806 WINE_CONFIG_TEST(dlls/winmm/tests)
2807 WINE_CONFIG_DLL(winnls.dll16,enable_win16)
2808 WINE_CONFIG_DLL(winnls32,,[winnls32])
2809 WINE_CONFIG_DLL(winscard,,[winscard])
2810 WINE_CONFIG_DLL(winsock.dll16,enable_win16)
2811 WINE_CONFIG_DLL(winspool.drv,,[winspool])
2812 WINE_CONFIG_TEST(dlls/winspool.drv/tests)
2813 WINE_CONFIG_DLL(wintab.dll16,enable_win16)
2814 WINE_CONFIG_DLL(wintab32,,[wintab32])
2815 WINE_CONFIG_TEST(dlls/wintab32/tests)
2816 WINE_CONFIG_DLL(wintrust,,[wintrust])
2817 WINE_CONFIG_TEST(dlls/wintrust/tests)
2818 WINE_CONFIG_DLL(wlanapi)
2819 WINE_CONFIG_DLL(wldap32,,[wldap32])
2820 WINE_CONFIG_TEST(dlls/wldap32/tests)
2821 WINE_CONFIG_DLL(wmi)
2822 WINE_CONFIG_DLL(wmiutils)
2823 WINE_CONFIG_DLL(wnaspi32,,[wnaspi32])
2824 WINE_CONFIG_DLL(wow32,enable_win16,[wow32])
2825 WINE_CONFIG_DLL(ws2_32,,[ws2_32])
2826 WINE_CONFIG_TEST(dlls/ws2_32/tests)
2827 WINE_CONFIG_DLL(wsock32,,[wsock32])
2828 WINE_CONFIG_DLL(wtsapi32,,[wtsapi32])
2829 WINE_CONFIG_DLL(wuapi)
2830 WINE_CONFIG_DLL(wuaueng)
2831 WINE_CONFIG_DLL(xapofx1_1)
2832 WINE_CONFIG_DLL(xinput1_1)
2833 WINE_CONFIG_DLL(xinput1_2)
2834 WINE_CONFIG_DLL(xinput1_3,,[xinput])
2835 WINE_CONFIG_TEST(dlls/xinput1_3/tests)
2836 WINE_CONFIG_DLL(xinput9_1_0)
2837 WINE_CONFIG_DLL(xmllite)
2838 WINE_CONFIG_TEST(dlls/xmllite/tests)
2839 WINE_CONFIG_MAKEFILE([documentation])
2840 WINE_CONFIG_MAKEFILE([fonts])
2841 WINE_CONFIG_MAKEFILE([include])
2842 WINE_CONFIG_MAKEFILE([libs/port])
2843 WINE_CONFIG_MAKEFILE([libs/wine])
2844 WINE_CONFIG_MAKEFILE([libs/wpp])
2845 WINE_CONFIG_MAKEFILE([loader])
2846 WINE_CONFIG_PROGRAM(aspnet_regiis,install)
2847 WINE_CONFIG_PROGRAM(attrib,install)
2848 WINE_CONFIG_PROGRAM(cacls,install)
2849 WINE_CONFIG_PROGRAM(clock,install)
2850 WINE_CONFIG_PROGRAM(cmd,install)
2851 WINE_CONFIG_TEST(programs/cmd/tests)
2852 WINE_CONFIG_PROGRAM(cmdlgtst)
2853 WINE_CONFIG_PROGRAM(control,install)
2854 WINE_CONFIG_PROGRAM(dxdiag,install)
2855 WINE_CONFIG_PROGRAM(eject,install)
2856 WINE_CONFIG_PROGRAM(expand,install)
2857 WINE_CONFIG_PROGRAM(explorer,install)
2858 WINE_CONFIG_PROGRAM(extrac32,install)
2859 WINE_CONFIG_PROGRAM(hh,install)
2860 WINE_CONFIG_PROGRAM(icinfo,install)
2861 WINE_CONFIG_PROGRAM(iexplore,install)
2862 WINE_CONFIG_PROGRAM(ipconfig,install)
2863 WINE_CONFIG_PROGRAM(lodctr,install)
2864 WINE_CONFIG_PROGRAM(mofcomp,install)
2865 WINE_CONFIG_PROGRAM(mshta,install)
2866 WINE_CONFIG_PROGRAM(msiexec,installbin)
2867 WINE_CONFIG_PROGRAM(net,install)
2868 WINE_CONFIG_PROGRAM(ngen,install)
2869 WINE_CONFIG_PROGRAM(notepad,installbin)
2870 WINE_CONFIG_PROGRAM(oleview,install)
2871 WINE_CONFIG_PROGRAM(ping,install)
2872 WINE_CONFIG_PROGRAM(progman,install)
2873 WINE_CONFIG_PROGRAM(reg,install)
2874 WINE_CONFIG_PROGRAM(regedit,installbin)
2875 WINE_CONFIG_TEST(programs/regedit/tests)
2876 WINE_CONFIG_PROGRAM(regsvcs,install)
2877 WINE_CONFIG_PROGRAM(regsvr32,installbin)
2878 WINE_CONFIG_PROGRAM(rpcss,install)
2879 WINE_CONFIG_PROGRAM(rundll.exe16,install,enable_win16)
2880 WINE_CONFIG_PROGRAM(rundll32,install)
2881 WINE_CONFIG_PROGRAM(sc,install)
2882 WINE_CONFIG_PROGRAM(secedit,install)
2883 WINE_CONFIG_PROGRAM(servicemodelreg,install)
2884 WINE_CONFIG_PROGRAM(services,install)
2885 WINE_CONFIG_PROGRAM(spoolsv,install)
2886 WINE_CONFIG_PROGRAM(start,install)
2887 WINE_CONFIG_PROGRAM(svchost,install)
2888 WINE_CONFIG_PROGRAM(taskkill,install)
2889 WINE_CONFIG_PROGRAM(taskmgr,install)
2890 WINE_CONFIG_PROGRAM(termsv,install)
2891 WINE_CONFIG_PROGRAM(uninstaller,install)
2892 WINE_CONFIG_PROGRAM(unlodctr,install)
2893 WINE_CONFIG_PROGRAM(view)
2894 WINE_CONFIG_PROGRAM(wineboot,installbin)
2895 WINE_CONFIG_PROGRAM(winebrowser,install)
2896 WINE_CONFIG_PROGRAM(winecfg,installbin)
2897 WINE_CONFIG_PROGRAM(wineconsole,installbin)
2898 WINE_CONFIG_PROGRAM(winedbg,installbin)
2899 WINE_CONFIG_PROGRAM(winedevice,install)
2900 WINE_CONFIG_PROGRAM(winefile,installbin)
2901 WINE_CONFIG_PROGRAM(winemenubuilder,install)
2902 WINE_CONFIG_PROGRAM(winemine,installbin)
2903 WINE_CONFIG_PROGRAM(winepath,installbin)
2904 WINE_CONFIG_PROGRAM(winetest)
2905 WINE_CONFIG_PROGRAM(winevdm,install,enable_win16)
2906 WINE_CONFIG_PROGRAM(winhelp.exe16,install,enable_win16)
2907 WINE_CONFIG_PROGRAM(winhlp32,install)
2908 WINE_CONFIG_PROGRAM(winoldap.mod16,install,enable_win16)
2909 WINE_CONFIG_PROGRAM(winver,install)
2910 WINE_CONFIG_PROGRAM(wordpad,install)
2911 WINE_CONFIG_PROGRAM(write,install)
2912 WINE_CONFIG_PROGRAM(wscript,install)
2913 WINE_CONFIG_PROGRAM(xcopy,install)
2914 WINE_CONFIG_MAKEFILE([server])
2915 WINE_CONFIG_TOOL(tools)
2916 WINE_CONFIG_TOOL(tools/widl)
2917 WINE_CONFIG_TOOL(tools/winebuild)
2918 WINE_CONFIG_TOOL(tools/winedump)
2919 WINE_CONFIG_TOOL(tools/winegcc)
2920 WINE_CONFIG_TOOL(tools/wmc)
2921 WINE_CONFIG_TOOL(tools/wrc)
2922 dnl End of auto-generated output commands
2923
2924 AC_CONFIG_COMMANDS([Makefile], [wine_fn_output_makefile Makefile],
2925 [wine_fn_output_makefile ()
2926 {
2927     cat Make.tmp - <<\_WINE_EOF >\$tmp/makefile && mv -f \$tmp/makefile \$[]1 && rm -f Make.tmp && return
2928 $ALL_MAKEFILE_DEPENDS
2929 _WINE_EOF
2930     AS_ERROR([could not create Makefile])
2931 }])
2932
2933 AC_CONFIG_FILES([Make.tmp:Make.vars.in:Makefile.in])
2934
2935 dnl Some final makefile rules
2936
2937 if test -n "$with_wine64"
2938 then
2939 WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
2940 [all: fonts server $with_wine64/loader/wine
2941 fonts server:
2942         \$(RM) \$[@] && \$(LN_S) $with_wine64/\$[@] \$[@]
2943 $with_wine64/loader/wine:
2944         \$(RM) \$[@] && \$(LN_S) $ac_pwd/loader/wine \$[@]
2945 clean::
2946         \$(RM) fonts server $with_wine64/loader/wine])
2947 fi
2948
2949 WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
2950 [uninstall::
2951         -rmdir \$(DESTDIR)\$(datadir)/wine \$(DESTDIR)\$(fakedlldir) \$(DESTDIR)\$(dlldir)])
2952
2953 AC_OUTPUT
2954
2955 if test "$no_create" = "yes"
2956 then
2957   exit 0
2958 fi
2959
2960 WINE_PRINT_MESSAGES
2961
2962 echo "
2963 $as_me: Finished.  Do '${ac_make}' to compile Wine.
2964 " >&AS_MESSAGE_FD
2965
2966 dnl Local Variables:
2967 dnl comment-start: "dnl "
2968 dnl comment-end: ""
2969 dnl comment-start-skip: "\\bdnl\\b\\s *"
2970 dnl compile-command: "autoreconf --warnings=all"
2971 dnl End: