include/wtypes.idl

   1 /*
   2  * Basic types used by COM interfaces
   3  *
   4  * Copyright 2002 Ove Kaaven
   5  *
   6  * This library is free software; you can redistribute it and/or
   7  * modify it under the terms of the GNU Lesser General Public
   8  * License as published by the Free Software Foundation; either
   9  * version 2.1 of the License, or (at your option) any later version.
  10  *
  11  * This library is distributed in the hope that it will be useful,
  12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14  * Lesser General Public License for more details.
  15  *
  16  * You should have received a copy of the GNU Lesser General Public
  17  * License along with this library; if not, write to the Free Software
  18  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  19  */
  20
  21 import "basetsd.h";
  22 import "guiddef.h";
  23
  24 [
  25   uuid(D3980A60-910C-1068-9341-00DD010F2F1C),
  26   version(0.1),
  27   pointer_default(unique)
  28 ]
  29
  30 interface IWinTypes
  31 {
  32
  33 /******************** BASIC WIN32 TYPES ********************/
  34 cpp_quote("#if 0 /* winnt.h */") /* don't redefine these */
  35
  36 typedef unsigned char BYTE;
  37 typedef unsigned short WORD;
  38 typedef unsigned long DWORD;
  39 typedef long BOOL;
  40 typedef unsigned char UCHAR;
  41 typedef int INT;
  42 typedef unsigned int UINT;
  43 typedef short SHORT;
  44 typedef unsigned short USHORT;
  45 typedef long LONG;
  46 typedef unsigned long ULONG;
  47 typedef float FLOAT;
  48 typedef double DOUBLE;
  49
  50 typedef void *PVOID, *LPVOID;
  51
  52 typedef char CHAR;
  53 typedef [string] CHAR *LPSTR;
  54 typedef [string] const CHAR *LPCSTR;
  55
  56 typedef wchar_t WCHAR;
  57 typedef [string] WCHAR *LPWSTR;
  58 typedef [string] const WCHAR *LPCWSTR;
  59
  60 typedef boolean BOOLEAN;
  61
  62 typedef DWORD COLORREF;
  63
  64 typedef void *HANDLE;
  65 #define DECLARE_HANDLE(name) typedef void *name
  66 #define DECLARE_WIREM_HANDLE(name) typedef [wire_marshal(wire##name)] void*name
  67
  68 DECLARE_HANDLE(HACCEL);
  69 DECLARE_HANDLE(HDC);
  70 DECLARE_HANDLE(HFONT);
  71 DECLARE_HANDLE(HWND);
  72 DECLARE_HANDLE(HMENU);
  73 DECLARE_HANDLE(HMODULE);
  74 DECLARE_HANDLE(HINSTANCE);
  75 DECLARE_HANDLE(HRGN);
  76 DECLARE_HANDLE(HTASK);
  77 DECLARE_HANDLE(HKEY);
  78
  79 typedef LONG_PTR LRESULT;
  80
  81 typedef double DATE;
  82 typedef LONG HRESULT;
  83 typedef DWORD LCID;
  84
  85 typedef unsigned __int64 DWORDLONG;
  86 typedef __int64 LONGLONG;
  87 typedef unsigned __int64 ULONGLONG;
  88
  89 typedef struct _LARGE_INTEGER {
  90   LONGLONG QuadPart;
  91 } LARGE_INTEGER;
  92
  93 typedef struct _ULARGE_INTEGER {
  94   ULONGLONG QuadPart;
  95 } ULARGE_INTEGER;
  96
  97 typedef struct _SID_IDENTIFIER_AUTHORITY {
  98   UCHAR Value[6];
  99 } SID_IDENTIFIER_AUTHORITY, *PSID_IDENTIFIER_AUTHORITY;
 100
 101 typedef struct _SID {
 102   UCHAR Revision;
 103   UCHAR SubAuthorityCount;
 104   SID_IDENTIFIER_AUTHORITY IdentifierAuthority;
 105   [size_is(SubAuthorityCount)] ULONG SubAuthority[*];
 106 } SID, *PSID;
 107
 108 typedef USHORT SECURITY_DESCRIPTOR_CONTROL, *PSECURITY_DESCRIPTOR_CONTROL;
 109
 110 typedef struct _ACL {
 111   UCHAR AclRevision;
 112   UCHAR Sbz1;
 113   USHORT AclSize;
 114   USHORT AceCount;
 115   USHORT Sbz2;
 116 } ACL;
 117 typedef ACL *PACL;
 118
 119 typedef struct _SECURITY_DESCRIPTOR {
 120   UCHAR Revision;
 121   UCHAR Sbz1;
 122   SECURITY_DESCRIPTOR_CONTROL Control;
 123   PSID Owner;
 124   PSID Group;
 125   PACL Sacl;
 126   PACL Dacl;
 127 } SECURITY_DESCRIPTOR, *PSECURITY_DESCRIPTOR;
 128
 129 typedef struct tagSIZE
 130 {
 131     LONG cx;
 132     LONG cy;
 133 } SIZE, *PSIZE, *LPSIZE;
 134 typedef SIZE SIZEL, *PSIZEL, *LPSIZEL;
 135
 136 typedef struct tagPOINT
 137 {
 138     LONG  x;
 139     LONG  y;
 140 } POINT, *PPOINT, *LPPOINT;
 141
 142 typedef struct _POINTL
 143 {
 144     LONG x;
 145     LONG y;
 146 } POINTL;
 147
 148 typedef struct tagRECT
 149 {
 150     LONG left;
 151     LONG top;
 152     LONG right;
 153     LONG bottom;
 154 } RECT, *PRECT, *LPRECT;
 155 typedef const RECT *LPCRECT;
 156
 157 typedef struct _RECTL
 158 {
 159     LONG left;
 160     LONG top;
 161     LONG right;
 162     LONG bottom;
 163 } RECTL, *PRECTL, *LPRECTL;
 164 typedef const RECTL *LPCRECTL;
 165
 166 typedef UINT_PTR WPARAM;
 167 typedef LONG_PTR LPARAM;
 168
 169 typedef struct tagMSG
 170 {
 171     HWND   hwnd;
 172     UINT   message;
 173     WPARAM wParam;
 174     LPARAM lParam;
 175     DWORD  time;
 176     POINT  pt;
 177 } MSG, *PMSG, *NPMSG, *LPMSG;
 178
 179 cpp_quote("#endif /* winnt.h */")
 180
 181 cpp_quote("#ifndef _PALETTEENTRY_DEFINED")
 182 cpp_quote("#define _PALETTEENTRY_DEFINED")
 183 typedef struct tagPALETTEENTRY {
 184   BYTE peRed;
 185   BYTE peGreen;
 186   BYTE peBlue;
 187   BYTE peFlags;
 188 } PALETTEENTRY, *PPALETTEENTRY, *LPPALETTEENTRY;
 189 cpp_quote("#endif")
 190
 191 cpp_quote("#ifndef _LOGPALETTE_DEFINED")
 192 cpp_quote("#define _LOGPALETTE_DEFINED")
 193 typedef struct tagLOGPALETTE
 194 {
 195   WORD palVersion;
 196   WORD palNumEntries;
 197   [size_is(palNumEntries)] PALETTEENTRY palPalEntry[*];
 198 } LOGPALETTE, *PLOGPALETTE, *LPLOGPALETTE;
 199 cpp_quote("#endif")
 200
 201 cpp_quote("#ifndef _FILETIME_")
 202 cpp_quote("#define _FILETIME_")
 203 typedef struct _FILETIME {
 204   DWORD dwLowDateTime;
 205   DWORD dwHighDateTime;
 206 } FILETIME, *PFILETIME, *LPFILETIME;
 207 cpp_quote("#endif")
 208
 209 cpp_quote("#ifndef _TEXTMETRIC_DEFINED")
 210 cpp_quote("#define _TEXTMETRIC_DEFINED")
 211 typedef struct
 212 {
 213     LONG      tmHeight;
 214     LONG      tmAscent;
 215     LONG      tmDescent;
 216     LONG      tmInternalLeading;
 217     LONG      tmExternalLeading;
 218     LONG      tmAveCharWidth;
 219     LONG      tmMaxCharWidth;
 220     LONG      tmWeight;
 221     LONG      tmOverhang;
 222     LONG      tmDigitizedAspectX;
 223     LONG      tmDigitizedAspectY;
 224     BYTE      tmFirstChar;
 225     BYTE      tmLastChar;
 226     BYTE      tmDefaultChar;
 227     BYTE      tmBreakChar;
 228     BYTE      tmItalic;
 229     BYTE      tmUnderlined;
 230     BYTE      tmStruckOut;
 231     BYTE      tmPitchAndFamily;
 232     BYTE      tmCharSet;
 233 } TEXTMETRICA, *LPTEXTMETRICA, *PTEXTMETRICA;
 234
 235 typedef struct
 236 {
 237     LONG      tmHeight;
 238     LONG      tmAscent;
 239     LONG      tmDescent;
 240     LONG      tmInternalLeading;
 241     LONG      tmExternalLeading;
 242     LONG      tmAveCharWidth;
 243     LONG      tmMaxCharWidth;
 244     LONG      tmWeight;
 245     LONG      tmOverhang;
 246     LONG      tmDigitizedAspectX;
 247     LONG      tmDigitizedAspectY;
 248     WCHAR     tmFirstChar;
 249     WCHAR     tmLastChar;
 250     WCHAR     tmDefaultChar;
 251     WCHAR     tmBreakChar;
 252     BYTE      tmItalic;
 253     BYTE      tmUnderlined;
 254     BYTE      tmStruckOut;
 255     BYTE      tmPitchAndFamily;
 256     BYTE      tmCharSet;
 257 } TEXTMETRICW, *LPTEXTMETRICW, *PTEXTMETRICW;
 258 cpp_quote("#endif")
 259
 260 /******************** BASIC COM/OLE TYPES ********************/
 261
 262 typedef WCHAR OLECHAR;
 263 typedef [string] OLECHAR *LPOLESTR;
 264 typedef [string] const OLECHAR *LPCOLESTR;
 265 cpp_quote("#ifndef __WINESRC__")
 266 cpp_quote("#define OLESTR(str) L##str")
 267 cpp_quote("#endif")
 268
 269 /* from Wine's pre-WIDL wtypes.h */
 270 /* FIXME: does not belong here */
 271 typedef CHAR OLECHAR16;
 272 typedef LPSTR LPOLESTR16;
 273 typedef LPCSTR LPCOLESTR16;
 274 /* quoted because if BSTR16 is ever used in IDL files,
 275  * it'll probably need some wire_marshal stuff too,
 276  * and quoting these will detect any such necessity */
 277 cpp_quote("typedef OLECHAR16 *BSTR16;")
 278 cpp_quote("typedef BSTR16 *LPBSTR16;")
 279 cpp_quote("#define OLESTR16(x) x")
 280
 281 typedef LONG SCODE;
 282
 283 typedef struct _COAUTHIDENTITY {
 284   [size_is(UserLength+1)] USHORT *User;
 285   ULONG UserLength;
 286   [size_is(DomainLength+1)] USHORT *Domain;
 287   ULONG DomainLength;
 288   [size_is(PasswordLength+1)] USHORT *Password;
 289   ULONG PasswordLength;
 290   ULONG Flags;
 291 } COAUTHIDENTITY;
 292
 293 typedef struct _COAUTHINFO {
 294   DWORD dwAuthnSvc;
 295   DWORD dwAuthzSvc;
 296   LPWSTR pwszServerPrincName;
 297   DWORD dwAuthnLevel;
 298   DWORD dwImpersonationLevel;
 299   COAUTHIDENTITY *pAuthIdentityData;
 300   DWORD dwCapabilities;
 301 } COAUTHINFO;
 302
 303 /* FIXME: COSERVERINFO was in Wine's pre-WIDL wtypes.h, but should be in objidl.idl */
 304 typedef struct _COSERVERINFO {
 305   DWORD dwReserved1;
 306   LPWSTR pwszName;
 307   COAUTHINFO *pAuthInfo;
 308   DWORD dwReserved2;
 309 } COSERVERINFO;
 310
 311 typedef enum tagMEMCTX {
 312   MEMCTX_TASK      = 1,
 313   MEMCTX_SHARED    = 2,
 314   MEMCTX_MACSYSTEM = 3,
 315   MEMCTX_UNKNOWN   = -1,
 316   MEMCTX_SAME      = -2
 317 } MEMCTX;
 318
 319 cpp_quote("#ifndef _ROTFLAGS_DEFINED")
 320 cpp_quote("#define _ROTFLAGS_DEFINED")
 321 cpp_quote("#define ROTFLAGS_REGISTRATIONKEEPSALIVE 0x1")
 322 cpp_quote("#define ROTFLAGS_ALLOWANYCLIENT 0x2")
 323 cpp_quote("#endif")
 324
 325 typedef enum tagCLSCTX {
 326   CLSCTX_INPROC_SERVER        = 0x1,
 327   CLSCTX_INPROC_HANDLER       = 0x2,
 328   CLSCTX_LOCAL_SERVER         = 0x4,
 329   CLSCTX_INPROC_SERVER16      = 0x8,
 330   CLSCTX_REMOTE_SERVER        = 0x10,
 331   CLSCTX_INPROC_HANDLER16     = 0x20,
 332   CLSCTX_INPROC_SERVERX86     = 0x40,
 333   CLSCTX_INPROC_HANDLERX86    = 0x80,
 334   CLSCTX_ESERVER_HANDLER      = 0x100,
 335   CLSCTX_NO_CODE_DOWNLOAD     = 0x400,
 336   CLSCTX_NO_CUSTOM_MARSHAL    = 0x1000,
 337   CLSCTX_ENABLE_CODE_DOWNLOAD = 0x2000,
 338   CLSCTX_NO_FAILURE_LOG       = 0x4000,
 339   CLSCTX_DISABLE_AAA          = 0x8000,
 340   CLSCTX_ENABLE_AAA           = 0x10000,
 341   CLSCTX_FROM_DEFAULT_CONTEXT = 0x20000
 342 } CLSCTX;
 343
 344 cpp_quote("#define CLSCTX_INPROC (CLSCTX_INPROC_SERVER | CLSCTX_INPROC_HANDLER)")
 345 cpp_quote("#define CLSCTX_ALL (CLSCTX_INPROC_SERVER | CLSCTX_INPROC_HANDLER | CLSCTX_LOCAL_SERVER | CLSCTX_REMOTE_SERVER)")
 346 cpp_quote("#define CLSCTX_SERVER (CLSCTX_INPROC_SERVER | CLSCTX_LOCAL_SERVER | CLSCTX_REMOTE_SERVER)")
 347
 348 typedef enum tagMSHLFLAGS {
 349   MSHLFLAGS_NORMAL      = 0,
 350   MSHLFLAGS_TABLESTRONG = 1,
 351   MSHLFLAGS_TABLEWEAK   = 2,
 352   MSHLFLAGS_NOPING      = 4
 353 } MSHLFLAGS;
 354
 355 typedef enum tagMSHCTX {
 356   MSHCTX_LOCAL            = 0,
 357   MSHCTX_NOSHAREDMEM      = 1,
 358   MSHCTX_DIFFERENTMACHINE = 2,
 359   MSHCTX_INPROC           = 3,
 360   MSHCTX_CROSSCTX         = 4
 361 } MSHCTX;
 362
 363 /******************** BLOB TYPES ********************/
 364
 365 typedef struct _BYTE_BLOB {
 366   unsigned long clSize;
 367   [size_is(clSize)] byte abData[];
 368 } BYTE_BLOB;
 369 typedef [unique] BYTE_BLOB *UP_BYTE_BLOB;
 370
 371 typedef struct _FLAGGED_BYTE_BLOB {
 372   unsigned long fFlags;
 373   unsigned long clSize;
 374   [size_is(clSize)] byte abData[];
 375 } FLAGGED_BYTE_BLOB;
 376 typedef [unique] FLAGGED_BYTE_BLOB *UP_FLAGGED_BYTE_BLOB;
 377
 378 typedef struct _FLAGGED_WORD_BLOB {
 379   unsigned long fFlags;
 380   unsigned long clSize;
 381   [size_is(clSize)] unsigned short asData[];
 382 } FLAGGED_WORD_BLOB;
 383 typedef [unique] FLAGGED_WORD_BLOB *UP_FLAGGED_WORD_BLOB;
 384
 385 typedef struct _BYTE_SIZEDARR {
 386   unsigned long clSize;
 387   [size_is(clSize)] byte *pData;
 388 } BYTE_SIZEDARR;
 389
 390 typedef struct _SHORT_SIZEDARR {
 391   unsigned long clSize;
 392   [size_is(clSize)] unsigned short *pData;
 393 } WORD_SIZEDARR;
 394
 395 typedef struct _LONG_SIZEDARR {
 396   unsigned long clSize;
 397   [size_is(clSize)] unsigned long *pData;
 398 } DWORD_SIZEDARR;
 399
 400 typedef struct _HYPER_SIZEDARR {
 401   unsigned long clSize;
 402   [size_is(clSize)] hyper *pData;
 403 } HYPER_SIZEDARR;
 404
 405 /******************** GDI TYPES ********************/
 406
 407 const unsigned long WDT_INPROC_CALL = 0x48746457;
 408 const unsigned long WDT_REMOTE_CALL = 0x52746457;
 409
 410 typedef union _userCLIPFORMAT switch(long fContext) u {
 411   case WDT_INPROC_CALL: DWORD dwValue;
 412   case WDT_REMOTE_CALL: LPWSTR pwszName;
 413 } userCLIPFORMAT;
 414
 415 typedef [unique] userCLIPFORMAT *wireCLIPFORMAT;
 416 typedef [wire_marshal(wireCLIPFORMAT)] WORD CLIPFORMAT;
 417
 418 typedef struct tagRemHGLOBAL {
 419   long fNullHGlobal;
 420   unsigned long cbData;
 421   [size_is(cbData)] byte data[];
 422 } RemHGLOBAL;
 423
 424 typedef union _userHGLOBAL switch(long fContext) u {
 425   case WDT_INPROC_CALL: long               hInproc;
 426   case WDT_REMOTE_CALL: FLAGGED_BYTE_BLOB *hRemote;
 427   default:              long               hGlobal;
 428 } userHGLOBAL;
 429
 430 typedef [unique] userHGLOBAL *wireHGLOBAL;
 431
 432 typedef struct tagRemHMETAFILEPICT {
 433   long mm;
 434   long xExt;
 435   long yExt;
 436   unsigned long cbData;
 437   [size_is(cbData)] byte data[];
 438 } RemHMETAFILEPICT;
 439
 440 typedef union _userHMETAFILE switch(long fContext) u {
 441   case WDT_INPROC_CALL: long       hInproc;
 442   case WDT_REMOTE_CALL: BYTE_BLOB *hRemote;
 443   default:              long       hGlobal;
 444 } userHMETAFILE;
 445
 446 typedef [unique] userHMETAFILE *wireHMETAFILE;
 447
 448 typedef struct _remoteMETAFILEPICT {
 449   long mm;
 450   long xExt;
 451   long yExt;
 452   userHMETAFILE *hMF;
 453 } remoteMETAFILEPICT;
 454
 455 typedef union _userHMETAFILEPICT switch(long fContext) u {
 456   case WDT_INPROC_CALL: long                hInproc;
 457   case WDT_REMOTE_CALL: remoteMETAFILEPICT *hRemote;
 458   default:              long                hGlobal;
 459 } userHMETAFILEPICT;
 460
 461 typedef [unique] userHMETAFILEPICT *wireHMETAFILEPICT;
 462
 463 typedef struct tagRemHENHMETAFILE {
 464   unsigned long cbData;
 465   [size_is(cbData)] byte data[];
 466 } RemHENHMETAFILE;
 467
 468 typedef union _userHENHMETAFILE switch(long fContext) u {
 469   case WDT_INPROC_CALL: long       hInproc;
 470   case WDT_REMOTE_CALL: BYTE_BLOB *hRemote;
 471   default:              long       hGlobal;
 472 } userHENHMETAFILE;
 473
 474 typedef [unique] userHENHMETAFILE *wireHENHMETAFILE;
 475
 476 typedef struct tagRemHBITMAP
 477 {
 478   unsigned long cbData;
 479   [size_is(cbData)] byte data[];
 480 } RemHBITMAP;
 481
 482 typedef struct _userBITMAP {
 483   LONG bmType;
 484   LONG bmWidth;
 485   LONG bmHeight;
 486   LONG bmWidthBytes;
 487   WORD bmPlanes;
 488   WORD bmBitsPixel;
 489   ULONG cbSize;
 490   [size_is(cbSize)] byte pBuffer[];
 491 } userBITMAP;
 492
 493 typedef union _userHBITMAP switch(long fContext) u {
 494   case WDT_INPROC_CALL: long        hInproc;
 495   case WDT_REMOTE_CALL: userBITMAP *hRemote;
 496   default:              long        hGlobal;
 497 } userHBITMAP;
 498
 499 typedef [unique] userHBITMAP *wireHBITMAP;
 500
 501 typedef struct tagRemHPALETTE {
 502   unsigned long cbData;
 503   [size_is(cbData)] byte data[];
 504 } RemHPALETTE;
 505
 506 typedef struct tagrpcLOGPALETTE {
 507   WORD palVersion;
 508   WORD palNumEntries;
 509   [size_is(palNumEntries)] PALETTEENTRY palPalEntry[];
 510 } rpcLOGPALETTE;
 511
 512 typedef union _userHPALETTE switch(long fContext) u {
 513   case WDT_INPROC_CALL: long           hInproc;
 514   case WDT_REMOTE_CALL: rpcLOGPALETTE *hRemote;
 515   default:              long           hGlobal;
 516 } userHPALETTE;
 517
 518 typedef [unique] userHPALETTE *wireHPALETTE;
 519
 520 cpp_quote("#if 0")
 521 DECLARE_WIREM_HANDLE(HGLOBAL);
 522 typedef HGLOBAL HLOCAL;
 523 DECLARE_WIREM_HANDLE(HBITMAP);
 524 DECLARE_WIREM_HANDLE(HPALETTE);
 525 DECLARE_WIREM_HANDLE(HENHMETAFILE);
 526 DECLARE_WIREM_HANDLE(HMETAFILE);
 527 cpp_quote("#endif")
 528 DECLARE_WIREM_HANDLE(HMETAFILEPICT);
 529
 530 /******************** GUID TYPES ********************/
 531
 532 cpp_quote("#if 0") /* for IDL only (C/C++ defs are in guiddef.h) */
 533 typedef GUID *REFGUID;
 534 typedef IID *REFIID;
 535 typedef CLSID *REFCLSID;
 536 typedef FMTID *REFFMTID;
 537 cpp_quote("#endif")
 538
 539 /******************** MISC TYPES ********************/
 540
 541 typedef enum tagDVASPECT {
 542   DVASPECT_CONTENT   = 1,
 543   DVASPECT_THUMBNAIL = 2,
 544   DVASPECT_ICON      = 4,
 545   DVASPECT_DOCPRINT  = 8
 546 } DVASPECT;
 547
 548 typedef enum tagSTGC {
 549   STGC_DEFAULT       = 0,
 550   STGC_OVERWRITE     = 1,
 551   STGC_ONLYIFCURRENT = 2,
 552   STGC_DANGEROUSLYCOMMITMERELYTODISKCACHE = 4,
 553   STGC_CONSOLIDATE   = 8
 554 } STGC;
 555
 556 typedef enum tagSTGMOVE {
 557   STGMOVE_MOVE        = 0,
 558   STGMOVE_COPY        = 1,
 559   STGMOVE_SHALLOWCOPY = 2
 560 } STGMOVE;
 561
 562 typedef enum tagSTATFLAG {
 563   STATFLAG_DEFAULT = 0,
 564   STATFLAG_NONAME  = 1,
 565   STATFLAG_NOOPEN  = 2
 566 } STATFLAG;
 567
 568 /******************** OLE Automation ********************/
 569
 570 cpp_quote("#if 0") /* for IDL only */
 571 typedef struct tagCY {
 572   LONGLONG int64;
 573 } CY;
 574 cpp_quote("#else") /* C/C++ defs */
 575 cpp_quote("typedef union tagCY {")
 576 cpp_quote("    struct {")
 577 cpp_quote("#ifdef WORDS_BIGENDIAN")
 578 cpp_quote("        LONG  Hi;")
 579 cpp_quote("        ULONG Lo;")
 580 cpp_quote("#else")
 581 cpp_quote("        ULONG Lo;")
 582 cpp_quote("        LONG  Hi;")
 583 cpp_quote("#endif")
 584 cpp_quote("    } DUMMYSTRUCTNAME;")
 585 cpp_quote("    LONGLONG int64;")
 586 cpp_quote("} CY;")
 587 cpp_quote("#endif")
 588
 589 typedef CY *LPCY;
 590
 591 cpp_quote("#if 0") /* for IDL only */
 592 typedef struct tagDEC {
 593   USHORT wReserved;
 594   BYTE scale;
 595   BYTE sign;
 596   ULONG Hi32;
 597   ULONGLONG Lo64;
 598 } DECIMAL;
 599 cpp_quote("#else") /* C/C++ defs */
 600 cpp_quote("typedef struct tagDEC {")
 601 cpp_quote("  USHORT wReserved;")
 602 cpp_quote("  union {")
 603 cpp_quote("    struct {")
 604 cpp_quote("      BYTE scale;")
 605 cpp_quote("      BYTE sign;")
 606 cpp_quote("    } DUMMYSTRUCTNAME;")
 607 cpp_quote("    USHORT signscale;")
 608 cpp_quote("  } DUMMYUNIONNAME;")
 609 cpp_quote("  ULONG Hi32;")
 610 cpp_quote("  union {")
 611 cpp_quote("    struct {")
 612 cpp_quote("#ifdef WORDS_BIGENDIAN")
 613 cpp_quote("      ULONG Mid32;")
 614 cpp_quote("      ULONG Lo32;")
 615 cpp_quote("#else")
 616 cpp_quote("      ULONG Lo32;")
 617 cpp_quote("      ULONG Mid32;")
 618 cpp_quote("#endif")
 619 cpp_quote("    } DUMMYSTRUCTNAME1;")
 620 cpp_quote("    ULONGLONG Lo64;")
 621 cpp_quote("  } DUMMYUNIONNAME1;")
 622 cpp_quote("} DECIMAL;")
 623 cpp_quote("#endif")
 624 cpp_quote("#define DECIMAL_NEG ((BYTE)0x80)")
 625 cpp_quote("#define DECIMAL_SETZERO(d) do{ memset(((char*)(d)) + sizeof(USHORT), 0, sizeof(ULONG) * 3u + sizeof(USHORT)); }while (0)")
 626
 627 typedef DECIMAL *LPDECIMAL;
 628
 629 typedef [unique] FLAGGED_WORD_BLOB *wireBSTR;
 630 typedef [wire_marshal(wireBSTR)] OLECHAR *BSTR;
 631 typedef BSTR *LPBSTR;
 632
 633 typedef short VARIANT_BOOL;
 634 typedef VARIANT_BOOL _VARIANT_BOOL;
 635 cpp_quote("#define VARIANT_TRUE  ((VARIANT_BOOL)0xFFFF)")
 636 cpp_quote("#define VARIANT_FALSE ((VARIANT_BOOL)0x0000)")
 637
 638 typedef struct tagBSTRBLOB {
 639   ULONG cbSize;
 640   [size_is(cbSize)] BYTE *pData;
 641 } BSTRBLOB, *LPBSTRBLOB;
 642
 643 typedef struct tagBLOB {
 644   ULONG cbSize;
 645   [size_is(cbSize)] BYTE *pBlobData;
 646 } BLOB, *LPBLOB;
 647
 648 typedef struct tagCLIPDATA {
 649   ULONG cbSize;
 650   long ulClipFmt;
 651   [size_is(cbSize-sizeof(long))] BYTE *pClipData;
 652 } CLIPDATA;
 653 cpp_quote("#define CBPCLIPDATA(cb) ((cb).cbSize - sizeof((cb).ulClipFmt))")
 654
 655 typedef ULONG PROPID;
 656
 657 /******************** VARTYPE ********************/
 658
 659 typedef unsigned short VARTYPE;
 660 enum VARENUM {
 661   VT_EMPTY           = 0,
 662   VT_NULL            = 1,
 663   VT_I2              = 2,
 664   VT_I4              = 3,
 665   VT_R4              = 4,
 666   VT_R8              = 5,
 667   VT_CY              = 6,
 668   VT_DATE            = 7,
 669   VT_BSTR            = 8,
 670   VT_DISPATCH        = 9,
 671   VT_ERROR           = 10,
 672   VT_BOOL            = 11,
 673   VT_VARIANT         = 12,
 674   VT_UNKNOWN         = 13,
 675   VT_DECIMAL         = 14,
 676   VT_I1              = 16,
 677   VT_UI1             = 17,
 678   VT_UI2             = 18,
 679   VT_UI4             = 19,
 680   VT_I8              = 20,
 681   VT_UI8             = 21,
 682   VT_INT             = 22,
 683   VT_UINT            = 23,
 684   VT_VOID            = 24,
 685   VT_HRESULT         = 25,
 686   VT_PTR             = 26,
 687   VT_SAFEARRAY       = 27,
 688   VT_CARRAY          = 28,
 689   VT_USERDEFINED     = 29,
 690   VT_LPSTR           = 30,
 691   VT_LPWSTR          = 31,
 692   VT_RECORD          = 36,
 693   VT_INT_PTR         = 37,
 694   VT_UINT_PTR        = 38,
 695   VT_FILETIME        = 64,
 696   VT_BLOB            = 65,
 697   VT_STREAM          = 66,
 698   VT_STORAGE         = 67,
 699   VT_STREAMED_OBJECT = 68,
 700   VT_STORED_OBJECT   = 69,
 701   VT_BLOB_OBJECT     = 70,
 702   VT_CF              = 71,
 703   VT_CLSID           = 72,
 704   VT_BSTR_BLOB       = 0x0fff,
 705   VT_VECTOR          = 0x1000,
 706   VT_ARRAY           = 0x2000,
 707   VT_BYREF           = 0x4000,
 708   VT_RESERVED        = 0x8000,
 709   VT_ILLEGAL         = 0xffff,
 710   VT_ILLEGALMASKED   = 0x0fff,
 711   VT_TYPEMASK        = 0x0fff
 712 };
 713
 714 } /* interface IWinTypes */