| blob | 8d89e0c8a05b918c6926517037c95a61bdcaf326 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53b)
8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
18 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
19 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
20 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
22 AC_CANONICAL_HOST
23 case $host in
24 x86_64*linux*)
25 if test "x$enable_win64" != "xyes"
26 then
27 test -n "$CC" || CC="gcc -m32"
28 test -n "$LD" || LD="ld -m elf_i386"
29 test -n "$AS" || AS="as --32"
30 host_cpu="i386"
31 fi
32 ;;
33 esac
35 dnl enable_win16 defaults to yes on x86, to no on other CPUs
36 case $host_cpu in
37 *i[[3456789]]86*)
38 if test "x$enable_win16" != "xno"
39 then
40 enable_win16="yes"
41 fi
42 ;;
43 esac
45 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
46 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
47 if test "x$enable_win16" != "xyes"
48 then
49 WIN16_FILES=""
50 WIN16_INSTALL=""
51 fi
53 dnl **** Check for some programs ****
55 AC_PROG_MAKE_SET
56 AC_PROG_CC
57 AC_PROG_CXX
58 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
59 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
61 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
62 [if test -z "$with_wine_tools"; then
63 if test "$cross_compiling" = "yes"; then
64 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
65 else
66 wine_cv_toolsdir="\$(TOPOBJDIR)"
67 fi
68 elif test -d "$with_wine_tools/tools/winebuild"; then
69 case $with_wine_tools in
70 /*) wine_cv_toolsdir="$with_wine_tools" ;;
71 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
72 esac
73 else
74 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
75 fi])
76 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
78 AC_PATH_XTRA
79 AC_PROG_LEX
81 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
82 dnl **** without one present.
83 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
84 if test "$XLEX" = "none"
85 then
86 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
87 fi
89 dnl Check for bison
90 AC_CHECK_PROGS(BISON,bison,none)
91 if test "$BISON" = "none"
92 then
93 AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
94 fi
96 AC_CHECK_TOOLS(AS,[gas as],as)
97 AC_CHECK_TOOL(LD,ld,ld)
98 AC_CHECK_TOOL(AR,ar,ar)
99 AC_PROG_RANLIB
100 AC_CHECK_TOOL(STRIP,strip,strip)
101 AC_CHECK_TOOL(WINDRES,windres,false)
102 AC_PROG_LN_S
103 WINE_PROG_LN
104 AC_PROG_EGREP
105 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
106 AC_PROG_INSTALL
107 dnl Prepend src dir to install path dir if it's a relative path
108 case "$INSTALL" in
109 [[\\/$]]* | ?:[[\\/]]* ) ;;
110 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
111 esac
113 dnl Check for lint
114 AC_CHECK_PROGS(LINT, lclint lint)
115 if test "$LINT" = "lint"
116 then
117 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
118 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
119 fi
120 AC_SUBST(LINT)
121 AC_SUBST(LINTFLAGS)
123 dnl Check for various programs
124 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
125 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
127 case $host_cpu in
128 *i[[3456789]]86*)
129 AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
130 ;;
131 esac
133 dnl **** Check for some libraries ****
135 dnl Check for -li386 for NetBSD and OpenBSD
136 AC_CHECK_LIB(i386,i386_set_ldt)
137 dnl Check for -lossaudio for NetBSD
138 AC_CHECK_LIB(ossaudio,_oss_ioctl)
139 dnl Check for -lxpg4 for FreeBSD
140 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
141 dnl Check for -lpthread
142 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
144 AC_SUBST(XLIB,"")
145 AC_SUBST(XFILES,"")
146 AC_SUBST(OPENGLFILES,"")
147 AC_SUBST(GLU32FILES,"")
148 AC_SUBST(OPENGL_LIBS,"")
150 dnl **** Check for header files ****
152 AC_CHECK_HEADERS(\
153 AudioUnit/AudioUnit.h \
154 CoreAudio/CoreAudio.h \
155 IOKit/IOKitLib.h \
156 alsa/asoundlib.h \
157 arpa/inet.h \
158 arpa/nameser.h \
159 asm/types.h \
160 capi20.h \
161 cups/cups.h \
162 curses.h \
163 direct.h \
164 dlfcn.h \
165 elf.h \
166 float.h \
167 fontconfig/fontconfig.h \
168 getopt.h \
169 gif_lib.h \
170 ieeefp.h \
171 io.h \
172 jack/jack.h \
173 jpeglib.h \
174 lber.h \
175 lcms.h \
176 lcms/lcms.h \
177 ldap.h \
178 libaudioio.h \
179 link.h \
180 linux/cdrom.h \
181 linux/compiler.h \
182 linux/hdreg.h \
183 linux/input.h \
184 linux/ioctl.h \
185 linux/joystick.h \
186 linux/major.h \
187 linux/param.h \
188 linux/serial.h \
189 linux/ucdrom.h \
190 mach/machine.h \
191 machine/cpu.h \
192 machine/limits.h \
193 machine/soundcard.h \
194 mntent.h \
195 ncurses.h \
196 netdb.h \
197 netinet/in.h \
198 netinet/in_systm.h \
199 netinet/tcp.h \
200 netinet/tcp_fsm.h \
201 openssl/err.h \
202 openssl/ssl.h \
203 poll.h \
204 process.h \
205 pthread.h \
206 pthread_np.h \
207 pwd.h \
208 regex.h \
209 sched.h \
210 scsi/scsi.h \
211 scsi/scsi_ioctl.h \
212 scsi/sg.h \
213 soundcard.h \
214 stdint.h \
215 strings.h \
216 sys/asoundlib.h \
217 sys/cdio.h \
218 sys/elf32.h \
219 sys/epoll.h \
220 sys/errno.h \
221 sys/event.h \
222 sys/exec_elf.h \
223 sys/filio.h \
224 sys/ioctl.h \
225 sys/ipc.h \
226 sys/limits.h \
227 sys/link.h \
228 sys/lwp.h \
229 sys/mman.h \
230 sys/modem.h \
231 sys/msg.h \
232 sys/mtio.h \
233 sys/param.h \
234 sys/poll.h \
235 sys/prctl.h \
236 sys/ptrace.h \
237 sys/reg.h \
238 sys/resource.h \
239 sys/scsiio.h \
240 sys/shm.h \
241 sys/signal.h \
242 sys/socket.h \
243 sys/sockio.h \
244 sys/soundcard.h \
245 sys/statvfs.h \
246 sys/strtio.h \
247 sys/syscall.h \
248 sys/sysctl.h \
249 sys/time.h \
250 sys/times.h \
251 sys/uio.h \
252 sys/un.h \
253 sys/vm86.h \
254 sys/wait.h \
255 syscall.h \
256 termios.h \
257 unicode/ubidi.h \
258 unistd.h \
259 utime.h \
260 valgrind/memcheck.h
261 )
262 AC_HEADER_STAT()
264 dnl **** Checks for headers that depend on other ones ****
266 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
267 [#include <sys/types.h>
268 #if HAVE_SYS_PARAM_H
269 # include <sys/param.h>
270 #endif])
272 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
273 [#include <sys/types.h>
274 #if HAVE_SYS_SOCKET_H
275 # include <sys/socket.h>
276 #endif])
278 AC_CHECK_HEADERS([linux/ipx.h],,,
279 [#include <sys/types.h>
280 #ifdef HAVE_ASM_TYPES_H
281 # include <asm/types.h>
282 #endif
283 #if HAVE_SYS_SOCKET_H
284 # include <sys/socket.h>
285 #endif])
287 AC_CHECK_HEADERS([resolv.h],,,
288 [#include <sys/types.h>
289 #if HAVE_SYS_SOCKET_H
290 # include <sys/socket.h>
291 #endif
292 #if HAVE_NETINET_IN_H
293 # include <netinet/in.h>
294 #endif
295 #if HAVE_ARPA_NAMESER_H
296 # include <arpa/nameser.h>
297 #endif])
299 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
301 AC_CHECK_HEADERS([linux/videodev.h],,,
302 [#ifdef HAVE_SYS_TIME_H
303 #include <sys/time.h>
304 #endif
305 #include <sys/types.h>
306 #ifdef HAVE_ASM_TYPES_H
307 #include <asm/types.h>
308 #endif])
310 dnl Check for broken kernel header that doesn't define __user
311 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
313 dnl **** Check for X11 ****
315 if test "$have_x" = "yes"
316 then
317 XLIB="-lXext -lX11"
318 ac_save_CPPFLAGS="$CPPFLAGS"
319 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
321 dnl *** All of the following tests require X11/Xlib.h
322 AC_CHECK_HEADERS([X11/Xlib.h \
323 X11/XKBlib.h \
324 X11/Xutil.h \
325 X11/extensions/shape.h \
326 X11/extensions/XInput.h \
327 X11/extensions/XShm.h \
328 X11/extensions/Xrandr.h \
329 X11/extensions/Xrender.h \
330 X11/extensions/xf86vmode.h],,,
331 [#ifdef HAVE_X11_XLIB_H
332 # include <X11/Xlib.h>
333 #endif
334 #ifdef HAVE_X11_XUTIL_H
335 # include <X11/Xutil.h>
336 #endif])
338 dnl *** Check for X keyboard extension
339 if test "$ac_cv_header_X11_XKBlib_h" = "yes"
340 then
341 AC_CHECK_LIB(X11, XkbQueryExtension,
342 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
343 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
344 fi
346 dnl *** Check for X Shm extension
347 if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
348 then
349 AC_CHECK_LIB(Xext, XShmQueryExtension,
350 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
351 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
352 fi
354 dnl *** Check for X shape extension
355 if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
356 then
357 AC_CHECK_LIB(Xext,XShapeQueryExtension,
358 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
359 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
360 fi
362 dnl *** Check for XFree86 VMODE extension
363 if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
364 then
365 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
366 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
367 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
368 ],,
369 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
370 fi
372 dnl *** Check for X RandR extension
373 if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
374 then
375 AC_TRY_COMPILE([#include <X11/Xlib.h>
376 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
377 [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
378 fi
380 dnl *** Check for Transform functions in Xrender
381 if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
382 then
383 AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
384 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
385 [Define if Xrender has the XRenderSetPictureTransform function])],,
386 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
387 fi
388 dnl *** End of X11/Xlib.h check
390 dnl Check for the presence of OpenGL
391 if test "x$with_opengl" != "xno"
392 then
393 AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
394 [#ifdef HAVE_GL_GLX_H
395 # include <GL/glx.h>
396 #endif])
397 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
398 then
399 dnl Check for some problems due to old Mesa versions
400 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
401 AC_TRY_COMPILE(
402 [#include <GL/gl.h>],
403 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
404 [wine_cv_opengl_version_OK="yes"],
405 [wine_cv_opengl_version_OK="no"]
406 )
407 )
409 if test "$wine_cv_opengl_version_OK" = "yes"
410 then
411 dnl Check for the presence of the library
412 AC_CHECK_LIB(GL,glXCreateContext,
413 OPENGL_LIBS="-lGL"
414 ,,
415 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
417 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
418 then
419 OPENGLFILES='$(OPENGLFILES)'
420 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
421 else
422 if test -f /usr/X11R6/lib/libGL.a
423 then
424 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
425 This prevents linking to OpenGL. Delete the file and restart configure.])
426 fi
427 fi
429 dnl Check for GLU32 library.
430 AC_CHECK_LIB(GLU,gluLookAt,
431 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
432 GLU32FILES='$(GLU32FILES)']
433 ,,
434 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
435 )
436 fi
438 dnl Check for glut32 library.
439 AC_CHECK_LIB(glut,glutMainLoop,
440 [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
441 AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
442 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
443 fi
444 fi
446 dnl **** Check for NAS ****
447 AC_SUBST(NASLIBS,"")
448 AC_CHECK_HEADERS(audio/audiolib.h,
449 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
450 AC_CHECK_LIB(audio,AuCreateFlow,
451 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
452 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
453 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
455 CPPFLAGS="$ac_save_CPPFLAGS"
456 XFILES='$(XFILES)'
457 else
458 XLIB=""
459 X_CFLAGS=""
460 X_LIBS=""
461 fi
463 dnl **** Check for libxml2 ****
465 AC_SUBST(XML2LIBS,"")
466 AC_SUBST(XML2INCL,"")
467 AC_SUBST(XSLTLIBS,"")
468 AC_SUBST(XSLTINCL,"")
469 if test "$PKG_CONFIG" != "false"
470 then
471 ac_save_CPPFLAGS="$CPPFLAGS"
472 ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
473 ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
474 CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
475 AC_CHECK_HEADERS(libxml/parser.h,
476 [AC_CHECK_LIB(xml2, xmlParseMemory,
477 [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
478 XML2LIBS="$ac_xml_libs"
479 XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
480 AC_CHECK_LIB(xml2, xmlReadMemory,
481 [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
482 ])
483 CPPFLAGS="$ac_save_CPPFLAGS"
484 ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
485 ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
486 CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
487 AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
488 [AC_CHECK_LIB(xslt, xsltCompilePattern,
489 [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
490 XSLTLIBS="$ac_xslt_libs"
491 XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
492 ],,
493 [#ifdef HAVE_LIBXSLT_PATTERN_H
494 # include <libxslt/pattern.h>
495 #endif])
496 CPPFLAGS="$ac_save_CPPFLAGS"
497 fi
499 dnl **** Check for libhal ****
500 AC_SUBST(HALINCL,"")
501 if test "$PKG_CONFIG" != "false"
502 then
503 ac_save_CPPFLAGS="$CPPFLAGS"
504 ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
505 ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
506 CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
507 AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
508 if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
509 then
510 AC_CHECK_LIB(hal, libhal_ctx_new,
511 [AC_CHECK_LIB(dbus-1, dbus_connection_close,
512 [AC_DEFINE(HAVE_LIBHAL, 1, [Define if you have the hal library])
513 HALINCL="$ac_hal_cflags"],,$ac_hal_libs)])
514 fi
515 CPPFLAGS="$ac_save_CPPFLAGS"
516 fi
518 dnl **** Check which curses lib to use ***
519 CURSESLIBS=""
520 if test "x$with_curses" != "xno"
521 then
522 if test "$ac_cv_header_ncurses_h" = "yes"
523 then
524 AC_CHECK_LIB(ncurses,waddch,
525 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
526 CURSESLIBS="-lncurses"])
527 elif test "$ac_cv_header_curses_h" = "yes"
528 then
529 AC_CHECK_LIB(curses,waddch,
530 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
531 CURSESLIBS="-lcurses"])
532 fi
533 ac_save_LIBS="$LIBS"
534 LIBS="$LIBS $CURSESLIBS"
535 AC_CHECK_FUNCS(mousemask)
536 LIBS="$ac_save_LIBS"
537 fi
538 AC_SUBST(CURSESLIBS)
540 dnl **** Check for SANE ****
541 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
542 AC_SUBST(SANELIBS,"")
543 AC_SUBST(SANEINCL,"")
544 if test "$sane_devel" != "no"
545 then
546 SANELIBS="`$sane_devel --libs`"
547 SANEINCL="`$sane_devel --cflags`"
548 ac_save_CPPFLAGS="$CPPFLAGS"
549 ac_save_LIBS="$LIBS"
550 CPPFLAGS="$CPPFLAGS $SANEINCL"
551 LIBS="$LIBS $SANELIBS"
552 AC_CHECK_HEADER(sane/sane.h,
553 [AC_CHECK_LIB(sane,sane_open,
554 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
555 [SANELIBS=""
556 SANEINCL=""])],
557 [SANELIBS=""
558 SANEINCL=""])
559 LIBS="$ac_save_LIBS"
560 CPPFLAGS="$ac_save_CPPFLAGS"
561 fi
563 dnl **** Check for libgphoto2 ****
564 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
565 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
566 AC_SUBST(GPHOTO2LIBS,"")
567 AC_SUBST(GPHOTO2INCL,"")
568 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
569 then
570 GPHOTO2INCL="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
571 GPHOTO2LIBS=""
572 for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
573 do
574 case "$i" in
575 -L/usr/lib|-L/usr/lib64) ;;
576 -L*|-l*) GPHOTO2LIBS="$GPHOTO2LIBS $i";;
577 esac
578 done
579 ac_save_CPPFLAGS="$CPPFLAGS"
580 ac_save_LIBS="$LIBS"
581 CPPFLAGS="$CPPFLAGS $GPHOTO2INCL"
582 LIBS="$LIBS $GPHOTO2LIBS"
583 AC_CHECK_HEADER(gphoto2-camera.h,
584 [AC_CHECK_LIB(gphoto2,gp_camera_new,
585 [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])],
586 [GPHOTO2LIBS=""
587 GPHOTO2INCL=""])],
588 [GPHOTO2LIBS=""
589 GPHOTO2INCL=""])
590 LIBS="$ac_save_LIBS"
591 CPPFLAGS="$ac_save_CPPFLAGS"
592 fi
594 dnl **** Check for the ICU library ****
595 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
596 then
597 saved_libs="$LIBS"
598 for i in ${ICU_LIB_DIR-/usr/lib}/libsicu ${ICU_LIB_DIR-/usr/lib}/libicu
599 do
600 TEST_ICUUC_LIB="${ICUUC_LIB-${i}uc.a}"
601 TEST_ICUDATA_LIB="${ICUDATA_LIB-${i}data.a}"
602 AC_MSG_CHECKING(whether can link with ICU libraries $TEST_ICUUC_LIB and $TEST_ICUDATA_LIB)
603 LIBS="$saved_libs $TEST_ICUUC_LIB $TEST_ICUDATA_LIB -lstdc++ -lgcc_s"
604 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
605 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
606 AC_SUBST(ICULIBS,"$TEST_ICUUC_LIB $TEST_ICUDATA_LIB -lstdc++ -lgcc_s")
607 AC_MSG_RESULT(yes)],
608 [AC_MSG_RESULT(no)])
609 done
610 LIBS="$saved_libs"
611 fi
613 dnl **** Check for resolver library ***
614 AC_SUBST(RESOLVLIBS,"")
615 if test "$ac_cv_header_resolv_h" = "yes"
616 then
617 AC_CHECK_LIB(resolv, res_query,
618 [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
619 RESOLVLIBS="-lresolv"])
620 fi
622 dnl **** Check for LittleCMS ***
623 AC_SUBST(LCMSLIBS,"")
624 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
625 then
626 AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
627 [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
628 LCMSLIBS="-llcms"])
629 fi
631 dnl **** Check for OpenLDAP ***
632 AC_SUBST(LDAPLIBS,"")
633 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
634 then
635 AC_CHECK_LIB(ldap_r, ldap_initialize,
636 [AC_CHECK_LIB(lber, ber_init,
637 [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
638 LDAPLIBS="-lldap_r -llber"],,
639 [$LIBPTHREAD])],,
640 [$LIBPTHREAD])
641 WINE_CHECK_LIB_FUNCS(\
642 ldap_count_references \
643 ldap_first_reference \
644 ldap_next_reference \
645 ldap_parse_reference,
646 [$LDAPLIBS $LIBPTHREAD])
647 fi
649 dnl **** Check for FreeType 2 ****
650 AC_SUBST(FREETYPELIBS,"")
651 AC_SUBST(FREETYPEINCL,"")
652 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
653 if test "$ft_devel" = "no"
654 then
655 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
656 if test "$ft_devel2" = "freetype2-config"
657 then
658 ft_devel=$ft_devel2
659 fi
660 fi
662 if test "$ft_devel" = "no"
663 then
664 wine_cv_msg_freetype=yes
665 else
666 FREETYPELIBS=`$ft_devel --libs`
667 FREETYPEINCL=`$ft_devel --cflags`
668 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$FREETYPELIBS)
669 if test "$ft_lib" = "no"
670 then
671 wine_cv_msg_freetype=yes
672 FREETYPELIBS=""
673 FREETYPEINCL=""
674 else
675 ac_save_CPPFLAGS="$CPPFLAGS"
676 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
677 AC_CHECK_HEADERS(ft2build.h \
678 freetype/freetype.h \
679 freetype/ftglyph.h \
680 freetype/tttables.h \
681 freetype/ftnames.h \
682 freetype/ftsnames.h \
683 freetype/ttnameid.h \
684 freetype/ftoutln.h \
685 freetype/ftwinfnt.h \
686 freetype/ftmodapi.h \
687 freetype/internal/sfnt.h,,,
688 [#if HAVE_FT2BUILD_H
689 #include <ft2build.h>
690 #endif])
691 AC_TRY_CPP([#include <ft2build.h>
692 #include <freetype/fttrigon.h>],
693 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
694 [Define if you have the <freetype/fttrigon.h> header file.])
695 wine_cv_fttrigon=yes],
696 wine_cv_fttrigon=no)
697 AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
698 ac_save_CFLAGS="$CFLAGS"
699 CFLAGS="$CFLAGS $FREETYPELIBS"
700 AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
701 CFLAGS="$ac_save_CFLAGS"
702 CPPFLAGS="$ac_save_CPPFLAGS"
703 dnl Check that we have at least freetype/freetype.h
704 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
705 then
706 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
707 wine_cv_msg_freetype=no
708 else
709 FREETYPELIBS=""
710 FREETYPEINCL=""
711 wine_cv_msg_freetype=yes
712 fi
713 fi
714 fi
716 dnl Only build the fonts dir if we have both freetype and fontforge
717 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
718 then
719 AC_SUBST(FONTSSUBDIRS,"fonts")
720 fi
722 dnl **** Check for parport (currently Linux only) ****
723 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
724 AC_TRY_COMPILE(
725 [#include <linux/ppdev.h>],
726 [ioctl (1,PPCLAIM,0)],
727 [ac_cv_c_ppdev="yes"],
728 [ac_cv_c_ppdev="no"])
729 )
730 if test "$ac_cv_c_ppdev" = "yes"
731 then
732 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
733 fi
735 dnl **** Check for va_copy ****
736 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
737 AC_TRY_LINK(
738 [#include <stdarg.h>],
739 [va_list ap1, ap2;
740 va_copy(ap1,ap2);
741 ],
742 [ac_cv_c_va_copy="yes"],
743 [ac_cv_c_va_copy="no"])
744 )
745 if test "$ac_cv_c_va_copy" = "yes"
746 then
747 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
748 fi
749 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
750 AC_TRY_LINK(
751 [#include <stdarg.h>],
752 [va_list ap1, ap2;
753 __va_copy(ap1,ap2);
754 ],
755 [ac_cv_c___va_copy="yes"],
756 [ac_cv_c___va_copy="no"])
757 )
758 if test "$ac_cv_c___va_copy" = "yes"
759 then
760 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
761 fi
763 dnl **** Check for sigsetjmp ****
764 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
765 AC_TRY_LINK(
766 [#include <setjmp.h>],
767 [sigjmp_buf buf;
768 sigsetjmp( buf, 1 );
769 siglongjmp( buf, 1 );],
770 [ac_cv_c_sigsetjmp="yes"],
771 [ac_cv_c_sigsetjmp="no"])
772 )
773 if test "$ac_cv_c_sigsetjmp" = "yes"
774 then
775 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
776 fi
778 dnl **** Check for pthread_rwlock_t ****
779 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
780 #include <pthread.h>])
782 dnl **** Check for pthread functions ****
783 WINE_CHECK_LIB_FUNCS(\
784 pthread_attr_get_np \
785 pthread_getattr_np \
786 pthread_get_stackaddr_np \
787 pthread_get_stacksize_np,
788 [$LIBPTHREAD])
790 dnl **** Check for aRts Sound Server ****
791 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
792 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
793 then
794 ARTSC_CFLAGS=""
795 for i in `$ARTSCCONFIG --cflags`
796 do
797 case "$i" in
798 -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
799 esac
800 done
801 ARTSC_LIBS=""
802 for i in `$ARTSCCONFIG --libs`
803 do
804 case "$i" in
805 -L/usr/lib|-L/usr/lib64) ;;
806 -L*|-l*) ARTSC_LIBS="$ARTSC_LIBS $i";;
807 esac
808 done
809 save_CFLAGS="$CFLAGS"
810 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
811 AC_CHECK_LIB(artsc,arts_init,
812 [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
813 [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
814 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
815 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],,
816 $ARTSC_LIBS)
817 CFLAGS="$save_CFLAGS"
818 fi
820 dnl **** Check for EsounD ****
821 AC_PATH_PROG(ESDCONFIG, esd-config)
822 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
823 then
824 ESD_CFLAGS=""
825 for i in `$ESDCONFIG --cflags`
826 do
827 case "$i" in
828 -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
829 esac
830 done
831 ESD_LIBS=`$ESDCONFIG --libs`
832 save_CFLAGS="$CFLAGS"
833 CFLAGS="$CFLAGS $ESD_CFLAGS"
834 AC_CHECK_LIB(esd,esd_open_sound,
835 [AC_SUBST(ESDLIBS, $ESD_LIBS)
836 AC_SUBST(ESDINCL, $ESD_CFLAGS)
837 AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
838 CFLAGS="$save_CFLAGS"
839 fi
841 dnl **** Check for ALSA 1.x ****
842 AC_SUBST(ALSALIBS,"")
843 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
844 then
845 AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
846 [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
847 #include <alsa/asoundlib.h>
848 #elif defined(HAVE_SYS_ASOUNDLIB_H)
849 #include <sys/asoundlib.h>
850 #endif],
851 [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
852 [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
853 ALSALIBS="-lasound"])])
854 fi
856 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
858 AC_SUBST(AUDIOIOLIBS,"")
859 if test "$ac_cv_header_libaudioio_h" = "yes"
860 then
861 AC_CHECK_LIB(audioio,AudioIOGetVersion,
862 [AUDIOIOLIBS="-laudioio"
863 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
864 fi
866 dnl **** Check for capi4linux ****
868 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
869 then
870 AC_CHECK_LIB(capi20,capi20_register,[AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])])
871 fi
873 dnl **** Check for gif header usability ****
875 if test "$ac_cv_header_gif_lib_h" = "yes"
876 then
877 AC_TRY_COMPILE([#include <gif_lib.h>],[static typeof(DGifOpen) * func;],
878 AC_DEFINE(HAVE_GIF, 1, [Define if you have usable GIF headers]))
879 fi
881 dnl **** Check for gcc specific options ****
883 AC_SUBST(EXTRACFLAGS,"")
884 if test "x${GCC}" = "xyes"
885 then
886 EXTRACFLAGS="-Wall -pipe"
888 dnl Check for strength-reduce bug
889 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
890 AC_TRY_RUN([
891 int L[[4]] = {0,1,2,3};
892 int main(void) {
893 static int Array[[3]];
894 unsigned int B = 3;
895 int i;
896 for(i=0; i<B; i++) Array[[i]] = i - 3;
897 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
898 L[[i]] = 4;
900 exit( Array[[1]] != -2 || L[[2]] != 3);
901 }],
902 ac_cv_c_gcc_strength_bug="no",
903 ac_cv_c_gcc_strength_bug="yes",
904 ac_cv_c_gcc_strength_bug="yes") )
905 if test "$ac_cv_c_gcc_strength_bug" = "yes"
906 then
907 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
908 fi
910 dnl Check for -fshort-wchar
911 AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
912 [WINE_TRY_CFLAGS([-fshort-wchar],
913 ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
914 if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
915 then
916 AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
917 fi
919 dnl Check for -fno-strict-aliasing
920 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
921 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
922 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
923 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
924 then
925 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
926 fi
928 dnl Check for -gstabs+ option
929 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
930 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
931 if test "$ac_cv_c_gcc_gstabs" = "yes"
932 then
933 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
934 fi
936 dnl Check for -Wdeclaration-after-statement option
937 AC_CACHE_CHECK([for gcc -Wdeclaration-after-statement support], ac_cv_c_gcc_decl_after_statement,
938 [WINE_TRY_CFLAGS([-Wdeclaration-after-statement],ac_cv_c_gcc_decl_after_statement="yes", ac_cv_c_gcc_decl_after_statement="no")])
939 if test "$ac_cv_c_gcc_decl_after_statement" = "yes"
940 then
941 EXTRACFLAGS="$EXTRACFLAGS -Wdeclaration-after-statement"
942 fi
944 dnl Check for noisy string.h
945 saved_CFLAGS="$CFLAGS"
946 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
947 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
948 AC_TRY_COMPILE([#include <string.h>],[],
949 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
950 CFLAGS="$saved_CFLAGS"
951 if test "$ac_cv_c_string_h_warnings" = "no"
952 then
953 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
954 fi
956 AC_SUBST(BUILTINFLAG,"")
957 saved_CFLAGS="$CFLAGS"
958 CFLAGS="$CFLAGS -Werror"
959 AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
960 AC_TRY_COMPILE([],
961 [int iswlower(unsigned short);],
962 [ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
963 CFLAGS="$saved_CFLAGS"
964 if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
965 then
966 BUILTINFLAG="-fno-builtin"
967 fi
968 fi
970 dnl **** Check how to define a function in assembly code ****
972 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
973 WINE_TRY_ASM_LINK(
974 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
975 ac_cv_asm_func_def=".def",
976 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
977 ac_cv_asm_func_def=".type @function",
978 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
979 ac_cv_asm_func_def=".type 2",
980 ac_cv_asm_func_def="unknown")])]))
982 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
983 case "$ac_cv_asm_func_def" in
984 ".def")
985 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
986 ".type @function")
987 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
988 ".type 2")
989 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
990 *)
991 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
992 esac
994 dnl **** Check for underscore on external symbols ****
996 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
997 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
998 [extern int ac_test;],
999 [if (ac_test) return 1],
1000 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1002 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1003 if test "$ac_cv_c_extern_prefix" = "yes"
1004 then
1005 AC_DEFINE([__ASM_NAME(name)], ["_" name])
1006 else
1007 AC_DEFINE([__ASM_NAME(name)], [name])
1008 fi
1010 dnl **** Check for working dll ****
1012 AC_SUBST(DLLEXT,"")
1013 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
1014 AC_SUBST(LDSHARED,"")
1015 AC_SUBST(LDDLLFLAGS,"")
1016 AC_SUBST(LIBEXT,"so")
1017 AC_SUBST(IMPLIBEXT,"def")
1019 case $host_os in
1020 cygwin*|mingw32*)
1021 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
1022 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
1023 if test "$DLLWRAP" = "false"; then
1024 LIBEXT="a"
1025 else
1026 dnl FIXME - check whether dllwrap works correctly...
1027 LIBEXT="dll"
1028 fi
1029 IMPLIBEXT="a"
1030 dnl We can't build 16-bit NE dlls
1031 WIN16_FILES=""
1032 WIN16_INSTALL=""
1033 ;;
1034 darwin*|macosx*)
1035 DLLEXT=".so"
1036 LIBEXT="dylib"
1037 DLLFLAGS="$DLLFLAGS -fPIC"
1038 LDDLLFLAGS="-bundle -multiply_defined suppress"
1039 LDSHARED="\$(CC) -dynamiclib -install_name @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/\$(DYNAME)"
1040 STRIP="$STRIP -u -r"
1041 dnl declare needed frameworks
1042 AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1043 AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
1044 AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
1045 if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
1046 then
1047 dnl CoreServices needed by AudioUnit
1048 AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices")
1049 fi
1050 case $host_cpu in
1051 *powerpc*)
1052 LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning" dnl FIXME
1053 ;;
1054 esac
1055 dnl Disable optimizations because of force_align_arg_pointer bug
1056 dnl FIXME: should be removed when gcc is fixed
1057 CFLAGS=`echo "$CFLAGS" | sed -e s/-O2/-O1/`
1058 ;;
1059 *)
1060 DLLFLAGS="$DLLFLAGS -fPIC"
1061 DLLEXT=".so"
1062 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
1063 [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
1064 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
1065 if test "$ac_cv_c_dll_gnuelf" = "yes"
1066 then
1067 LDSHARED="\$(CC) -shared"
1068 LDDLLFLAGS="-shared -Wl,-Bsymbolic"
1069 AC_CACHE_CHECK([whether the linker accepts soname], ac_cv_c_sonames,
1070 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
1071 ac_cv_c_sonames="yes",ac_cv_c_sonames="no")])
1072 if test "$ac_cv_c_sonames" = "yes"
1073 then
1074 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
1075 else
1076 AC_CACHE_CHECK([check to see if -h soname is an alternate], ac_cv_c_h_sonames,
1077 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
1078 ac_cv_c_h_sonames="yes",ac_cv_c_h_sonames="no")])
1079 if test "$ac_cv_c_h_sonames" = "yes"
1080 then
1081 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"
1082 fi
1083 fi
1085 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
1086 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
1087 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
1088 if test "$ac_cv_c_dll_zdefs" = "yes"
1089 then
1090 LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
1091 fi
1093 AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
1094 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
1095 ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
1096 if test "$ac_cv_c_dll_init_fini" = "yes"
1097 then
1098 LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
1099 fi
1101 AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
1102 [echo '{ global: *; };' >conftest.map
1103 WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
1104 ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
1105 rm -f conftest.map])
1106 if test "$ac_cv_c_ld_version_scripts" = "yes"
1107 then
1108 LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
1109 fi
1111 AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
1112 [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
1113 ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
1114 if test "$ac_cv_c_export_dynamic" = "yes"
1115 then
1116 AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
1117 fi
1119 AC_CACHE_CHECK([whether the linker accepts --rpath], ac_cv_ld_rpath,
1120 [WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
1121 ac_cv_ld_rpath="yes",ac_cv_ld_rpath="no")])
1122 if test "$ac_cv_ld_rpath" = "yes"
1123 then
1124 AC_SUBST(LDEXERPATH,["-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"])
1125 AC_SUBST(LDDLLRPATH,["-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(dlldir) \$(libdir)\`"])
1126 fi
1128 case $host_cpu in
1129 *i[[3456789]]86* | x86_64)
1130 AC_CACHE_CHECK([whether we can relocate the executable to 0x7bf00000], ac_cv_ld_reloc_exec,
1131 [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
1132 ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
1133 if test "$ac_cv_ld_reloc_exec" = "yes"
1134 then
1135 LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"
1136 fi
1137 ;;
1138 esac
1140 else
1141 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
1142 [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
1143 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
1144 if test "$ac_cv_c_dll_unixware" = "yes"
1145 then
1146 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
1147 LDDLLFLAGS="-Wl,-G,-B,symbolic"
1149 else
1150 AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1151 [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1152 if test "$ac_cv_c_dll_hpux" = "yes"
1153 then
1154 LIBEXT="sl"
1155 DLLEXT=".sl"
1156 LDDLLFLAGS="-shared -fPIC"
1157 LDSHARED="\$(CC) -shared"
1158 fi
1159 fi
1160 fi
1162 dnl Check for cross compiler to build test programs
1163 AC_SUBST(CROSSTEST,"")
1164 if test "$cross_compiling" = "no"
1165 then
1166 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1167 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1168 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1169 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1170 fi
1171 ;;
1172 esac
1174 if test "$LIBEXT" = "a"; then
1175 AC_MSG_ERROR(
1176 [could not find a way to build shared libraries.
1177 It is currently not possible to build Wine without shared library
1178 (.so) support to allow transparent switch between .so and .dll files.
1179 If you are using Linux, you will need a newer binutils.]
1180 )
1181 fi
1183 case $build_os in
1184 cygwin*|mingw32*)
1185 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\"") ;;
1186 darwin*|macosx*)
1187 AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$DYLD_LIBRARY_PATH\"") ;;
1188 *)
1189 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\"") ;;
1190 esac
1192 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1193 case $host_os in
1194 mingw32*)
1195 AC_SUBST(CRTLIBS,"-lmsvcrt")
1196 AC_SUBST(SOCKETLIBS,"-lws2_32")
1197 ;;
1198 esac
1200 AC_SUBST(MAIN_BINARY,"wine-pthread") dnl Default value
1201 case $host_cpu in
1202 *i[[3456789]]86*)
1203 case $host_os in
1204 linux* | k*bsd*-gnu)
1205 AC_SUBST(MAIN_BINARY,"wine-glibc")
1206 AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1207 esac
1208 ;;
1209 esac
1211 dnl **** Get the soname for libraries that we load dynamically ****
1213 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1214 then
1215 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1216 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1217 WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1218 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1219 WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1220 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1221 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1222 WINE_GET_SONAME(dbus-1,dbus_error_init)
1223 WINE_GET_SONAME(hal,libhal_ctx_new)
1224 WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1225 WINE_GET_SONAME(cups,cupsGetDefault)
1226 WINE_GET_SONAME(jack,jack_client_new)
1227 WINE_GET_SONAME(fontconfig,FcInit)
1228 WINE_GET_SONAME(ssl,SSL_library_init)
1229 WINE_GET_SONAME(crypto,BIO_new_socket)
1230 WINE_GET_SONAME(ncurses,waddch)
1231 WINE_GET_SONAME(curses,waddch)
1232 WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1233 WINE_GET_SONAME(ungif,DGifOpen)
1234 WINE_GET_SONAME(gif,DGifOpen)
1235 WINE_GET_SONAME(capi20,capi20_isinstalled)
1236 fi
1239 dnl **** Check for functions ****
1241 AC_CHECK_FUNCS(\
1242 _pclose \
1243 _popen \
1244 _snprintf \
1245 _spawnvp \
1246 _stricmp \
1247 _strnicmp \
1248 _vsnprintf \
1249 asctime_r \
1250 chsize \
1251 clone \
1252 connect \
1253 dlopen \
1254 epoll_create \
1255 ffs \
1256 finite \
1257 fork \
1258 fpclass \
1259 fstatfs \
1260 fstatvfs \
1261 ftruncate \
1262 futimes \
1263 futimesat \
1264 getaddrinfo \
1265 gethostbyname \
1266 getnameinfo \
1267 getnetbyname \
1268 getopt_long \
1269 getpagesize \
1270 getprotobyname \
1271 getprotobynumber \
1272 getpwuid \
1273 getservbyport \
1274 gettid \
1275 gettimeofday \
1276 getuid \
1277 inet_aton \
1278 inet_network \
1279 kqueue \
1280 lstat \
1281 memmove \
1282 mmap \
1283 pclose \
1284 poll \
1285 popen \
1286 prctl \
1287 pread \
1288 pwrite \
1289 readlink \
1290 rfork \
1291 sched_yield \
1292 select \
1293 sendmsg \
1294 setrlimit \
1295 settimeofday \
1296 sigaltstack \
1297 sigprocmask \
1298 snprintf \
1299 spawnvp \
1300 statfs \
1301 statvfs \
1302 strcasecmp \
1303 strerror \
1304 strncasecmp \
1305 tcgetattr \
1306 timegm \
1307 usleep \
1308 vsnprintf \
1309 wait4 \
1310 waitpid \
1311 )
1313 dnl Check for -ldl
1314 if test "$ac_cv_func_dlopen" = no
1315 then
1316 AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1317 fi
1318 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1320 dnl Check for -lpoll for Mac OS X/Darwin
1321 if test "$ac_cv_func_poll" = no
1322 then
1323 AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1324 fi
1326 dnl Check for -lnsl for Solaris
1327 if test "$ac_cv_func_gethostbyname" = no
1328 then
1329 AC_CHECK_LIB(nsl,gethostbyname)
1330 fi
1332 dnl Check for -lsocket for Solaris
1333 if test "$ac_cv_func_connect" = no
1334 then
1335 AC_CHECK_LIB(socket,connect)
1336 fi
1338 dnl Check for -lresolv for Solaris
1339 if test "$ac_cv_func_inet_aton" = no
1340 then
1341 AC_CHECK_LIB(resolv,inet_aton)
1342 fi
1344 dnl **** Check for types ****
1346 AC_C_CONST
1347 AC_C_INLINE
1348 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1349 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1350 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1352 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1353 [#ifdef HAVE_LINUX_INPUT_H
1354 #include <linux/input.h>
1355 #endif])
1357 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1358 AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1359 wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1360 if test "$wine_cv_have_sigaddset" = "yes"
1361 then
1362 AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1363 fi
1366 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1367 wine_cv_linux_gethostbyname_r_6,
1368 AC_TRY_LINK([
1369 #include <netdb.h>
1370 ], [
1371 char *name=NULL;
1372 struct hostent he;
1373 struct hostent *result;
1374 char *buf=NULL;
1375 int bufsize=0;
1376 int res,errnr;
1377 char *addr=NULL;
1378 int addrlen=0;
1379 int addrtype=0;
1380 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1381 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1382 ],
1383 wine_cv_linux_gethostbyname_r_6=yes,
1384 wine_cv_linux_gethostbyname_r_6=no
1385 )
1386 )
1387 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1388 then
1389 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1390 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1391 fi
1393 if test "$ac_cv_header_linux_joystick_h" = "yes"
1394 then
1395 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1396 wine_cv_linux_joystick_22_api,
1397 AC_TRY_COMPILE([
1398 #include <sys/ioctl.h>
1399 #include <linux/joystick.h>
1401 struct js_event blub;
1402 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1403 #error "no 2.2 header"
1404 #endif
1405 ],/*empty*/,
1406 wine_cv_linux_joystick_22_api=yes,
1407 wine_cv_linux_joystick_22_api=no,
1408 wine_cv_linux_joystick_22_api=no
1409 )
1410 )
1411 if test "$wine_cv_linux_joystick_22_api" = "yes"
1412 then
1413 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1414 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1415 fi
1416 fi
1418 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1420 dnl Check for statfs members
1421 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1422 [#include <sys/types.h>
1423 #ifdef HAVE_SYS_PARAM_H
1424 # include <sys/param.h>
1425 #endif
1426 #ifdef HAVE_SYS_MOUNT_H
1427 # include <sys/mount.h>
1428 #endif
1429 #ifdef HAVE_SYS_VFS_H
1430 # include <sys/vfs.h>
1431 #endif
1432 #ifdef HAVE_SYS_STATFS_H
1433 # include <sys/statfs.h>
1434 #endif])
1436 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1437 [#ifdef HAVE_SYS_STATVFS_H
1438 #include <sys/statvfs.h>
1439 #endif])
1441 dnl Check for socket structure members
1442 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1443 [#include <sys/types.h>
1444 #ifdef HAVE_SYS_SOCKET_H
1445 # include <sys/socket.h>
1446 #endif
1447 #ifdef HAVE_SYS_UN_H
1448 # include <sys/un.h>
1449 #endif])
1451 dnl Check for scsireq_t and sg_io_hdr_t members
1452 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1453 [#include <sys/types.h>
1454 #ifdef HAVE_SCSI_SG_H
1455 #include <scsi/sg.h>
1456 #endif])
1458 dnl Check for siginfo_t members
1459 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1461 dnl Check for struct mtget members
1462 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1463 [#include <sys/types.h>
1464 #ifdef HAVE_SYS_MTIO_H
1465 #include <sys/mtio.h>
1466 #endif])
1468 dnl Check for struct option
1469 AC_CHECK_MEMBERS([struct option.name],,,
1470 [#ifdef HAVE_GETOPT_H
1471 #include <getopt.h>
1472 #endif])
1474 dnl Check for stat.st_blocks
1475 AC_CHECK_MEMBERS([struct stat.st_blocks])
1477 dnl Check for sin6_scope_id
1478 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1479 [#ifdef HAVE_SYS_TYPES_H
1480 #include <sys/types.h>
1481 #endif
1482 #ifdef HAVE_NETINET_IN_H
1483 #include <netinet/in.h>
1484 #endif])
1486 dnl Check for ns_msg ptr member
1487 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1488 [#ifdef HAVE_SYS_TYPES_H
1489 #include <sys/types.h>
1490 #endif
1491 #ifdef HAVE_NETINET_IN_H
1492 # include <netinet/in.h>
1493 #endif
1494 #ifdef HAVE_ARPA_NAMESER_H
1495 # include <arpa/nameser.h>
1496 #endif])
1498 dnl Check for the external timezone variables timezone and daylight
1499 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1500 AC_TRY_LINK([#include <time.h>],[timezone;],
1501 ac_cv_have_timezone="yes", ac_cv_have_timezone="no"))
1502 if test "$ac_cv_have_timezone" = "yes"
1503 then
1504 AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1505 fi
1506 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1507 AC_TRY_LINK([#include <time.h>],[daylight;],
1508 ac_cv_have_daylight="yes", ac_cv_have_daylight="no"))
1509 if test "$ac_cv_have_daylight" = "yes"
1510 then
1511 AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1512 fi
1514 dnl *** check for the need to define platform-specific symbols
1516 case $host_cpu in
1517 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1518 *x86_64*) WINE_CHECK_DEFINE([__x86_64__])
1519 WINE_CHECK_DEFINE([_WIN64]) ;;
1520 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1521 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1522 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1523 esac
1525 case $host_vendor in
1526 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1527 esac
1529 dnl **** Generate output files ****
1531 AH_TOP([#define __WINE_CONFIG_H])
1533 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1534 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1535 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1536 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1537 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1538 WINE_CONFIG_EXTRA_DIR(include/wine)
1540 MAKE_RULES=Make.rules
1541 AC_SUBST_FILE(MAKE_RULES)
1543 MAKE_DLL_RULES=dlls/Makedll.rules
1544 AC_SUBST_FILE(MAKE_DLL_RULES)
1546 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1547 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1549 MAKE_TEST_RULES=dlls/Maketest.rules
1550 AC_SUBST_FILE(MAKE_TEST_RULES)
1552 MAKE_PROG_RULES=programs/Makeprog.rules
1553 AC_SUBST_FILE(MAKE_PROG_RULES)
1555 AC_CONFIG_FILES([
1556 Make.rules
1557 dlls/Makedll.rules
1558 dlls/Makeimplib.rules
1559 dlls/Maketest.rules
1560 programs/Makeprog.rules
1561 Makefile
1562 dlls/Makefile
1563 dlls/activeds/Makefile
1564 dlls/advapi32/Makefile
1565 dlls/advapi32/tests/Makefile
1566 dlls/advpack/Makefile
1567 dlls/advpack/tests/Makefile
1568 dlls/amstream/Makefile
1569 dlls/atl/Makefile
1570 dlls/avicap32/Makefile
1571 dlls/avifil32/Makefile
1572 dlls/cabinet/Makefile
1573 dlls/cabinet/tests/Makefile
1574 dlls/capi2032/Makefile
1575 dlls/cards/Makefile
1576 dlls/cfgmgr32/Makefile
1577 dlls/comcat/Makefile
1578 dlls/comcat/tests/Makefile
1579 dlls/comctl32/Makefile
1580 dlls/comctl32/tests/Makefile
1581 dlls/comdlg32/Makefile
1582 dlls/comdlg32/tests/Makefile
1583 dlls/compstui/Makefile
1584 dlls/crtdll/Makefile
1585 dlls/crypt32/Makefile
1586 dlls/crypt32/tests/Makefile
1587 dlls/cryptdll/Makefile
1588 dlls/cryptnet/Makefile
1589 dlls/ctl3d32/Makefile
1590 dlls/d3d8/Makefile
1591 dlls/d3d8/tests/Makefile
1592 dlls/d3d9/Makefile
1593 dlls/d3d9/tests/Makefile
1594 dlls/d3dim/Makefile
1595 dlls/d3drm/Makefile
1596 dlls/d3dx8/Makefile
1597 dlls/d3dxof/Makefile
1598 dlls/dbghelp/Makefile
1599 dlls/dciman32/Makefile
1600 dlls/ddraw/Makefile
1601 dlls/ddraw/tests/Makefile
1602 dlls/devenum/Makefile
1603 dlls/dinput/Makefile
1604 dlls/dinput/tests/Makefile
1605 dlls/dinput8/Makefile
1606 dlls/dmband/Makefile
1607 dlls/dmcompos/Makefile
1608 dlls/dmime/Makefile
1609 dlls/dmloader/Makefile
1610 dlls/dmscript/Makefile
1611 dlls/dmstyle/Makefile
1612 dlls/dmsynth/Makefile
1613 dlls/dmusic/Makefile
1614 dlls/dmusic32/Makefile
1615 dlls/dnsapi/Makefile
1616 dlls/dnsapi/tests/Makefile
1617 dlls/dplay/Makefile
1618 dlls/dplayx/Makefile
1619 dlls/dpnet/Makefile
1620 dlls/dpnhpast/Makefile
1621 dlls/dsound/Makefile
1622 dlls/dsound/tests/Makefile
1623 dlls/dswave/Makefile
1624 dlls/dxdiagn/Makefile
1625 dlls/dxerr8/Makefile
1626 dlls/dxerr9/Makefile
1627 dlls/dxguid/Makefile
1628 dlls/gdi/Makefile
1629 dlls/gdi/tests/Makefile
1630 dlls/glu32/Makefile
1631 dlls/glut32/Makefile
1632 dlls/gphoto2.ds/Makefile
1633 dlls/hhctrl.ocx/Makefile
1634 dlls/hid/Makefile
1635 dlls/hlink/Makefile
1636 dlls/hlink/tests/Makefile
1637 dlls/iccvid/Makefile
1638 dlls/icmp/Makefile
1639 dlls/ifsmgr.vxd/Makefile
1640 dlls/imaadp32.acm/Makefile
1641 dlls/imagehlp/Makefile
1642 dlls/imm32/Makefile
1643 dlls/infosoft/Makefile
1644 dlls/inseng/Makefile
1645 dlls/iphlpapi/Makefile
1646 dlls/iphlpapi/tests/Makefile
1647 dlls/itss/Makefile
1648 dlls/kernel/Makefile
1649 dlls/kernel/tests/Makefile
1650 dlls/lz32/Makefile
1651 dlls/lz32/tests/Makefile
1652 dlls/mapi32/Makefile
1653 dlls/mapi32/tests/Makefile
1654 dlls/mciavi32/Makefile
1655 dlls/mcicda/Makefile
1656 dlls/mciseq/Makefile
1657 dlls/mciwave/Makefile
1658 dlls/midimap/Makefile
1659 dlls/mlang/Makefile
1660 dlls/mlang/tests/Makefile
1661 dlls/mmdevldr.vxd/Makefile
1662 dlls/monodebg.vxd/Makefile
1663 dlls/mpr/Makefile
1664 dlls/mprapi/Makefile
1665 dlls/msacm32.drv/Makefile
1666 dlls/msacm32/Makefile
1667 dlls/msacm32/tests/Makefile
1668 dlls/msadp32.acm/Makefile
1669 dlls/mscms/Makefile
1670 dlls/mscms/tests/Makefile
1671 dlls/msdmo/Makefile
1672 dlls/msftedit/Makefile
1673 dlls/msg711.acm/Makefile
1674 dlls/mshtml/Makefile
1675 dlls/mshtml/tests/Makefile
1676 dlls/msi/Makefile
1677 dlls/msi/tests/Makefile
1678 dlls/msimg32/Makefile
1679 dlls/msisys.ocx/Makefile
1680 dlls/msnet32/Makefile
1681 dlls/msrle32/Makefile
1682 dlls/msvcrt/Makefile
1683 dlls/msvcrt/tests/Makefile
1684 dlls/msvcrt20/Makefile
1685 dlls/msvcrt40/Makefile
1686 dlls/msvcrtd/Makefile
1687 dlls/msvcrtd/tests/Makefile
1688 dlls/msvfw32/Makefile
1689 dlls/msvidc32/Makefile
1690 dlls/mswsock/Makefile
1691 dlls/msxml3/Makefile
1692 dlls/msxml3/tests/Makefile
1693 dlls/netapi32/Makefile
1694 dlls/netapi32/tests/Makefile
1695 dlls/newdev/Makefile
1696 dlls/ntdll/Makefile
1697 dlls/ntdll/tests/Makefile
1698 dlls/ntdsapi/Makefile
1699 dlls/objsel/Makefile
1700 dlls/odbc32/Makefile
1701 dlls/odbccp32/Makefile
1702 dlls/ole32/Makefile
1703 dlls/ole32/tests/Makefile
1704 dlls/oleacc/Makefile
1705 dlls/oleaut32/Makefile
1706 dlls/oleaut32/tests/Makefile
1707 dlls/olecli32/Makefile
1708 dlls/oledlg/Makefile
1709 dlls/olepro32/Makefile
1710 dlls/olesvr32/Makefile
1711 dlls/opengl32/Makefile
1712 dlls/powrprof/Makefile
1713 dlls/psapi/Makefile
1714 dlls/psapi/tests/Makefile
1715 dlls/pstorec/Makefile
1716 dlls/qcap/Makefile
1717 dlls/quartz/Makefile
1718 dlls/quartz/tests/Makefile
1719 dlls/query/Makefile
1720 dlls/rasapi32/Makefile
1721 dlls/riched20/Makefile
1722 dlls/riched20/tests/Makefile
1723 dlls/riched32/Makefile
1724 dlls/rpcrt4/Makefile
1725 dlls/rpcrt4/tests/Makefile
1726 dlls/rsabase/Makefile
1727 dlls/rsabase/tests/Makefile
1728 dlls/rsaenh/Makefile
1729 dlls/rsaenh/tests/Makefile
1730 dlls/sane.ds/Makefile
1731 dlls/secur32/Makefile
1732 dlls/secur32/tests/Makefile
1733 dlls/security/Makefile
1734 dlls/sensapi/Makefile
1735 dlls/serialui/Makefile
1736 dlls/setupapi/Makefile
1737 dlls/setupapi/tests/Makefile
1738 dlls/sfc/Makefile
1739 dlls/shdocvw/Makefile
1740 dlls/shdocvw/tests/Makefile
1741 dlls/shell32/Makefile
1742 dlls/shell32/tests/Makefile
1743 dlls/shfolder/Makefile
1744 dlls/shlwapi/Makefile
1745 dlls/shlwapi/tests/Makefile
1746 dlls/snmpapi/Makefile
1747 dlls/spoolss/Makefile
1748 dlls/stdole2.tlb/Makefile
1749 dlls/stdole32.tlb/Makefile
1750 dlls/sti/Makefile
1751 dlls/strmiids/Makefile
1752 dlls/tapi32/Makefile
1753 dlls/twain_32/Makefile
1754 dlls/unicows/Makefile
1755 dlls/url/Makefile
1756 dlls/urlmon/Makefile
1757 dlls/urlmon/tests/Makefile
1758 dlls/user/Makefile
1759 dlls/user/tests/Makefile
1760 dlls/userenv/Makefile
1761 dlls/usp10/Makefile
1762 dlls/usp10/tests/Makefile
1763 dlls/uuid/Makefile
1764 dlls/uxtheme/Makefile
1765 dlls/uxtheme/tests/Makefile
1766 dlls/vdhcp.vxd/Makefile
1767 dlls/vdmdbg/Makefile
1768 dlls/version/Makefile
1769 dlls/version/tests/Makefile
1770 dlls/vmm.vxd/Makefile
1771 dlls/vnbt.vxd/Makefile
1772 dlls/vnetbios.vxd/Makefile
1773 dlls/vtdapi.vxd/Makefile
1774 dlls/vwin32.vxd/Makefile
1775 dlls/w32skrnl/Makefile
1776 dlls/winecrt0/Makefile
1777 dlls/wined3d/Makefile
1778 dlls/winedos/Makefile
1779 dlls/winemp3.acm/Makefile
1780 dlls/wineps.drv/Makefile
1781 dlls/winex11.drv/Makefile
1782 dlls/wininet/Makefile
1783 dlls/wininet/tests/Makefile
1784 dlls/winmm/Makefile
1785 dlls/winmm/joystick/Makefile
1786 dlls/winmm/tests/Makefile
1787 dlls/winmm/winealsa/Makefile
1788 dlls/winmm/winearts/Makefile
1789 dlls/winmm/wineaudioio/Makefile
1790 dlls/winmm/winecoreaudio/Makefile
1791 dlls/winmm/wineesd/Makefile
1792 dlls/winmm/winejack/Makefile
1793 dlls/winmm/winenas/Makefile
1794 dlls/winmm/wineoss/Makefile
1795 dlls/winnls32/Makefile
1796 dlls/winspool.drv/Makefile
1797 dlls/winspool.drv/tests/Makefile
1798 dlls/wintab32/Makefile
1799 dlls/wintrust/Makefile
1800 dlls/wldap32/Makefile
1801 dlls/wnaspi32/Makefile
1802 dlls/wow32/Makefile
1803 dlls/ws2_32/Makefile
1804 dlls/ws2_32/tests/Makefile
1805 dlls/wsock32/Makefile
1806 dlls/wtsapi32/Makefile
1807 documentation/Makefile
1808 fonts/Makefile
1809 include/Makefile
1810 libs/Makefile
1811 libs/port/Makefile
1812 libs/wine/Makefile
1813 libs/wpp/Makefile
1814 loader/Makefile
1815 programs/Makefile
1816 programs/clock/Makefile
1817 programs/cmdlgtst/Makefile
1818 programs/control/Makefile
1819 programs/eject/Makefile
1820 programs/expand/Makefile
1821 programs/explorer/Makefile
1822 programs/hh/Makefile
1823 programs/icinfo/Makefile
1824 programs/iexplore/Makefile
1825 programs/msiexec/Makefile
1826 programs/notepad/Makefile
1827 programs/oleview/Makefile
1828 programs/progman/Makefile
1829 programs/regedit/Makefile
1830 programs/regsvr32/Makefile
1831 programs/rpcss/Makefile
1832 programs/rundll32/Makefile
1833 programs/start/Makefile
1834 programs/taskmgr/Makefile
1835 programs/uninstaller/Makefile
1836 programs/view/Makefile
1837 programs/wcmd/Makefile
1838 programs/wineboot/Makefile
1839 programs/winebrowser/Makefile
1840 programs/winecfg/Makefile
1841 programs/wineconsole/Makefile
1842 programs/winedbg/Makefile
1843 programs/winefile/Makefile
1844 programs/winemenubuilder/Makefile
1845 programs/winemine/Makefile
1846 programs/winepath/Makefile
1847 programs/winetest/Makefile
1848 programs/winevdm/Makefile
1849 programs/winhelp/Makefile
1850 programs/winver/Makefile
1851 programs/wordpad/Makefile
1852 server/Makefile
1853 tools/Makefile
1854 tools/widl/Makefile
1855 tools/winapi/Makefile
1856 tools/winebuild/Makefile
1857 tools/winedump/Makefile
1858 tools/winegcc/Makefile
1859 tools/wmc/Makefile
1860 tools/wrc/Makefile])
1862 AC_OUTPUT
1864 if test "$have_x" = "no"
1865 then
1866 echo >&2
1867 AC_MSG_WARN([X development files not found. Wine will be built without])
1868 AC_MSG_WARN([X support, which currently does not work, and probably])
1869 AC_MSG_WARN([isn't what you want anyway. You will need to install devel])
1870 AC_MSG_WARN([ packages of Xlib/Xfree86 at the very least.])
1871 fi
1873 if test "$wine_cv_opengl_version_OK" = "no"
1874 then
1875 echo >&2
1876 AC_MSG_WARN([Old Mesa headers detected. Wine will be built without Direct3D])
1877 AC_MSG_WARN([support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/).])
1878 fi
1880 if test "$wine_cv_msg_freetype" = "yes"
1881 then
1882 echo >&2
1883 AC_MSG_WARN([Your system appears to have the FreeType 2 runtime libraries])
1884 AC_MSG_WARN([installed, but 'freetype-config' is not in your PATH. Install])
1885 AC_MSG_WARN([the freetype-devel package (or its equivalent on your distribution)])
1886 AC_MSG_WARN([to enable Wine to use TrueType fonts.])
1887 fi
1889 if test -z "$FONTSSUBDIRS"
1890 then
1891 echo >&2
1892 if test "$FONTFORGE" = "false"
1893 then
1894 AC_MSG_WARN([FontForge is missing.])
1895 else
1896 AC_MSG_WARN([FreeType is missing.])
1897 fi
1898 AC_MSG_WARN([Fonts will not be built. Dialog text may be invisible or unaligned.])
1899 fi
1901 if test -z "$ALSALIBS" -a \
1902 -z "$ARTSC_LIBS" -a \
1903 -z "$AUDIOIOLIBS" -a \
1904 -z "$NASLIBS" -a \
1905 -z "$ESD_LIBS" -a \
1906 -z "$ac_cv_lib_soname_jack" -a \
1907 "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1908 "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1909 "$ac_cv_header_soundcard_h" != "yes"
1910 then
1911 echo >&2
1912 AC_MSG_WARN([No sound system was found. Windows applications will be silent.])
1913 AC_MSG_WARN([The currently supported sound systems are:])
1914 AC_MSG_WARN([ALSA, ARTS, EsounD, AudioIO, Jack, NAS and OSS])
1915 fi
1917 echo
1918 echo "Configure finished. Do '${ac_make} depend && ${ac_make}' to compile Wine."
1919 echo
1921 dnl Local Variables:
1922 dnl comment-start: "dnl "
1923 dnl comment-end: ""
1924 dnl comment-start-skip: "\\bdnl\\b\\s *"
1925 dnl compile-command: "autoconf && autoheader"
1926 dnl End: