aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18 dnl
  19 dnl As a special exception to the GNU Lesser General Public License,
  20 dnl if you distribute this file as part of a program that contains a
  21 dnl configuration script generated by Autoconf, you may include it
  22 dnl under the same distribution terms that you use for the rest of
  23 dnl that program.
  24
  25 dnl **** Get the ldd program name; used by WINE_GET_SONAME ****
  26 dnl
  27 dnl Usage: WINE_PATH_LDD
  28 dnl
  29 AC_DEFUN([WINE_PATH_LDD],[AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)])
  30
  31 dnl **** Extract the soname of a library ****
  32 dnl
  33 dnl Usage: WINE_CHECK_SONAME(library, function, [action-if-found, [action-if-not-found, [other_libraries, [pattern]]]])
  34 dnl
  35 AC_DEFUN([WINE_CHECK_SONAME],
  36 [AC_REQUIRE([WINE_PATH_LDD])dnl
  37 AS_VAR_PUSHDEF([ac_Lib],[ac_cv_lib_soname_$1])dnl
  38 m4_pushdef([ac_lib_pattern],m4_default([$6],[lib$1]))dnl
  39 AC_MSG_CHECKING([for -l$1])
  40 AC_CACHE_VAL(ac_Lib,
  41 [ac_check_soname_save_LIBS=$LIBS
  42 LIBS="-l$1 $5 $LIBS"
  43   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  44   [case "$LIBEXT" in
  45     dll) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest.exe | grep "$1" | sed -e "s/dll.*/dll/"';2,$d'`]) ;;
  46     dylib) AS_VAR_SET(ac_Lib,[`otool -L conftest$ac_exeext | grep "ac_lib_pattern\\.[[0-9A-Za-z.]]*dylib" | sed -e "s/^.*\/\(ac_lib_pattern\.[[0-9A-Za-z.]]*dylib\).*$/\1/"';2,$d'`]) ;;
  47     *) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest$ac_exeext | grep "ac_lib_pattern\\.$LIBEXT" | sed -e "s/^.*\(ac_lib_pattern\.$LIBEXT[[^      ]]*\).*$/\1/"';2,$d'`]) ;;
  48   esac])
  49   LIBS=$ac_check_soname_save_LIBS])dnl
  50 AS_IF([test "x]AS_VAR_GET(ac_Lib)[" = "x"],
  51       [AC_MSG_RESULT([not found])
  52        $4],
  53       [AC_MSG_RESULT(AS_VAR_GET(ac_Lib))
  54        AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),["]AS_VAR_GET(ac_Lib)["],
  55                           [Define to the soname of the lib$1 library.])
  56        $3])dnl
  57 m4_popdef([ac_lib_pattern])dnl
  58 AS_VAR_POPDEF([ac_Lib])])
  59
  60 dnl **** Link C code with an assembly file ****
  61 dnl
  62 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
  63 dnl
  64 AC_DEFUN([WINE_TRY_ASM_LINK],
  65 [AC_LINK_IFELSE(AC_LANG_PROGRAM([[$2]],[[asm($1); $3]]),[$4],[$5])])
  66
  67 dnl **** Check if we can link an empty program with special CFLAGS ****
  68 dnl
  69 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
  70 dnl
  71 dnl The default action-if-yes is to append the flags to EXTRACFLAGS.
  72 dnl
  73 AC_DEFUN([WINE_TRY_CFLAGS],
  74 [AS_VAR_PUSHDEF([ac_var], ac_cv_cflags_[[$1]])dnl
  75 AC_CACHE_CHECK([whether the compiler supports $1], ac_var,
  76 [ac_wine_try_cflags_saved=$CFLAGS
  77 CFLAGS="$CFLAGS $1"
  78 AC_LINK_IFELSE(AC_LANG_SOURCE([[int main(int argc, char **argv) { return 0; }]]),
  79                [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
  80 CFLAGS=$ac_wine_try_cflags_saved])
  81 AS_IF([test AS_VAR_GET(ac_var) = yes],
  82       [m4_default([$2], [EXTRACFLAGS="$EXTRACFLAGS $1"])], [$3])dnl
  83 AS_VAR_POPDEF([ac_var])])
  84
  85 dnl **** Check if we can link an empty shared lib (no main) with special CFLAGS ****
  86 dnl
  87 dnl Usage: WINE_TRY_SHLIB_FLAGS(flags,[action-if-yes,[action-if-no]])
  88 dnl
  89 AC_DEFUN([WINE_TRY_SHLIB_FLAGS],
  90 [ac_wine_try_cflags_saved=$CFLAGS
  91 CFLAGS="$CFLAGS $1"
  92 AC_LINK_IFELSE([void myfunc() {}],[$2],[$3])
  93 CFLAGS=$ac_wine_try_cflags_saved])
  94
  95 dnl **** Check whether we need to define a symbol on the compiler command line ****
  96 dnl
  97 dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]])
  98 dnl
  99 AC_DEFUN([WINE_CHECK_DEFINE],
 100 [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl
 101 AC_CACHE_CHECK([whether we need to define $1],ac_var,
 102     AC_EGREP_CPP(yes,[#ifndef $1
 103 yes
 104 #endif],
 105     [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)]))
 106 AS_IF([test AS_VAR_GET(ac_var) = yes],
 107       [CFLAGS="$CFLAGS -D$1"
 108   LINTFLAGS="$LINTFLAGS -D$1"])dnl
 109 AS_VAR_POPDEF([ac_var])])
 110
 111 dnl **** Check for functions with some extra libraries ****
 112 dnl
 113 dnl Usage: WINE_CHECK_LIB_FUNCS(funcs,libs,[action-if-found,[action-if-not-found]])
 114 dnl
 115 AC_DEFUN([WINE_CHECK_LIB_FUNCS],
 116 [ac_wine_check_funcs_save_LIBS="$LIBS"
 117 LIBS="$LIBS $2"
 118 AC_CHECK_FUNCS([$1],[$3],[$4])
 119 LIBS="$ac_wine_check_funcs_save_LIBS"])
 120
 121 dnl **** Check for a mingw program, trying the various mingw prefixes ****
 122 dnl
 123 dnl Usage: WINE_CHECK_MINGW_PROG(variable,prog,[value-if-not-found],[path])
 124 dnl
 125 AC_DEFUN([WINE_CHECK_MINGW_PROG],
 126 [case "$host_cpu" in
 127   i[[3456789]]86*)
 128     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32, mingw32msvc, mingw32],
 129                         m4_foreach([ac_wine_cpu],[i686,i586,i486,i386],[ac_wine_cpu-ac_wine_prefix-$2 ]))" ;;
 130   x86_64)
 131     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32,w64-mingw32],[x86_64-ac_wine_prefix-$2 ])" ;;
 132   *)
 133     ac_prefix_list="" ;;
 134 esac
 135 AC_CHECK_PROGS([$1],[$ac_prefix_list],[$3],[$4])])
 136
 137
 138 dnl **** Define helper functions for creating config.status files ****
 139 dnl
 140 dnl Usage: AC_REQUIRE([WINE_CONFIG_HELPERS])
 141 dnl
 142 AC_DEFUN([WINE_CONFIG_HELPERS],
 143 [ALL_MAKEFILE_DEPENDS="
 144 # Rules automatically generated by configure
 145
 146 .INIT: Makefile
 147 .MAKEFILEDEPS:
 148 all: Makefile
 149 Makefile: Makefile.in Make.rules config.status
 150         @./config.status Make.tmp Makefile"
 151
 152 AC_SUBST(ALL_WINETEST_DEPENDS,["# Test binaries"])
 153 AC_SUBST(ALL_TEST_BINARIES,"")
 154
 155 wine_fn_append_file ()
 156 {
 157     AS_VAR_APPEND($[1]," \\$as_nl       $[2]")
 158 }
 159
 160 wine_fn_append_rule ()
 161 {
 162     AS_VAR_APPEND($[1],"$as_nl$[2]")
 163 }
 164
 165 wine_fn_all_dir_rules ()
 166 {
 167     wine_fn_append_file ALL_DIRS $[1]
 168     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 169 "__clean__: $[1]/__clean__
 170 .PHONY: $[1]/__clean__
 171 $[1]/__clean__: $[1]/Makefile
 172         @cd $[1] && \$(MAKE) clean
 173         \$(RM) $[1]/Makefile
 174 $[1]/Makefile: $[1]/Makefile.in config.status $[2]
 175         @./config.status --file $[1]/Makefile && cd $[1] && \$(MAKE) depend
 176 depend: $[1]/__depend__
 177 .PHONY: $[1]/__depend__
 178 $[1]/__depend__: \$(MAKEDEP) dummy
 179         @./config.status --file $[1]/Makefile && cd $[1] && \$(MAKE) depend"
 180 }
 181
 182 wine_fn_config_makefile ()
 183 {
 184     ac_dir=$[1]
 185     ac_enable=$[2]
 186     AS_VAR_IF([$ac_enable],[no],[return 0])
 187
 188     wine_fn_all_dir_rules $ac_dir "Make.rules \$(MAKEDEP)"
 189     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 190 "all: $ac_dir
 191 .PHONY: $ac_dir
 192 $ac_dir: $ac_dir/Makefile dummy
 193         @cd $ac_dir && \$(MAKE)
 194 install:: $ac_dir
 195         @cd $ac_dir && \$(MAKE) install
 196 install-lib:: $ac_dir
 197         @cd $ac_dir && \$(MAKE) install-lib
 198 install-dev:: $ac_dir
 199         @cd $ac_dir && \$(MAKE) install-dev
 200 uninstall:: $ac_dir/Makefile
 201         @cd $ac_dir && \$(MAKE) uninstall"
 202 }
 203
 204 wine_fn_config_lib ()
 205 {
 206     ac_name=$[1]
 207     ac_dir=dlls/$ac_name
 208     wine_fn_all_dir_rules $ac_dir "dlls/Makeimplib.rules \$(MAKEDEP)"
 209     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 210 "all __builddeps__: $ac_dir
 211 $ac_dir: $ac_dir/Makefile tools/widl tools/winebuild tools/winegcc include dummy
 212         @cd $ac_dir && \$(MAKE)
 213 install install-dev:: $ac_dir
 214         @cd $ac_dir && \$(MAKE) install
 215 uninstall:: $ac_dir/Makefile
 216         @cd $ac_dir && \$(MAKE) uninstall"
 217 }
 218
 219 wine_fn_config_dll ()
 220 {
 221     ac_dir=$[1]
 222     ac_enable=$[2]
 223     ac_implib=$[3]
 224     ac_implibsrc=$[4]
 225     ac_file="dlls/$ac_dir/lib$ac_implib"
 226     ac_deps="tools/widl tools/winebuild tools/winegcc include"
 227
 228     wine_fn_all_dir_rules dlls/$ac_dir "dlls/Makedll.rules \$(MAKEDEP)"
 229
 230     AS_VAR_IF([$ac_enable],[no],
 231               dnl enable_win16 is special in that it disables import libs too
 232               [test "$ac_enable" != enable_win16 || return 0],
 233               [wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 234 "all: dlls/$ac_dir
 235 .PHONY: dlls/$ac_dir
 236 dlls/$ac_dir: dlls/$ac_dir/Makefile __builddeps__ dummy
 237         @cd dlls/$ac_dir && \$(MAKE)
 238 install:: dlls/$ac_dir/Makefile __builddeps__
 239         @cd dlls/$ac_dir && \$(MAKE) install
 240 install-lib:: dlls/$ac_dir/Makefile __builddeps__
 241         @cd dlls/$ac_dir && \$(MAKE) install-lib
 242 uninstall manpages htmlpages sgmlpages xmlpages:: dlls/$ac_dir/Makefile
 243         @cd dlls/$ac_dir && \$(MAKE) \$[@]"])
 244
 245     if test -n "$ac_implibsrc"
 246     then
 247         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 248 "__builddeps__: $ac_file.$IMPLIBEXT $ac_file.$STATIC_IMPLIBEXT
 249 $ac_file.$IMPLIBEXT $ac_file.$STATIC_IMPLIBEXT $ac_file.cross.a: $ac_deps
 250 $ac_file.def: dlls/$ac_dir/$ac_dir.spec dlls/$ac_dir/Makefile
 251         @cd dlls/$ac_dir && \$(MAKE) lib$ac_implib.def
 252 $ac_file.$STATIC_IMPLIBEXT: dlls/$ac_dir/Makefile dummy
 253         @cd dlls/$ac_dir && \$(MAKE) lib$ac_implib.$STATIC_IMPLIBEXT
 254 install-dev:: dlls/$ac_dir/Makefile __builddeps__
 255         @cd dlls/$ac_dir && \$(MAKE) install-dev"
 256         if test "x$CROSSTEST_DISABLE" = x
 257         then
 258             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 259 "__builddeps__: $ac_file.cross.a
 260 $ac_file.cross.a: dlls/$ac_dir/Makefile dummy
 261         @cd dlls/$ac_dir && \$(MAKE) lib$ac_implib.cross.a"
 262         fi
 263
 264     elif test -n "$ac_implib"
 265     then
 266         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 267 "__builddeps__: $ac_file.$IMPLIBEXT
 268 $ac_file.$IMPLIBEXT: dlls/$ac_dir/$ac_dir.spec dlls/$ac_dir/Makefile $ac_deps
 269         @cd dlls/$ac_dir && \$(MAKE) lib$ac_implib.$IMPLIBEXT
 270 install-dev:: dlls/$ac_dir/Makefile __builddeps__
 271         @cd dlls/$ac_dir && \$(MAKE) install-dev"
 272         if test "x$CROSSTEST_DISABLE" = x
 273         then
 274             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 275 "__builddeps__: $ac_file.cross.a
 276 $ac_file.cross.a: dlls/$ac_dir/$ac_dir.spec dlls/$ac_dir/Makefile $ac_deps
 277         @cd dlls/$ac_dir && \$(MAKE) lib$ac_implib.cross.a"
 278         fi
 279
 280         if test "$ac_dir" != "$ac_implib"
 281         then
 282             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 283 "__builddeps__: dlls/lib$ac_implib.$IMPLIBEXT
 284 dlls/lib$ac_implib.$IMPLIBEXT: $ac_file.$IMPLIBEXT
 285         \$(RM) \$[@] && \$(LN_S) $ac_dir/lib$ac_implib.$IMPLIBEXT \$[@]
 286 clean::
 287         \$(RM) dlls/lib$ac_implib.$IMPLIBEXT"
 288             if test "x$CROSSTEST_DISABLE" = x
 289             then
 290                 wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 291 "__builddeps__: dlls/lib$ac_implib.cross.a
 292 dlls/lib$ac_implib.cross.a: $ac_file.cross.a
 293         \$(RM) \$[@] && \$(LN_S) $ac_dir/lib$ac_implib.cross.a \$[@]"
 294             fi
 295         fi
 296     fi
 297 }
 298
 299 wine_fn_config_program ()
 300 {
 301     ac_dir=$[1]
 302     ac_enable=$[2]
 303     ac_install=$[3]
 304     wine_fn_all_dir_rules programs/$ac_dir "programs/Makeprog.rules \$(MAKEDEP)"
 305
 306     AS_VAR_IF([$ac_enable],[no],,[wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 307 "all: programs/$ac_dir
 308 .PHONY: programs/$ac_dir
 309 programs/$ac_dir: programs/$ac_dir/Makefile __builddeps__ dummy
 310         @cd programs/$ac_dir && \$(MAKE)"
 311
 312     test -n "$ac_install" || return
 313     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 314 "install install-lib:: programs/$ac_dir/Makefile __builddeps__
 315         @cd programs/$ac_dir && \$(MAKE) install
 316 uninstall:: programs/$ac_dir/Makefile
 317         @cd programs/$ac_dir && \$(MAKE) uninstall"
 318     if test "$ac_install" = installbin -a -n "$DLLEXT" -a "x$enable_tools" != xno
 319     then
 320         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 321 "install install-lib:: tools \$(DESTDIR)\$(bindir)
 322         \$(INSTALL_SCRIPT) tools/wineapploader \$(DESTDIR)\$(bindir)/$ac_dir
 323 uninstall::
 324         \$(RM) \$(DESTDIR)\$(bindir)/$ac_dir"
 325     fi])
 326 }
 327
 328 wine_fn_config_test ()
 329 {
 330     ac_dir=$[1]
 331     ac_name=$[2]
 332     wine_fn_append_file ALL_TEST_BINARIES $ac_name.exe
 333     wine_fn_append_rule ALL_WINETEST_DEPENDS \
 334 "$ac_name.exe: \$(TOPOBJDIR)/$ac_dir/$ac_name.exe$DLLEXT
 335         cp \$(TOPOBJDIR)/$ac_dir/$ac_name.exe$DLLEXT \$[@] && \$(STRIP) \$[@]
 336 $ac_name.rc:
 337         echo \"$ac_name.exe TESTRES \\\"$ac_name.exe\\\"\" >\$[@] || (\$(RM) \$[@] && false)
 338 $ac_name.res: $ac_name.rc $ac_name.exe"
 339     wine_fn_all_dir_rules $ac_dir "Maketest.rules \$(MAKEDEP)"
 340
 341     AS_VAR_IF([enable_tests],[no],,[wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 342 "all programs/winetest: $ac_dir
 343 .PHONY: $ac_dir
 344 $ac_dir: $ac_dir/Makefile __builddeps__ dummy
 345         @cd $ac_dir && \$(MAKE)
 346 test: $ac_dir/__test__
 347 .PHONY: $ac_dir/__test__
 348 $ac_dir/__test__: dummy
 349         @cd $ac_dir && \$(MAKE) test
 350 testclean::
 351         \$(RM) $ac_dir/*.ok"
 352
 353         if test "x$CROSSTEST_DISABLE" = x
 354         then
 355             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 356 "crosstest: $ac_dir/__crosstest__
 357 .PHONY: $ac_dir/__crosstest__
 358 $ac_dir/__crosstest__: $ac_dir/Makefile __builddeps__ dummy
 359         @cd $ac_dir && \$(MAKE) crosstest"
 360         else
 361             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 362 "crosstest:
 363         @echo \"crosstest is not supported (mingw not installed?)\" && false"
 364         fi])
 365 }
 366
 367 wine_fn_config_tool ()
 368 {
 369     ac_dir=$[1]
 370     ac_deps="Make.rules"
 371     if test "$ac_dir" != tools
 372     then
 373         dnl makedep is in tools so tools makefile cannot depend on it
 374         ac_deps="$ac_deps \$(MAKEDEP)"
 375     fi
 376     wine_fn_all_dir_rules $ac_dir "$ac_deps"
 377
 378     AS_VAR_IF([enable_tools],[no],,[case $ac_dir in
 379       dnl tools directory has both install-lib and install-dev
 380       tools) wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 381 "install:: $ac_dir
 382         @cd $ac_dir && \$(MAKE) install
 383 install-lib:: $ac_dir
 384         @cd $ac_dir && \$(MAKE) install-lib
 385 install-dev:: $ac_dir
 386         @cd $ac_dir && \$(MAKE) install-dev" ;;
 387       *)     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 388 "install install-dev:: $ac_dir
 389         @cd $ac_dir && \$(MAKE) install" ;;
 390       esac
 391       wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 392 "uninstall:: $ac_dir/Makefile
 393         @cd $ac_dir && \$(MAKE) uninstall
 394 all __tooldeps__: $ac_dir
 395 .PHONY: $ac_dir
 396 $ac_dir: $ac_dir/Makefile libs/port dummy
 397         @cd $ac_dir && \$(MAKE)"])
 398 }
 399
 400 wine_fn_config_makerules ()
 401 {
 402     ac_rules=$[1]
 403     ac_deps=$[2]
 404     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 405 "$ac_rules: $ac_rules.in $ac_deps config.status
 406         @./config.status $ac_rules
 407 distclean::
 408         \$(RM) $ac_rules"
 409 }
 410
 411 wine_fn_config_symlink ()
 412 {
 413     ac_link=$[1]
 414     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 415 "$ac_link:
 416         @./config.status $ac_link
 417 distclean::
 418         \$(RM) $ac_link"
 419 }])
 420
 421 dnl **** Define helper function to append a file to a makefile file list ****
 422 dnl
 423 dnl Usage: WINE_APPEND_FILE(var,file)
 424 dnl
 425 AC_DEFUN([WINE_APPEND_FILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_file $1 "$2"])
 426
 427 dnl **** Define helper function to append a rule to a makefile command list ****
 428 dnl
 429 dnl Usage: WINE_APPEND_RULE(var,rule)
 430 dnl
 431 AC_DEFUN([WINE_APPEND_RULE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_rule $1 "$2"])
 432
 433 dnl **** Create nonexistent directories from config.status ****
 434 dnl
 435 dnl Usage: WINE_CONFIG_EXTRA_DIR(dirname)
 436 dnl
 437 AC_DEFUN([WINE_CONFIG_EXTRA_DIR],
 438 [AC_CONFIG_COMMANDS([$1],[test -d "$1" || { AC_MSG_NOTICE([creating $1]); AS_MKDIR_P("$1"); }])])
 439
 440 dnl **** Create symlinks from config.status ****
 441 dnl
 442 dnl Usage: WINE_CONFIG_SYMLINK(name,target,enable)
 443 dnl
 444 AC_DEFUN([WINE_CONFIG_SYMLINK],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 445 m4_ifval([$3],[if test "x$[$3]" != xno; then
 446 ])AC_CONFIG_LINKS([$1:]m4_default([$2],[$1]))dnl
 447 m4_if([$2],,[test "$srcdir" = "." || ])wine_fn_config_symlink $1[]m4_ifval([$3],[
 448 fi])])
 449
 450 dnl **** Create a make rules file from config.status ****
 451 dnl
 452 dnl Usage: WINE_CONFIG_MAKERULES(file,var,deps)
 453 dnl
 454 AC_DEFUN([WINE_CONFIG_MAKERULES],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 455 wine_fn_config_makerules $1 $3
 456 $2=$1
 457 AC_SUBST_FILE([$2])dnl
 458 AC_CONFIG_FILES([$1])])
 459
 460 dnl **** Create a makefile from config.status ****
 461 dnl
 462 dnl Usage: WINE_CONFIG_MAKEFILE(file,enable)
 463 dnl
 464 AC_DEFUN([WINE_CONFIG_MAKEFILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 465 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 466 wine_fn_config_makefile [$1] ac_enable[]dnl
 467 AS_VAR_POPDEF([ac_enable])])
 468
 469 dnl **** Create a dll makefile from config.status ****
 470 dnl
 471 dnl Usage: WINE_CONFIG_DLL(name,enable,implib,implibsrc)
 472 dnl
 473 AC_DEFUN([WINE_CONFIG_DLL],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 474 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 475 wine_fn_config_dll [$1] ac_enable [$3] m4_ifval([$4],["$4"])dnl
 476 AS_VAR_POPDEF([ac_enable])])
 477
 478 dnl **** Create a program makefile from config.status ****
 479 dnl
 480 dnl Usage: WINE_CONFIG_PROGRAM(name,install,enable)
 481 dnl
 482 AC_DEFUN([WINE_CONFIG_PROGRAM],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 483 AS_VAR_PUSHDEF([ac_enable],m4_default([$3],[enable_]$1))dnl
 484 wine_fn_config_program [$1] ac_enable [$2]dnl
 485 AS_VAR_POPDEF([ac_enable])])
 486
 487 dnl **** Create a test makefile from config.status ****
 488 dnl
 489 dnl Usage: WINE_CONFIG_TEST(dir)
 490 dnl
 491 AC_DEFUN([WINE_CONFIG_TEST],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 492 m4_pushdef([ac_suffix],m4_if(m4_substr([$1],0,9),[programs/],[.exe_test],[_test]))dnl
 493 m4_pushdef([ac_name],[m4_bpatsubst([$1],[.*/\(.*\)/tests$],[\1])])dnl
 494 wine_fn_config_test $1 ac_name[]ac_suffix[]dnl
 495 m4_popdef([ac_suffix])dnl
 496 m4_popdef([ac_name])])
 497
 498 dnl **** Create a static lib makefile from config.status ****
 499 dnl
 500 dnl Usage: WINE_CONFIG_LIB(name)
 501 dnl
 502 AC_DEFUN([WINE_CONFIG_LIB],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 503 wine_fn_config_lib $1])
 504
 505 dnl **** Create a tool makefile from config.status ****
 506 dnl
 507 dnl Usage: WINE_CONFIG_TOOL(name)
 508 dnl
 509 AC_DEFUN([WINE_CONFIG_TOOL],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 510 wine_fn_config_tool $1])
 511
 512 dnl **** Add a message to the list displayed at the end ****
 513 dnl
 514 dnl Usage: WINE_NOTICE(notice)
 515 dnl Usage: WINE_NOTICE_WITH(with_flag, test, notice)
 516 dnl Usage: WINE_WARNING(warning)
 517 dnl Usage: WINE_WARNING_WITH(with_flag, test, warning)
 518 dnl Usage: WINE_PRINT_MESSAGES
 519 dnl
 520 AC_DEFUN([WINE_NOTICE],[AS_VAR_APPEND([wine_notices],["|$1"])])
 521 AC_DEFUN([WINE_WARNING],[AS_VAR_APPEND([wine_warnings],["|$1"])])
 522
 523 AC_DEFUN([WINE_NOTICE_WITH],[AS_IF([$2],[case "x$with_$1" in
 524   x)   WINE_NOTICE([$3]) ;;
 525   xno) ;;
 526   *)   AC_MSG_ERROR([$3
 527 This is an error since --with-$1 was requested.]) ;;
 528 esac])])
 529
 530 AC_DEFUN([WINE_WARNING_WITH],[AS_IF([$2],[case "x$with_$1" in
 531   x)   WINE_WARNING([$3]) ;;
 532   xno) ;;
 533   *)   AC_MSG_ERROR([$3
 534 This is an error since --with-$1 was requested.]) ;;
 535 esac])])
 536
 537 AC_DEFUN([WINE_ERROR_WITH],[AS_IF([$2],[case "x$with_$1" in
 538   xno) ;;
 539   *)   AC_MSG_ERROR([$3
 540 Use the --without-$1 option if you really want this.]) ;;
 541 esac])])
 542
 543 AC_DEFUN([WINE_PRINT_MESSAGES],[ac_save_IFS="$IFS"
 544 if test "x$wine_notices != "x; then
 545     echo >&AS_MESSAGE_FD
 546     IFS="|"
 547     for msg in $wine_notices; do
 548         IFS="$ac_save_IFS"
 549         if test -n "$msg"; then
 550             AC_MSG_NOTICE([$msg])
 551         fi
 552     done
 553 fi
 554 IFS="|"
 555 for msg in $wine_warnings; do
 556     IFS="$ac_save_IFS"
 557     if test -n "$msg"; then
 558         echo >&2
 559         AC_MSG_WARN([$msg])
 560     fi
 561 done
 562 IFS="$ac_save_IFS"])
 563
 564 dnl Local Variables:
 565 dnl compile-command: "autoreconf --warnings=all"
 566 dnl End: