| blob | 3dfc1f3fe4763746cabd8d525671eb3be223413f |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53)
8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
18 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
20 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
21 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
24 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
25 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
26 if test "x$enable_win16" = "xno"
27 then
28 WIN16_FILES=""
29 WIN16_INSTALL=""
30 fi
32 AC_SUBST(DLLDEFS,"")
33 if test "x$enable_debug" = "xno"
34 then
35 DLLDEFS="$DLLDEFS -DWINE_NO_DEBUG_MSGS"
36 fi
37 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
38 then
39 DLLDEFS="$DLLDEFS -DWINE_NO_TRACE_MSGS"
40 fi
42 dnl **** Check for some programs ****
44 AC_CANONICAL_HOST
45 case $host in
46 x86_64*linux*)
47 if test "x$enable_win64" != "xyes"
48 then
49 test -n "$CC" || CC="gcc -m32"
50 test -n "$LD" || LD="ld -m elf_i386"
51 test -n "$AS" || AS="as --32"
52 host_cpu="i386"
53 fi
54 ;;
55 esac
57 AC_PROG_MAKE_SET
58 AC_PROG_CC
59 AC_PROG_CXX
60 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
61 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
63 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
64 [if test -z "$with_wine_tools"; then
65 if test "$cross_compiling" = "yes"; then
66 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
67 else
68 wine_cv_toolsdir="\$(TOPOBJDIR)"
69 fi
70 elif test -d "$with_wine_tools/tools/winebuild"; then
71 case $with_wine_tools in
72 /*) wine_cv_toolsdir="$with_wine_tools" ;;
73 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
74 esac
75 else
76 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
77 fi])
78 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
80 AC_PATH_XTRA
81 AC_PROG_LEX
83 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
84 dnl **** without one present.
85 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
86 if test "$XLEX" = "none"
87 then
88 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
89 fi
91 dnl Check for bison
92 AC_CHECK_PROGS(BISON,bison,none)
93 if test "$BISON" = "none"
94 then
95 AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
96 fi
98 AC_CHECK_TOOLS(AS,[gas as],as)
99 AC_CHECK_TOOL(LD,ld,ld)
100 AC_CHECK_TOOL(AR,ar,ar)
101 AC_PROG_RANLIB
102 AC_CHECK_TOOL(STRIP,strip,strip)
103 AC_CHECK_TOOL(WINDRES,windres,false)
104 AC_PROG_LN_S
105 WINE_PROG_LN
106 AC_PROG_EGREP
107 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
108 AC_PROG_INSTALL
109 dnl Prepend src dir to install path dir if it's a relative path
110 case "$INSTALL" in
111 [[\\/$]]* | ?:[[\\/]]* ) ;;
112 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
113 esac
115 dnl Check for lint
116 AC_CHECK_PROGS(LINT, lclint lint)
117 if test "$LINT" = "lint"
118 then
119 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
120 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
121 fi
122 AC_SUBST(LINT)
123 AC_SUBST(LINTFLAGS)
125 dnl Check for various programs
126 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
127 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
128 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
129 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
130 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
132 dnl **** Check for some libraries ****
134 dnl Check for -li386 for NetBSD and OpenBSD
135 AC_CHECK_LIB(i386,i386_set_ldt)
136 dnl Check for -lossaudio for NetBSD
137 AC_CHECK_LIB(ossaudio,_oss_ioctl)
138 dnl Check for -lw for Solaris
139 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
140 dnl Check for -lnsl for Solaris
141 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
142 dnl Check for -lsocket for Solaris
143 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
144 dnl Check for -lresolv for Solaris
145 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
146 dnl Check for -lxpg4 for FreeBSD
147 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
148 dnl Check for -lpoll for Mac OS X/Darwin
149 AC_CHECK_LIB(poll,poll)
150 dnl Check for -lresolv for Mac OS X/Darwin
151 AC_CHECK_LIB(resolv,res_9_init)
152 dnl Check for -lpthread
153 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
155 AC_SUBST(XLIB)
156 AC_SUBST(XFILES)
157 XFILES=""
158 AC_SUBST(OPENGLFILES)
159 OPENGLFILES=""
160 AC_SUBST(GLU32FILES)
161 GLU32FILES=""
162 AC_SUBST(OPENGL_LIBS)
163 OPENGL_LIBS=""
165 dnl **** Check for header files ****
167 AC_CHECK_HEADERS(\
168 arpa/inet.h \
169 arpa/nameser.h \
170 cups/cups.h \
171 direct.h \
172 elf.h \
173 float.h \
174 fontconfig/fontconfig.h \
175 getopt.h \
176 gif_lib.h \
177 ieeefp.h \
178 io.h \
179 jack/jack.h \
180 jpeglib.h \
181 lcms/lcms.h \
182 lcms.h \
183 link.h \
184 linux/cdrom.h \
185 linux/compiler.h \
186 linux/hdreg.h \
187 linux/input.h \
188 linux/ioctl.h \
189 linux/joystick.h \
190 linux/major.h \
191 linux/param.h \
192 linux/serial.h \
193 linux/ucdrom.h \
194 machine/cpu.h \
195 mntent.h \
196 netdb.h \
197 netinet/in.h \
198 netinet/in_systm.h \
199 netinet/tcp.h \
200 netinet/tcp_fsm.h \
201 openssl/ssl.h \
202 poll.h \
203 process.h \
204 pthread.h \
205 pwd.h \
206 regex.h \
207 sched.h \
208 scsi/sg.h \
209 scsi/scsi.h \
210 scsi/scsi_ioctl.h \
211 stdint.h \
212 strings.h \
213 sys/cdio.h \
214 sys/elf32.h \
215 sys/errno.h \
216 sys/epoll.h \
217 sys/exec_elf.h \
218 sys/filio.h \
219 sys/ioctl.h \
220 sys/ipc.h \
221 sys/link.h \
222 sys/lwp.h \
223 sys/mman.h \
224 sys/modem.h \
225 sys/msg.h \
226 sys/param.h \
227 sys/poll.h \
228 sys/ptrace.h \
229 sys/reg.h \
230 sys/scsiio.h \
231 sys/shm.h \
232 sys/signal.h \
233 sys/socket.h \
234 sys/sockio.h \
235 sys/statfs.h \
236 sys/statvfs.h \
237 sys/strtio.h \
238 sys/syscall.h \
239 sys/sysctl.h \
240 sys/time.h \
241 sys/times.h \
242 sys/uio.h \
243 sys/un.h \
244 sys/vfs.h \
245 sys/vm86.h \
246 sys/wait.h \
247 syscall.h \
248 termios.h \
249 unistd.h \
250 utime.h \
251 valgrind/memcheck.h
252 )
253 AC_HEADER_STAT()
255 dnl **** Check for X11 ****
257 if test "$have_x" = "yes"
258 then
259 XLIB="-lXext -lX11"
260 ac_save_CPPFLAGS="$CPPFLAGS"
261 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
263 dnl *** All of the following tests require X11/Xlib.h
264 AC_CHECK_HEADERS(X11/Xlib.h,
265 [
266 AC_CHECK_HEADERS([X11/XKBlib.h \
267 X11/Xutil.h \
268 X11/extensions/shape.h \
269 X11/extensions/XInput.h \
270 X11/extensions/XShm.h \
271 X11/extensions/Xrandr.h \
272 X11/extensions/Xrender.h \
273 X11/extensions/xf86dga.h \
274 X11/extensions/xf86vmode.h],,,
275 [#include <X11/Xlib.h>
276 #ifdef HAVE_X11_XUTIL_H
277 # include <X11/Xutil.h>
278 #endif])
280 dnl *** Check for X keyboard extension
281 if test "$ac_cv_header_X11_XKBlib_h" = "yes"
282 then
283 AC_CHECK_LIB(X11, XkbQueryExtension,
284 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
285 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
286 fi
288 dnl *** Check for X Shm extension
289 if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
290 then
291 AC_CHECK_LIB(Xext, XShmQueryExtension,
292 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
293 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
294 fi
296 dnl *** Check for X shape extension
297 if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
298 then
299 AC_CHECK_LIB(Xext,XShapeQueryExtension,
300 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
301 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
302 fi
304 dnl *** Check for XFree86 DGA / DGA 2.0 extension
305 if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
306 then
307 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
308 [ AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
309 [Define if you have the Xxf86dga library version 2])
310 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
311 ],,
312 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
313 fi
315 dnl *** Check for XFree86 VMODE extension
316 if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
317 then
318 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
319 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
320 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
321 ],,
322 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
323 fi
325 dnl *** Check for X RandR extension
326 if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
327 then
328 AC_TRY_COMPILE([#include <X11/Xlib.h>
329 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
330 [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
331 fi
333 dnl *** Check for Transform functions in Xrender
334 if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
335 then
336 AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
337 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
338 [Define if Xrender has the XRenderSetPictureTransform function])],,
339 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
340 fi
341 ]
342 ) dnl *** End of X11/Xlib.h check
344 dnl Check for the presence of OpenGL
345 if test "x$with_opengl" != "xno"
346 then
347 if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
348 then
349 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
350 This prevents linking to OpenGL. Delete the file and restart configure.])
351 fi
353 AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
354 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
355 then
356 AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
357 dnl Check for some problems due to old Mesa versions
358 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
359 AC_TRY_COMPILE(
360 [#include <GL/gl.h>],
361 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
362 [wine_cv_opengl_version_OK="yes"],
363 [wine_cv_opengl_version_OK="no"]
364 )
365 )
367 if test "$wine_cv_opengl_version_OK" = "yes"
368 then
369 dnl Check for the presence of the library
370 AC_CHECK_LIB(GL,glXCreateContext,
371 OPENGL_LIBS="-lGL"
372 ,,
373 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
375 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
376 then
377 OPENGLFILES='$(OPENGLFILES)'
378 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
379 fi
380 dnl Check for GLU32 library.
381 AC_CHECK_LIB(GLU,gluLookAt,
382 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
383 GLU32FILES='$(GLU32FILES)']
384 ,,
385 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
386 )
387 fi
389 dnl Check for glut32 library.
390 AC_CHECK_LIB(glut,glutMainLoop,
391 [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
392 AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
393 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
394 fi
395 fi
397 dnl **** Check for NAS ****
398 AC_SUBST(NASLIBS,"")
399 AC_CHECK_HEADERS(audio/audiolib.h,
400 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
401 AC_CHECK_LIB(audio,AuCreateFlow,
402 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
403 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
404 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
406 CPPFLAGS="$ac_save_CPPFLAGS"
407 XFILES='$(XFILES)'
408 else
409 XLIB=""
410 X_CFLAGS=""
411 X_LIBS=""
412 fi
414 dnl **** Check which curses lib to use ***
415 CURSESLIBS=""
416 if test "x$with_curses" != "xno"
417 then
418 AC_CHECK_HEADERS(ncurses.h,
419 [AC_CHECK_LIB(ncurses,waddch,
420 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
421 CURSESLIBS="-lncurses"],
422 [AC_CHECK_HEADERS(curses.h,
423 [AC_CHECK_LIB(curses,waddch,
424 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
425 CURSESLIBS="-lcurses"])])])])
426 fi
427 AC_SUBST(CURSESLIBS)
429 dnl **** Check for SANE ****
430 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
431 if test "$sane_devel" = "no"
432 then
433 SANELIBS=""
434 SANEINCL=""
435 else
436 SANELIBS="`$sane_devel --libs`"
437 SANEINCL="`$sane_devel --cflags`"
438 ac_save_CPPFLAGS="$CPPFLAGS"
439 ac_save_LIBS="$LIBS"
440 CPPFLAGS="$CPPFLAGS $SANEINCL"
441 LIBS="$LIBS $SANELIBS"
442 AC_CHECK_HEADER(sane/sane.h,
443 [AC_CHECK_LIB(sane,sane_open,
444 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
445 [SANELIBS=""
446 SANEINCL=""])],
447 [SANELIBS=""
448 SANEINCL=""])
449 LIBS="$ac_save_LIBS"
450 CPPFLAGS="$ac_save_CPPFLAGS"
451 fi
452 AC_SUBST(SANELIBS)
453 AC_SUBST(SANEINCL)
455 dnl **** Check for the ICU library ****
456 AC_CHECK_HEADERS(unicode/ubidi.h)
457 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
458 then
459 saved_libs="$LIBS"
460 ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
461 ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
462 ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
463 AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
464 LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
465 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
466 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
467 AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
468 AC_MSG_RESULT(yes)],
469 [AC_MSG_RESULT(no)])
470 LIBS="$saved_libs"
471 fi
473 dnl **** Check for FreeType 2 ****
474 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
475 if test "$ft_lib" = "no"
476 then
477 FREETYPELIBS=""
478 FREETYPEINCL=""
479 wine_cv_msg_freetype=no
480 else
481 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
482 if test "$ft_devel" = "no"
483 then
484 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
485 if test "$ft_devel2" = "freetype2-config"
486 then
487 ft_devel=$ft_devel2
488 fi
489 fi
490 if test "$ft_devel" = "no"
491 then
492 FREETYPELIBS=""
493 FREETYPEINCL=""
494 wine_cv_msg_freetype=yes
495 else
496 FREETYPELIBS=`$ft_devel --libs`
497 FREETYPEINCL=`$ft_devel --cflags`
498 ac_save_CPPFLAGS="$CPPFLAGS"
499 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
500 AC_CHECK_HEADERS(ft2build.h \
501 freetype/freetype.h \
502 freetype/ftglyph.h \
503 freetype/tttables.h \
504 freetype/ftnames.h \
505 freetype/ftsnames.h \
506 freetype/ttnameid.h \
507 freetype/ftoutln.h \
508 freetype/ftwinfnt.h \
509 freetype/internal/sfnt.h,,,
510 [#if HAVE_FT2BUILD_H
511 #include <ft2build.h>
512 #endif])
513 AC_TRY_CPP([#include <ft2build.h>
514 #include <freetype/fttrigon.h>],
515 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
516 [Define if you have the <freetype/fttrigon.h> header file.])
517 wine_cv_fttrigon=yes],
518 wine_cv_fttrigon=no)
519 CPPFLAGS="$ac_save_CPPFLAGS"
520 dnl Check that we have at least freetype/freetype.h
521 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
522 then
523 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
524 wine_cv_msg_freetype=no
525 else
526 FREETYPELIBS=""
527 FREETYPEINCL=""
528 wine_cv_msg_freetype=yes
529 fi
530 fi
531 fi
532 AC_SUBST(FREETYPELIBS)
533 AC_SUBST(FREETYPEINCL)
535 dnl Only build the fonts dir if we have both freetype and fontforge
536 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
537 then
538 AC_SUBST(FONTSSUBDIRS,"fonts")
539 fi
541 dnl **** Check for parport (currently Linux only) ****
542 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
543 AC_TRY_COMPILE(
544 [#include <linux/ppdev.h>],
545 [ioctl (1,PPCLAIM,0)],
546 [ac_cv_c_ppdev="yes"],
547 [ac_cv_c_ppdev="no"])
548 )
549 if test "$ac_cv_c_ppdev" = "yes"
550 then
551 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
552 fi
554 dnl **** Check for va_copy ****
555 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
556 AC_TRY_LINK(
557 [#include <stdarg.h>],
558 [va_list ap1, ap2;
559 va_copy(ap1,ap2);
560 ],
561 [ac_cv_c_va_copy="yes"],
562 [ac_cv_c_va_copy="no"])
563 )
564 if test "$ac_cv_c_va_copy" = "yes"
565 then
566 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
567 fi
568 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
569 AC_TRY_LINK(
570 [#include <stdarg.h>],
571 [va_list ap1, ap2;
572 __va_copy(ap1,ap2);
573 ],
574 [ac_cv_c___va_copy="yes"],
575 [ac_cv_c___va_copy="no"])
576 )
577 if test "$ac_cv_c___va_copy" = "yes"
578 then
579 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
580 fi
582 dnl **** Check for sigsetjmp ****
583 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
584 AC_TRY_LINK(
585 [#include <setjmp.h>],
586 [sigjmp_buf buf;
587 sigsetjmp( buf, 1 );
588 siglongjmp( buf, 1 );],
589 [ac_cv_c_sigsetjmp="yes"],
590 [ac_cv_c_sigsetjmp="no"])
591 )
592 if test "$ac_cv_c_sigsetjmp" = "yes"
593 then
594 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
595 fi
597 dnl **** Check for pthread_rwlock_t ****
598 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
599 #include <pthread.h>])
601 dnl **** Check for pthread functions ****
602 ac_save_LIBS="$LIBS"
603 LIBS="$LIBS $LIBPTHREAD"
604 AC_CHECK_FUNCS(\
605 pthread_getattr_np \
606 pthread_get_stackaddr_np \
607 pthread_get_stacksize_np \
608 )
609 LIBS="$ac_save_LIBS"
611 dnl **** Check for Open Sound System ****
612 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
614 AC_CACHE_CHECK([for Open Sound System],
615 ac_cv_c_opensoundsystem,
616 AC_TRY_COMPILE([
617 #if defined(HAVE_SYS_SOUNDCARD_H)
618 #include <sys/soundcard.h>
619 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
620 #include <machine/soundcard.h>
621 #elif defined(HAVE_SOUNDCARD_H)
622 #include <soundcard.h>
623 #endif
624 ],[
626 /* check for one of the Open Sound System specific SNDCTL_ defines */
627 #if !defined(SNDCTL_DSP_STEREO)
628 #error No open sound system
629 #endif
630 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
632 if test "$ac_cv_c_opensoundsystem" = "yes"
633 then
634 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
635 fi
637 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
638 ac_cv_c_opensoundsystem_midi,
639 AC_TRY_COMPILE([
640 #if defined(HAVE_SYS_SOUNDCARD_H)
641 #include <sys/soundcard.h>
642 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
643 #include <machine/soundcard.h>
644 #elif defined(HAVE_SOUNDCARD_H)
645 #include <soundcard.h>
646 #endif
647 ],[
649 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
650 #if !defined(SNDCTL_SEQ_SYNC)
651 #error No open sound system MIDI interface
652 #endif
653 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
655 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
656 then
657 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
658 fi
660 dnl **** Check for aRts Sound Server ****
661 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
662 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
663 then
664 ARTSC_CFLAGS=""
665 for i in `$ARTSCCONFIG --cflags`
666 do
667 case "$i" in
668 -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
669 esac
670 done
671 ARTSC_LIBS=`$ARTSCCONFIG --libs`
672 save_CFLAGS="$CFLAGS"
673 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
674 AC_CHECK_LIB(artsc,arts_init,
675 [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
676 [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
677 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
678 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],)
679 CFLAGS="$save_CFLAGS"
680 fi
682 dnl **** Check for ALSA 1.x ****
683 AC_SUBST(ALSALIBS,"")
684 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
685 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
686 then
687 AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
688 [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
689 #include <alsa/asoundlib.h>
690 #elif defined(HAVE_SYS_ASOUNDLIB_H)
691 #include <sys/asoundlib.h>
692 #endif],
693 [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
694 [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
695 ALSALIBS="-lasound"])])
696 fi
698 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
700 AC_SUBST(AUDIOIOLIBS,"")
701 AC_CHECK_HEADERS(libaudioio.h,
702 [AC_CHECK_LIB(audioio,AudioIOGetVersion,
703 [AUDIOIOLIBS="-laudioio"
704 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
706 dnl **** Check for capi4linux ****
708 AC_CHECK_HEADERS(capi20.h,[
709 AC_CHECK_HEADERS(linux/capi.h,[
710 AC_CHECK_LIB(capi20,capi20_register,[
711 AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
712 ])
713 ])
714 ])
716 dnl **** Check for broken glibc mmap64 ****
718 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
719 AC_TRY_RUN([
720 #define _FILE_OFFSET_BITS 64
721 #include <stdio.h>
722 #include <unistd.h>
723 #include <fcntl.h>
724 #include <sys/mman.h>
725 #include <errno.h>
727 int main(int argc,char **argv) {
728 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
729 if (fd == -1) exit(1);
731 unlink("conftest.map");
733 write(fd,"test",4);
735 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
736 (errno == EINVAL)
737 ) {
738 exit(1);
739 }
740 close(fd);
741 fprintf(stderr,"success!\n");
742 exit(0);
743 }
745 ],
746 ac_cv_mmap64_works="yes",
747 ac_cv_mmap64_works="no",
748 ac_cv_mmap64_works="no") )
750 if test "$ac_cv_mmap64_works" = "yes"
751 then
752 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
753 fi
755 dnl **** Check for gcc specific options ****
757 AC_SUBST(EXTRACFLAGS,"")
758 if test "x${GCC}" = "xyes"
759 then
760 EXTRACFLAGS="-Wall -pipe"
762 dnl Check for strength-reduce bug
763 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
764 AC_TRY_RUN([
765 int L[[4]] = {0,1,2,3};
766 int main(void) {
767 static int Array[[3]];
768 unsigned int B = 3;
769 int i;
770 for(i=0; i<B; i++) Array[[i]] = i - 3;
771 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
772 L[[i]] = 4;
774 exit( Array[[1]] != -2 || L[[2]] != 3);
775 }],
776 ac_cv_c_gcc_strength_bug="no",
777 ac_cv_c_gcc_strength_bug="yes",
778 ac_cv_c_gcc_strength_bug="yes") )
779 if test "$ac_cv_c_gcc_strength_bug" = "yes"
780 then
781 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
782 fi
784 dnl Check for -fshort-wchar
785 AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
786 [WINE_TRY_CFLAGS([-fshort-wchar],
787 ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
788 if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
789 then
790 AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
791 fi
793 dnl Check for -mpreferred-stack-boundary
794 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
795 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
796 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
797 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
798 then
799 EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
800 fi
802 dnl Check for -fno-strict-aliasing
803 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
804 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
805 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
806 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
807 then
808 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
809 fi
811 dnl Check for -gstabs+ option
812 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
813 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
814 if test "$ac_cv_c_gcc_gstabs" = "yes"
815 then
816 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
817 fi
819 dnl Check for noisy string.h
820 saved_CFLAGS="$CFLAGS"
821 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
822 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
823 AC_TRY_COMPILE([#include <string.h>],[],
824 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
825 CFLAGS="$saved_CFLAGS"
826 if test "$ac_cv_c_string_h_warnings" = "no"
827 then
828 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
829 fi
830 fi
832 dnl **** Check how to define a function in assembly code ****
834 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
835 WINE_TRY_ASM_LINK(
836 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
837 ac_cv_asm_func_def=".def",
838 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
839 ac_cv_asm_func_def=".type @function",
840 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
841 ac_cv_asm_func_def=".type 2",
842 ac_cv_asm_func_def="unknown")])]))
844 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
845 case "$ac_cv_asm_func_def" in
846 ".def")
847 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
848 ".type @function")
849 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
850 ".type 2")
851 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
852 *)
853 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
854 esac
856 dnl **** Check for underscore on external symbols ****
858 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
859 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
860 [extern int ac_test;],
861 [if (ac_test) return 1],
862 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
864 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
865 if test "$ac_cv_c_extern_prefix" = "yes"
866 then
867 AC_DEFINE([__ASM_NAME(name)], ["_" name])
868 else
869 AC_DEFINE([__ASM_NAME(name)], [name])
870 fi
872 dnl **** Check how to do strings in assembler ****
874 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
875 WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
876 WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
877 WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
878 AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
880 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
881 [Define to the assembler keyword used to specify an ASCII string])
883 dnl **** Check for .short in assembler ****
885 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
886 WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
887 WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
888 AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
890 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
891 [Define to the assembler keyword used to specify a word value])
893 dnl **** Check for .size in assembler ****
895 AC_CACHE_CHECK([for .size in assembler], ac_cv_c_asm_size,
896 WINE_TRY_ASM_LINK([".globl _ac_test\n.size _ac_test, . - _ac_test"],,,
897 ac_cv_c_asm_size="yes",ac_cv_c_asm_size="no"))
899 if test "$ac_cv_c_asm_size" = "yes"
900 then
901 AC_DEFINE(HAVE_ASM_DOT_SIZE, 1, [Define if the assembler keyword .size is accepted])
902 fi
904 dnl **** Check for working dll ****
906 AC_SUBST(DLLEXT,"")
907 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
908 AC_SUBST(DLLIBS,"")
909 AC_SUBST(LDSHARED,"")
910 AC_SUBST(LDDLLFLAGS,"")
911 AC_SUBST(LIBEXT,"so")
912 AC_SUBST(IMPLIBEXT,"def")
914 case $host_os in
915 cygwin*|mingw32*)
916 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
917 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
918 if test "$DLLWRAP" = "false"; then
919 LIBEXT="a"
920 else
921 dnl FIXME - check whether dllwrap works correctly...
922 LIBEXT="dll"
923 fi
924 IMPLIBEXT="a"
925 dnl We can't build 16-bit NE dlls
926 WIN16_FILES=""
927 WIN16_INSTALL=""
928 ;;
929 *)
930 AC_CHECK_HEADERS(dlfcn.h,
931 [AC_CHECK_FUNCS(dlopen,,
932 [AC_CHECK_LIB(dl,dlopen,
933 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
934 DLLIBS="-ldl"],
935 [LIBEXT="a"])])],
936 [LIBEXT="a"])
938 if test "$LIBEXT" = "so"
939 then
940 DLLFLAGS="$DLLFLAGS -fPIC"
941 DLLEXT=".so"
942 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
943 [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
944 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
945 if test "$ac_cv_c_dll_gnuelf" = "yes"
946 then
947 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
948 LDDLLFLAGS="-shared -Wl,-Bsymbolic"
949 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
950 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
951 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
952 if test "$ac_cv_c_dll_zdefs" = "yes"
953 then
954 LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
955 fi
957 AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
958 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
959 ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
960 if test "$ac_cv_c_dll_init_fini" = "yes"
961 then
962 LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
963 fi
965 AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
966 [echo '{ global: *; };' >conftest.map
967 WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
968 ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
969 rm -f conftest.map])
970 if test "$ac_cv_c_ld_version_scripts" = "yes"
971 then
972 LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
973 fi
975 AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
976 [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
977 ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
978 if test "$ac_cv_c_export_dynamic" = "yes"
979 then
980 AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
981 fi
983 case $host_cpu in
984 *i[[3456789]]86*)
985 AC_CACHE_CHECK([whether we can relocate the executable to 0x77f00000], ac_cv_ld_reloc_exec,
986 [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x77f00400],
987 ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
988 if test "$ac_cv_ld_reloc_exec" = "yes"
989 then
990 LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x77f00400"
991 fi
992 ;;
993 esac
995 else
996 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
997 [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
998 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
999 if test "$ac_cv_c_dll_unixware" = "yes"
1000 then
1001 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
1002 LDDLLFLAGS="-Wl,-G,-B,symbolic"
1004 else
1005 AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
1006 [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
1007 if test "$ac_cv_c_dll_macho" = "yes"
1008 then
1009 LIBEXT="dylib"
1010 LDDLLFLAGS="-bundle -flat_namespace -undefined suppress -read_only_relocs warning"
1011 LDSHARED="\$(CC) -dynamiclib"
1012 CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
1013 STRIP="$STRIP -u -r"
1014 dnl Relocate wine executable
1015 AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
1016 dnl Relocate libwine.dyld too
1017 AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
1018 dnl declare needed frameworks
1019 AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1020 AC_SUBST(IOKITLIB,"-framework IOKit")
1021 dnl using IOKit imply we use CoreFoundation too
1022 IOKITLIB="$IOKITLIB $COREFOUNDATIONLIB"
1023 else
1024 AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1025 [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1026 if test "$ac_cv_c_dll_hpux" = "yes"
1027 then
1028 LIBEXT="sl"
1029 DLLEXT=".sl"
1030 LDDLLFLAGS="-shared -fPIC"
1031 LDSHARED="\$(CC) -shared"
1032 fi
1033 fi
1034 fi
1035 fi
1036 fi
1038 dnl Check for cross compiler to build test programs
1039 AC_SUBST(CROSSTEST,"")
1040 if test "$cross_compiling" = "no"
1041 then
1042 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1043 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1044 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1045 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1046 fi
1047 ;;
1048 esac
1050 if test "$LIBEXT" = "a"; then
1051 AC_MSG_ERROR(
1052 [could not find a way to build shared libraries.
1053 It is currently not possible to build Wine without shared library
1054 (.so) support to allow transparent switch between .so and .dll files.
1055 If you are using Linux, you will need a newer binutils.]
1056 )
1057 fi
1059 case $build_os in
1060 cygwin*|mingw32*)
1061 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
1062 darwin*|macosx*)
1063 AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1064 *)
1065 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1066 esac
1068 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1069 case $host_os in
1070 mingw32*)
1071 AC_SUBST(CRTLIBS,"-lmsvcrt")
1072 AC_SUBST(SOCKETLIBS,"-lws2_32")
1073 ;;
1074 esac
1076 case $host_os in
1077 linux*)
1078 case $host_cpu in
1079 *i[[3456789]]86*) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader") ;;
1080 *) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread") ;;
1081 esac
1082 AC_SUBST(MAIN_BINARY,"wine-glibc")
1083 ;;
1084 darwin*)
1085 AC_SUBST(WINE_BINARIES,"wine-pthread")
1086 AC_SUBST(MAIN_BINARY,"wine-pthread")
1087 ;;
1088 *)
1089 AC_SUBST(WINE_BINARIES,"wine-kthread")
1090 AC_SUBST(MAIN_BINARY,"wine-kthread")
1091 ;;
1092 esac
1094 dnl **** Get the soname for libraries that we load dynamically ****
1096 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1097 then
1098 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1099 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1100 WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1101 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1102 WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1103 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1104 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1105 WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1106 WINE_GET_SONAME(cups,cupsGetDefault)
1107 WINE_GET_SONAME(jack,jack_client_new)
1108 WINE_GET_SONAME(fontconfig,FcInit)
1109 WINE_GET_SONAME(ssl,SSL_library_init)
1110 WINE_GET_SONAME(crypto,BIO_new_socket)
1111 WINE_GET_SONAME(ncurses,waddch)
1112 WINE_GET_SONAME(curses,waddch)
1113 WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1114 WINE_GET_SONAME(ungif,DGifOpen)
1115 WINE_GET_SONAME(gif,DGifOpen)
1116 WINE_GET_SONAME(lcms,cmsOpenProfileFromFile)
1117 WINE_GET_SONAME(capi20,capi20_isinstalled)
1118 fi
1121 dnl **** Check for functions ****
1123 AC_FUNC_ALLOCA()
1124 AC_CHECK_FUNCS(\
1125 _lwp_create \
1126 _lwp_self \
1127 _pclose \
1128 _popen \
1129 _snprintf \
1130 _spawnvp \
1131 _stricmp \
1132 _strnicmp \
1133 _vsnprintf \
1134 chsize \
1135 clone \
1136 epoll_create \
1137 ffs \
1138 finite \
1139 fork \
1140 fpclass \
1141 fstatfs \
1142 fstatvfs \
1143 ftruncate \
1144 futimes \
1145 getnetbyname \
1146 getopt_long \
1147 getpagesize \
1148 getprotobyname \
1149 getprotobynumber \
1150 getpwuid \
1151 getservbyport \
1152 gettid \
1153 gettimeofday \
1154 getuid \
1155 inet_network \
1156 lstat \
1157 memmove \
1158 mmap \
1159 pclose \
1160 popen \
1161 pread \
1162 pwrite \
1163 readlink \
1164 rfork \
1165 sched_yield \
1166 select \
1167 sendmsg \
1168 settimeofday \
1169 sigaltstack \
1170 sigprocmask \
1171 snprintf \
1172 spawnvp \
1173 statfs \
1174 statvfs \
1175 strcasecmp \
1176 strerror \
1177 strncasecmp \
1178 tcgetattr \
1179 timegm \
1180 usleep \
1181 vsnprintf \
1182 wait4 \
1183 waitpid \
1184 )
1186 dnl **** Checks for headers that depend on other ones ****
1188 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1189 [#include <sys/types.h>
1190 #if HAVE_SYS_PARAM_H
1191 # include <sys/param.h>
1192 #endif])
1194 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1195 [#include <sys/types.h>
1196 #if HAVE_SYS_SOCKET_H
1197 # include <sys/socket.h>
1198 #endif])
1200 AC_CHECK_HEADERS([resolv.h],,,
1201 [#include <sys/types.h>
1202 #if HAVE_SYS_SOCKET_H
1203 # include <sys/socket.h>
1204 #endif
1205 #if HAVE_NETINET_IN_H
1206 # include <netinet/in.h>
1207 #endif
1208 #if HAVE_ARPA_NAMESER_H
1209 # include <arpa/nameser.h>
1210 #endif])
1212 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1214 dnl **** Check for IPX headers (currently Linux only) ****
1216 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1217 AC_TRY_COMPILE(
1218 [#include <sys/types.h>
1219 #ifdef HAVE_SYS_SOCKET_H
1220 # include <sys/socket.h>
1221 #endif
1222 #include <netipx/ipx.h>],
1223 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1224 [ac_cv_c_ipx_gnu="yes"],
1225 [ac_cv_c_ipx_gnu="no"])
1226 )
1227 if test "$ac_cv_c_ipx_gnu" = "yes"
1228 then
1229 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1230 fi
1232 if test "$ac_cv_c_ipx_gnu" = "no"
1233 then
1234 AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1235 AC_TRY_COMPILE(
1236 [#include <sys/types.h>
1237 #ifdef HAVE_SYS_SOCKET_H
1238 # include <sys/socket.h>
1239 #endif
1240 #include <asm/types.h>
1241 #include <linux/ipx.h>],
1242 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1243 [ac_cv_c_ipx_linux="yes"],
1244 [ac_cv_c_ipx_linux="no"])
1245 )
1246 if test "$ac_cv_c_ipx_linux" = "yes"
1247 then
1248 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1249 fi
1250 fi
1252 dnl **** Check for types ****
1254 AC_C_CONST
1255 AC_C_INLINE
1256 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1257 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1259 AC_CACHE_CHECK([whether linux/input.h is for real],
1260 wine_cv_linux_input_h,
1261 AC_TRY_COMPILE([
1262 #include <linux/input.h>
1263 ] , [
1264 int foo = EVIOCGBIT(EV_ABS,42);
1265 int bar = BTN_PINKIE;
1266 int fortytwo = 42;
1267 ],
1268 wine_cv_linux_input_h=yes,
1269 wine_cv_linux_input_h=no,
1270 no
1271 )
1272 )
1273 if test "$wine_cv_linux_input_h" = "yes"
1274 then
1275 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1276 [Define if we have linux/input.h AND it contains the INPUT event API])
1277 fi
1279 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1280 AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1281 wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1282 if test "$wine_cv_have_sigaddset" = "yes"
1283 then
1284 AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1285 fi
1288 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1289 wine_cv_linux_gethostbyname_r_6,
1290 AC_TRY_LINK([
1291 #include <netdb.h>
1292 ], [
1293 char *name=NULL;
1294 struct hostent he;
1295 struct hostent *result;
1296 char *buf=NULL;
1297 int bufsize=0;
1298 int res,errnr;
1299 char *addr=NULL;
1300 int addrlen=0;
1301 int addrtype=0;
1302 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1303 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1304 ],
1305 wine_cv_linux_gethostbyname_r_6=yes,
1306 wine_cv_linux_gethostbyname_r_6=no
1307 )
1308 )
1309 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1310 then
1311 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1312 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1313 fi
1315 if test "$ac_cv_header_linux_joystick_h" = "yes"
1316 then
1317 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1318 wine_cv_linux_joystick_22_api,
1319 AC_TRY_COMPILE([
1320 #include <sys/ioctl.h>
1321 #include <linux/joystick.h>
1323 struct js_event blub;
1324 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1325 #error "no 2.2 header"
1326 #endif
1327 ],/*empty*/,
1328 wine_cv_linux_joystick_22_api=yes,
1329 wine_cv_linux_joystick_22_api=no,
1330 wine_cv_linux_joystick_22_api=no
1331 )
1332 )
1333 if test "$wine_cv_linux_joystick_22_api" = "yes"
1334 then
1335 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1336 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1337 fi
1338 fi
1340 dnl **** statfs checks ****
1342 if test "$ac_cv_header_sys_vfs_h" = "yes"
1343 then
1344 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1345 wine_cv_sys_vfs_has_statfs,
1346 AC_TRY_COMPILE([
1347 #include <sys/types.h>
1348 #ifdef HAVE_SYS_PARAM_H
1349 # include <sys/param.h>
1350 #endif
1351 #include <sys/vfs.h>
1352 ],[
1353 struct statfs stfs;
1355 memset(&stfs,0,sizeof(stfs));
1356 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1357 )
1358 )
1359 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1360 then
1361 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1362 [Define if the struct statfs is defined by <sys/vfs.h>])
1363 fi
1364 fi
1366 if test "$ac_cv_header_sys_statfs_h" = "yes"
1367 then
1368 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1369 wine_cv_sys_statfs_has_statfs,
1370 AC_TRY_COMPILE([
1371 #include <sys/types.h>
1372 #ifdef HAVE_SYS_PARAM_H
1373 # include <sys/param.h>
1374 #endif
1375 #include <sys/statfs.h>
1376 ],[
1377 struct statfs stfs;
1378 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1379 )
1380 )
1381 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1382 then
1383 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1384 [Define if the struct statfs is defined by <sys/statfs.h>])
1385 fi
1386 fi
1388 if test "$ac_cv_header_sys_mount_h" = "yes"
1389 then
1390 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1391 wine_cv_sys_mount_has_statfs,
1392 AC_TRY_COMPILE([
1393 #include <sys/types.h>
1394 #ifdef HAVE_SYS_PARAM_H
1395 # include <sys/param.h>
1396 #endif
1397 #include <sys/mount.h>
1398 ],[
1399 struct statfs stfs;
1400 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1401 )
1402 )
1403 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1404 then
1405 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1406 [Define if the struct statfs is defined by <sys/mount.h>])
1407 fi
1408 fi
1410 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1412 dnl Check for statfs members
1413 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1414 [#include <sys/types.h>
1415 #ifdef HAVE_SYS_PARAM_H
1416 # include <sys/param.h>
1417 #endif
1418 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1419 # include <sys/mount.h>
1420 #else
1421 # ifdef STATFS_DEFINED_BY_SYS_VFS
1422 # include <sys/vfs.h>
1423 # else
1424 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1425 # include <sys/statfs.h>
1426 # endif
1427 # endif
1428 #endif])
1430 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1431 [#ifdef HAVE_SYS_STATVFS_H
1432 #include <sys/statvfs.h>
1433 #endif])
1435 dnl Check for socket structure members
1436 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1437 [#include <sys/types.h>
1438 #ifdef HAVE_SYS_SOCKET_H
1439 # include <sys/socket.h>
1440 #endif
1441 #ifdef HAVE_SYS_UN_H
1442 # include <sys/un.h>
1443 #endif])
1445 dnl Check for siginfo_t members
1446 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1448 dnl Check for struct option
1449 AC_CHECK_MEMBERS([struct option.name],,,
1450 [#ifdef HAVE_GETOPT_H
1451 #include <getopt.h>
1452 #endif])
1454 dnl Check for stat.st_blocks
1455 AC_CHECK_MEMBERS([struct stat.st_blocks])
1457 dnl *** check for the need to define platform-specific symbols
1459 case $host_cpu in
1460 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1461 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1462 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1463 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1464 esac
1466 case $host_vendor in
1467 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1468 esac
1470 dnl **** Generate output files ****
1472 AH_TOP([#define __WINE_CONFIG_H])
1474 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1475 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1476 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1477 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1478 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1479 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1480 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1481 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1482 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1483 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1484 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1485 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1486 WINE_CONFIG_EXTRA_DIR(include/wine)
1487 WINE_CONFIG_EXTRA_DIR(misc)
1488 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1489 WINE_CONFIG_EXTRA_DIR(windows)
1491 MAKE_RULES=Make.rules
1492 AC_SUBST_FILE(MAKE_RULES)
1494 MAKE_DLL_RULES=dlls/Makedll.rules
1495 AC_SUBST_FILE(MAKE_DLL_RULES)
1497 MAKE_TEST_RULES=dlls/Maketest.rules
1498 AC_SUBST_FILE(MAKE_TEST_RULES)
1500 MAKE_LIB_RULES=libs/Makelib.rules
1501 AC_SUBST_FILE(MAKE_LIB_RULES)
1503 MAKE_PROG_RULES=programs/Makeprog.rules
1504 AC_SUBST_FILE(MAKE_PROG_RULES)
1506 AC_CONFIG_FILES([
1507 Make.rules
1508 dlls/Makedll.rules
1509 dlls/Maketest.rules
1510 libs/Makelib.rules
1511 programs/Makeprog.rules
1512 Makefile
1513 dlls/Makefile
1514 dlls/advapi32/Makefile
1515 dlls/advapi32/tests/Makefile
1516 dlls/advpack/Makefile
1517 dlls/advpack/tests/Makefile
1518 dlls/amstream/Makefile
1519 dlls/atl/Makefile
1520 dlls/avicap32/Makefile
1521 dlls/avifil32/Makefile
1522 dlls/cabinet/Makefile
1523 dlls/capi2032/Makefile
1524 dlls/cards/Makefile
1525 dlls/cfgmgr32/Makefile
1526 dlls/comcat/Makefile
1527 dlls/comctl32/Makefile
1528 dlls/comctl32/tests/Makefile
1529 dlls/commdlg/Makefile
1530 dlls/crtdll/Makefile
1531 dlls/crypt32/Makefile
1532 dlls/cryptdll/Makefile
1533 dlls/ctl3d/Makefile
1534 dlls/d3d8/Makefile
1535 dlls/d3d9/Makefile
1536 dlls/d3dim/Makefile
1537 dlls/d3drm/Makefile
1538 dlls/d3dx8/Makefile
1539 dlls/d3dxof/Makefile
1540 dlls/dbghelp/Makefile
1541 dlls/dciman32/Makefile
1542 dlls/ddraw/Makefile
1543 dlls/ddraw/tests/Makefile
1544 dlls/devenum/Makefile
1545 dlls/dinput/Makefile
1546 dlls/dinput8/Makefile
1547 dlls/dmband/Makefile
1548 dlls/dmcompos/Makefile
1549 dlls/dmime/Makefile
1550 dlls/dmloader/Makefile
1551 dlls/dmscript/Makefile
1552 dlls/dmstyle/Makefile
1553 dlls/dmsynth/Makefile
1554 dlls/dmusic/Makefile
1555 dlls/dmusic32/Makefile
1556 dlls/dplay/Makefile
1557 dlls/dplayx/Makefile
1558 dlls/dpnet/Makefile
1559 dlls/dpnhpast/Makefile
1560 dlls/dsound/Makefile
1561 dlls/dsound/tests/Makefile
1562 dlls/dswave/Makefile
1563 dlls/dxdiagn/Makefile
1564 dlls/dxerr8/Makefile
1565 dlls/dxerr9/Makefile
1566 dlls/dxguid/Makefile
1567 dlls/gdi/Makefile
1568 dlls/gdi/tests/Makefile
1569 dlls/glu32/Makefile
1570 dlls/glut32/Makefile
1571 dlls/hhctrl.ocx/Makefile
1572 dlls/iccvid/Makefile
1573 dlls/icmp/Makefile
1574 dlls/ifsmgr.vxd/Makefile
1575 dlls/imagehlp/Makefile
1576 dlls/imm32/Makefile
1577 dlls/iphlpapi/Makefile
1578 dlls/iphlpapi/tests/Makefile
1579 dlls/itss/Makefile
1580 dlls/kernel/Makefile
1581 dlls/kernel/tests/Makefile
1582 dlls/lzexpand/Makefile
1583 dlls/lzexpand/tests/Makefile
1584 dlls/mapi32/Makefile
1585 dlls/mapi32/tests/Makefile
1586 dlls/mlang/Makefile
1587 dlls/mlang/tests/Makefile
1588 dlls/mmdevldr.vxd/Makefile
1589 dlls/monodebg.vxd/Makefile
1590 dlls/mpr/Makefile
1591 dlls/msacm/Makefile
1592 dlls/msacm/imaadp32/Makefile
1593 dlls/msacm/msadp32/Makefile
1594 dlls/msacm/msg711/Makefile
1595 dlls/msacm/winemp3/Makefile
1596 dlls/msacm/tests/Makefile
1597 dlls/mscms/Makefile
1598 dlls/mscms/tests/Makefile
1599 dlls/msdmo/Makefile
1600 dlls/mshtml/Makefile
1601 dlls/msi/Makefile
1602 dlls/msi/tests/Makefile
1603 dlls/msimg32/Makefile
1604 dlls/msisys/Makefile
1605 dlls/msnet32/Makefile
1606 dlls/msrle32/Makefile
1607 dlls/msvcrt/Makefile
1608 dlls/msvcrt/tests/Makefile
1609 dlls/msvcrt20/Makefile
1610 dlls/msvcrt40/Makefile
1611 dlls/msvcrtd/Makefile
1612 dlls/msvcrtd/tests/Makefile
1613 dlls/msvidc32/Makefile
1614 dlls/msvideo/Makefile
1615 dlls/mswsock/Makefile
1616 dlls/netapi32/Makefile
1617 dlls/netapi32/tests/Makefile
1618 dlls/newdev/Makefile
1619 dlls/ntdll/Makefile
1620 dlls/ntdll/tests/Makefile
1621 dlls/odbc32/Makefile
1622 dlls/ole32/Makefile
1623 dlls/ole32/tests/Makefile
1624 dlls/oleacc/Makefile
1625 dlls/oleaut32/Makefile
1626 dlls/oleaut32/tests/Makefile
1627 dlls/olecli/Makefile
1628 dlls/oledlg/Makefile
1629 dlls/olepro32/Makefile
1630 dlls/olesvr/Makefile
1631 dlls/opengl32/Makefile
1632 dlls/psapi/Makefile
1633 dlls/psapi/tests/Makefile
1634 dlls/qcap/Makefile
1635 dlls/quartz/Makefile
1636 dlls/quartz/tests/Makefile
1637 dlls/rasapi32/Makefile
1638 dlls/riched20/Makefile
1639 dlls/richedit/Makefile
1640 dlls/rpcrt4/Makefile
1641 dlls/rpcrt4/tests/Makefile
1642 dlls/rsabase/Makefile
1643 dlls/rsabase/tests/Makefile
1644 dlls/rsaenh/Makefile
1645 dlls/rsaenh/tests/Makefile
1646 dlls/secur32/Makefile
1647 dlls/sensapi/Makefile
1648 dlls/serialui/Makefile
1649 dlls/setupapi/Makefile
1650 dlls/shdocvw/Makefile
1651 dlls/shell32/Makefile
1652 dlls/shell32/tests/Makefile
1653 dlls/shfolder/Makefile
1654 dlls/shlwapi/Makefile
1655 dlls/shlwapi/tests/Makefile
1656 dlls/snmpapi/Makefile
1657 dlls/stdole32.tlb/Makefile
1658 dlls/sti/Makefile
1659 dlls/strmiids/Makefile
1660 dlls/tapi32/Makefile
1661 dlls/ttydrv/Makefile
1662 dlls/twain/Makefile
1663 dlls/unicows/Makefile
1664 dlls/url/Makefile
1665 dlls/urlmon/Makefile
1666 dlls/urlmon/tests/Makefile
1667 dlls/user/Makefile
1668 dlls/user/tests/Makefile
1669 dlls/uuid/Makefile
1670 dlls/uxtheme/Makefile
1671 dlls/vdhcp.vxd/Makefile
1672 dlls/vdmdbg/Makefile
1673 dlls/version/Makefile
1674 dlls/version/tests/Makefile
1675 dlls/vmm.vxd/Makefile
1676 dlls/vnbt.vxd/Makefile
1677 dlls/vnetbios.vxd/Makefile
1678 dlls/vtdapi.vxd/Makefile
1679 dlls/vwin32.vxd/Makefile
1680 dlls/win32s/Makefile
1681 dlls/winaspi/Makefile
1682 dlls/wined3d/Makefile
1683 dlls/winedos/Makefile
1684 dlls/wineps/Makefile
1685 dlls/wininet/Makefile
1686 dlls/wininet/tests/Makefile
1687 dlls/winmm/Makefile
1688 dlls/winmm/joystick/Makefile
1689 dlls/winmm/mcianim/Makefile
1690 dlls/winmm/mciavi/Makefile
1691 dlls/winmm/mcicda/Makefile
1692 dlls/winmm/mciseq/Makefile
1693 dlls/winmm/mciwave/Makefile
1694 dlls/winmm/midimap/Makefile
1695 dlls/winmm/tests/Makefile
1696 dlls/winmm/wavemap/Makefile
1697 dlls/winmm/winealsa/Makefile
1698 dlls/winmm/winearts/Makefile
1699 dlls/winmm/wineaudioio/Makefile
1700 dlls/winmm/winejack/Makefile
1701 dlls/winmm/winenas/Makefile
1702 dlls/winmm/wineoss/Makefile
1703 dlls/winnls/Makefile
1704 dlls/winsock/Makefile
1705 dlls/winsock/tests/Makefile
1706 dlls/winspool/Makefile
1707 dlls/winspool/tests/Makefile
1708 dlls/wintab32/Makefile
1709 dlls/wintrust/Makefile
1710 dlls/wow32/Makefile
1711 dlls/wsock32/Makefile
1712 dlls/wtsapi32/Makefile
1713 dlls/x11drv/Makefile
1714 documentation/Makefile
1715 fonts/Makefile
1716 include/Makefile
1717 libs/Makefile
1718 libs/port/Makefile
1719 libs/unicode/Makefile
1720 libs/wine/Makefile
1721 libs/wpp/Makefile
1722 loader/Makefile
1723 programs/Makefile
1724 programs/avitools/Makefile
1725 programs/clock/Makefile
1726 programs/cmdlgtst/Makefile
1727 programs/control/Makefile
1728 programs/expand/Makefile
1729 programs/msiexec/Makefile
1730 programs/notepad/Makefile
1731 programs/progman/Makefile
1732 programs/regedit/Makefile
1733 programs/regsvr32/Makefile
1734 programs/rpcss/Makefile
1735 programs/rundll32/Makefile
1736 programs/start/Makefile
1737 programs/taskmgr/Makefile
1738 programs/uninstaller/Makefile
1739 programs/view/Makefile
1740 programs/wcmd/Makefile
1741 programs/wineboot/Makefile
1742 programs/winebrowser/Makefile
1743 programs/winecfg/Makefile
1744 programs/wineconsole/Makefile
1745 programs/winedbg/Makefile
1746 programs/winefile/Makefile
1747 programs/winemenubuilder/Makefile
1748 programs/winemine/Makefile
1749 programs/winepath/Makefile
1750 programs/winetest/Makefile
1751 programs/winevdm/Makefile
1752 programs/winhelp/Makefile
1753 programs/winver/Makefile
1754 server/Makefile
1755 tools/Makefile
1756 tools/widl/Makefile
1757 tools/winapi/Makefile
1758 tools/winebuild/Makefile
1759 tools/winedump/Makefile
1760 tools/winegcc/Makefile
1761 tools/wmc/Makefile
1762 tools/wrc/Makefile])
1764 AC_OUTPUT
1766 if test "$have_x" = "no"
1767 then
1768 echo
1769 echo "*** Warning: X development files not found. Wine will be built without"
1770 echo "*** X support, which currently does not work, and would probably not be"
1771 echo "*** what you want anyway. You will need to install devel packages of"
1772 echo "*** Xlib/Xfree86 at the very least."
1773 fi
1775 if test "$wine_cv_opengl_version_OK" = "no"
1776 then
1777 echo
1778 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1779 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1780 fi
1782 if test "$wine_cv_msg_freetype" = "yes"
1783 then
1784 echo
1785 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1786 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1787 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1788 echo "*** enable Wine to use TrueType fonts."
1789 fi
1791 if test -z "$ALSALIBS" -a -z "$ARTSC_LIBS" -a -z "$AUDIOIOLIBS" -a \
1792 -z "$ac_cv_lib_soname_jack" -a -z "$NASLIBS" -a \
1793 "$ac_cv_c_opensoundsystem" = "no"
1794 then
1795 echo "*** No sound system was found. Windows applications will be silent."
1796 echo "*** The currently supported sound systems are:"
1797 echo "*** ALSA, ARTS, AudioIO, Jack, NAS and OSS"
1798 fi
1800 echo
1801 echo "Configure finished. Do '${ac_make} depend && ${ac_make}' to compile Wine."
1802 echo
1804 dnl Local Variables:
1805 dnl comment-start: "dnl "
1806 dnl comment-end: ""
1807 dnl comment-start-skip: "\\bdnl\\b\\s *"
1808 dnl compile-command: "autoconf"
1809 dnl End: