| blob | 0a004e1ba6085c00735fc3f5b7074acb031f9d83 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53)
8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
19 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
20 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
21 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
23 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
24 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
25 if test "x$enable_win16" = "xno"
26 then
27 WIN16_FILES=""
28 WIN16_INSTALL=""
29 fi
30 if test "x$enable_debug" = "xno"
31 then
32 AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
33 fi
34 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
35 then
36 AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
37 fi
39 dnl **** Check for some programs ****
41 AC_CANONICAL_HOST
42 AC_PROG_MAKE_SET
43 AC_PROG_CC
44 AC_PROG_CXX
45 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
46 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
48 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
49 [if test -z "$with_wine_tools"; then
50 if test "$cross_compiling" = "yes"; then
51 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
52 else
53 wine_cv_toolsdir="\$(TOPOBJDIR)"
54 fi
55 elif test -d "$with_wine_tools/tools/winebuild"; then
56 case $with_wine_tools in
57 /*) wine_cv_toolsdir="$with_wine_tools" ;;
58 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
59 esac
60 else
61 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
62 fi])
63 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
65 AC_PATH_XTRA
66 AC_PROG_LEX
68 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
69 dnl **** without one present.
70 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
71 if test "$XLEX" = "none"
72 then
73 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
74 fi
76 dnl Check for bison
77 AC_CHECK_PROGS(BISON,bison,none)
78 if test "$BISON" = "none"
79 then
80 AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
81 fi
83 AC_CHECK_TOOLS(AS,[gas as],as)
84 AC_CHECK_TOOL(LD,ld,ld)
85 AC_CHECK_TOOL(AR,ar,ar)
86 AC_PROG_RANLIB
87 AC_CHECK_TOOL(STRIP,strip,strip)
88 AC_CHECK_TOOL(WINDRES,windres,false)
89 AC_PROG_LN_S
90 WINE_PROG_LN
91 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
92 AC_PROG_INSTALL
93 dnl Prepend src dir to install path dir if it's a relative path
94 case "$INSTALL" in
95 [[\\/$]]* | ?:[[\\/]]* ) ;;
96 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
97 esac
99 dnl Check for lint
100 AC_CHECK_PROGS(LINT, lclint lint)
101 if test "$LINT" = "lint"
102 then
103 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
104 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
105 fi
106 AC_SUBST(LINT)
107 AC_SUBST(LINTFLAGS)
109 dnl Check for db2html
110 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
111 AC_SUBST(DB2HTML)
113 dnl Check for db2pdf
114 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
115 AC_SUBST(DB2PDF)
117 dnl Check for db2ps
118 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
119 AC_SUBST(DB2PS)
121 dnl Check for db2txt
122 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
123 AC_SUBST(DB2TXT)
125 dnl **** Check for some libraries ****
127 dnl Check for -li386 for NetBSD and OpenBSD
128 AC_CHECK_LIB(i386,i386_set_ldt)
129 dnl Check for -lossaudio for NetBSD
130 AC_CHECK_LIB(ossaudio,_oss_ioctl)
131 dnl Check for -lw for Solaris
132 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
133 dnl Check for -lnsl for Solaris
134 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
135 dnl Check for -lsocket for Solaris
136 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
137 dnl Check for -lresolv for Solaris
138 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
139 dnl Check for -lxpg4 for FreeBSD
140 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
141 dnl Check for -lpoll for Mac OS X/Darwin
142 AC_CHECK_LIB(poll,poll)
143 dnl Check for -lresolv for Mac OS X/Darwin
144 AC_CHECK_LIB(resolv,res_9_init)
145 dnl Check for -lpthread
146 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
148 JPEGLIB=""
149 AC_SUBST(JPEGLIB)
150 AC_CHECK_HEADERS(jpeglib.h,
151 AC_CHECK_LIB(jpeg,jpeg_start_decompress,
152 AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
153 JPEGLIB="-ljpeg"
154 )
155 )
157 AC_SUBST(GIFLIB,"")
158 AC_CHECK_HEADERS(gif_lib.h,
159 AC_CHECK_LIB(ungif,DGifOpen,
160 [AC_DEFINE(HAVE_LIBGIF,1,[Define if you have libgif/libungif including devel headers])
161 GIFLIB="-lungif"],
162 [AC_CHECK_LIB(gif,DGifOpen,
163 [AC_DEFINE(HAVE_LIBGIF,1)
164 GIFLIB="-lgif"])]))
166 AC_SUBST(XLIB)
167 AC_SUBST(XFILES)
168 XFILES=""
169 AC_SUBST(OPENGLFILES)
170 OPENGLFILES=""
171 AC_SUBST(GLU32FILES)
172 GLU32FILES=""
173 AC_SUBST(OPENGL_LIBS)
174 OPENGL_LIBS=""
175 if test "$have_x" = "yes"
176 then
177 XLIB="-lXext -lX11"
178 ac_save_CPPFLAGS="$CPPFLAGS"
179 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
181 dnl *** All of the following tests require X11/Xlib.h
182 AC_CHECK_HEADERS(X11/Xlib.h,
183 [
184 AC_CHECK_HEADERS([X11/XKBlib.h \
185 X11/Xutil.h \
186 X11/extensions/shape.h \
187 X11/extensions/XInput.h \
188 X11/extensions/XShm.h \
189 X11/extensions/Xrandr.h \
190 X11/extensions/Xrender.h \
191 X11/extensions/Xvlib.h \
192 X11/extensions/xf86dga.h \
193 X11/extensions/xf86vmode.h],,,
194 [#include <X11/Xlib.h>
195 #ifdef HAVE_X11_XUTIL_H
196 # include <X11/Xutil.h>
197 #endif])
199 dnl *** Check for X keyboard extension
200 if test "$ac_cv_header_X11_XKBlib_h" = "yes"
201 then
202 AC_CHECK_LIB(X11, XkbQueryExtension,
203 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
204 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
205 fi
207 dnl *** Check for X Shm extension
208 if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
209 then
210 AC_CHECK_LIB(Xext, XShmQueryExtension,
211 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
212 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
213 fi
215 dnl *** Check for X shape extension
216 if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
217 then
218 AC_CHECK_LIB(Xext,XShapeQueryExtension,
219 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
220 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
221 fi
223 dnl *** Check for XFree86 DGA / DGA 2.0 extension
224 if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
225 then
226 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
227 [ dnl *** If found...
228 AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
229 [Define if you have the Xxf86dga library version 2])
230 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
231 ],
232 [ dnl *** If not found, look for XF86DGAQueryExtension()
233 dnl *** instead (DGA 2.0 not found)...
234 AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
235 [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
236 [Define if you have the Xxf86dga library version 1])
237 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
238 ],,
239 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
240 )
241 ],
242 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
243 fi
245 dnl *** Check for XFree86 VMODE extension
246 if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
247 then
248 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
249 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
250 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
251 ],,
252 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
253 fi
255 dnl *** Check for X RandR extension
256 if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
257 then
258 AC_TRY_COMPILE([#include <X11/Xlib.h>
259 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
260 [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
261 fi
263 dnl *** Check for XVideo extension supporting XvImages
264 if test "$ac_cv_header_X11_extensions_Xvlib_h" = "yes"
265 then
266 AC_CHECK_LIB(Xv, XvShmCreateImage,
267 [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
268 X_PRE_LIBS="$X_PRE_LIBS -lXv"
269 ],,
270 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
271 fi
272 ]
273 ) dnl *** End of X11/Xlib.h check
275 dnl Check for the presence of OpenGL
276 if test "x$with_opengl" != "xno"
277 then
278 if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
279 then
280 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
281 This prevents linking to OpenGL. Delete the file and restart configure.])
282 fi
284 AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
285 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
286 then
287 AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
288 dnl Check for some problems due to old Mesa versions
289 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
290 AC_TRY_COMPILE(
291 [#include <GL/gl.h>],
292 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
293 [wine_cv_opengl_version_OK="yes"],
294 [wine_cv_opengl_version_OK="no"]
295 )
296 )
298 if test "$wine_cv_opengl_version_OK" = "yes"
299 then
300 dnl Check for the presence of the library
301 AC_CHECK_LIB(GL,glXCreateContext,
302 OPENGL_LIBS="-lGL"
303 ,,
304 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
306 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
307 then
308 OPENGLFILES='$(OPENGLFILES)'
309 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
311 AC_CHECK_LIB(GL,glXGetProcAddressARB,
312 AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
313 [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
314 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
316 if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
317 then
318 AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
319 [AC_TRY_COMPILE([#include <GL/gl.h>
320 #ifdef HAVE_GL_GLEXT_H
321 # include <GL/glext.h>
322 #endif
323 ],
324 [PFNGLCOLORTABLEEXTPROC test_proc;],
325 [wine_cv_extension_prototypes="yes"],
326 [wine_cv_extension_prototypes="no"]
327 )]
328 )
329 if test "$wine_cv_extension_prototypes" = "yes"
330 then
331 AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
332 [Define if the OpenGL headers define extension typedefs])
333 fi
334 fi
336 fi
337 dnl Check for GLU32 library.
338 AC_CHECK_LIB(GLU,gluLookAt,
339 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
340 GLU32FILES='$(GLU32FILES)']
341 ,,
342 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
343 )
344 fi
346 dnl Check for glut32 library.
347 AC_CHECK_LIB(glut,glutMainLoop,
348 [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
349 AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
350 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
351 fi
352 fi
354 dnl **** Check for NAS ****
355 AC_SUBST(NASLIBS,"")
356 AC_CHECK_HEADERS(audio/audiolib.h,
357 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
358 AC_CHECK_LIB(audio,AuCreateFlow,
359 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
360 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
361 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
363 CPPFLAGS="$ac_save_CPPFLAGS"
364 XFILES='$(XFILES)'
365 else
366 XLIB=""
367 X_CFLAGS=""
368 X_LIBS=""
369 fi
371 dnl **** Check which curses lib to use ***
372 CURSESLIBS=""
373 if test "x$with_curses" != "xno"
374 then
375 AC_CHECK_HEADERS(ncurses.h,
376 [AC_CHECK_LIB(ncurses,waddch,
377 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
378 CURSESLIBS="-lncurses"],
379 [AC_CHECK_HEADERS(curses.h,
380 [AC_CHECK_LIB(curses,waddch,
381 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
382 CURSESLIBS="-lcurses"])])])])
383 saved_libs="$LIBS"
384 LIBS="$CURSESLIBS $LIBS"
385 AC_CHECK_FUNCS(getbkgd resizeterm)
386 LIBS="$saved_libs"
387 fi
388 AC_SUBST(CURSESLIBS)
390 dnl **** Check for SANE ****
391 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
392 if test "$sane_devel" = "no"
393 then
394 SANELIBS=""
395 SANEINCL=""
396 else
397 SANELIBS="`$sane_devel --libs`"
398 SANEINCL="`$sane_devel --cflags`"
399 ac_save_CPPFLAGS="$CPPFLAGS"
400 ac_save_LIBS="$LIBS"
401 CPPFLAGS="$CPPFLAGS $SANEINCL"
402 LIBS="$LIBS $SANELIBS"
403 AC_CHECK_HEADER(sane/sane.h,
404 [AC_CHECK_LIB(sane,sane_open,
405 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
406 [SANELIBS=""
407 SANEINCL=""])],
408 [SANELIBS=""
409 SANEINCL=""])
410 LIBS="$ac_save_LIBS"
411 CPPFLAGS="$ac_save_CPPFLAGS"
412 fi
413 AC_SUBST(SANELIBS)
414 AC_SUBST(SANEINCL)
416 dnl **** Check for the ICU library ****
417 AC_CHECK_HEADERS(unicode/ubidi.h)
418 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
419 then
420 saved_libs="$LIBS"
421 ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
422 ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
423 ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
424 AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
425 LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
426 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
427 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
428 AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
429 AC_MSG_RESULT(yes)],
430 [AC_MSG_RESULT(no)])
431 LIBS="$saved_libs"
432 fi
434 dnl **** Check for FreeType 2 ****
435 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
436 if test "$ft_lib" = "no"
437 then
438 FREETYPEINCL=""
439 wine_cv_msg_freetype=no
440 else
441 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
442 if test "$ft_devel" = "no"
443 then
444 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
445 if test "$ft_devel2" = "freetype2-config"
446 then
447 ft_devel=$ft_devel2
448 fi
449 fi
450 if test "$ft_devel" = "no"
451 then
452 FREETYPEINCL=""
453 wine_cv_msg_freetype=yes
454 else
455 FREETYPEINCL=`$ft_devel --cflags`
456 ac_save_CPPFLAGS="$CPPFLAGS"
457 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
458 AC_CHECK_HEADERS(ft2build.h \
459 freetype/freetype.h \
460 freetype/ftglyph.h \
461 freetype/tttables.h \
462 freetype/ftnames.h \
463 freetype/ftsnames.h \
464 freetype/ttnameid.h \
465 freetype/ftoutln.h \
466 freetype/ftwinfnt.h \
467 freetype/internal/sfnt.h,,,
468 [#if HAVE_FT2BUILD_H
469 #include <ft2build.h>
470 #endif])
471 AC_TRY_CPP([#include <ft2build.h>
472 #include <freetype/fttrigon.h>],
473 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
474 [Define if you have the <freetype/fttrigon.h> header file.])
475 wine_cv_fttrigon=yes],
476 wine_cv_fttrigon=no)
477 CPPFLAGS="$ac_save_CPPFLAGS"
478 dnl Check that we have at least freetype/freetype.h
479 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
480 then
481 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
482 wine_cv_msg_freetype=no
483 else
484 FREETYPEINCL=""
485 wine_cv_msg_freetype=yes
486 fi
487 fi
488 fi
489 AC_SUBST(FREETYPEINCL)
491 dnl **** Check for parport (currently Linux only) ****
492 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
493 AC_TRY_COMPILE(
494 [#include <linux/ppdev.h>],
495 [ioctl (1,PPCLAIM,0)],
496 [ac_cv_c_ppdev="yes"],
497 [ac_cv_c_ppdev="no"])
498 )
499 if test "$ac_cv_c_ppdev" = "yes"
500 then
501 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
502 fi
504 dnl **** Check for va_copy ****
505 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
506 AC_TRY_LINK(
507 [#include <stdarg.h>],
508 [va_list ap1, ap2;
509 va_copy(ap1,ap2);
510 ],
511 [ac_cv_c_va_copy="yes"],
512 [ac_cv_c_va_copy="no"])
513 )
514 if test "$ac_cv_c_va_copy" = "yes"
515 then
516 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
517 fi
518 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
519 AC_TRY_LINK(
520 [#include <stdarg.h>],
521 [va_list ap1, ap2;
522 __va_copy(ap1,ap2);
523 ],
524 [ac_cv_c___va_copy="yes"],
525 [ac_cv_c___va_copy="no"])
526 )
527 if test "$ac_cv_c___va_copy" = "yes"
528 then
529 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
530 fi
532 dnl **** Check for sigsetjmp ****
533 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
534 AC_TRY_LINK(
535 [#include <setjmp.h>],
536 [sigjmp_buf buf;
537 sigsetjmp( buf, 1 );
538 siglongjmp( buf, 1 );],
539 [ac_cv_c_sigsetjmp="yes"],
540 [ac_cv_c_sigsetjmp="no"])
541 )
542 if test "$ac_cv_c_sigsetjmp" = "yes"
543 then
544 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
545 fi
547 dnl **** Check for pthread_rwlock_t ****
548 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
549 #include <pthread.h>])
551 dnl **** Check for pthread functions ****
552 ac_save_LIBS="$LIBS"
553 LIBS="$LIBS $LIBPTHREAD"
554 AC_CHECK_FUNCS(\
555 pthread_getattr_np \
556 pthread_get_stackaddr_np \
557 pthread_get_stacksize_np \
558 )
559 LIBS="$ac_save_LIBS"
561 dnl **** Check for Open Sound System ****
562 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
564 AC_CACHE_CHECK([for Open Sound System],
565 ac_cv_c_opensoundsystem,
566 AC_TRY_COMPILE([
567 #if defined(HAVE_SYS_SOUNDCARD_H)
568 #include <sys/soundcard.h>
569 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
570 #include <machine/soundcard.h>
571 #elif defined(HAVE_SOUNDCARD_H)
572 #include <soundcard.h>
573 #endif
574 ],[
576 /* check for one of the Open Sound System specific SNDCTL_ defines */
577 #if !defined(SNDCTL_DSP_STEREO)
578 #error No open sound system
579 #endif
580 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
582 if test "$ac_cv_c_opensoundsystem" = "yes"
583 then
584 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
585 fi
587 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
588 ac_cv_c_opensoundsystem_midi,
589 AC_TRY_COMPILE([
590 #if defined(HAVE_SYS_SOUNDCARD_H)
591 #include <sys/soundcard.h>
592 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
593 #include <machine/soundcard.h>
594 #elif defined(HAVE_SOUNDCARD_H)
595 #include <soundcard.h>
596 #endif
597 ],[
599 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
600 #if !defined(SNDCTL_SEQ_SYNC)
601 #error No open sound system MIDI interface
602 #endif
603 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
605 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
606 then
607 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
608 fi
610 dnl **** Check for aRts Sound Server ****
611 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
612 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
613 then
614 ARTSC_CFLAGS=""
615 for i in `$ARTSCCONFIG --cflags`
616 do
617 case "$i" in
618 -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
619 esac
620 done
621 ARTSC_LIBS=`$ARTSCCONFIG --libs`
622 save_CFLAGS="$CFLAGS"
623 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
624 AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
625 [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
626 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
627 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])
628 CFLAGS="$save_CFLAGS"
629 fi
631 dnl **** Check for ALSA ****
632 AC_SUBST(ALSALIBS,"")
633 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
634 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
635 then
636 AC_CHECK_LIB(asound,snd_pcm_open,
637 AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
638 ALSALIBS="-lasound")
639 fi
641 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
643 AC_SUBST(AUDIOIOLIBS,"")
644 AC_CHECK_HEADERS(libaudioio.h,
645 [AC_CHECK_LIB(audioio,AudioIOGetVersion,
646 [AUDIOIOLIBS="-laudioio"
647 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
649 dnl **** Check for capi4linux ****
651 AC_CHECK_HEADERS(capi20.h,[
652 AC_CHECK_HEADERS(linux/capi.h,[
653 AC_CHECK_LIB(capi20,capi20_register,[
654 AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
655 AC_SUBST(CAPI4LINUXLIBS,"-lcapi20")
656 ])
657 ])
658 ])
660 dnl **** Check for broken glibc mmap64 ****
662 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
663 AC_TRY_RUN([
664 #define _FILE_OFFSET_BITS 64
665 #include <stdio.h>
666 #include <unistd.h>
667 #include <fcntl.h>
668 #include <sys/mman.h>
669 #include <errno.h>
671 int main(int argc,char **argv) {
672 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
673 if (fd == -1) exit(1);
675 unlink("conftest.map");
677 write(fd,"test",4);
679 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
680 (errno == EINVAL)
681 ) {
682 exit(1);
683 }
684 close(fd);
685 fprintf(stderr,"success!\n");
686 exit(0);
687 }
689 ],
690 ac_cv_mmap64_works="yes",
691 ac_cv_mmap64_works="no",
692 ac_cv_mmap64_works="no") )
694 if test "$ac_cv_mmap64_works" = "yes"
695 then
696 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
697 fi
699 dnl **** Check for gcc specific options ****
701 AC_SUBST(EXTRACFLAGS,"")
702 if test "x${GCC}" = "xyes"
703 then
704 EXTRACFLAGS="-Wall -pipe"
706 dnl Check for strength-reduce bug
707 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
708 AC_TRY_RUN([
709 int L[[4]] = {0,1,2,3};
710 int main(void) {
711 static int Array[[3]];
712 unsigned int B = 3;
713 int i;
714 for(i=0; i<B; i++) Array[[i]] = i - 3;
715 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
716 L[[i]] = 4;
718 exit( Array[[1]] != -2 || L[[2]] != 3);
719 }],
720 ac_cv_c_gcc_strength_bug="no",
721 ac_cv_c_gcc_strength_bug="yes",
722 ac_cv_c_gcc_strength_bug="yes") )
723 if test "$ac_cv_c_gcc_strength_bug" = "yes"
724 then
725 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
726 fi
728 dnl Check for -fshort-wchar
729 AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
730 [WINE_TRY_CFLAGS([-fshort-wchar],
731 ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
732 if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
733 then
734 AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
735 fi
737 dnl Check for -mpreferred-stack-boundary
738 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
739 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
740 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
741 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
742 then
743 EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
744 fi
746 dnl Check for -fno-strict-aliasing
747 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
748 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
749 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
750 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
751 then
752 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
753 fi
755 dnl Check for -gstabs+ option
756 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
757 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
758 if test "$ac_cv_c_gcc_gstabs" = "yes"
759 then
760 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
761 fi
763 dnl Check for noisy string.h
764 saved_CFLAGS="$CFLAGS"
765 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
766 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
767 AC_TRY_COMPILE([#include <string.h>],[],
768 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
769 CFLAGS="$saved_CFLAGS"
770 if test "$ac_cv_c_string_h_warnings" = "no"
771 then
772 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
773 fi
774 fi
776 dnl **** Check how to define a function in assembly code ****
778 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
779 WINE_TRY_ASM_LINK(
780 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
781 ac_cv_asm_func_def=".def",
782 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
783 ac_cv_asm_func_def=".type @function",
784 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
785 ac_cv_asm_func_def=".type 2",
786 ac_cv_asm_func_def="unknown")])]))
788 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
789 case "$ac_cv_asm_func_def" in
790 ".def")
791 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
792 ".type @function")
793 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
794 ".type 2")
795 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
796 *)
797 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
798 esac
800 dnl **** Check for underscore on external symbols ****
802 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
803 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
804 [extern int ac_test;],
805 [if (ac_test) return 1],
806 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
808 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
809 if test "$ac_cv_c_extern_prefix" = "yes"
810 then
811 AC_DEFINE([__ASM_NAME(name)], ["_" name])
812 else
813 AC_DEFINE([__ASM_NAME(name)], [name])
814 fi
816 dnl **** Check how to do strings in assembler ****
818 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
819 WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
820 WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
821 WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
822 AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
824 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
825 [Define to the assembler keyword used to specify an ASCII string])
827 dnl **** Check for .short in assembler ****
829 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
830 WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
831 WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
832 AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
834 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
835 [Define to the assembler keyword used to specify a word value])
837 dnl **** Check for .size in assembler ****
839 AC_CACHE_CHECK([for .size in assembler], ac_cv_c_asm_size,
840 WINE_TRY_ASM_LINK([".globl _ac_test\n.size _ac_test, . - _ac_test"],,,
841 ac_cv_c_asm_size="yes",ac_cv_c_asm_size="no"))
843 if test "$ac_cv_c_asm_size" = "yes"
844 then
845 AC_DEFINE(HAVE_ASM_DOT_SIZE, 1, [Define if the assembler keyword .size is accepted])
846 fi
848 dnl **** Check for working dll ****
850 AC_SUBST(DLLEXT,"")
851 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
852 AC_SUBST(DLLIBS,"")
853 AC_SUBST(LDSHARED,"")
854 AC_SUBST(LDDLLFLAGS,"")
855 AC_SUBST(LIBEXT,"so")
856 AC_SUBST(IMPLIBEXT,"def")
858 case $host_os in
859 cygwin*|mingw32*)
860 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
861 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
862 if test "$DLLWRAP" = "false"; then
863 LIBEXT="a"
864 else
865 dnl FIXME - check whether dllwrap works correctly...
866 LIBEXT="dll"
867 fi
868 IMPLIBEXT="a"
869 ;;
870 *)
871 AC_CHECK_HEADERS(dlfcn.h,
872 [AC_CHECK_FUNCS(dlopen,,
873 [AC_CHECK_LIB(dl,dlopen,
874 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
875 DLLIBS="-ldl"],
876 [LIBEXT="a"])])],
877 [LIBEXT="a"])
879 if test "$LIBEXT" = "so"
880 then
881 DLLFLAGS="$DLLFLAGS -fPIC"
882 DLLEXT=".so"
883 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
884 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
885 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
886 if test "$ac_cv_c_dll_gnuelf" = "yes"
887 then
888 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
889 LDDLLFLAGS="-shared -Wl,-Bsymbolic"
890 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
891 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
892 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
893 if test "$ac_cv_c_dll_zdefs" = "yes"
894 then
895 LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
896 fi
898 AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
899 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
900 ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
901 if test "$ac_cv_c_dll_init_fini" = "yes"
902 then
903 LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
904 fi
906 AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
907 [echo '{ global: *; };' >conftest.map
908 WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
909 ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
910 rm -f conftest.map])
911 if test "$ac_cv_c_ld_version_scripts" = "yes"
912 then
913 LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
914 fi
916 AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
917 [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
918 ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
919 if test "$ac_cv_c_export_dynamic" = "yes"
920 then
921 AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
922 fi
924 case $host_cpu in
925 *i[[3456789]]86*)
926 AC_CACHE_CHECK([whether we can relocate the executable to 0x77f00000], ac_cv_ld_reloc_exec,
927 [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x77f00400],
928 ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
929 if test "$ac_cv_ld_reloc_exec" = "yes"
930 then
931 LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x77f00400"
932 fi
933 ;;
934 esac
936 else
937 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
938 [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
939 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
940 if test "$ac_cv_c_dll_unixware" = "yes"
941 then
942 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
943 LDDLLFLAGS="-Wl,-G,-B,symbolic"
945 else
946 AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
947 [WINE_TRY_CFLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
948 if test "$ac_cv_c_dll_macho" = "yes"
949 then
950 LIBEXT="dylib"
951 LDDLLFLAGS="-bundle -flat_namespace -undefined suppress"
952 LDSHARED="\$(CC) -dynamiclib"
953 CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
954 STRIP="$STRIP -u -r"
955 fi
956 fi
957 fi
958 fi
960 dnl Check for cross compiler to build test programs
961 AC_SUBST(CROSSTEST,"")
962 if test "$cross_compiling" = "no"
963 then
964 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
965 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
966 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
967 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
968 fi
969 ;;
970 esac
972 if test "$LIBEXT" = "a"; then
973 AC_MSG_ERROR(
974 [could not find a way to build shared libraries.
975 It is currently not possible to build Wine without shared library
976 (.so) support to allow transparent switch between .so and .dll files.
977 If you are using Linux, you will need a newer binutils.]
978 )
979 fi
981 case $build_os in
982 cygwin*|mingw32*)
983 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
984 darwin*|macosx*)
985 AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
986 *)
987 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
988 esac
990 dnl Mingw needs explicit msvcrt for linking libwine
991 case $host_os in
992 mingw32*)
993 AC_SUBST(CRTLIBS,"-lmsvcrt") ;;
994 esac
996 case $host_os in
997 linux*)
998 AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader")
999 AC_SUBST(MAIN_BINARY,"wine-glibc")
1000 ;;
1001 darwin*)
1002 AC_SUBST(WINE_BINARIES,"wine-pthread")
1003 AC_SUBST(MAIN_BINARY,"wine-pthread")
1004 ;;
1005 *)
1006 AC_SUBST(WINE_BINARIES,"wine-kthread")
1007 AC_SUBST(MAIN_BINARY,"wine-kthread")
1008 ;;
1009 esac
1011 dnl **** Get the soname for libraries that we load dynamically ****
1013 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1014 then
1015 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1016 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1017 WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1018 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1019 WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1020 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1021 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1022 WINE_GET_SONAME(cups,cupsGetDefault)
1023 WINE_GET_SONAME(jack,jack_client_new)
1024 WINE_GET_SONAME(fontconfig,FcInit)
1025 WINE_GET_SONAME(ssl,SSL_library_init)
1026 WINE_GET_SONAME(crypto,BIO_new_socket)
1027 WINE_GET_SONAME(ncurses,waddch)
1028 WINE_GET_SONAME(curses,waddch)
1029 fi
1032 dnl **** Check for functions ****
1034 AC_FUNC_ALLOCA()
1035 AC_CHECK_FUNCS(\
1036 _lwp_create \
1037 _lwp_self \
1038 _pclose \
1039 _popen \
1040 _snprintf \
1041 _spawnvp \
1042 _stricmp \
1043 _strnicmp \
1044 _vsnprintf \
1045 chsize \
1046 clone \
1047 finite \
1048 fpclass \
1049 fstatfs \
1050 fstatvfs \
1051 ftruncate \
1052 ftruncate64 \
1053 futimes \
1054 getnetbyaddr \
1055 getnetbyname \
1056 getopt_long \
1057 getpagesize \
1058 getprotobyname \
1059 getprotobynumber \
1060 getpwuid \
1061 getservbyport \
1062 gettid \
1063 gettimeofday \
1064 inet_network \
1065 lseek64 \
1066 lstat \
1067 memmove \
1068 mmap \
1069 pclose \
1070 popen \
1071 pread \
1072 pwrite \
1073 readlink \
1074 rfork \
1075 select \
1076 sendmsg \
1077 settimeofday \
1078 sigaltstack \
1079 snprintf \
1080 spawnvp \
1081 statfs \
1082 statvfs \
1083 strcasecmp \
1084 strerror \
1085 strncasecmp \
1086 tcgetattr \
1087 timegm \
1088 usleep \
1089 vfscanf \
1090 vsnprintf \
1091 wait4 \
1092 waitpid \
1093 )
1095 dnl **** Check for header files ****
1097 AC_CHECK_HEADERS(\
1098 arpa/inet.h \
1099 arpa/nameser.h \
1100 cups/cups.h \
1101 direct.h \
1102 elf.h \
1103 float.h \
1104 fontconfig/fontconfig.h \
1105 getopt.h \
1106 ieeefp.h \
1107 io.h \
1108 jack/jack.h \
1109 libio.h \
1110 libutil.h \
1111 link.h \
1112 linux/cdrom.h \
1113 linux/hdreg.h \
1114 linux/input.h \
1115 linux/ioctl.h \
1116 linux/joystick.h \
1117 linux/major.h \
1118 linux/param.h \
1119 linux/serial.h \
1120 linux/ucdrom.h \
1121 machine/cpu.h \
1122 mntent.h \
1123 netdb.h \
1124 netinet/in.h \
1125 netinet/in_systm.h \
1126 netinet/tcp.h \
1127 netinet/tcp_fsm.h \
1128 openssl/ssl.h \
1129 process.h \
1130 pthread.h \
1131 pty.h \
1132 pwd.h \
1133 regex.h \
1134 sched.h \
1135 scsi/sg.h \
1136 scsi/scsi.h \
1137 scsi/scsi_ioctl.h \
1138 socket.h \
1139 stdint.h \
1140 strings.h \
1141 sys/cdio.h \
1142 sys/elf32.h \
1143 sys/errno.h \
1144 sys/exec_elf.h \
1145 sys/file.h \
1146 sys/filio.h \
1147 sys/inttypes.h \
1148 sys/ioctl.h \
1149 sys/ipc.h \
1150 sys/link.h \
1151 sys/lwp.h \
1152 sys/mman.h \
1153 sys/modem.h \
1154 sys/msg.h \
1155 sys/param.h \
1156 sys/poll.h \
1157 sys/ptrace.h \
1158 sys/reg.h \
1159 sys/scsiio.h \
1160 sys/shm.h \
1161 sys/signal.h \
1162 sys/socket.h \
1163 sys/sockio.h \
1164 sys/statfs.h \
1165 sys/statvfs.h \
1166 sys/strtio.h \
1167 sys/syscall.h \
1168 sys/sysctl.h \
1169 sys/time.h \
1170 sys/times.h \
1171 sys/uio.h \
1172 sys/un.h \
1173 sys/v86.h \
1174 sys/v86intr.h \
1175 sys/vfs.h \
1176 sys/vm86.h \
1177 sys/wait.h \
1178 syscall.h \
1179 termios.h \
1180 unistd.h \
1181 utime.h \
1182 valgrind/memcheck.h
1183 )
1184 AC_HEADER_STAT()
1186 dnl **** Checks for headers that depend on other ones ****
1188 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1189 [#include <sys/types.h>
1190 #if HAVE_SYS_PARAM_H
1191 # include <sys/param.h>
1192 #endif])
1194 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1195 [#include <sys/types.h>
1196 #if HAVE_SYS_SOCKET_H
1197 # include <sys/socket.h>
1198 #endif])
1200 AC_CHECK_HEADERS([resolv.h],,,
1201 [#include <sys/types.h>
1202 #if HAVE_SYS_SOCKET_H
1203 # include <sys/socket.h>
1204 #endif
1205 #if HAVE_NETINET_IN_H
1206 # include <netinet/in.h>
1207 #endif
1208 #if HAVE_ARPA_NAMESER_H
1209 # include <arpa/nameser.h>
1210 #endif])
1212 AC_CHECK_HEADERS(netinet/ip.h,,,
1213 [#include <sys/types.h>
1214 #if HAVE_SYS_SOCKET_H
1215 # include <sys/socket.h>
1216 #endif
1217 #if HAVE_NETINET_IN_SYSTM_H
1218 # include <netinet/in_systm.h>
1219 #endif])
1221 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1223 dnl **** Check for IPX headers (currently Linux only) ****
1225 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1226 AC_TRY_COMPILE(
1227 [#include <sys/types.h>
1228 #ifdef HAVE_SYS_SOCKET_H
1229 # include <sys/socket.h>
1230 #endif
1231 #include <netipx/ipx.h>],
1232 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1233 [ac_cv_c_ipx_gnu="yes"],
1234 [ac_cv_c_ipx_gnu="no"])
1235 )
1236 if test "$ac_cv_c_ipx_gnu" = "yes"
1237 then
1238 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1239 fi
1241 if test "$ac_cv_c_ipx_gnu" = "no"
1242 then
1243 AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1244 AC_TRY_COMPILE(
1245 [#include <sys/types.h>
1246 #ifdef HAVE_SYS_SOCKET_H
1247 # include <sys/socket.h>
1248 #endif
1249 #include <asm/types.h>
1250 #include <linux/ipx.h>],
1251 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1252 [ac_cv_c_ipx_linux="yes"],
1253 [ac_cv_c_ipx_linux="no"])
1254 )
1255 if test "$ac_cv_c_ipx_linux" = "yes"
1256 then
1257 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1258 fi
1259 fi
1261 dnl **** Check for types ****
1263 AC_C_CONST
1264 AC_C_INLINE
1265 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1267 AC_CACHE_CHECK([whether linux/input.h is for real],
1268 wine_cv_linux_input_h,
1269 AC_TRY_COMPILE([
1270 #include <linux/input.h>
1271 ] , [
1272 int foo = EVIOCGBIT(EV_ABS,42);
1273 int bar = BTN_PINKIE;
1274 int fortytwo = 42;
1275 ],
1276 wine_cv_linux_input_h=yes,
1277 wine_cv_linux_input_h=no,
1278 no
1279 )
1280 )
1281 if test "$wine_cv_linux_input_h" = "yes"
1282 then
1283 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1284 [Define if we have linux/input.h AND it contains the INPUT event API])
1285 fi
1288 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1289 wine_cv_linux_gethostbyname_r_6,
1290 AC_TRY_LINK([
1291 #include <netdb.h>
1292 ], [
1293 char *name=NULL;
1294 struct hostent he;
1295 struct hostent *result;
1296 char *buf=NULL;
1297 int bufsize=0;
1298 int res,errnr;
1299 char *addr=NULL;
1300 int addrlen=0;
1301 int addrtype=0;
1302 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1303 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1304 ],
1305 wine_cv_linux_gethostbyname_r_6=yes,
1306 wine_cv_linux_gethostbyname_r_6=no
1307 )
1308 )
1309 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1310 then
1311 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1312 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1313 fi
1315 if test "$ac_cv_header_linux_joystick_h" = "yes"
1316 then
1317 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1318 wine_cv_linux_joystick_22_api,
1319 AC_TRY_COMPILE([
1320 #include <sys/ioctl.h>
1321 #include <linux/joystick.h>
1323 struct js_event blub;
1324 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1325 #error "no 2.2 header"
1326 #endif
1327 ],/*empty*/,
1328 wine_cv_linux_joystick_22_api=yes,
1329 wine_cv_linux_joystick_22_api=no,
1330 wine_cv_linux_joystick_22_api=no
1331 )
1332 )
1333 if test "$wine_cv_linux_joystick_22_api" = "yes"
1334 then
1335 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1336 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1337 fi
1338 fi
1340 dnl **** statfs checks ****
1342 if test "$ac_cv_header_sys_vfs_h" = "yes"
1343 then
1344 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1345 wine_cv_sys_vfs_has_statfs,
1346 AC_TRY_COMPILE([
1347 #include <sys/types.h>
1348 #ifdef HAVE_SYS_PARAM_H
1349 # include <sys/param.h>
1350 #endif
1351 #include <sys/vfs.h>
1352 ],[
1353 struct statfs stfs;
1355 memset(&stfs,0,sizeof(stfs));
1356 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1357 )
1358 )
1359 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1360 then
1361 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1362 [Define if the struct statfs is defined by <sys/vfs.h>])
1363 fi
1364 fi
1366 if test "$ac_cv_header_sys_statfs_h" = "yes"
1367 then
1368 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1369 wine_cv_sys_statfs_has_statfs,
1370 AC_TRY_COMPILE([
1371 #include <sys/types.h>
1372 #ifdef HAVE_SYS_PARAM_H
1373 # include <sys/param.h>
1374 #endif
1375 #include <sys/statfs.h>
1376 ],[
1377 struct statfs stfs;
1378 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1379 )
1380 )
1381 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1382 then
1383 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1384 [Define if the struct statfs is defined by <sys/statfs.h>])
1385 fi
1386 fi
1388 if test "$ac_cv_header_sys_mount_h" = "yes"
1389 then
1390 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1391 wine_cv_sys_mount_has_statfs,
1392 AC_TRY_COMPILE([
1393 #include <sys/types.h>
1394 #ifdef HAVE_SYS_PARAM_H
1395 # include <sys/param.h>
1396 #endif
1397 #include <sys/mount.h>
1398 ],[
1399 struct statfs stfs;
1400 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1401 )
1402 )
1403 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1404 then
1405 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1406 [Define if the struct statfs is defined by <sys/mount.h>])
1407 fi
1408 fi
1410 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1412 dnl Check for statfs members
1413 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1414 [#include <sys/types.h>
1415 #ifdef HAVE_SYS_PARAM_H
1416 # include <sys/param.h>
1417 #endif
1418 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1419 # include <sys/mount.h>
1420 #else
1421 # ifdef STATFS_DEFINED_BY_SYS_VFS
1422 # include <sys/vfs.h>
1423 # else
1424 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1425 # include <sys/statfs.h>
1426 # endif
1427 # endif
1428 #endif])
1430 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1431 [#ifdef HAVE_SYS_STATVFS_H
1432 #include <sys/statvfs.h>
1433 #endif])
1435 dnl Check for socket structure members
1436 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1437 [#include <sys/types.h>
1438 #ifdef HAVE_SYS_SOCKET_H
1439 # include <sys/socket.h>
1440 #endif
1441 #ifdef HAVE_SYS_UN_H
1442 # include <sys/un.h>
1443 #endif])
1445 dnl Check for siginfo_t members
1446 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1448 dnl Check for struct option
1449 AC_CHECK_MEMBERS([struct option.name],,,
1450 [#ifdef HAVE_GETOPT_H
1451 #include <getopt.h>
1452 #endif])
1454 dnl Check for stat.st_blocks
1455 AC_CHECK_MEMBERS([struct stat.st_blocks])
1457 dnl *** check for the need to define platform-specific symbols
1459 case $host_cpu in
1460 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1461 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1462 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1463 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1464 esac
1466 case $host_vendor in
1467 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1468 esac
1470 dnl **** Generate output files ****
1472 AH_TOP([#define __WINE_CONFIG_H])
1474 WINE_CONFIG_EXTRA_DIR(controls)
1475 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1476 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1477 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1478 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1479 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1480 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1481 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1482 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1483 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1484 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1485 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1486 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1487 WINE_CONFIG_EXTRA_DIR(include/wine)
1488 WINE_CONFIG_EXTRA_DIR(misc)
1489 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1490 WINE_CONFIG_EXTRA_DIR(windows)
1492 MAKE_RULES=Make.rules
1493 AC_SUBST_FILE(MAKE_RULES)
1495 MAKE_DLL_RULES=dlls/Makedll.rules
1496 AC_SUBST_FILE(MAKE_DLL_RULES)
1498 MAKE_TEST_RULES=dlls/Maketest.rules
1499 AC_SUBST_FILE(MAKE_TEST_RULES)
1501 MAKE_LIB_RULES=libs/Makelib.rules
1502 AC_SUBST_FILE(MAKE_LIB_RULES)
1504 MAKE_PROG_RULES=programs/Makeprog.rules
1505 AC_SUBST_FILE(MAKE_PROG_RULES)
1507 AC_CONFIG_FILES([
1508 Make.rules
1509 dlls/Makedll.rules
1510 dlls/Maketest.rules
1511 libs/Makelib.rules
1512 programs/Makeprog.rules
1513 Makefile
1514 dlls/Makefile
1515 dlls/advapi32/Makefile
1516 dlls/advapi32/tests/Makefile
1517 dlls/amstream/Makefile
1518 dlls/atl/Makefile
1519 dlls/avicap32/Makefile
1520 dlls/avifil32/Makefile
1521 dlls/cabinet/Makefile
1522 dlls/capi2032/Makefile
1523 dlls/cards/Makefile
1524 dlls/cfgmgr32/Makefile
1525 dlls/comcat/Makefile
1526 dlls/comctl32/Makefile
1527 dlls/comctl32/tests/Makefile
1528 dlls/commdlg/Makefile
1529 dlls/crtdll/Makefile
1530 dlls/crypt32/Makefile
1531 dlls/ctl3d/Makefile
1532 dlls/d3d8/Makefile
1533 dlls/d3d9/Makefile
1534 dlls/d3dim/Makefile
1535 dlls/d3drm/Makefile
1536 dlls/d3dx8/Makefile
1537 dlls/d3dxof/Makefile
1538 dlls/dbghelp/Makefile
1539 dlls/dciman32/Makefile
1540 dlls/ddraw/Makefile
1541 dlls/ddraw/tests/Makefile
1542 dlls/devenum/Makefile
1543 dlls/dinput/Makefile
1544 dlls/dinput8/Makefile
1545 dlls/dmband/Makefile
1546 dlls/dmcompos/Makefile
1547 dlls/dmime/Makefile
1548 dlls/dmloader/Makefile
1549 dlls/dmscript/Makefile
1550 dlls/dmstyle/Makefile
1551 dlls/dmsynth/Makefile
1552 dlls/dmusic/Makefile
1553 dlls/dmusic32/Makefile
1554 dlls/dplay/Makefile
1555 dlls/dplayx/Makefile
1556 dlls/dpnet/Makefile
1557 dlls/dpnhpast/Makefile
1558 dlls/dsound/Makefile
1559 dlls/dsound/tests/Makefile
1560 dlls/dswave/Makefile
1561 dlls/dxdiagn/Makefile
1562 dlls/dxerr8/Makefile
1563 dlls/dxerr9/Makefile
1564 dlls/dxguid/Makefile
1565 dlls/gdi/Makefile
1566 dlls/gdi/tests/Makefile
1567 dlls/glu32/Makefile
1568 dlls/glut32/Makefile
1569 dlls/hhctrl.ocx/Makefile
1570 dlls/iccvid/Makefile
1571 dlls/icmp/Makefile
1572 dlls/ifsmgr.vxd/Makefile
1573 dlls/imagehlp/Makefile
1574 dlls/imm32/Makefile
1575 dlls/iphlpapi/Makefile
1576 dlls/iphlpapi/tests/Makefile
1577 dlls/kernel/Makefile
1578 dlls/kernel/tests/Makefile
1579 dlls/lzexpand/Makefile
1580 dlls/mapi32/Makefile
1581 dlls/mapi32/tests/Makefile
1582 dlls/mmdevldr.vxd/Makefile
1583 dlls/monodebg.vxd/Makefile
1584 dlls/mpr/Makefile
1585 dlls/msacm/Makefile
1586 dlls/msacm/imaadp32/Makefile
1587 dlls/msacm/msadp32/Makefile
1588 dlls/msacm/msg711/Makefile
1589 dlls/msacm/winemp3/Makefile
1590 dlls/msacm/tests/Makefile
1591 dlls/msdmo/Makefile
1592 dlls/mshtml/Makefile
1593 dlls/msi/Makefile
1594 dlls/msimg32/Makefile
1595 dlls/msisys/Makefile
1596 dlls/msnet32/Makefile
1597 dlls/msrle32/Makefile
1598 dlls/msvcrt/Makefile
1599 dlls/msvcrt/tests/Makefile
1600 dlls/msvcrt20/Makefile
1601 dlls/msvcrt40/Makefile
1602 dlls/msvcrtd/Makefile
1603 dlls/msvcrtd/tests/Makefile
1604 dlls/msvidc32/Makefile
1605 dlls/msvideo/Makefile
1606 dlls/mswsock/Makefile
1607 dlls/netapi32/Makefile
1608 dlls/netapi32/tests/Makefile
1609 dlls/newdev/Makefile
1610 dlls/ntdll/Makefile
1611 dlls/ntdll/tests/Makefile
1612 dlls/odbc32/Makefile
1613 dlls/ole32/Makefile
1614 dlls/oleacc/Makefile
1615 dlls/oleaut32/Makefile
1616 dlls/oleaut32/tests/Makefile
1617 dlls/olecli/Makefile
1618 dlls/oledlg/Makefile
1619 dlls/olepro32/Makefile
1620 dlls/olesvr/Makefile
1621 dlls/opengl32/Makefile
1622 dlls/psapi/Makefile
1623 dlls/psapi/tests/Makefile
1624 dlls/qcap/Makefile
1625 dlls/quartz/Makefile
1626 dlls/rasapi32/Makefile
1627 dlls/richedit/Makefile
1628 dlls/rpcrt4/Makefile
1629 dlls/rpcrt4/tests/Makefile
1630 dlls/rsabase/Makefile
1631 dlls/secur32/Makefile
1632 dlls/serialui/Makefile
1633 dlls/setupapi/Makefile
1634 dlls/shdocvw/Makefile
1635 dlls/shell32/Makefile
1636 dlls/shell32/tests/Makefile
1637 dlls/shfolder/Makefile
1638 dlls/shlwapi/Makefile
1639 dlls/shlwapi/tests/Makefile
1640 dlls/snmpapi/Makefile
1641 dlls/sti/Makefile
1642 dlls/tapi32/Makefile
1643 dlls/ttydrv/Makefile
1644 dlls/twain/Makefile
1645 dlls/unicows/Makefile
1646 dlls/url/Makefile
1647 dlls/urlmon/Makefile
1648 dlls/urlmon/tests/Makefile
1649 dlls/user/Makefile
1650 dlls/user/tests/Makefile
1651 dlls/uuid/Makefile
1652 dlls/uxtheme/Makefile
1653 dlls/vdhcp.vxd/Makefile
1654 dlls/vdmdbg/Makefile
1655 dlls/version/Makefile
1656 dlls/version/tests/Makefile
1657 dlls/vmm.vxd/Makefile
1658 dlls/vnbt.vxd/Makefile
1659 dlls/vnetbios.vxd/Makefile
1660 dlls/vtdapi.vxd/Makefile
1661 dlls/vwin32.vxd/Makefile
1662 dlls/win32s/Makefile
1663 dlls/winaspi/Makefile
1664 dlls/wined3d/Makefile
1665 dlls/winedos/Makefile
1666 dlls/wineps/Makefile
1667 dlls/wininet/Makefile
1668 dlls/wininet/tests/Makefile
1669 dlls/winmm/Makefile
1670 dlls/winmm/joystick/Makefile
1671 dlls/winmm/mcianim/Makefile
1672 dlls/winmm/mciavi/Makefile
1673 dlls/winmm/mcicda/Makefile
1674 dlls/winmm/mciseq/Makefile
1675 dlls/winmm/mciwave/Makefile
1676 dlls/winmm/midimap/Makefile
1677 dlls/winmm/tests/Makefile
1678 dlls/winmm/wavemap/Makefile
1679 dlls/winmm/winealsa/Makefile
1680 dlls/winmm/winearts/Makefile
1681 dlls/winmm/wineaudioio/Makefile
1682 dlls/winmm/winejack/Makefile
1683 dlls/winmm/winenas/Makefile
1684 dlls/winmm/wineoss/Makefile
1685 dlls/winnls/Makefile
1686 dlls/winsock/Makefile
1687 dlls/winsock/tests/Makefile
1688 dlls/winspool/Makefile
1689 dlls/winspool/tests/Makefile
1690 dlls/wintab32/Makefile
1691 dlls/wintrust/Makefile
1692 dlls/wow32/Makefile
1693 dlls/wsock32/Makefile
1694 dlls/x11drv/Makefile
1695 documentation/Makefile
1696 include/Makefile
1697 libs/Makefile
1698 libs/port/Makefile
1699 libs/unicode/Makefile
1700 libs/wine/Makefile
1701 libs/wpp/Makefile
1702 loader/Makefile
1703 programs/Makefile
1704 programs/avitools/Makefile
1705 programs/clock/Makefile
1706 programs/cmdlgtst/Makefile
1707 programs/control/Makefile
1708 programs/expand/Makefile
1709 programs/msiexec/Makefile
1710 programs/notepad/Makefile
1711 programs/progman/Makefile
1712 programs/regedit/Makefile
1713 programs/regsvr32/Makefile
1714 programs/rpcss/Makefile
1715 programs/rundll32/Makefile
1716 programs/start/Makefile
1717 programs/taskmgr/Makefile
1718 programs/uninstaller/Makefile
1719 programs/view/Makefile
1720 programs/wcmd/Makefile
1721 programs/wineboot/Makefile
1722 programs/winebrowser/Makefile
1723 programs/winecfg/Makefile
1724 programs/wineconsole/Makefile
1725 programs/winedbg/Makefile
1726 programs/winefile/Makefile
1727 programs/winemenubuilder/Makefile
1728 programs/winemine/Makefile
1729 programs/winepath/Makefile
1730 programs/winetest/Makefile
1731 programs/winevdm/Makefile
1732 programs/winhelp/Makefile
1733 programs/winver/Makefile
1734 server/Makefile
1735 tools/Makefile
1736 tools/widl/Makefile
1737 tools/winapi/Makefile
1738 tools/winebuild/Makefile
1739 tools/winedump/Makefile
1740 tools/winegcc/Makefile
1741 tools/wmc/Makefile
1742 tools/wrc/Makefile])
1744 AC_OUTPUT
1746 if test "$have_x" = "no"
1747 then
1748 echo
1749 echo "*** Warning: X development files not found. Wine will be built without"
1750 echo "*** X support, which currently does not work, and would probably not be"
1751 echo "*** what you want anyway. You will need to install devel packages of"
1752 echo "*** Xlib/Xfree86 at the very least."
1753 fi
1755 if test "$wine_cv_opengl_version_OK" = "no"
1756 then
1757 echo
1758 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1759 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1760 fi
1762 if test "$wine_cv_msg_freetype" = "yes"
1763 then
1764 echo
1765 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1766 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1767 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1768 echo "*** enable Wine to use TrueType fonts."
1769 fi
1771 echo
1772 echo "Configure finished. Do 'make depend && make' to compile Wine."
1773 echo
1775 dnl Local Variables:
1776 dnl comment-start: "dnl "
1777 dnl comment-end: ""
1778 dnl comment-start-skip: "\\bdnl\\b\\s *"
1779 dnl compile-command: "autoconf"
1780 dnl End: