| blob | be3634c7e8f20db1976e7de41e3216ec504c98e4 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53b)
8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
18 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
20 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
21 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
24 AC_SUBST(DLLDEFS,"")
25 if test "x$enable_debug" = "xno"
26 then
27 DLLDEFS="$DLLDEFS -DWINE_NO_DEBUG_MSGS"
28 fi
29 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
30 then
31 DLLDEFS="$DLLDEFS -DWINE_NO_TRACE_MSGS"
32 fi
34 AC_CANONICAL_HOST
35 case $host in
36 x86_64*linux*)
37 if test "x$enable_win64" != "xyes"
38 then
39 test -n "$CC" || CC="gcc -m32"
40 test -n "$LD" || LD="ld -m elf_i386"
41 test -n "$AS" || AS="as --32"
42 host_cpu="i386"
43 fi
44 ;;
45 esac
47 dnl enable_win16 defaults to yes on x86, to no on other CPUs
48 case $host_cpu in
49 *i[[3456789]]86*)
50 if test "x$enable_win16" != "xno"
51 then
52 enable_win16="yes"
53 fi
54 ;;
55 esac
57 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
58 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
59 if test "x$enable_win16" != "xyes"
60 then
61 WIN16_FILES=""
62 WIN16_INSTALL=""
63 fi
65 dnl **** Check for some programs ****
67 AC_PROG_MAKE_SET
68 AC_PROG_CC
69 AC_PROG_CXX
70 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
71 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
73 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
74 [if test -z "$with_wine_tools"; then
75 if test "$cross_compiling" = "yes"; then
76 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
77 else
78 wine_cv_toolsdir="\$(TOPOBJDIR)"
79 fi
80 elif test -d "$with_wine_tools/tools/winebuild"; then
81 case $with_wine_tools in
82 /*) wine_cv_toolsdir="$with_wine_tools" ;;
83 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
84 esac
85 else
86 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
87 fi])
88 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
90 AC_PATH_XTRA
91 AC_PROG_LEX
93 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
94 dnl **** without one present.
95 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
96 if test "$XLEX" = "none"
97 then
98 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
99 fi
101 dnl Check for bison
102 AC_CHECK_PROGS(BISON,bison,none)
103 if test "$BISON" = "none"
104 then
105 AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
106 fi
108 AC_CHECK_TOOLS(AS,[gas as],as)
109 AC_CHECK_TOOL(LD,ld,ld)
110 AC_CHECK_TOOL(AR,ar,ar)
111 AC_PROG_RANLIB
112 AC_CHECK_TOOL(STRIP,strip,strip)
113 AC_CHECK_TOOL(WINDRES,windres,false)
114 AC_PROG_LN_S
115 WINE_PROG_LN
116 AC_PROG_EGREP
117 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
118 AC_PROG_INSTALL
119 dnl Prepend src dir to install path dir if it's a relative path
120 case "$INSTALL" in
121 [[\\/$]]* | ?:[[\\/]]* ) ;;
122 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
123 esac
125 dnl Check for lint
126 AC_CHECK_PROGS(LINT, lclint lint)
127 if test "$LINT" = "lint"
128 then
129 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
130 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
131 fi
132 AC_SUBST(LINT)
133 AC_SUBST(LINTFLAGS)
135 dnl Check for various programs
136 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
137 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
139 case $host_cpu in
140 *i[[3456789]]86*)
141 AC_CHECK_PROGS(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
142 ;;
143 esac
145 dnl **** Check for some libraries ****
147 dnl Check for -li386 for NetBSD and OpenBSD
148 AC_CHECK_LIB(i386,i386_set_ldt)
149 dnl Check for -lossaudio for NetBSD
150 AC_CHECK_LIB(ossaudio,_oss_ioctl)
151 dnl Check for -lnsl for Solaris
152 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
153 dnl Check for -lsocket for Solaris
154 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
155 dnl Check for -lresolv for Solaris
156 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
157 dnl Check for -lxpg4 for FreeBSD
158 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
159 dnl Check for -lpoll for Mac OS X/Darwin
160 AC_CHECK_LIB(poll,poll)
161 dnl Check for -lresolv for Mac OS X/Darwin
162 AC_CHECK_LIB(resolv,res_9_init)
163 dnl Check for -lpthread
164 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
166 AC_SUBST(XLIB,"")
167 AC_SUBST(XFILES,"")
168 AC_SUBST(OPENGLFILES,"")
169 AC_SUBST(GLU32FILES,"")
170 AC_SUBST(OPENGL_LIBS,"")
172 dnl **** Check for header files ****
174 AC_CHECK_HEADERS(\
175 IOKit/IOKitLib.h \
176 alsa/asoundlib.h \
177 arpa/inet.h \
178 arpa/nameser.h \
179 asm/types.h \
180 capi20.h \
181 cups/cups.h \
182 curses.h \
183 direct.h \
184 dlfcn.h \
185 elf.h \
186 float.h \
187 fontconfig/fontconfig.h \
188 getopt.h \
189 gif_lib.h \
190 ieeefp.h \
191 io.h \
192 jack/jack.h \
193 jpeglib.h \
194 lber.h \
195 lcms.h \
196 lcms/lcms.h \
197 ldap.h \
198 libaudioio.h \
199 link.h \
200 linux/capi.h \
201 linux/cdrom.h \
202 linux/compiler.h \
203 linux/hdreg.h \
204 linux/input.h \
205 linux/ioctl.h \
206 linux/joystick.h \
207 linux/major.h \
208 linux/param.h \
209 linux/serial.h \
210 linux/ucdrom.h \
211 mach/machine.h \
212 machine/cpu.h \
213 machine/limits.h \
214 machine/soundcard.h \
215 mntent.h \
216 ncurses.h \
217 netdb.h \
218 netinet/in.h \
219 netinet/in_systm.h \
220 netinet/tcp.h \
221 netinet/tcp_fsm.h \
222 openssl/ssl.h \
223 poll.h \
224 process.h \
225 pthread.h \
226 pwd.h \
227 regex.h \
228 sched.h \
229 scsi/scsi.h \
230 scsi/scsi_ioctl.h \
231 scsi/sg.h \
232 soundcard.h \
233 stdint.h \
234 strings.h \
235 sys/asoundlib.h \
236 sys/cdio.h \
237 sys/elf32.h \
238 sys/epoll.h \
239 sys/errno.h \
240 sys/exec_elf.h \
241 sys/filio.h \
242 sys/ioctl.h \
243 sys/ipc.h \
244 sys/limits.h \
245 sys/link.h \
246 sys/lwp.h \
247 sys/mman.h \
248 sys/modem.h \
249 sys/msg.h \
250 sys/param.h \
251 sys/poll.h \
252 sys/ptrace.h \
253 sys/reg.h \
254 sys/scsiio.h \
255 sys/shm.h \
256 sys/signal.h \
257 sys/socket.h \
258 sys/sockio.h \
259 sys/soundcard.h \
260 sys/statvfs.h \
261 sys/strtio.h \
262 sys/syscall.h \
263 sys/sysctl.h \
264 sys/time.h \
265 sys/times.h \
266 sys/uio.h \
267 sys/un.h \
268 sys/vm86.h \
269 sys/wait.h \
270 syscall.h \
271 termios.h \
272 unicode/ubidi.h \
273 unistd.h \
274 utime.h \
275 valgrind/memcheck.h
276 )
277 AC_HEADER_STAT()
279 dnl **** Check for X11 ****
281 if test "$have_x" = "yes"
282 then
283 XLIB="-lXext -lX11"
284 ac_save_CPPFLAGS="$CPPFLAGS"
285 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
287 dnl *** All of the following tests require X11/Xlib.h
288 AC_CHECK_HEADERS([X11/Xlib.h \
289 X11/XKBlib.h \
290 X11/Xutil.h \
291 X11/extensions/shape.h \
292 X11/extensions/XInput.h \
293 X11/extensions/XShm.h \
294 X11/extensions/Xrandr.h \
295 X11/extensions/Xrender.h \
296 X11/extensions/xf86dga.h \
297 X11/extensions/xf86vmode.h],,,
298 [#ifdef HAVE_X11_XLIB_H
299 # include <X11/Xlib.h>
300 #endif
301 #ifdef HAVE_X11_XUTIL_H
302 # include <X11/Xutil.h>
303 #endif])
305 dnl *** Check for X keyboard extension
306 if test "$ac_cv_header_X11_XKBlib_h" = "yes"
307 then
308 AC_CHECK_LIB(X11, XkbQueryExtension,
309 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
310 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
311 fi
313 dnl *** Check for X Shm extension
314 if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
315 then
316 AC_CHECK_LIB(Xext, XShmQueryExtension,
317 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
318 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
319 fi
321 dnl *** Check for X shape extension
322 if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
323 then
324 AC_CHECK_LIB(Xext,XShapeQueryExtension,
325 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
326 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
327 fi
329 dnl *** Check for XFree86 DGA / DGA 2.0 extension
330 if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
331 then
332 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
333 [ AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
334 [Define if you have the Xxf86dga library version 2])
335 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
336 ],,
337 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
338 fi
340 dnl *** Check for XFree86 VMODE extension
341 if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
342 then
343 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
344 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
345 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
346 ],,
347 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
348 fi
350 dnl *** Check for X RandR extension
351 if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
352 then
353 AC_TRY_COMPILE([#include <X11/Xlib.h>
354 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
355 [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
356 fi
358 dnl *** Check for Transform functions in Xrender
359 if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
360 then
361 AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
362 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
363 [Define if Xrender has the XRenderSetPictureTransform function])],,
364 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
365 fi
366 dnl *** End of X11/Xlib.h check
368 dnl Check for the presence of OpenGL
369 if test "x$with_opengl" != "xno"
370 then
371 AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h,,,
372 [#ifdef HAVE_GL_GLX_H
373 # include <GL/glx.h>
374 #endif])
375 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
376 then
377 dnl Check for some problems due to old Mesa versions
378 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
379 AC_TRY_COMPILE(
380 [#include <GL/gl.h>],
381 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
382 [wine_cv_opengl_version_OK="yes"],
383 [wine_cv_opengl_version_OK="no"]
384 )
385 )
387 if test "$wine_cv_opengl_version_OK" = "yes"
388 then
389 dnl Check for the presence of the library
390 AC_CHECK_LIB(GL,glXCreateContext,
391 OPENGL_LIBS="-lGL"
392 ,,
393 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
395 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
396 then
397 OPENGLFILES='$(OPENGLFILES)'
398 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
399 else
400 if test -f /usr/X11R6/lib/libGL.a
401 then
402 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
403 This prevents linking to OpenGL. Delete the file and restart configure.])
404 fi
405 fi
407 dnl Check for GLU32 library.
408 AC_CHECK_LIB(GLU,gluLookAt,
409 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
410 GLU32FILES='$(GLU32FILES)']
411 ,,
412 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
413 )
414 fi
416 dnl Check for glut32 library.
417 AC_CHECK_LIB(glut,glutMainLoop,
418 [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
419 AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
420 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
421 fi
422 fi
424 dnl **** Check for NAS ****
425 AC_SUBST(NASLIBS,"")
426 AC_CHECK_HEADERS(audio/audiolib.h,
427 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
428 AC_CHECK_LIB(audio,AuCreateFlow,
429 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
430 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
431 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
433 CPPFLAGS="$ac_save_CPPFLAGS"
434 XFILES='$(XFILES)'
435 else
436 XLIB=""
437 X_CFLAGS=""
438 X_LIBS=""
439 fi
441 dnl **** Check for libxml2 ****
443 AC_SUBST(XML2LIBS,"")
444 AC_SUBST(XML2INCL,"")
445 AC_SUBST(XSLTLIBS,"")
446 AC_SUBST(XSLTINCL,"")
447 if test "$PKG_CONFIG" != "false"
448 then
449 ac_save_CPPFLAGS="$CPPFLAGS"
450 ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0`"
451 ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0`"
452 CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
453 AC_CHECK_HEADERS(libxml/parser.h,
454 [AC_CHECK_LIB(xml2, xmlParseMemory,
455 [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
456 XML2LIBS="$ac_xml_libs"
457 XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
458 AC_CHECK_LIB(xml2, xmlReadMemory,
459 [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
460 ])
461 CPPFLAGS="$ac_save_CPPFLAGS"
462 ac_xslt_libs="`$PKG_CONFIG --libs libxslt`"
463 ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt`"
464 CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
465 AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
466 [AC_CHECK_LIB(xslt, xsltCompilePattern,
467 [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
468 XSLTLIBS="$ac_xslt_libs"
469 XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
470 ],,
471 [#ifdef HAVE_LIBXSLT_PATTERN_H
472 # include <libxslt/pattern.h>
473 #endif])
474 CPPFLAGS="$ac_save_CPPFLAGS"
475 fi
477 dnl **** Check which curses lib to use ***
478 CURSESLIBS=""
479 if test "x$with_curses" != "xno"
480 then
481 if test "$ac_cv_header_ncurses_h" = "yes"
482 then
483 AC_CHECK_LIB(ncurses,waddch,
484 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
485 CURSESLIBS="-lncurses"])
486 elif test "$ac_cv_header_curses_h" = "yes"
487 then
488 AC_CHECK_LIB(curses,waddch,
489 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
490 CURSESLIBS="-lcurses"])
491 fi
492 fi
493 AC_SUBST(CURSESLIBS)
495 dnl **** Check for SANE ****
496 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
497 AC_SUBST(SANELIBS,"")
498 AC_SUBST(SANEINCL,"")
499 if test "$sane_devel" != "no"
500 then
501 SANELIBS="`$sane_devel --libs`"
502 SANEINCL="`$sane_devel --cflags`"
503 ac_save_CPPFLAGS="$CPPFLAGS"
504 ac_save_LIBS="$LIBS"
505 CPPFLAGS="$CPPFLAGS $SANEINCL"
506 LIBS="$LIBS $SANELIBS"
507 AC_CHECK_HEADER(sane/sane.h,
508 [AC_CHECK_LIB(sane,sane_open,
509 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
510 [SANELIBS=""
511 SANEINCL=""])],
512 [SANELIBS=""
513 SANEINCL=""])
514 LIBS="$ac_save_LIBS"
515 CPPFLAGS="$ac_save_CPPFLAGS"
516 fi
518 dnl **** Check for the ICU library ****
519 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
520 then
521 saved_libs="$LIBS"
522 ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
523 ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
524 ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
525 AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
526 LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
527 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
528 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
529 AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
530 AC_MSG_RESULT(yes)],
531 [AC_MSG_RESULT(no)])
532 LIBS="$saved_libs"
533 fi
535 dnl **** Check for LittleCMS ***
536 AC_SUBST(LCMSLIBS,"")
537 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
538 then
539 AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
540 [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
541 LCMSLIBS="-llcms"])
542 fi
544 dnl **** Check for OpenLDAP ***
545 AC_SUBST(LDAPLIBS,"")
546 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
547 then
548 AC_CHECK_LIB(ldap_r, ldap_initialize,
549 [AC_CHECK_LIB(lber, ber_init,
550 [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
551 LDAPLIBS="-lldap_r -llber"],,
552 [$LIBPTHREAD])],,
553 [$LIBPTHREAD])
554 fi
556 dnl **** Check for FreeType 2 ****
557 AC_SUBST(FREETYPELIBS,"")
558 AC_SUBST(FREETYPEINCL,"")
559 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
560 if test "$ft_lib" = "no"
561 then
562 wine_cv_msg_freetype=no
563 else
564 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
565 if test "$ft_devel" = "no"
566 then
567 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
568 if test "$ft_devel2" = "freetype2-config"
569 then
570 ft_devel=$ft_devel2
571 fi
572 fi
573 if test "$ft_devel" = "no"
574 then
575 wine_cv_msg_freetype=yes
576 else
577 FREETYPELIBS=`$ft_devel --libs`
578 FREETYPEINCL=`$ft_devel --cflags`
579 ac_save_CPPFLAGS="$CPPFLAGS"
580 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
581 AC_CHECK_HEADERS(ft2build.h \
582 freetype/freetype.h \
583 freetype/ftglyph.h \
584 freetype/tttables.h \
585 freetype/ftnames.h \
586 freetype/ftsnames.h \
587 freetype/ttnameid.h \
588 freetype/ftoutln.h \
589 freetype/ftwinfnt.h \
590 freetype/internal/sfnt.h,,,
591 [#if HAVE_FT2BUILD_H
592 #include <ft2build.h>
593 #endif])
594 AC_TRY_CPP([#include <ft2build.h>
595 #include <freetype/fttrigon.h>],
596 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
597 [Define if you have the <freetype/fttrigon.h> header file.])
598 wine_cv_fttrigon=yes],
599 wine_cv_fttrigon=no)
600 CPPFLAGS="$ac_save_CPPFLAGS"
601 dnl Check that we have at least freetype/freetype.h
602 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
603 then
604 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
605 wine_cv_msg_freetype=no
606 else
607 FREETYPELIBS=""
608 FREETYPEINCL=""
609 wine_cv_msg_freetype=yes
610 fi
611 fi
612 fi
614 dnl Only build the fonts dir if we have both freetype and fontforge
615 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
616 then
617 AC_SUBST(FONTSSUBDIRS,"fonts")
618 fi
620 dnl **** Check for parport (currently Linux only) ****
621 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
622 AC_TRY_COMPILE(
623 [#include <linux/ppdev.h>],
624 [ioctl (1,PPCLAIM,0)],
625 [ac_cv_c_ppdev="yes"],
626 [ac_cv_c_ppdev="no"])
627 )
628 if test "$ac_cv_c_ppdev" = "yes"
629 then
630 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
631 fi
633 dnl **** Check for va_copy ****
634 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
635 AC_TRY_LINK(
636 [#include <stdarg.h>],
637 [va_list ap1, ap2;
638 va_copy(ap1,ap2);
639 ],
640 [ac_cv_c_va_copy="yes"],
641 [ac_cv_c_va_copy="no"])
642 )
643 if test "$ac_cv_c_va_copy" = "yes"
644 then
645 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
646 fi
647 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
648 AC_TRY_LINK(
649 [#include <stdarg.h>],
650 [va_list ap1, ap2;
651 __va_copy(ap1,ap2);
652 ],
653 [ac_cv_c___va_copy="yes"],
654 [ac_cv_c___va_copy="no"])
655 )
656 if test "$ac_cv_c___va_copy" = "yes"
657 then
658 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
659 fi
661 dnl **** Check for sigsetjmp ****
662 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
663 AC_TRY_LINK(
664 [#include <setjmp.h>],
665 [sigjmp_buf buf;
666 sigsetjmp( buf, 1 );
667 siglongjmp( buf, 1 );],
668 [ac_cv_c_sigsetjmp="yes"],
669 [ac_cv_c_sigsetjmp="no"])
670 )
671 if test "$ac_cv_c_sigsetjmp" = "yes"
672 then
673 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
674 fi
676 dnl **** Check for pthread_rwlock_t ****
677 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
678 #include <pthread.h>])
680 dnl **** Check for pthread functions ****
681 ac_save_LIBS="$LIBS"
682 LIBS="$LIBS $LIBPTHREAD"
683 AC_CHECK_FUNCS(\
684 pthread_getattr_np \
685 pthread_get_stackaddr_np \
686 pthread_get_stacksize_np \
687 )
688 LIBS="$ac_save_LIBS"
690 dnl **** Check for aRts Sound Server ****
691 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
692 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
693 then
694 ARTSC_CFLAGS=""
695 for i in `$ARTSCCONFIG --cflags`
696 do
697 case "$i" in
698 -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
699 esac
700 done
701 ARTSC_LIBS=`$ARTSCCONFIG --libs`
702 save_CFLAGS="$CFLAGS"
703 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
704 AC_CHECK_LIB(artsc,arts_init,
705 [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
706 [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
707 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
708 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],,
709 $ARTSC_LIBS)
710 CFLAGS="$save_CFLAGS"
711 fi
713 dnl **** Check for EsounD ****
714 AC_PATH_PROG(ESDCONFIG, esd-config)
715 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
716 then
717 ESD_CFLAGS=""
718 for i in `$ESDCONFIG --cflags`
719 do
720 case "$i" in
721 -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
722 esac
723 done
724 ESD_LIBS=`$ESDCONFIG --libs`
725 save_CFLAGS="$CFLAGS"
726 CFLAGS="$CFLAGS $ESD_CFLAGS"
727 AC_CHECK_LIB(esd,esd_open_sound,
728 [AC_SUBST(ESDLIBS, $ESD_LIBS)
729 AC_SUBST(ESDINCL, $ESD_CFLAGS)
730 AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
731 CFLAGS="$save_CFLAGS"
732 fi
734 dnl **** Check for ALSA 1.x ****
735 AC_SUBST(ALSALIBS,"")
736 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
737 then
738 AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
739 [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
740 #include <alsa/asoundlib.h>
741 #elif defined(HAVE_SYS_ASOUNDLIB_H)
742 #include <sys/asoundlib.h>
743 #endif],
744 [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
745 [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
746 ALSALIBS="-lasound"])])
747 fi
749 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
751 AC_SUBST(AUDIOIOLIBS,"")
752 if test "$ac_cv_header_libaudioio_h" = "yes"
753 then
754 AC_CHECK_LIB(audioio,AudioIOGetVersion,
755 [AUDIOIOLIBS="-laudioio"
756 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
757 fi
759 dnl **** Check for capi4linux ****
761 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
762 then
763 AC_CHECK_LIB(capi20,capi20_register,[AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])])
764 fi
766 dnl **** Check for gcc specific options ****
768 AC_SUBST(EXTRACFLAGS,"")
769 if test "x${GCC}" = "xyes"
770 then
771 EXTRACFLAGS="-Wall -pipe"
773 dnl Check for strength-reduce bug
774 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
775 AC_TRY_RUN([
776 int L[[4]] = {0,1,2,3};
777 int main(void) {
778 static int Array[[3]];
779 unsigned int B = 3;
780 int i;
781 for(i=0; i<B; i++) Array[[i]] = i - 3;
782 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
783 L[[i]] = 4;
785 exit( Array[[1]] != -2 || L[[2]] != 3);
786 }],
787 ac_cv_c_gcc_strength_bug="no",
788 ac_cv_c_gcc_strength_bug="yes",
789 ac_cv_c_gcc_strength_bug="yes") )
790 if test "$ac_cv_c_gcc_strength_bug" = "yes"
791 then
792 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
793 fi
795 dnl Check for -fshort-wchar
796 AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
797 [WINE_TRY_CFLAGS([-fshort-wchar],
798 ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
799 if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
800 then
801 AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
802 fi
804 dnl Check for -mpreferred-stack-boundary
805 case $host_cpu in
806 *i[[3456789]]86*)
807 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
808 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
809 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
810 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
811 then
812 EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
813 fi
814 ;;
815 esac
817 dnl Check for -fno-strict-aliasing
818 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
819 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
820 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
821 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
822 then
823 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
824 fi
826 dnl Check for -gstabs+ option
827 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
828 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
829 if test "$ac_cv_c_gcc_gstabs" = "yes"
830 then
831 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
832 fi
834 dnl Check for -Wdeclaration-after-statement option
835 AC_CACHE_CHECK([for gcc -Wdeclaration-after-statement support], ac_cv_c_gcc_decl_after_statement,
836 [WINE_TRY_CFLAGS([-Wdeclaration-after-statement],ac_cv_c_gcc_decl_after_statement="yes", ac_cv_c_gcc_decl_after_statement="no")])
837 if test "$ac_cv_c_gcc_decl_after_statement" = "yes"
838 then
839 EXTRACFLAGS="$EXTRACFLAGS -Wdeclaration-after-statement"
840 fi
842 dnl Check for noisy string.h
843 saved_CFLAGS="$CFLAGS"
844 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
845 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
846 AC_TRY_COMPILE([#include <string.h>],[],
847 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
848 CFLAGS="$saved_CFLAGS"
849 if test "$ac_cv_c_string_h_warnings" = "no"
850 then
851 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
852 fi
854 AC_SUBST(BUILTINFLAG,"")
855 saved_CFLAGS="$CFLAGS"
856 CFLAGS="$CFLAGS -Werror"
857 AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
858 AC_TRY_COMPILE([],
859 [int iswlower(unsigned short);],
860 [ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
861 CFLAGS="$saved_CFLAGS"
862 if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
863 then
864 BUILTINFLAG=""
865 for builtin in \
866 iswalnum iswalpha iswcntrl iswdigit iswgraph iswlower \
867 iswprint iswpunct iswspace iswupper iswxdigit towlower towupper
868 do
869 BUILTINFLAG="$BUILTINFLAG -fno-builtin-$builtin"
870 done
871 fi
872 fi
874 dnl **** Check how to define a function in assembly code ****
876 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
877 WINE_TRY_ASM_LINK(
878 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
879 ac_cv_asm_func_def=".def",
880 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
881 ac_cv_asm_func_def=".type @function",
882 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
883 ac_cv_asm_func_def=".type 2",
884 ac_cv_asm_func_def="unknown")])]))
886 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
887 case "$ac_cv_asm_func_def" in
888 ".def")
889 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
890 ".type @function")
891 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
892 ".type 2")
893 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
894 *)
895 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
896 esac
898 dnl **** Check for underscore on external symbols ****
900 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
901 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
902 [extern int ac_test;],
903 [if (ac_test) return 1],
904 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
906 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
907 if test "$ac_cv_c_extern_prefix" = "yes"
908 then
909 AC_DEFINE([__ASM_NAME(name)], ["_" name])
910 else
911 AC_DEFINE([__ASM_NAME(name)], [name])
912 fi
914 dnl **** Check for working dll ****
916 AC_SUBST(DLLEXT,"")
917 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
918 AC_SUBST(DLLIBS,"")
919 AC_SUBST(LDSHARED,"")
920 AC_SUBST(LDDLLFLAGS,"")
921 AC_SUBST(LIBEXT,"so")
922 AC_SUBST(IMPLIBEXT,"def")
924 case $host_os in
925 cygwin*|mingw32*)
926 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
927 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
928 if test "$DLLWRAP" = "false"; then
929 LIBEXT="a"
930 else
931 dnl FIXME - check whether dllwrap works correctly...
932 LIBEXT="dll"
933 fi
934 IMPLIBEXT="a"
935 dnl We can't build 16-bit NE dlls
936 WIN16_FILES=""
937 WIN16_INSTALL=""
938 ;;
939 *)
940 if test "$ac_cv_header_dlfcn_h" = "yes"
941 then
942 AC_CHECK_FUNCS(dlopen,,
943 [AC_CHECK_LIB(dl,dlopen,
944 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
945 DLLIBS="-ldl"],
946 [LIBEXT="a"])])
947 else
948 LIBEXT="a"
949 fi
951 if test "$LIBEXT" = "so"
952 then
953 DLLFLAGS="$DLLFLAGS -fPIC"
954 DLLEXT=".so"
955 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
956 [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
957 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
958 if test "$ac_cv_c_dll_gnuelf" = "yes"
959 then
960 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
961 LDDLLFLAGS="-shared -Wl,-Bsymbolic"
962 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
963 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
964 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
965 if test "$ac_cv_c_dll_zdefs" = "yes"
966 then
967 LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
968 fi
970 AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
971 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
972 ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
973 if test "$ac_cv_c_dll_init_fini" = "yes"
974 then
975 LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
976 fi
978 AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
979 [echo '{ global: *; };' >conftest.map
980 WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
981 ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
982 rm -f conftest.map])
983 if test "$ac_cv_c_ld_version_scripts" = "yes"
984 then
985 LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
986 fi
988 AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
989 [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
990 ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
991 if test "$ac_cv_c_export_dynamic" = "yes"
992 then
993 AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
994 fi
996 case $host_cpu in
997 *i[[3456789]]86*)
998 AC_CACHE_CHECK([whether we can relocate the executable to 0x7bf00000], ac_cv_ld_reloc_exec,
999 [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
1000 ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
1001 if test "$ac_cv_ld_reloc_exec" = "yes"
1002 then
1003 LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"
1004 fi
1005 ;;
1006 esac
1008 else
1009 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
1010 [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
1011 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
1012 if test "$ac_cv_c_dll_unixware" = "yes"
1013 then
1014 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
1015 LDDLLFLAGS="-Wl,-G,-B,symbolic"
1017 else
1018 AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
1019 [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
1020 if test "$ac_cv_c_dll_macho" = "yes"
1021 then
1022 LIBEXT="dylib"
1023 LDDLLFLAGS="-bundle"
1024 LDSHARED="\$(CC) -dynamiclib"
1025 STRIP="$STRIP -u -r"
1026 dnl declare needed frameworks
1027 AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1028 AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
1029 case $host_cpu in
1030 *i[[3456789]]86*)
1031 AC_SUBST(LDEXECFLAGS,"-image_base 0x7bf00000")
1032 ;;
1033 *powerpc*)
1034 CFLAGS="$CFLAGS -ffixed-r13"
1035 LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"
1036 dnl Relocate wine executable (FIXME: is this really needed?)
1037 AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
1038 AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
1039 ;;
1040 esac
1042 else
1043 AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1044 [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1045 if test "$ac_cv_c_dll_hpux" = "yes"
1046 then
1047 LIBEXT="sl"
1048 DLLEXT=".sl"
1049 LDDLLFLAGS="-shared -fPIC"
1050 LDSHARED="\$(CC) -shared"
1051 fi
1052 fi
1053 fi
1054 fi
1055 fi
1057 dnl Check for cross compiler to build test programs
1058 AC_SUBST(CROSSTEST,"")
1059 if test "$cross_compiling" = "no"
1060 then
1061 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1062 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1063 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1064 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1065 fi
1066 ;;
1067 esac
1069 if test "$LIBEXT" = "a"; then
1070 AC_MSG_ERROR(
1071 [could not find a way to build shared libraries.
1072 It is currently not possible to build Wine without shared library
1073 (.so) support to allow transparent switch between .so and .dll files.
1074 If you are using Linux, you will need a newer binutils.]
1075 )
1076 fi
1078 case $build_os in
1079 cygwin*|mingw32*)
1080 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
1081 darwin*|macosx*)
1082 AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1083 *)
1084 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1085 esac
1087 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1088 case $host_os in
1089 mingw32*)
1090 AC_SUBST(CRTLIBS,"-lmsvcrt")
1091 AC_SUBST(SOCKETLIBS,"-lws2_32")
1092 ;;
1093 esac
1095 case $host_os in
1096 linux*)
1097 case $host_cpu in
1098 *i[[3456789]]86*) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader") ;;
1099 *) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread") ;;
1100 esac
1101 AC_SUBST(MAIN_BINARY,"wine-glibc")
1102 ;;
1103 darwin*)
1104 AC_SUBST(WINE_BINARIES,"wine-pthread")
1105 AC_SUBST(MAIN_BINARY,"wine-pthread")
1106 ;;
1107 *)
1108 AC_SUBST(WINE_BINARIES,"wine-kthread")
1109 AC_SUBST(MAIN_BINARY,"wine-kthread")
1110 ;;
1111 esac
1113 dnl **** Get the soname for libraries that we load dynamically ****
1115 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1116 then
1117 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1118 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1119 WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1120 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1121 WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1122 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1123 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1124 WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1125 WINE_GET_SONAME(cups,cupsGetDefault)
1126 WINE_GET_SONAME(jack,jack_client_new)
1127 WINE_GET_SONAME(fontconfig,FcInit)
1128 WINE_GET_SONAME(ssl,SSL_library_init)
1129 WINE_GET_SONAME(crypto,BIO_new_socket)
1130 WINE_GET_SONAME(ncurses,waddch)
1131 WINE_GET_SONAME(curses,waddch)
1132 WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1133 WINE_GET_SONAME(ungif,DGifOpen)
1134 WINE_GET_SONAME(gif,DGifOpen)
1135 WINE_GET_SONAME(capi20,capi20_isinstalled)
1136 fi
1139 dnl **** Check for functions ****
1141 AC_CHECK_FUNCS(\
1142 _lwp_create \
1143 _lwp_self \
1144 _pclose \
1145 _popen \
1146 _snprintf \
1147 _spawnvp \
1148 _stricmp \
1149 _strnicmp \
1150 _vsnprintf \
1151 chsize \
1152 clone \
1153 epoll_create \
1154 ffs \
1155 finite \
1156 fork \
1157 fpclass \
1158 fstatfs \
1159 fstatvfs \
1160 ftruncate \
1161 futimes \
1162 futimesat \
1163 getaddrinfo \
1164 getnetbyname \
1165 getopt_long \
1166 getpagesize \
1167 getprotobyname \
1168 getprotobynumber \
1169 getpwuid \
1170 getservbyport \
1171 gettid \
1172 gettimeofday \
1173 getuid \
1174 inet_network \
1175 lstat \
1176 memmove \
1177 mmap \
1178 pclose \
1179 popen \
1180 pread \
1181 pwrite \
1182 readlink \
1183 rfork \
1184 sched_yield \
1185 select \
1186 sendmsg \
1187 settimeofday \
1188 sigaltstack \
1189 sigprocmask \
1190 snprintf \
1191 spawnvp \
1192 statfs \
1193 statvfs \
1194 strcasecmp \
1195 strerror \
1196 strncasecmp \
1197 tcgetattr \
1198 timegm \
1199 usleep \
1200 vsnprintf \
1201 wait4 \
1202 waitpid \
1203 )
1205 dnl **** Checks for headers that depend on other ones ****
1207 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
1208 [#include <sys/types.h>
1209 #if HAVE_SYS_PARAM_H
1210 # include <sys/param.h>
1211 #endif])
1213 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
1214 [#include <sys/types.h>
1215 #if HAVE_SYS_SOCKET_H
1216 # include <sys/socket.h>
1217 #endif])
1219 AC_CHECK_HEADERS([resolv.h],,,
1220 [#include <sys/types.h>
1221 #if HAVE_SYS_SOCKET_H
1222 # include <sys/socket.h>
1223 #endif
1224 #if HAVE_NETINET_IN_H
1225 # include <netinet/in.h>
1226 #endif
1227 #if HAVE_ARPA_NAMESER_H
1228 # include <arpa/nameser.h>
1229 #endif])
1231 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1233 AC_CHECK_HEADERS([linux/ipx.h linux/videodev.h],,,
1234 [#ifdef HAVE_SYS_TIME_H
1235 #include <sys/time.h>
1236 #endif
1237 #include <sys/types.h>
1238 #ifdef HAVE_ASM_TYPES_H
1239 #include <asm/types.h>
1240 #endif])
1242 dnl **** Check for types ****
1244 AC_C_CONST
1245 AC_C_INLINE
1246 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1247 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1248 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1250 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1251 [#ifdef HAVE_LINUX_INPUT_H
1252 #include <linux/input.h>
1253 #endif])
1255 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1256 AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1257 wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1258 if test "$wine_cv_have_sigaddset" = "yes"
1259 then
1260 AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1261 fi
1264 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1265 wine_cv_linux_gethostbyname_r_6,
1266 AC_TRY_LINK([
1267 #include <netdb.h>
1268 ], [
1269 char *name=NULL;
1270 struct hostent he;
1271 struct hostent *result;
1272 char *buf=NULL;
1273 int bufsize=0;
1274 int res,errnr;
1275 char *addr=NULL;
1276 int addrlen=0;
1277 int addrtype=0;
1278 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1279 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1280 ],
1281 wine_cv_linux_gethostbyname_r_6=yes,
1282 wine_cv_linux_gethostbyname_r_6=no
1283 )
1284 )
1285 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1286 then
1287 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1288 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1289 fi
1291 if test "$ac_cv_header_linux_joystick_h" = "yes"
1292 then
1293 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1294 wine_cv_linux_joystick_22_api,
1295 AC_TRY_COMPILE([
1296 #include <sys/ioctl.h>
1297 #include <linux/joystick.h>
1299 struct js_event blub;
1300 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1301 #error "no 2.2 header"
1302 #endif
1303 ],/*empty*/,
1304 wine_cv_linux_joystick_22_api=yes,
1305 wine_cv_linux_joystick_22_api=no,
1306 wine_cv_linux_joystick_22_api=no
1307 )
1308 )
1309 if test "$wine_cv_linux_joystick_22_api" = "yes"
1310 then
1311 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1312 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1313 fi
1314 fi
1316 dnl **** statfs checks ****
1318 if test "$ac_cv_header_sys_vfs_h" = "yes"
1319 then
1320 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1321 wine_cv_sys_vfs_has_statfs,
1322 AC_TRY_COMPILE([
1323 #include <sys/types.h>
1324 #ifdef HAVE_SYS_PARAM_H
1325 # include <sys/param.h>
1326 #endif
1327 #include <sys/vfs.h>
1328 ],[
1329 struct statfs stfs;
1331 memset(&stfs,0,sizeof(stfs));
1332 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1333 )
1334 )
1335 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1336 then
1337 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1338 [Define if the struct statfs is defined by <sys/vfs.h>])
1339 fi
1340 fi
1342 if test "$ac_cv_header_sys_statfs_h" = "yes"
1343 then
1344 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1345 wine_cv_sys_statfs_has_statfs,
1346 AC_TRY_COMPILE([
1347 #include <sys/types.h>
1348 #ifdef HAVE_SYS_PARAM_H
1349 # include <sys/param.h>
1350 #endif
1351 #include <sys/statfs.h>
1352 ],[
1353 struct statfs stfs;
1354 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1355 )
1356 )
1357 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1358 then
1359 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1360 [Define if the struct statfs is defined by <sys/statfs.h>])
1361 fi
1362 fi
1364 if test "$ac_cv_header_sys_mount_h" = "yes"
1365 then
1366 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1367 wine_cv_sys_mount_has_statfs,
1368 AC_TRY_COMPILE([
1369 #include <sys/types.h>
1370 #ifdef HAVE_SYS_PARAM_H
1371 # include <sys/param.h>
1372 #endif
1373 #include <sys/mount.h>
1374 ],[
1375 struct statfs stfs;
1376 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1377 )
1378 )
1379 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1380 then
1381 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1382 [Define if the struct statfs is defined by <sys/mount.h>])
1383 fi
1384 fi
1386 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1388 dnl Check for statfs members
1389 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1390 [#include <sys/types.h>
1391 #ifdef HAVE_SYS_PARAM_H
1392 # include <sys/param.h>
1393 #endif
1394 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1395 # include <sys/mount.h>
1396 #else
1397 # ifdef STATFS_DEFINED_BY_SYS_VFS
1398 # include <sys/vfs.h>
1399 # else
1400 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1401 # include <sys/statfs.h>
1402 # endif
1403 # endif
1404 #endif])
1406 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1407 [#ifdef HAVE_SYS_STATVFS_H
1408 #include <sys/statvfs.h>
1409 #endif])
1411 dnl Check for socket structure members
1412 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1413 [#include <sys/types.h>
1414 #ifdef HAVE_SYS_SOCKET_H
1415 # include <sys/socket.h>
1416 #endif
1417 #ifdef HAVE_SYS_UN_H
1418 # include <sys/un.h>
1419 #endif])
1421 dnl Check for scsireq_t and sg_io_hdr_t members
1422 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1423 [#include <sys/types.h>
1424 #ifdef HAVE_SCSI_SG_H
1425 #include <scsi/sg.h>
1426 #endif])
1428 dnl Check for siginfo_t members
1429 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1431 dnl Check for struct option
1432 AC_CHECK_MEMBERS([struct option.name],,,
1433 [#ifdef HAVE_GETOPT_H
1434 #include <getopt.h>
1435 #endif])
1437 dnl Check for stat.st_blocks
1438 AC_CHECK_MEMBERS([struct stat.st_blocks])
1440 dnl Check for the external timezone variables timezone and daylight
1441 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1442 AC_TRY_LINK([#include <time.h>],[timezone;],
1443 ac_cv_have_timezone="yes", ac_cv_have_timezone="no"))
1444 if test "$ac_cv_have_timezone" = "yes"
1445 then
1446 AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1447 fi
1448 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1449 AC_TRY_LINK([#include <time.h>],[daylight;],
1450 ac_cv_have_daylight="yes", ac_cv_have_daylight="no"))
1451 if test "$ac_cv_have_daylight" = "yes"
1452 then
1453 AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1454 fi
1456 dnl *** check for the need to define platform-specific symbols
1458 case $host_cpu in
1459 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1460 *x86_64*) WINE_CHECK_DEFINE([__x86_64__]) ;;
1461 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1462 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1463 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1464 esac
1466 case $host_vendor in
1467 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1468 esac
1470 dnl **** Generate output files ****
1472 AH_TOP([#define __WINE_CONFIG_H])
1474 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1475 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1476 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1477 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1478 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1479 WINE_CONFIG_EXTRA_DIR(include/wine)
1481 MAKE_RULES=Make.rules
1482 AC_SUBST_FILE(MAKE_RULES)
1484 MAKE_DLL_RULES=dlls/Makedll.rules
1485 AC_SUBST_FILE(MAKE_DLL_RULES)
1487 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1488 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1490 MAKE_TEST_RULES=dlls/Maketest.rules
1491 AC_SUBST_FILE(MAKE_TEST_RULES)
1493 MAKE_LIB_RULES=libs/Makelib.rules
1494 AC_SUBST_FILE(MAKE_LIB_RULES)
1496 MAKE_PROG_RULES=programs/Makeprog.rules
1497 AC_SUBST_FILE(MAKE_PROG_RULES)
1499 AC_CONFIG_FILES([
1500 Make.rules
1501 dlls/Makedll.rules
1502 dlls/Makeimplib.rules
1503 dlls/Maketest.rules
1504 libs/Makelib.rules
1505 programs/Makeprog.rules
1506 Makefile
1507 dlls/Makefile
1508 dlls/activeds/Makefile
1509 dlls/advapi32/Makefile
1510 dlls/advapi32/tests/Makefile
1511 dlls/advpack/Makefile
1512 dlls/advpack/tests/Makefile
1513 dlls/amstream/Makefile
1514 dlls/atl/Makefile
1515 dlls/avicap32/Makefile
1516 dlls/avifil32/Makefile
1517 dlls/cabinet/Makefile
1518 dlls/capi2032/Makefile
1519 dlls/cards/Makefile
1520 dlls/cfgmgr32/Makefile
1521 dlls/comcat/Makefile
1522 dlls/comctl32/Makefile
1523 dlls/comctl32/tests/Makefile
1524 dlls/commdlg/Makefile
1525 dlls/crtdll/Makefile
1526 dlls/crypt32/Makefile
1527 dlls/crypt32/tests/Makefile
1528 dlls/cryptdll/Makefile
1529 dlls/ctl3d/Makefile
1530 dlls/d3d8/Makefile
1531 dlls/d3d9/Makefile
1532 dlls/d3dim/Makefile
1533 dlls/d3drm/Makefile
1534 dlls/d3dx8/Makefile
1535 dlls/d3dxof/Makefile
1536 dlls/dbghelp/Makefile
1537 dlls/dciman32/Makefile
1538 dlls/ddraw/Makefile
1539 dlls/ddraw/tests/Makefile
1540 dlls/devenum/Makefile
1541 dlls/dinput/Makefile
1542 dlls/dinput/tests/Makefile
1543 dlls/dinput8/Makefile
1544 dlls/dmband/Makefile
1545 dlls/dmcompos/Makefile
1546 dlls/dmime/Makefile
1547 dlls/dmloader/Makefile
1548 dlls/dmscript/Makefile
1549 dlls/dmstyle/Makefile
1550 dlls/dmsynth/Makefile
1551 dlls/dmusic/Makefile
1552 dlls/dmusic32/Makefile
1553 dlls/dplay/Makefile
1554 dlls/dplayx/Makefile
1555 dlls/dpnet/Makefile
1556 dlls/dpnhpast/Makefile
1557 dlls/dsound/Makefile
1558 dlls/dsound/tests/Makefile
1559 dlls/dswave/Makefile
1560 dlls/dxdiagn/Makefile
1561 dlls/dxerr8/Makefile
1562 dlls/dxerr9/Makefile
1563 dlls/dxguid/Makefile
1564 dlls/gdi/Makefile
1565 dlls/gdi/tests/Makefile
1566 dlls/glu32/Makefile
1567 dlls/glut32/Makefile
1568 dlls/hhctrl.ocx/Makefile
1569 dlls/iccvid/Makefile
1570 dlls/icmp/Makefile
1571 dlls/ifsmgr.vxd/Makefile
1572 dlls/imagehlp/Makefile
1573 dlls/imm32/Makefile
1574 dlls/iphlpapi/Makefile
1575 dlls/iphlpapi/tests/Makefile
1576 dlls/itss/Makefile
1577 dlls/kernel/Makefile
1578 dlls/kernel/tests/Makefile
1579 dlls/lzexpand/Makefile
1580 dlls/lzexpand/tests/Makefile
1581 dlls/mapi32/Makefile
1582 dlls/mapi32/tests/Makefile
1583 dlls/mciavi32/Makefile
1584 dlls/mcicda/Makefile
1585 dlls/mciseq/Makefile
1586 dlls/midimap/Makefile
1587 dlls/mlang/Makefile
1588 dlls/mlang/tests/Makefile
1589 dlls/mmdevldr.vxd/Makefile
1590 dlls/monodebg.vxd/Makefile
1591 dlls/mpr/Makefile
1592 dlls/msacm/Makefile
1593 dlls/msacm/imaadp32/Makefile
1594 dlls/msacm/msadp32/Makefile
1595 dlls/msacm/msg711/Makefile
1596 dlls/msacm/tests/Makefile
1597 dlls/msacm/winemp3/Makefile
1598 dlls/mscms/Makefile
1599 dlls/mscms/tests/Makefile
1600 dlls/msdmo/Makefile
1601 dlls/mshtml/Makefile
1602 dlls/mshtml/tests/Makefile
1603 dlls/msi/Makefile
1604 dlls/msi/tests/Makefile
1605 dlls/msimg32/Makefile
1606 dlls/msisys/Makefile
1607 dlls/msnet32/Makefile
1608 dlls/msrle32/Makefile
1609 dlls/msvcrt/Makefile
1610 dlls/msvcrt/tests/Makefile
1611 dlls/msvcrt20/Makefile
1612 dlls/msvcrt40/Makefile
1613 dlls/msvcrtd/Makefile
1614 dlls/msvcrtd/tests/Makefile
1615 dlls/msvidc32/Makefile
1616 dlls/msvideo/Makefile
1617 dlls/mswsock/Makefile
1618 dlls/msxml3/Makefile
1619 dlls/msxml3/tests/Makefile
1620 dlls/netapi32/Makefile
1621 dlls/netapi32/tests/Makefile
1622 dlls/newdev/Makefile
1623 dlls/ntdll/Makefile
1624 dlls/ntdll/tests/Makefile
1625 dlls/objsel/Makefile
1626 dlls/odbc32/Makefile
1627 dlls/odbccp32/Makefile
1628 dlls/ole32/Makefile
1629 dlls/ole32/tests/Makefile
1630 dlls/oleacc/Makefile
1631 dlls/oleaut32/Makefile
1632 dlls/oleaut32/tests/Makefile
1633 dlls/olecli/Makefile
1634 dlls/oledlg/Makefile
1635 dlls/olepro32/Makefile
1636 dlls/olesvr/Makefile
1637 dlls/opengl32/Makefile
1638 dlls/powrprof/Makefile
1639 dlls/psapi/Makefile
1640 dlls/psapi/tests/Makefile
1641 dlls/qcap/Makefile
1642 dlls/quartz/Makefile
1643 dlls/quartz/tests/Makefile
1644 dlls/rasapi32/Makefile
1645 dlls/riched20/Makefile
1646 dlls/richedit/Makefile
1647 dlls/rpcrt4/Makefile
1648 dlls/rpcrt4/tests/Makefile
1649 dlls/rsabase/Makefile
1650 dlls/rsabase/tests/Makefile
1651 dlls/rsaenh/Makefile
1652 dlls/rsaenh/tests/Makefile
1653 dlls/secur32/Makefile
1654 dlls/secur32/tests/Makefile
1655 dlls/sensapi/Makefile
1656 dlls/serialui/Makefile
1657 dlls/setupapi/Makefile
1658 dlls/setupapi/tests/Makefile
1659 dlls/shdocvw/Makefile
1660 dlls/shdocvw/tests/Makefile
1661 dlls/shell32/Makefile
1662 dlls/shell32/tests/Makefile
1663 dlls/shfolder/Makefile
1664 dlls/shlwapi/Makefile
1665 dlls/shlwapi/tests/Makefile
1666 dlls/snmpapi/Makefile
1667 dlls/stdole2.tlb/Makefile
1668 dlls/stdole32.tlb/Makefile
1669 dlls/sti/Makefile
1670 dlls/strmiids/Makefile
1671 dlls/tapi32/Makefile
1672 dlls/twain/Makefile
1673 dlls/unicows/Makefile
1674 dlls/url/Makefile
1675 dlls/urlmon/Makefile
1676 dlls/urlmon/tests/Makefile
1677 dlls/user/Makefile
1678 dlls/user/tests/Makefile
1679 dlls/usp10/Makefile
1680 dlls/uuid/Makefile
1681 dlls/uxtheme/Makefile
1682 dlls/vdhcp.vxd/Makefile
1683 dlls/vdmdbg/Makefile
1684 dlls/version/Makefile
1685 dlls/version/tests/Makefile
1686 dlls/vmm.vxd/Makefile
1687 dlls/vnbt.vxd/Makefile
1688 dlls/vnetbios.vxd/Makefile
1689 dlls/vtdapi.vxd/Makefile
1690 dlls/vwin32.vxd/Makefile
1691 dlls/win32s/Makefile
1692 dlls/winaspi/Makefile
1693 dlls/winecrt0/Makefile
1694 dlls/wined3d/Makefile
1695 dlls/winedos/Makefile
1696 dlls/wineps/Makefile
1697 dlls/wininet/Makefile
1698 dlls/wininet/tests/Makefile
1699 dlls/winmm/Makefile
1700 dlls/winmm/joystick/Makefile
1701 dlls/winmm/mciwave/Makefile
1702 dlls/winmm/tests/Makefile
1703 dlls/winmm/wavemap/Makefile
1704 dlls/winmm/winealsa/Makefile
1705 dlls/winmm/winearts/Makefile
1706 dlls/winmm/wineaudioio/Makefile
1707 dlls/winmm/wineesd/Makefile
1708 dlls/winmm/winejack/Makefile
1709 dlls/winmm/winenas/Makefile
1710 dlls/winmm/wineoss/Makefile
1711 dlls/winnls/Makefile
1712 dlls/winsock/Makefile
1713 dlls/winsock/tests/Makefile
1714 dlls/winspool/Makefile
1715 dlls/winspool/tests/Makefile
1716 dlls/wintab32/Makefile
1717 dlls/wintrust/Makefile
1718 dlls/wldap32/Makefile
1719 dlls/wow32/Makefile
1720 dlls/wsock32/Makefile
1721 dlls/wtsapi32/Makefile
1722 dlls/x11drv/Makefile
1723 documentation/Makefile
1724 fonts/Makefile
1725 include/Makefile
1726 libs/Makefile
1727 libs/port/Makefile
1728 libs/unicode/Makefile
1729 libs/wine/Makefile
1730 libs/wpp/Makefile
1731 loader/Makefile
1732 programs/Makefile
1733 programs/avitools/Makefile
1734 programs/clock/Makefile
1735 programs/cmdlgtst/Makefile
1736 programs/control/Makefile
1737 programs/eject/Makefile
1738 programs/expand/Makefile
1739 programs/explorer/Makefile
1740 programs/hh/Makefile
1741 programs/msiexec/Makefile
1742 programs/notepad/Makefile
1743 programs/progman/Makefile
1744 programs/regedit/Makefile
1745 programs/regsvr32/Makefile
1746 programs/rpcss/Makefile
1747 programs/rundll32/Makefile
1748 programs/start/Makefile
1749 programs/taskmgr/Makefile
1750 programs/uninstaller/Makefile
1751 programs/view/Makefile
1752 programs/wcmd/Makefile
1753 programs/wineboot/Makefile
1754 programs/winebrowser/Makefile
1755 programs/winecfg/Makefile
1756 programs/wineconsole/Makefile
1757 programs/winedbg/Makefile
1758 programs/winefile/Makefile
1759 programs/winemenubuilder/Makefile
1760 programs/winemine/Makefile
1761 programs/winepath/Makefile
1762 programs/winetest/Makefile
1763 programs/winevdm/Makefile
1764 programs/winhelp/Makefile
1765 programs/winver/Makefile
1766 server/Makefile
1767 tools/Makefile
1768 tools/widl/Makefile
1769 tools/winapi/Makefile
1770 tools/winebuild/Makefile
1771 tools/winedump/Makefile
1772 tools/winegcc/Makefile
1773 tools/wmc/Makefile
1774 tools/wrc/Makefile])
1776 AC_OUTPUT
1778 if test "$have_x" = "no"
1779 then
1780 echo
1781 echo "*** Warning: X development files not found. Wine will be built without"
1782 echo "*** X support, which currently does not work, and would probably not be"
1783 echo "*** what you want anyway. You will need to install devel packages of"
1784 echo "*** Xlib/Xfree86 at the very least."
1785 fi
1787 if test "$wine_cv_opengl_version_OK" = "no"
1788 then
1789 echo
1790 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1791 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1792 fi
1794 if test "$wine_cv_msg_freetype" = "yes"
1795 then
1796 echo
1797 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1798 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1799 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1800 echo "*** enable Wine to use TrueType fonts."
1801 fi
1803 if test -z "$ALSALIBS" -a \
1804 -z "$ARTSC_LIBS" -a \
1805 -z "$AUDIOIOLIBS" -a \
1806 -z "$NASLIBS" -a \
1807 -z "$ESD_LIBS" -a \
1808 -z "$ac_cv_lib_soname_jack" -a \
1809 "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1810 "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1811 "$ac_cv_header_soundcard_h" != "yes"
1812 then
1813 echo "*** No sound system was found. Windows applications will be silent."
1814 echo "*** The currently supported sound systems are:"
1815 echo "*** ALSA, ARTS, EsounD, AudioIO, Jack, NAS and OSS"
1816 fi
1818 echo
1819 echo "Configure finished. Do '${ac_make} depend && ${ac_make}' to compile Wine."
1820 echo
1822 dnl Local Variables:
1823 dnl comment-start: "dnl "
1824 dnl comment-end: ""
1825 dnl comment-start-skip: "\\bdnl\\b\\s *"
1826 dnl compile-command: "autoconf"
1827 dnl End: