configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 dnl **** Command-line arguments ****
  10
  11 dnl Default values
  12 LIBEXT=so       # library type .so or .a
  13 TRACE_MSGS=yes  # the TRACE() macro
  14 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  15 CURSES=yes
  16 OPENGL=normal
  17
  18 AC_ARG_ENABLE(debug,
  19 [  --disable-debug         compile out all debugging messages],
  20 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  21
  22 AC_ARG_ENABLE(opengl,
  23 [  --enable-opengl         force usage of OpenGL even if the latter is thread-safe],
  24 [if test "$enableval" = "no"; then OPENGL="no"; elif test "$enableval" = "yes"; then OPENGL="yes"; fi])
  25
  26 AC_ARG_ENABLE(trace,
  27 [  --disable-trace         compile out TRACE messages],
  28 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  29
  30 AC_ARG_WITH(curses,
  31 [  --without-curses        do not use curses],
  32 [if test "$withval" = "no"; then CURSES="no"; fi])
  33
  34 AC_ARG_WITH(reentrant-x,
  35 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  36
  37 AC_SUBST(OPTIONS)
  38
  39 if test "$DEBUG_MSGS" = "no"
  40 then
  41     AC_DEFINE(NO_DEBUG_MSGS)
  42     AC_DEFINE(NO_TRACE_MSGS)
  43 else
  44     if test "$TRACE_MSGS" = "no"
  45     then
  46         AC_DEFINE(NO_TRACE_MSGS)
  47     fi
  48 fi
  49
  50 dnl **** Check for some programs ****
  51
  52 AC_PROG_MAKE_SET
  53 AC_PROG_CC
  54 AC_PROG_CPP
  55 AC_PATH_XTRA
  56 AC_PROG_YACC
  57 AC_PROG_LEX
  58 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  59 if test "$XLEX" = "none"
  60 then
  61         echo "*** Error: No suitable lex found. ***"
  62         echo "    Please install the 'flex' package."
  63         exit 1
  64 fi
  65 AC_DECL_YYTEXT
  66 AC_PROG_RANLIB
  67 AC_PROG_INSTALL
  68 AC_PROG_LN_S
  69 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
  70 AC_PATH_PROG(LDCONFIG, ldconfig, true, /sbin:/usr/sbin:$PATH)
  71 AC_CYGWIN
  72
  73 dnl Check for lint
  74 AC_CHECK_PROGS(LINT, lclint lint)
  75 if test "$LINT" = "lint"
  76 then
  77   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
  78   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
  79 fi
  80 AC_SUBST(LINT)
  81 AC_SUBST(LINTFLAGS)
  82
  83 if test "$CYGWIN" = "yes"
  84 then
  85     LDCOMBINE="ld -r --enable-stdcall-fixup"
  86 else
  87     LDCOMBINE="ld -r"
  88 fi
  89 AC_SUBST(LDCOMBINE)
  90
  91 dnl **** Check for some libraries ****
  92
  93 dnl Check for -lm for BeOS
  94 AC_CHECK_LIB(m,sqrt)
  95 dnl Check for -li386 for NetBSD and OpenBSD
  96 AC_CHECK_LIB(i386,i386_set_ldt)
  97 dnl Check for -lossaudio for NetBSD
  98 AC_CHECK_LIB(ossaudio,_oss_ioctl)
  99 dnl Check for -lw for Solaris
 100 AC_CHECK_LIB(w,iswalnum)
 101 dnl Check for -lnsl for Solaris
 102 AC_CHECK_FUNCS(gethostbyname,, AC_CHECK_LIB(nsl, gethostbyname, X_EXTRA_LIBS="$X_EXTRA_LIBS -lnsl", AC_CHECK_LIB(socket, gethostbyname, X_EXTRA_LIBS="$X_EXTRA_LIBS -lnsl", , -lnsl), -lsocket))
 103 dnl Check for -lsocket for Solaris
 104 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 105 dnl Check for -lxpg4 for FreeBSD
 106 AC_CHECK_LIB(xpg4,setrunelocale)
 107 dnl Check for -lmmap for OS/2
 108 AC_CHECK_LIB(mmap,mmap)
 109 dnl Check for openpty
 110 AC_CHECK_FUNCS(openpty,,
 111         AC_CHECK_LIB(util,openpty,
 112                 AC_DEFINE(HAVE_OPENPTY)
 113                 LIBS="$LIBS -lutil"
 114         ))
 115
 116 AC_CHECK_HEADERS(dlfcn.h,
 117         AC_CHECK_FUNCS(dlopen,
 118                 AC_DEFINE(HAVE_DL_API),
 119                 AC_CHECK_LIB(dl,dlopen,
 120                         AC_DEFINE(HAVE_DL_API)
 121                         LIBS="$LIBS -ldl",
 122                         LIBEXT="a"
 123                 )
 124         ),
 125         LIBEXT="a"
 126 )
 127 AC_SUBST(XLIB)
 128 AC_SUBST(X_DLLS)
 129 X_DLLS=""
 130 AC_SUBST(XFILES)
 131 XFILES=""
 132 AC_SUBST(OPENGLFILES)
 133 OPENGLFILES=""
 134 AC_SUBST(OPENGL32_DLL)
 135 OPENGL32_DLL=""
 136 AC_SUBST(DGA_SRCS)
 137 DGA_SRCS=""
 138 AC_SUBST(DGA2_SRCS)
 139 DGA2_SRCS=""
 140 AC_SUBST(MESA_SRCS)
 141 MESA_SRCS=""
 142 if test "$have_x" = "yes"
 143 then
 144     XLIB="-lXext -lX11"
 145     ac_save_CPPFLAGS="$CPPFLAGS"
 146     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 147
 148     dnl *** Check for -lXpm
 149     AC_CHECK_HEADERS(X11/xpm.h,
 150       [ dnl *** If X11/xpm.h exists...
 151         AC_CHECK_LIB(Xpm, XpmCreatePixmapFromData,
 152           [ AC_DEFINE(HAVE_LIBXXPM) X_PRE_LIBS="$X_PRE_LIBS -lXpm"],,
 153           $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 154         )
 155       ],
 156       [ dnl *** If X11/xpm.h does not exist...
 157         dnl NOTE: autoconf does not allow commas inside the third
 158         dnl       parameter to AC_CHECK_HEADERS, due to some quoting
 159         dnl       magic it does.
 160         echo "Redhat            :       xpm xpm-devel"
 161         echo "Caldera OpenLinux :       xpm xpm-devel xpm-devel-static"
 162         echo "SuSE              :       xpm"
 163         echo "Debian/Corel Linux:       xpm4g xpm4g-dev"
 164         echo
 165         echo "Or get the sources from ftp.x.org and all its mirror sites from "
 166         echo "the directory /contrib/libraries."
 167         echo
 168         exit 1
 169       ]
 170     )
 171
 172     dnl *** All three of the following tests require X11/Xlib.h
 173     AC_CHECK_HEADERS(X11/Xlib.h,
 174       [
 175         dnl *** Check for X Shm extension
 176         AC_CHECK_HEADERS(X11/extensions/XShm.h,
 177             [ dnl *** If X11/extensions/XShm.h exists...
 178               AC_CHECK_LIB(Xext, XShmQueryExtension,
 179               AC_DEFINE(HAVE_LIBXXSHM),,
 180               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 181             ],
 182             AC_MSG_WARN([Xshm extension not found!!])
 183         )
 184
 185         dnl *** Check for X shape extension
 186         AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/shape.h,
 187             [ dnl *** If X11/extensions/shape.h exists...
 188               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 189               AC_DEFINE(HAVE_LIBXSHAPE),,
 190               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 191             ],
 192             AC_MSG_WARN([XShape extension found!!])
 193         )
 194
 195         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 196         AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
 197             [ dnl *** If X11/extensions/xf86dga.h exists, check
 198               dnl *** for XDGAQueryExtension()...
 199               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 200                 [ dnl *** If found...
 201                   AC_DEFINE(HAVE_LIBXXF86DGA2)
 202                   AC_DEFINE(HAVE_LIBXXF86DGA)
 203                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 204                   DGA_SRCS='$(DGA_SRCS)'
 205                   DGA2_SRCS='$(DGA2_SRCS)'
 206                ],
 207                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 208                   dnl *** instead (DGA 2.0 not found)...
 209                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 210                     [ AC_DEFINE(HAVE_LIBXXF86DGA)
 211                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 212                       DGA_SRCS='$(DGA_SRCS)'
 213                     ],,
 214                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 215                   )
 216                 ],
 217                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 218               )
 219             ],
 220             AC_MSG_WARN([DGA extension not found!!])
 221         )
 222
 223         dnl *** Check for XFree86 VMODE extension
 224         AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
 225             [ dnl *** If X11/extensions/xf86vmode.h exists...
 226                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 227                   [ AC_DEFINE(HAVE_LIBXXF86VM)
 228                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 229                   ],,
 230                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 231                 )
 232             ],
 233             AC_MSG_WARN([XFree86 VMODE extension not found!!])
 234         )
 235
 236         dnl *** Check for XVideo extension supporting XvImages
 237         AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
 238             [ dnl *** If X11/extensions/Xvlib.h exists...
 239                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 240                   [ AC_DEFINE(HAVE_XVIDEO)
 241                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 242                   ],,
 243                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 244                 )
 245             ],
 246             AC_MSG_WARN([XVideo extension not found !!])
 247         )
 248
 249       ]
 250     ) dnl *** End of X11/Xlib.h check
 251
 252     dnl Check for the presence of OpenGL
 253     if test $OPENGL = "yes" -o $OPENGL = "normal"
 254     then
 255         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h)
 256         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 257         then
 258             dnl Check for some problems due to old Mesa versions
 259             AC_CACHE_CHECK("for up-to-date OpenGL version", wine_cv_opengl_version_OK,
 260               AC_TRY_COMPILE(
 261                 [#include <GL/gl.h>],
 262                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 263                 [wine_cv_opengl_version_OK="yes"],
 264                 [wine_cv_opengl_version_OK="no"]
 265               )
 266             )
 267
 268             dnl Check for the thread-safety of the OpenGL library
 269             AC_CACHE_CHECK("for thread-safe OpenGL version",
 270                            wine_cv_opengl_version_threadsafe,
 271               [saved_libs=$LIBS
 272                LIBS="$X_LIBS -lGL"
 273                AC_TRY_LINK([],[pthread_getspecific();],
 274                               [wine_cv_opengl_version_threadsafe="yes"],
 275                               [wine_cv_opengl_version_threadsafe="no"])
 276                LIBS=$saved_libs]
 277             )
 278
 279             if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o $OPENGL = "yes" \)
 280             then
 281                 dnl Check for the presence of the library
 282                 AC_CHECK_LIB(GL,glXCreateContext,
 283                              X_PRE_LIBS="$X_PRE_LIBS -lGL"
 284                              MESA_SRCS='$(MESA_SRCS)'
 285                              ,,
 286                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 287
 288                 if test $ac_cv_lib_GL_glXCreateContext = "yes"
 289                 then
 290
 291                         OPENGLFILES='$(OPENGLFILES)'
 292                         AC_DEFINE(HAVE_OPENGL)
 293
 294                         AC_CHECK_LIB(GL,glXGetProcAddressARB,AC_DEFINE(HAVE_GLX_GETPROCADDRESS),,$X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 295
 296                         if test $ac_cv_lib_GL_glXGetProcAddressARB = "yes"
 297                         then
 298                                AC_CACHE_CHECK("for OpenGL extension functions prototypes", wine_cv_extension_prototypes,
 299                                   AC_TRY_COMPILE([#include <GL/gl.h>
 300                                                   #ifdef HAVE_GL_GLEXT_H
 301                                                   # include <GL/glext.h>
 302                                                   #endif
 303                                                   ],
 304                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 305                                                  [wine_cv_extension_prototypes="yes"],
 306                                                  [wine_cv_extension_prototypes="no"]
 307                                   )
 308                                 )
 309                                 if test $wine_cv_extension_prototypes = "yes"
 310                                 then
 311                                         AC_DEFINE(HAVE_GLEXT_PROTOTYPES)
 312                                 fi
 313
 314                                 OPENGL32_DLL=opengl32
 315                         fi
 316                 fi
 317              fi
 318          fi
 319     fi
 320
 321     CPPFLAGS="$ac_save_CPPFLAGS"
 322     X_DLLS='$(X_DLLS)'
 323     XFILES='$(XFILES)'
 324 else
 325     XLIB=""
 326     X_CFLAGS=""
 327     X_LIBS=""
 328 fi
 329
 330 dnl **** Check which curses lib to use ***
 331 if test "$CURSES" = "yes"
 332 then
 333     AC_CHECK_HEADERS(ncurses.h)
 334     if test "$ac_cv_header_ncurses_h" = "yes"
 335     then
 336         AC_CHECK_LIB(ncurses,waddch)
 337     fi
 338     if test "$ac_cv_lib_ncurses_waddch" = "yes"
 339     then
 340         AC_CHECK_LIB(ncurses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 341         AC_CHECK_LIB(ncurses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 342     else
 343         AC_CHECK_HEADERS(curses.h)
 344         if test "$ac_cv_header_curses_h" = "yes"
 345         then
 346             AC_CHECK_LIB(curses,waddch)
 347             if test "$ac_cv_lib_curses_waddch" = "yes"
 348             then
 349                 AC_CHECK_LIB(curses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 350                 AC_CHECK_LIB(curses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 351             fi
 352         fi
 353     fi
 354 fi
 355
 356 dnl **** Check for IPX (currently Linux only) ****
 357 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
 358  AC_TRY_COMPILE(
 359    [#include <sys/socket.h>
 360     #include <netipx/ipx.h>],
 361    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 362    [ac_cv_c_ipx_gnu="yes"],
 363    [ac_cv_c_ipx_gnu="no"])
 364  )
 365 if test "$ac_cv_c_ipx_gnu" = "yes"
 366 then
 367     AC_DEFINE(HAVE_IPX_GNU)
 368 fi
 369
 370 if test "$ac_cv_c_ipx_gnu" = "no"
 371 then
 372  AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
 373   AC_TRY_COMPILE(
 374     [#include <sys/socket.h>
 375      #include <asm/types.h>
 376      #include <linux/ipx.h>],
 377     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 378     [ac_cv_c_ipx_linux="yes"],
 379     [ac_cv_c_ipx_linux="no"])
 380   )
 381   if test "$ac_cv_c_ipx_linux" = "yes"
 382   then
 383       AC_DEFINE(HAVE_IPX_LINUX)
 384   fi
 385 fi
 386
 387 dnl **** Check for Open Sound System ****
 388 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 389
 390 AC_CACHE_CHECK("for Open Sound System",
 391         ac_cv_c_opensoundsystem,
 392         AC_TRY_COMPILE([
 393         #if defined(HAVE_SYS_SOUNDCARD_H)
 394                 #include <sys/soundcard.h>
 395         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 396                 #include <machine/soundcard.h>
 397         #elif defined(HAVE_SOUNDCARD_H)
 398                 #include <soundcard.h>
 399         #endif
 400         ],[
 401
 402 /* check for one of the Open Sound System specific SNDCTL_ defines */
 403 #if !defined(SNDCTL_DSP_STEREO)
 404 #error No open sound system
 405 #endif
 406 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 407
 408 if test "$ac_cv_c_opensoundsystem" = "yes"
 409 then
 410     AC_DEFINE(HAVE_OSS)
 411 fi
 412
 413 AC_CACHE_CHECK("for Open Sound System/MIDI interface",
 414         ac_cv_c_opensoundsystem_midi,
 415         AC_TRY_COMPILE([
 416         #if defined(HAVE_SYS_SOUNDCARD_H)
 417                 #include <sys/soundcard.h>
 418         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 419                 #include <machine/soundcard.h>
 420         #elif defined(HAVE_SOUNDCARD_H)
 421                 #include <soundcard.h>
 422         #endif
 423         ],[
 424
 425 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 426 #if !defined(SNDCTL_SEQ_SYNC)
 427 #error No open sound system MIDI interface
 428 #endif
 429 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 430
 431 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 432 then
 433     AC_DEFINE(HAVE_OSS_MIDI)
 434 fi
 435
 436 dnl **** If ln -s doesn't work, use cp instead ****
 437 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 438
 439 dnl **** Check for gcc strength-reduce bug ****
 440
 441 if test "x${GCC}" = "xyes"
 442 then
 443   CFLAGS="$CFLAGS -Wall"
 444   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
 445                   AC_TRY_RUN([
 446 int     L[[4]] = {0,1,2,3};
 447 int main(void) {
 448   static int Array[[3]];
 449   unsigned int B = 3;
 450   int i;
 451   for(i=0; i<B; i++) Array[[i]] = i - 3;
 452   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 453   L[[i]] = 4;
 454
 455   exit( Array[[1]] != -2 || L[[2]] != 3);
 456 }],
 457     ac_cv_c_gcc_strength_bug="no",
 458     ac_cv_c_gcc_strength_bug="yes",
 459     ac_cv_c_gcc_strength_bug="yes") )
 460   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 461   then
 462     CFLAGS="$CFLAGS -fno-strength-reduce"
 463   fi
 464 fi
 465
 466 dnl **** Check if we need to place .type inside a .def directive ****
 467
 468 AC_CACHE_CHECK("whether .type must sit inside a .def directive",
 469                ac_cv_c_type_in_def,
 470 [saved_libs=$LIBS
 471 LIBS="conftest_asm.s $LIBS"
 472 cat > conftest_asm.s <<EOF
 473         .globl _ac_test
 474         .def _ac_test; .scl 2; .type 32; .endef
 475 _ac_test:
 476         .long 0
 477 EOF
 478 AC_TRY_LINK(,,ac_cv_c_type_in_def="yes",ac_cv_c_type_in_def="no")
 479 LIBS=$saved_libs])
 480 if test "$ac_cv_c_type_in_def" = "yes"
 481 then
 482   AC_DEFINE(NEED_TYPE_IN_DEF)
 483 fi
 484
 485 dnl **** Check for underscore on external symbols ****
 486
 487 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
 488                ac_cv_c_extern_prefix,
 489 [saved_libs=$LIBS
 490 LIBS="conftest_asm.s $LIBS"
 491 cat > conftest_asm.s <<EOF
 492         .globl _ac_test
 493 _ac_test:
 494         .long 0
 495 EOF
 496 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 497             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 498 LIBS=$saved_libs])
 499 if test "$ac_cv_c_extern_prefix" = "yes"
 500 then
 501   AC_DEFINE(NEED_UNDERSCORE_PREFIX)
 502 fi
 503
 504 dnl **** Check for .string in assembler ****
 505
 506 AC_CACHE_CHECK("whether assembler accepts .string",
 507                ac_cv_c_asm_string,
 508 [saved_libs=$LIBS
 509 LIBS="conftest_asm.s $LIBS"
 510 cat > conftest_asm.s <<EOF
 511         .string "test"
 512 EOF
 513 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 514 LIBS=$saved_libs])
 515 if test "$ac_cv_c_asm_string" = "yes"
 516 then
 517   AC_DEFINE(HAVE_ASM_STRING)
 518 fi
 519
 520 dnl **** Check for working dll ****
 521
 522 LDSHARED=""
 523 LDDLLFLAGS=""
 524 if test "$LIBEXT" = "so"
 525 then
 526   AC_CACHE_CHECK("whether we can build a Linux dll",
 527                  ac_cv_c_dll_linux,
 528   [saved_cflags=$CFLAGS
 529   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic"
 530   AC_TRY_LINK(,[return 1],ac_cv_c_dll_linux="yes",ac_cv_c_dll_linux="no")
 531   CFLAGS=$saved_cflags
 532   ])
 533   if test "$ac_cv_c_dll_linux" = "yes"
 534   then
 535     LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%) -Wl,-rpath,\$(libdir)"
 536     LDDLLFLAGS="-Wl,-Bsymbolic"
 537   else
 538     AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll,
 539                  ac_cv_c_dll_unixware,
 540     [saved_cflags=$CFLAGS
 541     CFLAGS="$CFLAGS -fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic"
 542     AC_TRY_LINK(,[return 1],ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")
 543     CFLAGS=$saved_cflags
 544     ])
 545     if test "$ac_cv_c_dll_unixware" = "yes"
 546     then
 547       LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,h,\$(libdir)/%)"
 548       LDDLLFLAGS="-Wl,-B,symbolic"
 549     else
 550       AC_CACHE_CHECK("whether we can build a NetBSD dll",
 551                    ac_cv_c_dll_netbsd,
 552       [saved_cflags=$CFLAGS
 553       CFLAGS="$CFLAGS -fPIC -Wl,-Bshareable,-Bforcearchive"
 554       AC_TRY_LINK(,[return 1],ac_cv_c_dll_netbsd="yes",ac_cv_c_dll_netbsd="no")
 555       CFLAGS=$saved_cflags
 556       ])
 557       if test "$ac_cv_c_dll_netbsd" = "yes"
 558       then
 559         LDSHARED="\$(CC) -Wl,-Bshareable,-Bforcearchive"
 560         LDDLLFLAGS="" #FIXME
 561       fi
 562     fi
 563   fi
 564   if test "$ac_cv_c_dll_linux" = "no" -a "$ac_cv_c_dll_unixware" = "no" -a "$ac_cv_c_dll_netbsd" = "no"
 565   then
 566     echo "*** It is currently not possible to build WINE without shared"
 567     echo "*** library (.so) support to allow transparent switch between .so"
 568     echo "*** and .dll files."
 569     echo "*** If you are using Linux, you will need a newer binutils."
 570     exit 1
 571   fi
 572 fi
 573
 574 DLLFLAGS=""
 575
 576 if test "$LIBEXT" = "so"; then
 577     DLLFLAGS="-fPIC"
 578     DLL_LINK="-L\$(DLLDIR) \$(IMPORTS:%=-l%) \$(LIBWINE) \$(LIBUNICODE)"
 579 else
 580     DLL_LINK="-L\$(DLLDIR) \$(DLLS:%=-l%) \$(LIBWINE) \$(LIBUNICODE) \$(X_LIBS) \$(XLIB)"
 581     AC_CACHE_CHECK([whether the linker supports --[[no]]-whole-archive (Linux)],
 582                    ac_cv_c_whole_archive,
 583             [saved_cflags=$CFLAGS
 584             CFLAGS="$CFLAGS -Wl,--whole-archive -Wl,--no-whole-archive"
 585             AC_TRY_LINK(,[return 1],ac_cv_c_whole_archive="yes",ac_cv_c_whole_archive="no")
 586             CFLAGS=$saved_cflags
 587             ])
 588     if test "$ac_cv_c_whole_archive" = "yes"
 589     then
 590         DLL_LINK="-Wl,--whole-archive $DLL_LINK -Wl,--no-whole-archive"
 591     else
 592         AC_CACHE_CHECK([whether the linker supports -z {all,default}extract (Linux)],
 593                        ac_cv_c_allextract,
 594                 [saved_cflags=$CFLAGS
 595                 CFLAGS="$CFLAGS -Wl,-z,allextract -Wl,-z,defaultextract"
 596                 AC_TRY_LINK(,[return 1],ac_cv_c_allextract="yes",ac_cv_c_allextract="no")
 597                 CFLAGS=$saved_cflags
 598                 ])
 599         if test "$ac_cv_c_allextract" = "yes"
 600         then
 601             DLL_LINK="-Wl,-z,allextract $DLL_LINK -Wl,-z,defaultextract"
 602         fi
 603     fi
 604 fi
 605
 606 AC_SUBST(DLL_LINK)
 607 AC_SUBST(DLLFLAGS)
 608 AC_SUBST(LDSHARED)
 609 AC_SUBST(LDDLLFLAGS)
 610 AC_SUBST(LIBEXT)
 611
 612 dnl **** Check for reentrant libc ****
 613 dnl
 614 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 615 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 616
 617 wine_cv_libc_reentrant=no
 618 dnl
 619 dnl Linux style errno location
 620 dnl
 621 AC_CACHE_CHECK("for reentrant libc: __errno_location", wine_cv_libc_r__errno_location,
 622   [AC_TRY_RUN([int myerrno = 0;
 623 char buf[256];
 624 int *__errno_location(){return &myerrno;}
 625 main(){connect(0,buf,255); exit(!myerrno);}],
 626   wine_cv_libc_r__errno_location=yes, wine_cv_libc_r__errno_location=no,
 627   wine_cv_libc_r__errno_location=yes )
 628 ])
 629 if test "$wine_cv_libc_r__errno_location" = "yes"
 630 then
 631     AC_DEFINE(HAVE__ERRNO_LOCATION)
 632     wine_cv_libc_reentrant=__errno_location
 633 fi
 634 dnl
 635 dnl FreeBSD style errno location
 636 dnl
 637 AC_CACHE_CHECK("for reentrant libc: __error", wine_cv_libc_r__error,
 638   [AC_TRY_RUN([int myerrno = 0;
 639 char buf[256];
 640 int *__error(){return &myerrno;}
 641 main(){connect(0,buf,255); exit(!myerrno);}],
 642     wine_cv_libc_r__error=yes, wine_cv_libc_r__error=no,
 643     wine_cv_libc_r__error=yes )
 644 ])
 645 if test "$wine_cv_libc_r__error" = "yes"
 646 then
 647     AC_DEFINE(HAVE__ERROR)
 648     wine_cv_libc_reentrant=__error
 649 fi
 650 dnl
 651 dnl Solaris style errno location
 652 dnl
 653 AC_CACHE_CHECK("for reentrant libc: ___errno", wine_cv_libc_r___errno,
 654   [AC_TRY_RUN([int myerrno = 0;
 655 char buf[256];
 656 int *___errno(){return &myerrno;}
 657 main(){connect(0,buf,255); exit(!myerrno);}],
 658     wine_cv_libc_r___errno=yes, wine_cv_libc_r___errno=no,
 659     wine_cv_libc_r___errno=yes )
 660 ])
 661 if test "$wine_cv_libc_r___errno" = "yes"
 662 then
 663     AC_DEFINE(HAVE___ERRNO)
 664     wine_cv_libc_reentrant=___errno
 665 fi
 666 dnl
 667 dnl UnixWare style errno location
 668 dnl
 669 AC_CACHE_CHECK("for reentrant libc: __thr_errno", wine_cv_libc_r__thr_errno,
 670   [AC_TRY_RUN([int myerrno = 0;
 671 char buf[256];
 672 int *__thr_errno(){return &myerrno;}
 673 main(){connect(0,buf,255); exit(!myerrno);}],
 674     wine_cv_libc_r__thr_errno=yes, wine_cv_libc_r__thr_errno=no,
 675     wine_cv_libc_r__thr_errno=yes )
 676 ])
 677 if test "$wine_cv_libc_r__thr_errno" = "yes"
 678 then
 679     AC_DEFINE(HAVE__THR_ERRNO)
 680     wine_cv_libc_reentrant=__thr_errno
 681 fi
 682 if test "$wine_cv_libc_reentrant" = "no"
 683 then
 684   AC_DEFINE(NO_REENTRANT_LIBC)
 685 fi
 686
 687 dnl **** Check for reentrant X libraries ****
 688 dnl
 689 dnl This may fail to determine whether X libraries are reentrant if
 690 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 691 dnl is possible with the --without-reentrant-x option.
 692
 693 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
 694 then
 695 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
 696   [ if test "x$with_reentrant_x" = "xno"
 697     then
 698         wine_cv_x_reentrant=no
 699     else
 700         libX11_check=none
 701         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 702             if test -r $dir/libX11.so; then
 703                 libX11_check="-D $dir/libX11.so"
 704                 break 1
 705             fi
 706             if test -r $dir/libX11.a; then
 707                 libX11_check="$dir/libX11.a"
 708                 break 1
 709             fi
 710         done
 711         if test "$libX11_check" != "none"; then
 712             if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
 713             then
 714                 wine_cv_x_reentrant=yes
 715             else
 716                 wine_cv_x_reentrant=no
 717             fi
 718         else
 719             wine_cv_x_reentrant=unknown
 720         fi
 721     fi ] )
 722 else
 723     wine_cv_x_reentrant=no
 724 fi
 725 if test "$wine_cv_x_reentrant" = "no"
 726 then
 727   AC_DEFINE(NO_REENTRANT_X11)
 728 fi
 729
 730 dnl **** Check for endianness ****
 731
 732 AC_C_BIGENDIAN
 733
 734 dnl **** Check for functions ****
 735
 736 AC_FUNC_ALLOCA()
 737 AC_CHECK_FUNCS(\
 738         __libc_fork \
 739         _lwp_create \
 740         clone \
 741         finite \
 742         fpclass \
 743         getnetbyaddr \
 744         getnetbyname \
 745         getpagesize \
 746         getprotobyname \
 747         getprotobynumber \
 748         getrlimit \
 749         getservbyport \
 750         getsockopt \
 751         inet_network \
 752         lstat \
 753         memmove \
 754         mmap \
 755         rfork \
 756         select \
 757         sendmsg \
 758         settimeofday \
 759         sigaltstack \
 760         statfs \
 761         strcasecmp \
 762         strerror \
 763         strncasecmp \
 764         tcgetattr \
 765         timegm \
 766         usleep \
 767         vfscanf \
 768         wait4 \
 769         waitpid \
 770 )
 771
 772 dnl **** Check for header files ****
 773
 774 AC_CHECK_HEADERS(\
 775         arpa/inet.h \
 776         arpa/nameser.h \
 777         elf.h \
 778         float.h \
 779         libio.h \
 780         libutil.h \
 781         link.h \
 782         linux/cdrom.h \
 783         linux/joystick.h \
 784         linux/ucdrom.h \
 785         net/if.h \
 786         netdb.h \
 787         netinet/in.h \
 788         netinet/in_systm.h \
 789         netinet/ip.h \
 790         netinet/tcp.h \
 791         pty.h \
 792         resolv.h \
 793         sched.h \
 794         socket.h \
 795         strings.h \
 796         sys/cdio.h \
 797         sys/errno.h \
 798         sys/file.h \
 799         sys/filio.h \
 800         sys/ipc.h \
 801         sys/lwp.h \
 802         sys/mman.h \
 803         sys/modem.h \
 804         sys/mount.h \
 805         sys/msg.h \
 806         sys/param.h \
 807         sys/ptrace.h \
 808         sys/reg.h \
 809         sys/signal.h \
 810         sys/shm.h \
 811         sys/socket.h \
 812         sys/sockio.h \
 813         sys/statfs.h \
 814         sys/strtio.h \
 815         sys/syscall.h \
 816         sys/user.h \
 817         sys/wait.h \
 818         sys/v86.h \
 819         sys/v86intr.h \
 820         sys/vfs.h \
 821         sys/vm86.h \
 822         syscall.h \
 823         ucontext.h \
 824 )
 825 AC_HEADER_STAT()
 826
 827 dnl **** Check for types ****
 828
 829 AC_C_CONST()
 830 AC_C_INLINE()
 831 AC_TYPE_SIZE_T()
 832 AC_CHECK_SIZEOF(long long,0)
 833
 834
 835 AC_CACHE_CHECK("whether we can use re-entrant gethostbyname_r Linux style",
 836         wine_cv_linux_gethostbyname_r_6,
 837         AC_TRY_COMPILE([
 838 #include <netdb.h>
 839         ], [
 840     char *name=NULL;
 841     struct hostent he;
 842     struct hostent *result;
 843     char *buf=NULL;
 844     int bufsize=0;
 845     int res,errnr;
 846     char *addr=NULL;
 847     int addrlen=0;
 848     int addrtype=0;
 849     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
 850     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
 851     ],
 852         wine_cv_linux_gethostbyname_r_6=yes,
 853         wine_cv_linux_gethostbyname_r_6=no
 854         )
 855    )
 856    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
 857    then
 858       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6)
 859    fi
 860
 861 if test "$ac_cv_header_linux_joystick_h" = "yes"
 862 then
 863    AC_CACHE_CHECK("whether linux/joystick.h uses the Linux 2.2+ API",
 864         wine_cv_linux_joystick_22_api,
 865         AC_TRY_COMPILE([
 866         #include <sys/ioctl.h>
 867         #include <linux/joystick.h>
 868
 869         struct js_event blub;
 870         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
 871         #error "no 2.2 header"
 872         #endif
 873         ],/*empty*/,
 874         wine_cv_linux_joystick_22_api=yes,
 875         wine_cv_linux_joystick_22_api=no,
 876         wine_cv_linux_joystick_22_api=no
 877         )
 878    )
 879    if test "$wine_cv_linux_joystick_22_api" = "yes"
 880    then
 881       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API)
 882    fi
 883 fi
 884
 885 dnl **** statfs checks ****
 886
 887 if test "$ac_cv_header_sys_vfs_h" = "yes"
 888 then
 889     AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
 890                     wine_cv_sys_vfs_has_statfs,
 891         AC_TRY_COMPILE([
 892         #include <sys/types.h>
 893         #ifdef HAVE_SYS_PARAM_H
 894         # include <sys/param.h>
 895         #endif
 896         #include <sys/vfs.h>
 897         ],[
 898                 struct statfs stfs;
 899
 900                 memset(&stfs,0,sizeof(stfs));
 901         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
 902         )
 903     )
 904     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
 905     then
 906       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS)
 907     fi
 908 fi
 909
 910 if test "$ac_cv_header_sys_statfs_h" = "yes"
 911 then
 912     AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
 913                     wine_cv_sys_statfs_has_statfs,
 914         AC_TRY_COMPILE([
 915         #include <sys/types.h>
 916         #ifdef HAVE_SYS_PARAM_H
 917         # include <sys/param.h>
 918         #endif
 919         #include <sys/statfs.h>
 920         ],[
 921                 struct statfs stfs;
 922         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
 923         )
 924     )
 925     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
 926     then
 927       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS)
 928     fi
 929 fi
 930
 931 if test "$ac_cv_header_sys_mount_h" = "yes"
 932 then
 933     AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
 934                     wine_cv_sys_mount_has_statfs,
 935         AC_TRY_COMPILE([
 936         #include <sys/types.h>
 937         #ifdef HAVE_SYS_PARAM_H
 938         # include <sys/param.h>
 939         #endif
 940         #include <sys/mount.h>
 941         ],[
 942                 struct statfs stfs;
 943         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
 944         )
 945     )
 946     if test "$wine_cv_sys_mount_has_statfs" = "yes"
 947     then
 948       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT)
 949     fi
 950 fi
 951
 952 dnl **** FIXME: what about mixed cases, where we need two of them? ***
 953
 954 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
 955   [ if test "x$statfs_bfree" = "xno"
 956     then
 957         wine_cv_statfs_bfree=no
 958     else
 959         AC_TRY_COMPILE([
 960         #include <sys/types.h>
 961         #ifdef HAVE_SYS_PARAM_H
 962         # include <sys/param.h>
 963         #endif
 964         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 965         # include <sys/mount.h>
 966         #else
 967         # ifdef STATFS_DEFINED_BY_SYS_VFS
 968         #  include <sys/vfs.h>
 969         # else
 970         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 971         #   include <sys/statfs.h>
 972         #  endif
 973         # endif
 974         #endif
 975         ],[
 976                 struct statfs stfs;
 977
 978                 stfs.f_bfree++;
 979         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
 980         )
 981     fi ] )
 982 if test "$wine_cv_statfs_bfree" = "yes"
 983 then
 984   AC_DEFINE(STATFS_HAS_BFREE)
 985 fi
 986
 987 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
 988   [ if test "x$statfs_bavail" = "xno"
 989     then
 990         wine_cv_statfs_bavail=no
 991     else
 992         AC_TRY_COMPILE([
 993         #include <sys/types.h>
 994         #ifdef HAVE_SYS_PARAM_H
 995         # include <sys/param.h>
 996         #endif
 997         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 998         # include <sys/mount.h>
 999         #else
1000         # ifdef STATFS_DEFINED_BY_SYS_VFS
1001         #  include <sys/vfs.h>
1002         # else
1003         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1004         #   include <sys/statfs.h>
1005         #  endif
1006         # endif
1007         #endif
1008         ],[
1009                 struct statfs stfs;
1010
1011                 stfs.f_bavail++;
1012         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
1013         )
1014     fi ] )
1015 if test "$wine_cv_statfs_bavail" = "yes"
1016 then
1017   AC_DEFINE(STATFS_HAS_BAVAIL)
1018 fi
1019
1020 dnl *** check for file descriptor passing with msg_accrights
1021
1022 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
1023  AC_TRY_COMPILE([#include <sys/types.h>
1024 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
1025                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
1026 if test "$ac_cv_c_msg_accrights" = "yes"
1027 then
1028     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS)
1029 fi
1030
1031 dnl *** Check for the sun_len member in struct sockaddr_un
1032
1033 AC_CACHE_CHECK("for sun_len in struct sockaddr_un", ac_cv_c_sun_len,
1034  AC_TRY_COMPILE([#include <sys/types.h>
1035 #include <sys/socket.h>
1036 #include <sys/un.h>], [static struct sockaddr_un addr; addr.sun_len = 1],
1037                 ac_cv_c_sun_len="yes", ac_cv_c_sun_len="no"))
1038 if test "$ac_cv_c_sun_len" = "yes"
1039 then
1040     AC_DEFINE(HAVE_SOCKADDR_SUN_LEN)
1041 fi
1042
1043 dnl *** check for the need to define __i386__
1044
1045 AC_CACHE_CHECK("whether we need to define __i386__",ac_cv_cpp_def_i386,
1046  AC_EGREP_CPP(yes,[#if (defined(i386) || defined(__i386)) && !defined(__i386__)
1047 yes
1048 #endif],
1049  ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
1050 if test "$ac_cv_cpp_def_i386" = "yes"
1051 then
1052     CFLAGS="$CFLAGS -D__i386__"
1053     LINTFLAGS="$LINTFLAGS -D__i386__"
1054 fi
1055
1056 dnl $GCC is set by autoconf
1057 GCC_NO_BUILTIN=""
1058 if test "$GCC" = "yes"
1059 then
1060     GCC_NO_BUILTIN="-fno-builtin"
1061 fi
1062 AC_SUBST(GCC_NO_BUILTIN)
1063
1064 dnl **** Generate output files ****
1065
1066 AC_OUTPUT_COMMANDS([
1067 extra_subdirs="\
1068 dlls/ddraw/d3ddevice \
1069 dlls/ddraw/dclipper \
1070 dlls/ddraw/ddraw \
1071 dlls/ddraw/direct3d \
1072 dlls/ddraw/dpalette \
1073 dlls/ddraw/dsurface \
1074 dlls/dinput/joystick \
1075 dlls/dinput/keyboard \
1076 dlls/dinput/mouse \
1077 dlls/kernel/messages \
1078 dlls/user/resources \
1079 "
1080 for i in $extra_subdirs; do [ -d $i ] || (echo "creating $i" && mkdir $i); done ])
1081
1082 MAKE_RULES=Make.rules
1083 AC_SUBST_FILE(MAKE_RULES)
1084
1085 MAKE_DLL_RULES=dlls/Makedll.rules
1086 AC_SUBST_FILE(MAKE_DLL_RULES)
1087
1088 MAKE_PROG_RULES=programs/Makeprog.rules
1089 AC_SUBST_FILE(MAKE_PROG_RULES)
1090
1091 AC_OUTPUT([
1092 Make.rules
1093 dlls/Makedll.rules
1094 programs/Makeprog.rules
1095 Makefile
1096 console/Makefile
1097 controls/Makefile
1098 debugger/Makefile
1099 dlls/Makefile
1100 dlls/advapi32/Makefile
1101 dlls/avifil32/Makefile
1102 dlls/comctl32/Makefile
1103 dlls/commdlg/Makefile
1104 dlls/crtdll/Makefile
1105 dlls/dciman32/Makefile
1106 dlls/ddraw/Makefile
1107 dlls/dinput/Makefile
1108 dlls/dplay/Makefile
1109 dlls/dplayx/Makefile
1110 dlls/dsound/Makefile
1111 dlls/gdi/Makefile
1112 dlls/icmp/Makefile
1113 dlls/imagehlp/Makefile
1114 dlls/imm32/Makefile
1115 dlls/kernel/Makefile
1116 dlls/lzexpand/Makefile
1117 dlls/mpr/Makefile
1118 dlls/msacm/Makefile
1119 dlls/msnet32/Makefile
1120 dlls/msvideo/Makefile
1121 dlls/ntdll/Makefile
1122 dlls/odbc32/Makefile
1123 dlls/ole32/Makefile
1124 dlls/oleaut32/Makefile
1125 dlls/olecli/Makefile
1126 dlls/oledlg/Makefile
1127 dlls/olepro32/Makefile
1128 dlls/olesvr/Makefile
1129 dlls/opengl32/Makefile
1130 dlls/psapi/Makefile
1131 dlls/rasapi32/Makefile
1132 dlls/richedit/Makefile
1133 dlls/rpcrt4/Makefile
1134 dlls/serialui/Makefile
1135 dlls/setupapi/Makefile
1136 dlls/shell32/Makefile
1137 dlls/shfolder/Makefile
1138 dlls/shlwapi/Makefile
1139 dlls/tapi32/Makefile
1140 dlls/ttydrv/Makefile
1141 dlls/urlmon/Makefile
1142 dlls/user/Makefile
1143 dlls/version/Makefile
1144 dlls/win32s/Makefile
1145 dlls/winaspi/Makefile
1146 dlls/wineps/Makefile
1147 dlls/wininet/Makefile
1148 dlls/winmm/Makefile
1149 dlls/winmm/joystick/Makefile
1150 dlls/winmm/mcianim/Makefile
1151 dlls/winmm/mciavi/Makefile
1152 dlls/winmm/mcicda/Makefile
1153 dlls/winmm/mciseq/Makefile
1154 dlls/winmm/mciwave/Makefile
1155 dlls/winmm/midimap/Makefile
1156 dlls/winmm/wavemap/Makefile
1157 dlls/winmm/wineoss/Makefile
1158 dlls/winsock/Makefile
1159 dlls/winspool/Makefile
1160 dlls/wow32/Makefile
1161 dlls/wsock32/Makefile
1162 dlls/x11drv/Makefile
1163 documentation/Makefile
1164 documentation/wine.conf.man
1165 documentation/wine.man
1166 files/Makefile
1167 graphics/Makefile
1168 graphics/enhmetafiledrv/Makefile
1169 graphics/metafiledrv/Makefile
1170 graphics/win16drv/Makefile
1171 graphics/x11drv/Makefile
1172 if1632/Makefile
1173 include/Makefile
1174 library/Makefile
1175 libtest/Makefile
1176 loader/Makefile
1177 loader/dos/Makefile
1178 loader/ne/Makefile
1179 memory/Makefile
1180 misc/Makefile
1181 miscemu/Makefile
1182 msdos/Makefile
1183 objects/Makefile
1184 ole/Makefile
1185 programs/Makefile
1186 programs/avitools/Makefile
1187 programs/clock/Makefile
1188 programs/cmdlgtst/Makefile
1189 programs/control/Makefile
1190 programs/notepad/Makefile
1191 programs/osversioncheck/Makefile
1192 programs/progman/Makefile
1193 programs/regapi/Makefile
1194 programs/regtest/Makefile
1195 programs/uninstaller/Makefile
1196 programs/view/Makefile
1197 programs/wcmd/Makefile
1198 programs/winemine/Makefile
1199 programs/winhelp/Makefile
1200 programs/winver/Makefile
1201 relay32/Makefile
1202 scheduler/Makefile
1203 server/Makefile
1204 tools/Makefile
1205 tools/cvdump/Makefile
1206 tools/winebuild/Makefile
1207 tools/winelauncher
1208 tools/wmc/Makefile
1209 tools/wrc/Makefile
1210 tsx11/Makefile
1211 unicode/Makefile
1212 win32/Makefile
1213 windows/Makefile
1214 windows/x11drv/Makefile ])
1215
1216 if test "$have_x" = "no"
1217 then
1218   echo
1219   echo "*** Warning: X development files not found. Wine will be built without"
1220   echo "*** X support, which currently does not work, and would probably not be"
1221   echo "*** what you want anyway. You will need to install devel packages of"
1222   echo "*** Xlib/Xfree86 and Xpm at the very least."
1223 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
1224 then
1225   echo
1226   echo "*** Warning: Xpm development files not found. Wine will be built without"
1227   echo "*** Xpm support, which currently does not work. You will need to install"
1228   echo "*** devel packages of Xpm."
1229 fi
1230
1231 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1232 then
1233   echo
1234   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1235   echo "*** terminal resize support. Consider upgrading ncurses."
1236 fi
1237
1238 if test "$wine_cv_libc_reentrant" = "no"
1239 then
1240   echo
1241   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
1242   echo "*** thread support. Consider upgrading libc to a more recent"
1243   echo "*** reentrant version of libc."
1244 fi
1245
1246 if test "$wine_cv_opengl_version_OK" = "no"
1247 then
1248   echo
1249   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1250   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1251 fi
1252
1253 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "normal"
1254 then
1255   echo
1256   echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1257   echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1258   echo "*** A fix for glibc 2.1.3 that seem to work is included in this version of Wine,"
1259   echo "*** start configure with '--enable-opengl' to force OpenGL support."
1260 fi
1261
1262 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "yes"
1263 then
1264   echo
1265   echo "*** Warning: you explicitely linked in a thread-safe OpenGL version. If you"
1266   echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1267   echo "*** support before reporting bugs."
1268 fi
1269
1270
1271 echo
1272 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1273 echo
1274
1275 dnl Local Variables:
1276 dnl comment-start: "dnl "
1277 dnl comment-end: ""
1278 dnl comment-start-skip: "\\bdnl\\b\\s *"
1279 dnl compile-command: "autoconf"
1280 dnl End: