aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18 dnl
  19 dnl As a special exception to the GNU Lesser General Public License,
  20 dnl if you distribute this file as part of a program that contains a
  21 dnl configuration script generated by Autoconf, you may include it
  22 dnl under the same distribution terms that you use for the rest of
  23 dnl that program.
  24
  25 dnl **** Get the ldd program name; used by WINE_GET_SONAME ****
  26 dnl
  27 dnl Usage: WINE_PATH_LDD
  28 dnl
  29 AC_DEFUN([WINE_PATH_LDD],[AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)])
  30
  31 dnl **** Extract the soname of a library ****
  32 dnl
  33 dnl Usage: WINE_CHECK_SONAME(library, function, [action-if-found, [action-if-not-found, [other_libraries, [pattern]]]])
  34 dnl
  35 AC_DEFUN([WINE_CHECK_SONAME],
  36 [AC_REQUIRE([WINE_PATH_LDD])dnl
  37 AS_VAR_PUSHDEF([ac_Lib],[ac_cv_lib_soname_$1])dnl
  38 m4_pushdef([ac_lib_pattern],m4_default([$6],[lib$1]))dnl
  39 AC_MSG_CHECKING([for -l$1])
  40 AC_CACHE_VAL(ac_Lib,
  41 [ac_check_soname_save_LIBS=$LIBS
  42 LIBS="-l$1 $5 $LIBS"
  43   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  44   [case "$LIBEXT" in
  45     dll) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest.exe | grep "$1" | sed -e "s/dll.*/dll/"';2,$d'`]) ;;
  46     dylib) AS_VAR_SET(ac_Lib,[`otool -L conftest$ac_exeext | grep "ac_lib_pattern\\.[[0-9A-Za-z.]]*dylib" | sed -e "s/^.*\/\(ac_lib_pattern\.[[0-9A-Za-z.]]*dylib\).*$/\1/"';2,$d'`]) ;;
  47     *) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest$ac_exeext | grep "ac_lib_pattern\\.$LIBEXT" | sed -e "s/^.*\(ac_lib_pattern\.$LIBEXT[[^      ]]*\).*$/\1/"';2,$d'`]) ;;
  48   esac])
  49   LIBS=$ac_check_soname_save_LIBS])dnl
  50 AS_IF([test "x]AS_VAR_GET(ac_Lib)[" = "x"],
  51       [AC_MSG_RESULT([not found])
  52        $4],
  53       [AC_MSG_RESULT(AS_VAR_GET(ac_Lib))
  54        AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),["]AS_VAR_GET(ac_Lib)["],
  55                           [Define to the soname of the lib$1 library.])
  56        $3])dnl
  57 m4_popdef([ac_lib_pattern])dnl
  58 AS_VAR_POPDEF([ac_Lib])])
  59
  60 dnl **** Link C code with an assembly file ****
  61 dnl
  62 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
  63 dnl
  64 AC_DEFUN([WINE_TRY_ASM_LINK],
  65 [AC_LINK_IFELSE(AC_LANG_PROGRAM([[$2]],[[asm($1); $3]]),[$4],[$5])])
  66
  67 dnl **** Check if we can link an empty program with special CFLAGS ****
  68 dnl
  69 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
  70 dnl
  71 dnl The default action-if-yes is to append the flags to EXTRACFLAGS.
  72 dnl
  73 AC_DEFUN([WINE_TRY_CFLAGS],
  74 [AS_VAR_PUSHDEF([ac_var], ac_cv_cflags_[[$1]])dnl
  75 AC_CACHE_CHECK([whether the compiler supports $1], ac_var,
  76 [ac_wine_try_cflags_saved=$CFLAGS
  77 CFLAGS="$CFLAGS $1"
  78 AC_LINK_IFELSE(AC_LANG_SOURCE([[int main(int argc, char **argv) { return 0; }]]),
  79                [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
  80 CFLAGS=$ac_wine_try_cflags_saved])
  81 AS_IF([test AS_VAR_GET(ac_var) = yes],
  82       [m4_default([$2], [EXTRACFLAGS="$EXTRACFLAGS $1"])], [$3])dnl
  83 AS_VAR_POPDEF([ac_var])])
  84
  85 dnl **** Check if we can link an empty shared lib (no main) with special CFLAGS ****
  86 dnl
  87 dnl Usage: WINE_TRY_SHLIB_FLAGS(flags,[action-if-yes,[action-if-no]])
  88 dnl
  89 AC_DEFUN([WINE_TRY_SHLIB_FLAGS],
  90 [ac_wine_try_cflags_saved=$CFLAGS
  91 CFLAGS="$CFLAGS $1"
  92 AC_LINK_IFELSE([void myfunc() {}],[$2],[$3])
  93 CFLAGS=$ac_wine_try_cflags_saved])
  94
  95 dnl **** Check whether we need to define a symbol on the compiler command line ****
  96 dnl
  97 dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]])
  98 dnl
  99 AC_DEFUN([WINE_CHECK_DEFINE],
 100 [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl
 101 AC_CACHE_CHECK([whether we need to define $1],ac_var,
 102     AC_EGREP_CPP(yes,[#ifndef $1
 103 yes
 104 #endif],
 105     [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)]))
 106 AS_IF([test AS_VAR_GET(ac_var) = yes],
 107       [CFLAGS="$CFLAGS -D$1"
 108   LINTFLAGS="$LINTFLAGS -D$1"])dnl
 109 AS_VAR_POPDEF([ac_var])])
 110
 111 dnl **** Check for functions with some extra libraries ****
 112 dnl
 113 dnl Usage: WINE_CHECK_LIB_FUNCS(funcs,libs,[action-if-found,[action-if-not-found]])
 114 dnl
 115 AC_DEFUN([WINE_CHECK_LIB_FUNCS],
 116 [ac_wine_check_funcs_save_LIBS="$LIBS"
 117 LIBS="$LIBS $2"
 118 AC_CHECK_FUNCS([$1],[$3],[$4])
 119 LIBS="$ac_wine_check_funcs_save_LIBS"])
 120
 121 dnl **** Check for a mingw program, trying the various mingw prefixes ****
 122 dnl
 123 dnl Usage: WINE_CHECK_MINGW_PROG(variable,prog,[value-if-not-found],[path])
 124 dnl
 125 AC_DEFUN([WINE_CHECK_MINGW_PROG],
 126 [case "$host_cpu" in
 127   i[[3456789]]86*)
 128     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32, mingw32msvc, mingw32],
 129                         m4_foreach([ac_wine_cpu],[i686,i586,i486,i386],[ac_wine_cpu-ac_wine_prefix-$2 ]))" ;;
 130   x86_64)
 131     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32,w64-mingw32],[x86_64-ac_wine_prefix-$2 ])" ;;
 132   *)
 133     ac_prefix_list="" ;;
 134 esac
 135 AC_CHECK_PROGS([$1],[$ac_prefix_list],[$3],[$4])])
 136
 137
 138 dnl **** Define helper functions for creating config.status files ****
 139 dnl
 140 dnl Usage: AC_REQUIRE([WINE_CONFIG_HELPERS])
 141 dnl
 142 AC_DEFUN([WINE_CONFIG_HELPERS],
 143 [wine_fn_append_file ()
 144 {
 145     AS_VAR_APPEND($[1]," \\$as_nl       $[2]")
 146 }
 147
 148 wine_fn_append_rule ()
 149 {
 150     AS_VAR_APPEND($[1],"$as_nl$[2]")
 151 }
 152
 153 wine_fn_config_makefile ()
 154 {
 155     ac_dir=$[1]
 156     ac_deps=$[2]
 157     wine_fn_append_file ALL_DIRS $ac_dir
 158     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 159 "$ac_dir/__clean__ $ac_dir/__install__ $ac_dir/__install-dev__ $ac_dir/__install-lib__ $ac_dir/__uninstall__ $ac_dir: $ac_dir/Makefile
 160 $ac_dir/Makefile $ac_dir/__depend__: $ac_dir/Makefile.in config.status $ac_deps
 161         @./config.status --file $ac_dir/Makefile && cd $ac_dir && \$(MAKE) depend"
 162 }
 163
 164 wine_fn_config_lib ()
 165 {
 166     ac_name=$[1]
 167     ac_dir=dlls/$ac_name
 168     wine_fn_append_file ALL_DIRS $ac_dir
 169     wine_fn_append_file ALL_STATICLIB_DIRS $ac_dir
 170     wine_fn_append_file ALL_STATIC_LIBS $ac_dir/lib$ac_name.a
 171     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 172 "$ac_dir/__install__ $ac_dir/__install-dev__: $ac_dir
 173 $ac_dir $ac_dir/lib$ac_name.cross.a: tools/widl tools/winebuild tools/winegcc include
 174 $ac_dir/lib$ac_name.cross.a: $ac_dir/Makefile dummy
 175         @cd $ac_dir && \$(MAKE) lib$ac_name.cross.a
 176 $ac_dir/__clean__ $ac_dir/__install-lib__ $ac_dir/__uninstall__ $ac_dir: $ac_dir/Makefile
 177 $ac_dir/Makefile $ac_dir/__depend__: $ac_dir/Makefile.in config.status dlls/Makeimplib.rules \$(MAKEDEP)
 178         @./config.status --file $ac_dir/Makefile && cd $ac_dir && \$(MAKE) depend"
 179 }
 180
 181 wine_fn_config_dll ()
 182 {
 183     ac_dir=$[1]
 184     ac_implib=$[2]
 185     ac_implibsrc=$[3]
 186     ac_file="dlls/$ac_dir/lib$ac_implib"
 187     ac_deps="tools/widl tools/winebuild tools/winegcc include"
 188
 189     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 190 "dlls/$ac_dir dlls/$ac_dir/__install__ dlls/$ac_dir/__install-lib__ dlls/$ac_dir/__install-dev__: __builddeps__"
 191
 192     if test -n "$ac_implibsrc"
 193     then
 194         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 195 "$ac_file.$IMPLIBEXT $ac_file.$STATIC_IMPLIBEXT $ac_file.cross.a: $ac_deps
 196 $ac_file.def: dlls/$ac_dir/$ac_dir.spec dlls/$ac_dir/Makefile
 197         @cd dlls/$ac_dir && \$(MAKE) \`basename \$[@]\`
 198 $ac_file.$STATIC_IMPLIBEXT $ac_file.cross.a: dlls/$ac_dir/Makefile dummy
 199         @cd dlls/$ac_dir && \$(MAKE) \`basename \$[@]\`"
 200     elif test -n "$ac_implib"
 201     then
 202         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 203 "$ac_file.$IMPLIBEXT $ac_file.cross.a: $ac_deps
 204 $ac_file.$IMPLIBEXT $ac_file.cross.a: dlls/$ac_dir/$ac_dir.spec dlls/$ac_dir/Makefile
 205         @cd dlls/$ac_dir && \$(MAKE) \`basename \$[@]\`"
 206
 207         if test "$ac_dir" != "$ac_implib"
 208         then
 209             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 210 "dlls/lib$ac_implib.$IMPLIBEXT: $ac_file.$IMPLIBEXT
 211         \$(RM) \$[@] && \$(LN_S) $ac_dir/lib$ac_implib.$IMPLIBEXT \$[@]
 212 dlls/lib$ac_implib.cross.a: $ac_file.cross.a
 213         \$(RM) \$[@] && \$(LN_S) $ac_dir/lib$ac_implib.cross.a \$[@]
 214 clean::
 215         \$(RM) dlls/lib$ac_implib.$IMPLIBEXT"
 216         fi
 217     fi
 218 }
 219
 220 wine_fn_config_program ()
 221 {
 222     ac_dir=$[1]
 223     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 224 "programs/$ac_dir programs/$ac_dir/__install__ programs/$ac_dir/__install-lib__: __builddeps__"
 225 }
 226
 227 wine_fn_config_test ()
 228 {
 229     ac_dir=$[1]
 230     ac_name=$[2]
 231     wine_fn_append_file ALL_TEST_BINARIES $ac_name.exe
 232     wine_fn_append_rule ALL_WINETEST_DEPENDS \
 233 "$ac_name.exe: \$(TOPOBJDIR)/$ac_dir/$ac_name.exe$DLLEXT
 234         cp \$(TOPOBJDIR)/$ac_dir/$ac_name.exe$DLLEXT \$[@] && \$(STRIP) \$[@]
 235 $ac_name.rc:
 236         echo \"$ac_name.exe TESTRES \\\"$ac_name.exe\\\"\" >\$[@] || (\$(RM) \$[@] && false)
 237 $ac_name.res: $ac_name.rc $ac_name.exe"
 238     wine_fn_append_file ALL_DIRS $ac_dir
 239     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 240 "$ac_dir: __builddeps__
 241 $ac_dir/__crosstest__: __buildcrossdeps__
 242 $ac_dir/__clean__ $ac_dir/__crosstest__ $ac_dir: $ac_dir/Makefile
 243 $ac_dir/Makefile $ac_dir/__depend__: $ac_dir/Makefile.in config.status Maketest.rules \$(MAKEDEP)
 244         @./config.status --file $ac_dir/Makefile && cd $ac_dir && \$(MAKE) depend"
 245     AS_VAR_IF([enable_tests],[no],,[wine_fn_append_file ALL_TEST_DIRS $ac_dir])
 246 }])
 247
 248 dnl **** Define helper function to append a file to a makefile file list ****
 249 dnl
 250 dnl Usage: WINE_APPEND_FILE(var,file)
 251 dnl
 252 AC_DEFUN([WINE_APPEND_FILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_file $1 "$2"])
 253
 254 dnl **** Define helper function to append a rule to a makefile command list ****
 255 dnl
 256 dnl Usage: WINE_APPEND_RULE(var,rule)
 257 dnl
 258 AC_DEFUN([WINE_APPEND_RULE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_rule $1 "$2"])
 259
 260 dnl **** Create nonexistent directories from config.status ****
 261 dnl
 262 dnl Usage: WINE_CONFIG_EXTRA_DIR(dirname)
 263 dnl
 264 AC_DEFUN([WINE_CONFIG_EXTRA_DIR],
 265 [AC_CONFIG_COMMANDS([$1],[test -d "$1" || { AC_MSG_NOTICE([creating $1]); AS_MKDIR_P("$1"); }])])
 266
 267 dnl **** Create symlinks from config.status ****
 268 dnl
 269 dnl Usage: WINE_CONFIG_SYMLINK(name,target)
 270 dnl
 271 AC_DEFUN([WINE_CONFIG_SYMLINK],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 272 AC_CONFIG_LINKS([$1:]m4_default([$2],[$1]))dnl
 273 m4_if([$2],,[test "$srcdir" = "." || ])WINE_APPEND_FILE(ALL_SYMLINKS,[$1])])
 274
 275 dnl **** Create a make rules file from config.status ****
 276 dnl
 277 dnl Usage: WINE_CONFIG_MAKERULES(file,var,deps)
 278 dnl
 279 AC_DEFUN([WINE_CONFIG_MAKERULES],
 280 [WINE_APPEND_FILE(ALL_MAKERULES,[$1])
 281 WINE_APPEND_RULE(ALL_MAKEFILE_DEPENDS,[$1: m4_ifval([$3],[$1.in $3],[$1.in]) config.status])
 282 $2=$1
 283 AC_SUBST_FILE([$2])dnl
 284 AC_CONFIG_FILES([$1])])
 285
 286 dnl **** Create a makefile from config.status ****
 287 dnl
 288 dnl Usage: WINE_CONFIG_MAKEFILE(file,deps,var,enable)
 289 dnl
 290 AC_DEFUN([WINE_CONFIG_MAKEFILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 291 m4_pushdef([ac_dir],m4_bpatsubst([$1],[^\(\(.*\)/\)?Makefile$],[\2]))dnl
 292 m4_pushdef([ac_name],m4_bpatsubst(ac_dir,[.*/\(.*\)$],[\1]))dnl
 293 m4_if(ac_dir,,WINE_APPEND_RULE(ALL_MAKEFILE_DEPENDS,[$1: $1.in $2 config.status])
 294 AC_CONFIG_FILES([$1]),
 295 [wine_fn_config_makefile ac_dir m4_if(ac_dir,tools,[$2],["$2 \$(MAKEDEP)"])
 296 AS_VAR_PUSHDEF([ac_enable],m4_default([$4],[enable_]ac_name))dnl
 297 m4_ifval([$3],[test "x$ac_enable" != xno]m4_foreach([ac_var],[$3],[ && WINE_APPEND_FILE(ac_var,ac_dir)]))
 298 AS_VAR_POPDEF([ac_enable])])dnl
 299 m4_popdef([ac_dir])dnl
 300 m4_popdef([ac_name])])
 301
 302 dnl **** Create a dll makefile from config.status ****
 303 dnl
 304 dnl Usage: WINE_CONFIG_DLL(name,enable,implib,implibsrc)
 305 dnl
 306 AC_DEFUN([WINE_CONFIG_DLL],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 307 m4_pushdef([ac_implib],m4_ifval([$3],[dlls/$1/lib$3.$IMPLIBEXT]))dnl
 308 m4_ifval(ac_implib,[m4_ifval([$2],[test "x$[$2]" != xno && ])WINE_APPEND_FILE(ALL_IMPORT_LIBS,ac_implib)dnl
 309 m4_if([$1],[$3],,[ && WINE_APPEND_FILE(ALL_IMPORT_LIBS,[dlls/lib$3.$IMPLIBEXT])])dnl
 310 m4_ifval([$4],[ && WINE_APPEND_FILE(ALL_IMPORT_LIBS,[dlls/$1/lib$3.$STATIC_IMPLIBEXT])])
 311 ])wine_fn_config_dll [$1] [$3] m4_ifval([$4],["$4"])
 312 WINE_CONFIG_MAKEFILE([dlls/$1/Makefile],[dlls/Makedll.rules],[ALL_DLL_DIRS],[$2])dnl
 313 m4_popdef([ac_implib])])
 314
 315 dnl **** Create a program makefile from config.status ****
 316 dnl
 317 dnl Usage: WINE_CONFIG_PROGRAM(name,var,enable)
 318 dnl
 319 AC_DEFUN([WINE_CONFIG_PROGRAM],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 320 wine_fn_config_program [$1]
 321 WINE_CONFIG_MAKEFILE([programs/$1/Makefile],[programs/Makeprog.rules],[$2],[$3])])
 322
 323 dnl **** Create a test makefile from config.status ****
 324 dnl
 325 dnl Usage: WINE_CONFIG_TEST(dir)
 326 dnl
 327 AC_DEFUN([WINE_CONFIG_TEST],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 328 m4_pushdef([ac_suffix],m4_if(m4_substr([$1],0,9),[programs/],[.exe_test],[_test]))dnl
 329 m4_pushdef([ac_name],[m4_bpatsubst([$1],[.*/\(.*\)/tests$],[\1])])dnl
 330 wine_fn_config_test $1 ac_name[]ac_suffix[]dnl
 331 m4_popdef([ac_suffix])dnl
 332 m4_popdef([ac_name])])
 333
 334 dnl **** Create a static lib makefile from config.status ****
 335 dnl
 336 dnl Usage: WINE_CONFIG_LIB(name)
 337 dnl
 338 AC_DEFUN([WINE_CONFIG_LIB],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 339 wine_fn_config_lib $1])
 340
 341 dnl **** Add a message to the list displayed at the end ****
 342 dnl
 343 dnl Usage: WINE_NOTICE(notice)
 344 dnl Usage: WINE_NOTICE_WITH(with_flag, test, notice)
 345 dnl Usage: WINE_WARNING(warning)
 346 dnl Usage: WINE_WARNING_WITH(with_flag, test, warning)
 347 dnl Usage: WINE_PRINT_MESSAGES
 348 dnl
 349 AC_DEFUN([WINE_NOTICE],[AS_VAR_APPEND([wine_notices],["|$1"])])
 350 AC_DEFUN([WINE_WARNING],[AS_VAR_APPEND([wine_warnings],["|$1"])])
 351
 352 AC_DEFUN([WINE_NOTICE_WITH],[AS_IF([$2],[case "x$with_$1" in
 353   x)   WINE_NOTICE([$3]) ;;
 354   xno) ;;
 355   *)   AC_MSG_ERROR([$3
 356 This is an error since --with-$1 was requested.]) ;;
 357 esac])])
 358
 359 AC_DEFUN([WINE_WARNING_WITH],[AS_IF([$2],[case "x$with_$1" in
 360   x)   WINE_WARNING([$3]) ;;
 361   xno) ;;
 362   *)   AC_MSG_ERROR([$3
 363 This is an error since --with-$1 was requested.]) ;;
 364 esac])])
 365
 366 AC_DEFUN([WINE_ERROR_WITH],[AS_IF([$2],[case "x$with_$1" in
 367   xno) ;;
 368   *)   AC_MSG_ERROR([$3
 369 Use the --without-$1 option if you really want this.]) ;;
 370 esac])])
 371
 372 AC_DEFUN([WINE_PRINT_MESSAGES],[ac_save_IFS="$IFS"
 373 if test "x$wine_notices != "x; then
 374     echo >&AS_MESSAGE_FD
 375     IFS="|"
 376     for msg in $wine_notices; do
 377         IFS="$ac_save_IFS"
 378         if test -n "$msg"; then
 379             AC_MSG_NOTICE([$msg])
 380         fi
 381     done
 382 fi
 383 IFS="|"
 384 for msg in $wine_warnings; do
 385     IFS="$ac_save_IFS"
 386     if test -n "$msg"; then
 387         echo >&2
 388         AC_MSG_WARN([$msg])
 389     fi
 390 done
 391 IFS="$ac_save_IFS"])
 392
 393 dnl Local Variables:
 394 dnl compile-command: "autoreconf --warnings=all"
 395 dnl End: