aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  18 dnl
  19
  20 dnl **** Get the ldd program name; used by WINE_GET_SONAME ****
  21 dnl
  22 dnl Usage: WINE_PATH_LDD
  23 dnl
  24 AC_DEFUN([WINE_PATH_LDD],[AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)])
  25
  26 dnl **** Extract the soname of a library ****
  27 dnl
  28 dnl Usage: WINE_GET_SONAME(LIBRARY, FUNCTION, [OTHER_LIBRARIES])
  29 dnl
  30 AC_DEFUN([WINE_GET_SONAME],
  31 [AC_REQUIRE([WINE_PATH_LDD])
  32 AC_CACHE_CHECK([for -l$1 soname], ac_cv_lib_soname_$1,
  33 [ac_get_soname_save_LIBS=$LIBS
  34 LIBS="-l$1 $3 $LIBS"
  35   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  36   [ac_cv_lib_soname_$1=`$ac_cv_path_LDD conftest$ac_exeext | grep lib$1\\.so | sed 's/^[[       ]]*\([[^        ]]*\)[[         ]]*=>.*$/\1/'`
  37   if test "x$ac_cv_lib_soname_$1" = "x"
  38   then
  39      ac_cv_lib_soname_$1="lib$1.so"
  40   fi],
  41   [ac_cv_lib_soname_$1="lib$1.so"])
  42   LIBS=$ac_get_soname_save_LIBS])
  43 if test "x$ac_cv_lib_soname_$1" != xNONE
  44 then AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),"$ac_cv_lib_soname_$1",
  45                         [Define to the soname of the lib$1 library.])dnl
  46 fi])
  47
  48 dnl **** Check if a structure contains a specified member ****
  49 dnl
  50 dnl Usage: WINE_CHECK_STRUCT_MEMBER(struct,member,[includes,[action-if-found,[action-if-not-found]]])
  51 dnl
  52 AC_DEFUN([WINE_CHECK_STRUCT_MEMBER],
  53 [AC_CACHE_CHECK([for $2 in struct $1], ac_cv_c_$1_$2,
  54  AC_TRY_COMPILE([$3],[struct $1 s; s.$2 = 0],ac_cv_c_$1_$2="yes",ac_cv_c_$1_$2="no"))
  55 AS_IF([ test "x$ac_cv_c_$1_$2" = "xyes"],[$4],[$5])
  56 ])
  57
  58 dnl **** Check for reentrant libc ****
  59 dnl
  60 dnl Usage: WINE_CHECK_ERRNO(errno-name,[action-if-yes,[action-if-no]])
  61 dnl
  62 dnl For cross-compiling we blindly assume that libc is reentrant. This is
  63 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
  64 dnl
  65 AC_DEFUN([WINE_CHECK_ERRNO],
  66 [AC_CACHE_CHECK([for reentrant libc: $1],[wine_cv_libc_r_$1],
  67   [AC_TRY_RUN([int myerrno = 0;
  68 int *$1(){return &myerrno;}
  69 main(){close(333); close(333); exit(!myerrno);}],
  70   wine_cv_libc_r_$1=yes, wine_cv_libc_r_$1=no,
  71   wine_cv_libc_r_$1=yes)])
  72 AS_IF([test "$wine_cv_libc_r_$1" = "yes"],[$2],[$3])])
  73
  74 dnl **** Link C code with an assembly file ****
  75 dnl
  76 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
  77 dnl
  78 AC_DEFUN([WINE_TRY_ASM_LINK],
  79 [AC_TRY_LINK([static void ac_asm(void) { asm([$1]); }
  80 [$2]],[$3],[$4],[$5])])
  81
  82 dnl **** Check if we can link an empty program with special CFLAGS ****
  83 dnl
  84 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
  85 dnl
  86 AC_DEFUN([WINE_TRY_CFLAGS],
  87 [ac_wine_try_cflags_saved=$CFLAGS
  88 CFLAGS="$CFLAGS $1"
  89 AC_TRY_LINK([],[],[$2],[$3])
  90 CFLAGS=$ac_wine_try_cflags_saved])
  91
  92 dnl **** Check for ln ****
  93 dnl
  94 dnl Usage: WINE_PROG_LN
  95 dnl
  96 AC_DEFUN([WINE_PROG_LN],
  97 [AC_MSG_CHECKING([whether ln works])
  98 rm -f conf$$ conf$$.file
  99 echo >conf$$.file
 100 if ln conf$$.file conf$$ 2>/dev/null; then
 101   AC_SUBST(LN,ln)
 102   AC_MSG_RESULT([yes])
 103 else
 104   AC_SUBST(LN,["cp -p"])
 105   AC_MSG_RESULT([no, using $LN])
 106 fi
 107 rm -f conf$$ conf$$.file])
 108
 109 dnl **** Create non-existent directories from config.status ****
 110 dnl
 111 dnl Usage: WINE_CONFIG_EXTRA_DIR(dirname)
 112 dnl
 113 AC_DEFUN([WINE_CONFIG_EXTRA_DIR],
 114 [AC_CONFIG_COMMANDS([$1],[test -d "$1" || (AC_MSG_NOTICE([creating $1]) && mkdir "$1")])])