programs/winedbg/debug.l

   1 /* -*-C-*-
   2  * Lexical scanner for command line parsing
   3  *
   4  * Copyright 1993 Eric Youngdale
   5  *           2000 Eric Pouech
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  20  */
  21
  22 %option nounput interactive 8bit prefix="dbg_"
  23
  24 %{
  25 #include <stdlib.h>
  26 #include <string.h>
  27 #include <stdarg.h>
  28
  29 #include "debugger.h"
  30 #include "dbg.tab.h"
  31
  32 #undef YY_INPUT
  33
  34 static int read_input(const char* pfx, char* buf, int size)
  35 {
  36     int len;
  37     static char*  last_line = NULL;
  38     static size_t last_line_idx = 0;
  39
  40     /* try first to fetch the remaining of an existing line */
  41     if (last_line_idx == 0)
  42     {
  43         char* tmp = NULL;
  44         /* no remaining chars to be read from last line, grab a brand new line up to '\n' */
  45         lexeme_flush();
  46         len = input_fetch_entire_line(pfx, &tmp);
  47         if (len < 0) return 0;  /* eof */
  48         /* FIXME: should have a pair of buffers, and switch between the two, instead of
  49          * reallocating a new one for each line
  50          */
  51         if (last_line && (len == 0 || (len == 1 && tmp[0] == '\n') || (len == 2 && tmp[0] == '\r' && tmp[1] == '\n')))
  52         {
  53             HeapFree(GetProcessHeap(), 0, tmp);
  54         }
  55         else
  56         {
  57             HeapFree(GetProcessHeap(), 0, last_line);
  58             last_line = tmp;
  59         }
  60     }
  61
  62     len = min(strlen(last_line + last_line_idx), size - 1);
  63     memcpy(buf, last_line + last_line_idx, len);
  64     buf[len] = '\0';
  65     if ((last_line_idx += len) >= strlen(last_line))
  66         last_line_idx = 0;
  67     return len;
  68 }
  69
  70 #define YY_INPUT(buf,result,max_size) \
  71         if ((result = read_input("Wine-dbg>", buf, max_size)) < 0) \
  72             YY_FATAL_ERROR("read_input in flex scanner failed");
  73
  74 static int syntax_error;
  75 %}
  76
  77 DIGIT      [0-9]
  78 HEXDIGIT   [0-9a-fA-F]
  79 FORMAT     [ubcdgiswx]
  80 IDENTIFIER [_a-zA-Z~?][_a-zA-Z0-9~?@]*
  81 PATHNAME   [\\/-_a-zA-Z0-9\.~@]+
  82 STRING     \"[^\n"]+\"
  83
  84 %s FORMAT_EXPECTED
  85 %s PATH_EXPECTED
  86 %s INFO_CMD
  87 %s HELP_CMD
  88 %s BD_CMD
  89 %s LOCAL_CMD
  90 %s SHOW_CMD
  91 %s MODE_CMD
  92 %s MAINT_CMD
  93 %s NOCMD
  94
  95 %x ASTRING_EXPECTED
  96 %x NOPROCESS
  97 %%
  98                                         /* set to special state when no process is loaded. */
  99                                         if (!dbg_num_processes() && YYSTATE == INITIAL) {BEGIN(NOPROCESS);}
 100
 101 <<EOF>>                                 { return tEOF; }
 102 <*>\n                                   { BEGIN(INITIAL); syntax_error = 0; return tEOL; }
 103                                         /* Indicates end of command. Reset state. */
 104
 105                                         /* This rule must precede the ones below, */
 106                                         /* otherwise paths like '/' or '0x9' would */
 107                                         /* get parsed as an operator or tNUM */
 108 <PATH_EXPECTED>{PATHNAME}               { dbg_lval.string = lexeme_alloc(yytext); return tPATH; }
 109
 110 "||"                                    { return OP_LOR; }
 111 "&&"                                    { return OP_LAND; }
 112 "=="                                    { return OP_EQ; }
 113 "!="                                    { return OP_NE; }
 114 "<="                                    { return OP_LE; }
 115 ">="                                    { return OP_GE; }
 116 "<<"                                    { return OP_SHL; }
 117 ">>"                                    { return OP_SHR; }
 118 "->"                                    { return OP_DRF; }
 119 "::"                                    { return OP_SCOPE; }
 120 [-+<=>|&^()*/%:!~,\.]                   { return *yytext; }
 121 "["                                     { return *yytext; }
 122 "]"                                     { return *yytext; }
 123
 124 "0x"{HEXDIGIT}+                         { sscanf(yytext, "%x", &dbg_lval.integer); return tNUM; }
 125 {DIGIT}+                                { sscanf(yytext, "%d", &dbg_lval.integer); return tNUM; }
 126
 127 <FORMAT_EXPECTED>"/"{DIGIT}+{FORMAT}    { char* last;
 128                                           dbg_lval.integer = strtol(yytext+1, &last, 0) << 8;
 129                                           dbg_lval.integer |= *last;
 130                                           return tFORMAT; }
 131
 132 <FORMAT_EXPECTED>"/"{FORMAT}            { dbg_lval.integer = (1 << 8) | yytext[1]; return tFORMAT; }
 133
 134 {STRING}                                { dbg_lval.string = lexeme_alloc(yytext + 1); dbg_lval.string[strlen(dbg_lval.string) - 1] = '\0'; return tSTRING; }
 135 <ASTRING_EXPECTED>[^\n]+                { char* p = yytext; while (*p == ' ' || *p == '\t') p++;
 136                                           dbg_lval.string = lexeme_alloc(p); return tSTRING; }
 137
 138 <INITIAL,NOPROCESS>info|inf|in          { BEGIN(INFO_CMD); return tINFO; }
 139 <INITIAL>up                             { BEGIN(NOCMD); return tUP; }
 140 <INITIAL>down|dow|do                    { BEGIN(NOCMD); return tDOWN; }
 141 <INITIAL>frame|fram|fra|fr              { BEGIN(NOCMD); return tFRAME; }
 142 <INITIAL>list|lis|li|l                  { BEGIN(PATH_EXPECTED); return tLIST; }
 143 <INITIAL>enable|enabl|enab|ena          { BEGIN(BD_CMD); return tENABLE;}
 144 <INITIAL>disable|disabl|disab|disa|dis  { BEGIN(BD_CMD); return tDISABLE; }
 145 <INITIAL>disassemble|disassembl|disassemb|disassem|disasse|disass|disas { BEGIN(NOCMD); return tDISASSEMBLE; }
 146 <INITIAL>locally|local                  { BEGIN(LOCAL_CMD); return tLOCAL; }
 147 <INITIAL,LOCAL_CMD>display|displa|displ|disp    { BEGIN(FORMAT_EXPECTED); return tDISPLAY; }
 148 <INFO_CMD,BD_CMD>display|displa|displ|disp|dis|di|d     { BEGIN(NOCMD); return tDISPLAY; }
 149 <INITIAL>undisplay|undispla|undispl|undisp|undis|undi|und       { BEGIN(NOCMD); return tUNDISPLAY; }
 150 <INITIAL>delete|delet|dele|del          { BEGIN(BD_CMD); return tDELETE; }
 151 <INITIAL,NOPROCESS>quit|qui|qu|q        { BEGIN(NOCMD); return tQUIT; }
 152 <INITIAL>set|se                         { BEGIN(NOCMD); return tSET; }
 153 <INITIAL>x                              { BEGIN(FORMAT_EXPECTED); return tEXAM; }
 154 <INITIAL,NOPROCESS>help|hel|he|"?"      { BEGIN(HELP_CMD); return tHELP; }
 155
 156 <INITIAL,NOPROCESS>backtrace|backtrac|backtra|backt|back|bac|ba|bt { BEGIN(NOCMD); return tBACKTRACE; }
 157 <INITIAL,NOPROCESS>where|wher|whe       { BEGIN(NOCMD); return tBACKTRACE; }
 158
 159 <INITIAL>cont|con|co|c                  { BEGIN(NOCMD); return tCONT; }
 160 <INITIAL>pass|pas|pa                    { BEGIN(NOCMD); return tPASS; }
 161 <INITIAL>condition|conditio|conditi|condit|condi|cond   { BEGIN(NOCMD); return tCOND; }
 162 <INITIAL>step|ste|st|s                  { BEGIN(NOCMD); return tSTEP; }
 163 <INITIAL>next|nex|ne|n                  { BEGIN(NOCMD); return tNEXT; }
 164 <INITIAL>stepi|si                       { BEGIN(NOCMD); return tSTEPI; }
 165 <INITIAL>nexti|ni                       { BEGIN(NOCMD); return tNEXTI; }
 166 <INITIAL>finish|finis|fini|fin|fi       { BEGIN(NOCMD); return tFINISH; }
 167
 168 <INITIAL>abort|abor|abo                 { BEGIN(NOCMD); return tABORT; }
 169 <INITIAL>print|prin|pri|pr|p            { BEGIN(FORMAT_EXPECTED); return tPRINT; }
 170
 171 <INITIAL>show|sho|sh                    { BEGIN(SHOW_CMD); return tSHOW; }
 172 <INITIAL,NOPROCESS>source|sourc|sour|src { BEGIN(PATH_EXPECTED); return tSOURCE; }
 173 <INITIAL>symbolfile|symbols|symbol|sf   { BEGIN(PATH_EXPECTED); return tSYMBOLFILE; }
 174
 175 <INITIAL,INFO_CMD,BD_CMD>break|brea|bre|br|b    { BEGIN(NOCMD); return tBREAK; }
 176 <INITIAL,INFO_CMD,BD_CMD>hbreak|hbrea|hbre|hbr|hb { BEGIN(NOCMD); return tHBREAK; }
 177 <INITIAL>watch|watc|wat                 { BEGIN(NOCMD); return tWATCH; }
 178 <INITIAL>whatis|whati|what              { BEGIN(NOCMD); return tWHATIS; }
 179 <INITIAL,NOPROCESS>run|ru|r             { BEGIN(ASTRING_EXPECTED); return tRUN;}
 180 <INITIAL>detach|detac|deta|det          { BEGIN(NOCMD); return tDETACH; }
 181 <INITIAL,NOPROCESS>maintenance|maint    { BEGIN(MAINT_CMD); return tMAINTENANCE; }
 182 <INITIAL>minidump|mdmp                  { BEGIN(PATH_EXPECTED); return tMINIDUMP; }
 183 <INITIAL>echo                           { BEGIN(ASTRING_EXPECTED); return tECHO; }
 184 <NOPROCESS>attach|attac|atta|att        { BEGIN(NOCMD); return tATTACH; }
 185 <INFO_CMD>share|shar|sha                { return tSHARE; }
 186 <MAINT_CMD>module|modul|mod             { BEGIN(ASTRING_EXPECTED); return tMODULE; }
 187 <INFO_CMD>locals|local|loca|loc         { return tLOCAL; }
 188 <INFO_CMD>class|clas|cla                { return tCLASS; }
 189 <INFO_CMD>process|proces|proce|proc     { return tPROCESS; }
 190 <INFO_CMD>threads|thread|threa|thre|thr|th { return tTHREAD; }
 191 <INFO_CMD>exception|except|exc|ex       { return tEXCEPTION; }
 192 <INFO_CMD>registers|regs|reg|re         { return tREGS; }
 193 <INFO_CMD>allregs|allreg|allre          { return tALLREGS; }
 194 <INFO_CMD>"all-registers"|"all-regs"|"all-reg"|"all-re" { return tALLREGS; }
 195 <INFO_CMD>segments|segment|segm|seg|se  { return tSEGMENTS; }
 196 <INFO_CMD>stack|stac|sta|st             { return tSTACK; }
 197 <INFO_CMD>symbol|symbo|symb|sym         { BEGIN(ASTRING_EXPECTED); return tSYMBOL; }
 198 <INFO_CMD>maps|map                      { return tMAPS; }
 199 <INFO_CMD>window|windo|wind|win|wnd     { return tWND; }
 200 <HELP_CMD>info|inf|in                   { return tINFO; }
 201 <MAINT_CMD>type                         { return tTYPE; }
 202
 203 <INITIAL,SHOW_CMD>directories|directorie|directori|director|directo|direct|direc|direc|dir {
 204                                           BEGIN(PATH_EXPECTED); return tDIR; }
 205
 206 char                                    { return tCHAR; }
 207 short                                   { return tSHORT; }
 208 int                                     { return tINT; }
 209 long                                    { return tLONG; }
 210 float                                   { return tFLOAT; }
 211 double                                  { return tDOUBLE; }
 212 unsigned                                { return tUNSIGNED; }
 213 signed                                  { return tSIGNED; }
 214 struct                                  { return tSTRUCT; }
 215 union                                   { return tUNION; }
 216 enum                                    { return tENUM; }
 217 all                                     { return tALL; }
 218
 219 {IDENTIFIER}                            { dbg_lval.string = lexeme_alloc(yytext); return tIDENTIFIER; }
 220 "$"{IDENTIFIER}                         { dbg_lval.string = lexeme_alloc(yytext+1); return tINTVAR; }
 221
 222 <*>[ \t\r]+                             /* Eat up whitespace and DOS LF */
 223
 224 <NOPROCESS>.                            { BEGIN(ASTRING_EXPECTED); yyless(0); return tNOPROCESS;}
 225 <*>.                                    { if (syntax_error == 0) { syntax_error++; dbg_printf("Syntax Error (%s)\n", yytext); } }
 226 %%
 227
 228 #ifndef dbg_wrap
 229 int dbg_wrap(void) { return 1; }
 230 #endif
 231
 232 static char** local_lexemes /* = NULL */;
 233 static int next_lexeme /* = 0 */;
 234 static int alloc_lexeme /* = 0 */;
 235
 236 char* lexeme_alloc_size(int size)
 237 {
 238     assert(0 <= next_lexeme && next_lexeme < alloc_lexeme + 1);
 239     if (next_lexeme >= alloc_lexeme)
 240     {
 241         alloc_lexeme += 32;
 242         local_lexemes = dbg_heap_realloc(local_lexemes, alloc_lexeme * sizeof(local_lexemes[0]));
 243         assert(local_lexemes);
 244     }
 245     return local_lexemes[next_lexeme++] = HeapAlloc(GetProcessHeap(), 0, size + 1);
 246 }
 247
 248 char* lexeme_alloc(const char* lexeme)
 249 {
 250     char*       ptr = lexeme_alloc_size(strlen(lexeme) + 1);
 251     return strcpy(ptr, lexeme);
 252 }
 253
 254 void lexeme_flush(void)
 255 {
 256     while (--next_lexeme >= 0) HeapFree(GetProcessHeap(), 0, local_lexemes[next_lexeme]);
 257     next_lexeme = 0;
 258 }