configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 # We want these before the checks, so the checks can modify their values.
  10 LIBS="$LIBS -lm"
  11 test -z "$PROGEXT" && PROGEXT="" AC_SUBST(PROGEXT)
  12
  13 dnl **** Command-line arguments ****
  14
  15 dnl Default values
  16 MAIN_TARGET=emu
  17 LIB_TARGET=libwine.a
  18 ALT_LINK="-L\$(TOPOBJDIR) -lwine"
  19 TRACE_MSGS=yes  # the TRACE() macro
  20 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  21
  22 AC_ARG_ENABLE(emulator,
  23 [  --disable-emulator      build only the Wine library, not the emulator],
  24 [if test "$enableval" = "no"; then MAIN_TARGET="lib"; fi])
  25
  26 AC_ARG_ENABLE(dll,
  27 [  --enable-dll            build the Wine library as a DLL],
  28 [if test "$enableval" = "no"; then : ; else LIB_TARGET="libwine.so.1.0"; fi])
  29
  30 AC_ARG_ENABLE(lib,
  31 [  --disable-lib           build the Wine without building libwine.a],
  32 [if test "$enableval" = "no"; then ALT_LINK="\$(LIBOBJS) \$(X11OBJS)"; LIB_TARGET=""; fi])
  33
  34 dnl AC_ARG_WITH(ipc,
  35 dnl [  --enable-ipc            use inter-process communication for DDE],
  36 dnl [if test "$enableval" = "no"; then : ; else OPTIONS="-DCONFIG_IPC"; fi])
  37
  38 AC_ARG_ENABLE(debug,
  39 [  --disable-debug         compile out all debugging messages],
  40 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  41
  42 AC_ARG_ENABLE(trace,
  43 [  --disable-trace         compile out TRACE messages],
  44 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  45
  46 AC_ARG_WITH(reentrant-x,
  47 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  48
  49 AC_SUBST(MAIN_TARGET)
  50 AC_SUBST(LIB_TARGET)
  51 AC_SUBST(ALT_LINK)
  52 AC_SUBST(OPTIONS)
  53
  54 if test "$DEBUG_MSGS" = "no"
  55 then
  56     AC_DEFINE(NO_DEBUG_MSGS)
  57     AC_DEFINE(NO_TRACE_MSGS)
  58 else
  59     if test "$TRACE_MSGS" = "no"
  60     then
  61         AC_DEFINE(NO_TRACE_MSGS)
  62     fi
  63 fi
  64
  65 dnl **** Check for some programs ****
  66
  67 AC_PROG_MAKE_SET
  68 AC_PROG_CC
  69 AC_PROG_CPP
  70 AC_PATH_XTRA
  71 AC_PROG_YACC
  72 AC_PROG_LEX
  73 AC_PROG_RANLIB
  74 AC_PROG_INSTALL
  75 AC_PROG_LN_S
  76 AC_CHECK_PROG(C2MAN,c2man,c2man,true)
  77
  78 dnl **** Check for some libraries ****
  79
  80 dnl Check for -li386 for NetBSD and OpenBSD
  81 AC_CHECK_LIB(i386,i386_set_ldt)
  82 dnl Check for -lossaudio for NetBSD
  83 AC_CHECK_LIB(ossaudio,_oss_ioctl)
  84 dnl Check for -lw for Solaris
  85 AC_CHECK_LIB(w,iswalnum)
  86 dnl Check for -lnsl for Solaris
  87 AC_CHECK_FUNCS(gethostbyname)
  88 if test "$ac_cv_func_gethostbyname" = "no"
  89 then
  90     AC_CHECK_LIB(nsl,gethostbyname)
  91 fi
  92 dnl Check for -lxpg4 for FreeBSD
  93 AC_CHECK_LIB(xpg4,setrunelocale)
  94 dnl Check for -ldl
  95 AC_CHECK_LIB(dl,dlopen)
  96 AC_SUBST(XLIB)
  97 if test "$have_x" = "yes"
  98 then
  99     XLIB="-lXext -lX11"
 100     ac_save_CPPFLAGS="$CPPFLAGS"
 101     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 102
 103     dnl Check for -lXpm
 104     AC_CHECK_HEADERS(X11/xpm.h)
 105     if test "$ac_cv_header_X11_xpm_h" = "yes"
 106     then
 107         AC_CHECK_LIB(Xpm,XpmCreatePixmapFromData,AC_DEFINE(HAVE_LIBXXPM) X_PRE_LIBS="$X_PRE_LIBS -lXpm",,$X_LIBS -lXext -lX11)
 108     fi
 109
 110     dnl Check for X Shm extension
 111     AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/XShm.h)
 112     if test "$ac_cv_header_X11_Xlib_h" = "yes" -a "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 113     then
 114         AC_CHECK_LIB(Xext,XShmQueryExtension,AC_DEFINE(HAVE_LIBXXSHM),,$X_LIBS -lXext -lX11)
 115     fi
 116     dnl Check for XFree86 DGA extension
 117     AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/xf86dga.h)
 118     if test "$ac_cv_header_X11_Xlib_h" = "yes" -a "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 119     then
 120          AC_CHECK_LIB(Xxf86dga,XF86DGAQueryExtension,AC_DEFINE(HAVE_LIBXXF86DGA) X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga",,$X_LIBS -lXext -lX11)
 121     fi
 122
 123     dnl Check for XFree86 VMODE extension
 124     AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/xf86vmode.h)
 125     if test "$ac_cv_header_X11_Xlib_h" = "yes" -a "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 126     then
 127         AC_CHECK_LIB(Xxf86vm,XF86VidModeQueryExtension,AC_DEFINE(HAVE_LIBXXF86VM) X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm",,$X_LIBS -lXext -lX11)
 128     fi
 129
 130     dnl Check for the presence of Mesa
 131     AC_CHECK_HEADERS(GL/gl.h GL/osmesa.h)
 132     if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_osmesa_h" = "yes"
 133     then
 134         dnl Check for some problems due to old Mesa versions
 135         AC_CACHE_CHECK("for up-to-date Mesa version", wine_cv_mesa_version_OK,
 136           AC_TRY_COMPILE(
 137             [#include <GL/gl.h>],
 138             [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 139             [wine_cv_mesa_version_OK="yes"],
 140             [wine_cv_mesa_version_OK="no"]
 141           )
 142         )
 143
 144         if test "$wine_cv_mesa_version_OK" = "yes"
 145         then
 146             dnl Check for the presense of the library
 147             AC_CHECK_LIB(MesaGL,OSMesaCreateContext,AC_DEFINE(HAVE_LIBMESAGL) X_PRE_LIBS="$X_PRE_LIBS -lMesaGL",,$X_LIBS -lXext -lX11 -lm)
 148         fi
 149     fi
 150
 151     CPPFLAGS="$ac_save_CPPFLAGS"
 152 else
 153     XLIB=""
 154     X_CFLAGS=""
 155     X_LIBS=""
 156 fi
 157
 158 dnl **** Check which curses lib to use ***
 159 AC_CHECK_HEADERS(ncurses.h)
 160 if test "$ac_cv_header_ncurses_h" = "yes"
 161 then
 162     AC_CHECK_LIB(ncurses,waddch)
 163 fi
 164 if test "$ac_cv_lib_ncurses_waddch" = "yes"
 165 then
 166     AC_CHECK_LIB(ncurses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 167     AC_CHECK_LIB(ncurses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 168 else
 169     AC_CHECK_HEADERS(curses.h)
 170     if test "$ac_cv_header_curses_h" = "yes"
 171     then
 172        AC_CHECK_LIB(curses,waddch)
 173        AC_CHECK_LIB(curses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 174        AC_CHECK_LIB(curses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 175     fi
 176 fi
 177
 178 dnl **** Check for IPX (currently Linux only) ****
 179 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
 180  AC_TRY_COMPILE(
 181    [#include <sys/socket.h>
 182     #include <netipx/ipx.h>],
 183    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 184    [AC_DEFINE(HAVE_IPX_GNU)
 185     ac_cv_c_ipx_gnu="yes"],
 186    [ac_cv_c_ipx_gnu="no"])
 187  )
 188
 189 if test "$ac_cv_c_ipx_gnu" = "no"
 190 then
 191  AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
 192   AC_TRY_COMPILE(
 193     [#include <sys/socket.h>
 194      #include <asm/types.h>
 195      #include <linux/ipx.h>],
 196     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 197     [AC_DEFINE(HAVE_IPX_LINUX)
 198      ac_cv_c_ipx_linux="yes"],
 199     [ac_cv_c_ipx_linux="no"])
 200   )
 201 fi
 202
 203 dnl **** Check for Open Sound System ****
 204 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 205
 206 AC_CACHE_CHECK("for Open Sound System",
 207         ac_cv_c_opensoundsystem,
 208         AC_TRY_COMPILE([
 209         #if defined(HAVE_SYS_SOUNDCARD_H)
 210                 #include <sys/soundcard.h>
 211         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 212                 #include <machine/soundcard.h>
 213         #elif defined(HAVE_SOUNDCARD_H)
 214                 #include <soundcard.h>
 215         #endif
 216         ],[
 217
 218 /* check for one of the Open Sound System specific SNDCTL_ defines */
 219 #if !defined(SNDCTL_DSP_STEREO)
 220 #error No open sound system
 221 #endif
 222 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 223
 224 if test "$ac_cv_c_opensoundsystem" = "yes"
 225 then
 226     AC_DEFINE(HAVE_OSS)
 227 fi
 228
 229 dnl **** Check for union semun ****
 230
 231 AC_CACHE_CHECK("for union semun", ac_cv_c_union_semun,
 232  AC_TRY_COMPILE([#include <sys/types.h>
 233 #include <sys/sem.h>],[union semun foo],
 234                 ac_cv_c_union_semun="yes", ac_cv_c_union_semun="no"))
 235 if test "$ac_cv_c_union_semun" = "yes"
 236 then
 237     AC_DEFINE(HAVE_UNION_SEMUN)
 238 fi
 239
 240 dnl **** If ln -s doesn't work, use cp instead ****
 241 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 242
 243 dnl **** Check for gcc strength-reduce bug ****
 244
 245 if test "x${GCC}" = "xyes"
 246 then
 247   CFLAGS="$CFLAGS -Wall"
 248   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
 249                   AC_TRY_RUN([
 250 int main(void) {
 251   static int Array[[3]];
 252   unsigned int B = 3;
 253   int i;
 254   for(i=0; i<B; i++) Array[[i]] = i - 3;
 255   exit( Array[[1]] != -2 );
 256 }],
 257     ac_cv_c_gcc_strength_bug="no",
 258     ac_cv_c_gcc_strength_bug="yes",
 259     ac_cv_c_gcc_strength_bug="yes") )
 260   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 261   then
 262     CFLAGS="$CFLAGS -fno-strength-reduce"
 263   fi
 264 fi
 265
 266 dnl **** Check for underscore on external symbols ****
 267
 268 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
 269                ac_cv_c_extern_prefix,
 270 [saved_libs=$LIBS
 271 LIBS="conftest_asm.s $LIBS"
 272 cat > conftest_asm.s <<EOF
 273         .globl _ac_test
 274 _ac_test:
 275         .long 0
 276 EOF
 277 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 278             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 279 LIBS=$saved_libs])
 280 if test "$ac_cv_c_extern_prefix" = "yes"
 281 then
 282   AC_DEFINE(NEED_UNDERSCORE_PREFIX)
 283 fi
 284
 285 dnl **** Check for .string in assembler ****
 286
 287 AC_CACHE_CHECK("whether assembler accepts .string",
 288                ac_cv_c_asm_string,
 289 [saved_libs=$LIBS
 290 LIBS="conftest_asm.s $LIBS"
 291 cat > conftest_asm.s <<EOF
 292         .string "test"
 293 EOF
 294 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 295 LIBS=$saved_libs])
 296 if test "$ac_cv_c_asm_string" = "yes"
 297 then
 298   AC_DEFINE(HAVE_ASM_STRING)
 299 fi
 300
 301 dnl **** Check for working dll ****
 302
 303 DLLFLAGS=""
 304 LDSHARED=""
 305 if test "$LIB_TARGET" = "libwine.so.1.0"
 306 then
 307   AC_CACHE_CHECK("whether we can build a Linux dll",
 308                  ac_cv_c_dll_linux,
 309   [saved_cflags=$CFLAGS
 310   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0"
 311   AC_TRY_LINK(,[return 1],ac_cv_c_dll_linux="yes",ac_cv_c_dll_linux="no")
 312   CFLAGS=$saved_cflags
 313   ])
 314   if test "$ac_cv_c_dll_linux" = "yes"
 315   then
 316     DLLFLAGS="-fPIC"
 317     LDSHARED="\$(CC) -shared -Wl,-soname,libwine.so"
 318   else
 319     AC_CACHE_CHECK("whether we can build a NetBSD dll",
 320                    ac_cv_c_dll_netbsd,
 321     [saved_cflags=$CFLAGS
 322     CFLAGS="$CFLAGS -fPIC -Bshareable -Bforcearchive"
 323     AC_TRY_LINK(,[return 1],ac_cv_c_dll_netbsd="yes",ac_cv_c_dll_netbsd="no")
 324     CFLAGS=$saved_cflags
 325     ])
 326     if test "$ac_cv_c_dll_netbsd" = "yes"
 327     then
 328       DLLFLAGS="-fPIC"
 329       LDSHARED="ld -Bshareable -Bforcearchive"
 330     fi
 331   fi
 332   if test "$ac_cv_c_dll_linux" = "no" -a "$ac_cv_c_dll_netbsd" = "no"
 333   then
 334     LIB_TARGET="libwine.a"
 335   fi
 336 fi
 337 AC_SUBST(DLLFLAGS)
 338 AC_SUBST(LDSHARED)
 339
 340 dnl **** Check for reentrant libc ****
 341 dnl
 342 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 343 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 344
 345 AC_CACHE_CHECK("for reentrant libc", wine_cv_libc_reentrant,
 346   [AC_TRY_RUN([int myerrno = 0;
 347 char buf[256];
 348 int *__errno_location(){return &myerrno;}
 349 main(){connect(0,buf,255); exit(!myerrno);}],
 350   wine_cv_libc_reentrant=yes, wine_cv_libc_reentrant=no,
 351   wine_cv_libc_reentrant=yes ) ] )
 352 if test "$wine_cv_libc_reentrant" = "no"
 353 then
 354   AC_DEFINE(NO_REENTRANT_LIBC)
 355 fi
 356
 357 dnl **** Check for reentrant X libraries ****
 358 dnl
 359 dnl This may fail to determine whether X libraries are reentrant if
 360 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 361 dnl is possible with the --without-reentrant-x option.
 362
 363 if test "$have_x" = "yes"
 364 then
 365 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
 366   [ if test "x$with_reentrant_x" = "xno"
 367     then
 368         wine_cv_x_reentrant=no
 369     else
 370         libX11_ckeck=none
 371         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 372             if test -r $dir/libX11.so; then
 373                 libX11_check="-D $dir/libX11.so"
 374                 break 1
 375             fi
 376             if test -r $dir/libX11.a; then
 377                 libX11_check="$dir/libX11.a"
 378                 break 1
 379             fi
 380         done
 381         if test "$libX11_check" != "none"; then
 382             if nm $libX11_check | grep __errno_location >/dev/null 2>&1
 383             then
 384                 wine_cv_x_reentrant=yes
 385             else
 386                 wine_cv_x_reentrant=no
 387             fi
 388         else
 389             wine_cv_x_reentrant=unknown
 390         fi
 391     fi ] )
 392 else
 393     wine_cv_x_reentrant=no
 394 fi
 395 if test "$wine_cv_x_reentrant" = "no"
 396 then
 397   AC_DEFINE(NO_REENTRANT_X11)
 398 fi
 399
 400 dnl **** Check for functions and header files ****
 401
 402 AC_CHECK_FUNCS(clone getpagesize memmove sendmsg sigaltstack strerror stricmp tcgetattr timegm usleep wait4 waitpid vfscanf)
 403 AC_CHECK_HEADERS(wctype.h sys/syscall.h syscall.h sys/param.h sys/vfs.h sys/mount.h sys/statfs.h float.h linux/cdrom.h linux/ucdrom.h sys/cdio.h sys/filio.h sys/modem.h strings.h sys/strtio.h dlfcn.h unistd.h sys/sockio.h net/if.h netinet/in.h sys/file.h libio.h curses.h ncurses.h elf.h arpa/nameser.h resolv.h)
 404 AC_HEADER_STAT()
 405 AC_C_CONST()
 406 AC_TYPE_SIZE_T()
 407 AC_CHECK_SIZEOF(long long,0)
 408
 409 dnl **** Check for sendmsg in -lsocket if not found above ****
 410
 411 if test $ac_cv_func_sendmsg = no; then
 412     AC_CHECK_LIB(socket,sendmsg)
 413 fi
 414
 415 dnl **** statfs checks ****
 416
 417 if test "$ac_cv_header_sys_vfs_h" = "yes"
 418 then
 419     AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
 420                     wine_cv_sys_vfs_has_statfs,
 421         AC_TRY_COMPILE([
 422         #include <sys/types.h>
 423         #ifdef HAVE_SYS_PARAM_H
 424         # include <sys/param.h>
 425         #endif
 426         #include <sys/vfs.h>
 427         ],[
 428                 struct statfs stfs;
 429
 430                 memset(&stfs,0,sizeof(stfs));
 431         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
 432         )
 433     )
 434     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
 435     then
 436       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS)
 437     fi
 438 fi
 439
 440 if test "$ac_cv_header_sys_statfs_h" = "yes"
 441 then
 442     AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
 443                     wine_cv_sys_statfs_has_statfs,
 444         AC_TRY_COMPILE([
 445         #include <sys/types.h>
 446         #ifdef HAVE_SYS_PARAM_H
 447         # include <sys/param.h>
 448         #endif
 449         #include <sys/statfs.h>
 450         ],[
 451                 struct statfs stfs;
 452         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
 453         )
 454     )
 455     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
 456     then
 457       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS)
 458     fi
 459 fi
 460
 461 if test "$ac_cv_header_sys_mount_h" = "yes"
 462 then
 463     AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
 464                     wine_cv_sys_mount_has_statfs,
 465         AC_TRY_COMPILE([
 466         #include <sys/types.h>
 467         #ifdef HAVE_SYS_PARAM_H
 468         # include <sys/param.h>
 469         #endif
 470         #include <sys/mount.h>
 471         ],[
 472                 struct statfs stfs;
 473         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
 474         )
 475     )
 476     if test "$wine_cv_sys_mount_has_statfs" = "yes"
 477     then
 478       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT)
 479     fi
 480 fi
 481
 482 dnl **** FIXME: what about mixed cases, where we need two of them? ***
 483
 484 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
 485   [ if test "x$statfs_bfree" = "xno"
 486     then
 487         wine_cv_statfs_bfree=no
 488     else
 489         AC_TRY_COMPILE([
 490         #include <sys/types.h>
 491         #ifdef HAVE_SYS_PARAM_H
 492         # include <sys/param.h>
 493         #endif
 494         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 495         # include <sys/mount.h>
 496         #else
 497         # ifdef STATFS_DEFINED_BY_SYS_VFS
 498         #  include <sys/vfs.h>
 499         # else
 500         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 501         #   include <sys/statfs.h>
 502         #  endif
 503         # endif
 504         #endif
 505         ],[
 506                 struct statfs stfs;
 507
 508                 stfs.f_bfree++;
 509         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
 510         )
 511     fi ] )
 512 if test "$wine_cv_statfs_bfree" = "yes"
 513 then
 514   AC_DEFINE(STATFS_HAS_BFREE)
 515 fi
 516
 517 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
 518   [ if test "x$statfs_bavail" = "xno"
 519     then
 520         wine_cv_statfs_bavail=no
 521     else
 522         AC_TRY_COMPILE([
 523         #include <sys/types.h>
 524         #ifdef HAVE_SYS_PARAM_H
 525         # include <sys/param.h>
 526         #endif
 527         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 528         # include <sys/mount.h>
 529         #else
 530         # ifdef STATFS_DEFINED_BY_SYS_VFS
 531         #  include <sys/vfs.h>
 532         # else
 533         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 534         #   include <sys/statfs.h>
 535         #  endif
 536         # endif
 537         #endif
 538         ],[
 539                 struct statfs stfs;
 540
 541                 stfs.f_bavail++;
 542         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
 543         )
 544     fi ] )
 545 if test "$wine_cv_statfs_bavail" = "yes"
 546 then
 547   AC_DEFINE(STATFS_HAS_BAVAIL)
 548 fi
 549
 550 dnl *** check for working sigaltstack
 551 dnl glibc 2.0x defines it, but it always fails... so it is useless for us.
 552
 553 AC_CACHE_CHECK("for working sigaltstack",
 554         ac_cv_c_working_sigaltstack,
 555         AC_TRY_RUN([
 556         #include <stdio.h>
 557         #include <time.h> /* <sys/time.h> ? bad magic without end */
 558         #include <sys/types.h>
 559         #include <sys/signal.h>
 560         #ifdef HAVE_SYS_PARAM_H
 561         # include <sys/param.h>
 562         #endif
 563         #ifdef HAVE_SYSCALL_H
 564         # include <syscall.h>
 565         #else
 566         # ifdef HAVE_SYS_SYSCALL_H
 567         #  include <sys/syscall.h>
 568         # endif
 569         #endif
 570
 571         unsigned char *xaltstack;
 572
 573         int
 574         main(int argc,char **argv) {
 575             struct sigaltstack  ss;
 576
 577             xaltstack = malloc(16384);
 578             ss.ss_sp    = xaltstack;
 579             ss.ss_size  = 16384;
 580             ss.ss_flags = 0;
 581             if (sigaltstack(&ss, NULL) < 0) {
 582                 /* this catches the glibc case */
 583                 perror("sigaltstack");
 584                 return (1); /* aka exit(1) aka fail */
 585             }
 586             /* assume it works. */
 587             return 0; /* OK */
 588         }
 589         ],
 590         ac_cv_c_working_sigaltstack="yes",
 591         ac_cv_c_working_sigaltstack="no",
 592         ac_cv_c_working_sigaltstack="no"
 593 ))
 594
 595 if test "$ac_cv_c_working_sigaltstack" = "yes"
 596 then
 597     AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
 598 fi
 599
 600
 601 dnl *** check for file descriptor passing with msg_accrights
 602
 603 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
 604  AC_TRY_COMPILE([#include <sys/types.h>
 605 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
 606                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
 607 if test "$ac_cv_c_msg_accrights" = "yes"
 608 then
 609     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS)
 610 fi
 611
 612 dnl **** Generate output files ****
 613
 614 MAKE_RULES=Make.rules
 615 AC_SUBST_FILE(MAKE_RULES)
 616
 617 AC_OUTPUT([
 618 Make.rules
 619 Makefile
 620 console/Makefile
 621 controls/Makefile
 622 debugger/Makefile
 623 dlls/Makefile
 624 dlls/advapi32/Makefile
 625 dlls/avifil32/Makefile
 626 dlls/comctl32/Makefile
 627 dlls/commdlg/Makefile
 628 dlls/imagehlp/Makefile
 629 dlls/msacm/Makefile
 630 dlls/msacm32/Makefile
 631 dlls/ntdll/Makefile
 632 dlls/psapi/Makefile
 633 dlls/rasapi32/Makefile
 634 dlls/shell32/Makefile
 635 dlls/tapi32/Makefile
 636 dlls/ver/Makefile
 637 dlls/version/Makefile
 638 dlls/winaspi/Makefile
 639 dlls/wnaspi32/Makefile
 640 documentation/Makefile
 641 files/Makefile
 642 graphics/Makefile
 643 graphics/metafiledrv/Makefile
 644 graphics/psdrv/Makefile
 645 graphics/ttydrv/Makefile
 646 graphics/win16drv/Makefile
 647 graphics/x11drv/Makefile
 648 if1632/Makefile
 649 include/Makefile
 650 ipc/Makefile
 651 library/Makefile
 652 libtest/Makefile
 653 loader/Makefile
 654 loader/ne/Makefile
 655 loader/dos/Makefile
 656 memory/Makefile
 657 misc/Makefile
 658 miscemu/Makefile
 659 msdos/Makefile
 660 multimedia/Makefile
 661 objects/Makefile
 662 ole/Makefile
 663 programs/Makefile
 664 programs/clock/Makefile
 665 programs/cmdlgtst/Makefile
 666 programs/control/Makefile
 667 programs/avitools/Makefile
 668 programs/notepad/Makefile
 669 programs/progman/Makefile
 670 programs/regtest/Makefile
 671 programs/regapi/Makefile
 672 programs/view/Makefile
 673 programs/winhelp/Makefile
 674 programs/winver/Makefile
 675 rc/Makefile
 676 relay32/Makefile
 677 resources/Makefile
 678 scheduler/Makefile
 679 server/Makefile
 680 tools/Makefile
 681 tools/wrc/Makefile
 682 tsx11/Makefile
 683 win32/Makefile
 684 windows/Makefile
 685 windows/ttydrv/Makefile
 686 windows/x11drv/Makefile ])
 687
 688 if test "$have_x" = "no"
 689 then
 690   echo
 691   echo "*** Warning: X development files not found. Wine will be built without"
 692   echo "*** X support, which currently does not work, and would probably not be"
 693   echo "*** what you want anyway. You will need to install devel packages of"
 694   echo "*** Xlib/Xfree86 and Xpm at the very least."
 695 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
 696 then
 697   echo
 698   echo "*** Warning: Xpm development files not found. Wine will be built without"
 699   echo "*** Xpm support, which currently does not work. You will need to install"
 700   echo "*** devel packages of Xpm."
 701 fi
 702
 703 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
 704 then
 705   echo
 706   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
 707   echo "*** terminal resize support. Consider upgrading ncurses."
 708 fi
 709
 710 if test "$wine_cv_libc_reentrant" = "no"
 711 then
 712   echo
 713   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
 714   echo "*** thread support. Consider upgrading libc to a more recent"
 715   echo "*** reentrant version of libc."
 716 fi
 717
 718 if test "$wine_cv_mesa_version_OK" = "no"
 719 then
 720   echo
 721   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
 722   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)"
 723 fi
 724
 725 echo
 726 echo "Configure finished.  Do 'make depend && make' to compile Wine."
 727 echo
 728
 729 dnl Local Variables:
 730 dnl comment-start: "dnl "
 731 dnl comment-end: ""
 732 dnl comment-start-skip: "\\bdnl\\b\\s *"
 733 dnl compile-command: "autoconf"
 734 dnl End: