tools/wrc/parser.l

   1 /* -*-C-*-
   2  *
   3  * Copyright 1998-2000  Bertho A. Stultiens (BS)
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9  *
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18  *
  19  * History:
  20  * 21-May-2000 BS       - Fixed the ident requirement of resource names
  21  *                        which can be keywords.
  22  * 30-Apr-2000 BS       - Reintegration into the wine-tree
  23  * 11-Jan-2000 BS       - Very drastic cleanup because we don't have a
  24  *                        preprocessor in here anymore.
  25  * 02-Jan-2000 BS       - Removed the preprocessor code
  26  * 23-Dec-1999 BS       - Removed the copyright for Martin von Loewis.
  27  *                        There is really nothing left of his code in
  28  *                        this parser.
  29  * 20-Jun-1998 BS       - Changed the filename conversion. Filenames are
  30  *                        case-sensitive inder *nix, but not under dos.
  31  *                        default behaviour is to convert to lower case.
  32  *                      - All backslashes are converted to forward and
  33  *                        both single and double slash is recognized as
  34  *                        MS/Borland does.
  35  *                      - Fixed a bug in 'yywf' case that prevented
  36  *                        double quoted names to be scanned propperly.
  37  *
  38  * 19-May-1998 BS       - Started to build a preprocessor.
  39  *                      - Changed keyword processing completely to
  40  *                        table-lookups.
  41  *
  42  * 20-Apr-1998 BS       - Added ';' comment stripping
  43  *
  44  * 17-Apr-1998 BS       - Made the win32 keywords optional when compiling in
  45  *                        16bit mode
  46  *
  47  * 15-Apr-1998 BS       - Changed string handling to include escapes
  48  *                      - Added unicode string handling (no codepage
  49  *                        translation though).
  50  *                      - 'Borrowed' the main idea of string scanning from
  51  *                        the flex manual pages.
  52  *                      - Added conditional handling of scanning depending
  53  *                        on the state of the parser. This was mainly required
  54  *                        to distinguish a file to load or raw data that
  55  *                        follows. MS's definition of filenames is rather
  56  *                        complex... It can be unquoted or double quoted. If
  57  *                        double quoted, then the '\\' char is not automatically
  58  *                        escaped according to Borland's rc compiler, but it
  59  *                        accepts both "\\path\\file.rc" and "\path\file.rc".
  60  *                        This makes life very hard! I go for the escaped
  61  *                        version, as this seems to be the documented way...
  62  *                      - Single quoted strings are now parsed and converted
  63  *                        here.
  64  *                      - Added comment stripping. The implementation is
  65  *                        'borrowed' from the flex manpages.
  66  *                      - Rebuild string processing so that it may contain
  67  *                        escaped '\0'.
  68  */
  69
  70 /* Exclusive string handling */
  71 %x tkstr
  72 /* Exclusive unicode string handling */
  73 %x tklstr
  74 /* Exclusive rcdata single quoted data handling */
  75 %x tkrcd
  76 /* Exclusive comment eating... */
  77 %x comment
  78 /* Set when stripping c-junk */
  79 %x pp_cstrip
  80 /* Set when scanning #line style directives */
  81 %x pp_line
  82 /* Set when scanning #pragma */
  83 %x pp_pragma
  84 %x pp_code_page
  85
  86 %option stack
  87 %option noinput nounput noyy_top_state noyywrap
  88 %option 8bit never-interactive
  89 %option prefix="parser_"
  90
  91 /* Some shortcut definitions */
  92 ws      [ \f\t\r]
  93 cident  [a-zA-Z_][0-9a-zA-Z_]*
  94
  95 %{
  96
  97 /*#define LEX_DEBUG*/
  98
  99 #include "config.h"
 100
 101 #include <stdio.h>
 102 #include <stdlib.h>
 103 #include <string.h>
 104 #include <ctype.h>
 105 #include <assert.h>
 106 #include <errno.h>
 107 #include <limits.h>
 108
 109 #ifdef HAVE_UNISTD_H
 110 #include <unistd.h>
 111 #else
 112 #define YY_NO_UNISTD_H
 113 #endif
 114
 115 #include "wine/unicode.h"
 116 #include "wrc.h"
 117 #include "utils.h"
 118 #include "parser.h"
 119 #include "newstruc.h"
 120
 121 #include "parser.tab.h"
 122
 123 /* Always update the current character position within a line */
 124 #define YY_USER_ACTION  char_number+=yyleng; wanted_id = want_id; want_id = 0;
 125
 126 #define YY_USER_INIT current_codepage = -1;
 127
 128 static void addcchar(char c);
 129 static void addwchar(WCHAR s);
 130 static string_t *get_buffered_cstring(void);
 131 static string_t *get_buffered_wstring(void);
 132 static string_t *make_string(char *s);
 133
 134 static char *cbuffer;           /* Buffers for string collection */
 135 static int cbufidx;
 136 static int cbufalloc = 0;
 137 static WCHAR *wbuffer;
 138 static int wbufidx;
 139 static int wbufalloc = 0;
 140
 141 static int current_codepage = -1;  /* use language default */
 142
 143 /*
 144  * This one is a bit tricky.
 145  * We set 'want_id' in the parser to get the first
 146  * identifier we get across in the scanner, but we
 147  * also want it to be reset at nearly any token we
 148  * see. Exceptions are:
 149  * - newlines
 150  * - comments
 151  * - whitespace
 152  *
 153  * The scanner will automatically reset 'want_id'
 154  * after *each* scanner reduction and puts is value
 155  * into the var below. In this way we can see the
 156  * state after the YY_RULE_SETUP (i.e. the user action;
 157  * see above) and don't have to worry too much when
 158  * it needs to be reset.
 159  */
 160 static int wanted_id = 0;
 161 static int save_wanted_id;      /* To save across comment reductions */
 162
 163 struct keyword {
 164         const char      *keyword;
 165         int             token;
 166         int             isextension;
 167         int             needcase;
 168         int             alwayskw;
 169 };
 170
 171 static struct keyword keywords[] = {
 172         { "ACCELERATORS",       tACCELERATORS,          0, 0, 0},
 173         { "ALT",                tALT,                   0, 0, 0},
 174         { "ASCII",              tASCII,                 0, 0, 0},
 175         { "AUTO3STATE",         tAUTO3STATE,            1, 0, 0},
 176         { "AUTOCHECKBOX",       tAUTOCHECKBOX,          1, 0, 0},
 177         { "AUTORADIOBUTTON",    tAUTORADIOBUTTON,       1, 0, 0},
 178         { "BEGIN",              tBEGIN,                 0, 0, 0},
 179         { "BITMAP",             tBITMAP,                0, 0, 0},
 180         { "BLOCK",              tBLOCK,                 0, 0, 0},
 181         { "BUTTON",             tBUTTON,                1, 0, 0},
 182         { "CAPTION",            tCAPTION,               0, 0, 0},
 183         { "CHARACTERISTICS",    tCHARACTERISTICS,       1, 0, 0},
 184         { "CHECKBOX",           tCHECKBOX,              0, 0, 0},
 185         { "CHECKED",            tCHECKED,               0, 0, 0},
 186         { "CLASS",              tCLASS,                 0, 0, 0},
 187         { "COMBOBOX",           tCOMBOBOX,              0, 0, 0},
 188         { "CONTROL",            tCONTROL,               0, 0, 0},
 189         { "CTEXT",              tCTEXT,                 0, 0, 0},
 190         { "CURSOR",             tCURSOR,                0, 0, 0},
 191         { "DEFPUSHBUTTON",      tDEFPUSHBUTTON,         0, 0, 0},
 192         { "DIALOG",             tDIALOG,                0, 0, 0},
 193         { "DIALOGEX",           tDIALOGEX,              1, 0, 0},
 194         { "DISCARDABLE",        tDISCARDABLE,           0, 0, 0},
 195         { "DLGINIT",            tDLGINIT,               0, 0, 0},
 196         { "EDITTEXT",           tEDITTEXT,              0, 0, 0},
 197         { "END",                tEND,                   0, 0, 0},
 198         { "EXSTYLE",            tEXSTYLE,               0, 0, 0},
 199         { "FILEFLAGS",          tFILEFLAGS,             0, 0, 0},
 200         { "FILEFLAGSMASK",      tFILEFLAGSMASK,         0, 0, 0},
 201         { "FILEOS",             tFILEOS,                0, 0, 0},
 202         { "FILESUBTYPE",        tFILESUBTYPE,           0, 0, 0},
 203         { "FILETYPE",           tFILETYPE,              0, 0, 0},
 204         { "FILEVERSION",        tFILEVERSION,           0, 0, 0},
 205         { "FIXED",              tFIXED,                 0, 0, 0},
 206         { "FONT",               tFONT,                  0, 0, 0},
 207         { "FONTDIR",            tFONTDIR,               0, 0, 0},       /* This is a Borland BRC extension */
 208         { "GRAYED",             tGRAYED,                0, 0, 0},
 209         { "GROUPBOX",           tGROUPBOX,              0, 0, 0},
 210         { "HELP",               tHELP,                  0, 0, 0},
 211         { "HTML",               tHTML,                  0, 0, 0},
 212         { "ICON",               tICON,                  0, 0, 0},
 213         { "IMPURE",             tIMPURE,                0, 0, 0},
 214         { "INACTIVE",           tINACTIVE,              0, 0, 0},
 215         { "LANGUAGE",           tLANGUAGE,              1, 0, 1},
 216         { "LISTBOX",            tLISTBOX,               0, 0, 0},
 217         { "LOADONCALL",         tLOADONCALL,            0, 0, 0},
 218         { "LTEXT",              tLTEXT,                 0, 0, 0},
 219         { "MENU",               tMENU,                  0, 0, 0},
 220         { "MENUBARBREAK",       tMENUBARBREAK,          0, 0, 0},
 221         { "MENUBREAK",          tMENUBREAK,             0, 0, 0},
 222         { "MENUEX",             tMENUEX,                1, 0, 0},
 223         { "MENUITEM",           tMENUITEM,              0, 0, 0},
 224         { "MESSAGETABLE",       tMESSAGETABLE,          1, 0, 0},
 225         { "MOVEABLE",           tMOVEABLE,              0, 0, 0},
 226         { "NOINVERT",           tNOINVERT,              0, 0, 0},
 227         { "NOT",                tNOT,                   0, 0, 0},
 228         { "POPUP",              tPOPUP,                 0, 0, 0},
 229         { "PRELOAD",            tPRELOAD,               0, 0, 0},
 230         { "PRODUCTVERSION",     tPRODUCTVERSION,        0, 0, 0},
 231         { "PURE",               tPURE,                  0, 0, 0},
 232         { "PUSHBUTTON",         tPUSHBUTTON,            0, 0, 0},
 233         { "RADIOBUTTON",        tRADIOBUTTON,           0, 0, 0},
 234         { "RCDATA",             tRCDATA,                0, 0, 0},
 235         { "RTEXT",              tRTEXT,                 0, 0, 0},
 236         { "SCROLLBAR",          tSCROLLBAR,             0, 0, 0},
 237         { "SEPARATOR",          tSEPARATOR,             0, 0, 0},
 238         { "SHIFT",              tSHIFT,                 0, 0, 0},
 239         { "STATE3",             tSTATE3,                1, 0, 0},
 240         { "STRING",             tSTRING,                0, 0, 0},
 241         { "STRINGTABLE",        tSTRINGTABLE,           0, 0, 1},
 242         { "STYLE",              tSTYLE,                 0, 0, 0},
 243         { "TOOLBAR",            tTOOLBAR,               1, 0, 0},
 244         { "VALUE",              tVALUE,                 0, 0, 0},
 245         { "VERSION",            tVERSION,               1, 0, 0},
 246         { "VERSIONINFO",        tVERSIONINFO,           0, 0, 0},
 247         { "VIRTKEY",            tVIRTKEY,               0, 0, 0}
 248 };
 249
 250 #define NKEYWORDS       (sizeof(keywords)/sizeof(keywords[0]))
 251 #define KWP(p)          ((const struct keyword *)(p))
 252 static int kw_cmp_func(const void *s1, const void *s2)
 253 {
 254         int ret;
 255         ret = strcasecmp(KWP(s1)->keyword, KWP(s2)->keyword);
 256         if(!ret && (KWP(s1)->needcase || KWP(s2)->needcase))
 257                 return strcmp(KWP(s1)->keyword, KWP(s2)->keyword);
 258         else
 259                 return ret;
 260 }
 261
 262 #define KW_BSEARCH
 263 #define DO_SORT
 264 static struct keyword *iskeyword(char *kw)
 265 {
 266         struct keyword *kwp;
 267         struct keyword key;
 268         key.keyword = kw;
 269         key.needcase = 0;
 270 #ifdef DO_SORT
 271         {
 272                 /* Make sure that it is sorted for bsearsh */
 273                 static int sorted = 0;
 274                 if(!sorted)
 275                 {
 276                         qsort(keywords, NKEYWORDS, sizeof(keywords[0]), kw_cmp_func);
 277                         sorted = 1;
 278                 }
 279         }
 280 #endif
 281 #ifdef KW_BSEARCH
 282         kwp = bsearch(&key, keywords, NKEYWORDS, sizeof(keywords[0]), kw_cmp_func);
 283 #else
 284         {
 285                 int i;
 286                 for(i = 0; i < NKEYWORDS; i++)
 287                 {
 288                         if(!kw_cmp_func(&key, &keywords[i]))
 289                                 break;
 290                 }
 291                 if(i < NKEYWORDS)
 292                         kwp = &keywords[i];
 293                 else
 294                         kwp = NULL;
 295         }
 296 #endif
 297
 298         if(kwp == NULL || (kwp->isextension && !extensions))
 299                 return NULL;
 300         else
 301                 return kwp;
 302 }
 303
 304 /* converts an integer in string form to an unsigned long and prints an error
 305  * on overflow */
 306 static unsigned long xstrtoul(const char *nptr, char **endptr, int base)
 307 {
 308     unsigned long l;
 309
 310     errno = 0;
 311     l = strtoul(nptr, endptr, base);
 312     if (l == ULONG_MAX && errno == ERANGE)
 313         parser_error("integer constant %s is too large", nptr);
 314     return l;
 315 }
 316
 317 %}
 318
 319 /*
 320  **************************************************************************
 321  * The flexer starts here
 322  **************************************************************************
 323  */
 324 %%
 325         /*
 326          * Catch the GCC-style line statements here and parse them.
 327          * This has the advantage that you can #include at any
 328          * stage in the resource file.
 329          * The preprocessor generates line directives in the format:
 330          * # <linenum> "filename" <codes>
 331          *
 332          * Codes can be a sequence of:
 333          * - 1 start of new file
 334          * - 2 returning to previous
 335          * - 3 system header
 336          * - 4 interpret as C-code
 337          *
 338          * 4 is not used and 1 mutually excludes 2
 339          * Anyhow, we are not really interested in these at all
 340          * because we only want to know the linenumber and
 341          * filename.
 342          */
 343 <INITIAL,pp_cstrip>^{ws}*\#{ws}*pragma{ws}+     yy_push_state(pp_pragma);
 344 <INITIAL,pp_cstrip>^{ws}*\#{ws}*        yy_push_state(pp_line);
 345 <pp_line>[^\n]* {
 346                 int lineno, len;
 347                 char *cptr;
 348                 char *fname;
 349                 yy_pop_state();
 350                 lineno = (int)strtol(yytext, &cptr, 10);
 351                 if(!lineno)
 352                         parser_error("Malformed '#...' line-directive; invalid linenumber");
 353                 fname = strchr(cptr, '"');
 354                 if(!fname)
 355                         parser_error("Malformed '#...' line-directive; missing filename");
 356                 fname++;
 357                 cptr = strchr(fname, '"');
 358                 if(!cptr)
 359                         parser_error("Malformed '#...' line-directive; missing terminating \"");
 360                 *cptr = '\0';
 361                 line_number = lineno - 1;       /* We didn't read the newline */
 362                 input_name = xstrdup(fname);
 363                 /* ignore contents of C include files */
 364                 len = strlen(input_name);
 365                 if (len > 1 && !strcasecmp( input_name + len - 2, ".h" ))
 366                     BEGIN(pp_cstrip);
 367                 else
 368                     BEGIN(INITIAL);
 369         }
 370
 371 <pp_pragma>code_page[^\n]*      yyless(9); yy_pop_state(); yy_push_state(pp_code_page);
 372 <pp_pragma>[^\n]*               yy_pop_state(); if (pedantic) parser_warning("Unrecognized #pragma directive '%s'\n",yytext);
 373
 374 <pp_code_page>\({ws}*default{ws}*\)[^\n]*       current_codepage = -1; yy_pop_state();
 375 <pp_code_page>\({ws}*utf8{ws}*\)[^\n]*          current_codepage = CP_UTF8; yy_pop_state();
 376 <pp_code_page>\({ws}*[0-9]+{ws}*\)[^\n]* {
 377         char *p = yytext;
 378         yy_pop_state();
 379         while (*p < '0' || *p > '9') p++;
 380         current_codepage = strtol( p, NULL, 10 );
 381         if (current_codepage != CP_UTF8 && !wine_cp_get_table( current_codepage ))
 382         {
 383             parser_error("Codepage %d not supported", current_codepage);
 384             current_codepage = 0;
 385         }
 386     }
 387 <pp_code_page>[^\n]*    yy_pop_state(); parser_error("Malformed #pragma code_page directive");
 388
 389         /*
 390          * Strip everything until a ';' taking
 391          * into account braces {} for structures,
 392          * classes and enums.
 393          */
 394 <pp_cstrip>\n                   line_number++; char_number = 1;
 395 <pp_cstrip>.                    ; /* ignore */
 396
 397 \{                      return tBEGIN;
 398 \}                      return tEND;
 399
 400 [0-9]+[lL]?             { parser_lval.num = xstrtoul(yytext,  0, 10);
 401                           return (yytext[yyleng-1] == 'L' || yytext[yyleng-1] == 'l') ? tLNUMBER : tNUMBER; }
 402 0[xX][0-9A-Fa-f]+[lL]?  { parser_lval.num = xstrtoul(yytext,  0, 16);
 403                           return (yytext[yyleng-1] == 'L' || yytext[yyleng-1] == 'l') ? tLNUMBER : tNUMBER; }
 404 0[oO][0-7]+[lL]?        { parser_lval.num = xstrtoul(yytext+2, 0, 8);
 405                           return (yytext[yyleng-1] == 'L' || yytext[yyleng-1] == 'l') ? tLNUMBER : tNUMBER; }
 406
 407         /*
 408          * The next two rules scan identifiers and filenames.
 409          * This is achieved by using the priority ruling
 410          * of the scanner where a '.' is valid in a filename
 411          * and *only* in a filename. In this case, the second
 412          * rule will be reduced because it is longer.
 413          */
 414 [A-Za-z_0-9.]+          {
 415                                 struct keyword *tok = iskeyword(yytext);
 416
 417                                 if(tok)
 418                                 {
 419                                         if(wanted_id && !tok->alwayskw)
 420                                         {
 421                                                 parser_lval.str = make_string(yytext);
 422                                                 return tIDENT;
 423                                         }
 424                                         else
 425                                                 return tok->token;
 426                                 }
 427                                 else
 428                                 {
 429                                         parser_lval.str = make_string(yytext);
 430                                         return tIDENT;
 431                                 }
 432                         }
 433 [A-Za-z_0-9./\\]+               parser_lval.str = make_string(yytext); return tFILENAME;
 434
 435         /*
 436          * Wide string scanning
 437          */
 438 L\"                     {
 439                                 yy_push_state(tklstr);
 440                                 wbufidx = 0;
 441                                 if(!win32)
 442                                         parser_warning("16bit resource contains unicode strings\n");
 443                         }
 444 <tklstr>\"{ws}+ |
 445 <tklstr>\"              {
 446                                 yy_pop_state();
 447                                 parser_lval.str = get_buffered_wstring();
 448                                 return tSTRING;
 449                         }
 450 <tklstr>\\[0-7]{1,6}    { /* octal escape sequence */
 451                                 unsigned int result;
 452                                 result = strtoul(yytext+1, 0, 8);
 453                                 if ( result > 0xffff )
 454                                         parser_error("Character constant out of range");
 455                                 addwchar((WCHAR)result);
 456                         }
 457 <tklstr>\\x[0-9a-fA-F]{4} {  /* hex escape sequence */
 458                                 unsigned int result;
 459                                 result = strtoul(yytext+2, 0, 16);
 460                                 addwchar((WCHAR)result);
 461                         }
 462 <tklstr>\\x[0-9a-fA-F]{1,3} {  parser_error("Invalid hex escape sequence '%s'", yytext); }
 463
 464 <tklstr>\\[0-9]+        parser_error("Bad escape sequence");
 465 <tklstr>\\\n{ws}*       line_number++; char_number = 1; /* backslash at EOL continues string after leading whitespace on next line */
 466 <tklstr>\\a             addwchar('\a');
 467 <tklstr>\\b             addwchar('\b');
 468 <tklstr>\\f             addwchar('\f');
 469 <tklstr>\\n             addwchar('\n');
 470 <tklstr>\\r             addwchar('\r');
 471 <tklstr>\\t             addwchar('\t');
 472 <tklstr>\\v             addwchar('\v');
 473 <tklstr>\\.             addwchar(yytext[1]);
 474 <tklstr>\\\r\n          addwchar(yytext[2]); line_number++; char_number = 1;
 475 <tklstr>\"\"            addwchar('\"');         /* "bla""bla"  -> "bla\"bla" */
 476 <tklstr>\\\"\"          addwchar('\"');         /* "bla\""bla" -> "bla\"bla" */
 477 <tklstr>\"{ws}+\"       ;                       /* "bla" "bla" -> "blabla" */
 478 <tklstr>[^\\\n\"]+      {
 479                                 char *yptr = yytext;
 480                                 while(*yptr)    /* FIXME: codepage translation */
 481                                         addwchar(*yptr++ & 0xff);
 482                         }
 483 <tklstr>\n              parser_error("Unterminated string");
 484
 485         /*
 486          * Normal string scanning
 487          */
 488 \"                      yy_push_state(tkstr); cbufidx = 0;
 489 <tkstr>\"{ws}+  |
 490 <tkstr>\"               {
 491                                 yy_pop_state();
 492                                 parser_lval.str = get_buffered_cstring();
 493                                 return tSTRING;
 494                         }
 495 <tkstr>\\[0-7]{1,3}     { /* octal escape sequence */
 496                                 int result;
 497                                 result = strtol(yytext+1, 0, 8);
 498                                 if ( result > 0xff )
 499                                         parser_error("Character constant out of range");
 500                                 addcchar((char)result);
 501                         }
 502 <tkstr>\\x[0-9a-fA-F]{2} {  /* hex escape sequence */
 503                                 int result;
 504                                 result = strtol(yytext+2, 0, 16);
 505                                 addcchar((char)result);
 506                         }
 507 <tkstr>\\x[0-9a-fA-F]   {  parser_error("Invalid hex escape sequence '%s'", yytext); }
 508
 509 <tkstr>\\[0-9]+         parser_error("Bad escape sequence");
 510 <tkstr>\\\n{ws}*        line_number++; char_number = 1; /* backslash at EOL continues string after leading whitespace on next line */
 511 <tkstr>\\a              addcchar('\a');
 512 <tkstr>\\b              addcchar('\b');
 513 <tkstr>\\f              addcchar('\f');
 514 <tkstr>\\n              addcchar('\n');
 515 <tkstr>\\r              addcchar('\r');
 516 <tkstr>\\t              addcchar('\t');
 517 <tkstr>\\v              addcchar('\v');
 518 <tkstr>\\.              addcchar(yytext[1]);
 519 <tkstr>\\\r\n           addcchar(yytext[2]); line_number++; char_number = 1;
 520 <tkstr>[^\\\n\"]+       {
 521                                 char *yptr = yytext;
 522                                 while(*yptr)
 523                                         addcchar(*yptr++);
 524                         }
 525 <tkstr>\"\"             addcchar('\"');         /* "bla""bla"   -> "bla\"bla" */
 526 <tkstr>\\\"\"           addcchar('\"');         /* "bla\""bla"  -> "bla\"bla" */
 527 <tkstr>\"{ws}+\"        ;                       /* "bla" "bla"  -> "blabla" */
 528 <tkstr>\n               parser_error("Unterminated string");
 529
 530         /*
 531          * Raw data scanning
 532          */
 533 \'                      yy_push_state(tkrcd); cbufidx = 0;
 534 <tkrcd>\'               {
 535                                 yy_pop_state();
 536                                 parser_lval.raw = new_raw_data();
 537                                 parser_lval.raw->size = cbufidx;
 538                                 parser_lval.raw->data = xmalloc(parser_lval.raw->size);
 539                                 memcpy(parser_lval.raw->data, cbuffer, parser_lval.raw->size);
 540                                 return tRAWDATA;
 541                         }
 542 <tkrcd>[0-9a-fA-F]{2}   {
 543                                 int result;
 544                                 result = strtol(yytext, 0, 16);
 545                                 addcchar((char)result);
 546                         }
 547 <tkrcd>{ws}+            ;       /* Ignore space */
 548 <tkrcd>\n               line_number++; char_number = 1;
 549 <tkrcd>.                parser_error("Malformed data-line");
 550
 551         /*
 552          * Comment stripping
 553          * Should never occur after preprocessing
 554          */
 555 <INITIAL,pp_cstrip>"/*" {
 556                                 yy_push_state(comment);
 557                                 save_wanted_id = wanted_id;
 558                                 if(!no_preprocess)
 559                                         parser_warning("Found comments after preprocessing, please report\n");
 560                         }
 561 <comment>[^*\n]*        ;
 562 <comment>"*"+[^*/\n]*   ;
 563 <comment>\n             line_number++; char_number = 1;
 564 <comment>"*"+"/"        yy_pop_state(); want_id = save_wanted_id;
 565
 566 ;[^\n]*                 want_id = wanted_id; /* not really comment, but left-over c-junk */
 567 "//"[^\n]*              want_id = wanted_id; if(!no_preprocess) parser_warning("Found comments after preprocessing, please report\n");
 568
 569 \n                      {
 570                                 want_id = wanted_id;
 571                                 line_number++;
 572                                 char_number = 1;
 573                                 if(want_nl)
 574                                 {
 575                                         want_nl = 0;
 576                                         return tNL;
 577                                 }
 578                         }
 579 {ws}+                   want_id = wanted_id;    /* Eat whitespace */
 580
 581 <INITIAL>[ -~]          return yytext[0];
 582
 583 <*>.|\n                 {
 584                                 /* Catch all rule to find any unmatched text */
 585                                 if(*yytext == '\n')
 586                                 {
 587                                         line_number++;
 588                                         char_number = 1;
 589                                 }
 590                                 parser_error("Unmatched text '%c' (0x%02x) YY_START=%d",
 591                                              isprint((unsigned char)*yytext) ? *yytext : '.', *yytext, YY_START);
 592                         }
 593
 594 %%
 595
 596 /* These dup functions copy the enclosed '\0' from
 597  * the resource string.
 598  */
 599 static void addcchar(char c)
 600 {
 601         if(cbufidx >= cbufalloc)
 602         {
 603                 cbufalloc += 1024;
 604                 cbuffer = xrealloc(cbuffer, cbufalloc * sizeof(cbuffer[0]));
 605                 if(cbufalloc > 65536)
 606                         parser_warning("Reallocating string buffer larger than 64kB\n");
 607         }
 608         cbuffer[cbufidx++] = c;
 609 }
 610
 611 static void addwchar(WCHAR s)
 612 {
 613         if(wbufidx >= wbufalloc)
 614         {
 615                 wbufalloc += 1024;
 616                 wbuffer = xrealloc(wbuffer, wbufalloc * sizeof(wbuffer[0]));
 617                 if(wbufalloc > 65536)
 618                         parser_warning("Reallocating wide string buffer larger than 64kB\n");
 619         }
 620         wbuffer[wbufidx++] = s;
 621 }
 622
 623 static string_t *get_buffered_cstring(void)
 624 {
 625     string_t *str = new_string();
 626
 627     str->size = cbufidx;
 628     str->type = str_char;
 629     str->str.cstr = xmalloc(cbufidx+1);
 630     memcpy(str->str.cstr, cbuffer, cbufidx);
 631     str->str.cstr[cbufidx] = '\0';
 632
 633     if (!current_codepage || current_codepage == -1 || !win32)  /* store as ANSI string */
 634     {
 635         if (!current_codepage) parser_error("Codepage set to Unicode only, cannot use ASCII string here");
 636         return str;
 637     }
 638     else  /* convert to Unicode before storing */
 639     {
 640         string_t *str_w = convert_string( str, str_unicode, current_codepage );
 641         if (!check_unicode_conversion( str, str_w, current_codepage ))
 642             parser_error("String %s does not convert identically to Unicode and back in codepage %d. "
 643                     "Try using a Unicode string instead", str->str.cstr, current_codepage );
 644         if (check_valid_utf8( str, current_codepage ))
 645             parser_warning( "string \"%s\" seems to be UTF-8 but codepage %u is in use.\n",
 646                             str->str.cstr, current_codepage );
 647         free_string( str );
 648         return str_w;
 649     }
 650 }
 651
 652 static string_t *get_buffered_wstring(void)
 653 {
 654         string_t *str = new_string();
 655         str->size = wbufidx;
 656         str->type = str_unicode;
 657         str->str.wstr = xmalloc((wbufidx+1)*sizeof(WCHAR));
 658         memcpy(str->str.wstr, wbuffer, wbufidx*sizeof(WCHAR));
 659         str->str.wstr[wbufidx] = 0;
 660         return str;
 661 }
 662
 663 static string_t *make_string(char *s)
 664 {
 665         string_t *str = new_string();
 666         str->size = strlen(s);
 667         str->type = str_char;
 668         str->str.cstr = xmalloc(str->size+1);
 669         memcpy(str->str.cstr, s, str->size+1);
 670         return str;
 671 }